4b41f5bd3be6eb514600614e290c834df62f3a49
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / maplist.qc
1 #include "maplist.qh"
2
3 #include <common/mapinfo.qh>
4 #include "dialog_multiplayer_create_mapinfo.qh"
5 #include "mainwindow.qh"
6 #include "inputbox.qh"
7
8 .bool disabled;
9
10 void XonoticMapList_destroy(entity me)
11 {
12         MapInfo_Shutdown();
13 }
14
15 entity makeXonoticMapList()
16 {
17         entity me;
18         me = NEW(XonoticMapList);
19         me.configureXonoticMapList(me);
20         return me;
21 }
22
23 entity MapList_Set_String_Filter_Box(entity me, entity e)
24 {
25         me.stringFilterBox = e;
26         return e;
27 }
28
29 void XonoticMapList_configureXonoticMapList(entity me)
30 {
31         me.configureXonoticListBox(me);
32         me.refilter(me);
33 }
34
35 void XonoticMapList_loadCvars(entity me)
36 {
37         me.refilter(me);
38 }
39
40
41 float XonoticMapList_g_maplistCacheQuery(entity me, float i)
42 {
43         return stof(substring(me.g_maplistCache, i, 1));
44 }
45 void XonoticMapList_g_maplistCacheToggle(entity me, float i)
46 {
47         string a, b, c, s, bspname;
48         float n;
49         s = me.g_maplistCache;
50         if (!s)
51                 return;
52         b = substring(s, i, 1);
53         if(b == "0")
54                 b = "1";
55         else if(b == "1")
56                 b = "0";
57         else
58                 return; // nothing happens
59         a = substring(s, 0, i);
60         c = substring(s, i+1, strlen(s) - (i+1));
61         strunzone(s);
62         me.g_maplistCache = strzone(strcat(a, b, c));
63         // TODO also update the actual cvar
64         if (!((bspname = MapInfo_BSPName_ByID(i))))
65                 return;
66         if(b == "1")
67                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
68         else
69         {
70                 s = "";
71                 n = tokenize_console(cvar_string("g_maplist"));
72                 for(i = 0; i < n; ++i)
73                         if(argv(i) != bspname)
74                                 s = strcat(s, " ", argv(i));
75                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
76         }
77 }
78
79 void XonoticMapList_draw(entity me)
80 {
81         if(me.startButton)
82                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
83         SUPER(XonoticMapList).draw(me);
84 }
85
86 void XonoticMapList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
87 {
88         me.itemAbsSize = '0 0 0';
89         SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
90
91         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
92         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
93         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
94         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
95
96         me.columnPreviewOrigin = 0;
97         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
98         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
99         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
100
101         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
102         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
103 }
104
105 void XonoticMapList_clickListBoxItem(entity me, float i, vector where)
106 {
107         if(where.x <= me.columnPreviewOrigin + me.columnPreviewSize)
108                 if(where.x >= 0)
109                 {
110                         m_play_click_sound(MENU_SOUND_SELECT);
111                         me.g_maplistCacheToggle(me, i);
112                 }
113 }
114
115 void XonoticMapList_doubleClickListBoxItem(entity me, float i, vector where)
116 {
117         if(where.x >= me.columnNameOrigin)
118                 if(where.x <= 1)
119                 {
120                         // pop up map info screen
121                         m_play_click_sound(MENU_SOUND_OPEN);
122                         main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
123                         DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
124                 }
125 }
126
127 void XonoticMapList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
128 {
129         // layout: Ping, Map name, Map name, NP, TP, MP
130         string s;
131         float theAlpha;
132         float included;
133
134         if(!MapInfo_Get_ByID(i))
135                 return;
136
137         included = me.g_maplistCacheQuery(me, i);
138         if(included || isSelected)
139                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
140         else
141                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
142
143         if(isSelected)
144                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
145         else
146         {
147                 if(included)
148                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
149                 if(isFocused)
150                 {
151                         me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
152                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
153                 }
154         }
155
156         if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
157                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
158         else
159                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
160
161         if(included)
162                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
163         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
164         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
165         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
166         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
167
168         MapInfo_ClearTemps();
169 }
170
171 void XonoticMapList_refilter(entity me)
172 {
173         float i, j, n;
174         string s;
175         float gt, f;
176         gt = MapInfo_CurrentGametype();
177         f = MapInfo_CurrentFeatures();
178         MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
179         if (me.stringFilter)
180                 MapInfo_FilterString(me.stringFilter);
181         me.nItems = MapInfo_count;
182
183         for(i = 0; i < MapInfo_count; ++i)
184                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
185         if(me.g_maplistCache)
186                 strunzone(me.g_maplistCache);
187         s = "0";
188         for(i = 1; i < MapInfo_count; i *= 2)
189                 s = strcat(s, s);
190         n = tokenize_console(cvar_string("g_maplist"));
191         for(i = 0; i < n; ++i)
192         {
193                 j = MapInfo_FindName(argv(i));
194                 if(j >= 0)
195                 {
196                         // double check that the two mapnames are "identical", not just share the same prefix
197                         if (strlen(MapInfo_BSPName_ByID(j)) == strlen(argv(i)))
198                                 s = strcat(
199                                         substring(s, 0, j),
200                                         "1",
201                                         substring(s, j+1, MapInfo_count - (j+1))
202                                 );
203                 }
204         }
205         me.g_maplistCache = strzone(s);
206         if(gt != me.lastGametype || f != me.lastFeatures)
207         {
208                 me.lastGametype = gt;
209                 me.lastFeatures = f;
210                 me.setSelected(me, 0);
211         }
212 }
213
214 void XonoticMapList_refilterCallback(entity me, entity cb)
215 {
216         me.refilter(me);
217 }
218
219 void MapList_StringFilterBox_Change(entity box, entity me)
220 {
221         if(me.stringFilter)
222                 strunzone(me.stringFilter);
223         if(box.text != "")
224                 me.stringFilter = strzone(box.text);
225         else
226                 me.stringFilter = string_null;
227
228         me.refilter(me);
229 }
230
231 void MapList_Add_Shown(entity btn, entity me)
232 {
233         float i, n;
234         n = strlen(me.g_maplistCache);
235         for (i = 0 ; i < n; i++)
236         {
237                 if (!me.g_maplistCacheQuery(me, i))
238                         me.g_maplistCacheToggle(me, i);
239         }
240         me.refilter(me);
241 }
242
243 void MapList_Remove_Shown(entity btn, entity me)
244 {
245         float i, n;
246         n = strlen(me.g_maplistCache);
247         for (i = 0 ; i < n; i++)
248         {
249                 if (me.g_maplistCacheQuery(me, i))
250                         me.g_maplistCacheToggle(me, i);
251         }
252         me.refilter(me);
253 }
254
255 void MapList_Add_All(entity btn, entity me)
256 {
257         float i;
258         string s;
259         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MapInfo_ForbiddenFlags(), 0); // all
260         s = "";
261         for(i = 0; i < MapInfo_count; ++i)
262                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
263         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
264         me.refilter(me);
265 }
266
267 void MapList_Remove_All(entity btn, entity me)
268 {
269         cvar_set("g_maplist", "");
270         me.refilter(me);
271 }
272
273 void MapList_LoadMap(entity btn, entity me)
274 {
275         string m;
276         float i;
277
278         i = me.selectedItem;
279
280         if(btn.parent.instanceOfXonoticMapInfoDialog)
281         {
282                 i = btn.parent.currentMapIndex;
283                 Dialog_Close(btn, btn.parent);
284         }
285
286         if(i >= me.nItems || i < 0)
287                 return;
288
289         m = MapInfo_BSPName_ByID(i);
290         if (!m)
291         {
292                 LOG_INFO(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n"));
293                 me.refilter(me);
294                 return;
295         }
296         if(MapInfo_CheckMap(m))
297         {
298                 localcmd("\nmenu_loadmap_prepare\n");
299                 if(cvar("menu_use_default_hostname"))
300                         localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
301                 MapInfo_LoadMap(m, 1);
302         }
303         else
304         {
305                 LOG_INFO(_("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n"));
306                 me.refilter(me);
307                 return;
308         }
309 }
310
311 float XonoticMapList_keyDown(entity me, float scan, float ascii, float shift)
312 {
313         string ch, save;
314         if(me.nItems <= 0)
315                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
316         if(scan == K_MOUSE2 || scan == K_SPACE || scan == K_ENTER || scan == K_KP_ENTER)
317         {
318                 // pop up map info screen
319                 m_play_click_sound(MENU_SOUND_OPEN);
320                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
321                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
322         }
323         else if(scan == K_MOUSE3 || scan == K_INS || scan == K_KP_INS)
324         {
325                 m_play_click_sound(MENU_SOUND_SELECT);
326                 me.g_maplistCacheToggle(me, me.selectedItem);
327         }
328         else if(ascii == 43) // +
329         {
330                 if (!me.g_maplistCacheQuery(me, me.selectedItem))
331                 {
332                         m_play_click_sound(MENU_SOUND_SELECT);
333                         me.g_maplistCacheToggle(me, me.selectedItem);
334                 }
335         }
336         else if(ascii == 45) // -
337         {
338                 if(me.g_maplistCacheQuery(me, me.selectedItem))
339                 {
340                         m_play_click_sound(MENU_SOUND_SELECT);
341                         me.g_maplistCacheToggle(me, me.selectedItem);
342                 }
343         }
344         else if(scan == K_BACKSPACE)
345         {
346                 if(time < me.typeToSearchTime)
347                 {
348                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
349                         if(me.typeToSearchString)
350                                 strunzone(me.typeToSearchString);
351                         me.typeToSearchString = strzone(save);
352                         me.typeToSearchTime = time + 0.5;
353                         if(strlen(me.typeToSearchString))
354                         {
355                                 MapInfo_FindName(me.typeToSearchString);
356                                 if(MapInfo_FindName_firstResult >= 0)
357                                         me.setSelected(me, MapInfo_FindName_firstResult);
358                         }
359                 }
360         }
361         else if(ascii >= 32 && ascii != 127)
362         {
363                 ch = chr(ascii);
364                 if(time > me.typeToSearchTime)
365                         save = ch;
366                 else
367                         save = strcat(me.typeToSearchString, ch);
368                 if(me.typeToSearchString)
369                         strunzone(me.typeToSearchString);
370                 me.typeToSearchString = strzone(save);
371                 me.typeToSearchTime = time + 0.5;
372                 MapInfo_FindName(me.typeToSearchString);
373                 if(MapInfo_FindName_firstResult >= 0)
374                         me.setSelected(me, MapInfo_FindName_firstResult);
375         }
376         else if(shift & S_CTRL && scan == 'f') // ctrl-f (as in "F"ind)
377         {
378                 me.parent.setFocus(me.parent, me.stringFilterBox);
379         }
380         else if(shift & S_CTRL && scan == 'u') // ctrl-u (remove stringFilter line
381         {
382                 me.stringFilterBox.setText(me.stringFilterBox, "");
383                 MapList_StringFilterBox_Change(me.stringFilterBox, me);
384         }
385         else
386                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
387         return 1;
388 }
389
390 float MapList_StringFilterBox_keyDown(entity me, float scan, float ascii, float shift)
391 {
392         // in this section, note that onChangeEntity has the ref to mapListBox
393         // we make use of that, instead of extending a class to add one more attrib
394         switch(scan)
395         {
396                 case K_KP_ENTER:
397                 case K_ENTER:
398                         // move the focus to the mapListBox
399                         me.onChangeEntity.parent.setFocus(me.onChangeEntity.parent, me.onChangeEntity);
400                         return 1;
401                 case K_KP_UPARROW:
402                 case K_UPARROW:
403                 case K_KP_DOWNARROW:
404                 case K_DOWNARROW:
405                         // pass the event to the mapListBox (to scroll up and down)
406                         return me.onChangeEntity.keyDown(me.onChangeEntity, scan, ascii, shift);
407         }
408         return SUPER(XonoticInputBox).keyDown(me, scan, ascii, shift);
409 }