qcsrc/menu/xonotic/slider_resolution.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticResolutionSlider) EXTENDS(XonoticTextSlider)
   3         METHOD(XonoticResolutionSlider, configureXonoticResolutionSlider, void(entity))
   4         METHOD(XonoticResolutionSlider, addResolution, void(entity, float, float, float))
   5         METHOD(XonoticResolutionSlider, loadCvars, void(entity))
   6         METHOD(XonoticResolutionSlider, saveCvars, void(entity))
   7         METHOD(XonoticResolutionSlider, draw, void(entity))
   8 ENDCLASS(XonoticResolutionSlider)
   9 entity makeXonoticResolutionSlider();
  10 void updateConwidths(float width, float height, float pixelheight);
  11 #endif
  12
  13 #ifdef IMPLEMENTATION
  14
  15 /* private static */ float XonoticResolutionSlider_DataHasChanged;
  16
  17 // Updates cvars (to be called by menu.qc at startup or on detected res change)
  18 void updateConwidths(float width, float height, float pixelheight)
  19 {
  20         vector r, c;
  21         float minfactor, maxfactor;
  22         float sz, f;
  23
  24         // Save off current settings.
  25         cvar_set("_menu_vid_width", ftos(width));
  26         cvar_set("_menu_vid_height", ftos(height));
  27         cvar_set("_menu_vid_pixelheight", ftos(pixelheight));
  28
  29         r_x = width;
  30         r_y = height;
  31         r_z = pixelheight;
  32         sz = cvar("menu_vid_scale");
  33
  34         // calculate the base resolution
  35         c_z = 0;
  36         c_x = 800;
  37         c_y = c_x * r_y * r_z / r_x;
  38         if(c_y < 600)
  39         {
  40                 c_y = 600;
  41                 c_x = c_y * r_x / (r_y * r_z);
  42         }
  43
  44         f = min(r_x / c_x, r_y / c_y);
  45         if(f < 1)
  46                 c = c * f; // ensures that c_x <= r_x and c_y <= r_y
  47
  48         minfactor = min(1, 640 / c_x);            // can be > 1 only if c_x is <640
  49         maxfactor = max(1, r_x / c_x, r_y / c_y); // can be < 1 only if r_x < c_x and r_y < c_y
  50         dprint("min factor: ", ftos(minfactor), "\n");
  51         dprint("max factor: ", ftos(maxfactor), "\n");
  52
  53         if(sz < 0)
  54                 f = 1 - (maxfactor - 1) * sz;
  55         else if(sz > 0)
  56                 f = 1 + (minfactor - 1) * sz;
  57         else
  58                 f = 1;
  59         c = c * f; // fteqcc fail
  60
  61         cvar_set("vid_conwidth", ftos(rint(c_x)));
  62         cvar_set("vid_conheight", ftos(rint(c_y)));
  63         XonoticResolutionSlider_DataHasChanged = TRUE;
  64 }
  65 entity makeXonoticResolutionSlider()
  66 {
  67         entity me;
  68         me = spawnXonoticResolutionSlider();
  69         me.configureXonoticResolutionSlider(me);
  70         return me;
  71 }
  72 void XonoticResolutionSlider_addResolution(entity me, float w, float h, float pixelheight)
  73 {
  74         me.addValue(me, strzone(sprintf(_("%dx%d"), w, h)), strzone(strcat(ftos(w), " ", ftos(h), " ", ftos(pixelheight))));
  75         // FIXME (in case you ever want to dynamically instantiate this): THIS IS NEVER FREED
  76 }
  77 float autocvar_menu_vid_allowdualscreenresolution;
  78 void XonoticResolutionSlider_configureXonoticResolutionSlider(entity me)
  79 {
  80         float i;
  81         vector r0, r;
  82
  83         me.configureXonoticTextSlider(me, "_menu_vid_width");
  84
  85         r0 = '0 0 0';
  86         for(i = 0;; ++i)
  87         {
  88                 r = getresolution(i);
  89                 if(r_x == 0 && r_y == 0)
  90                         break;
  91                 if(r_z == 0)
  92                         r_z = 1; // compat
  93                 if(r == r0)
  94                         continue;
  95                 r0 = r;
  96                 if(r_x < 640 || r_y < 480)
  97                         continue;
  98                 if(r_x > 2 * r_y) // likely dualscreen resolution, skip this one
  99                         if(autocvar_menu_vid_allowdualscreenresolution <= 0)
 100                                 continue;
 101
 102                 me.addResolution(me, r_x, r_y, r_z);
 103         }
 104
 105         if(me.nValues == 0)
 106         {
 107                 me.addResolution(me, 640, 480, 1);
 108                 me.addResolution(me, 800, 600, 1);
 109                 me.addResolution(me, 1024, 768, 1);
 110                 me.addResolution(me, 1280, 960, 1);
 111                 me.addResolution(me, 1280, 1024, 1);
 112                 me.addResolution(me, 1650, 1080, 1);
 113                 me.addResolution(me, 1920, 1080, 1);
 114         }
 115
 116         me.configureXonoticTextSliderValues(me);
 117 }
 118 void XonoticResolutionSlider_loadCvars(entity me)
 119 {
 120         me.setValueFromIdentifier(me, strcat(cvar_string("_menu_vid_width"), " ", cvar_string("_menu_vid_height"), " ", cvar_string("_menu_vid_pixelheight")));
 121 }
 122 void XonoticResolutionSlider_saveCvars(entity me)
 123 {
 124         if(me.value >= 0 || me.value < me.nValues)
 125         {
 126                 tokenize_console(me.getIdentifier(me));
 127                 cvar_set("_menu_vid_width", argv(0));
 128                 cvar_set("_menu_vid_height", argv(1));
 129                 cvar_set("_menu_vid_pixelheight", argv(2));
 130         }
 131 }
 132 void XonoticResolutionSlider_draw(entity me)
 133 {
 134         if (XonoticResolutionSlider_DataHasChanged)
 135         {
 136                 XonoticResolutionSlider_DataHasChanged = FALSE;
 137                 me.loadCvars(me);
 138         }
 139         SUPER(XonoticResolutionSlider).draw(me);
 140 }
 141 #endif