qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 void loadTooltips()
  12 {
  13         tooltipdb = db_load(language_filename("tooltips.db"));
  14 }
  15 void unloadTooltips()
  16 {
  17         if(tooltipdb >= 0)
  18                 db_close(tooltipdb);
  19         tooltipdb = -1;
  20 }
  21 string getZonedTooltipForIdentifier(string s)
  22 {
  23         string t;
  24         if(s == "")
  25                 return string_null;
  26         if(tooltipdb >= 0)
  27         {
  28                 t = db_get(tooltipdb, s);
  29                 if(t == "-")
  30                         return string_null;
  31                 if(t != "")
  32                         return strzone(t);
  33         }
  34         if(prvm_language == "en" || prvm_language == "")
  35         {
  36                 t = cvar_description(s);
  37                 if(t != "" && t != "custom cvar")
  38                         return strzone(t);
  39         }
  40         dprint("WARNING: no tooltip set for ", s, "\n");
  41         return string_null;
  42 }
  43
  44 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  45 {
  46         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  47 }
  48
  49 .string cvarName;
  50 void SUB_Null_ee(entity e1, entity e2)
  51 {
  52 }
  53 void saveCvarsOf(entity ignore, entity e)
  54 {
  55         if(e.saveCvars)
  56                 e.saveCvars(e);
  57 }
  58 void loadCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.loadCvars)
  61                 e.loadCvars(e);
  62 }
  63 void saveAllCvars(entity root)
  64 {
  65         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  66 }
  67 void loadAllCvars(entity root)
  68 {
  69         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  70 }
  71
  72 .string cvarNames_Multi;
  73 .void(entity me) saveCvars_Multi;
  74 string getCvarsMulti(entity me)
  75 {
  76         if (me.cvarNames_Multi)
  77                 return me.cvarNames_Multi;
  78         return string_null;
  79 }
  80 void saveCvarsMulti(entity me)
  81 {
  82         float n, i;
  83         string s;
  84
  85         me.saveCvars_Multi(me);
  86         s = cvar_string(me.cvarName);
  87
  88         n = tokenize_console(me.cvarNames_Multi);
  89         for(i = 0; i < n; ++i)
  90                 cvar_set(argv(i), s);
  91 }
  92 void makeMulti(entity e, string otherCvars)
  93 {
  94         e.cvarNames_Multi = otherCvars;
  95         e.saveCvars_Multi = e.saveCvars;
  96         e.saveCvars = saveCvarsMulti;
  97 }
  98
  99 .void(entity me) saveCvars_Callback;
 100 .entity saveCvars_Callback_ent;
 101 .void(entity me, entity cb) saveCvars_Callback_func;
 102 void saveCvarsCallback(entity me)
 103 {
 104         me.saveCvars_Callback(me);
 105         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 106 }
 107 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 108 {
 109         e.saveCvars_Callback = e.saveCvars;
 110         e.saveCvars = saveCvarsCallback;
 111         e.saveCvars_Callback_ent = cbent;
 112         e.saveCvars_Callback_func = cbfunc;
 113 }
 114
 115 .void(entity) draw_setDependent;
 116 .string cvar_setDependent;
 117 .float cvarMin_setDependent;
 118 .float cvarMax_setDependent;
 119 .string cvar2_setDependent;
 120 .float cvar2Min_setDependent;
 121 .float cvar2Max_setDependent;
 122 .string cvar3_setDependent;
 123 .float cvar3Min_setDependent;
 124 .float cvar3Max_setDependent;
 125 .float op_setDependent;
 126 .string cvarString_setDependent;
 127 .string cvarValue_setDependent;
 128 .float(entity) func_setDependent;
 129 void setDependent_Check(entity e)
 130 {
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169 }
 170 void setDependent_Draw(entity e)
 171 {
 172         setDependent_Check(e);
 173         e.draw_setDependent(e);
 174 }
 175 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 176 {
 177         e.draw_setDependent = e.draw;
 178         e.cvar_setDependent = theCvarName;
 179         e.cvarMin_setDependent = theCvarMin;
 180         e.cvarMax_setDependent = theCvarMax;
 181         e.cvar2_setDependent = string_null;
 182         e.cvar3_setDependent = string_null;
 183         e.func_setDependent = func_null;
 184         e.draw = setDependent_Draw;
 185         setDependent_Check(e);
 186 }
 187 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvarString_setDependent = theCvarName;
 191         e.cvarValue_setDependent = theCvarValue;
 192         e.cvar_setDependent = string_null;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvar_setDependent = theCvarName;
 203         e.cvarMin_setDependent = theCvarMin;
 204         e.cvarMax_setDependent = theCvarMax;
 205         e.cvar2_setDependent = theCvar2Name;
 206         e.cvar2Min_setDependent = theCvar2Min;
 207         e.cvar2Max_setDependent = theCvar2Max;
 208         e.cvar3_setDependent = string_null;
 209         e.op_setDependent = 0;
 210         e.func_setDependent = func_null;
 211         e.draw = setDependent_Draw;
 212         setDependent_Check(e);
 213 }
 214 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 215 {
 216         e.draw_setDependent = e.draw;
 217         e.cvar_setDependent = theCvarName;
 218         e.cvarMin_setDependent = theCvarMin;
 219         e.cvarMax_setDependent = theCvarMax;
 220         e.cvar2_setDependent = theCvar2Name;
 221         e.cvar2Min_setDependent = theCvar2Min;
 222         e.cvar2Max_setDependent = theCvar2Max;
 223         e.cvar3_setDependent = string_null;
 224         e.op_setDependent = 1;
 225         e.func_setDependent = func_null;
 226         e.draw = setDependent_Draw;
 227         setDependent_Check(e);
 228 }
 229 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 230 {
 231         e.draw_setDependent = e.draw;
 232         e.cvar_setDependent = theCvarName;
 233         e.cvarMin_setDependent = theCvarMin;
 234         e.cvarMax_setDependent = theCvarMax;
 235         e.cvar2_setDependent = theCvar2Name;
 236         e.cvar2Min_setDependent = theCvar2Min;
 237         e.cvar2Max_setDependent = theCvar2Max;
 238         e.cvar3_setDependent = theCvar3Name;
 239         e.cvar3Min_setDependent = theCvar3Min;
 240         e.cvar3Max_setDependent = theCvar3Max;
 241         e.op_setDependent = 0;
 242         e.func_setDependent = func_null;
 243         e.draw = setDependent_Draw;
 244         setDependent_Check(e);
 245 }
 246 void setDependentWeird(entity e, float(entity) func)
 247 {
 248         e.draw_setDependent = e.draw;
 249         e.func_setDependent = func;
 250         e.draw = setDependent_Draw;
 251         setDependent_Check(e);
 252 }
 253
 254 // URI SYSTEM ////////////////////////////////////////////////////////
 255
 256 float _Nex_ExtResponseSystem_Queried;
 257 string _Nex_ExtResponseSystem_UpdateTo;
 258 string _Nex_ExtResponseSystem_UpdateToURL;
 259 string _Nex_ExtResponseSystem_BannedServers;
 260
 261 void URI_Get_Callback(float id, float status, string data)
 262 {
 263         if (id == URI_GET_DISCARD)
 264         {
 265                 // discard
 266         }
 267         else if(id == URI_GET_UPDATENOTIFICATION)
 268         {
 269                 UpdateNotification_URI_Get_Callback(id, status, data);
 270         }
 271         else if(id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 272         {
 273                 Curl_URI_Get_Callback(id, status, data);
 274         }
 275         else
 276         {
 277                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 278         }
 279 }
 280
 281 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 282 {
 283         float n;
 284
 285         if(_Nex_ExtResponseSystem_UpdateTo)
 286         {
 287                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 288                 return;
 289         }
 290         if(status != 0)
 291         {
 292                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 293                 return;
 294         }
 295         if(substring(data, 0, 1) == "<")
 296         {
 297                 print(_("error: received HTML instead of an update notification\n"));
 298                 return;
 299         }
 300         if(strstrofs(data, "\r", 0) != -1)
 301         {
 302                 print(_("error: received carriage returns from update notification server\n"));
 303                 return;
 304         }
 305
 306         if(data == "")
 307                 n = 0;
 308         else
 309                 n = tokenizebyseparator(data, "\n");
 310
 311         if(n >= 1)
 312         {
 313                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 314
 315                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 316                 {
 317                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 318                 }
 319                 else
 320                 {
 321                         // update needed
 322                         if(n >= 2)
 323                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 324                         if(n >= 3)
 325                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 326                 }
 327
 328                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 329
 330                 if(n >= 4)
 331                         _Nex_ExtResponseSystem_BannedServers = strzone(argv(3));
 332         }
 333 }
 334
 335 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 336
 337 float preMenuInit()
 338 {
 339         vector sz;
 340         vector boxA, boxB;
 341
 342         MapInfo_Cache_Create();
 343         MapInfo_Enumerate();
 344         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 345         {
 346                 draw_reset_cropped();
 347
 348                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 349                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 350
 351                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 352                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 353                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 354
 355                 boxA += sz * 0.1;
 356                 boxB -= sz * 0.1;
 357                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 358
 359                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 360                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 361
 362                 return FALSE;
 363         }
 364         return TRUE;
 365 }
 366
 367 string campaign_name_previous;
 368 float campaign_won_previous;
 369 #ifdef WATERMARK
 370 var string autocvar_menu_watermark = WATERMARK();
 371 #else
 372 var string autocvar_menu_watermark = "";
 373 #endif
 374 void postMenuDraw()
 375 {
 376         if(autocvar_menu_watermark != "")
 377         {
 378                 vector fs = '48 48 0';
 379                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 380         }
 381 }
 382 void preMenuDraw()
 383 {
 384         vector fs, sz, line, mid;
 385
 386         if(cvar("menu_updatecheck"))
 387         {
 388                 if(!_Nex_ExtResponseSystem_Queried)
 389                 {
 390                         _Nex_ExtResponseSystem_Queried = 1;
 391                         float startcnt;
 392                         string uri;
 393
 394                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 395
 396                         // for privacy, munge the start count a little
 397                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 398                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 399
 400 #ifdef CVAR_POPCON
 401                         float cvar_handle, popcon_handle;
 402                         float n, i, j;
 403                         string k, s;
 404                         cvar_handle = buf_create();
 405                         buf_cvarlist(cvar_handle, "", "");
 406                         n = buf_getsize(cvar_handle);
 407                         popcon_handle = buf_create();
 408                         for(i= 0, j = 0; i < n; ++i)
 409                         {
 410                                 k = bufstr_get(cvar_handle, i);
 411                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 412                                         continue;
 413                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 414                                 bufstr_set(popcon_handle, j, s);
 415                                 ++j;
 416                         }
 417                         buf_del(cvar_handle);
 418                         uri_postbuf(
 419                                 uri, URI_GET_UPDATENOTIFICATION,
 420                                 "application/x-www-form-urlencoded",
 421                                 "&",
 422                                 popcon_handle
 423                         );
 424                         buf_del(popcon_handle);
 425 #else
 426                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 427 #endif
 428                 }
 429         }
 430
 431         if(_Nex_ExtResponseSystem_UpdateTo != "")
 432         {
 433                 // TODO rather turn this into a dialog
 434                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 435                 line = eY * fs_y;
 436                 string l1, l2;
 437                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 438                 l2 = "http://www.xonotic.org/";
 439                 if(_Nex_ExtResponseSystem_UpdateToURL)
 440                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 441
 442                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 443                                 draw_TextWidth(l1, 0, fs),
 444                                 draw_TextWidth(l2, 0, fs)
 445                         );
 446                 sz_y = 3 * fs_y;
 447
 448                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 449                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 450                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 451
 452                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 453                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 454                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 455         }
 456         if not(campaign_name_previous)
 457                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 458         if(campaign_name == campaign_name_previous)
 459         {
 460                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 461                 {
 462                         if(!campaign_won_previous)
 463                         {
 464                                 m_display();
 465                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 466                         }
 467                         campaign_won_previous = 1;
 468                 }
 469                 else
 470                         campaign_won_previous = 0;
 471         }
 472         else
 473         {
 474                 strunzone(campaign_name_previous);
 475                 campaign_name_previous = strzone(campaign_name);
 476                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 477         }
 478 }
 479
 480 string resolvemod(string m)
 481 {
 482         if(m == "=")
 483                 return getcurrentmod();
 484         else
 485                 return m;
 486 }
 487
 488 float updateCompression()
 489 {
 490         float have_dds, have_jpg, have_tga;
 491         float can_dds;
 492         have_dds = (fexists("dds/particles/particlefont.dds"));
 493         have_jpg = (fexists("particles/particlefont.jpg"));
 494         have_tga = (fexists("particles/particlefont.tga"));
 495         can_dds = GL_Have_TextureCompression();
 496         if(have_dds && (have_jpg || have_tga))
 497         {
 498                 // both? Let's only use good quality precompressed files
 499                 // but ONLY if we actually support it!
 500                 if(can_dds)
 501                 {
 502                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 503                         cvar_set("gl_texturecompression", "0");
 504                         return 1;
 505
 506                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 507                         //return 2;
 508                 }
 509                 else
 510                 {
 511                         cvar_set("gl_texturecompression", "0");
 512                         cvar_set("r_texture_dds_load", "0");
 513                         return 0;
 514                 }
 515         }
 516         else if(have_dds)
 517         {
 518                 // DDS only? We probably always want texture compression
 519                 cvar_set("gl_texturecompression", "1");
 520                 cvar_set("r_texture_dds_load", "1");
 521                 if(!can_dds)
 522                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 523                 return 0;
 524         }
 525         else
 526         {
 527                 // TGA only? Allow runtime compression
 528                 if(can_dds)
 529                 {
 530                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 531                         return 2;
 532                 }
 533                 else
 534                 {
 535                         cvar_set("gl_texturecompression", "0");
 536                         cvar_set("r_texture_dds_load", "0");
 537                         return 0;
 538                 }
 539         }
 540 }
 541
 542 // note: include only those that should be in the menu!
 543 #define GAMETYPES \
 544         GAMETYPE(MAPINFO_TYPE_ARENA, _("Arena")) \
 545         GAMETYPE(MAPINFO_TYPE_ASSAULT, _("Assault")) \
 546         GAMETYPE(MAPINFO_TYPE_CTF, _("Capture The Flag")) \
 547         GAMETYPE(MAPINFO_TYPE_CA, _("Clan Arena")) \
 548         GAMETYPE(MAPINFO_TYPE_DEATHMATCH, _("Deathmatch")) \
 549         GAMETYPE(MAPINFO_TYPE_DOMINATION, _("Domination")) \
 550         GAMETYPE(MAPINFO_TYPE_FREEZETAG, _("Freeze Tag")) \
 551         GAMETYPE(MAPINFO_TYPE_KEEPAWAY, _("Keepaway")) \
 552         GAMETYPE(MAPINFO_TYPE_KEYHUNT, _("Key Hunt")) \
 553         GAMETYPE(MAPINFO_TYPE_LMS, _("Last Man Standing")) \
 554         GAMETYPE(MAPINFO_TYPE_NEXBALL, _("Nexball")) \
 555         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT, _("Onslaught")) \
 556         GAMETYPE(MAPINFO_TYPE_RACE, _("Race")) \
 557         GAMETYPE(MAPINFO_TYPE_CTS, _("Race CTS")) \
 558         GAMETYPE(MAPINFO_TYPE_RUNEMATCH, _("Runematch")) \
 559         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH, _("Team Deathmatch")) \
 560         /* nothing */
 561
 562 float GameType_GetID(float cnt)
 563 {
 564         float i;
 565         i = 0;
 566 #define GAMETYPE(id,name) if(i++ == cnt) return id;
 567         GAMETYPES
 568 #undef GAMETYPE
 569         return 0;
 570 }
 571 string GameType_GetName(float cnt)
 572 {
 573         float i;
 574         i = 0;
 575 #define GAMETYPE(id,name) if(i++ == cnt) return name;
 576         GAMETYPES
 577 #undef GAMETYPE
 578         return _("@!#%'n Tuba Throwing");
 579 }
 580 float GameType_GetCount()
 581 {
 582         float i;
 583         i = 0;
 584 #define GAMETYPE(id,name) ++i;
 585         GAMETYPES
 586 #undef GAMETYPE
 587         return i;
 588 }
 589
 590 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 591 {
 592         float i;
 593         entity e;
 594
 595         me.TR(me);
 596                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 597                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 598                                 e.addValue(e, _("Default"), "");
 599                                 e.addValue(e, _("Disable"), "0");
 600                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 601                                 e.configureXonoticTextSliderValues(e);
 602         me.TR(me);
 603                 me.TDempty(me, 0.2);
 604                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 605                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 606                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 607         me.TR(me);
 608                 me.TDempty(me, 0.2);
 609                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 610         me.TR(me);
 611                 me.TDempty(me, 0.2);
 612                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 613                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 614                                 e.addValue(e, _("Default"), "");
 615                                 e.addValue(e, _("Disable"), "0");
 616                                 for(i = 1; i <= 10; ++i)
 617                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 618                                 e.configureXonoticTextSliderValues(e);
 619         me.TR(me);
 620                 me.TDempty(me, 0.2);
 621                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 622                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 623                                 e.addValue(e, _("Default"), "");
 624                                 for(i = 1; i <= 10; ++i)
 625                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 626                                 e.configureXonoticTextSliderValues(e);
 627         me.TR(me);
 628                 me.TDempty(me, 0.2);
 629                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 630                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 631                                 e.addValue(e, _("Default"), "");
 632                                 e.addValue(e, _("Disable"), "0");
 633                                 for(i = 1; i <= 10; ++i)
 634                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 635                                 e.configureXonoticTextSliderValues(e);
 636         me.TR(me);
 637                 me.TDempty(me, 0.4);
 638                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 639         me.TR(me);
 640                 me.TDempty(me, 0.2);
 641                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 642                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 643                                 e.addValue(e, _("Default"), "");
 644                                 for(i = 0; i <= 10; ++i)
 645                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 646                                 e.configureXonoticTextSliderValues(e);
 647 }