qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 174                 TeamBalance_GetTeamCounts(balance, NULL);
 175                 int smallest_team = -1;
 176                 int smallest_count = -1;
 177                 if (teamplay)
 178                 {
 179                         for (int i = 1; i <= AvailableTeams(); ++i)
 180                         {
 181                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 182                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 183                                 // since it keeps a spot for the real player in the desired team
 184                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 185                                 if (smallest_count < 0 || count < smallest_count)
 186                                 {
 187                                         smallest_team = i;
 188                                         smallest_count = count;
 189                                 }
 190                         }
 191                 }
 192                 TeamBalance_Destroy(balance);
 193                 RandomSelection_Init();
 194                 while((readfile = fgets(file)))
 195                 {
 196                         if(substring(readfile, 0, 2) == "//")
 197                                 continue;
 198                         if(substring(readfile, 0, 1) == "#")
 199                                 continue;
 200                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 201                         // will create 1 empty token because there's no separator (bug?)
 202                         if (readfile == "")
 203                                 continue;
 204                         tokens = tokenizebyseparator(readfile, "\t");
 205                         if(tokens == 0)
 206                                 continue;
 207                         s = argv(0);
 208                         prio = 0;
 209                         bool conflict = false;
 210                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 211                                 if (s == it.cleanname)
 212                                 {
 213                                         conflict = true;
 214                                         break;
 215                                 }
 216                         });
 217                         if (!conflict)
 218                                 prio += 1;
 219                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 220                         {
 221                                 int forced_team = stof(argv(5));
 222                                 if (!Team_IsValidIndex(forced_team))
 223                                         forced_team = 0;
 224                                 if (!forced_team || forced_team == smallest_team)
 225                                         prio += 2;
 226                         }
 227                         RandomSelection_AddString(readfile, 1, prio);
 228                 }
 229                 readfile = RandomSelection_chosen_string;
 230                 fclose(file);
 231         }
 232
 233         tokens = tokenizebyseparator(readfile, "\t");
 234         if(argv(0) != "") bot_name = argv(0);
 235         else bot_name = "Bot";
 236
 237         if(argv(1) != "") bot_model = argv(1);
 238         else bot_model = "";
 239
 240         if(argv(2) != "") bot_skin = argv(2);
 241         else bot_skin = "0";
 242
 243         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 244         else bot_shirt = ftos(floor(random() * 15));
 245
 246         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 247         else bot_pants = ftos(floor(random() * 15));
 248
 249         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 250                 this.bot_forced_team = stof(argv(5));
 251         else
 252                 this.bot_forced_team = 0;
 253
 254         prio = 6;
 255
 256         #define READSKILL(f, w, r) MACRO_BEGIN \
 257                 if(argv(prio) != "") \
 258                         this.f = stof(argv(prio)) * w; \
 259                 else \
 260                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 261                 prio++; \
 262         MACRO_END
 263         //print(bot_name, ": ping=", argv(9), "\n");
 264
 265         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 266         READSKILL(bot_moveskill, 2, 0); // move skill
 267         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 268
 269         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 270
 271         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 272         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 273         READSKILL(bot_rangepreference, 1, 0); // read skill
 274
 275         READSKILL(bot_aimskill, 2, 0); // aim skill
 276         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 277         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 278
 279         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 280         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 281
 282         if (file >= 0 && argv(prio) != "")
 283                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 284
 285         this.bot_config_loaded = true;
 286
 287         // this is really only a default, TeamBalance_JoinBestTeam is called later
 288         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 289         this.bot_preferredcolors = this.clientcolors;
 290
 291         // pick the name
 292         if (autocvar_bot_usemodelnames)
 293                 name = bot_model;
 294         else
 295                 name = bot_name;
 296
 297         // number bots with identical names
 298         if (name == "")
 299         {
 300                 name = ftos(etof(this));
 301                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 302         }
 303         else
 304         {
 305                 int j = 0;
 306                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 307                         if(it.cleanname == name)
 308                                 ++j;
 309                 });
 310                 if (j)
 311                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 312                 else
 313                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 314         }
 315         this.cleanname = strzone(name);
 316
 317         // pick the model and skin
 318         if(substring(bot_model, -4, 1) != ".")
 319                 bot_model = strcat(bot_model, ".iqm");
 320         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 321         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 322 }
 323
 324 void bot_custom_weapon_priority_setup()
 325 {
 326         float tokens, i, w;
 327
 328         bot_custom_weapon = false;
 329
 330         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 331                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 332                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 333                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 334         )
 335                 return;
 336
 337         // Parse distances
 338         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 339
 340         if (tokens!=2)
 341                 return;
 342
 343         bot_distance_far = stof(argv(0));
 344         bot_distance_close = stof(argv(1));
 345
 346         if(bot_distance_far < bot_distance_close){
 347                 bot_distance_far = stof(argv(1));
 348                 bot_distance_close = stof(argv(0));
 349         }
 350
 351         int c;
 352
 353         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 354                 tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 355                 bot_weapons_##dist[0] = -1; \
 356                 c = 0; \
 357                 for(i = 0; i < tokens && c < Weapons_COUNT; ++i) { \
 358                         w = stof(argv(i)); \
 359                         if (w >= WEP_FIRST && w <= WEP_LAST) { \
 360                                 bot_weapons_##dist[c] = w; \
 361                                 ++c; \
 362                         } \
 363                 } \
 364                 if (c < Weapons_COUNT) \
 365                         bot_weapons_##dist[c] = -1; \
 366         MACRO_END
 367
 368         PARSE_WEAPON_PRIORITIES(far);
 369         PARSE_WEAPON_PRIORITIES(mid);
 370         PARSE_WEAPON_PRIORITIES(close);
 371
 372         bot_custom_weapon = true;
 373 }
 374
 375 void bot_endgame()
 376 {
 377         bot_relinkplayerlist();
 378         entity e = bot_list;
 379         while (e)
 380         {
 381                 setcolor(e, e.bot_preferredcolors);
 382                 e = e.nextbot;
 383         }
 384         // if dynamic waypoints are ever implemented, save them here
 385 }
 386
 387 void bot_relinkplayerlist()
 388 {
 389         player_count = 0;
 390         currentbots = 0;
 391         bot_list = NULL;
 392
 393         entity prevbot = NULL;
 394         FOREACH_CLIENT(true,
 395         {
 396                 ++player_count;
 397
 398                 if(IS_BOT_CLIENT(it))
 399                 {
 400                         if(prevbot)
 401                                 prevbot.nextbot = it;
 402                         else
 403                                 bot_list = it;
 404                         prevbot = it;
 405                         ++currentbots;
 406                 }
 407         });
 408         if(prevbot)
 409                 prevbot.nextbot = NULL;
 410         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 411         bot_strategytoken = bot_list;
 412         bot_strategytoken_taken = true;
 413 }
 414
 415 void bot_clientdisconnect(entity this)
 416 {
 417         if (!IS_BOT_CLIENT(this))
 418                 return;
 419         bot_clearqueue(this);
 420         strfree(this.cleanname);
 421         strfree(this.netname_freeme);
 422         strfree(this.playermodel_freeme);
 423         strfree(this.playerskin_freeme);
 424         if(this.bot_cmd_current)
 425                 delete(this.bot_cmd_current);
 426         if(bot_waypoint_queue_owner == this)
 427                 bot_waypoint_queue_owner = NULL;
 428 }
 429
 430 void bot_clientconnect(entity this)
 431 {
 432         if (!IS_BOT_CLIENT(this)) return;
 433         this.bot_preferredcolors = this.clientcolors;
 434         this.bot_nextthink = time - random();
 435         this.lag_func = bot_lagfunc;
 436         this.isbot = true;
 437         this.createdtime = this.bot_nextthink;
 438
 439         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 440         {
 441                 bot_setnameandstuff(this);
 442                 bot_setclientfields(this);
 443         }
 444
 445         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 446         {
 447                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 448         }
 449         else
 450         {
 451                 this.bot_forced_team = 0;
 452                 TeamBalance_JoinBestTeam(this);
 453         }
 454
 455         havocbot_setupbot(this);
 456 }
 457
 458 void bot_removefromlargestteam()
 459 {
 460         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 461         TeamBalance_GetTeamCounts(balance, NULL);
 462
 463         entity best = NULL;
 464         float besttime = 0;
 465         int bestcount = 0;
 466
 467         int bcount = 0;
 468         FOREACH_CLIENT(it.isbot,
 469         {
 470                 ++bcount;
 471
 472                 if(!best)
 473                 {
 474                         best = it;
 475                         besttime = it.createdtime;
 476                 }
 477
 478                 int thiscount = 0;
 479
 480                 if (Team_IsValidTeam(it.team))
 481                 {
 482                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 483                                 Team_TeamToIndex(it.team));
 484                 }
 485
 486                 if(thiscount > bestcount)
 487                 {
 488                         bestcount = thiscount;
 489                         besttime = it.createdtime;
 490                         best = it;
 491                 }
 492                 else if(thiscount == bestcount && besttime < it.createdtime)
 493                 {
 494                         besttime = it.createdtime;
 495                         best = it;
 496                 }
 497         });
 498         TeamBalance_Destroy(balance);
 499         if(!bcount)
 500                 return; // no bots to remove
 501         currentbots = currentbots - 1;
 502         dropclient(best);
 503 }
 504
 505 void bot_removenewest()
 506 {
 507         if(teamplay)
 508         {
 509                 bot_removefromlargestteam();
 510                 return;
 511         }
 512
 513         float besttime = 0;
 514         entity best = NULL;
 515         int bcount = 0;
 516
 517         FOREACH_CLIENT(it.isbot,
 518         {
 519                 ++bcount;
 520
 521                 if(!best)
 522                 {
 523                         best = it;
 524                         besttime = it.createdtime;
 525                 }
 526
 527                 if(besttime < it.createdtime)
 528                 {
 529                         besttime = it.createdtime;
 530                         best = it;
 531                 }
 532         });
 533
 534         if(!bcount)
 535                 return; // no bots to remove
 536
 537         currentbots = currentbots - 1;
 538         dropclient(best);
 539 }
 540
 541 void autoskill(float factor)
 542 {
 543         float bestbot;
 544         float bestplayer;
 545
 546         bestbot = -1;
 547         bestplayer = -1;
 548         FOREACH_CLIENT(IS_PLAYER(it), {
 549                 if(IS_REAL_CLIENT(it))
 550                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 551                 else
 552                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 553         });
 554
 555         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 556         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 557         if(bestbot < 0 || bestplayer < 0)
 558         {
 559                 LOG_DEBUG("not doing anything");
 560                 // don't return, let it reset all counters below
 561         }
 562         else if(bestbot <= bestplayer * factor - 2)
 563         {
 564                 if(autocvar_skill < 17)
 565                 {
 566                         LOG_DEBUG("2 frags difference, increasing skill");
 567                         cvar_set("skill", ftos(autocvar_skill + 1));
 568                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 569                 }
 570         }
 571         else if(bestbot >= bestplayer * factor + 2)
 572         {
 573                 if(autocvar_skill > 0)
 574                 {
 575                         LOG_DEBUG("2 frags difference, decreasing skill");
 576                         cvar_set("skill", ftos(autocvar_skill - 1));
 577                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 578                 }
 579         }
 580         else
 581         {
 582                 LOG_DEBUG("not doing anything");
 583                 return;
 584                 // don't reset counters, wait for them to accumulate
 585         }
 586
 587         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 588 }
 589
 590 void bot_calculate_stepheightvec()
 591 {
 592         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 593         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 594         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 595         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 596 }
 597
 598 bool bot_fixcount()
 599 {
 600         int activerealplayers = 0;
 601         int realplayers = 0;
 602         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 603                 activerealplayers = M_ARGV(0, int);
 604                 realplayers = M_ARGV(1, int);
 605         } else {
 606                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 607                         if(IS_PLAYER(it))
 608                                 ++activerealplayers;
 609                         ++realplayers;
 610                 });
 611         }
 612
 613         int bots;
 614         // But don't remove bots immediately on level change, as the real players
 615         // usually haven't rejoined yet
 616         bots_would_leave = false;
 617         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 618                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 619         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 620         {
 621                 int minplayers = max(0, floor(autocvar_minplayers));
 622                 if (teamplay)
 623                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 624                 int minbots = max(0, floor(autocvar_bot_number));
 625
 626                 // add bots to reach minplayers if needed
 627                 bots = max(minbots, minplayers - activerealplayers);
 628                 // cap bots to the max players allowed by the server
 629                 int player_limit = GetPlayerLimit();
 630                 if(player_limit)
 631                         bots = min(bots, max(player_limit - activerealplayers, 0));
 632                 bots = min(bots, maxclients - realplayers);
 633
 634                 if(bots > minbots)
 635                         bots_would_leave = true;
 636         }
 637         else
 638         {
 639                 // if there are no players, remove bots
 640                 bots = 0;
 641         }
 642
 643         // only add one bot per frame to avoid utter chaos
 644         if(time > botframe_nextthink)
 645         {
 646                 if (currentbots < bots)
 647                 {
 648                         if (bot_spawn() == NULL)
 649                         {
 650                                 bprint("Can not add bot, server full.\n");
 651                                 return false;
 652                         }
 653                 }
 654                 while (currentbots > bots && bots >= 0)
 655                         bot_removenewest();
 656         }
 657
 658         return true;
 659 }
 660
 661 void bot_remove_from_bot_list(entity this)
 662 {
 663         entity e = bot_list;
 664         entity prev_bot = NULL;
 665         while (e)
 666         {
 667                 if(e == this)
 668                 {
 669                         if(!prev_bot)
 670                                 bot_list = this.nextbot;
 671                         else
 672                                 prev_bot.nextbot = this.nextbot;
 673                         if(bot_strategytoken == this)
 674                         {
 675                                 bot_strategytoken = this.nextbot;
 676                                 bot_strategytoken_taken = true;
 677                         }
 678                         this.nextbot = NULL;
 679                         break;
 680                 }
 681                 prev_bot = e;
 682                 e = e.nextbot;
 683         }
 684 }
 685
 686 void bot_clear(entity this)
 687 {
 688         bot_remove_from_bot_list(this);
 689         if(bot_waypoint_queue_owner == this)
 690                 bot_waypoint_queue_owner = NULL;
 691         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 692 }
 693
 694 void bot_serverframe()
 695 {
 696         if (intermission_running && currentbots > 0)
 697         {
 698                 // after the end of the match all bots stay unless all human players disconnect
 699                 int realplayers = 0;
 700                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 701                 if (!realplayers)
 702                 {
 703                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 704                         currentbots = 0;
 705                 }
 706                 return;
 707         }
 708
 709         if (game_stopped)
 710                 return;
 711
 712         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 713         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 714         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 715         // either intentionally or automatically (sv_spectate 0)
 716         if (time < 2.5)
 717         {
 718                 currentbots = -1;
 719                 return;
 720         }
 721
 722         if (currentbots == -1)
 723         {
 724                 // count bots already in the server from the previous match
 725                 currentbots = 0;
 726                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 727         }
 728
 729         if(autocvar_skill != skill)
 730         {
 731                 float wpcost_update = false;
 732                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 733                         wpcost_update = true;
 734                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 735                         wpcost_update = true;
 736
 737                 skill = autocvar_skill;
 738                 if (wpcost_update)
 739                         waypoint_updatecost_foralllinks();
 740         }
 741
 742         bot_calculate_stepheightvec();
 743         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 744
 745         if(time > autoskill_nextthink)
 746         {
 747                 float a;
 748                 a = autocvar_skill_auto;
 749                 if(a)
 750                         autoskill(a);
 751                 autoskill_nextthink = time + 5;
 752         }
 753
 754         if(time > botframe_nextthink)
 755         {
 756                 if(!bot_fixcount())
 757                         botframe_nextthink = time + 10;
 758         }
 759
 760         if(botframe_spawnedwaypoints)
 761         {
 762                 if(autocvar_waypoint_benchmark)
 763                         localcmd("quit\n");
 764         }
 765
 766         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 767         if (botframe_spawnedwaypoints)
 768         {
 769                 if(botframe_cachedwaypointlinks)
 770                 {
 771                         if(!botframe_loadedforcedlinks)
 772                                 waypoint_load_hardwiredlinks();
 773                 }
 774                 else
 775                 {
 776                         // TODO: Make this check cleaner
 777                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 778                         {
 779                                 waypoint_save_links();
 780                                 break;
 781                         });
 782                 }
 783         }
 784         else
 785         {
 786                 botframe_spawnedwaypoints = true;
 787                 waypoint_loadall();
 788                 waypoint_load_links();
 789         }
 790
 791         if (bot_list)
 792         {
 793                 // cycle the goal token from one bot to the next each frame
 794                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 795                 //  frame, which causes choppy framerates)
 796                 if (bot_strategytoken_taken)
 797                 {
 798                         // give goal token to the first bot without goals; if all bots don't have
 799                         // any goal (or are dead/frozen) simply give it to the next one
 800                         bot_strategytoken_taken = false;
 801                         entity bot_strategytoken_save = bot_strategytoken;
 802                         while (true)
 803                         {
 804                                 if (bot_strategytoken)
 805                                         bot_strategytoken = bot_strategytoken.nextbot;
 806                                 if (!bot_strategytoken)
 807                                         bot_strategytoken = bot_list;
 808
 809                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 810                                         && !bot_strategytoken.goalcurrent)
 811                                         break;
 812
 813                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 814                                         break;
 815                                 if (bot_strategytoken == bot_strategytoken_save)
 816                                         bot_strategytoken_save = NULL; // looped through all the bots
 817                         }
 818                 }
 819
 820                 if (botframe_nextdangertime < time)
 821                 {
 822                         float interval;
 823                         interval = autocvar_bot_ai_dangerdetectioninterval;
 824                         if (botframe_nextdangertime < time - interval * 1.5)
 825                                 botframe_nextdangertime = time;
 826                         botframe_nextdangertime = botframe_nextdangertime + interval;
 827                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 828                 }
 829         }
 830
 831         if (autocvar_g_waypointeditor)
 832                 botframe_showwaypointlinks();
 833
 834         if (autocvar_g_waypointeditor_auto)
 835                 botframe_autowaypoints();
 836
 837         if(time > bot_cvar_nextthink)
 838         {
 839                 if(currentbots>0)
 840                         bot_custom_weapon_priority_setup();
 841                 bot_cvar_nextthink = time + 5;
 842         }
 843 }