qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include <common/stats.qh>
  21 #include <server/world.qh>
  22 #include <server/damage.qh>
  23 #include "../../race.qh"
  24 #include <server/items/items.qh>
  25
  26 #include <server/mutators/_mod.qh>
  27
  28 #include "../../weapons/accuracy.qh"
  29
  30 #include <common/physics/player.qh>
  31 #include <common/constants.qh>
  32 #include <common/net_linked.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/teams.qh>
  35 #include <common/util.qh>
  36
  37 #include <server/scores_rules.qh>
  38
  39 #include <common/weapons/_all.qh>
  40
  41 #include <lib/csqcmodel/sv_model.qh>
  42
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/util_server.qh>
  45
  46 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  47
  48 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  49 void bot_setclientfields(entity this)
  50 {
  51         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  52         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  53 }
  54
  55 entity bot_spawn()
  56 {
  57         entity bot = spawnclient();
  58         if (bot)
  59         {
  60                 setItemGroupCount();
  61                 currentbots = currentbots + 1;
  62                 bot_setnameandstuff(bot);
  63                 ClientConnect(bot);
  64                 bot_setclientfields(bot);
  65                 PutClientInServer(bot);
  66         }
  67         return bot;
  68 }
  69
  70 void bot_think(entity this)
  71 {
  72         if (this.bot_nextthink > time)
  73                 return;
  74
  75         this.flags &= ~FL_GODMODE;
  76         if(autocvar_bot_god)
  77                 this.flags |= FL_GODMODE;
  78
  79         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  80
  81         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  82         {
  83                 CS(this).movement = '0 0 0';
  84                 this.bot_nextthink = time + 0.5;
  85                 return;
  86         }
  87
  88         if (this.fixangle)
  89         {
  90                 this.v_angle = this.angles;
  91                 this.v_angle_z = 0;
  92                 this.fixangle = false;
  93         }
  94
  95         this.dmg_take = 0;
  96         this.dmg_save = 0;
  97         this.dmg_inflictor = NULL;
  98
  99         // calculate an aiming latency based on the skill setting
 100         // (simulated network latency + naturally delayed reflexes)
 101         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 102         // minimum ping 20+10 random
 103         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 104         // skill 10 = ping 0.2 (adrenaline)
 105         // skill 0 = ping 0.7 (slightly drunk)
 106
 107         // clear buttons
 108         PHYS_INPUT_BUTTON_ATCK(this) = false;
 109         // keep jump button pressed for a short while, useful with ramp jumps
 110         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 111         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 112         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 113         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 114         PHYS_INPUT_BUTTON_HOOK(this) = false;
 115         PHYS_INPUT_BUTTON_INFO(this) = false;
 116         PHYS_INPUT_BUTTON_DRAG(this) = false;
 117         PHYS_INPUT_BUTTON_CHAT(this) = false;
 118         PHYS_INPUT_BUTTON_USE(this) = false;
 119
 120         if (time < game_starttime)
 121         {
 122                 // block the bot during the countdown to game start
 123                 CS(this).movement = '0 0 0';
 124                 this.bot_nextthink = game_starttime;
 125                 return;
 126         }
 127
 128         // if dead, just wait until we can respawn
 129         if (IS_DEAD(this))
 130         {
 131                 if (bot_waypoint_queue_owner == this)
 132                         bot_waypoint_queue_owner = NULL;
 133                 this.aistatus = 0;
 134                 CS(this).movement = '0 0 0';
 135                 if (this.deadflag == DEAD_DEAD)
 136                 {
 137                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 138                         navigation_goalrating_timeout_force(this);
 139                 }
 140         }
 141         else if(this.aistatus & AI_STATUS_STUCK)
 142                 navigation_unstuck(this);
 143
 144         // now call the current bot AI (havocbot for example)
 145         this.bot_ai(this);
 146 }
 147
 148 void bot_setnameandstuff(entity this)
 149 {
 150         string readfile, s;
 151         int file, tokens, prio;
 152
 153         file = fopen(autocvar_bot_config_file, FILE_READ);
 154
 155         if(file < 0)
 156         {
 157                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 158                 readfile = "";
 159         }
 160         else
 161         {
 162                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 163                 TeamBalance_GetTeamCounts(balance, NULL);
 164                 int smallest_team = -1;
 165                 int smallest_count = -1;
 166                 if (teamplay)
 167                 {
 168                         for (int i = 1; i <= AvailableTeams(); ++i)
 169                         {
 170                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 171                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 172                                 // since it keeps a spot for the real player in the desired team
 173                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 174                                 if (smallest_count < 0 || count < smallest_count)
 175                                 {
 176                                         smallest_team = i;
 177                                         smallest_count = count;
 178                                 }
 179                         }
 180                 }
 181                 TeamBalance_Destroy(balance);
 182                 RandomSelection_Init();
 183                 while((readfile = fgets(file)))
 184                 {
 185                         if(substring(readfile, 0, 2) == "//")
 186                                 continue;
 187                         if(substring(readfile, 0, 1) == "#")
 188                                 continue;
 189                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 190                         // will create 1 empty token because there's no separator (bug?)
 191                         if (readfile == "")
 192                                 continue;
 193                         tokens = tokenizebyseparator(readfile, "\t");
 194                         if(tokens == 0)
 195                                 continue;
 196                         s = argv(0);
 197                         prio = 0;
 198                         bool conflict = false;
 199                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 200                                 if (s == it.cleanname)
 201                                 {
 202                                         conflict = true;
 203                                         break;
 204                                 }
 205                         });
 206                         if (!conflict)
 207                                 prio += 1;
 208                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 209                         {
 210                                 int forced_team = stof(argv(5));
 211                                 if (!Team_IsValidIndex(forced_team))
 212                                         forced_team = 0;
 213                                 if (!forced_team || forced_team == smallest_team)
 214                                         prio += 2;
 215                         }
 216                         RandomSelection_AddString(readfile, 1, prio);
 217                 }
 218                 readfile = RandomSelection_chosen_string;
 219                 fclose(file);
 220         }
 221
 222         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 223
 224         tokens = tokenizebyseparator(readfile, "\t");
 225         if(argv(0) != "") bot_name = argv(0);
 226         else bot_name = "Bot";
 227
 228         if(argv(1) != "") bot_model = argv(1);
 229         else bot_model = "";
 230
 231         if(argv(2) != "") bot_skin = argv(2);
 232         else bot_skin = "0";
 233
 234         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 235         else bot_shirt = ftos(floor(random() * 15));
 236
 237         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 238         else bot_pants = ftos(floor(random() * 15));
 239
 240         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 241                 this.bot_forced_team = stof(argv(5));
 242         else
 243                 this.bot_forced_team = 0;
 244
 245         prio = 6;
 246
 247         #define READSKILL(f, w, r) MACRO_BEGIN \
 248                 if(argv(prio) != "") \
 249                         this.f = stof(argv(prio)) * w; \
 250                 else \
 251                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 252                 prio++; \
 253         MACRO_END
 254         //print(bot_name, ": ping=", argv(9), "\n");
 255
 256         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 257         READSKILL(bot_moveskill, 2, 0); // move skill
 258         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 259
 260         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 261
 262         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 263         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 264         READSKILL(bot_rangepreference, 1, 0); // read skill
 265
 266         READSKILL(bot_aimskill, 2, 0); // aim skill
 267         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 268         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 269
 270         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 271         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 272
 273         if (file >= 0 && argv(prio) != "")
 274                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 275
 276         this.bot_config_loaded = true;
 277
 278         // this is really only a default, TeamBalance_JoinBestTeam is called later
 279         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 280         this.bot_preferredcolors = this.clientcolors;
 281
 282         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 283         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 284         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 285
 286         if (name == "")
 287         {
 288                 name = ftos(etof(this));
 289                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 290         }
 291         else
 292         {
 293                 // number bots with identical names
 294                 int j = 0;
 295                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 296                         if(it.cleanname == name)
 297                                 ++j;
 298                 });
 299                 if (j)
 300                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 301                 else
 302                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 303         }
 304         this.cleanname = strzone(name);
 305
 306         // pick the model and skin
 307         if(substring(bot_model, -4, 1) != ".")
 308                 bot_model = strcat(bot_model, ".iqm");
 309         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 310         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 311 }
 312
 313 void bot_custom_weapon_priority_setup()
 314 {
 315         static string bot_priority_far_prev;
 316         static string bot_priority_mid_prev;
 317         static string bot_priority_close_prev;
 318         static string bot_priority_distances_prev;
 319         float tokens, i, w;
 320
 321         bot_custom_weapon = false;
 322
 323         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 324                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 325                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 326                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 327         )
 328                 return;
 329
 330         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 331         {
 332                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 333                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 334
 335                 if (tokens!=2)
 336                         return;
 337
 338                 bot_distance_far = stof(argv(0));
 339                 bot_distance_close = stof(argv(1));
 340
 341                 if(bot_distance_far < bot_distance_close){
 342                         bot_distance_far = stof(argv(1));
 343                         bot_distance_close = stof(argv(0));
 344                 }
 345         }
 346
 347         int c;
 348
 349         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 350                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 351                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 352                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 353                         bot_weapons_##dist[0] = -1; \
 354                         c = 0; \
 355                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 356                                 w = stof(argv(i)); \
 357                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 358                                         bot_weapons_##dist[c] = w; \
 359                                         ++c; \
 360                                 } \
 361                         } \
 362                         if (c < REGISTRY_COUNT(Weapons)) \
 363                                 bot_weapons_##dist[c] = -1; \
 364                 } \
 365         MACRO_END
 366
 367         PARSE_WEAPON_PRIORITIES(far);
 368         PARSE_WEAPON_PRIORITIES(mid);
 369         PARSE_WEAPON_PRIORITIES(close);
 370
 371         bot_custom_weapon = true;
 372 }
 373
 374 void bot_endgame()
 375 {
 376         bot_relinkplayerlist();
 377         entity e = bot_list;
 378         while (e)
 379         {
 380                 setcolor(e, e.bot_preferredcolors);
 381                 e = e.nextbot;
 382         }
 383         // if dynamic waypoints are ever implemented, save them here
 384 }
 385
 386 void bot_relinkplayerlist()
 387 {
 388         player_count = 0;
 389         currentbots = 0;
 390         bot_list = NULL;
 391
 392         entity prevbot = NULL;
 393         FOREACH_CLIENT(true,
 394         {
 395                 ++player_count;
 396
 397                 if(IS_BOT_CLIENT(it))
 398                 {
 399                         if(prevbot)
 400                                 prevbot.nextbot = it;
 401                         else
 402                                 bot_list = it;
 403                         prevbot = it;
 404                         ++currentbots;
 405                 }
 406         });
 407         if(prevbot)
 408                 prevbot.nextbot = NULL;
 409         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 410         bot_strategytoken = bot_list;
 411         bot_strategytoken_taken = true;
 412 }
 413
 414 void bot_clientdisconnect(entity this)
 415 {
 416         if (!IS_BOT_CLIENT(this))
 417                 return;
 418         bot_clearqueue(this);
 419         strfree(this.cleanname);
 420         strfree(this.netname_freeme);
 421         strfree(this.playermodel_freeme);
 422         strfree(this.playerskin_freeme);
 423         if(this.bot_cmd_current)
 424                 delete(this.bot_cmd_current);
 425         if(bot_waypoint_queue_owner == this)
 426                 bot_waypoint_queue_owner = NULL;
 427 }
 428
 429 void bot_clientconnect(entity this)
 430 {
 431         if (!IS_BOT_CLIENT(this)) return;
 432         this.bot_preferredcolors = this.clientcolors;
 433         this.bot_nextthink = time - random();
 434         this.lag_func = bot_lagfunc;
 435         this.isbot = true;
 436         this.createdtime = this.bot_nextthink;
 437
 438         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 439         {
 440                 bot_setnameandstuff(this);
 441                 bot_setclientfields(this);
 442         }
 443
 444         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 445         {
 446                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 447         }
 448         else
 449         {
 450                 this.bot_forced_team = 0;
 451                 TeamBalance_JoinBestTeam(this);
 452         }
 453
 454         havocbot_setupbot(this);
 455 }
 456
 457 void bot_removefromlargestteam()
 458 {
 459         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 460         TeamBalance_GetTeamCounts(balance, NULL);
 461
 462         entity best = NULL;
 463         float besttime = 0;
 464         int bestcount = 0;
 465
 466         int bcount = 0;
 467         FOREACH_CLIENT(it.isbot,
 468         {
 469                 ++bcount;
 470
 471                 if(!best)
 472                 {
 473                         best = it;
 474                         besttime = it.createdtime;
 475                 }
 476
 477                 int thiscount = 0;
 478
 479                 if (Team_IsValidTeam(it.team))
 480                 {
 481                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 482                                 Team_TeamToIndex(it.team));
 483                 }
 484
 485                 if(thiscount > bestcount)
 486                 {
 487                         bestcount = thiscount;
 488                         besttime = it.createdtime;
 489                         best = it;
 490                 }
 491                 else if(thiscount == bestcount && besttime < it.createdtime)
 492                 {
 493                         besttime = it.createdtime;
 494                         best = it;
 495                 }
 496         });
 497         TeamBalance_Destroy(balance);
 498         if(!bcount)
 499                 return; // no bots to remove
 500         currentbots = currentbots - 1;
 501         dropclient(best);
 502 }
 503
 504 void bot_removenewest()
 505 {
 506         if(teamplay)
 507         {
 508                 bot_removefromlargestteam();
 509                 return;
 510         }
 511
 512         float besttime = 0;
 513         entity best = NULL;
 514         int bcount = 0;
 515
 516         FOREACH_CLIENT(it.isbot,
 517         {
 518                 ++bcount;
 519
 520                 if(!best)
 521                 {
 522                         best = it;
 523                         besttime = it.createdtime;
 524                 }
 525
 526                 if(besttime < it.createdtime)
 527                 {
 528                         besttime = it.createdtime;
 529                         best = it;
 530                 }
 531         });
 532
 533         if(!bcount)
 534                 return; // no bots to remove
 535
 536         currentbots = currentbots - 1;
 537         dropclient(best);
 538 }
 539
 540 void autoskill(float factor)
 541 {
 542         float bestbot;
 543         float bestplayer;
 544
 545         bestbot = -1;
 546         bestplayer = -1;
 547         FOREACH_CLIENT(IS_PLAYER(it), {
 548                 if(IS_REAL_CLIENT(it))
 549                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 550                 else
 551                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 552         });
 553
 554         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 555         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 556         if(bestbot < 0 || bestplayer < 0)
 557         {
 558                 LOG_DEBUG("not doing anything");
 559                 // don't return, let it reset all counters below
 560         }
 561         else if(bestbot <= bestplayer * factor - 2)
 562         {
 563                 if(autocvar_skill < 17)
 564                 {
 565                         LOG_DEBUG("2 frags difference, increasing skill");
 566                         cvar_set("skill", ftos(autocvar_skill + 1));
 567                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 568                 }
 569         }
 570         else if(bestbot >= bestplayer * factor + 2)
 571         {
 572                 if(autocvar_skill > 0)
 573                 {
 574                         LOG_DEBUG("2 frags difference, decreasing skill");
 575                         cvar_set("skill", ftos(autocvar_skill - 1));
 576                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 577                 }
 578         }
 579         else
 580         {
 581                 LOG_DEBUG("not doing anything");
 582                 return;
 583                 // don't reset counters, wait for them to accumulate
 584         }
 585
 586         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 587 }
 588
 589 void bot_calculate_stepheightvec()
 590 {
 591         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 592         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 593         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 594         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 595 }
 596
 597 bool bot_fixcount()
 598 {
 599         int activerealplayers = 0;
 600         int realplayers = 0;
 601         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 602                 activerealplayers = M_ARGV(0, int);
 603                 realplayers = M_ARGV(1, int);
 604         } else {
 605                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 606                         if(IS_PLAYER(it))
 607                                 ++activerealplayers;
 608                         ++realplayers;
 609                 });
 610         }
 611
 612         int bots;
 613         // But don't remove bots immediately on level change, as the real players
 614         // usually haven't rejoined yet
 615         bots_would_leave = false;
 616         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 617                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 618         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 619         {
 620                 int minplayers = max(0, floor(autocvar_minplayers));
 621                 if (teamplay)
 622                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 623                 int minbots = max(0, floor(autocvar_bot_number));
 624
 625                 // add bots to reach minplayers if needed
 626                 bots = max(minbots, minplayers - activerealplayers);
 627                 // cap bots to the max players allowed by the server
 628                 int player_limit = GetPlayerLimit();
 629                 if(player_limit)
 630                         bots = min(bots, max(player_limit - activerealplayers, 0));
 631                 bots = min(bots, maxclients - realplayers);
 632
 633                 if(bots > minbots)
 634                         bots_would_leave = true;
 635         }
 636         else
 637         {
 638                 // if there are no players, remove bots
 639                 bots = 0;
 640         }
 641
 642         // only add one bot per frame to avoid utter chaos
 643         if(time > botframe_nextthink)
 644         {
 645                 if (currentbots < bots)
 646                 {
 647                         if (bot_spawn() == NULL)
 648                         {
 649                                 bprint("Can not add bot, server full.\n");
 650                                 return false;
 651                         }
 652                 }
 653                 while (currentbots > bots && bots >= 0)
 654                         bot_removenewest();
 655         }
 656
 657         return true;
 658 }
 659
 660 void bot_remove_from_bot_list(entity this)
 661 {
 662         entity e = bot_list;
 663         entity prev_bot = NULL;
 664         while (e)
 665         {
 666                 if(e == this)
 667                 {
 668                         if(!prev_bot)
 669                                 bot_list = this.nextbot;
 670                         else
 671                                 prev_bot.nextbot = this.nextbot;
 672                         if(bot_strategytoken == this)
 673                         {
 674                                 bot_strategytoken = this.nextbot;
 675                                 bot_strategytoken_taken = true;
 676                         }
 677                         this.nextbot = NULL;
 678                         break;
 679                 }
 680                 prev_bot = e;
 681                 e = e.nextbot;
 682         }
 683 }
 684
 685 void bot_clear(entity this)
 686 {
 687         bot_remove_from_bot_list(this);
 688         if(bot_waypoint_queue_owner == this)
 689                 bot_waypoint_queue_owner = NULL;
 690         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 691 }
 692
 693 void bot_serverframe()
 694 {
 695         if (intermission_running && currentbots > 0)
 696         {
 697                 // after the end of the match all bots stay unless all human players disconnect
 698                 int realplayers = 0;
 699                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 700                 if (!realplayers)
 701                 {
 702                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 703                         currentbots = 0;
 704                 }
 705                 return;
 706         }
 707
 708         if (game_stopped)
 709                 return;
 710
 711         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 712         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 713         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 714         // either intentionally or automatically (sv_spectate 0)
 715         if (time < 2.5)
 716         {
 717                 currentbots = -1;
 718                 return;
 719         }
 720
 721         if (currentbots == -1)
 722         {
 723                 // count bots already in the server from the previous match
 724                 currentbots = 0;
 725                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 726         }
 727
 728         if(autocvar_skill != skill)
 729         {
 730                 float wpcost_update = false;
 731                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 732                         wpcost_update = true;
 733                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 734                         wpcost_update = true;
 735
 736                 skill = autocvar_skill;
 737                 if (wpcost_update)
 738                         waypoint_updatecost_foralllinks();
 739         }
 740
 741         bot_calculate_stepheightvec();
 742         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 743
 744         if(time > autoskill_nextthink)
 745         {
 746                 float a;
 747                 a = autocvar_skill_auto;
 748                 if(a)
 749                         autoskill(a);
 750                 autoskill_nextthink = time + 5;
 751         }
 752
 753         if(time > botframe_nextthink)
 754         {
 755                 if(!bot_fixcount())
 756                         botframe_nextthink = time + 10;
 757         }
 758
 759         if(botframe_spawnedwaypoints)
 760         {
 761                 if(autocvar_waypoint_benchmark)
 762                         localcmd("quit\n");
 763         }
 764
 765         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 766         if (botframe_spawnedwaypoints)
 767         {
 768                 if(botframe_cachedwaypointlinks)
 769                 {
 770                         if(!botframe_loadedforcedlinks)
 771                                 waypoint_load_hardwiredlinks();
 772                 }
 773                 else
 774                 {
 775                         // TODO: Make this check cleaner
 776                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 777                         {
 778                                 waypoint_save_links();
 779                                 break;
 780                         });
 781                 }
 782         }
 783         else
 784         {
 785                 botframe_spawnedwaypoints = true;
 786                 waypoint_loadall();
 787                 waypoint_load_links();
 788         }
 789
 790         if (bot_list)
 791         {
 792                 // cycle the goal token from one bot to the next each frame
 793                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 794                 //  frame, which causes choppy framerates)
 795                 if (bot_strategytoken_taken)
 796                 {
 797                         // give goal token to the first bot without goals; if all bots don't have
 798                         // any goal (or are dead/frozen) simply give it to the next one
 799                         bot_strategytoken_taken = false;
 800                         entity bot_strategytoken_save = bot_strategytoken;
 801                         while (true)
 802                         {
 803                                 if (bot_strategytoken)
 804                                         bot_strategytoken = bot_strategytoken.nextbot;
 805                                 if (!bot_strategytoken)
 806                                         bot_strategytoken = bot_list;
 807
 808                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 809                                         && !bot_strategytoken.goalcurrent)
 810                                         break;
 811
 812                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 813                                         break;
 814                                 if (bot_strategytoken == bot_strategytoken_save)
 815                                         bot_strategytoken_save = NULL; // looped through all the bots
 816                         }
 817                 }
 818
 819                 if (botframe_nextdangertime < time)
 820                 {
 821                         float interval;
 822                         interval = autocvar_bot_ai_dangerdetectioninterval;
 823                         if (botframe_nextdangertime < time - interval * 1.5)
 824                                 botframe_nextdangertime = time;
 825                         botframe_nextdangertime = botframe_nextdangertime + interval;
 826                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 827                 }
 828         }
 829
 830         if (autocvar_g_waypointeditor)
 831                 botframe_showwaypointlinks();
 832
 833         if (autocvar_g_waypointeditor_auto)
 834                 botframe_autowaypoints();
 835
 836         if (currentbots > 0)
 837                 bot_custom_weapon_priority_setup();
 838 }