qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 174                 TeamBalance_GetTeamCounts(balance, NULL);
 175                 int smallest_team = -1;
 176                 int smallest_count = -1;
 177                 if (teamplay)
 178                 {
 179                         for (int i = 1; i <= AvailableTeams(); ++i)
 180                         {
 181                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 182                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 183                                 // since it keeps a spot for the real player in the desired team
 184                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 185                                 if (smallest_count < 0 || count < smallest_count)
 186                                 {
 187                                         smallest_team = i;
 188                                         smallest_count = count;
 189                                 }
 190                         }
 191                 }
 192                 TeamBalance_Destroy(balance);
 193                 RandomSelection_Init();
 194                 while((readfile = fgets(file)))
 195                 {
 196                         if(substring(readfile, 0, 2) == "//")
 197                                 continue;
 198                         if(substring(readfile, 0, 1) == "#")
 199                                 continue;
 200                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 201                         // will create 1 empty token because there's no separator (bug?)
 202                         if (readfile == "")
 203                                 continue;
 204                         tokens = tokenizebyseparator(readfile, "\t");
 205                         if(tokens == 0)
 206                                 continue;
 207                         s = argv(0);
 208                         prio = 0;
 209                         bool conflict = false;
 210                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 211                                 if (s == it.cleanname)
 212                                 {
 213                                         conflict = true;
 214                                         break;
 215                                 }
 216                         });
 217                         if (!conflict)
 218                                 prio += 1;
 219                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 220                         {
 221                                 int forced_team = stof(argv(5));
 222                                 if (!Team_IsValidIndex(forced_team))
 223                                         forced_team = 0;
 224                                 if (!forced_team || forced_team == smallest_team)
 225                                         prio += 2;
 226                         }
 227                         RandomSelection_AddString(readfile, 1, prio);
 228                 }
 229                 readfile = RandomSelection_chosen_string;
 230                 fclose(file);
 231         }
 232
 233         tokens = tokenizebyseparator(readfile, "\t");
 234         if(argv(0) != "") bot_name = argv(0);
 235         else bot_name = "Bot";
 236
 237         if(argv(1) != "") bot_model = argv(1);
 238         else bot_model = "";
 239
 240         if(argv(2) != "") bot_skin = argv(2);
 241         else bot_skin = "0";
 242
 243         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 244         else bot_shirt = ftos(floor(random() * 15));
 245
 246         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 247         else bot_pants = ftos(floor(random() * 15));
 248
 249         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 250                 this.bot_forced_team = stof(argv(5));
 251         else
 252                 this.bot_forced_team = 0;
 253
 254         prio = 6;
 255
 256         #define READSKILL(f, w, r) MACRO_BEGIN \
 257                 if(argv(prio) != "") \
 258                         this.f = stof(argv(prio)) * w; \
 259                 else \
 260                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 261                 prio++; \
 262         MACRO_END
 263         //print(bot_name, ": ping=", argv(9), "\n");
 264
 265         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 266         READSKILL(bot_moveskill, 2, 0); // move skill
 267         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 268
 269         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 270
 271         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 272         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 273         READSKILL(bot_rangepreference, 1, 0); // read skill
 274
 275         READSKILL(bot_aimskill, 2, 0); // aim skill
 276         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 277         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 278
 279         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 280         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 281
 282         if (file >= 0 && argv(prio) != "")
 283                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 284
 285         this.bot_config_loaded = true;
 286
 287         // this is really only a default, TeamBalance_JoinBestTeam is called later
 288         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 289         this.bot_preferredcolors = this.clientcolors;
 290
 291         // pick the name
 292         if (autocvar_bot_usemodelnames)
 293                 name = bot_model;
 294         else
 295                 name = bot_name;
 296
 297         // number bots with identical names
 298         if (name == "")
 299         {
 300                 name = ftos(etof(this));
 301                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 302         }
 303         else
 304         {
 305                 int j = 0;
 306                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 307                         if(it.cleanname == name)
 308                                 ++j;
 309                 });
 310                 if (j)
 311                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 312                 else
 313                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 314         }
 315         this.cleanname = strzone(name);
 316
 317         // pick the model and skin
 318         if(substring(bot_model, -4, 1) != ".")
 319                 bot_model = strcat(bot_model, ".iqm");
 320         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 321         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 322 }
 323
 324 void bot_custom_weapon_priority_setup()
 325 {
 326         static string bot_priority_far_prev;
 327         static string bot_priority_mid_prev;
 328         static string bot_priority_close_prev;
 329         static string bot_priority_distances_prev;
 330         float tokens, i, w;
 331
 332         bot_custom_weapon = false;
 333
 334         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 335                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 336                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 337                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 338         )
 339                 return;
 340
 341         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 342         {
 343                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 344                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 345
 346                 if (tokens!=2)
 347                         return;
 348
 349                 bot_distance_far = stof(argv(0));
 350                 bot_distance_close = stof(argv(1));
 351
 352                 if(bot_distance_far < bot_distance_close){
 353                         bot_distance_far = stof(argv(1));
 354                         bot_distance_close = stof(argv(0));
 355                 }
 356         }
 357
 358         int c;
 359
 360         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 361                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 362                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 363                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 364                         bot_weapons_##dist[0] = -1; \
 365                         c = 0; \
 366                         for(i = 0; i < tokens && c < Weapons_COUNT; ++i) { \
 367                                 w = stof(argv(i)); \
 368                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 369                                         bot_weapons_##dist[c] = w; \
 370                                         ++c; \
 371                                 } \
 372                         } \
 373                         if (c < Weapons_COUNT) \
 374                                 bot_weapons_##dist[c] = -1; \
 375                 } \
 376         MACRO_END
 377
 378         PARSE_WEAPON_PRIORITIES(far);
 379         PARSE_WEAPON_PRIORITIES(mid);
 380         PARSE_WEAPON_PRIORITIES(close);
 381
 382         bot_custom_weapon = true;
 383 }
 384
 385 void bot_endgame()
 386 {
 387         bot_relinkplayerlist();
 388         entity e = bot_list;
 389         while (e)
 390         {
 391                 setcolor(e, e.bot_preferredcolors);
 392                 e = e.nextbot;
 393         }
 394         // if dynamic waypoints are ever implemented, save them here
 395 }
 396
 397 void bot_relinkplayerlist()
 398 {
 399         player_count = 0;
 400         currentbots = 0;
 401         bot_list = NULL;
 402
 403         entity prevbot = NULL;
 404         FOREACH_CLIENT(true,
 405         {
 406                 ++player_count;
 407
 408                 if(IS_BOT_CLIENT(it))
 409                 {
 410                         if(prevbot)
 411                                 prevbot.nextbot = it;
 412                         else
 413                                 bot_list = it;
 414                         prevbot = it;
 415                         ++currentbots;
 416                 }
 417         });
 418         if(prevbot)
 419                 prevbot.nextbot = NULL;
 420         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 421         bot_strategytoken = bot_list;
 422         bot_strategytoken_taken = true;
 423 }
 424
 425 void bot_clientdisconnect(entity this)
 426 {
 427         if (!IS_BOT_CLIENT(this))
 428                 return;
 429         bot_clearqueue(this);
 430         strfree(this.cleanname);
 431         strfree(this.netname_freeme);
 432         strfree(this.playermodel_freeme);
 433         strfree(this.playerskin_freeme);
 434         if(this.bot_cmd_current)
 435                 delete(this.bot_cmd_current);
 436         if(bot_waypoint_queue_owner == this)
 437                 bot_waypoint_queue_owner = NULL;
 438 }
 439
 440 void bot_clientconnect(entity this)
 441 {
 442         if (!IS_BOT_CLIENT(this)) return;
 443         this.bot_preferredcolors = this.clientcolors;
 444         this.bot_nextthink = time - random();
 445         this.lag_func = bot_lagfunc;
 446         this.isbot = true;
 447         this.createdtime = this.bot_nextthink;
 448
 449         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 450         {
 451                 bot_setnameandstuff(this);
 452                 bot_setclientfields(this);
 453         }
 454
 455         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 456         {
 457                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 458         }
 459         else
 460         {
 461                 this.bot_forced_team = 0;
 462                 TeamBalance_JoinBestTeam(this);
 463         }
 464
 465         havocbot_setupbot(this);
 466 }
 467
 468 void bot_removefromlargestteam()
 469 {
 470         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 471         TeamBalance_GetTeamCounts(balance, NULL);
 472
 473         entity best = NULL;
 474         float besttime = 0;
 475         int bestcount = 0;
 476
 477         int bcount = 0;
 478         FOREACH_CLIENT(it.isbot,
 479         {
 480                 ++bcount;
 481
 482                 if(!best)
 483                 {
 484                         best = it;
 485                         besttime = it.createdtime;
 486                 }
 487
 488                 int thiscount = 0;
 489
 490                 if (Team_IsValidTeam(it.team))
 491                 {
 492                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 493                                 Team_TeamToIndex(it.team));
 494                 }
 495
 496                 if(thiscount > bestcount)
 497                 {
 498                         bestcount = thiscount;
 499                         besttime = it.createdtime;
 500                         best = it;
 501                 }
 502                 else if(thiscount == bestcount && besttime < it.createdtime)
 503                 {
 504                         besttime = it.createdtime;
 505                         best = it;
 506                 }
 507         });
 508         TeamBalance_Destroy(balance);
 509         if(!bcount)
 510                 return; // no bots to remove
 511         currentbots = currentbots - 1;
 512         dropclient(best);
 513 }
 514
 515 void bot_removenewest()
 516 {
 517         if(teamplay)
 518         {
 519                 bot_removefromlargestteam();
 520                 return;
 521         }
 522
 523         float besttime = 0;
 524         entity best = NULL;
 525         int bcount = 0;
 526
 527         FOREACH_CLIENT(it.isbot,
 528         {
 529                 ++bcount;
 530
 531                 if(!best)
 532                 {
 533                         best = it;
 534                         besttime = it.createdtime;
 535                 }
 536
 537                 if(besttime < it.createdtime)
 538                 {
 539                         besttime = it.createdtime;
 540                         best = it;
 541                 }
 542         });
 543
 544         if(!bcount)
 545                 return; // no bots to remove
 546
 547         currentbots = currentbots - 1;
 548         dropclient(best);
 549 }
 550
 551 void autoskill(float factor)
 552 {
 553         float bestbot;
 554         float bestplayer;
 555
 556         bestbot = -1;
 557         bestplayer = -1;
 558         FOREACH_CLIENT(IS_PLAYER(it), {
 559                 if(IS_REAL_CLIENT(it))
 560                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 561                 else
 562                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 563         });
 564
 565         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 566         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 567         if(bestbot < 0 || bestplayer < 0)
 568         {
 569                 LOG_DEBUG("not doing anything");
 570                 // don't return, let it reset all counters below
 571         }
 572         else if(bestbot <= bestplayer * factor - 2)
 573         {
 574                 if(autocvar_skill < 17)
 575                 {
 576                         LOG_DEBUG("2 frags difference, increasing skill");
 577                         cvar_set("skill", ftos(autocvar_skill + 1));
 578                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 579                 }
 580         }
 581         else if(bestbot >= bestplayer * factor + 2)
 582         {
 583                 if(autocvar_skill > 0)
 584                 {
 585                         LOG_DEBUG("2 frags difference, decreasing skill");
 586                         cvar_set("skill", ftos(autocvar_skill - 1));
 587                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 588                 }
 589         }
 590         else
 591         {
 592                 LOG_DEBUG("not doing anything");
 593                 return;
 594                 // don't reset counters, wait for them to accumulate
 595         }
 596
 597         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 598 }
 599
 600 void bot_calculate_stepheightvec()
 601 {
 602         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 603         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 604         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 605         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 606 }
 607
 608 bool bot_fixcount()
 609 {
 610         int activerealplayers = 0;
 611         int realplayers = 0;
 612         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 613                 activerealplayers = M_ARGV(0, int);
 614                 realplayers = M_ARGV(1, int);
 615         } else {
 616                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 617                         if(IS_PLAYER(it))
 618                                 ++activerealplayers;
 619                         ++realplayers;
 620                 });
 621         }
 622
 623         int bots;
 624         // But don't remove bots immediately on level change, as the real players
 625         // usually haven't rejoined yet
 626         bots_would_leave = false;
 627         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 628                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 629         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 630         {
 631                 int minplayers = max(0, floor(autocvar_minplayers));
 632                 if (teamplay)
 633                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 634                 int minbots = max(0, floor(autocvar_bot_number));
 635
 636                 // add bots to reach minplayers if needed
 637                 bots = max(minbots, minplayers - activerealplayers);
 638                 // cap bots to the max players allowed by the server
 639                 int player_limit = GetPlayerLimit();
 640                 if(player_limit)
 641                         bots = min(bots, max(player_limit - activerealplayers, 0));
 642                 bots = min(bots, maxclients - realplayers);
 643
 644                 if(bots > minbots)
 645                         bots_would_leave = true;
 646         }
 647         else
 648         {
 649                 // if there are no players, remove bots
 650                 bots = 0;
 651         }
 652
 653         // only add one bot per frame to avoid utter chaos
 654         if(time > botframe_nextthink)
 655         {
 656                 if (currentbots < bots)
 657                 {
 658                         if (bot_spawn() == NULL)
 659                         {
 660                                 bprint("Can not add bot, server full.\n");
 661                                 return false;
 662                         }
 663                 }
 664                 while (currentbots > bots && bots >= 0)
 665                         bot_removenewest();
 666         }
 667
 668         return true;
 669 }
 670
 671 void bot_remove_from_bot_list(entity this)
 672 {
 673         entity e = bot_list;
 674         entity prev_bot = NULL;
 675         while (e)
 676         {
 677                 if(e == this)
 678                 {
 679                         if(!prev_bot)
 680                                 bot_list = this.nextbot;
 681                         else
 682                                 prev_bot.nextbot = this.nextbot;
 683                         if(bot_strategytoken == this)
 684                         {
 685                                 bot_strategytoken = this.nextbot;
 686                                 bot_strategytoken_taken = true;
 687                         }
 688                         this.nextbot = NULL;
 689                         break;
 690                 }
 691                 prev_bot = e;
 692                 e = e.nextbot;
 693         }
 694 }
 695
 696 void bot_clear(entity this)
 697 {
 698         bot_remove_from_bot_list(this);
 699         if(bot_waypoint_queue_owner == this)
 700                 bot_waypoint_queue_owner = NULL;
 701         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 702 }
 703
 704 void bot_serverframe()
 705 {
 706         if (intermission_running && currentbots > 0)
 707         {
 708                 // after the end of the match all bots stay unless all human players disconnect
 709                 int realplayers = 0;
 710                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 711                 if (!realplayers)
 712                 {
 713                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 714                         currentbots = 0;
 715                 }
 716                 return;
 717         }
 718
 719         if (game_stopped)
 720                 return;
 721
 722         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 723         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 724         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 725         // either intentionally or automatically (sv_spectate 0)
 726         if (time < 2.5)
 727         {
 728                 currentbots = -1;
 729                 return;
 730         }
 731
 732         if (currentbots == -1)
 733         {
 734                 // count bots already in the server from the previous match
 735                 currentbots = 0;
 736                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 737         }
 738
 739         if(autocvar_skill != skill)
 740         {
 741                 float wpcost_update = false;
 742                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 743                         wpcost_update = true;
 744                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 745                         wpcost_update = true;
 746
 747                 skill = autocvar_skill;
 748                 if (wpcost_update)
 749                         waypoint_updatecost_foralllinks();
 750         }
 751
 752         bot_calculate_stepheightvec();
 753         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 754
 755         if(time > autoskill_nextthink)
 756         {
 757                 float a;
 758                 a = autocvar_skill_auto;
 759                 if(a)
 760                         autoskill(a);
 761                 autoskill_nextthink = time + 5;
 762         }
 763
 764         if(time > botframe_nextthink)
 765         {
 766                 if(!bot_fixcount())
 767                         botframe_nextthink = time + 10;
 768         }
 769
 770         if(botframe_spawnedwaypoints)
 771         {
 772                 if(autocvar_waypoint_benchmark)
 773                         localcmd("quit\n");
 774         }
 775
 776         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 777         if (botframe_spawnedwaypoints)
 778         {
 779                 if(botframe_cachedwaypointlinks)
 780                 {
 781                         if(!botframe_loadedforcedlinks)
 782                                 waypoint_load_hardwiredlinks();
 783                 }
 784                 else
 785                 {
 786                         // TODO: Make this check cleaner
 787                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 788                         {
 789                                 waypoint_save_links();
 790                                 break;
 791                         });
 792                 }
 793         }
 794         else
 795         {
 796                 botframe_spawnedwaypoints = true;
 797                 waypoint_loadall();
 798                 waypoint_load_links();
 799         }
 800
 801         if (bot_list)
 802         {
 803                 // cycle the goal token from one bot to the next each frame
 804                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 805                 //  frame, which causes choppy framerates)
 806                 if (bot_strategytoken_taken)
 807                 {
 808                         // give goal token to the first bot without goals; if all bots don't have
 809                         // any goal (or are dead/frozen) simply give it to the next one
 810                         bot_strategytoken_taken = false;
 811                         entity bot_strategytoken_save = bot_strategytoken;
 812                         while (true)
 813                         {
 814                                 if (bot_strategytoken)
 815                                         bot_strategytoken = bot_strategytoken.nextbot;
 816                                 if (!bot_strategytoken)
 817                                         bot_strategytoken = bot_list;
 818
 819                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 820                                         && !bot_strategytoken.goalcurrent)
 821                                         break;
 822
 823                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 824                                         break;
 825                                 if (bot_strategytoken == bot_strategytoken_save)
 826                                         bot_strategytoken_save = NULL; // looped through all the bots
 827                         }
 828                 }
 829
 830                 if (botframe_nextdangertime < time)
 831                 {
 832                         float interval;
 833                         interval = autocvar_bot_ai_dangerdetectioninterval;
 834                         if (botframe_nextdangertime < time - interval * 1.5)
 835                                 botframe_nextdangertime = time;
 836                         botframe_nextdangertime = botframe_nextdangertime + interval;
 837                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 838                 }
 839         }
 840
 841         if (autocvar_g_waypointeditor)
 842                 botframe_showwaypointlinks();
 843
 844         if (autocvar_g_waypointeditor_auto)
 845                 botframe_autowaypoints();
 846
 847         if (currentbots > 0)
 848                 bot_custom_weapon_priority_setup();
 849 }