qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if (this.goalcurrent && wasfreed(this.goalcurrent))
  93         {
  94                 navigation_clearroute(this);
  95                 navigation_goalrating_timeout_force(this);
  96                 return;
  97         }
  98
  99         if(IS_DEAD(this) || STAT(FROZEN, this))
 100         {
 101                 if (this.goalcurrent)
 102                         navigation_clearroute(this);
 103                 return;
 104         }
 105
 106         havocbot_chooseenemy(this);
 107
 108         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 109         {
 110                 .entity weaponentity = weaponentities[slot];
 111                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 112                 if(this.(weaponentity).bot_chooseweapontime < time)
 113                 {
 114                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 115                         havocbot_chooseweapon(this, weaponentity);
 116                 }
 117         }
 118         havocbot_aim(this);
 119         lag_update(this);
 120
 121         if (this.bot_aimtarg)
 122         {
 123                 this.aistatus |= AI_STATUS_ATTACKING;
 124                 this.aistatus &= ~AI_STATUS_ROAMING;
 125
 126                 if(STAT(WEAPONS, this))
 127                 {
 128                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 129                         {
 130                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 131                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 132                         }
 133                         else
 134                         {
 135                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 136                                 {
 137                                         .entity weaponentity = weaponentities[slot];
 138                                         Weapon w = this.(weaponentity).m_weapon;
 139                                         if(w == WEP_Null && slot != 0)
 140                                                 continue;
 141                                         w.wr_aim(w, this, weaponentity);
 142                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 143                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 144                                 }
 145                         }
 146                 }
 147                 else
 148                 {
 149                         if(IS_PLAYER(this.bot_aimtarg))
 150                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 151                 }
 152         }
 153         else if (this.goalcurrent)
 154         {
 155                 this.aistatus |= AI_STATUS_ROAMING;
 156                 this.aistatus &= ~AI_STATUS_ATTACKING;
 157         }
 158
 159         havocbot_movetogoal(this);
 160         if (!this.bot_aimdir_executed && this.goalcurrent)
 161         {
 162                 // Heading
 163                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 164                 dir -= this.origin + this.view_ofs;
 165                 dir.z = 0;
 166                 bot_aimdir(this, dir, 0);
 167         }
 168
 169         // if the bot is not attacking, consider reloading weapons
 170         if (!(this.aistatus & AI_STATUS_ATTACKING))
 171         {
 172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 173                 {
 174                         .entity weaponentity = weaponentities[slot];
 175
 176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 177                                 continue;
 178
 179                         // we are currently holding a weapon that's not fully loaded, reload it
 180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 182                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 183
 184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 185                         // the code above executes next frame, starting the reloading then
 186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 188                         {
 189                                 FOREACH(Weapons, it != WEP_Null, {
 190                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 191                                         {
 192                                                 this.(weaponentity).m_switchweapon = it;
 193                                                 break;
 194                                         }
 195                                 });
 196                         }
 197                 }
 198         }
 199 }
 200
 201 void havocbot_bunnyhop(entity this, vector dir)
 202 {
 203         bool can_run = false;
 204         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 205                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 206                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 207                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 208         {
 209                 vector vel_angles = vectoangles(this.velocity);
 210                 vector deviation = vel_angles - vectoangles(dir);
 211                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 212                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 213                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 214                 {
 215                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 216                         float vel = vlen(vec2(this.velocity));
 217
 218                         // with the current physics, jump distance grows linearly with the speed
 219                         float jump_distance = 52.661 + 0.606 * vel;
 220                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 221                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 222                                 can_run = true;
 223                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 224                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 225                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 226                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 227                         {
 228                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 229                                 vector ang = vectoangles(gco - this.origin);
 230                                 deviation = vectoangles(gno - gco) - vel_angles;
 231                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 232                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 233
 234                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 235                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 236                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 237                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 238                                 {
 239                                         can_run = true;
 240                                 }
 241                         }
 242                 }
 243         }
 244
 245         if (can_run)
 246         {
 247                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 248                 this.bot_jump_time = time;
 249                 this.aistatus |= AI_STATUS_RUNNING;
 250         }
 251         else
 252         {
 253                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 254                         this.aistatus &= ~AI_STATUS_RUNNING;
 255         }
 256 }
 257
 258 void havocbot_keyboard_movement(entity this, vector destorg)
 259 {
 260         if(time <= this.havocbot_keyboardtime)
 261                 return;
 262
 263         float sk = skill + this.bot_moveskill;
 264         this.havocbot_keyboardtime =
 265                 max(
 266                         this.havocbot_keyboardtime
 267                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 268                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 269                 , time);
 270         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 271
 272         float trigger = autocvar_bot_ai_keyboard_threshold;
 273
 274         // categorize forward movement
 275         // at skill < 1.5 only forward
 276         // at skill < 2.5 only individual directions
 277         // at skill < 4.5 only individual directions, and forward diagonals
 278         // at skill >= 4.5, all cases allowed
 279         if (keyboard.x > trigger)
 280         {
 281                 keyboard.x = 1;
 282                 if (sk < 2.5)
 283                         keyboard.y = 0;
 284         }
 285         else if (keyboard.x < -trigger && sk > 1.5)
 286         {
 287                 keyboard.x = -1;
 288                 if (sk < 4.5)
 289                         keyboard.y = 0;
 290         }
 291         else
 292         {
 293                 keyboard.x = 0;
 294                 if (sk < 1.5)
 295                         keyboard.y = 0;
 296         }
 297         if (sk < 4.5)
 298                 keyboard.z = 0;
 299
 300         if (keyboard.y > trigger)
 301                 keyboard.y = 1;
 302         else if (keyboard.y < -trigger)
 303                 keyboard.y = -1;
 304         else
 305                 keyboard.y = 0;
 306
 307         if (keyboard.z > trigger)
 308                 keyboard.z = 1;
 309         else if (keyboard.z < -trigger)
 310                 keyboard.z = -1;
 311         else
 312                 keyboard.z = 0;
 313
 314         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 315         if (keyboard == '0 0 0')
 316                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 317
 318         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 319         if (this.havocbot_ducktime > time)
 320                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 321
 322         keyboard = this.havocbot_keyboard;
 323         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 324         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 325         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 326 }
 327
 328 // return true when bot isn't getting closer to the current goal
 329 bool havocbot_checkgoaldistance(entity this, vector gco)
 330 {
 331         if (this.bot_stop_moving_timeout > time)
 332                 return false;
 333         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 334         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 335         float distance_time = this.goalcurrent_distance_time;
 336         if(distance_time < 0)
 337                 distance_time = -distance_time;
 338         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 339         {
 340                 if(!distance_time)
 341                         this.goalcurrent_distance_time = time;
 342                 else if (time - distance_time > 0.5)
 343                         return true;
 344         }
 345         else
 346         {
 347                 // reduce it a little bit so it works even with very small approaches to the goal
 348                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 349                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 350                 this.goalcurrent_distance_time = 0;
 351         }
 352         return false;
 353 }
 354
 355 entity havocbot_select_an_item_of_group(entity this, int gr)
 356 {
 357         entity selected = NULL;
 358         float selected_dist2 = 0;
 359         // select farthest item of this group from bot's position
 360         IL_EACH(g_items, it.item_group == gr && it.solid,
 361         {
 362                 float dist2 = vlen2(this.origin - it.origin);
 363                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 364                 {
 365                         selected = it;
 366                         selected_dist2 = vlen2(this.origin - selected.origin);
 367                 }
 368         });
 369
 370         if (!selected)
 371                 return NULL;
 372
 373         set_tracewalk_dest(selected, this.origin, false);
 374         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 375                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 376         {
 377                 return NULL;
 378         }
 379
 380         return selected;
 381 }
 382
 383 void havocbot_movetogoal(entity this)
 384 {
 385         vector diff;
 386         vector dir;
 387         vector flatdir;
 388         float dodge_enemy_factor = 1;
 389         float maxspeed;
 390         //float dist;
 391         vector dodge;
 392         //if (this.goalentity)
 393         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 394         CS(this).movement = '0 0 0';
 395         maxspeed = autocvar_sv_maxspeed;
 396
 397         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 398
 399         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 400         // Jetpack navigation
 401         if(this.navigation_jetpack_goal)
 402         if(this.goalcurrent==this.navigation_jetpack_goal)
 403         if(GetResource(this, RES_FUEL))
 404         {
 405                 if(autocvar_bot_debug_goalstack)
 406                 {
 407                         debuggoalstack(this);
 408                         te_wizspike(this.navigation_jetpack_point);
 409                 }
 410
 411                 // Take off
 412                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 413                 {
 414                         // Brake almost completely so it can get a good direction
 415                         if(vdist(this.velocity, >, 10))
 416                                 return;
 417                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 418                 }
 419
 420                 makevectors(this.v_angle.y * '0 1 0');
 421                 dir = normalize(this.navigation_jetpack_point - this.origin);
 422
 423                 // Landing
 424                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 425                 {
 426                         // Calculate brake distance in xy
 427                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 428                         float vel2 = vlen2(vec2(this.velocity));
 429                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 430                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 431                         if(d < db || d < 500)
 432                         {
 433                                 // Brake
 434                                 if (vel2 > (maxspeed * 0.3) ** 2)
 435                                 {
 436                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 437                                         return;
 438                                 }
 439                                 // Switch to normal mode
 440                                 this.navigation_jetpack_goal = NULL;
 441                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 442                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 443                                 return;
 444                         }
 445                 }
 446                 else if(checkpvs(this.origin,this.goalcurrent))
 447                 {
 448                         // If I can see the goal switch to landing code
 449                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 450                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 451                         return;
 452                 }
 453
 454                 // Flying
 455                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 456                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 457                 {
 458                         CS(this).movement_x = dir * v_forward * maxspeed;
 459                         CS(this).movement_y = dir * v_right * maxspeed;
 460                 }
 461                 return;
 462         }
 463
 464         // Handling of jump pads
 465         if(this.jumppadcount)
 466         {
 467                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 468                 {
 469                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 470                         if(navigation_poptouchedgoals(this))
 471                                 return;
 472                 }
 473                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 474                 {
 475                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 476                         // but with some randomness so it can try out different paths
 477                         if(!this.goalcurrent)
 478                         {
 479                                 entity newgoal = NULL;
 480                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 481                                 {
 482                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 483                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 484                                                 continue;
 485
 486                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 487
 488                                         if(trace_fraction < 1)
 489                                                 continue;
 490
 491                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 492                                                 newgoal = it;
 493                                 });
 494
 495                                 if(newgoal)
 496                                 {
 497                                         this.ignoregoal = this.goalcurrent;
 498                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 499                                         navigation_clearroute(this);
 500                                         navigation_routetogoal(this, newgoal, this.origin);
 501                                         if(autocvar_bot_debug_goalstack)
 502                                                 debuggoalstack(this);
 503                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 504                                 }
 505                         }
 506                         else //if (this.goalcurrent)
 507                         {
 508                                 if (this.goalcurrent.bot_pickup)
 509                                 {
 510                                         entity jumppad_wp = this.goalcurrent_prev;
 511                                         navigation_poptouchedgoals(this);
 512                                         if(!this.goalcurrent && jumppad_wp.wp00)
 513                                         {
 514                                                 // head to the jumppad destination once bot reaches the goal item
 515                                                 navigation_pushroute(this, jumppad_wp.wp00);
 516                                         }
 517                                 }
 518                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 519                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 520                                 {
 521                                         if (this.velocity.z < 0)
 522                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 523                                 }
 524                                 else if(havocbot_checkgoaldistance(this, gco))
 525                                 {
 526                                         navigation_clearroute(this);
 527                                         navigation_goalrating_timeout_force(this);
 528                                 }
 529                                 else
 530                                         return;
 531                         }
 532                 }
 533                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 534                 {
 535                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 536                         {
 537                                 vector velxy = this.velocity; velxy_z = 0;
 538                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 539                                 {
 540                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 541                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 542                                 }
 543                                 return;
 544                         }
 545
 546                         // Don't chase players while using a jump pad
 547                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 548                                 return;
 549                 }
 550         }
 551         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 552                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 553
 554         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 555         if (skill > 6 && !(IS_ONGROUND(this)))
 556         {
 557                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 558                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 559                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 560
 561                 // save some CPU cycles by checking trigger_hurt after checking
 562                 // that something can be done to evade it (cheaper checks)
 563                 int action_for_trigger_hurt = 0;
 564                 if (this.items & IT_JETPACK)
 565                         action_for_trigger_hurt = 1;
 566                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 567                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 568                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 569                 {
 570                         action_for_trigger_hurt = 2;
 571                 }
 572                 else if (!this.goalcurrent)
 573                         action_for_trigger_hurt = 3;
 574
 575                 if (action_for_trigger_hurt)
 576                 {
 577                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 578                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 579                                 action_for_trigger_hurt = 0;
 580                 }
 581
 582                 if(action_for_trigger_hurt == 1) // jetpack
 583                 {
 584                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 585                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 586                         {
 587                                 if(this.velocity.z<0)
 588                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 589                         }
 590                         else
 591                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 592
 593                         // If there is no goal try to move forward
 594
 595                         if(this.goalcurrent==NULL)
 596                                 dir = v_forward;
 597                         else
 598                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 599
 600                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 601                         float xyspeed = xyvelocity * dir;
 602
 603                         if(xyspeed < (maxspeed / 2))
 604                         {
 605                                 makevectors(this.v_angle.y * '0 1 0');
 606                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 607                                 if(trace_fraction==1)
 608                                 {
 609                                         CS(this).movement_x = dir * v_forward * maxspeed;
 610                                         CS(this).movement_y = dir * v_right * maxspeed;
 611                                         if (skill < 10)
 612                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 613                                 }
 614                         }
 615
 616                         this.havocbot_blockhead = true;
 617
 618                         return;
 619                 }
 620                 else if(action_for_trigger_hurt == 2) // rocketjump
 621                 {
 622                         if(this.velocity.z < 0)
 623                         {
 624                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 625                                 {
 626                                         .entity weaponentity = weaponentities[slot];
 627
 628                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 629                                                 continue;
 630
 631                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 632                                         {
 633                                                 CS(this).movement_x = maxspeed;
 634
 635                                                 if(this.rocketjumptime)
 636                                                 {
 637                                                         if(time > this.rocketjumptime)
 638                                                         {
 639                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 640                                                                 this.rocketjumptime = 0;
 641                                                         }
 642                                                         return;
 643                                                 }
 644
 645                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 646                                                 this.v_angle_x = 90;
 647                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 648                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 649                                                 return;
 650                                         }
 651                                 }
 652                         }
 653                 }
 654                 else if(action_for_trigger_hurt == 3) // no goal
 655                 {
 656                         // If there is no goal try to move forward
 657                         CS(this).movement_x = maxspeed;
 658                 }
 659         }
 660
 661         // If we are under water with no goals, swim up
 662         if(this.waterlevel && !this.goalcurrent)
 663         {
 664                 dir = '0 0 0';
 665                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 666                         dir.z = 1;
 667                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 668                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 669                 makevectors(this.v_angle.y * '0 1 0');
 670                 vector v = dir * maxspeed;
 671                 CS(this).movement.x = v * v_forward;
 672                 CS(this).movement.y = v * v_right;
 673                 CS(this).movement.z = v * v_up;
 674         }
 675
 676         // if there is nowhere to go, exit
 677         if (this.goalcurrent == NULL)
 678                 return;
 679
 680
 681         bool locked_goal = false;
 682         if((this.goalentity && wasfreed(this.goalentity))
 683                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 684         {
 685                 navigation_clearroute(this);
 686                 navigation_goalrating_timeout_force(this);
 687                 return;
 688         }
 689         else if(this.goalentity.tag_entity)
 690         {
 691                 navigation_goalrating_timeout_expire(this, 2);
 692         }
 693         else if(this.goalentity.bot_pickup)
 694         {
 695                 if(this.goalentity.bot_pickup_respawning)
 696                 {
 697                         if(this.goalentity.solid) // item respawned
 698                                 this.goalentity.bot_pickup_respawning = false;
 699                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 700                         {
 701                                 if(checkpvs(this.origin, this.goalentity))
 702                                 {
 703                                         this.goalentity.bot_pickup_respawning = false;
 704                                         navigation_goalrating_timeout_expire(this, random());
 705                                 }
 706                                 locked_goal = true; // wait for item to respawn
 707                         }
 708                         else if(this.goalentity == this.goalcurrent)
 709                                 locked_goal = true; // wait for item to respawn
 710                 }
 711                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 712                 {
 713                         if(checkpvs(this.origin, this.goalentity))
 714                         {
 715                                 navigation_goalrating_timeout_expire(this, random());
 716                         }
 717                 }
 718         }
 719         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 720                 locked_goal = true;
 721
 722         if (navigation_shortenpath(this))
 723         {
 724                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 725                         && navigation_goalrating_timeout_can_be_anticipated(this))
 726                 {
 727                         navigation_goalrating_timeout_force(this);
 728                 }
 729         }
 730
 731         bool goalcurrent_can_be_removed = false;
 732         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 733         {
 734                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 735                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 736                 {
 737                         goalcurrent_can_be_removed = true;
 738                         // don't remove if not visible
 739                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 740                         {
 741                                 if (IS_DEAD(this.goalcurrent))
 742                                 {
 743                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 744                                         {
 745                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 746                                                 {
 747                                                         navigation_clearroute(this);
 748                                                         navigation_pushroute(this, it);
 749                                                         // loot can't be immediately rated since it isn't on ground yet
 750                                                         // it will be rated after a second when on ground, meanwhile head to it
 751                                                         navigation_goalrating_timeout_expire(this, 1);
 752                                                         return;
 753                                                 }
 754                                         });
 755                                 }
 756                                 if (!Item_IsLoot(this.goalcurrent))
 757                                 {
 758                                         navigation_goalrating_timeout_force(this);
 759                                         return;
 760                                 }
 761                         }
 762                 }
 763                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 764                 {
 765                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 766                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 767                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 768                         {
 769                                 navigation_goalrating_timeout_force(this);
 770                                 return;
 771                         }
 772                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 773                 }
 774         }
 775
 776         if(!locked_goal)
 777         {
 778                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 779                 // in this case path finding can start directly from a waypoint instead of
 780                 // looking for all the reachable waypoints up to a certain distance
 781                 if (navigation_poptouchedgoals(this))
 782                 {
 783                         if (this.goalcurrent)
 784                         {
 785                                 if (goalcurrent_can_be_removed)
 786                                 {
 787                                         // remove even if not visible
 788                                         navigation_goalrating_timeout_force(this);
 789                                         return;
 790                                 }
 791                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 792                                         navigation_goalrating_timeout_force(this);
 793                         }
 794                         else
 795                         {
 796                                 entity old_goal = this.goalcurrent_prev;
 797                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 798                                 {
 799                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 800                                         // item of the group by telling the bot to head directly to the farthest item.
 801                                         // Next time we let the bot select a goal as usual which can be another item
 802                                         // of this group (the closest one) and so on
 803                                         this.item_group = old_goal.item_group;
 804                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 805                                         if (new_goal)
 806                                                 navigation_pushroute(this, new_goal);
 807                                 }
 808                         }
 809                 }
 810         }
 811
 812         // if ran out of goals try to use an alternative goal or get a new strategy asap
 813         if(this.goalcurrent == NULL)
 814         {
 815                 navigation_goalrating_timeout_force(this);
 816                 return;
 817         }
 818
 819
 820         if(autocvar_bot_debug_goalstack)
 821                 debuggoalstack(this);
 822
 823         bool bunnyhop_forbidden = false;
 824         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 825         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 826         {
 827                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 828                 destorg = this.goalcurrent.origin;
 829         }
 830         else if (this.goalcurrent.wpisbox)
 831         {
 832                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 833                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 834                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 835                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 836                 {
 837                         bunnyhop_forbidden = true;
 838                         destorg = this.goalcurrent.origin;
 839                         if(destorg.z > this.origin.z)
 840                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 841                 }
 842         }
 843
 844         diff = destorg - this.origin;
 845
 846         if (time < this.bot_stop_moving_timeout
 847                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 848         {
 849                 // stop if the locked goal has been reached
 850                 destorg = this.origin;
 851                 diff = dir = '0 0 0';
 852         }
 853         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 854         {
 855                 if (vdist(diff, <, 80))
 856                 {
 857                         // stop if too close to target player (even if frozen)
 858                         destorg = this.origin;
 859                         diff = dir = '0 0 0';
 860                 }
 861                 else
 862                 {
 863                         // move destorg out of target players, otherwise bot will consider them
 864                         // an obstacle that needs to be jumped (especially if frozen)
 865                         dir = normalize(diff);
 866                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 867                         diff = destorg - this.origin;
 868                 }
 869         }
 870         else
 871                 dir = normalize(diff);
 872         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 873
 874         vector evadedanger = '0 0 0';
 875
 876         //if (this.bot_dodgevector_time < time)
 877         {
 878                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 879                 //this.bot_dodgevector_jumpbutton = 1;
 880
 881                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 882                 makevectors(this.v_angle.y * '0 1 0');
 883                 if (this.waterlevel > WATERLEVEL_WETFEET)
 884                 {
 885                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 886                         {
 887                                 if(!this.goalcurrent)
 888                                         this.aistatus |= AI_STATUS_OUT_WATER;
 889                                 else if(destorg.z > this.origin.z)
 890                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 891                         }
 892                         else
 893                         {
 894                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 895                                         (this.aistatus & AI_STATUS_OUT_WATER))
 896                                 {
 897                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 898                                         dir = flatdir;
 899                                 }
 900                                 else
 901                                 {
 902                                         if (destorg.z > this.origin.z)
 903                                                 dir = flatdir;
 904                                 }
 905                         }
 906                 }
 907                 else
 908                 {
 909                         float s;
 910                         vector offset;
 911                         if(this.aistatus & AI_STATUS_OUT_WATER)
 912                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 913
 914                         // jump if going toward an obstacle that doesn't look like stairs we
 915                         // can walk up directly
 916                         vector deviation = '0 0 0';
 917                         float current_speed = vlen(vec2(this.velocity));
 918                         if (current_speed < maxspeed * 0.2)
 919                                 current_speed = maxspeed * 0.2;
 920                         else
 921                         {
 922                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 923                                 while (deviation.y < -180) deviation.y += 360;
 924                                 while (deviation.y > 180) deviation.y -= 360;
 925                         }
 926                         float turning = false;
 927                         vector flat_diff = vec2(diff);
 928                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 929                         vector actual_destorg = this.origin + offset;
 930                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 931                         {
 932                                 if (time > this.bot_stop_moving_timeout
 933                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 934                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 935                                 {
 936                                         this.bot_stop_moving_timeout = time + 0.1;
 937                                 }
 938                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 939                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 940                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 941                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 942                                 )
 943                                 {
 944                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 945                                         this.bot_jump_time = time;
 946                                         // avoid changing route while bot is jumping a gap
 947                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
 948                                 }
 949                         }
 950                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 951                         {
 952                                 if (vlen2(flat_diff) < vlen2(offset))
 953                                 {
 954                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 955                                         {
 956                                                 // oblique warpzones need a jump otherwise bots gets stuck
 957                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 958                                         }
 959                                         else
 960                                         {
 961                                                 actual_destorg.x = destorg.x;
 962                                                 actual_destorg.y = destorg.y;
 963                                         }
 964                                 }
 965                         }
 966                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 967                         {
 968                                 actual_destorg.x = destorg.x;
 969                                 actual_destorg.y = destorg.y;
 970                         }
 971                         else if (vlen2(flat_diff) < vlen2(offset))
 972                         {
 973                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 974                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 975                                 float dist = vlen(vec2(this.origin + offset - destorg));
 976                                 // if current and next goal are close to each other make sure
 977                                 // actual_destorg isn't set beyond next_goal_org
 978                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 979                                         actual_destorg = next_goal_org;
 980                                 else
 981                                         actual_destorg = vec2(destorg) + dist * next_dir;
 982                                 actual_destorg.z = this.origin.z;
 983                                 turning = true;
 984                         }
 985
 986                         LABEL(jumpobstacle_check);
 987                         dir = flatdir = normalize(actual_destorg - this.origin);
 988
 989                         bool jump_forbidden = false;
 990                         if (!turning && fabs(deviation.y) > 50)
 991                                 jump_forbidden = true;
 992                         else if (IS_DUCKED(this))
 993                         {
 994                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
 995                                 if (trace_startsolid)
 996                                         jump_forbidden = true;
 997                         }
 998
 999                         if (!jump_forbidden)
1000                         {
1001                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1002                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1003                                 {
1004                                         s = trace_fraction;
1005                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1006                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1007                                         {
1008                                                 // found an obstacle
1009                                                 if (turning && fabs(deviation.y) > 5)
1010                                                 {
1011                                                         // check if the obstacle is still there without turning
1012                                                         actual_destorg = destorg;
1013                                                         turning = false;
1014                                                         this.bot_tracewalk_time = time + 0.25;
1015                                                         goto jumpobstacle_check;
1016                                                 }
1017                                                 s = trace_fraction;
1018                                                 // don't artificially reduce max jump height in real-time
1019                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1020                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1021                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1022                                                 if (trace_fraction > s)
1023                                                 {
1024                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1025                                                         this.bot_jump_time = time;
1026                                                 }
1027                                                 else
1028                                                 {
1029                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1030                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1031                                                         if (trace_fraction > s)
1032                                                         {
1033                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1034                                                                 this.bot_jump_time = time;
1035                                                         }
1036                                                 }
1037                                         }
1038                                 }
1039                         }
1040
1041                         // if bot for some reason doesn't get close to the current goal find another one
1042                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1043                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1044                         if(havocbot_checkgoaldistance(this, destorg))
1045                         {
1046                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1047                                 {
1048                                         navigation_clearroute(this);
1049                                         navigation_goalrating_timeout_force(this);
1050                                         return;
1051                                 }
1052
1053                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1054                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1055                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1056                                 {
1057                                         navigation_clearroute(this);
1058                                         navigation_goalrating_timeout_force(this);
1059                                         return;
1060                                 }
1061
1062                                 // give bot only another chance to prevent bot getting stuck
1063                                 // in case it thinks it can walk but actually can't
1064                                 this.goalcurrent_distance_z = FLOAT_MAX;
1065                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1066                                 this.goalcurrent_distance_time = -time; // mark second try
1067                         }
1068
1069                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1070                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1071                         {
1072                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1073                         }
1074
1075                         // Check for water/slime/lava and dangerous edges
1076                         // (only when the bot is on the ground or jumping intentionally)
1077
1078                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1079                         vector dst_ahead = this.origin + this.view_ofs + offset;
1080                         vector dst_down = dst_ahead - '0 0 3000';
1081                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1082
1083                         bool unreachable = false;
1084                         s = CONTENT_SOLID;
1085                         bool danger_detected = false;
1086                         if (trace_fraction == 1 && !this.jumppadcount
1087                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1088                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1089                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1090                         {
1091                                 // Look downwards
1092                                 traceline(dst_ahead , dst_down, true, NULL);
1093                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1094                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1095                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1096                                 {
1097                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1098                                                 danger_detected = true;
1099                                         else
1100                                         {
1101                                                 s = pointcontents(trace_endpos + '0 0 1');
1102                                                 if (s != CONTENT_SOLID)
1103                                                 {
1104                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1105                                                                 danger_detected = true;
1106                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1107                                                         {
1108                                                                 // the traceline check isn't enough but is good as optimization,
1109                                                                 // when not true (most of the time) this tracebox call is avoided
1110                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1111                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1112                                                                 {
1113                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1114                                                                         {
1115                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1116                                                                                 unreachable = true;
1117                                                                         }
1118                                                                         else
1119                                                                                 danger_detected = true;
1120                                                                 }
1121                                                         }
1122                                                 }
1123                                         }
1124                                 }
1125                         }
1126                         if (danger_detected && fabs(deviation.y) < 80
1127                                 && (fabs(deviation.y) > 5 || vdist(vec2(this.velocity), >, maxspeed * 1.5)))
1128                         {
1129                                 evadedanger = normalize(this.velocity) * -1;
1130                                 evadedanger.z = 0;
1131                         }
1132
1133                         dir = flatdir;
1134                         makevectors(this.v_angle.y * '0 1 0');
1135
1136                         if (danger_detected || (s == CONTENT_WATER))
1137                         {
1138                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1139                                 if(IS_PLAYER(this.goalcurrent))
1140                                         unreachable = true;
1141                         }
1142
1143                         // slow down if bot is in the air and goal is under it
1144                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1145                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1146                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1147                         {
1148                                 // tracebox wouldn't work when bot is still on the ledge
1149                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1150                                 if (this.origin.z - trace_endpos.z > 120)
1151                                         evadedanger = normalize(this.velocity) * -1;
1152                         }
1153
1154                         if(unreachable)
1155                         {
1156                                 navigation_clearroute(this);
1157                                 navigation_goalrating_timeout_force(this);
1158                                 this.ignoregoal = this.goalcurrent;
1159                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1160                         }
1161                 }
1162
1163                 dodge = havocbot_dodge(this);
1164                 if (dodge)
1165                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1166                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1167                 if (this.enemy)
1168                 {
1169                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1170                         if (IS_PLAYER(trace_ent))
1171                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1172                 }
1173         //      this.bot_dodgevector = dir;
1174         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1175         }
1176
1177         float ladder_zdir = 0;
1178         if(time < this.ladder_time)
1179         {
1180                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1181                 {
1182                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1183                                 ladder_zdir = 1;
1184                 }
1185                 else
1186                 {
1187                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1188                                 ladder_zdir = -1;
1189                 }
1190                 if (ladder_zdir)
1191                 {
1192                         if (vdist(vec2(diff), <, 40))
1193                                 dir.z = ladder_zdir * 4;
1194                         else
1195                                 dir.z = ladder_zdir * 2;
1196                         dir = normalize(dir);
1197                 }
1198         }
1199
1200         if (this.goalcurrent.wpisbox
1201                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1202         {
1203                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1204                 // head to teleport origin
1205                 dir = (this.goalcurrent.origin - this.origin);
1206                 dir.z = 0;
1207                 dir = normalize(dir);
1208         }
1209
1210         // already executed when bot targets an enemy
1211         if (!this.bot_aimdir_executed)
1212         {
1213                 if (time < this.bot_stop_moving_timeout)
1214                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1215                 else
1216                         bot_aimdir(this, dir, 0);
1217         }
1218
1219         if (!ladder_zdir)
1220         {
1221                 dir *= dodge_enemy_factor;
1222                 dir = normalize(dir + dodge + evadedanger);
1223         }
1224
1225         makevectors(this.v_angle);
1226         //dir = this.bot_dodgevector;
1227         //if (this.bot_dodgevector_jumpbutton)
1228         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1229         CS(this).movement_x = dir * v_forward * maxspeed;
1230         CS(this).movement_y = dir * v_right * maxspeed;
1231         CS(this).movement_z = dir * v_up * maxspeed;
1232
1233         // Emulate keyboard interface
1234         if (skill < 10)
1235                 havocbot_keyboard_movement(this, destorg);
1236
1237         // Bunnyhop!
1238         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1239                 havocbot_bunnyhop(this, dir);
1240
1241         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1242                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1243         if (dodge)
1244         {
1245                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1246                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1247                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1248                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1249         }
1250 }
1251
1252 entity havocbot_gettarget(entity this, bool secondary)
1253 {
1254         entity best = NULL;
1255         vector eye = CENTER_OR_VIEWOFS(this);
1256         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1257         {
1258                 vector v = CENTER_OR_VIEWOFS(it);
1259                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1260                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1261                 if(bot_shouldattack(this, it))
1262                 {
1263                         traceline(eye, v, true, this);
1264                         if (trace_ent == it || trace_fraction >= 1)
1265                                 best = it;
1266                 }
1267         });
1268
1269         return best;
1270 }
1271
1272 void havocbot_chooseenemy(entity this)
1273 {
1274         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1275         {
1276                 this.enemy = NULL;
1277                 return;
1278         }
1279
1280         if (this.enemy)
1281         {
1282                 if (!bot_shouldattack(this, this.enemy))
1283                 {
1284                         // enemy died or something, find a new target
1285                         this.enemy = NULL;
1286                         this.havocbot_chooseenemy_finished = time;
1287                 }
1288                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1289                 {
1290                         // tracking last chosen enemy
1291                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1292                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1293                         if (trace_ent == this.enemy || trace_fraction == 1)
1294                         if (vdist(targ_pos - this.origin, <, 1000))
1295                         {
1296                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1297                                 this.havocbot_chooseenemy_finished = time + 0.5;
1298                                 return;
1299                         }
1300
1301                         // stop preferring this enemy
1302                         this.havocbot_stickenemy_time = 0;
1303                 }
1304         }
1305         if (time < this.havocbot_chooseenemy_finished)
1306                 return;
1307         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1308         vector eye = this.origin + this.view_ofs;
1309         entity best = NULL;
1310         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1311
1312         // Backup hit flags
1313         int hf = this.dphitcontentsmask;
1314
1315         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1316
1317         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1318
1319         bool scan_transparent = false;
1320         bool scan_secondary_targets = false;
1321         bool have_secondary_targets = false;
1322         while(true)
1323         {
1324                 scan_secondary_targets = false;
1325 LABEL(scan_targets)
1326                 IL_EACH(g_bot_targets, it.bot_attack,
1327                 {
1328                         if(!scan_secondary_targets)
1329                         {
1330                                 if(it.classname == "misc_breakablemodel")
1331                                 {
1332                                         have_secondary_targets = true;
1333                                         continue;
1334                                 }
1335                         }
1336                         else if(it.classname != "misc_breakablemodel")
1337                                 continue;
1338
1339                         vector v = (it.absmin + it.absmax) * 0.5;
1340                         float rating = vlen2(v - eye);
1341                         if (rating < bestrating && bot_shouldattack(this, it))
1342                         {
1343                                 traceline(eye, v, true, this);
1344                                 if (trace_ent == it || trace_fraction >= 1)
1345                                 {
1346                                         best = it;
1347                                         bestrating = rating;
1348                                 }
1349                         }
1350                 });
1351
1352                 if(!best && have_secondary_targets && !scan_secondary_targets)
1353                 {
1354                         scan_secondary_targets = true;
1355                         // restart the loop
1356                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1357                         goto scan_targets;
1358                 }
1359
1360                 // I want to do a second scan if no enemy was found or I don't have weapons
1361                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1362                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1363                         break;
1364                 if(scan_transparent)
1365                         break;
1366
1367                 // Set flags to see through transparent objects
1368                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1369
1370                 scan_transparent = true;
1371         }
1372
1373         // Restore hit flags
1374         this.dphitcontentsmask = hf;
1375
1376         this.enemy = best;
1377         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1378         if(best && best.classname == "misc_breakablemodel")
1379                 this.havocbot_stickenemy_time = 0;
1380 }
1381
1382 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1383 {
1384         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1385         // so skip this for them, or they'll never get to reload their weapons at all.
1386         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1387         if(skill < 5)
1388                 return false;
1389
1390         // if this weapon is scheduled for reloading, don't switch to it during combat
1391         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1392         {
1393                 FOREACH(Weapons, it != WEP_Null, {
1394                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1395                                 return true; // other weapon available
1396                 });
1397         }
1398
1399         return false;
1400 }
1401
1402 void havocbot_chooseweapon(entity this, .entity weaponentity)
1403 {
1404         int i;
1405
1406         // ;)
1407         if(g_weaponarena_weapons == WEPSET(TUBA))
1408         {
1409                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1410                 return;
1411         }
1412
1413         // TODO: clean this up by moving it to weapon code
1414         if(this.enemy==NULL)
1415         {
1416                 // If no weapon was chosen get the first available weapon
1417                 if(this.(weaponentity).m_weapon==WEP_Null)
1418                 FOREACH(Weapons, it != WEP_Null, {
1419                         if(client_hasweapon(this, it, weaponentity, true, false))
1420                         {
1421                                 this.(weaponentity).m_switchweapon = it;
1422                                 return;
1423                         }
1424                 });
1425                 return;
1426         }
1427
1428         // Do not change weapon during the next second after a combo
1429         float f = time - this.lastcombotime;
1430         if(f < 1)
1431                 return;
1432
1433         float w;
1434         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1435
1436         // Should it do a weapon combo?
1437         float af, ct, combo_time, combo;
1438
1439         af = ATTACK_FINISHED(this, weaponentity);
1440         ct = autocvar_bot_ai_weapon_combo_threshold;
1441
1442         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1443         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1444         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1445
1446         combo = false;
1447
1448         if(autocvar_bot_ai_weapon_combo)
1449         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1450         if(af > combo_time)
1451         {
1452                 combo = true;
1453                 this.lastcombotime = time;
1454         }
1455
1456         distance *= (2 ** this.bot_rangepreference);
1457
1458         // Custom weapon list based on distance to the enemy
1459         if(bot_custom_weapon){
1460
1461                 // Choose weapons for far distance
1462                 if ( distance > bot_distance_far ) {
1463                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1464                                 w = bot_weapons_far[i];
1465                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1466                                 {
1467                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1468                                                 continue;
1469                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1470                                         return;
1471                                 }
1472                         }
1473                 }
1474
1475                 // Choose weapons for mid distance
1476                 if ( distance > bot_distance_close) {
1477                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1478                                 w = bot_weapons_mid[i];
1479                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1480                                 {
1481                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1482                                                 continue;
1483                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1484                                         return;
1485                                 }
1486                         }
1487                 }
1488
1489                 // Choose weapons for close distance
1490                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1491                         w = bot_weapons_close[i];
1492                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1493                         {
1494                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1495                                         continue;
1496                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1497                                 return;
1498                         }
1499                 }
1500         }
1501 }
1502
1503 void havocbot_aim(entity this)
1504 {
1505         if (time < this.nextaim)
1506                 return;
1507         this.nextaim = time + 0.1;
1508         vector myvel = this.velocity;
1509         if (!this.waterlevel)
1510                 myvel.z = 0;
1511         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1512         else if (this.enemy)
1513         {
1514                 vector enemyvel = this.enemy.velocity;
1515                 if (!this.enemy.waterlevel)
1516                         enemyvel.z = 0;
1517                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1518         }
1519         else
1520                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1521 }
1522
1523 bool havocbot_moveto_refresh_route(entity this)
1524 {
1525         // Refresh path to goal if necessary
1526         entity wp;
1527         wp = this.havocbot_personal_waypoint;
1528         navigation_goalrating_start(this);
1529         navigation_routerating(this, wp, 10000, 10000);
1530         navigation_goalrating_end(this);
1531         return (this.goalentity != NULL);
1532 }
1533
1534 float havocbot_moveto(entity this, vector pos)
1535 {
1536         entity wp;
1537
1538         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1539         {
1540                 // Step 4: Move to waypoint
1541                 if(this.havocbot_personal_waypoint==NULL)
1542                 {
1543                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1544                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1545                         return CMD_STATUS_ERROR;
1546                 }
1547
1548                 if (!bot_strategytoken_taken)
1549                 if(this.havocbot_personal_waypoint_searchtime<time)
1550                 {
1551                         bot_strategytoken_taken = true;
1552                         if(havocbot_moveto_refresh_route(this))
1553                         {
1554                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1555                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1556                                 this.havocbot_personal_waypoint_failcounter = 0;
1557                         }
1558                         else
1559                         {
1560                                 this.havocbot_personal_waypoint_failcounter += 1;
1561                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1562                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1563                                 {
1564                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1565                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1566                                         delete(this.havocbot_personal_waypoint);
1567                                         return CMD_STATUS_ERROR;
1568                                 }
1569                                 else
1570                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1571                         }
1572                 }
1573
1574                 if(autocvar_bot_debug_goalstack)
1575                         debuggoalstack(this);
1576
1577
1578                 // Go!
1579                 havocbot_movetogoal(this);
1580
1581                 if (!this.bot_aimdir_executed && this.goalcurrent)
1582                 {
1583                         // Heading
1584                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1585                         dir -= this.origin + this.view_ofs;
1586                         dir.z = 0;
1587                         bot_aimdir(this, dir, 0);
1588                 }
1589
1590                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1591                 {
1592                         // Step 5: Waypoint reached
1593                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1594                         waypoint_remove(this.havocbot_personal_waypoint);
1595                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1596                         return CMD_STATUS_FINISHED;
1597                 }
1598
1599                 return CMD_STATUS_EXECUTING;
1600         }
1601
1602         // Step 2: Linking waypoint
1603         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1604         {
1605                 // Wait until it is linked
1606                 if(!this.havocbot_personal_waypoint.wplinked)
1607                 {
1608                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1609                         return CMD_STATUS_EXECUTING;
1610                 }
1611
1612                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1613                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1614                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1615
1616                 // Step 3: Route to waypoint
1617                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1618
1619                 return CMD_STATUS_EXECUTING;
1620         }
1621
1622         // Step 1: Spawning waypoint
1623         wp = waypoint_spawnpersonal(this, pos);
1624         if(wp==NULL)
1625         {
1626                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1627                 return CMD_STATUS_ERROR;
1628         }
1629
1630         this.havocbot_personal_waypoint = wp;
1631         this.havocbot_personal_waypoint_failcounter = 0;
1632         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1633
1634         // if pos is inside a teleport, then let's mark it as teleport waypoint
1635         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1636         {
1637                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1638                 this.lastteleporttime = 0;
1639         });
1640
1641 /*
1642         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1643                 print("routing to a teleporter\n");
1644         else
1645                 print("routing to a non-teleporter\n");
1646 */
1647
1648         return CMD_STATUS_EXECUTING;
1649 }
1650
1651 float havocbot_resetgoal(entity this)
1652 {
1653         navigation_clearroute(this);
1654         return CMD_STATUS_FINISHED;
1655 }
1656
1657 void havocbot_setupbot(entity this)
1658 {
1659         this.bot_ai = havocbot_ai;
1660         this.cmd_moveto = havocbot_moveto;
1661         this.cmd_resetgoal = havocbot_resetgoal;
1662
1663         // NOTE: bot is not player yet
1664         havocbot_chooserole(this);
1665 }
1666
1667 vector havocbot_dodge(entity this)
1668 {
1669         // LordHavoc: disabled because this is too expensive
1670         return '0 0 0';
1671 #if 0
1672         entity head;
1673         vector dodge, v, n;
1674         float danger, bestdanger, vl, d;
1675         dodge = '0 0 0';
1676         bestdanger = -20;
1677         // check for dangerous objects near bot or approaching bot
1678         head = findchainfloat(bot_dodge, true);
1679         while(head)
1680         {
1681                 if (head.owner != this)
1682                 {
1683                         vl = vlen(head.velocity);
1684                         if (vl > autocvar_sv_maxspeed * 0.3)
1685                         {
1686                                 n = normalize(head.velocity);
1687                                 v = this.origin - head.origin;
1688                                 d = v * n;
1689                                 if (d > (0 - head.bot_dodgerating))
1690                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1691                                 {
1692                                         // calculate direction and distance from the flight path, by removing the forward axis
1693                                         v = v - (n * (v * n));
1694                                         danger = head.bot_dodgerating - vlen(v);
1695                                         if (bestdanger < danger)
1696                                         {
1697                                                 bestdanger = danger;
1698                                                 // dodge to the side of the object
1699                                                 dodge = normalize(v);
1700                                         }
1701                                 }
1702                         }
1703                         else
1704                         {
1705                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1706                                 if (bestdanger < danger)
1707                                 {
1708                                         bestdanger = danger;
1709                                         dodge = normalize(this.origin - head.origin);
1710                                 }
1711                         }
1712                 }
1713                 head = head.chain;
1714         }
1715         return dodge;
1716 #endif
1717 }