qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if (this.goalcurrent && wasfreed(this.goalcurrent))
  93         {
  94                 navigation_clearroute(this);
  95                 navigation_goalrating_timeout_force(this);
  96                 return;
  97         }
  98
  99         if(IS_DEAD(this) || STAT(FROZEN, this))
 100         {
 101                 if (this.goalcurrent)
 102                         navigation_clearroute(this);
 103                 return;
 104         }
 105
 106         havocbot_chooseenemy(this);
 107
 108         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 109         {
 110                 .entity weaponentity = weaponentities[slot];
 111                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 112                 if(this.(weaponentity).bot_chooseweapontime < time)
 113                 {
 114                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 115                         havocbot_chooseweapon(this, weaponentity);
 116                 }
 117         }
 118         havocbot_aim(this);
 119         lag_update(this);
 120
 121         if (this.bot_aimtarg)
 122         {
 123                 this.aistatus |= AI_STATUS_ATTACKING;
 124                 this.aistatus &= ~AI_STATUS_ROAMING;
 125
 126                 if(STAT(WEAPONS, this))
 127                 {
 128                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 129                         {
 130                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 131                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 132                         }
 133                         else
 134                         {
 135                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 136                                 {
 137                                         .entity weaponentity = weaponentities[slot];
 138                                         Weapon w = this.(weaponentity).m_weapon;
 139                                         if(w == WEP_Null && slot != 0)
 140                                                 continue;
 141                                         w.wr_aim(w, this, weaponentity);
 142                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 143                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 144                                 }
 145                         }
 146                 }
 147                 else
 148                 {
 149                         if(IS_PLAYER(this.bot_aimtarg))
 150                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 151                 }
 152         }
 153         else if (this.goalcurrent)
 154         {
 155                 this.aistatus |= AI_STATUS_ROAMING;
 156                 this.aistatus &= ~AI_STATUS_ATTACKING;
 157         }
 158
 159         havocbot_movetogoal(this);
 160         if (!this.bot_aimdir_executed && this.goalcurrent)
 161         {
 162                 // Heading
 163                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 164                 dir -= this.origin + this.view_ofs;
 165                 dir.z = 0;
 166                 bot_aimdir(this, dir, 0);
 167         }
 168
 169         // if the bot is not attacking, consider reloading weapons
 170         if (!(this.aistatus & AI_STATUS_ATTACKING))
 171         {
 172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 173                 {
 174                         .entity weaponentity = weaponentities[slot];
 175
 176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 177                                 continue;
 178
 179                         // we are currently holding a weapon that's not fully loaded, reload it
 180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 182                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 183
 184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 185                         // the code above executes next frame, starting the reloading then
 186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 188                         {
 189                                 FOREACH(Weapons, it != WEP_Null, {
 190                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 191                                         {
 192                                                 this.(weaponentity).m_switchweapon = it;
 193                                                 break;
 194                                         }
 195                                 });
 196                         }
 197                 }
 198         }
 199 }
 200
 201 void havocbot_keyboard_movement(entity this, vector destorg)
 202 {
 203         if(time <= this.havocbot_keyboardtime)
 204                 return;
 205
 206         float sk = skill + this.bot_moveskill;
 207         this.havocbot_keyboardtime =
 208                 max(
 209                         this.havocbot_keyboardtime
 210                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 211                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 212                 , time);
 213         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 214
 215         float trigger = autocvar_bot_ai_keyboard_threshold;
 216
 217         // categorize forward movement
 218         // at skill < 1.5 only forward
 219         // at skill < 2.5 only individual directions
 220         // at skill < 4.5 only individual directions, and forward diagonals
 221         // at skill >= 4.5, all cases allowed
 222         if (keyboard.x > trigger)
 223         {
 224                 keyboard.x = 1;
 225                 if (sk < 2.5)
 226                         keyboard.y = 0;
 227         }
 228         else if (keyboard.x < -trigger && sk > 1.5)
 229         {
 230                 keyboard.x = -1;
 231                 if (sk < 4.5)
 232                         keyboard.y = 0;
 233         }
 234         else
 235         {
 236                 keyboard.x = 0;
 237                 if (sk < 1.5)
 238                         keyboard.y = 0;
 239         }
 240         if (sk < 4.5)
 241                 keyboard.z = 0;
 242
 243         if (keyboard.y > trigger)
 244                 keyboard.y = 1;
 245         else if (keyboard.y < -trigger)
 246                 keyboard.y = -1;
 247         else
 248                 keyboard.y = 0;
 249
 250         if (keyboard.z > trigger)
 251                 keyboard.z = 1;
 252         else if (keyboard.z < -trigger)
 253                 keyboard.z = -1;
 254         else
 255                 keyboard.z = 0;
 256
 257         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 258         if (keyboard == '0 0 0')
 259                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 260
 261         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 262         if (this.havocbot_ducktime > time)
 263                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 264
 265         keyboard = this.havocbot_keyboard;
 266         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 267         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 268         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 269 }
 270
 271 void havocbot_bunnyhop(entity this, vector dir)
 272 {
 273         // Don't jump when attacking
 274         if(this.aistatus & AI_STATUS_ATTACKING)
 275                 return;
 276
 277         if (!this.goalcurrent || IS_PLAYER(this.goalcurrent))
 278                 return;
 279
 280         if((this.aistatus & AI_STATUS_RUNNING) && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 281                 || (this.aistatus & AI_STATUS_DANGER_AHEAD))
 282         {
 283                 this.aistatus &= ~AI_STATUS_RUNNING;
 284                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 285                 this.bot_canruntogoal = 0;
 286                 this.bot_timelastseengoal = 0;
 287                 return;
 288         }
 289
 290         if(this.waterlevel > WATERLEVEL_WETFEET || IS_DUCKED(this))
 291         {
 292                 this.aistatus &= ~AI_STATUS_RUNNING;
 293                 return;
 294         }
 295
 296         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 297         {
 298                 this.bot_canruntogoal = 0;
 299                 this.bot_timelastseengoal = 0;
 300         }
 301
 302         // Run only to visible goals
 303         if(IS_ONGROUND(this))
 304         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed))
 305         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 306         {
 307                 this.bot_lastseengoal = this.goalcurrent;
 308
 309                 // seen it before
 310                 if(this.bot_timelastseengoal)
 311                 {
 312                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 313                         // for a period of time
 314                         if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 315                         {
 316                                 bool checkdistance = true;
 317
 318                                 // don't run if it is too close
 319                                 if(this.bot_canruntogoal==0)
 320                                 {
 321                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_startdistance))
 322                                                 this.bot_canruntogoal = 1;
 323                                         else
 324                                                 this.bot_canruntogoal = -1;
 325                                 }
 326
 327                                 if(this.bot_canruntogoal != 1)
 328                                         return;
 329
 330                                 if(this.aistatus & AI_STATUS_ROAMING)
 331                                 if(this.goalcurrent.classname == "waypoint")
 332                                 if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 333                                 if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 334                                 if (this.goalstack01 && !wasfreed(this.goalstack01))
 335                                 if (!(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP))
 336                                 {
 337                                         vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 338                                         vector deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 339                                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 340                                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 341
 342                                         if(fabs(deviation.y) < 20)
 343                                         if(vlen2(this.origin - gco) < vlen2(this.origin - gno))
 344                                         if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 345                                         {
 346                                                 if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 347                                                 if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 348                                                 {
 349                                                         checkdistance = false;
 350                                                 }
 351                                         }
 352                                 }
 353
 354                                 if(checkdistance)
 355                                 {
 356                                         this.aistatus &= ~AI_STATUS_RUNNING;
 357                                         // increase stop distance in case the goal is on a slope or a lower platform
 358                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z)))
 359                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 360                                 }
 361                                 else
 362                                 {
 363                                         this.aistatus |= AI_STATUS_RUNNING;
 364                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 365                                 }
 366                         }
 367                 }
 368                 else
 369                 {
 370                         this.bot_timelastseengoal = time;
 371                 }
 372         }
 373         else
 374         {
 375                 this.bot_timelastseengoal = 0;
 376         }
 377 }
 378
 379 // return true when bot isn't getting closer to the current goal
 380 bool havocbot_checkgoaldistance(entity this, vector gco)
 381 {
 382         if (this.bot_stop_moving_timeout > time)
 383                 return false;
 384         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 385         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 386         float distance_time = this.goalcurrent_distance_time;
 387         if(distance_time < 0)
 388                 distance_time = -distance_time;
 389         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 390         {
 391                 if(!distance_time)
 392                         this.goalcurrent_distance_time = time;
 393                 else if (time - distance_time > 0.5)
 394                         return true;
 395         }
 396         else
 397         {
 398                 // reduce it a little bit so it works even with very small approaches to the goal
 399                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 400                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 401                 this.goalcurrent_distance_time = 0;
 402         }
 403         return false;
 404 }
 405
 406 entity havocbot_select_an_item_of_group(entity this, int gr)
 407 {
 408         entity selected = NULL;
 409         float selected_dist2 = 0;
 410         // select farthest item of this group from bot's position
 411         IL_EACH(g_items, it.item_group == gr && it.solid,
 412         {
 413                 float dist2 = vlen2(this.origin - it.origin);
 414                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 415                 {
 416                         selected = it;
 417                         selected_dist2 = vlen2(this.origin - selected.origin);
 418                 }
 419         });
 420
 421         if (!selected)
 422                 return NULL;
 423
 424         set_tracewalk_dest(selected, this.origin, false);
 425         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 426                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 427         {
 428                 return NULL;
 429         }
 430
 431         return selected;
 432 }
 433
 434 void havocbot_movetogoal(entity this)
 435 {
 436         vector diff;
 437         vector dir;
 438         vector flatdir;
 439         float dodge_enemy_factor = 1;
 440         float maxspeed;
 441         //float dist;
 442         vector dodge;
 443         //if (this.goalentity)
 444         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 445         CS(this).movement = '0 0 0';
 446         maxspeed = autocvar_sv_maxspeed;
 447
 448         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 449
 450         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 451         // Jetpack navigation
 452         if(this.navigation_jetpack_goal)
 453         if(this.goalcurrent==this.navigation_jetpack_goal)
 454         if(GetResource(this, RES_FUEL))
 455         {
 456                 if(autocvar_bot_debug_goalstack)
 457                 {
 458                         debuggoalstack(this);
 459                         te_wizspike(this.navigation_jetpack_point);
 460                 }
 461
 462                 // Take off
 463                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 464                 {
 465                         // Brake almost completely so it can get a good direction
 466                         if(vdist(this.velocity, >, 10))
 467                                 return;
 468                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 469                 }
 470
 471                 makevectors(this.v_angle.y * '0 1 0');
 472                 dir = normalize(this.navigation_jetpack_point - this.origin);
 473
 474                 // Landing
 475                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 476                 {
 477                         // Calculate brake distance in xy
 478                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 479                         float vel2 = vlen2(vec2(this.velocity));
 480                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 481                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 482                         if(d < db || d < 500)
 483                         {
 484                                 // Brake
 485                                 if (vel2 > (maxspeed * 0.3) ** 2)
 486                                 {
 487                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 488                                         return;
 489                                 }
 490                                 // Switch to normal mode
 491                                 this.navigation_jetpack_goal = NULL;
 492                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 493                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 494                                 return;
 495                         }
 496                 }
 497                 else if(checkpvs(this.origin,this.goalcurrent))
 498                 {
 499                         // If I can see the goal switch to landing code
 500                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 501                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 502                         return;
 503                 }
 504
 505                 // Flying
 506                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 507                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 508                 {
 509                         CS(this).movement_x = dir * v_forward * maxspeed;
 510                         CS(this).movement_y = dir * v_right * maxspeed;
 511                 }
 512                 return;
 513         }
 514
 515         // Handling of jump pads
 516         if(this.jumppadcount)
 517         {
 518                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 519                 {
 520                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 521                         if(navigation_poptouchedgoals(this))
 522                                 return;
 523                 }
 524                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 525                 {
 526                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 527                         // but with some randomness so it can try out different paths
 528                         if(!this.goalcurrent)
 529                         {
 530                                 entity newgoal = NULL;
 531                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 532                                 {
 533                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 534                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 535                                                 continue;
 536
 537                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 538
 539                                         if(trace_fraction < 1)
 540                                                 continue;
 541
 542                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 543                                                 newgoal = it;
 544                                 });
 545
 546                                 if(newgoal)
 547                                 {
 548                                         this.ignoregoal = this.goalcurrent;
 549                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 550                                         navigation_clearroute(this);
 551                                         navigation_routetogoal(this, newgoal, this.origin);
 552                                         if(autocvar_bot_debug_goalstack)
 553                                                 debuggoalstack(this);
 554                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 555                                 }
 556                         }
 557                         else //if (this.goalcurrent)
 558                         {
 559                                 if (this.goalcurrent.bot_pickup)
 560                                 {
 561                                         entity jumppad_wp = this.goalcurrent_prev;
 562                                         navigation_poptouchedgoals(this);
 563                                         if(!this.goalcurrent && jumppad_wp.wp00)
 564                                         {
 565                                                 // head to the jumppad destination once bot reaches the goal item
 566                                                 navigation_pushroute(this, jumppad_wp.wp00);
 567                                         }
 568                                 }
 569                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 570                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 571                                 {
 572                                         if (this.velocity.z < 0)
 573                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 574                                 }
 575                                 else if(havocbot_checkgoaldistance(this, gco))
 576                                 {
 577                                         navigation_clearroute(this);
 578                                         navigation_goalrating_timeout_force(this);
 579                                 }
 580                                 else
 581                                         return;
 582                         }
 583                 }
 584                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 585                 {
 586                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 587                         {
 588                                 vector velxy = this.velocity; velxy_z = 0;
 589                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 590                                 {
 591                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 592                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 593                                 }
 594                                 return;
 595                         }
 596
 597                         // Don't chase players while using a jump pad
 598                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 599                                 return;
 600                 }
 601         }
 602         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 603                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 604
 605         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 606         if (skill > 6 && !(IS_ONGROUND(this)))
 607         {
 608                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 609                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 610                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 611
 612                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 613                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 614                 if(this.items & IT_JETPACK)
 615                 {
 616                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 617                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 618                         {
 619                                 if(this.velocity.z<0)
 620                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 621                         }
 622                         else
 623                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 624
 625                         // If there is no goal try to move forward
 626
 627                         if(this.goalcurrent==NULL)
 628                                 dir = v_forward;
 629                         else
 630                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 631
 632                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 633                         float xyspeed = xyvelocity * dir;
 634
 635                         if(xyspeed < (maxspeed / 2))
 636                         {
 637                                 makevectors(this.v_angle.y * '0 1 0');
 638                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 639                                 if(trace_fraction==1)
 640                                 {
 641                                         CS(this).movement_x = dir * v_forward * maxspeed;
 642                                         CS(this).movement_y = dir * v_right * maxspeed;
 643                                         if (skill < 10)
 644                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 645                                 }
 646                         }
 647
 648                         this.havocbot_blockhead = true;
 649
 650                         return;
 651                 }
 652                 else if(!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 653                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 654                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 655                 {
 656                         if(this.velocity.z < 0)
 657                         {
 658                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 659                                 {
 660                                         .entity weaponentity = weaponentities[slot];
 661
 662                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 663                                                 continue;
 664
 665                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 666                                         {
 667                                                 CS(this).movement_x = maxspeed;
 668
 669                                                 if(this.rocketjumptime)
 670                                                 {
 671                                                         if(time > this.rocketjumptime)
 672                                                         {
 673                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 674                                                                 this.rocketjumptime = 0;
 675                                                         }
 676                                                         return;
 677                                                 }
 678
 679                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 680                                                 this.v_angle_x = 90;
 681                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 682                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 683                                                 return;
 684                                         }
 685                                 }
 686                         }
 687                 }
 688                 else
 689                 {
 690                         // If there is no goal try to move forward
 691                         if(this.goalcurrent==NULL)
 692                                 CS(this).movement_x = maxspeed;
 693                 }
 694         }
 695
 696         // If we are under water with no goals, swim up
 697         if(this.waterlevel && !this.goalcurrent)
 698         {
 699                 dir = '0 0 0';
 700                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 701                         dir.z = 1;
 702                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 703                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 704                 else
 705                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 706                 makevectors(this.v_angle.y * '0 1 0');
 707                 vector v = dir * maxspeed;
 708                 CS(this).movement.x = v * v_forward;
 709                 CS(this).movement.y = v * v_right;
 710                 CS(this).movement.z = v * v_up;
 711         }
 712
 713         // if there is nowhere to go, exit
 714         if (this.goalcurrent == NULL)
 715                 return;
 716
 717
 718         bool locked_goal = false;
 719         if((this.goalentity && wasfreed(this.goalentity))
 720                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 721         {
 722                 navigation_clearroute(this);
 723                 navigation_goalrating_timeout_force(this);
 724                 return;
 725         }
 726         else if(this.goalentity.tag_entity)
 727         {
 728                 navigation_goalrating_timeout_expire(this, 2);
 729         }
 730         else if(this.goalentity.bot_pickup)
 731         {
 732                 if(this.goalentity.bot_pickup_respawning)
 733                 {
 734                         if(this.goalentity.solid) // item respawned
 735                                 this.goalentity.bot_pickup_respawning = false;
 736                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 737                         {
 738                                 if(checkpvs(this.origin, this.goalentity))
 739                                 {
 740                                         this.goalentity.bot_pickup_respawning = false;
 741                                         navigation_goalrating_timeout_expire(this, random());
 742                                 }
 743                                 locked_goal = true; // wait for item to respawn
 744                         }
 745                         else if(this.goalentity == this.goalcurrent)
 746                                 locked_goal = true; // wait for item to respawn
 747                 }
 748                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 749                 {
 750                         if(checkpvs(this.origin, this.goalentity))
 751                         {
 752                                 navigation_goalrating_timeout_expire(this, random());
 753                         }
 754                 }
 755         }
 756         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 757                 locked_goal = true;
 758
 759         if (navigation_shortenpath(this))
 760         {
 761                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 762                         && navigation_goalrating_timeout_can_be_anticipated(this))
 763                 {
 764                         navigation_goalrating_timeout_force(this);
 765                 }
 766         }
 767
 768         bool goalcurrent_can_be_removed = false;
 769         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 770         {
 771                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 772                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 773                 {
 774                         goalcurrent_can_be_removed = true;
 775                         // don't remove if not visible
 776                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 777                         {
 778                                 if (IS_DEAD(this.goalcurrent))
 779                                 {
 780                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 781                                         {
 782                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 783                                                 {
 784                                                         navigation_clearroute(this);
 785                                                         navigation_pushroute(this, it);
 786                                                         // loot can't be immediately rated since it isn't on ground yet
 787                                                         // it will be rated after a second when on ground, meanwhile head to it
 788                                                         navigation_goalrating_timeout_expire(this, 1);
 789                                                         return;
 790                                                 }
 791                                         });
 792                                 }
 793                                 if (!Item_IsLoot(this.goalcurrent))
 794                                 {
 795                                         navigation_goalrating_timeout_force(this);
 796                                         return;
 797                                 }
 798                         }
 799                 }
 800                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 801                 {
 802                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 803                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 804                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 805                         {
 806                                 navigation_goalrating_timeout_force(this);
 807                                 return;
 808                         }
 809                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 810                 }
 811         }
 812
 813         if(!locked_goal)
 814         {
 815                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 816                 // in this case path finding can start directly from a waypoint instead of
 817                 // looking for all the reachable waypoints up to a certain distance
 818                 if (navigation_poptouchedgoals(this))
 819                 {
 820                         if (this.goalcurrent)
 821                         {
 822                                 if (goalcurrent_can_be_removed)
 823                                 {
 824                                         // remove even if not visible
 825                                         navigation_goalrating_timeout_force(this);
 826                                         return;
 827                                 }
 828                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 829                                         navigation_goalrating_timeout_force(this);
 830                         }
 831                         else
 832                         {
 833                                 entity old_goal = this.goalcurrent_prev;
 834                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 835                                 {
 836                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 837                                         // item of the group by telling the bot to head directly to the farthest item.
 838                                         // Next time we let the bot select a goal as usual which can be another item
 839                                         // of this group (the closest one) and so on
 840                                         this.item_group = old_goal.item_group;
 841                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 842                                         if (new_goal)
 843                                                 navigation_pushroute(this, new_goal);
 844                                 }
 845                         }
 846                 }
 847         }
 848
 849         // if ran out of goals try to use an alternative goal or get a new strategy asap
 850         if(this.goalcurrent == NULL)
 851         {
 852                 navigation_goalrating_timeout_force(this);
 853                 return;
 854         }
 855
 856
 857         if(autocvar_bot_debug_goalstack)
 858                 debuggoalstack(this);
 859
 860         bool bunnyhop_forbidden = false;
 861         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 862         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 863         {
 864                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 865                 destorg = this.goalcurrent.origin;
 866         }
 867         else if (this.goalcurrent.wpisbox)
 868         {
 869                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 870                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 871                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 872                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 873                 {
 874                         bunnyhop_forbidden = true;
 875                         destorg = this.goalcurrent.origin;
 876                         if(destorg.z > this.origin.z)
 877                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 878                 }
 879         }
 880
 881         diff = destorg - this.origin;
 882
 883         if (time < this.bot_stop_moving_timeout
 884                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 885         {
 886                 // stop if the locked goal has been reached
 887                 destorg = this.origin;
 888                 diff = dir = '0 0 0';
 889         }
 890         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 891         {
 892                 if (vdist(diff, <, 80))
 893                 {
 894                         // stop if too close to target player (even if frozen)
 895                         destorg = this.origin;
 896                         diff = dir = '0 0 0';
 897                 }
 898                 else
 899                 {
 900                         // move destorg out of target players, otherwise bot will consider them
 901                         // an obstacle that needs to be jumped (especially if frozen)
 902                         dir = normalize(diff);
 903                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 904                         diff = destorg - this.origin;
 905                 }
 906         }
 907         else
 908                 dir = normalize(diff);
 909         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 910
 911         vector evadeobstacle = '0 0 0';
 912         vector evadelava = '0 0 0';
 913
 914         //if (this.bot_dodgevector_time < time)
 915         {
 916                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 917                 //this.bot_dodgevector_jumpbutton = 1;
 918
 919                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 920                 makevectors(this.v_angle.y * '0 1 0');
 921                 if (this.waterlevel > WATERLEVEL_WETFEET)
 922                 {
 923                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 924                         {
 925                                 if(!this.goalcurrent)
 926                                         this.aistatus |= AI_STATUS_OUT_WATER;
 927                                 else if(destorg.z > this.origin.z)
 928                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 929                         }
 930                         else
 931                         {
 932                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 933                                         (this.aistatus & AI_STATUS_OUT_WATER))
 934                                 {
 935                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 936                                         dir = flatdir;
 937                                 }
 938                                 else
 939                                 {
 940                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 941                                         if (destorg.z > this.origin.z)
 942                                                 dir = flatdir;
 943                                 }
 944                         }
 945                 }
 946                 else
 947                 {
 948                         float s;
 949                         vector offset;
 950                         if(this.aistatus & AI_STATUS_OUT_WATER)
 951                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 952
 953                         // jump if going toward an obstacle that doesn't look like stairs we
 954                         // can walk up directly
 955                         vector deviation = '0 0 0';
 956                         float current_speed = vlen(vec2(this.velocity));
 957                         if (current_speed < maxspeed * 0.2)
 958                                 current_speed = maxspeed * 0.2;
 959                         else
 960                         {
 961                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 962                                 while (deviation.y < -180) deviation.y += 360;
 963                                 while (deviation.y > 180) deviation.y -= 360;
 964                         }
 965                         float turning = false;
 966                         vector flat_diff = vec2(diff);
 967                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 968                         vector actual_destorg = this.origin + offset;
 969                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 970                         {
 971                                 if (time > this.bot_stop_moving_timeout
 972                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 973                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 974                                 {
 975                                         this.bot_stop_moving_timeout = time + 0.1;
 976                                 }
 977                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 978                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 979                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 980                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 981                                 )
 982                                 {
 983                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 984                                         // avoid changing route while bot is jumping a gap
 985                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
 986                                 }
 987                         }
 988                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 989                         {
 990                                 if (vlen2(flat_diff) < vlen2(offset))
 991                                 {
 992                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 993                                         {
 994                                                 // oblique warpzones need a jump otherwise bots gets stuck
 995                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 996                                         }
 997                                         else
 998                                         {
 999                                                 actual_destorg.x = destorg.x;
1000                                                 actual_destorg.y = destorg.y;
1001                                         }
1002                                 }
1003                         }
1004                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1005                         {
1006                                 actual_destorg.x = destorg.x;
1007                                 actual_destorg.y = destorg.y;
1008                         }
1009                         else if (vlen2(flat_diff) < vlen2(offset))
1010                         {
1011                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1012                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1013                                 float dist = vlen(vec2(this.origin + offset - destorg));
1014                                 // if current and next goal are close to each other make sure
1015                                 // actual_destorg isn't set beyond next_goal_org
1016                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1017                                         actual_destorg = next_goal_org;
1018                                 else
1019                                         actual_destorg = vec2(destorg) + dist * next_dir;
1020                                 actual_destorg.z = this.origin.z;
1021                                 turning = true;
1022                         }
1023
1024                         LABEL(jumpobstacle_check);
1025                         dir = flatdir = normalize(actual_destorg - this.origin);
1026
1027                         bool jump_forbidden = false;
1028                         if (!turning && fabs(deviation.y) > 50)
1029                                 jump_forbidden = true;
1030                         else if (IS_DUCKED(this))
1031                         {
1032                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1033                                 if (trace_startsolid)
1034                                         jump_forbidden = true;
1035                         }
1036
1037                         if (!jump_forbidden)
1038                         {
1039                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1040                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1041                                 {
1042                                         s = trace_fraction;
1043                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1044                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1045                                         {
1046                                                 // found an obstacle
1047                                                 if (turning && fabs(deviation.y) > 5)
1048                                                 {
1049                                                         // check if the obstacle is still there without turning
1050                                                         actual_destorg = destorg;
1051                                                         turning = false;
1052                                                         this.bot_tracewalk_time = time + 0.25;
1053                                                         goto jumpobstacle_check;
1054                                                 }
1055                                                 s = trace_fraction;
1056                                                 // don't artificially reduce max jump height in real-time
1057                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1058                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1059                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1060                                                 if (trace_fraction > s)
1061                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1062                                                 else
1063                                                 {
1064                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1065                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1066                                                         if (trace_fraction > s)
1067                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1068                                                 }
1069                                         }
1070                                 }
1071                         }
1072
1073                         // if bot for some reason doesn't get close to the current goal find another one
1074                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1075                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1076                         if(havocbot_checkgoaldistance(this, destorg))
1077                         {
1078                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1079                                 {
1080                                         navigation_clearroute(this);
1081                                         navigation_goalrating_timeout_force(this);
1082                                         return;
1083                                 }
1084
1085                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1086                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1087                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1088                                 {
1089                                         navigation_clearroute(this);
1090                                         navigation_goalrating_timeout_force(this);
1091                                         return;
1092                                 }
1093
1094                                 // give bot only another chance to prevent bot getting stuck
1095                                 // in case it thinks it can walk but actually can't
1096                                 this.goalcurrent_distance_z = FLOAT_MAX;
1097                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1098                                 this.goalcurrent_distance_time = -time; // mark second try
1099                         }
1100
1101                         // Check for water/slime/lava and dangerous edges
1102                         // (only when the bot is on the ground or jumping intentionally)
1103
1104                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1105                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1106                         {
1107                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1108                         }
1109
1110                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1111                         vector dst_ahead = this.origin + this.view_ofs + offset;
1112                         vector dst_down = dst_ahead - '0 0 3000';
1113                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1114
1115                         bool unreachable = false;
1116                         s = CONTENT_SOLID;
1117                         if (trace_fraction == 1 && !this.jumppadcount
1118                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1119                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1120                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1121                         {
1122                                 // Look downwards
1123                                 traceline(dst_ahead , dst_down, true, NULL);
1124                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1125                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1126                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1127                                 {
1128                                         s = pointcontents(trace_endpos + '0 0 1');
1129                                         if (s != CONTENT_SOLID)
1130                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1131                                                 evadelava = normalize(this.velocity) * -1;
1132                                         else if (s == CONTENT_SKY)
1133                                                 evadeobstacle = normalize(this.velocity) * -1;
1134                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1135                                         {
1136                                                 // the traceline check isn't enough but is good as optimization,
1137                                                 // when not true (most of the time) this tracebox call is avoided
1138                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1139                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1140                                                 {
1141                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1142                                                         {
1143                                                                 // the goal is probably on an upper platform, assume bot can't get there
1144                                                                 unreachable = true;
1145                                                         }
1146                                                         else
1147                                                                 evadelava = normalize(this.velocity) * -1;
1148                                                 }
1149                                         }
1150                                 }
1151                         }
1152
1153                         dir = flatdir;
1154                         evadeobstacle.z = 0;
1155                         evadelava.z = 0;
1156                         makevectors(this.v_angle.y * '0 1 0');
1157
1158                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1159                         {
1160                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1161                                 if(IS_PLAYER(this.goalcurrent))
1162                                         unreachable = true;
1163                         }
1164
1165                         // slow down if bot is in the air and goal is under it
1166                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1167                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1168                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1169                         {
1170                                 // tracebox wouldn't work when bot is still on the ledge
1171                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1172                                 if (this.origin.z - trace_endpos.z > 120)
1173                                         evadeobstacle = normalize(this.velocity) * -1;
1174                         }
1175
1176                         if(unreachable)
1177                         {
1178                                 navigation_clearroute(this);
1179                                 navigation_goalrating_timeout_force(this);
1180                                 this.ignoregoal = this.goalcurrent;
1181                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1182                         }
1183                 }
1184
1185                 dodge = havocbot_dodge(this);
1186                 if (dodge)
1187                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1188                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1189                 if (this.enemy)
1190                 {
1191                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1192                         if (IS_PLAYER(trace_ent))
1193                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1194                 }
1195         //      this.bot_dodgevector = dir;
1196         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1197         }
1198
1199         float ladder_zdir = 0;
1200         if(time < this.ladder_time)
1201         {
1202                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1203                 {
1204                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1205                                 ladder_zdir = 1;
1206                 }
1207                 else
1208                 {
1209                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1210                                 ladder_zdir = -1;
1211                 }
1212                 if (ladder_zdir)
1213                 {
1214                         if (vdist(vec2(diff), <, 40))
1215                                 dir.z = ladder_zdir * 4;
1216                         else
1217                                 dir.z = ladder_zdir * 2;
1218                         dir = normalize(dir);
1219                 }
1220         }
1221
1222         if (this.goalcurrent.wpisbox
1223                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1224         {
1225                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1226                 // head to teleport origin
1227                 dir = (this.goalcurrent.origin - this.origin);
1228                 dir.z = 0;
1229                 dir = normalize(dir);
1230         }
1231
1232         // already executed when bot targets an enemy
1233         if (!this.bot_aimdir_executed)
1234         {
1235                 if (time < this.bot_stop_moving_timeout)
1236                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1237                 else
1238                         bot_aimdir(this, dir, 0);
1239         }
1240
1241         if (!ladder_zdir)
1242         {
1243                 dir *= dodge_enemy_factor;
1244                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
1245         }
1246
1247         makevectors(this.v_angle);
1248         //dir = this.bot_dodgevector;
1249         //if (this.bot_dodgevector_jumpbutton)
1250         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1251         CS(this).movement_x = dir * v_forward * maxspeed;
1252         CS(this).movement_y = dir * v_right * maxspeed;
1253         CS(this).movement_z = dir * v_up * maxspeed;
1254
1255         // Emulate keyboard interface
1256         if (skill < 10)
1257                 havocbot_keyboard_movement(this, destorg);
1258
1259         // Bunnyhop!
1260         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1261                 havocbot_bunnyhop(this, dir);
1262
1263         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1264                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1265         if (dodge)
1266         {
1267                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1268                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1269                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1270                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1271         }
1272 }
1273
1274 entity havocbot_gettarget(entity this, bool secondary)
1275 {
1276         entity best = NULL;
1277         vector eye = CENTER_OR_VIEWOFS(this);
1278         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1279         {
1280                 vector v = CENTER_OR_VIEWOFS(it);
1281                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1282                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1283                 if(bot_shouldattack(this, it))
1284                 {
1285                         traceline(eye, v, true, this);
1286                         if (trace_ent == it || trace_fraction >= 1)
1287                                 best = it;
1288                 }
1289         });
1290
1291         return best;
1292 }
1293
1294 void havocbot_chooseenemy(entity this)
1295 {
1296         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1297         {
1298                 this.enemy = NULL;
1299                 return;
1300         }
1301         if (this.enemy)
1302         {
1303                 if (!bot_shouldattack(this, this.enemy))
1304                 {
1305                         // enemy died or something, find a new target
1306                         this.enemy = NULL;
1307                         this.havocbot_chooseenemy_finished = time;
1308                 }
1309                 else if (this.havocbot_stickenemy)
1310                 {
1311                         // tracking last chosen enemy
1312                         // if enemy is visible
1313                         // and not really really far away
1314                         // and we're not severely injured
1315                         // then keep tracking for a half second into the future
1316                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1317                         if (trace_ent == this.enemy || trace_fraction == 1)
1318                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1319                         if (GetResource(this, RES_HEALTH) > 30)
1320                         {
1321                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1322                                 this.havocbot_chooseenemy_finished = time + 0.5;
1323                                 return;
1324                         }
1325                         // enemy isn't visible, or is far away, or we're injured severely
1326                         // so stop preferring this enemy
1327                         // (it will still take a half second until a new one is chosen)
1328                         this.havocbot_stickenemy = 0;
1329                 }
1330         }
1331         if (time < this.havocbot_chooseenemy_finished)
1332                 return;
1333         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1334         vector eye = this.origin + this.view_ofs;
1335         entity best = NULL;
1336         float bestrating = 100000000;
1337
1338         // Backup hit flags
1339         int hf = this.dphitcontentsmask;
1340
1341         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1342
1343         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1344
1345         bool scan_transparent = false;
1346         bool scan_secondary_targets = false;
1347         bool have_secondary_targets = false;
1348         while(true)
1349         {
1350                 scan_secondary_targets = false;
1351 LABEL(scan_targets)
1352                 IL_EACH(g_bot_targets, it.bot_attack,
1353                 {
1354                         if(!scan_secondary_targets)
1355                         {
1356                                 if(it.classname == "misc_breakablemodel")
1357                                 {
1358                                         have_secondary_targets = true;
1359                                         continue;
1360                                 }
1361                         }
1362                         else if(it.classname != "misc_breakablemodel")
1363                                 continue;
1364
1365                         vector v = (it.absmin + it.absmax) * 0.5;
1366                         float rating = vlen2(v - eye);
1367                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1368                         if (bestrating > rating)
1369                         if (bot_shouldattack(this, it))
1370                         {
1371                                 traceline(eye, v, true, this);
1372                                 if (trace_ent == it || trace_fraction >= 1)
1373                                 {
1374                                         best = it;
1375                                         bestrating = rating;
1376                                 }
1377                         }
1378                 });
1379
1380                 if(!best && have_secondary_targets && !scan_secondary_targets)
1381                 {
1382                         scan_secondary_targets = true;
1383                         // restart the loop
1384                         bestrating = 100000000;
1385                         goto scan_targets;
1386                 }
1387
1388                 // I want to do a second scan if no enemy was found or I don't have weapons
1389                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1390                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1391                         break;
1392                 if(scan_transparent)
1393                         break;
1394
1395                 // Set flags to see through transparent objects
1396                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1397
1398                 scan_transparent = true;
1399         }
1400
1401         // Restore hit flags
1402         this.dphitcontentsmask = hf;
1403
1404         this.enemy = best;
1405         this.havocbot_stickenemy = true;
1406         if(best && best.classname == "misc_breakablemodel")
1407                 this.havocbot_stickenemy = false;
1408 }
1409
1410 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1411 {
1412         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1413         // so skip this for them, or they'll never get to reload their weapons at all.
1414         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1415         if(skill < 5)
1416                 return false;
1417
1418         // if this weapon is scheduled for reloading, don't switch to it during combat
1419         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1420         {
1421                 FOREACH(Weapons, it != WEP_Null, {
1422                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1423                                 return true; // other weapon available
1424                 });
1425         }
1426
1427         return false;
1428 }
1429
1430 void havocbot_chooseweapon(entity this, .entity weaponentity)
1431 {
1432         int i;
1433
1434         // ;)
1435         if(g_weaponarena_weapons == WEPSET(TUBA))
1436         {
1437                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1438                 return;
1439         }
1440
1441         // TODO: clean this up by moving it to weapon code
1442         if(this.enemy==NULL)
1443         {
1444                 // If no weapon was chosen get the first available weapon
1445                 if(this.(weaponentity).m_weapon==WEP_Null)
1446                 FOREACH(Weapons, it != WEP_Null, {
1447                         if(client_hasweapon(this, it, weaponentity, true, false))
1448                         {
1449                                 this.(weaponentity).m_switchweapon = it;
1450                                 return;
1451                         }
1452                 });
1453                 return;
1454         }
1455
1456         // Do not change weapon during the next second after a combo
1457         float f = time - this.lastcombotime;
1458         if(f < 1)
1459                 return;
1460
1461         float w;
1462         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1463
1464         // Should it do a weapon combo?
1465         float af, ct, combo_time, combo;
1466
1467         af = ATTACK_FINISHED(this, weaponentity);
1468         ct = autocvar_bot_ai_weapon_combo_threshold;
1469
1470         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1471         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1472         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1473
1474         combo = false;
1475
1476         if(autocvar_bot_ai_weapon_combo)
1477         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1478         if(af > combo_time)
1479         {
1480                 combo = true;
1481                 this.lastcombotime = time;
1482         }
1483
1484         distance *= (2 ** this.bot_rangepreference);
1485
1486         // Custom weapon list based on distance to the enemy
1487         if(bot_custom_weapon){
1488
1489                 // Choose weapons for far distance
1490                 if ( distance > bot_distance_far ) {
1491                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1492                                 w = bot_weapons_far[i];
1493                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1494                                 {
1495                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1496                                                 continue;
1497                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1498                                         return;
1499                                 }
1500                         }
1501                 }
1502
1503                 // Choose weapons for mid distance
1504                 if ( distance > bot_distance_close) {
1505                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1506                                 w = bot_weapons_mid[i];
1507                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1508                                 {
1509                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1510                                                 continue;
1511                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1512                                         return;
1513                                 }
1514                         }
1515                 }
1516
1517                 // Choose weapons for close distance
1518                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1519                         w = bot_weapons_close[i];
1520                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1521                         {
1522                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1523                                         continue;
1524                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1525                                 return;
1526                         }
1527                 }
1528         }
1529 }
1530
1531 void havocbot_aim(entity this)
1532 {
1533         if (time < this.nextaim)
1534                 return;
1535         this.nextaim = time + 0.1;
1536         vector myvel = this.velocity;
1537         if (!this.waterlevel)
1538                 myvel.z = 0;
1539         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1540         else if (this.enemy)
1541         {
1542                 vector enemyvel = this.enemy.velocity;
1543                 if (!this.enemy.waterlevel)
1544                         enemyvel.z = 0;
1545                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1546         }
1547         else
1548                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1549 }
1550
1551 bool havocbot_moveto_refresh_route(entity this)
1552 {
1553         // Refresh path to goal if necessary
1554         entity wp;
1555         wp = this.havocbot_personal_waypoint;
1556         navigation_goalrating_start(this);
1557         navigation_routerating(this, wp, 10000, 10000);
1558         navigation_goalrating_end(this);
1559         return (this.goalentity != NULL);
1560 }
1561
1562 float havocbot_moveto(entity this, vector pos)
1563 {
1564         entity wp;
1565
1566         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1567         {
1568                 // Step 4: Move to waypoint
1569                 if(this.havocbot_personal_waypoint==NULL)
1570                 {
1571                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1572                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1573                         return CMD_STATUS_ERROR;
1574                 }
1575
1576                 if (!bot_strategytoken_taken)
1577                 if(this.havocbot_personal_waypoint_searchtime<time)
1578                 {
1579                         bot_strategytoken_taken = true;
1580                         if(havocbot_moveto_refresh_route(this))
1581                         {
1582                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1583                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1584                                 this.havocbot_personal_waypoint_failcounter = 0;
1585                         }
1586                         else
1587                         {
1588                                 this.havocbot_personal_waypoint_failcounter += 1;
1589                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1590                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1591                                 {
1592                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1593                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1594                                         delete(this.havocbot_personal_waypoint);
1595                                         return CMD_STATUS_ERROR;
1596                                 }
1597                                 else
1598                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1599                         }
1600                 }
1601
1602                 if(autocvar_bot_debug_goalstack)
1603                         debuggoalstack(this);
1604
1605
1606                 // Go!
1607                 havocbot_movetogoal(this);
1608
1609                 if (!this.bot_aimdir_executed && this.goalcurrent)
1610                 {
1611                         // Heading
1612                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1613                         dir -= this.origin + this.view_ofs;
1614                         dir.z = 0;
1615                         bot_aimdir(this, dir, 0);
1616                 }
1617
1618                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1619                 {
1620                         // Step 5: Waypoint reached
1621                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1622                         waypoint_remove(this.havocbot_personal_waypoint);
1623                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1624                         return CMD_STATUS_FINISHED;
1625                 }
1626
1627                 return CMD_STATUS_EXECUTING;
1628         }
1629
1630         // Step 2: Linking waypoint
1631         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1632         {
1633                 // Wait until it is linked
1634                 if(!this.havocbot_personal_waypoint.wplinked)
1635                 {
1636                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1637                         return CMD_STATUS_EXECUTING;
1638                 }
1639
1640                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1641                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1642                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1643
1644                 // Step 3: Route to waypoint
1645                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1646
1647                 return CMD_STATUS_EXECUTING;
1648         }
1649
1650         // Step 1: Spawning waypoint
1651         wp = waypoint_spawnpersonal(this, pos);
1652         if(wp==NULL)
1653         {
1654                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1655                 return CMD_STATUS_ERROR;
1656         }
1657
1658         this.havocbot_personal_waypoint = wp;
1659         this.havocbot_personal_waypoint_failcounter = 0;
1660         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1661
1662         // if pos is inside a teleport, then let's mark it as teleport waypoint
1663         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1664         {
1665                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1666                 this.lastteleporttime = 0;
1667         });
1668
1669 /*
1670         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1671                 print("routing to a teleporter\n");
1672         else
1673                 print("routing to a non-teleporter\n");
1674 */
1675
1676         return CMD_STATUS_EXECUTING;
1677 }
1678
1679 float havocbot_resetgoal(entity this)
1680 {
1681         navigation_clearroute(this);
1682         return CMD_STATUS_FINISHED;
1683 }
1684
1685 void havocbot_setupbot(entity this)
1686 {
1687         this.bot_ai = havocbot_ai;
1688         this.cmd_moveto = havocbot_moveto;
1689         this.cmd_resetgoal = havocbot_resetgoal;
1690
1691         // NOTE: bot is not player yet
1692         havocbot_chooserole(this);
1693 }
1694
1695 vector havocbot_dodge(entity this)
1696 {
1697         // LordHavoc: disabled because this is too expensive
1698         return '0 0 0';
1699 #if 0
1700         entity head;
1701         vector dodge, v, n;
1702         float danger, bestdanger, vl, d;
1703         dodge = '0 0 0';
1704         bestdanger = -20;
1705         // check for dangerous objects near bot or approaching bot
1706         head = findchainfloat(bot_dodge, true);
1707         while(head)
1708         {
1709                 if (head.owner != this)
1710                 {
1711                         vl = vlen(head.velocity);
1712                         if (vl > autocvar_sv_maxspeed * 0.3)
1713                         {
1714                                 n = normalize(head.velocity);
1715                                 v = this.origin - head.origin;
1716                                 d = v * n;
1717                                 if (d > (0 - head.bot_dodgerating))
1718                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1719                                 {
1720                                         // calculate direction and distance from the flight path, by removing the forward axis
1721                                         v = v - (n * (v * n));
1722                                         danger = head.bot_dodgerating - vlen(v);
1723                                         if (bestdanger < danger)
1724                                         {
1725                                                 bestdanger = danger;
1726                                                 // dodge to the side of the object
1727                                                 dodge = normalize(v);
1728                                         }
1729                                 }
1730                         }
1731                         else
1732                         {
1733                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1734                                 if (bestdanger < danger)
1735                                 {
1736                                         bestdanger = danger;
1737                                         dodge = normalize(this.origin - head.origin);
1738                                 }
1739                         }
1740                 }
1741                 head = head.chain;
1742         }
1743         return dodge;
1744 #endif
1745 }