qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27
  28         entity e2 = navigation_findnearestwaypoint(pl, false);
  29         if(!e2)
  30         {
  31                 LOG_INFOF("Can't find any waypoint nearby\n");
  32                 return;
  33         }
  34
  35         navigation_markroutes(pl, e2);
  36
  37         int j = 0;
  38         int m = 0;
  39         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  40         {
  41                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  42                 it.colormod_z = 8;
  43                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  44                 j++;
  45                 m++;
  46         });
  47         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  48         navigation_markroutes_inverted(e2);
  49
  50         j = 0;
  51         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  52         {
  53                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  54                 it.colormod_x = 8;
  55                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  56                         m++;
  57                 it.effects |= EF_NODEPTHTEST | EF_RED;
  58                 j++;
  59         });
  60         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  61         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  62
  63         j = 0;
  64         IL_EACH(g_spawnpoints, true,
  65         {
  66                 if (navigation_findnearestwaypoint(it, false))
  67                 {
  68                         if(it.spawnpointmodel)
  69                         {
  70                                 delete(it.spawnpointmodel);
  71                                 it.spawnpointmodel = NULL;
  72                         }
  73                 }
  74                 else
  75                 {
  76                         if(!it.spawnpointmodel)
  77                         {
  78                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  79                                 entity e = new(spawnpointmodel);
  80                                 vector org = trace_endpos + eZ;
  81                                 setorigin(e, org);
  82                                 e.solid = SOLID_TRIGGER;
  83                                 it.spawnpointmodel = e;
  84                         }
  85                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  86                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  87                         _setmodel(it.spawnpointmodel, pl.model);
  88                         it.spawnpointmodel.frame = pl.frame;
  89                         it.spawnpointmodel.skin = pl.skin;
  90                         it.spawnpointmodel.colormap = pl.colormap;
  91                         it.spawnpointmodel.colormod = pl.colormod;
  92                         it.spawnpointmodel.glowmod = pl.glowmod;
  93                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  94                         j++;
  95                 }
  96         });
  97         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  98
  99         j = 0;
 100         IL_EACH(g_items, true,
 101         {
 102                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 103                 it.colormod = '0.5 0.5 0.5';
 104         });
 105         IL_EACH(g_items, true,
 106         {
 107                 if (navigation_findnearestwaypoint(it, false))
 108                         continue;
 109                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 110                 it.effects |= EF_NODEPTHTEST | EF_RED;
 111                 it.colormod_x = 8;
 112                 j++;
 113         });
 114         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 115
 116         j = 0;
 117         IL_EACH(g_items, true,
 118         {
 119                 if (navigation_findnearestwaypoint(it, true))
 120                         continue;
 121                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 122                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 123                 it.colormod_z = 8;
 124                 j++;
 125         });
 126         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 127 }
 128
 129 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 130 {
 131         vector new_org = org;
 132         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 133         {
 134                 vector map_center = havocbot_middlepoint;
 135                 if (autocvar_g_waypointeditor_symmetrical == -1)
 136                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 137
 138                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 139         }
 140         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 141         {
 142                 float m = havocbot_symmetryaxis_equation.x;
 143                 float q = havocbot_symmetryaxis_equation.y;
 144                 if (autocvar_g_waypointeditor_symmetrical == -2)
 145                 {
 146                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 147                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 148                 }
 149
 150                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 151                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 152         }
 153         new_org.z = org.z;
 154         return new_org;
 155 }
 156
 157 void waypoint_setupmodel(entity wp)
 158 {
 159         if (autocvar_g_waypointeditor)
 160         {
 161                 // TODO: add some sort of visible box in edit mode for box waypoints
 162                 vector m1 = wp.mins;
 163                 vector m2 = wp.maxs;
 164                 setmodel(wp, MDL_WAYPOINT);
 165                 setsize(wp, m1, m2);
 166                 wp.effects = EF_LOWPRECISION;
 167                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 168                         wp.colormod = '1 0 0';
 169                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 170                         wp.colormod = '1 1 0';
 171                 else if (wp.wphardwired)
 172                         wp.colormod = '0.5 0 1';
 173                 else
 174                         wp.colormod = '1 1 1';
 175         }
 176         else
 177                 wp.model = "";
 178 }
 179
 180 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 181 // them back to it as well
 182 // (suitable for spawnfunc_waypoint editor)
 183 entity waypoint_spawn(vector m1, vector m2, float f)
 184 {
 185         if(!(f & WAYPOINTFLAG_PERSONAL))
 186         {
 187                 vector em1 = m1, em2 = m2;
 188                 if (!(f & WAYPOINTFLAG_GENERATED) && m1 == m2)
 189                 {
 190                         em1 = m1 - '8 8 8';
 191                         em2 = m2 + '8 8 8';
 192                 }
 193                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 194                 {
 195                         return it;
 196                 });
 197         }
 198
 199         entity w = new(waypoint);
 200         IL_PUSH(g_waypoints, w);
 201         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 202         w.wpflags = f;
 203         w.solid = SOLID_TRIGGER;
 204         setorigin(w, (m1 + m2) * 0.5);
 205         setsize(w, m1 - w.origin, m2 - w.origin);
 206         if (w.size)
 207                 w.wpisbox = true;
 208
 209         if(!w.wpisbox)
 210         {
 211                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 212                 if(!move_out_of_solid(w))
 213                 {
 214                         if(!(f & WAYPOINTFLAG_GENERATED))
 215                         {
 216                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 217                                 delete(w);
 218                                 return NULL;
 219                         }
 220                         else
 221                         {
 222                                 if(autocvar_developer)
 223                                 {
 224                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 225                                         backtrace("Waypoint stuck");
 226                                 }
 227                         }
 228                 }
 229                 setsize(w, '0 0 0', '0 0 0');
 230         }
 231
 232         waypoint_clearlinks(w);
 233         //waypoint_schedulerelink(w);
 234
 235         waypoint_setupmodel(w);
 236
 237         return w;
 238 }
 239
 240 void waypoint_spawn_fromeditor(entity pl)
 241 {
 242         entity e;
 243         vector org = pl.origin;
 244         int ctf_flags = havocbot_symmetryaxis_equation.z;
 245         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 246                    || (autocvar_g_waypointeditor_symmetrical < 0));
 247         int order = ctf_flags;
 248         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 249         {
 250                 order = autocvar_g_waypointeditor_symmetrical_order;
 251                 ctf_flags = order;
 252         }
 253
 254         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 255         {
 256                 // snap waypoint to item's origin if close enough
 257                 IL_EACH(g_items, true,
 258                 {
 259                         vector item_org = (it.absmin + it.absmax) * 0.5;
 260                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 261                         if(vlen(item_org - org) < 30)
 262                         {
 263                                 org = item_org;
 264                                 break;
 265                         }
 266                 });
 267         }
 268
 269         LABEL(add_wp);
 270         e = waypoint_spawn(org, org, 0);
 271         waypoint_schedulerelink(e);
 272         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 273         if(sym)
 274         {
 275                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 276                 if (vdist(org - pl.origin, >, 32))
 277                 {
 278                         if(order > 2)
 279                                 order--;
 280                         else
 281                                 sym = false;
 282                         goto add_wp;
 283                 }
 284         }
 285 }
 286
 287 void waypoint_remove(entity wp)
 288 {
 289         // tell all waypoints linked to wp that they need to relink
 290         IL_EACH(g_waypoints, it != wp,
 291         {
 292                 if (waypoint_islinked(it, wp))
 293                         waypoint_removelink(it, wp);
 294         });
 295         delete(wp);
 296 }
 297
 298 void waypoint_remove_fromeditor(entity pl)
 299 {
 300         entity e = navigation_findnearestwaypoint(pl, false);
 301
 302         int ctf_flags = havocbot_symmetryaxis_equation.z;
 303         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 304                    || (autocvar_g_waypointeditor_symmetrical < 0));
 305         int order = ctf_flags;
 306         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 307         {
 308                 order = autocvar_g_waypointeditor_symmetrical_order;
 309                 ctf_flags = order;
 310         }
 311
 312         LABEL(remove_wp);
 313         if (!e) return;
 314         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 315
 316         if (e.wphardwired)
 317         {
 318                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 319                 return;
 320         }
 321
 322         entity wp_sym = NULL;
 323         if (sym)
 324         {
 325                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 326                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 327                         if(vdist(org - it.origin, <, 3))
 328                         {
 329                                 wp_sym = it;
 330                                 break;
 331                         }
 332                 });
 333         }
 334
 335         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 336         waypoint_remove(e);
 337
 338         if (sym && wp_sym)
 339         {
 340                 e = wp_sym;
 341                 if(order > 2)
 342                         order--;
 343                 else
 344                         sym = false;
 345                 goto remove_wp;
 346         }
 347 }
 348
 349 void waypoint_removelink(entity from, entity to)
 350 {
 351         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 352                 return;
 353
 354         bool found = false;
 355         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 356         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 357         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 358         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 359         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 360         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 361         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 362         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 363         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 364         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 365         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 366         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 367         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 368         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 369         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 370         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 371         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 372         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 373         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 374         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 375         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 376         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 377         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 378         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 379         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 380         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 381         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 382         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 383         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 384         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 385         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 386         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 387 }
 388
 389 bool waypoint_islinked(entity from, entity to)
 390 {
 391         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 392         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 393         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 394         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 395         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 396         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 397         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 398         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 399         return false;
 400 }
 401
 402 void waypoint_updatecost_foralllinks()
 403 {
 404         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 405         {
 406                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 407                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 408                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 409                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 410                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 411                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 412                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 413                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 414                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 415                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 416                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 417                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 418                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 419                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 420                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 421                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 422                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 423                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 424                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 425                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 426                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 427                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 428                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 429                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 430                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 431                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 432                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 433                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 434                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 435                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 436                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 437                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 438         });
 439 }
 440
 441 float waypoint_getlinearcost(float dist)
 442 {
 443         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 444                 return dist / (autocvar_sv_maxspeed * 1.25);
 445         return dist / autocvar_sv_maxspeed;
 446 }
 447
 448 float waypoint_gettravelcost(vector from, vector to)
 449 {
 450         float c = waypoint_getlinearcost(vlen(to - from));
 451
 452         float height = from.z - to.z;
 453         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 454         {
 455                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 456                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 457                 if(height_cost > c)
 458                         c = height_cost;
 459         }
 460         return c;
 461 }
 462
 463 float waypoint_getlinkcost(entity from, entity to)
 464 {
 465         vector v1 = from.origin;
 466         vector v2 = to.origin;
 467         if (from.wpisbox)
 468         {
 469                 vector m1 = to.absmin, m2 = to.absmax;
 470                 v1_x = bound(m1_x, v1_x, m2_x);
 471                 v1_y = bound(m1_y, v1_y, m2_y);
 472                 v1_z = bound(m1_z, v1_z, m2_z);
 473         }
 474         if (to.wpisbox)
 475         {
 476                 vector m1 = from.absmin, m2 = from.absmax;
 477                 v2_x = bound(m1_x, v2_x, m2_x);
 478                 v2_y = bound(m1_y, v2_y, m2_y);
 479                 v2_z = bound(m1_z, v2_z, m2_z);
 480         }
 481         return waypoint_gettravelcost(v1, v2);
 482 }
 483
 484 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 485 // if c == -1 automatically determine cost of the link
 486 void waypoint_addlink_customcost(entity from, entity to, float c)
 487 {
 488         if (from == to || waypoint_islinked(from, to))
 489                 return;
 490         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 491                 return;
 492
 493         if(c == -1)
 494                 c = waypoint_getlinkcost(from, to);
 495
 496         if (from.wp31mincost < c) return;
 497         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 498         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 499         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 500         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 501         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 502         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 503         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 504         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 505         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 506         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 507         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 508         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 509         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 510         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 511         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 512         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 513         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 514         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 515         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 516         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 517         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 518         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 519         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 520         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 521         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 522         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 523         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 524         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 525         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 526         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 527         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 528         from.wp00 = to;from.wp00mincost = c;return;
 529 }
 530
 531 void waypoint_addlink(entity from, entity to)
 532 {
 533         waypoint_addlink_customcost(from, to, -1);
 534 }
 535
 536 // relink this spawnfunc_waypoint
 537 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 538 // (SLOW!)
 539 void waypoint_think(entity this)
 540 {
 541         vector sv, sm1, sm2, ev, em1, em2, dv;
 542
 543         bot_calculate_stepheightvec();
 544
 545         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 546
 547         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 548         sm1 = this.origin + this.mins;
 549         sm2 = this.origin + this.maxs;
 550         IL_EACH(g_waypoints, this != it,
 551         {
 552                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 553                 {
 554                         waypoint_addlink(this, it);
 555                         waypoint_addlink(it, this);
 556                 }
 557                 else
 558                 {
 559                         ++relink_total;
 560                         if(!checkpvs(this.origin, it))
 561                         {
 562                                 ++relink_pvsculled;
 563                                 continue;
 564                         }
 565                         sv = it.origin;
 566                         sv.x = bound(sm1_x, sv.x, sm2_x);
 567                         sv.y = bound(sm1_y, sv.y, sm2_y);
 568                         sv.z = bound(sm1_z, sv.z, sm2_z);
 569                         ev = this.origin;
 570                         em1 = it.origin + it.mins;
 571                         em2 = it.origin + it.maxs;
 572                         ev.x = bound(em1_x, ev.x, em2_x);
 573                         ev.y = bound(em1_y, ev.y, em2_y);
 574                         ev.z = bound(em1_z, ev.z, em2_z);
 575                         dv = ev - sv;
 576                         dv.z = 0;
 577                         if(vdist(dv, >=, 1050)) // max search distance in XY
 578                         {
 579                                 ++relink_lengthculled;
 580                                 continue;
 581                         }
 582                         float sv_deviation = 0;
 583                         float ev_deviation = 0;
 584                         navigation_testtracewalk = 0;
 585                         if (!this.wpisbox)
 586                         {
 587                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 588                                 if (!trace_startsolid)
 589                                 {
 590                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 591                                         sv_deviation = trace_endpos.z + 1 - sv.z;
 592                                         sv = trace_endpos + '0 0 1';
 593                                 }
 594                         }
 595                         if (!it.wpisbox)
 596                         {
 597                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 598                                 if (!trace_startsolid)
 599                                 {
 600                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 601                                         ev_deviation = trace_endpos.z + 1 - ev.z;
 602                                         ev = trace_endpos + '0 0 1';
 603                                 }
 604                         }
 605                         //traceline(this.origin, it.origin, false, NULL);
 606                         //if (trace_fraction == 1)
 607                         if (this.wpisbox)
 608                                 relink_walkculled += 0.5;
 609                         else
 610                         {
 611                                 vector dest = ev;
 612                                 dest.z = em1.z + ev_deviation;
 613                                 float dest_height = em2.z - em1.z;
 614                                 if(tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 615                                         waypoint_addlink(this, it);
 616                                 else
 617                                         relink_walkculled += 0.5;
 618                         }
 619
 620                         if (it.wpisbox)
 621                                 relink_walkculled += 0.5;
 622                         else
 623                         {
 624                                 vector dest = sv;
 625                                 dest.z = sm1.z + sv_deviation;
 626                                 float dest_height = sm2.z - sm1.z;
 627                                 if(tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 628                                         waypoint_addlink(it, this);
 629                                 else
 630                                         relink_walkculled += 0.5;
 631                         }
 632                 }
 633         });
 634         navigation_testtracewalk = 0;
 635         this.wplinked = true;
 636 }
 637
 638 void waypoint_clearlinks(entity wp)
 639 {
 640         // clear links to other waypoints
 641         float f = 10000000;
 642         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 643         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 644         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 645         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 646
 647         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 648         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 649         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 650         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 651
 652         wp.wplinked = false;
 653 }
 654
 655 // tell a spawnfunc_waypoint to relink
 656 void waypoint_schedulerelink(entity wp)
 657 {
 658         if (wp == NULL)
 659                 return;
 660
 661         waypoint_setupmodel(wp);
 662         wp.wpisbox = vdist(wp.size, >, 0);
 663         wp.enemy = NULL;
 664         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 665                 wp.owner = NULL;
 666         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 667                 waypoint_clearlinks(wp);
 668         // schedule an actual relink on next frame
 669         setthink(wp, waypoint_think);
 670         wp.nextthink = time;
 671         wp.effects = EF_LOWPRECISION;
 672 }
 673
 674 // spawnfunc_waypoint map entity
 675 spawnfunc(waypoint)
 676 {
 677         IL_PUSH(g_waypoints, this);
 678
 679         setorigin(this, this.origin);
 680         // schedule a relink after other waypoints have had a chance to spawn
 681         waypoint_clearlinks(this);
 682         //waypoint_schedulerelink(this);
 683 }
 684
 685 // tell all waypoints to relink
 686 // actually this is useful only to update relink_* stats
 687 void waypoint_schedulerelinkall()
 688 {
 689         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 690         IL_EACH(g_waypoints, true,
 691         {
 692                 waypoint_schedulerelink(it);
 693         });
 694         waypoint_load_links_hardwired();
 695 }
 696
 697 // Load waypoint links from file
 698 bool waypoint_load_links()
 699 {
 700         string filename, s;
 701         float file, tokens, c = 0, found;
 702         entity wp_from = NULL, wp_to;
 703         vector wp_to_pos, wp_from_pos;
 704         filename = strcat("maps/", mapname);
 705         filename = strcat(filename, ".waypoints.cache");
 706         file = fopen(filename, FILE_READ);
 707
 708         if (file < 0)
 709         {
 710                 LOG_TRACE("waypoint links load from ");
 711                 LOG_TRACE(filename);
 712                 LOG_TRACE(" failed");
 713                 return false;
 714         }
 715
 716         while ((s = fgets(file)))
 717         {
 718                 tokens = tokenizebyseparator(s, "*");
 719
 720                 if (tokens!=2)
 721                 {
 722                         // bad file format
 723                         fclose(file);
 724                         return false;
 725                 }
 726
 727                 wp_from_pos     = stov(argv(0));
 728                 wp_to_pos       = stov(argv(1));
 729
 730                 // Search "from" waypoint
 731                 if(!wp_from || wp_from.origin!=wp_from_pos)
 732                 {
 733                         wp_from = findradius(wp_from_pos, 1);
 734                         found = false;
 735                         while(wp_from)
 736                         {
 737                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 738                                 if(wp_from.classname == "waypoint")
 739                                 {
 740                                         found = true;
 741                                         break;
 742                                 }
 743                                 wp_from = wp_from.chain;
 744                         }
 745
 746                         if(!found)
 747                         {
 748                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 749                                 continue;
 750                         }
 751
 752                 }
 753
 754                 // Search "to" waypoint
 755                 wp_to = findradius(wp_to_pos, 1);
 756                 found = false;
 757                 while(wp_to)
 758                 {
 759                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 760                         if(wp_to.classname == "waypoint")
 761                         {
 762                                 found = true;
 763                                 break;
 764                         }
 765                         wp_to = wp_to.chain;
 766                 }
 767
 768                 if(!found)
 769                 {
 770                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 771                         continue;
 772                 }
 773
 774                 ++c;
 775                 waypoint_addlink(wp_from, wp_to);
 776         }
 777
 778         fclose(file);
 779
 780         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 781
 782         botframe_cachedwaypointlinks = true;
 783         return true;
 784 }
 785
 786 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 787 {
 788         string filename, s;
 789         float file, tokens, c = 0, found;
 790         entity wp_from = NULL, wp_to;
 791         vector wp_to_pos, wp_from_pos;
 792         filename = strcat("maps/", mapname);
 793         filename = strcat(filename, ".waypoints.hardwired");
 794         file = fopen(filename, FILE_READ);
 795
 796         botframe_loadedforcedlinks = true;
 797
 798         if (file < 0)
 799         {
 800                 if(!removal_mode)
 801                         LOG_TRACE("waypoint links load from ", filename, " failed");
 802                 return;
 803         }
 804
 805         while ((s = fgets(file)))
 806         {
 807                 if(substring(s, 0, 2)=="//")
 808                         continue;
 809
 810                 if(substring(s, 0, 1)=="#")
 811                         continue;
 812
 813                 tokens = tokenizebyseparator(s, "*");
 814
 815                 if (tokens!=2)
 816                         continue;
 817
 818                 wp_from_pos     = stov(argv(0));
 819                 wp_to_pos       = stov(argv(1));
 820
 821                 // Search "from" waypoint
 822                 if(!wp_from || wp_from.origin!=wp_from_pos)
 823                 {
 824                         wp_from = findradius(wp_from_pos, 5);
 825                         found = false;
 826                         while(wp_from)
 827                         {
 828                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 829                                 if(wp_from.classname == "waypoint")
 830                                 {
 831                                         found = true;
 832                                         break;
 833                                 }
 834                                 wp_from = wp_from.chain;
 835                         }
 836
 837                         if(!found)
 838                         {
 839                                 if(!removal_mode)
 840                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 841                                 continue;
 842                         }
 843                 }
 844
 845                 // Search "to" waypoint
 846                 wp_to = findradius(wp_to_pos, 5);
 847                 found = false;
 848                 while(wp_to)
 849                 {
 850                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 851                         if(wp_to.classname == "waypoint")
 852                         {
 853                                 found = true;
 854                                 break;
 855                         }
 856                         wp_to = wp_to.chain;
 857                 }
 858
 859                 if(!found)
 860                 {
 861                         if(!removal_mode)
 862                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 863                         continue;
 864                 }
 865
 866                 ++c;
 867                 if(removal_mode)
 868                 {
 869                         waypoint_removelink(wp_from, wp_to);
 870                         continue;
 871                 }
 872
 873                 waypoint_addlink(wp_from, wp_to);
 874                 wp_from.wphardwired = true;
 875                 wp_to.wphardwired = true;
 876         }
 877
 878         fclose(file);
 879
 880         if(!removal_mode)
 881                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 882 }
 883
 884 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 885 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 886
 887 entity waypoint_get_link(entity w, float i)
 888 {
 889         switch(i)
 890         {
 891                 case  0:return w.wp00;
 892                 case  1:return w.wp01;
 893                 case  2:return w.wp02;
 894                 case  3:return w.wp03;
 895                 case  4:return w.wp04;
 896                 case  5:return w.wp05;
 897                 case  6:return w.wp06;
 898                 case  7:return w.wp07;
 899                 case  8:return w.wp08;
 900                 case  9:return w.wp09;
 901                 case 10:return w.wp10;
 902                 case 11:return w.wp11;
 903                 case 12:return w.wp12;
 904                 case 13:return w.wp13;
 905                 case 14:return w.wp14;
 906                 case 15:return w.wp15;
 907                 case 16:return w.wp16;
 908                 case 17:return w.wp17;
 909                 case 18:return w.wp18;
 910                 case 19:return w.wp19;
 911                 case 20:return w.wp20;
 912                 case 21:return w.wp21;
 913                 case 22:return w.wp22;
 914                 case 23:return w.wp23;
 915                 case 24:return w.wp24;
 916                 case 25:return w.wp25;
 917                 case 26:return w.wp26;
 918                 case 27:return w.wp27;
 919                 case 28:return w.wp28;
 920                 case 29:return w.wp29;
 921                 case 30:return w.wp30;
 922                 case 31:return w.wp31;
 923                 default:return NULL;
 924         }
 925 }
 926
 927 // Save all waypoint links to a file
 928 void waypoint_save_links()
 929 {
 930         // temporarily remove hardwired links so they don't get saved among normal links
 931         waypoint_remove_links_hardwired();
 932
 933         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 934         int file = fopen(filename, FILE_WRITE);
 935         if (file < 0)
 936         {
 937                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 938                 return;
 939         }
 940
 941         int c = 0;
 942         IL_EACH(g_waypoints, true,
 943         {
 944                 for(int j = 0; j < 32; ++j)
 945                 {
 946                         entity link = waypoint_get_link(it, j);
 947                         if(link)
 948                         {
 949                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 950                                 fputs(file, s);
 951                                 ++c;
 952                         }
 953                 }
 954         });
 955         fclose(file);
 956         botframe_cachedwaypointlinks = true;
 957
 958         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 959
 960         waypoint_load_links_hardwired();
 961 }
 962
 963 // save waypoints to gamedir/data/maps/mapname.waypoints
 964 void waypoint_saveall()
 965 {
 966         string filename = sprintf("maps/%s.waypoints", mapname);
 967         int file = fopen(filename, FILE_WRITE);
 968         if (file < 0)
 969         {
 970                 waypoint_save_links(); // save anyway?
 971                 botframe_loadedforcedlinks = false;
 972
 973                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 974                 return;
 975         }
 976
 977         int c = 0;
 978         IL_EACH(g_waypoints, true,
 979         {
 980                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 981                         continue;
 982
 983                 string s;
 984                 s = strcat(vtos(it.origin + it.mins), "\n");
 985                 s = strcat(s, vtos(it.origin + it.maxs));
 986                 s = strcat(s, "\n");
 987                 s = strcat(s, ftos(it.wpflags));
 988                 s = strcat(s, "\n");
 989                 fputs(file, s);
 990                 c++;
 991         });
 992         fclose(file);
 993         waypoint_save_links();
 994         botframe_loadedforcedlinks = false;
 995
 996         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 997 }
 998
 999 // load waypoints from file
1000 float waypoint_loadall()
1001 {
1002         string filename, s;
1003         float file, cwp, cwb, fl;
1004         vector m1, m2;
1005         cwp = 0;
1006         cwb = 0;
1007         filename = strcat("maps/", mapname);
1008         filename = strcat(filename, ".waypoints");
1009         file = fopen(filename, FILE_READ);
1010         if (file >= 0)
1011         {
1012                 while ((s = fgets(file)))
1013                 {
1014                         m1 = stov(s);
1015                         s = fgets(file);
1016                         if (!s)
1017                                 break;
1018                         m2 = stov(s);
1019                         s = fgets(file);
1020                         if (!s)
1021                                 break;
1022                         fl = stof(s);
1023                         waypoint_spawn(m1, m2, fl);
1024                         if (m1 == m2)
1025                                 cwp = cwp + 1;
1026                         else
1027                                 cwb = cwb + 1;
1028                 }
1029                 fclose(file);
1030                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1031         }
1032         else
1033         {
1034                 LOG_TRACE("waypoint load from ", filename, " failed");
1035         }
1036         return cwp + cwb;
1037 }
1038
1039 vector waypoint_fixorigin(vector position)
1040 {
1041         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1042         if(trace_fraction < 1)
1043                 position = trace_endpos;
1044         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1045         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
1046         return position;
1047 }
1048
1049 void waypoint_spawnforitem_force(entity e, vector org)
1050 {
1051         // Fix the waypoint altitude if necessary
1052         org = waypoint_fixorigin(org);
1053
1054         // don't spawn an item spawnfunc_waypoint if it already exists
1055         IL_EACH(g_waypoints, true,
1056         {
1057                 if(it.wpisbox)
1058                 {
1059                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1060                         {
1061                                 e.nearestwaypoint = it;
1062                                 return;
1063                         }
1064                 }
1065                 else
1066                 {
1067                         if(vdist(it.origin - org, <, 16))
1068                         {
1069                                 e.nearestwaypoint = it;
1070                                 return;
1071                         }
1072                 }
1073         });
1074
1075         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1076 }
1077
1078 void waypoint_spawnforitem(entity e)
1079 {
1080         if(!bot_waypoints_for_items)
1081                 return;
1082
1083         waypoint_spawnforitem_force(e, e.origin);
1084 }
1085
1086 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1087 {
1088         entity w;
1089         entity dw;
1090         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1091         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1092         // one way link to the destination
1093         w.wp00 = dw;
1094         w.wp00mincost = timetaken; // this is just for jump pads
1095         // the teleporter's nearest spawnfunc_waypoint is this one
1096         // (teleporters are not goals, so this is probably useless)
1097         e.nearestwaypoint = w;
1098         e.nearestwaypointtimeout = -1;
1099 }
1100
1101 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1102 {
1103         org = waypoint_fixorigin(org);
1104         destination = waypoint_fixorigin(destination);
1105         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1106 }
1107
1108 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1109 {
1110         destination = waypoint_fixorigin(destination);
1111         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1112 }
1113
1114 entity waypoint_spawnpersonal(entity this, vector position)
1115 {
1116         entity w;
1117
1118         // drop the waypoint to a proper location:
1119         //   first move it up by a player height
1120         //   then move it down to hit the floor with player bbox size
1121         position = waypoint_fixorigin(position);
1122
1123         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1124         w.nearestwaypoint = NULL;
1125         w.nearestwaypointtimeout = 0;
1126         w.owner = this;
1127
1128         waypoint_schedulerelink(w);
1129
1130         return w;
1131 }
1132
1133 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1134 {
1135         if (!(wp1 && wp2))
1136                 return;
1137
1138         if (wp1.wphardwired && wp2.wphardwired)
1139                 te_beam(NULL, wp1.origin, wp2.origin);
1140         else if (display_type == 1)
1141                 te_lightning2(NULL, wp1.origin, wp2.origin);
1142 }
1143
1144 void waypoint_showlinks_to(entity wp, int display_type)
1145 {
1146         IL_EACH(g_waypoints, it != wp,
1147         {
1148                 if (waypoint_islinked(it, wp))
1149                         waypoint_showlink(it, wp, display_type);
1150         });
1151 }
1152
1153 void waypoint_showlinks_from(entity wp, int display_type)
1154 {
1155         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1156         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1157         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1158         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1159         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1160         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1161         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1162         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1163         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1164         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1165         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1166         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1167         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1168         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1169         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1170         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1171 }
1172
1173 void botframe_showwaypointlinks()
1174 {
1175         if (time < botframe_waypointeditorlightningtime)
1176                 return;
1177         botframe_waypointeditorlightningtime = time + 0.5;
1178         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1179         {
1180                 int display_type = 0;
1181                 entity head = navigation_findnearestwaypoint(it, false);
1182                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1183                         display_type = 1; // default
1184                 else if(head && (head.wphardwired))
1185                         display_type = 2; // only hardwired
1186
1187                 if (display_type)
1188                 {
1189                         //navigation_testtracewalk = true;
1190                         //print("currently selected WP is ", etos(head), "\n");
1191                         //navigation_testtracewalk = false;
1192                         if (head)
1193                         {
1194                                 te_lightning2(NULL, head.origin, it.origin);
1195                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1196                                         waypoint_showlinks_to(head, display_type);
1197                                 else
1198                                         waypoint_showlinks_from(head, display_type);
1199                         }
1200                 }
1201         });
1202 }
1203
1204 float botframe_autowaypoints_fixdown(vector v)
1205 {
1206         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1207         if(trace_fraction >= 1)
1208                 return 0;
1209         return 1;
1210 }
1211
1212 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1213 {
1214         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1215         {
1216                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1217                 return 0;
1218         });
1219
1220         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1221         return 1;
1222 }
1223
1224 // return value:
1225 //    1 = WP created
1226 //    0 = no action needed
1227 //   -1 = temp fail, try from world too
1228 //   -2 = permanent fail, do not retry
1229 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1230 {
1231         // make it possible to go from p to wp, if we can
1232         // if wp is NULL, nearest is chosen
1233
1234         entity w;
1235         vector porg;
1236         float t, tmin, tmax;
1237         vector o;
1238         vector save;
1239
1240         if(!botframe_autowaypoints_fixdown(p.origin))
1241                 return -2;
1242         porg = trace_endpos;
1243
1244         if(wp)
1245         {
1246                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1247
1248                 // if wp -> porg, then OK
1249                 float maxdist;
1250                 if(navigation_waypoint_will_link(wp.origin, porg, p, wp.origin, 0, walkfromwp, 1050))
1251                 {
1252                         // we may find a better one
1253                         maxdist = vlen(wp.origin - porg);
1254                 }
1255                 else
1256                 {
1257                         // accept any "good"
1258                         maxdist = 2100;
1259                 }
1260
1261                 float bestdist = maxdist;
1262                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1263                 {
1264                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1265                         if(d < bestdist)
1266                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, wp.origin, 0, walkfromwp, 1050))
1267                         if(navigation_waypoint_will_link(it.origin, porg, p, it.origin, 0, walkfromwp, 1050))
1268                         {
1269                                 bestdist = d;
1270                                 p.(fld) = it;
1271                         }
1272                 });
1273                 if(bestdist < maxdist)
1274                 {
1275                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1276                         return 0;
1277                 }
1278
1279                 if(bestdist < 2100)
1280                 {
1281                         // we know maxdist < 2100
1282                         // so wp -> porg is still valid
1283                         // all is good
1284                         p.(fld) = wp;
1285                         return 0;
1286                 }
1287
1288                 // otherwise, no existing WP can fix our issues
1289         }
1290         else
1291         {
1292                 save = p.origin;
1293                 setorigin(p, porg);
1294                 w = navigation_findnearestwaypoint(p, walkfromwp);
1295                 setorigin(p, save);
1296                 if(w)
1297                 {
1298                         p.(fld) = w;
1299                         return 0;
1300                 }
1301         }
1302
1303         tmin = 0;
1304         tmax = 1;
1305         for (;;)
1306         {
1307                 if(tmax - tmin < 0.001)
1308                 {
1309                         // did not get a good candidate
1310                         return -1;
1311                 }
1312
1313                 t = (tmin + tmax) * 0.5;
1314                 o = antilag_takebackorigin(p, CS(p), time - t);
1315                 if(!botframe_autowaypoints_fixdown(o))
1316                         return -2;
1317                 o = trace_endpos;
1318
1319                 if(wp)
1320                 {
1321                         if(!navigation_waypoint_will_link(wp.origin, o, p, wp.origin, 0, walkfromwp, 1050))
1322                         {
1323                                 // we cannot walk from wp.origin to o
1324                                 // get closer to tmax
1325                                 tmin = t;
1326                                 continue;
1327                         }
1328                 }
1329                 else
1330                 {
1331                         save = p.origin;
1332                         setorigin(p, o);
1333                         w = navigation_findnearestwaypoint(p, walkfromwp);
1334                         setorigin(p, save);
1335                         if(!w)
1336                         {
1337                                 // we cannot walk from any WP to o
1338                                 // get closer to tmax
1339                                 tmin = t;
1340                                 continue;
1341                         }
1342                 }
1343
1344                 // if we get here, o is valid regarding waypoints
1345                 // check if o is connected right to the player
1346                 // we break if it succeeds, as that means o is a good waypoint location
1347                 if(navigation_waypoint_will_link(o, porg, p, o, 0, walkfromwp, 1050))
1348                         break;
1349
1350                 // o is no good, we need to get closer to the player
1351                 tmax = t;
1352         }
1353
1354         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1355         botframe_autowaypoints_createwp(o, p, fld, 0);
1356         return 1;
1357 }
1358
1359 // automatically create missing waypoints
1360 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1361 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1362 {
1363         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1364         if(r != -1)
1365                 return;
1366         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1367         if(r != -1)
1368                 return;
1369
1370         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1371         if(!botframe_autowaypoints_fixdown(p.origin))
1372                 return; // shouldn't happen, caught above
1373         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1374 }
1375
1376 void botframe_deleteuselesswaypoints()
1377 {
1378         IL_EACH(g_items, it.bot_pickup,
1379         {
1380                 // NOTE: this protects waypoints if they're the ONLY nearest
1381                 // waypoint. That's the intention.
1382                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1383                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1384         });
1385         IL_EACH(g_waypoints, true,
1386         {
1387                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1388                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1389                 // WP is useful if:
1390                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1391                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1392                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1393                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1394                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1395                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1396                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1397                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1398                 // b) WP is closest WP for an item/spawnpoint/other entity
1399                 //    This has been done above by protecting these WPs.
1400         });
1401         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1402         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1403         {
1404                 for (int m = 0; m < 32; ++m)
1405                 {
1406                         entity w = waypoint_get_link(it, m);
1407                         if (!w)
1408                                 break;
1409                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1410                                 continue;
1411                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1412                                 continue;
1413                         for (int j = 0; j < 32; ++j)
1414                         {
1415                                 entity w2 = waypoint_get_link(w, j);
1416                                 if (!w2)
1417                                         break;
1418                                 if (it == w2)
1419                                         continue;
1420                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1421                                         continue;
1422                                 // If we got here, it != w2 exist with it -> w
1423                                 // and w -> w2. That means the waypoint is not
1424                                 // a dead end.
1425                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1426                                 for (int k = 0; k < 32; ++k)
1427                                 {
1428                                         if (waypoint_get_link(it, k) == w2)
1429                                                 continue;
1430                                         // IF WE GET HERE, w is proven useful
1431                                         // to get from it to w2!
1432                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1433                                         goto next;
1434                                 }
1435                         }
1436 LABEL(next)
1437                 }
1438         });
1439         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1440         //     they are needed to complete routes while autowaypointing.
1441
1442         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1443         {
1444                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1445                 te_explosion(it.origin);
1446                 waypoint_remove(it);
1447                 break;
1448         });
1449
1450         IL_EACH(g_waypoints, true,
1451         {
1452                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1453         });
1454 }
1455
1456 void botframe_autowaypoints()
1457 {
1458         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1459                 // going back is broken, so only fix waypoints to walk TO the player
1460                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1461                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1462                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1463         ));
1464
1465         if (autocvar_g_waypointeditor_auto >= 2) {
1466                 botframe_deleteuselesswaypoints();
1467         }
1468 }
1469