qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (g_arena && arena_roundbased)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(clienttype(self) == CLIENTTYPE_REAL)
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         if(g_lms)
 389         {
 390                 // Only if the player cannot play at all
 391                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 392                         self.frags = FRAGS_SPECTATOR;
 393                 else
 394                         self.frags = FRAGS_LMS_LOSER;
 395         }
 396         else if((g_race && g_race_qualifying) || g_cts)
 397         {
 398                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 399                         self.frags = FRAGS_LMS_LOSER;
 400                 else
 401                         self.frags = FRAGS_SPECTATOR;
 402         }
 403         else
 404                 self.frags = FRAGS_SPECTATOR;
 405
 406         MUTATOR_CALLHOOK(MakePlayerObserver);
 407
 408         minstagib_stop_countdown(self);
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 if(!inWarmupStage)
 415                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 416                 self.alivetime = 0;
 417         }
 418
 419         if(self.vehicle)
 420                 vehicles_exit(VHEF_RELESE);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 425                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 426
 427         if(self.killcount != -666)
 428         {
 429                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 430
 431                 if(self.just_joined == FALSE) {
 432                         LogTeamchange(self.playerid, -1, 4);
 433                 } else
 434                         self.just_joined = FALSE;
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         accuracy_resend(self);
 440
 441         self.spectatortime = time;
 442
 443         self.classname = "observer";
 444         self.iscreature = FALSE;
 445         self.teleportable = TELEPORT_SIMPLE;
 446         self.damagedbycontents = FALSE;
 447         self.health = -666;
 448         self.takedamage = DAMAGE_NO;
 449         self.solid = SOLID_NOT;
 450         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 451         self.flags = FL_CLIENT | FL_NOTARGET;
 452         self.armorvalue = 666;
 453         self.effects = 0;
 454         self.armorvalue = autocvar_g_balance_armor_start;
 455         self.pauserotarmor_finished = 0;
 456         self.pauserothealth_finished = 0;
 457         self.pauseregen_finished = 0;
 458         self.damageforcescale = 0;
 459         self.death_time = 0;
 460         self.respawn_flags = 0;
 461         self.respawn_time = 0;
 462         self.stat_respawn_time = 0;
 463         self.alpha = 0;
 464         self.scale = 0;
 465         self.fade_time = 0;
 466         self.pain_frame = 0;
 467         self.pain_finished = 0;
 468         self.strength_finished = 0;
 469         self.invincible_finished = 0;
 470         self.superweapons_finished = 0;
 471         self.pushltime = 0;
 472         self.istypefrag = 0;
 473         self.think = func_null;
 474         self.nextthink = 0;
 475         self.hook_time = 0;
 476         self.deadflag = DEAD_NO;
 477         self.angles = spot.angles;
 478         self.angles_z = 0;
 479         self.fixangle = TRUE;
 480         self.crouch = FALSE;
 481
 482         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 483         self.prevorigin = self.origin;
 484         self.items = 0;
 485         WEPSET_CLEAR_E(self);
 486         self.model = "";
 487         FixPlayermodel();
 488         setmodel(self, "null");
 489         self.drawonlytoclient = self;
 490
 491         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 492         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 493
 494         self.weapon = 0;
 495         self.weaponname = "";
 496         self.switchingweapon = 0;
 497         self.weaponmodel = "";
 498         self.weaponentity = world;
 499         self.exteriorweaponentity = world;
 500         self.killcount = -666;
 501         self.velocity = '0 0 0';
 502         self.avelocity = '0 0 0';
 503         self.punchangle = '0 0 0';
 504         self.punchvector = '0 0 0';
 505         self.oldvelocity = self.velocity;
 506         self.fire_endtime = -1;
 507 }
 508
 509 .float model_randomizer;
 510 void FixPlayermodel()
 511 {
 512         string defaultmodel;
 513         float defaultskin, chmdl, oldskin, n, i;
 514         vector m1, m2;
 515
 516         defaultmodel = "";
 517         defaultskin = 0;
 518         chmdl = FALSE;
 519
 520         if(autocvar_sv_defaultcharacter == 1)
 521         {
 522                 if(teamplay)
 523                 {
 524                         string s;
 525                         s = Team_ColorName_Lower(self.team);
 526                         if(s != "neutral")
 527                         {
 528                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 529                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 530                         }
 531                 }
 532
 533                 if(defaultmodel == "")
 534                 {
 535                         defaultmodel = autocvar_sv_defaultplayermodel;
 536                         defaultskin = autocvar_sv_defaultplayerskin;
 537                 }
 538
 539                 n = tokenize_console(defaultmodel);
 540                 if(n > 0)
 541                         defaultmodel = argv(floor(n * self.model_randomizer));
 542
 543                 i = strstrofs(defaultmodel, ":", 0);
 544                 if(i >= 0)
 545                 {
 546                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 547                         defaultmodel = substring(defaultmodel, 0, i);
 548                 }
 549         }
 550
 551         if(defaultmodel != "")
 552         {
 553                 if (defaultmodel != self.model)
 554                 {
 555                         m1 = self.mins;
 556                         m2 = self.maxs;
 557                         setplayermodel (self, defaultmodel);
 558                         setsize (self, m1, m2);
 559                         chmdl = TRUE;
 560                 }
 561
 562                 oldskin = self.skin;
 563                 self.skin = defaultskin;
 564         } else {
 565                 if (self.playermodel != self.model || self.playermodel == "")
 566                 {
 567                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 568                         m1 = self.mins;
 569                         m2 = self.maxs;
 570                         setplayermodel (self, self.playermodel);
 571                         setsize (self, m1, m2);
 572                         chmdl = TRUE;
 573                 }
 574
 575                 oldskin = self.skin;
 576                 self.skin = stof(self.playerskin);
 577         }
 578
 579         if(chmdl || oldskin != self.skin) // model or skin has changed
 580         {
 581                 self.species = player_getspecies(); // update species
 582                 UpdatePlayerSounds(); // update skin sounds
 583         }
 584
 585         if(!teamplay)
 586                 if(strlen(autocvar_sv_defaultplayercolors))
 587                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 588                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 589 }
 590
 591 /*
 592 =============
 593 PutClientInServer
 594
 595 Called when a client spawns in the server
 596 =============
 597 */
 598
 599 void PutClientInServer (void)
 600 {
 601         if(clienttype(self) == CLIENTTYPE_BOT)
 602                 self.classname = "player";
 603         else if(clienttype(self) == CLIENTTYPE_REAL)
 604         {
 605                 msg_entity = self;
 606                 WriteByte(MSG_ONE, SVC_SETVIEW);
 607                 WriteEntity(MSG_ONE, self);
 608         }
 609
 610         // reset player keys
 611         self.itemkeys = 0;
 612
 613         // player is dead and becomes observer
 614         // FIXME fix LMS scoring for new system
 615         if(g_lms)
 616         {
 617                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 618                         self.classname = "observer";
 619         }
 620
 621         MUTATOR_CALLHOOK(PutClientInServer);
 622
 623         if(gameover)
 624                 self.classname = "observer";
 625
 626         if(self.classname == "player") {
 627                 entity spot, oldself;
 628                 float j;
 629
 630                 accuracy_resend(self);
 631
 632                 if(self.team < 0)
 633                         JoinBestTeam(self, FALSE, TRUE);
 634
 635                 race_PreSpawn();
 636
 637                 spot = SelectSpawnPoint (FALSE);
 638                 if(!spot)
 639                 {
 640                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 641                         return; // spawn failed
 642                 }
 643
 644                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 645
 646                 self.classname = "player";
 647                 self.wasplayer = TRUE;
 648                 self.iscreature = TRUE;
 649                 self.teleportable = TELEPORT_NORMAL;
 650                 self.damagedbycontents = TRUE;
 651                 self.movetype = MOVETYPE_WALK;
 652                 self.solid = SOLID_SLIDEBOX;
 653                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 654                 if(autocvar_g_playerclip_collisions)
 655                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 656                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 657                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 658                 self.frags = FRAGS_PLAYER;
 659                 if(INDEPENDENT_PLAYERS)
 660                         MAKE_INDEPENDENT_PLAYER(self);
 661                 self.flags = FL_CLIENT;
 662                 if(autocvar__notarget)
 663                         self.flags |= FL_NOTARGET;
 664                 self.takedamage = DAMAGE_AIM;
 665                 if(g_minstagib)
 666                         self.effects = EF_FULLBRIGHT;
 667                 else
 668                         self.effects = 0;
 669                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 670                 self.air_finished = time + 12;
 671                 self.dmg = 2;
 672                 if(autocvar_g_balance_nex_charge)
 673                 {
 674                         if(autocvar_g_balance_nex_secondary_chargepool)
 675                                 self.nex_chargepool_ammo = 1;
 676                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 677                 }
 678
 679                 if(inWarmupStage)
 680                 {
 681                         self.ammo_shells = warmup_start_ammo_shells;
 682                         self.ammo_nails = warmup_start_ammo_nails;
 683                         self.ammo_rockets = warmup_start_ammo_rockets;
 684                         self.ammo_cells = warmup_start_ammo_cells;
 685                         self.ammo_fuel = warmup_start_ammo_fuel;
 686                         self.health = warmup_start_health;
 687                         self.armorvalue = warmup_start_armorvalue;
 688                         WEPSET_COPY_EA(self, warmup_start_weapons);
 689                 }
 690                 else
 691                 {
 692                         self.ammo_shells = start_ammo_shells;
 693                         self.ammo_nails = start_ammo_nails;
 694                         self.ammo_rockets = start_ammo_rockets;
 695                         self.ammo_cells = start_ammo_cells;
 696                         self.ammo_fuel = start_ammo_fuel;
 697                         self.health = start_health;
 698                         self.armorvalue = start_armorvalue;
 699                         WEPSET_COPY_EA(self, start_weapons);
 700                 }
 701
 702                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 703                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 704                 else
 705                         self.superweapons_finished = 0;
 706
 707                 if(g_weaponarena_random)
 708                 {
 709                         if(g_weaponarena_random_with_laser)
 710                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 711                         W_RandomWeapons(self, g_weaponarena_random);
 712                         if(g_weaponarena_random_with_laser)
 713                                 WEPSET_OR_EW(self, WEP_LASER);
 714                 }
 715
 716                 self.items = start_items;
 717
 718                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 719                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 720                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 721                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 722                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 723                 //extend the pause of rotting if client was reset at the beginning of the countdown
 724                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 725                         self.spawnshieldtime += game_starttime - time;
 726                         self.pauserotarmor_finished += game_starttime - time;
 727                         self.pauserothealth_finished += game_starttime - time;
 728                         self.pauseregen_finished += game_starttime - time;
 729                 }
 730                 self.damageforcescale = 2;
 731                 self.death_time = 0;
 732                 self.respawn_flags = 0;
 733                 self.respawn_time = 0;
 734                 self.stat_respawn_time = 0;
 735                 self.scale = 0;
 736                 self.fade_time = 0;
 737                 self.pain_frame = 0;
 738                 self.pain_finished = 0;
 739                 self.strength_finished = 0;
 740                 self.invincible_finished = 0;
 741                 self.pushltime = 0;
 742                 // players have no think function
 743                 self.think = func_null;
 744                 self.nextthink = 0;
 745                 self.hook_time = 0;
 746                 self.dmg_team = 0;
 747                 self.ballistics_density = autocvar_g_ballistics_density_player;
 748
 749                 self.metertime = 0;
 750
 751                 self.deadflag = DEAD_NO;
 752
 753                 self.angles = spot.angles;
 754
 755                 self.angles_z = 0; // never spawn tilted even if the spot says to
 756                 self.fixangle = TRUE; // turn this way immediately
 757                 self.velocity = '0 0 0';
 758                 self.avelocity = '0 0 0';
 759                 self.punchangle = '0 0 0';
 760                 self.punchvector = '0 0 0';
 761                 self.oldvelocity = self.velocity;
 762                 self.fire_endtime = -1;
 763
 764                 msg_entity = self;
 765                 WRITESPECTATABLE_MSG_ONE({
 766                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 767                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 768                 });
 769
 770                 self.model = "";
 771                 FixPlayermodel();
 772                 self.drawonlytoclient = world;
 773
 774                 self.crouch = FALSE;
 775                 self.view_ofs = PL_VIEW_OFS;
 776                 setsize (self, PL_MIN, PL_MAX);
 777                 self.spawnorigin = spot.origin;
 778                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 779                 // don't reset back to last position, even if new position is stuck in solid
 780                 self.oldorigin = self.origin;
 781                 self.prevorigin = self.origin;
 782                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 783                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 784         self.hud = HUD_NORMAL;
 785
 786                 self.event_damage = PlayerDamage;
 787
 788                 self.bot_attack = TRUE;
 789
 790                 self.statdraintime = time + 5;
 791                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 792
 793                 if(self.killcount == -666) {
 794                         PlayerScore_Clear(self);
 795                         self.killcount = 0;
 796                 }
 797
 798                 CL_SpawnWeaponentity();
 799                 self.alpha = default_player_alpha;
 800                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 801                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 802
 803                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 804                 self.lms_traveled_distance = 0;
 805                 self.speedrunning = FALSE;
 806
 807                 race_PostSpawn(spot);
 808
 809                 //stuffcmd(self, "chase_active 0");
 810                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 811
 812                 if(g_assault) {
 813                         if(self.team == assault_attacker_team)
 814                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 815                         else
 816                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 817                 }
 818
 819                 target_voicescript_clear(self);
 820
 821                 // reset fields the weapons may use
 822                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 823                 {
 824                         weapon_action(j, WR_RESETPLAYER);
 825
 826                         // all weapons must be fully loaded when we spawn
 827                         entity e;
 828                         e = get_weaponinfo(j);
 829                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 830                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 831                 }
 832
 833                 oldself = self;
 834                 self = spot;
 835                         activator = oldself;
 836                                 string s;
 837                                 s = self.target;
 838                                 self.target = string_null;
 839                                 SUB_UseTargets();
 840                                 self.target = s;
 841                         activator = world;
 842                 self = oldself;
 843
 844                 spawn_spot = spot;
 845                 MUTATOR_CALLHOOK(PlayerSpawn);
 846
 847                 if(autocvar_spawn_debug)
 848                 {
 849                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 850                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 851                 }
 852
 853                 self.switchweapon = w_getbestweapon(self);
 854                 self.cnt = -1; // W_LastWeapon will not complain
 855                 self.weapon = 0;
 856                 self.weaponname = "";
 857                 self.switchingweapon = 0;
 858
 859                 if(!inWarmupStage)
 860                         if(!self.alivetime)
 861                                 self.alivetime = time;
 862
 863                 antilag_clear(self);
 864
 865                 if (autocvar_g_spawnsound)
 866                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 867         } else if(self.classname == "observer") {
 868                 PutObserverInServer ();
 869         }
 870 }
 871
 872 .float ebouncefactor, ebouncestop; // electro's values
 873 // TODO do we need all these fields, or should we stop autodetecting runtime
 874 // changes and just have a console command to update this?
 875 float ClientInit_SendEntity(entity to, float sf)
 876 {
 877         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 878         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 879         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 880         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 881         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 882         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 883         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 884         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 885         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 886         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 887         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 888         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 889         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 890         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 891         if(sv_foginterval && world.fog != "")
 892                 WriteString(MSG_ENTITY, world.fog);
 893         else
 894                 WriteString(MSG_ENTITY, "");
 895         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 896         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 897         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 898         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 899         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 900         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 901         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 902         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 903         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 904         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 905         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 906         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 907         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 908         return TRUE;
 909 }
 910
 911 void ClientInit_CheckUpdate()
 912 {
 913         self.nextthink = time;
 914         if(self.count != autocvar_g_balance_armor_blockpercent)
 915         {
 916                 self.count = autocvar_g_balance_armor_blockpercent;
 917                 self.SendFlags |= 1;
 918         }
 919         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 920         {
 921                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 922                 self.SendFlags |= 1;
 923         }
 924         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 925         {
 926                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 927                 self.SendFlags |= 1;
 928         }
 929         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 930         {
 931                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 932                 self.SendFlags |= 1;
 933         }
 934         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 935         {
 936                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 937                 self.SendFlags |= 1;
 938         }
 939         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 940         {
 941                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 942                 self.SendFlags |= 1;
 943         }
 944 }
 945
 946 void ClientInit_Spawn()
 947 {
 948         entity o;
 949         entity e;
 950         e = spawn();
 951         e.classname = "clientinit";
 952         e.think = ClientInit_CheckUpdate;
 953         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 954
 955         o = self;
 956         self = e;
 957         ClientInit_CheckUpdate();
 958         self = o;
 959 }
 960
 961 /*
 962 =============
 963 SetNewParms
 964 =============
 965 */
 966 void SetNewParms (void)
 967 {
 968         // initialize parms for a new player
 969         parm1 = -(86400 * 366);
 970 }
 971
 972 /*
 973 =============
 974 SetChangeParms
 975 =============
 976 */
 977 void SetChangeParms (void)
 978 {
 979         // save parms for level change
 980         parm1 = self.parm_idlesince - time;
 981 }
 982
 983 /*
 984 =============
 985 DecodeLevelParms
 986 =============
 987 */
 988 void DecodeLevelParms (void)
 989 {
 990         // load parms
 991         self.parm_idlesince = parm1;
 992         if(self.parm_idlesince == -(86400 * 366))
 993                 self.parm_idlesince = time;
 994
 995         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 996         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 997 }
 998
 999 /*
1000 =============
1001 ClientKill
1002
1003 Called when a client types 'kill' in the console
1004 =============
1005 */
1006
1007 .float clientkill_nexttime;
1008 void ClientKill_Now_TeamChange()
1009 {
1010         if(self.killindicator_teamchange == -1)
1011         {
1012                 JoinBestTeam( self, FALSE, TRUE );
1013         }
1014         else if(self.killindicator_teamchange == -2)
1015         {
1016                 if(blockSpectators)
1017                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1018                 PutObserverInServer();
1019         }
1020         else
1021                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1022         self.killindicator_teamchange = 0;
1023 }
1024
1025 void ClientKill_Now()
1026 {
1027         if(self.vehicle)
1028         {
1029             vehicles_exit(VHEF_RELESE);
1030             if(!self.killindicator_teamchange)
1031             {
1032             self.vehicle_health = -1;
1033             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1034             }
1035         }
1036
1037         if(self.killindicator && !wasfreed(self.killindicator))
1038                 remove(self.killindicator);
1039
1040         self.killindicator = world;
1041
1042         if(self.killindicator_teamchange)
1043                 ClientKill_Now_TeamChange();
1044
1045         // in any case:
1046         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1047
1048         // now I am sure the player IS dead
1049 }
1050 void KillIndicator_Think()
1051 {
1052         if (gameover)
1053         {
1054                 self.owner.killindicator = world;
1055                 remove(self);
1056                 return;
1057         }
1058
1059         if (self.owner.alpha < 0 && !self.owner.vehicle)
1060         {
1061                 self.owner.killindicator = world;
1062                 remove(self);
1063                 return;
1064         }
1065
1066         if(self.cnt <= 0)
1067         {
1068                 self = self.owner;
1069                 ClientKill_Now(); // no oldself needed
1070                 return;
1071         }
1072     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1073     {
1074         self.nextthink = time + 1;
1075         self.cnt -= 1;
1076     }
1077         else
1078         {
1079                 if(self.cnt <= 10)
1080                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1081                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1082                 {
1083                         if(self.cnt <= 10)
1084                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1085                 }
1086                 self.nextthink = time + 1;
1087                 self.cnt -= 1;
1088         }
1089 }
1090
1091 float clientkilltime;
1092 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1093 {
1094         float killtime;
1095         float starttime;
1096         entity e;
1097
1098         if (gameover)
1099                 return;
1100
1101         killtime = autocvar_g_balance_kill_delay;
1102
1103         if(g_race_qualifying || g_cts)
1104                 killtime = 0;
1105
1106     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1107     {
1108                 remove(self.killindicator);
1109                 self.killindicator = world;
1110
1111         ClientKill_Now(); // allow instant kill in this case
1112         return;
1113     }
1114
1115         self.killindicator_teamchange = targetteam;
1116
1117     if(!self.killindicator)
1118         {
1119                 if(self.deadflag == DEAD_NO)
1120                 {
1121                         killtime = max(killtime, self.clientkill_nexttime - time);
1122                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1123                 }
1124
1125                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1126                 {
1127                         ClientKill_Now();
1128                 }
1129                 else
1130                 {
1131                         starttime = max(time, clientkilltime);
1132
1133                         self.killindicator = spawn();
1134                         self.killindicator.owner = self;
1135                         self.killindicator.scale = 0.5;
1136                         setattachment(self.killindicator, self, "");
1137                         setorigin(self.killindicator, '0 0 52');
1138                         self.killindicator.think = KillIndicator_Think;
1139                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1140                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1141                         self.killindicator.cnt = ceil(killtime);
1142                         self.killindicator.count = bound(0, ceil(killtime), 10);
1143                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1144
1145                         for(e = world; (e = find(e, classname, "body")) != world; )
1146                         {
1147                                 if(e.enemy != self)
1148                                         continue;
1149                                 e.killindicator = spawn();
1150                                 e.killindicator.owner = e;
1151                                 e.killindicator.scale = 0.5;
1152                                 setattachment(e.killindicator, e, "");
1153                                 setorigin(e.killindicator, '0 0 52');
1154                                 e.killindicator.think = KillIndicator_Think;
1155                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1156                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1157                                 e.killindicator.cnt = ceil(killtime);
1158                         }
1159                         self.lip = 0;
1160                 }
1161         }
1162         if(self.killindicator)
1163         {
1164                 if(targetteam == 0) // just die
1165                 {
1166                         self.killindicator.colormod = '0 0 0';
1167                         if(clienttype(self) == CLIENTTYPE_REAL)
1168                         if(self.killindicator.cnt > 0)
1169                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1170                 }
1171                 else if(targetteam == -1) // auto
1172                 {
1173                         self.killindicator.colormod = '0 1 0';
1174                         if(clienttype(self) == CLIENTTYPE_REAL)
1175                         if(self.killindicator.cnt > 0)
1176                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1177                 }
1178                 else if(targetteam == -2) // spectate
1179                 {
1180                         self.killindicator.colormod = '0.5 0.5 0.5';
1181                         if(clienttype(self) == CLIENTTYPE_REAL)
1182                         if(self.killindicator.cnt > 0)
1183                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1184                 }
1185                 else
1186                 {
1187                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1188                         if(clienttype(self) == CLIENTTYPE_REAL)
1189                         if(self.killindicator.cnt > 0)
1190                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1191                 }
1192         }
1193
1194 }
1195
1196 void ClientKill (void)
1197 {
1198         if(gameover) return;
1199         if(self.player_blocked) return;
1200         if(self.freezetag_frozen) return;
1201
1202         ClientKill_TeamChange(0);
1203 }
1204
1205 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1206 {
1207     e.killindicator = spawn();
1208     e.killindicator.owner = e;
1209     e.killindicator.think = KillIndicator_Think;
1210     e.killindicator.nextthink = time + (e.lip) * 0.05;
1211     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1212     e.killindicator.health = 1; // this is used to indicate that it should be silent
1213     e.lip = 0;
1214 }
1215
1216 void FixClientCvars(entity e)
1217 {
1218         // send prediction settings to the client
1219         stuffcmd(e, "\nin_bindmap 0 0\n");
1220         if(g_race || g_cts)
1221                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1222         if(autocvar_g_antilag == 3) // client side hitscan
1223                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1224         if(autocvar_sv_gentle)
1225                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1226         /*
1227          * we no longer need to stuff this. Remove this comment block if you feel
1228          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1229         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1230         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1231         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1232         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1233         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1234         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1235         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1236         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1237         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1238         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1239         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1240         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1241         stuffcmd(e, "cl_movement_edgefriction 1\n");
1242          */
1243 }
1244
1245 float PlayerInIDList(entity p, string idlist)
1246 {
1247         float n, i;
1248         string s;
1249
1250         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1251         if not(p.crypto_idfp)
1252                 return 0;
1253
1254         // this function allows abbreviated player IDs too!
1255         n = tokenize_console(idlist);
1256         for(i = 0; i < n; ++i)
1257         {
1258                 s = argv(i);
1259                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1260                         return 1;
1261         }
1262
1263         return 0;
1264 }
1265
1266 /*
1267 =============
1268 ClientConnect
1269
1270 Called when a client connects to the server
1271 =============
1272 */
1273 void DecodeLevelParms (void);
1274 //void dom_player_join_team(entity pl);
1275 void set_dom_state(entity e);
1276 void ClientConnect (void)
1277 {
1278         float t;
1279
1280         if(self.flags & FL_CLIENT)
1281         {
1282                 print("Warning: ClientConnect, but already connected!\n");
1283                 return;
1284         }
1285
1286         if(Ban_MaybeEnforceBanOnce(self))
1287                 return;
1288
1289         DecodeLevelParms();
1290
1291 #ifdef WATERMARK
1292         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1293 #endif
1294
1295         self.classname = "player_joining";
1296
1297         self.flags = FL_CLIENT;
1298         self.version_nagtime = time + 10 + random() * 10;
1299
1300         if(player_count<0)
1301         {
1302                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1303                 player_count = 0;
1304         }
1305
1306         PlayerScore_Attach(self);
1307         ClientData_Attach();
1308         accuracy_init(self);
1309
1310         bot_clientconnect();
1311
1312         playerdemo_init();
1313
1314         anticheat_init();
1315
1316         race_PreSpawnObserver();
1317
1318         // identify the right forced team
1319         if(autocvar_g_campaign)
1320         {
1321                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1322                 {
1323                         switch(autocvar_g_campaign_forceteam)
1324                         {
1325                                 case 1: self.team_forced = NUM_TEAM_1; break;
1326                                 case 2: self.team_forced = NUM_TEAM_2; break;
1327                                 case 3: self.team_forced = NUM_TEAM_3; break;
1328                                 case 4: self.team_forced = NUM_TEAM_4; break;
1329                                 default: self.team_forced = 0;
1330                         }
1331                 }
1332         }
1333         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1334                 self.team_forced = NUM_TEAM_1;
1335         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1336                 self.team_forced = NUM_TEAM_2;
1337         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1338                 self.team_forced = NUM_TEAM_3;
1339         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1340                 self.team_forced = NUM_TEAM_4;
1341         else if(autocvar_g_forced_team_otherwise == "red")
1342                 self.team_forced = NUM_TEAM_1;
1343         else if(autocvar_g_forced_team_otherwise == "blue")
1344                 self.team_forced = NUM_TEAM_2;
1345         else if(autocvar_g_forced_team_otherwise == "yellow")
1346                 self.team_forced = NUM_TEAM_3;
1347         else if(autocvar_g_forced_team_otherwise == "pink")
1348                 self.team_forced = NUM_TEAM_4;
1349         else if(autocvar_g_forced_team_otherwise == "spectate")
1350                 self.team_forced = -1;
1351         else if(autocvar_g_forced_team_otherwise == "spectator")
1352                 self.team_forced = -1;
1353         else
1354                 self.team_forced = 0;
1355
1356         if(!teamplay)
1357                 if(self.team_forced > 0)
1358                         self.team_forced = 0;
1359
1360         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1361
1362         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1363                 self.classname = "observer";
1364         } else {
1365                 if(teamplay)
1366                 {
1367                         if(autocvar_g_balance_teams)
1368                         {
1369                                 self.classname = "player";
1370                                 campaign_bots_may_start = 1;
1371                         }
1372                         else
1373                         {
1374                                 self.classname = "observer"; // do it anyway
1375                         }
1376                 }
1377                 else
1378                 {
1379                         self.classname = "player";
1380                         campaign_bots_may_start = 1;
1381                 }
1382         }
1383
1384         self.playerid = (playerid_last = playerid_last + 1);
1385
1386         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1387
1388     if(clienttype(self) == CLIENTTYPE_BOT)
1389         PlayerStats_AddPlayer(self);
1390
1391         if(autocvar_sv_eventlog)
1392                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1393
1394         LogTeamchange(self.playerid, self.team, 1);
1395
1396         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1397
1398         self.netname_previous = strzone(self.netname);
1399
1400         if((self.classname == STR_PLAYER && teamplay))
1401                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1402         else
1403                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1404
1405         stuffcmd(self, strcat(clientstuff, "\n"));
1406         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1407
1408         FixClientCvars(self);
1409
1410         // spawnfunc_waypoint sprites
1411         WaypointSprite_InitClient(self);
1412
1413         // Wazat's grappling hook
1414         SetGrappleHookBindings();
1415
1416         // get version info from player
1417         stuffcmd(self, "cmd clientversion $gameversion\n");
1418
1419         // get other cvars from player
1420         GetCvars(0);
1421
1422         // notify about available teams
1423         if(teamplay)
1424         {
1425                 CheckAllowedTeams(self);
1426                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1427                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1428         }
1429         else
1430                 stuffcmd(self, "set _teams_available 0\n");
1431
1432         attach_entcs();
1433
1434         bot_relinkplayerlist();
1435
1436         self.spectatortime = time;
1437         if(blockSpectators)
1438         {
1439                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1440         }
1441
1442         self.jointime = time;
1443         self.allowed_timeouts = autocvar_sv_timeout_number;
1444
1445         if(clienttype(self) == CLIENTTYPE_REAL)
1446         {
1447                 if(!autocvar_g_campaign)
1448                 {
1449                         self.motd_actived_time = -1;
1450                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1451                 }
1452
1453                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1454                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1455         }
1456
1457         if(!sv_foginterval && world.fog != "")
1458                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1459
1460         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1461         {
1462                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1463                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1464         }
1465         else
1466                 self.hitplotfh = -1;
1467
1468         if(g_race || g_cts) {
1469                 string rr;
1470                 if(g_cts)
1471                         rr = CTS_RECORD;
1472                 else
1473                         rr = RACE_RECORD;
1474
1475                 msg_entity = self;
1476                 race_send_recordtime(MSG_ONE);
1477                 race_send_speedaward(MSG_ONE);
1478
1479                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1480                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1481                 race_send_speedaward_alltimebest(MSG_ONE);
1482
1483                 float i;
1484                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1485                         race_SendRankings(i, 0, 0, MSG_ONE);
1486                 }
1487         }
1488         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1489                 send_CSQC_teamnagger();
1490
1491         CheatInitClient();
1492
1493         CSQCMODEL_AUTOINIT();
1494
1495         self.model_randomizer = random();
1496
1497         if(clienttype(self) == CLIENTTYPE_REAL)
1498                 sv_notice_join();
1499
1500         MUTATOR_CALLHOOK(ClientConnect);
1501 }
1502 /*
1503 =============
1504 ClientDisconnect
1505
1506 Called when a client disconnects from the server
1507 =============
1508 */
1509 .entity chatbubbleentity;
1510 void ReadyCount();
1511 void ClientDisconnect (void)
1512 {
1513         if(self.vehicle)
1514             vehicles_exit(VHEF_RELESE);
1515
1516         if not(self.flags & FL_CLIENT)
1517         {
1518                 print("Warning: ClientDisconnect without ClientConnect\n");
1519                 return;
1520         }
1521
1522         PlayerStats_AddGlobalInfo(self);
1523
1524         CheatShutdownClient();
1525
1526         if(self.hitplotfh >= 0)
1527         {
1528                 fclose(self.hitplotfh);
1529                 self.hitplotfh = -1;
1530         }
1531
1532         anticheat_report();
1533         anticheat_shutdown();
1534
1535         playerdemo_shutdown();
1536
1537         bot_clientdisconnect();
1538
1539         if(self.entcs)
1540                 detach_entcs();
1541
1542         if(autocvar_sv_eventlog)
1543                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1544
1545         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1546
1547         MUTATOR_CALLHOOK(ClientDisconnect);
1548
1549         Portal_ClearAll(self);
1550
1551         RemoveGrapplingHook(self);
1552
1553         // Here, everything has been done that requires this player to be a client.
1554
1555         self.flags &~= FL_CLIENT;
1556
1557         if (self.chatbubbleentity)
1558                 remove (self.chatbubbleentity);
1559
1560         if (self.killindicator)
1561                 remove (self.killindicator);
1562
1563         WaypointSprite_PlayerGone();
1564
1565         bot_relinkplayerlist();
1566
1567         accuracy_free(self);
1568         ClientData_Detach();
1569         PlayerScore_Detach(self);
1570
1571         if(self.netname_previous)
1572                 strunzone(self.netname_previous);
1573         if(self.clientstatus)
1574                 strunzone(self.clientstatus);
1575         if(self.weaponorder_byimpulse)
1576                 strunzone(self.weaponorder_byimpulse);
1577
1578         ClearPlayerSounds();
1579
1580         if(self.personal)
1581                 remove(self.personal);
1582
1583         self.playerid = 0;
1584         ReadyCount();
1585
1586         // free cvars
1587         GetCvars(-1);
1588 }
1589
1590 .float BUTTON_CHAT;
1591 void ChatBubbleThink()
1592 {
1593         self.nextthink = time;
1594         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1595         {
1596                 if(self.owner) // but why can that ever be world?
1597                         self.owner.chatbubbleentity = world;
1598                 remove(self);
1599                 return;
1600         }
1601         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1602 #ifdef TETRIS
1603                 || self.owner.tetris_on
1604 #endif
1605         )
1606                 self.model = self.mdl;
1607         else
1608                 self.model = "";
1609 }
1610
1611 void UpdateChatBubble()
1612 {
1613         if (self.alpha < 0)
1614                 return;
1615         // spawn a chatbubble entity if needed
1616         if (!self.chatbubbleentity)
1617         {
1618                 self.chatbubbleentity = spawn();
1619                 self.chatbubbleentity.owner = self;
1620                 self.chatbubbleentity.exteriormodeltoclient = self;
1621                 self.chatbubbleentity.think = ChatBubbleThink;
1622                 self.chatbubbleentity.nextthink = time;
1623                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1624                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1625                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1626                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1627                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1628                 self.chatbubbleentity.model = "";
1629                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1630         }
1631 }
1632
1633
1634 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1635 // added to the model skins
1636 /*void UpdateColorModHack()
1637 {
1638         float c;
1639         c = self.clientcolors & 15;
1640         // LordHavoc: only bothering to support white, green, red, yellow, blue
1641              if (!teamplay) self.colormod = '0 0 0';
1642         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1643         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1644         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1645         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1646         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1647         else self.colormod = '1 1 1';
1648 }*/
1649
1650 void respawn(void)
1651 {
1652         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1653         {
1654                 self.solid = SOLID_NOT;
1655                 self.takedamage = DAMAGE_NO;
1656                 self.movetype = MOVETYPE_FLY;
1657                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1658                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1659                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1660                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1661                 if(autocvar_g_respawn_ghosts_maxtime)
1662                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1663         }
1664
1665         CopyBody(1);
1666
1667         self.effects |= EF_NODRAW; // prevent another CopyBody
1668         PutClientInServer();
1669 }
1670
1671 void play_countdown(float finished, string samp)
1672 {
1673         if(clienttype(self) == CLIENTTYPE_REAL)
1674                 if(floor(finished - time - frametime) != floor(finished - time))
1675                         if(finished - time < 6)
1676                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1677 }
1678
1679 void player_powerups (void)
1680 {
1681         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1682         olditems = self.items;
1683
1684         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1685                 self.modelflags |= MF_ROCKET;
1686         else
1687                 self.modelflags &~= MF_ROCKET;
1688
1689         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1690
1691         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1692                 return;
1693
1694         Fire_ApplyDamage(self);
1695         Fire_ApplyEffect(self);
1696
1697         if (g_minstagib)
1698         {
1699                 self.effects |= EF_FULLBRIGHT;
1700
1701                 if (self.items & IT_STRENGTH)
1702                 {
1703                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1704                         if (time > self.strength_finished)
1705                         {
1706                                 self.alpha = default_player_alpha;
1707                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1708                                 self.items &~= IT_STRENGTH;
1709                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1710                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1711                         }
1712                 }
1713                 else
1714                 {
1715                         if (time < self.strength_finished)
1716                         {
1717                                 self.alpha = g_minstagib_invis_alpha;
1718                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1719                                 self.items |= IT_STRENGTH;
1720                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1721                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1722                         }
1723                 }
1724
1725                 if (self.items & IT_INVINCIBLE)
1726                 {
1727                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1728                         if (time > self.invincible_finished)
1729                         {
1730                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1731                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1732                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1733                         }
1734                 }
1735                 else
1736                 {
1737                         if (time < self.invincible_finished)
1738                         {
1739                                 self.items = self.items | IT_INVINCIBLE;
1740                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1741                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1742                         }
1743                 }
1744         }
1745         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1746         {
1747                 if (self.items & IT_STRENGTH)
1748                 {
1749                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1750                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1751                         if (time > self.strength_finished)
1752                         {
1753                                 self.items = self.items - (self.items & IT_STRENGTH);
1754                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1755                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1756                         }
1757                 }
1758                 else
1759                 {
1760                         if (time < self.strength_finished)
1761                         {
1762                                 self.items = self.items | IT_STRENGTH;
1763                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1764                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1765                         }
1766                 }
1767                 if (self.items & IT_INVINCIBLE)
1768                 {
1769                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1770                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1771                         if (time > self.invincible_finished)
1772                         {
1773                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1774                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1775                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1776                         }
1777                 }
1778                 else
1779                 {
1780                         if (time < self.invincible_finished)
1781                         {
1782                                 self.items = self.items | IT_INVINCIBLE;
1783                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1784                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1785                         }
1786                 }
1787                 if (self.items & IT_SUPERWEAPON)
1788                 {
1789                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1790                         {
1791                                 self.superweapons_finished = 0;
1792                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1793                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1794                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1795                         }
1796                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1797                         {
1798                                 // don't let them run out
1799                         }
1800                         else
1801                         {
1802                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1803                                 if (time > self.superweapons_finished)
1804                                 {
1805                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1806                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1807                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1808                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1809                                 }
1810                         }
1811                 }
1812                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1813                 {
1814                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1815                         {
1816                                 self.items = self.items | IT_SUPERWEAPON;
1817                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1818                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1819                         }
1820                         else
1821                         {
1822                                 self.superweapons_finished = 0;
1823                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1824                         }
1825                 }
1826                 else
1827                 {
1828                         self.superweapons_finished = 0;
1829                 }
1830         }
1831
1832         if(autocvar_g_nodepthtestplayers)
1833                 self.effects = self.effects | EF_NODEPTHTEST;
1834
1835         if(autocvar_g_fullbrightplayers)
1836                 self.effects = self.effects | EF_FULLBRIGHT;
1837
1838         // midair gamemode: damage only while in the air
1839         // if in midair mode, being on ground grants temporary invulnerability
1840         // (this is so that multishot weapon don't clear the ground flag on the
1841         // first damage in the frame, leaving the player vulnerable to the
1842         // remaining hits in the same frame)
1843         if (self.flags & FL_ONGROUND)
1844         if (g_midair)
1845                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1846
1847         if (time >= game_starttime)
1848         if (time < self.spawnshieldtime)
1849                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1850
1851         MUTATOR_CALLHOOK(PlayerPowerups);
1852 }
1853
1854 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1855 {
1856         if(current > stable)
1857                 return current;
1858         else if(current > stable - 0.25) // when close enough, "snap"
1859                 return stable;
1860         else
1861                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1862 }
1863
1864 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1865 {
1866         if(current < stable)
1867                 return current;
1868         else if(current < stable + 0.25) // when close enough, "snap"
1869                 return stable;
1870         else
1871                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1872 }
1873
1874 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1875 {
1876         if(current > rotstable)
1877         {
1878                 if(rotframetime > 0)
1879                 {
1880                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1881                         current = max(rotstable, current - rotlinear * rotframetime);
1882                 }
1883         }
1884         else if(current < regenstable)
1885         {
1886                 if(regenframetime > 0)
1887                 {
1888                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1889                         current = min(regenstable, current + regenlinear * regenframetime);
1890                 }
1891         }
1892
1893         if(current > limit)
1894                 current = limit;
1895
1896         return current;
1897 }
1898
1899 void player_regen (void)
1900 {
1901         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1902         maxh = autocvar_g_balance_health_rotstable;
1903         maxa = autocvar_g_balance_armor_rotstable;
1904         maxf = autocvar_g_balance_fuel_rotstable;
1905         minh = autocvar_g_balance_health_regenstable;
1906         mina = autocvar_g_balance_armor_regenstable;
1907         minf = autocvar_g_balance_fuel_regenstable;
1908         limith = autocvar_g_balance_health_limit;
1909         limita = autocvar_g_balance_armor_limit;
1910         limitf = autocvar_g_balance_fuel_limit;
1911
1912         max_mod = regen_mod = rot_mod = limit_mod = 1;
1913
1914         maxh = maxh * max_mod;
1915         //maxa = maxa * max_mod;
1916         //maxf = maxf * max_mod;
1917         minh = minh * max_mod;
1918         //mina = mina * max_mod;
1919         //minf = minf * max_mod;
1920         limith = limith * limit_mod;
1921         limita = limita * limit_mod;
1922         //limitf = limitf * limit_mod;
1923
1924         if(g_ca)
1925                 rot_mod = 0;
1926
1927         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1928         {
1929                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1930                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1931
1932                 // if player rotted to death...  die!
1933                 if(self.health < 1)
1934                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1935         }
1936
1937         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1938                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1939 }
1940
1941 float zoomstate_set;
1942 void SetZoomState(float z)
1943 {
1944         if(z != self.zoomstate)
1945         {
1946                 self.zoomstate = z;
1947                 ClientData_Touch(self);
1948         }
1949         zoomstate_set = 1;
1950 }
1951
1952 void GetPressedKeys(void) {
1953         MUTATOR_CALLHOOK(GetPressedKeys);
1954         if (self.movement_x > 0) // get if movement keys are pressed
1955         {       // forward key pressed
1956                 self.pressedkeys |= KEY_FORWARD;
1957                 self.pressedkeys &~= KEY_BACKWARD;
1958         }
1959         else if (self.movement_x < 0)
1960         {       // backward key pressed
1961                 self.pressedkeys |= KEY_BACKWARD;
1962                 self.pressedkeys &~= KEY_FORWARD;
1963         }
1964         else
1965         {       // no x input
1966                 self.pressedkeys &~= KEY_FORWARD;
1967                 self.pressedkeys &~= KEY_BACKWARD;
1968         }
1969
1970         if (self.movement_y > 0)
1971         {       // right key pressed
1972                 self.pressedkeys |= KEY_RIGHT;
1973                 self.pressedkeys &~= KEY_LEFT;
1974         }
1975         else if (self.movement_y < 0)
1976         {       // left key pressed
1977                 self.pressedkeys |= KEY_LEFT;
1978                 self.pressedkeys &~= KEY_RIGHT;
1979         }
1980         else
1981         {       // no y input
1982                 self.pressedkeys &~= KEY_RIGHT;
1983                 self.pressedkeys &~= KEY_LEFT;
1984         }
1985
1986         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1987                 self.pressedkeys |= KEY_JUMP;
1988         else
1989                 self.pressedkeys &~= KEY_JUMP;
1990         if (self.BUTTON_CROUCH)
1991                 self.pressedkeys |= KEY_CROUCH;
1992         else
1993                 self.pressedkeys &~= KEY_CROUCH;
1994
1995         if (self.BUTTON_ATCK)
1996                 self.pressedkeys |= KEY_ATCK;
1997         else
1998                 self.pressedkeys &~= KEY_ATCK;
1999         if (self.BUTTON_ATCK2)
2000                 self.pressedkeys |= KEY_ATCK2;
2001         else
2002                 self.pressedkeys &~= KEY_ATCK2;
2003 }
2004
2005 /*
2006 ======================
2007 spectate mode routines
2008 ======================
2009 */
2010
2011 void SpectateCopy(entity spectatee) {
2012         other = spectatee;
2013         MUTATOR_CALLHOOK(SpectateCopy);
2014         self.armortype = spectatee.armortype;
2015         self.armorvalue = spectatee.armorvalue;
2016         self.ammo_cells = spectatee.ammo_cells;
2017         self.ammo_shells = spectatee.ammo_shells;
2018         self.ammo_nails = spectatee.ammo_nails;
2019         self.ammo_rockets = spectatee.ammo_rockets;
2020         self.ammo_fuel = spectatee.ammo_fuel;
2021         self.clip_load = spectatee.clip_load;
2022         self.clip_size = spectatee.clip_size;
2023         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2024         self.health = spectatee.health;
2025         self.impulse = 0;
2026         self.items = spectatee.items;
2027         self.last_pickup = spectatee.last_pickup;
2028         self.hit_time = spectatee.hit_time;
2029         self.metertime = spectatee.metertime;
2030         self.strength_finished = spectatee.strength_finished;
2031         self.invincible_finished = spectatee.invincible_finished;
2032         self.pressedkeys = spectatee.pressedkeys;
2033         WEPSET_COPY_EE(self, spectatee);
2034         self.switchweapon = spectatee.switchweapon;
2035         self.switchingweapon = spectatee.switchingweapon;
2036         self.weapon = spectatee.weapon;
2037         self.nex_charge = spectatee.nex_charge;
2038         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2039         self.hagar_load = spectatee.hagar_load;
2040         self.minelayer_mines = spectatee.minelayer_mines;
2041         self.punchangle = spectatee.punchangle;
2042         self.view_ofs = spectatee.view_ofs;
2043         self.velocity = spectatee.velocity;
2044         self.dmg_take = spectatee.dmg_take;
2045         self.dmg_save = spectatee.dmg_save;
2046         self.dmg_inflictor = spectatee.dmg_inflictor;
2047         self.v_angle = spectatee.v_angle;
2048         self.angles = spectatee.v_angle;
2049         if(!self.BUTTON_USE)
2050                 self.fixangle = TRUE;
2051         setorigin(self, spectatee.origin);
2052         setsize(self, spectatee.mins, spectatee.maxs);
2053         SetZoomState(spectatee.zoomstate);
2054
2055     anticheat_spectatecopy(spectatee);
2056         self.hud = spectatee.hud;
2057         if(spectatee.vehicle)
2058     {
2059         self.fixangle = FALSE;
2060         //self.velocity = spectatee.vehicle.velocity;
2061         self.vehicle_health = spectatee.vehicle_health;
2062         self.vehicle_shield = spectatee.vehicle_shield;
2063         self.vehicle_energy = spectatee.vehicle_energy;
2064         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2065         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2066         self.vehicle_reload1 = spectatee.vehicle_reload1;
2067         self.vehicle_reload2 = spectatee.vehicle_reload2;
2068
2069         msg_entity = self;
2070
2071         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2072             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2073             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2074             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2075
2076         //WriteByte (MSG_ONE, SVC_SETVIEW);
2077         //    WriteEntity(MSG_ONE, self);
2078         //makevectors(spectatee.v_angle);
2079         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2080     }
2081 }
2082
2083 float SpectateUpdate() {
2084         if(!self.enemy)
2085             return 0;
2086
2087         if (self == self.enemy)
2088                 return 0;
2089
2090         if(self.enemy.classname != "player")
2091                 return 0;
2092
2093         SpectateCopy(self.enemy);
2094
2095         return 1;
2096 }
2097
2098
2099 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2100 entity CA_SpectateNext(entity start) {
2101         if (start.team == self.team) {
2102                 return start;
2103         }
2104
2105         other = start;
2106         // continue from current player
2107         while(other && other.team != self.team) {
2108                 other = find(other, classname, "player");
2109         }
2110
2111         if (!other) {
2112                 // restart from begining
2113                 other = find(other, classname, "player");
2114                 while(other && other.team != self.team) {
2115                         other = find(other, classname, "player");
2116                 }
2117         }
2118
2119         return other;
2120 }
2121
2122 float SpectateNext(entity _prefer) {
2123
2124         if(_prefer)
2125                 other = _prefer;
2126         else
2127                 other = find(self.enemy, classname, "player");
2128
2129         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2130                 // CA and ca players when spectating enemies is forbidden
2131                 other = CA_SpectateNext(other);
2132         } else {
2133                 // other modes and ca spectators or spectating enemies is allowed
2134                 if (!other)
2135                         other = find(other, classname, "player");
2136         }
2137
2138         if (other)
2139                 self.enemy = other;
2140
2141         if(self.enemy.classname == "player") {
2142             /*if(self.enemy.vehicle)
2143             {
2144
2145             msg_entity = self;
2146             WriteByte(MSG_ONE, SVC_SETVIEW);
2147             WriteEntity(MSG_ONE, self.enemy);
2148             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2149
2150             self.movetype = MOVETYPE_NONE;
2151             accuracy_resend(self);
2152             }
2153             else
2154             {*/
2155             msg_entity = self;
2156             WriteByte(MSG_ONE, SVC_SETVIEW);
2157             WriteEntity(MSG_ONE, self.enemy);
2158             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2159             self.movetype = MOVETYPE_NONE;
2160             accuracy_resend(self);
2161
2162             if(!SpectateUpdate())
2163                 PutObserverInServer();
2164         //}
2165         return 1;
2166         } else {
2167                 return 0;
2168         }
2169 }
2170
2171 /*
2172 =============
2173 ShowRespawnCountdown()
2174
2175 Update a respawn countdown display.
2176 =============
2177 */
2178 void ShowRespawnCountdown()
2179 {
2180         float number;
2181         if(self.deadflag == DEAD_NO) // just respawned?
2182                 return;
2183         else
2184         {
2185                 number = ceil(self.respawn_time - time);
2186                 if(number <= 0)
2187                         return;
2188                 if(number <= self.respawn_countdown)
2189                 {
2190                         self.respawn_countdown = number - 1;
2191                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2192                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2193                 }
2194         }
2195 }
2196
2197 void LeaveSpectatorMode()
2198 {
2199         if(self.caplayer)
2200                 return;
2201         if(nJoinAllowed(self))
2202         {
2203                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2204                 {
2205                         self.classname = "player";
2206
2207                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2208                                 { JoinBestTeam(self, FALSE, TRUE); }
2209
2210                         if(autocvar_g_campaign)
2211                                 { campaign_bots_may_start = 1; }
2212
2213                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2214
2215                         PutClientInServer();
2216
2217                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2218                 }
2219                 else
2220                         stuffcmd(self, "menu_showteamselect\n");
2221         }
2222         else
2223         {
2224                 // Player may not join because g_maxplayers is set
2225                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2226         }
2227 }
2228
2229 /**
2230  * Determines whether the player is allowed to join. This depends on cvar
2231  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2232  * it checks whether the number of currently playing players exceeds g_maxplayers.
2233  * @return int number of free slots for players, 0 if none
2234  */
2235 float nJoinAllowed(entity ignore) {
2236         if(!ignore)
2237         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2238         // so report 0 free slots if restricted
2239         {
2240                 if(autocvar_g_forced_team_otherwise == "spectate")
2241                         return 0;
2242                 if(autocvar_g_forced_team_otherwise == "spectator")
2243                         return 0;
2244         }
2245
2246         if(self.team_forced < 0)
2247                 return 0; // forced spectators can never join
2248
2249         // TODO simplify this
2250         entity e;
2251         float totalClients = 0;
2252         FOR_EACH_CLIENT(e)
2253                 if(e != ignore)
2254                         totalClients += 1;
2255
2256         if (!autocvar_g_maxplayers)
2257                 return maxclients - totalClients;
2258
2259         float currentlyPlaying = 0;
2260         FOR_EACH_REALCLIENT(e)
2261                 if(e.classname == "player" || e.caplayer == 1)
2262                         currentlyPlaying += 1;
2263
2264         if(currentlyPlaying < autocvar_g_maxplayers)
2265                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2266
2267         return 0;
2268 }
2269
2270 /**
2271  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2272  * g_maxplayers_spectator_blocktime seconds
2273  */
2274 void checkSpectatorBlock() {
2275         if(self.classname == "spectator" || self.classname == "observer") {
2276                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2277                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2278                         dropclient(self);
2279                 }
2280         }
2281 }
2282
2283 void PrintWelcomeMessage()
2284 {
2285         if(self.motd_actived_time == 0)
2286         {
2287                 if (autocvar_g_campaign) {
2288                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2289                                 self.motd_actived_time = time;
2290                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2291                         }
2292                 } else {
2293                         if (self.BUTTON_INFO) {
2294                                 self.motd_actived_time = time;
2295                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2296                         }
2297                 }
2298         }
2299         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2300         {
2301                 if (autocvar_g_campaign) {
2302                         if (self.BUTTON_INFO)
2303                                 self.motd_actived_time = time;
2304                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2305                                 self.motd_actived_time = 0;
2306                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2307                         }
2308                 } else {
2309                         if (self.BUTTON_INFO)
2310                                 self.motd_actived_time = time;
2311                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2312                                 self.motd_actived_time = 0;
2313                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2314                         }
2315                 }
2316         }
2317         else //if(self.motd_actived_time < 0) // just connected, motd is active
2318         {
2319                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2320                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2321                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2322                 {
2323                         // instanctly hide MOTD
2324                         self.motd_actived_time = 0;
2325                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2326                 }
2327         }
2328 }
2329
2330 void ObserverThink()
2331 {
2332         float prefered_movetype;
2333         if (self.flags & FL_JUMPRELEASED) {
2334                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2335                         self.flags &~= FL_JUMPRELEASED;
2336                         self.flags |= FL_SPAWNING;
2337                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2338                         self.flags &~= FL_JUMPRELEASED;
2339                         if(SpectateNext(world) == 1) {
2340                                 self.classname = "spectator";
2341                         }
2342                 } else {
2343                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2344                         if (self.movetype != prefered_movetype)
2345                                 self.movetype = prefered_movetype;
2346                 }
2347         } else {
2348                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2349                         self.flags |= FL_JUMPRELEASED;
2350                         if(self.flags & FL_SPAWNING)
2351                         {
2352                                 self.flags &~= FL_SPAWNING;
2353                                 LeaveSpectatorMode();
2354                                 return;
2355                         }
2356                 }
2357         }
2358 }
2359
2360 void SpectatorThink()
2361 {
2362         if (self.flags & FL_JUMPRELEASED) {
2363                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2364                         self.flags &~= FL_JUMPRELEASED;
2365                         self.flags |= FL_SPAWNING;
2366                 } else if(self.BUTTON_ATCK) {
2367                         self.flags &~= FL_JUMPRELEASED;
2368                         if(SpectateNext(world) == 1) {
2369                                 self.classname = "spectator";
2370                         } else {
2371                                 self.classname = "observer";
2372                                 PutClientInServer();
2373                         }
2374                 } else if (self.BUTTON_ATCK2) {
2375                         self.flags &~= FL_JUMPRELEASED;
2376                         self.classname = "observer";
2377                         PutClientInServer();
2378                 } else {
2379                         if(!SpectateUpdate())
2380                                 PutObserverInServer();
2381                 }
2382         } else {
2383                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2384                         self.flags |= FL_JUMPRELEASED;
2385                         if(self.flags & FL_SPAWNING)
2386                         {
2387                                 self.flags &~= FL_SPAWNING;
2388                                 LeaveSpectatorMode();
2389                                 return;
2390                         }
2391                 }
2392                 if(!SpectateUpdate())
2393                         PutObserverInServer();
2394         }
2395
2396         self.flags |= FL_CLIENT | FL_NOTARGET;
2397 }
2398
2399 void PlayerUseKey()
2400 {
2401         if(self.classname != "player")
2402                 return;
2403
2404         if(self.vehicle)
2405         {
2406         vehicles_exit(VHEF_NORMAL);
2407         return;
2408         }
2409
2410         // a use key was pressed; call handlers
2411         MUTATOR_CALLHOOK(PlayerUseKey);
2412 }
2413
2414 /*
2415 =============
2416 PlayerPreThink
2417
2418 Called every frame for each client before the physics are run
2419 =============
2420 */
2421 .float usekeypressed;
2422 void() nexball_setstatus;
2423 .float items_added;
2424 void PlayerPreThink (void)
2425 {
2426         WarpZone_PlayerPhysics_FixVAngle();
2427
2428         self.stat_game_starttime = game_starttime;
2429         self.stat_round_starttime = round_starttime;
2430         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2431         self.stat_leadlimit = autocvar_leadlimit;
2432
2433         if(frametime)
2434         {
2435                 // physics frames: update anticheat stuff
2436                 anticheat_prethink();
2437         }
2438
2439         if(blockSpectators && frametime)
2440                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2441                 checkSpectatorBlock();
2442
2443         zoomstate_set = 0;
2444
2445         if(self.netname_previous != self.netname)
2446         {
2447                 if(autocvar_sv_eventlog)
2448                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2449                 if(self.netname_previous)
2450                         strunzone(self.netname_previous);
2451                 self.netname_previous = strzone(self.netname);
2452         }
2453
2454         // version nagging
2455         if(self.version_nagtime)
2456                 if(self.cvar_g_xonoticversion)
2457                         if(time > self.version_nagtime)
2458                         {
2459                                 // don't notify git users
2460                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2461                                 {
2462                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2463                                         {
2464                                                 // notify release users if connecting to git
2465                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2466                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2467                                         }
2468                                         else
2469                                         {
2470                                                 float r;
2471                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2472                                                 if(r < 0)
2473                                                 {
2474                                                         // give users new version
2475                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2476                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2477                                                 }
2478                                                 else if(r > 0)
2479                                                 {
2480                                                         // notify users about old server version
2481                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2482                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2483                                                 }
2484                                         }
2485                                 }
2486                                 self.version_nagtime = 0;
2487                         }
2488
2489         // GOD MODE info
2490         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2491         {
2492                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2493                 self.max_armorvalue = 0;
2494         }
2495
2496 #ifdef TETRIS
2497         if (TetrisPreFrame())
2498                 return;
2499 #endif
2500
2501         MUTATOR_CALLHOOK(PlayerPreThink);
2502
2503         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2504         {
2505                 if(self.BUTTON_USE && !self.usekeypressed)
2506                         PlayerUseKey();
2507                 self.usekeypressed = self.BUTTON_USE;
2508         }
2509
2510         if(clienttype(self) == CLIENTTYPE_REAL)
2511                 PrintWelcomeMessage();
2512
2513         if(self.classname == "player") {
2514
2515                 CheckRules_Player();
2516
2517                 if (intermission_running)
2518                 {
2519                         IntermissionThink ();   // otherwise a button could be missed between
2520                         return;                                 // the think tics
2521                 }
2522
2523                 //don't allow the player to turn around while game is paused!
2524                 if(timeout_status == TIMEOUT_ACTIVE) {
2525                         // FIXME turn this into CSQC stuff
2526                         self.v_angle = self.lastV_angle;
2527                         self.angles = self.lastV_angle;
2528                         self.fixangle = TRUE;
2529                 }
2530
2531                 if(frametime)
2532                 {
2533                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2534                         {
2535                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2536                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2537                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2538
2539                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2540                                 {
2541                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2542                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2543                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2544                                 }
2545                         }
2546                         else
2547                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2548
2549                         player_powerups();
2550                 }
2551
2552                 if (g_minstagib)
2553                         minstagib_ammocheck();
2554
2555                 if (self.deadflag != DEAD_NO)
2556                 {
2557                         if(self.personal && g_race_qualifying)
2558                         {
2559                                 if(time > self.respawn_time)
2560                                 {
2561                                         self.respawn_time = time + 1; // only retry once a second
2562                                         self.stat_respawn_time = self.respawn_time;
2563                                         respawn();
2564                                         self.impulse = 141;
2565                                 }
2566                         }
2567                         else
2568                         {
2569                                 float button_pressed;
2570                                 if(frametime)
2571                                         player_anim();
2572                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2573
2574                                 if (self.deadflag == DEAD_DYING)
2575                                 {
2576                                         if(self.respawn_flags & RESPAWN_FORCE)
2577                                                 self.deadflag = DEAD_RESPAWNING;
2578                                         else if(!button_pressed)
2579                                                 self.deadflag = DEAD_DEAD;
2580                                 }
2581                                 else if (self.deadflag == DEAD_DEAD)
2582                                 {
2583                                         if(button_pressed)
2584                                                 self.deadflag = DEAD_RESPAWNABLE;
2585                                 }
2586                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2587                                 {
2588                                         if(!button_pressed)
2589                                                 self.deadflag = DEAD_RESPAWNING;
2590                                 }
2591                                 else if (self.deadflag == DEAD_RESPAWNING)
2592                                 {
2593                                         if(time > self.respawn_time)
2594                                         {
2595                                                 self.respawn_time = time + 1; // only retry once a second
2596                                                 respawn();
2597                                         }
2598                                 }
2599
2600                                 ShowRespawnCountdown();
2601
2602                                 if(self.respawn_flags & RESPAWN_SILENT)
2603                                         self.stat_respawn_time = 0;
2604                                 else
2605                                         self.stat_respawn_time = self.respawn_time;
2606                         }
2607
2608                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2609                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2610                                 self.stat_respawn_time *= -1;
2611
2612                         return;
2613                 }
2614
2615                 self.prevorigin = self.origin;
2616
2617                 float do_crouch = self.BUTTON_CROUCH;
2618                 if(self.hook.state)
2619                         do_crouch = 0;
2620                 if(self.health <= g_bloodloss)
2621                         do_crouch = 1;
2622                 if(self.vehicle)
2623                         do_crouch = 0;
2624                 if(self.freezetag_frozen)
2625                         do_crouch = 0;
2626                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2627                         do_crouch = 0;
2628
2629                 if (do_crouch)
2630                 {
2631                         if (!self.crouch)
2632                         {
2633                                 self.crouch = TRUE;
2634                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2635                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2636                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2637                         }
2638                 }
2639                 else
2640                 {
2641                         if (self.crouch)
2642                         {
2643                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2644                                 if (!trace_startsolid)
2645                                 {
2646                                         self.crouch = FALSE;
2647                                         self.view_ofs = PL_VIEW_OFS;
2648                                         setsize (self, PL_MIN, PL_MAX);
2649                                 }
2650                         }
2651                 }
2652
2653                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2654                 {
2655                         if(self.bloodloss_timer < time)
2656                         {
2657                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2658                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2659                         }
2660                 }
2661
2662                 FixPlayermodel();
2663
2664                 GrapplingHookFrame();
2665
2666                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2667                 //if(frametime)
2668                 {
2669                         self.items &~= self.items_added;
2670
2671                         W_WeaponFrame();
2672
2673                         self.items_added = 0;
2674                         if(self.items & IT_JETPACK)
2675                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2676                                         self.items_added |= IT_FUEL;
2677
2678                         self.items |= self.items_added;
2679                 }
2680
2681                 player_regen();
2682
2683                 // rot nex charge to the charge limit
2684                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2685                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2686
2687                 if(frametime)
2688                         player_anim();
2689
2690                 if(g_nexball)
2691                         nexball_setstatus();
2692
2693                 // secret status
2694                 secrets_setstatus();
2695
2696                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2697
2698                 //self.angles_y=self.v_angle_y + 90;   // temp
2699         } else if(gameover) {
2700                 if (intermission_running)
2701                         IntermissionThink ();   // otherwise a button could be missed between
2702                 return;
2703         } else if(self.classname == "observer") {
2704                 ObserverThink();
2705         } else if(self.classname == "spectator") {
2706                 SpectatorThink();
2707         }
2708
2709         if(!zoomstate_set)
2710                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2711
2712         float oldspectatee_status;
2713         oldspectatee_status = self.spectatee_status;
2714         if(self.classname == "spectator")
2715                 self.spectatee_status = num_for_edict(self.enemy);
2716         else if(self.classname == "observer")
2717                 self.spectatee_status = num_for_edict(self);
2718         else
2719                 self.spectatee_status = 0;
2720         if(self.spectatee_status != oldspectatee_status)
2721         {
2722                 ClientData_Touch(self);
2723                 if(g_race || g_cts)
2724                         race_InitSpectator();
2725         }
2726
2727         if(self.teamkill_soundtime)
2728         if(time > self.teamkill_soundtime)
2729         {
2730                 self.teamkill_soundtime = 0;
2731
2732                 entity oldpusher, oldself;
2733
2734                 oldself = self; self = self.teamkill_soundsource;
2735                 oldpusher = self.pusher; self.pusher = oldself;
2736
2737                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2738
2739                 self.pusher = oldpusher;
2740                 self = oldself;
2741         }
2742
2743         if(self.taunt_soundtime)
2744         if(time > self.taunt_soundtime)
2745         {
2746                 self.taunt_soundtime = 0;
2747                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2748         }
2749
2750         target_voicescript_next(self);
2751
2752         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2753         if(!self.weapon)
2754                 self.clip_load = self.clip_size = 0;
2755 }
2756
2757 float isInvisibleString(string s)
2758 {
2759         float i, n, c;
2760         s = strdecolorize(s);
2761         for((i = 0), (n = strlen(s)); i < n; ++i)
2762         {
2763                 c = str2chr(s, i);
2764                 switch(c)
2765                 {
2766                         case 0:
2767                         case 32: // space
2768                                 break;
2769                         case 192: // charmap space
2770                                 if (!autocvar_utf8_enable)
2771                                         break;
2772                                 return FALSE;
2773                         case 160: // space in unicode fonts
2774                         case 0xE000 + 192: // utf8 charmap space
2775                                 if (autocvar_utf8_enable)
2776                                         break;
2777                         default:
2778                                 return FALSE;
2779                 }
2780         }
2781         return TRUE;
2782 }
2783
2784 /*
2785 =============
2786 PlayerPostThink
2787
2788 Called every frame for each client after the physics are run
2789 =============
2790 */
2791 .float idlekick_lasttimeleft;
2792 void PlayerPostThink (void)
2793 {
2794         // Savage: Check for nameless players
2795         if (isInvisibleString(self.netname)) {
2796                 self.netname = "Player";
2797                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2798         }
2799
2800         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2801         {
2802                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2803                 {
2804                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2805                 }
2806                 else
2807                 {
2808                         float timeleft;
2809                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2810                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2811                         {
2812                                 if(!self.idlekick_lasttimeleft)
2813                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2814                         }
2815                         if(timeleft <= 0)
2816                         {
2817                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2818                                 dropclient(self);
2819                                 return;
2820                         }
2821                         else if(timeleft <= 10)
2822                         {
2823                                 if(timeleft != self.idlekick_lasttimeleft)
2824                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2825                                 self.idlekick_lasttimeleft = timeleft;
2826                         }
2827                 }
2828         }
2829
2830 #ifdef TETRIS
2831         if(self.impulse == 100)
2832                 ImpulseCommands();
2833         if (!TetrisPostFrame())
2834         {
2835 #endif
2836
2837         CheatFrame();
2838
2839         //CheckPlayerJump();
2840
2841         if(self.classname == "player") {
2842                 CheckRules_Player();
2843                 UpdateChatBubble();
2844                 if (self.impulse)
2845                         ImpulseCommands();
2846                 if (intermission_running)
2847                         return;         // intermission or finale
2848                 GetPressedKeys();
2849         }
2850
2851 #ifdef TETRIS
2852         }
2853 #endif
2854
2855         /*
2856         float i;
2857         for(i = 0; i < 1000; ++i)
2858         {
2859                 vector end;
2860                 end = self.origin + '0 0 1024' + 512 * randomvec();
2861                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2862                 if(trace_fraction < 1)
2863                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2864                 {
2865                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2866                         break;
2867                 }
2868         }
2869         */
2870
2871         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2872
2873         if(self.waypointsprite_attachedforcarrier)
2874                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2875
2876         playerdemo_write();
2877
2878         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2879         {
2880                 if not(self.stored_netname)
2881                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2882                 if(self.stored_netname != self.netname)
2883                 {
2884                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2885                         strunzone(self.stored_netname);
2886                         self.stored_netname = strzone(self.netname);
2887                 }
2888         }
2889
2890         /*
2891         if(g_race)
2892                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2893         */
2894
2895         CSQCMODEL_AUTOUPDATE();
2896 }