qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     WITHSELF(this, ClientConnect());
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     WITHSELF(this, PutClientInServer());
  63 }
  64
  65 void PutObserverInServer();
  66 void ClientDisconnect();
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     WITHSELF(this, PutClientInServer());
  72     WITHSELF(this, ClientDisconnect());
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 bool ClientData_Send(entity this, entity to, int sf)
  80 {
  81         assert(to == this.owner, return false);
  82
  83         entity e = to;
  84         if (IS_SPEC(e)) e = e.enemy;
  85
  86         sf = 0;
  87         if (e.race_completed)       sf |= 1; // forced scoreboard
  88         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
  89         if (e.zoomstate)            sf |= 4; // zoomed
  90         if (e.porto_v_angle_held)   sf |= 8; // angles held
  91
  92         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  93         WriteByte(MSG_ENTITY, sf);
  94
  95         if (sf & 2)
  96         {
  97                 WriteByte(MSG_ENTITY, to.spectatee_status);
  98         }
  99         if (sf & 8)
 100         {
 101                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 102                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 103         }
 104         return true;
 105 }
 106
 107 void ClientData_Attach(entity this)
 108 {
 109         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 110         this.clientdata.drawonlytoclient = this;
 111         this.clientdata.owner = this;
 112 }
 113
 114 void ClientData_Detach(entity this)
 115 {
 116         remove(this.clientdata);
 117         this.clientdata = NULL;
 118 }
 119
 120 void ClientData_Touch(entity e)
 121 {
 122         e.clientdata.SendFlags = 1;
 123
 124         // make it spectatable
 125         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 126 }
 127
 128 .string netname_previous;
 129
 130 void SetSpectatee(entity player, entity spectatee);
 131
 132
 133 /*
 134 =============
 135 CheckPlayerModel
 136
 137 Checks if the argument string can be a valid playermodel.
 138 Returns a valid one in doubt.
 139 =============
 140 */
 141 string FallbackPlayerModel;
 142 string CheckPlayerModel(string plyermodel) {
 143         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 144         {
 145                 // note: we cannot summon Don Strunzone here, some player may
 146                 // still have the model string set. In case anyone manages how
 147                 // to change a cvar default, we'll have a small leak here.
 148                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 149         }
 150         // only in right path
 151         if( substring(plyermodel,0,14) != "models/player/")
 152                 return FallbackPlayerModel;
 153         // only good file extensions
 154         if(substring(plyermodel,-4,4) != ".zym")
 155         if(substring(plyermodel,-4,4) != ".dpm")
 156         if(substring(plyermodel,-4,4) != ".iqm")
 157         if(substring(plyermodel,-4,4) != ".md3")
 158         if(substring(plyermodel,-4,4) != ".psk")
 159                 return FallbackPlayerModel;
 160         // forbid the LOD models
 161         if(substring(plyermodel, -9,5) == "_lod1")
 162                 return FallbackPlayerModel;
 163         if(substring(plyermodel, -9,5) == "_lod2")
 164                 return FallbackPlayerModel;
 165         if(plyermodel != strtolower(plyermodel))
 166                 return FallbackPlayerModel;
 167         // also, restrict to server models
 168         if(autocvar_sv_servermodelsonly)
 169         {
 170                 if(!fexists(plyermodel))
 171                         return FallbackPlayerModel;
 172         }
 173         return plyermodel;
 174 }
 175
 176 void setplayermodel(entity e, string modelname)
 177 {
 178         precache_model(modelname);
 179         _setmodel(e, modelname);
 180         player_setupanimsformodel();
 181         if(!autocvar_g_debug_globalsounds)
 182                 UpdatePlayerSounds(e);
 183 }
 184
 185 void FixPlayermodel(entity player);
 186 /** putting a client as observer in the server */
 187 void PutObserverInServer()
 188 {
 189         SELFPARAM();
 190     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 191         PlayerState_detach(this);
 192
 193         if (IS_PLAYER(this) && this.health >= 1) {
 194         // despawn effect
 195                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 196     }
 197
 198     {
 199         entity spot = SelectSpawnPoint(true);
 200         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 201         this.angles = spot.angles;
 202         this.angles_z = 0;
 203         this.fixangle = true;
 204         // offset it so that the spectator spawns higher off the ground, looks better this way
 205         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 206         this.prevorigin = this.origin;
 207         if (IS_REAL_CLIENT(this))
 208         {
 209             msg_entity = this;
 210             WriteByte(MSG_ONE, SVC_SETVIEW);
 211             WriteEntity(MSG_ONE, this);
 212         }
 213         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 214         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 215         if(!autocvar_g_debug_globalsounds)
 216         {
 217                 // needed for player sounds
 218                 this.model = "";
 219                 FixPlayermodel(this);
 220         }
 221         setmodel(this, MDL_Null);
 222         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 223         this.view_ofs = '0 0 0';
 224     }
 225
 226     RemoveGrapplingHook(this);
 227         Portal_ClearAll(this);
 228         Unfreeze(this);
 229
 230         if (this.alivetime)
 231         {
 232                 if (!warmup_stage)
 233                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 234                 this.alivetime = 0;
 235         }
 236
 237         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
 238
 239         WaypointSprite_PlayerDead(this);
 240
 241         if (mutator_returnvalue) {
 242             // mutator prevents resetting teams+score
 243         } else {
 244                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 245         this.frags = FRAGS_SPECTATOR;
 246         PlayerScore_Clear(this);  // clear scores when needed
 247     }
 248
 249         if (this.killcount != FRAGS_SPECTATOR)
 250         {
 251                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 252                 if(!intermission_running)
 253                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 254                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 255
 256                 if(this.just_joined == false) {
 257                         LogTeamchange(this.playerid, -1, 4);
 258                 } else
 259                         this.just_joined = false;
 260         }
 261
 262         accuracy_resend(this);
 263
 264         this.spectatortime = time;
 265         this.bot_attack = false;
 266     this.hud = HUD_NORMAL;
 267         TRANSMUTE(Observer, this);
 268         this.iscreature = false;
 269         this.teleportable = TELEPORT_SIMPLE;
 270         this.damagedbycontents = false;
 271         this.health = FRAGS_SPECTATOR;
 272         this.takedamage = DAMAGE_NO;
 273         this.solid = SOLID_NOT;
 274         this.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 275         this.flags = FL_CLIENT | FL_NOTARGET;
 276         this.armorvalue = 666;
 277         this.effects = 0;
 278         this.armorvalue = autocvar_g_balance_armor_start;
 279         this.pauserotarmor_finished = 0;
 280         this.pauserothealth_finished = 0;
 281         this.pauseregen_finished = 0;
 282         this.damageforcescale = 0;
 283         this.death_time = 0;
 284         this.respawn_flags = 0;
 285         this.respawn_time = 0;
 286         this.stat_respawn_time = 0;
 287         this.alpha = 0;
 288         this.scale = 0;
 289         this.fade_time = 0;
 290         this.pain_frame = 0;
 291         this.pain_finished = 0;
 292         this.strength_finished = 0;
 293         this.invincible_finished = 0;
 294         this.superweapons_finished = 0;
 295         this.pushltime = 0;
 296         this.istypefrag = 0;
 297         this.think = func_null;
 298         this.nextthink = 0;
 299         this.hook_time = 0;
 300         this.deadflag = DEAD_NO;
 301         this.crouch = false;
 302         this.revival_time = 0;
 303
 304         this.items = 0;
 305         this.weapons = '0 0 0';
 306         this.drawonlytoclient = this;
 307
 308         this.weaponname = "";
 309         this.weaponmodel = "";
 310         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 311         {
 312                 this.weaponentities[slot] = NULL;
 313         }
 314         this.exteriorweaponentity = NULL;
 315         this.killcount = FRAGS_SPECTATOR;
 316         this.velocity = '0 0 0';
 317         this.avelocity = '0 0 0';
 318         this.punchangle = '0 0 0';
 319         this.punchvector = '0 0 0';
 320         this.oldvelocity = this.velocity;
 321         this.fire_endtime = -1;
 322         this.event_damage = func_null;
 323 }
 324
 325 int player_getspecies(entity this)
 326 {
 327         get_model_parameters(this.model, this.skin);
 328         int s = get_model_parameters_species;
 329         get_model_parameters(string_null, 0);
 330         if (s < 0) return SPECIES_HUMAN;
 331         return s;
 332 }
 333
 334 .float model_randomizer;
 335 void FixPlayermodel(entity player)
 336 {
 337         string defaultmodel = "";
 338         int defaultskin = 0;
 339         if(autocvar_sv_defaultcharacter)
 340         {
 341                 if(teamplay)
 342                 {
 343                         string s = Static_Team_ColorName_Lower(player.team);
 344                         if (s != "neutral")
 345                         {
 346                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 347                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 348                         }
 349                 }
 350
 351                 if(defaultmodel == "")
 352                 {
 353                         defaultmodel = autocvar_sv_defaultplayermodel;
 354                         defaultskin = autocvar_sv_defaultplayerskin;
 355                 }
 356
 357                 int n = tokenize_console(defaultmodel);
 358                 if(n > 0)
 359                 {
 360                         defaultmodel = argv(floor(n * player.model_randomizer));
 361                         // However, do NOT randomize if the player-selected model is in the list.
 362                         for (int i = 0; i < n; ++i)
 363                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 364                                         defaultmodel = argv(i);
 365                 }
 366
 367                 int i = strstrofs(defaultmodel, ":", 0);
 368                 if(i >= 0)
 369                 {
 370                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 371                         defaultmodel = substring(defaultmodel, 0, i);
 372                 }
 373         }
 374         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 375         defaultmodel = ret_string;
 376         defaultskin = ret_int;
 377
 378         bool chmdl = false;
 379         int oldskin;
 380         if(defaultmodel != "")
 381         {
 382                 if (defaultmodel != player.model)
 383                 {
 384                         vector m1 = player.mins;
 385                         vector m2 = player.maxs;
 386                         setplayermodel (player, defaultmodel);
 387                         setsize (player, m1, m2);
 388                         chmdl = true;
 389                 }
 390
 391                 oldskin = player.skin;
 392                 player.skin = defaultskin;
 393         } else {
 394                 if (player.playermodel != player.model || player.playermodel == "")
 395                 {
 396                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 397                         vector m1 = player.mins;
 398                         vector m2 = player.maxs;
 399                         setplayermodel (player, player.playermodel);
 400                         setsize (player, m1, m2);
 401                         chmdl = true;
 402                 }
 403
 404                 oldskin = player.skin;
 405                 player.skin = stof(player.playerskin);
 406         }
 407
 408         if(chmdl || oldskin != player.skin) // model or skin has changed
 409         {
 410                 player.species = player_getspecies(player); // update species
 411                 if(!autocvar_g_debug_globalsounds)
 412                         UpdatePlayerSounds(player); // update skin sounds
 413         }
 414
 415         if(!teamplay)
 416                 if(strlen(autocvar_sv_defaultplayercolors))
 417                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 418                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 419 }
 420
 421
 422 /** Called when a client spawns in the server */
 423 void PutClientInServer()
 424 {
 425         SELFPARAM();
 426         if (IS_BOT_CLIENT(this)) {
 427                 TRANSMUTE(Player, this);
 428         } else if (IS_REAL_CLIENT(this)) {
 429                 msg_entity = this;
 430                 WriteByte(MSG_ONE, SVC_SETVIEW);
 431                 WriteEntity(MSG_ONE, this);
 432         }
 433         if (gameover) {
 434                 TRANSMUTE(Observer, this);
 435         }
 436
 437         SetSpectatee(this, NULL);
 438
 439         // reset player keys
 440         this.itemkeys = 0;
 441
 442         MUTATOR_CALLHOOK(PutClientInServer, this);
 443
 444         if (IS_OBSERVER(this)) {
 445                 PutObserverInServer();
 446         } else if (IS_PLAYER(this)) {
 447                 PlayerState_attach(this);
 448                 accuracy_resend(this);
 449
 450                 if (this.team < 0)
 451                         JoinBestTeam(this, false, true);
 452
 453                 entity spot = SelectSpawnPoint(false);
 454                 if (!spot) {
 455                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 456                         return; // spawn failed
 457                 }
 458
 459                 TRANSMUTE(Player, this);
 460                 this.wasplayer = true;
 461                 this.iscreature = true;
 462                 this.teleportable = TELEPORT_NORMAL;
 463                 this.damagedbycontents = true;
 464                 this.movetype = MOVETYPE_WALK;
 465                 this.solid = SOLID_SLIDEBOX;
 466                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 467                 if (autocvar_g_playerclip_collisions)
 468                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 469                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 470                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 471                 this.frags = FRAGS_PLAYER;
 472                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 473                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 474                 if (autocvar__notarget)
 475                         this.flags |= FL_NOTARGET;
 476                 this.takedamage = DAMAGE_AIM;
 477                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 478                 this.dmg = 2; // WTF
 479
 480                 if (warmup_stage) {
 481                         this.ammo_shells = warmup_start_ammo_shells;
 482                         this.ammo_nails = warmup_start_ammo_nails;
 483                         this.ammo_rockets = warmup_start_ammo_rockets;
 484                         this.ammo_cells = warmup_start_ammo_cells;
 485                         this.ammo_plasma = warmup_start_ammo_plasma;
 486                         this.ammo_fuel = warmup_start_ammo_fuel;
 487                         this.health = warmup_start_health;
 488                         this.armorvalue = warmup_start_armorvalue;
 489                         this.weapons = WARMUP_START_WEAPONS;
 490                 } else {
 491                         this.ammo_shells = start_ammo_shells;
 492                         this.ammo_nails = start_ammo_nails;
 493                         this.ammo_rockets = start_ammo_rockets;
 494                         this.ammo_cells = start_ammo_cells;
 495                         this.ammo_plasma = start_ammo_plasma;
 496                         this.ammo_fuel = start_ammo_fuel;
 497                         this.health = start_health;
 498                         this.armorvalue = start_armorvalue;
 499                         this.weapons = start_weapons;
 500                 }
 501
 502                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 503
 504                 this.items = start_items;
 505
 506                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 507                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 508                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 509                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 510                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 511                 // extend the pause of rotting if client was reset at the beginning of the countdown
 512                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 513                         float f = game_starttime - time;
 514                         this.spawnshieldtime += f;
 515                         this.pauserotarmor_finished += f;
 516                         this.pauserothealth_finished += f;
 517                         this.pauseregen_finished += f;
 518                 }
 519                 this.damageforcescale = 2;
 520                 this.death_time = 0;
 521                 this.respawn_flags = 0;
 522                 this.respawn_time = 0;
 523                 this.stat_respawn_time = 0;
 524                 this.scale = autocvar_sv_player_scale;
 525                 this.fade_time = 0;
 526                 this.pain_frame = 0;
 527                 this.pain_finished = 0;
 528                 this.pushltime = 0;
 529                 this.think = func_null; // players have no think function
 530                 this.nextthink = 0;
 531                 this.dmg_team = 0;
 532                 this.ballistics_density = autocvar_g_ballistics_density_player;
 533
 534                 this.deadflag = DEAD_NO;
 535
 536                 this.angles = spot.angles;
 537                 this.angles_z = 0; // never spawn tilted even if the spot says to
 538                 if (IS_BOT_CLIENT(this))
 539                         this.v_angle = this.angles;
 540                 this.fixangle = true; // turn this way immediately
 541                 this.oldvelocity = this.velocity = '0 0 0';
 542                 this.avelocity = '0 0 0';
 543                 this.punchangle = '0 0 0';
 544                 this.punchvector = '0 0 0';
 545
 546                 this.strength_finished = 0;
 547                 this.invincible_finished = 0;
 548                 this.fire_endtime = -1;
 549                 this.revival_time = 0;
 550                 this.air_finished = time + 12;
 551
 552                 entity spawnevent = new_pure(spawnevent);
 553                 spawnevent.owner = this;
 554                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 555
 556                 // Cut off any still running player sounds.
 557                 stopsound(this, CH_PLAYER_SINGLE);
 558
 559                 this.model = "";
 560                 FixPlayermodel(this);
 561                 this.drawonlytoclient = NULL;
 562
 563                 this.crouch = false;
 564                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 565                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 566                 this.spawnorigin = spot.origin;
 567                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 568                 // don't reset back to last position, even if new position is stuck in solid
 569                 this.oldorigin = this.origin;
 570                 this.prevorigin = this.origin;
 571                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 572         this.hud = HUD_NORMAL;
 573
 574                 this.event_damage = PlayerDamage;
 575
 576                 this.bot_attack = true;
 577                 this.monster_attack = true;
 578
 579                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 580
 581                 if (this.killcount == FRAGS_SPECTATOR) {
 582                         PlayerScore_Clear(this);
 583                         this.killcount = 0;
 584                 }
 585
 586                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 587                 {
 588                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 589                 }
 590                 this.alpha = default_player_alpha;
 591                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 592                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 593
 594                 this.speedrunning = false;
 595
 596                 target_voicescript_clear(this);
 597
 598                 // reset fields the weapons may use
 599                 FOREACH(Weapons, true, LAMBDA(
 600                         it.wr_resetplayer(it);
 601                         // reload all reloadable weapons
 602                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 603                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 604                         }
 605                 ));
 606
 607                 {
 608                         string s = spot.target;
 609                         spot.target = string_null;
 610                         WITH(entity, activator, this, LAMBDA(
 611                                 WITHSELF(spot, SUB_UseTargets())
 612                         ));
 613                         spot.target = s;
 614                 }
 615
 616                 Unfreeze(this);
 617
 618                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 619
 620                 if (autocvar_spawn_debug)
 621                 {
 622                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 623                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 624                 }
 625
 626                 PS(this).m_switchweapon = w_getbestweapon(this);
 627                 this.cnt = -1; // W_LastWeapon will not complain
 628                 PS(this).m_weapon = WEP_Null;
 629                 this.weaponname = "";
 630                 PS(this).m_switchingweapon = WEP_Null;
 631
 632                 if (!warmup_stage && !this.alivetime)
 633                         this.alivetime = time;
 634
 635                 antilag_clear(this, CS(this));
 636         }
 637 }
 638
 639 void ClientInit_misc();
 640
 641 .float ebouncefactor, ebouncestop; // electro's values
 642 // TODO do we need all these fields, or should we stop autodetecting runtime
 643 // changes and just have a console command to update this?
 644 bool ClientInit_SendEntity(entity this, entity to, int sf)
 645 {
 646         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 647         return = true;
 648         msg_entity = to;
 649         // MSG_INIT replacement
 650         // TODO: make easier to use
 651         Registry_send_all();
 652         W_PROP_reload(MSG_ONE, to);
 653         ClientInit_misc();
 654         MUTATOR_CALLHOOK(Ent_Init);
 655 }
 656 void ClientInit_misc()
 657 {
 658     SELFPARAM();
 659         int channel = MSG_ONE;
 660         WriteHeader(channel, ENT_CLIENT_INIT);
 661         WriteByte(channel, g_nexball_meter_period * 32);
 662         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 663         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 664         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 665         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 666         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 667         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 668         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 669         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 670
 671         if(sv_foginterval && world.fog != "")
 672                 WriteString(channel, world.fog);
 673         else
 674                 WriteString(channel, "");
 675         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 676         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 677         WriteCoord(channel, autocvar_g_trueaim_minrange);
 678 }
 679
 680 void ClientInit_CheckUpdate()
 681 {SELFPARAM();
 682         this.nextthink = time;
 683         if(this.count != autocvar_g_balance_armor_blockpercent)
 684         {
 685                 this.count = autocvar_g_balance_armor_blockpercent;
 686                 this.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {SELFPARAM();
 692
 693         entity e = new_pure(clientinit);
 694         e.think = ClientInit_CheckUpdate;
 695         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 696
 697         WITHSELF(e, ClientInit_CheckUpdate());
 698 }
 699
 700 /*
 701 =============
 702 SetNewParms
 703 =============
 704 */
 705 void SetNewParms ()
 706 {
 707         // initialize parms for a new player
 708         parm1 = -(86400 * 366);
 709
 710         MUTATOR_CALLHOOK(SetNewParms);
 711 }
 712
 713 /*
 714 =============
 715 SetChangeParms
 716 =============
 717 */
 718 void SetChangeParms ()
 719 {SELFPARAM();
 720         // save parms for level change
 721         parm1 = this.parm_idlesince - time;
 722
 723         MUTATOR_CALLHOOK(SetChangeParms);
 724 }
 725
 726 /*
 727 =============
 728 DecodeLevelParms
 729 =============
 730 */
 731 void DecodeLevelParms(entity this)
 732 {
 733         // load parms
 734         this.parm_idlesince = parm1;
 735         if (this.parm_idlesince == -(86400 * 366))
 736                 this.parm_idlesince = time;
 737
 738         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 739         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 740
 741         MUTATOR_CALLHOOK(DecodeLevelParms);
 742 }
 743
 744 /*
 745 =============
 746 ClientKill
 747
 748 Called when a client types 'kill' in the console
 749 =============
 750 */
 751
 752 .float clientkill_nexttime;
 753 void ClientKill_Now_TeamChange(entity this)
 754 {
 755         if(this.killindicator_teamchange == -1)
 756         {
 757                 JoinBestTeam( this, false, true );
 758         }
 759         else if(this.killindicator_teamchange == -2)
 760         {
 761                 if(blockSpectators)
 762                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 763                 WITHSELF(this, PutObserverInServer());
 764         }
 765         else
 766                 WITHSELF(this, SV_ChangeTeam(this.killindicator_teamchange - 1));
 767         this.killindicator_teamchange = 0;
 768 }
 769
 770 void ClientKill_Now()
 771 {SELFPARAM();
 772         if(this.vehicle)
 773         {
 774             vehicles_exit(VHEF_RELEASE);
 775             if(!this.killindicator_teamchange)
 776             {
 777             this.vehicle_health = -1;
 778             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 779             }
 780         }
 781
 782         if(this.killindicator && !wasfreed(this.killindicator))
 783                 remove(this.killindicator);
 784
 785         this.killindicator = world;
 786
 787         if(this.killindicator_teamchange)
 788                 ClientKill_Now_TeamChange(this);
 789
 790         if(IS_PLAYER(this))
 791                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 792
 793         // now I am sure the player IS dead
 794 }
 795 void KillIndicator_Think()
 796 {SELFPARAM();
 797         if (gameover)
 798         {
 799                 this.owner.killindicator = world;
 800                 remove(this);
 801                 return;
 802         }
 803
 804         if (this.owner.alpha < 0 && !this.owner.vehicle)
 805         {
 806                 this.owner.killindicator = world;
 807                 remove(this);
 808                 return;
 809         }
 810
 811         if(this.cnt <= 0)
 812         {
 813                 WITHSELF(this.owner, ClientKill_Now());
 814                 return;
 815         }
 816     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 817     {
 818         this.nextthink = time + 1;
 819         this.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(this.cnt <= 10)
 824                         setmodel(this, MDL_NUM(this.cnt));
 825                 if(IS_REAL_CLIENT(this.owner))
 826                 {
 827                         if(this.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 829                 }
 830                 this.nextthink = time + 1;
 831                 this.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {SELFPARAM();
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 851         return;
 852
 853         this.killindicator_teamchange = targetteam;
 854
 855     if(!this.killindicator)
 856         {
 857                 if(!IS_DEAD(this))
 858                 {
 859                         killtime = max(killtime, this.clientkill_nexttime - time);
 860                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 861                 }
 862
 863                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 864                 {
 865                         ClientKill_Now();
 866                 }
 867                 else
 868                 {
 869                         starttime = max(time, clientkilltime);
 870
 871                         this.killindicator = spawn();
 872                         this.killindicator.owner = this;
 873                         this.killindicator.scale = 0.5;
 874                         setattachment(this.killindicator, this, "");
 875                         setorigin(this.killindicator, '0 0 52');
 876                         this.killindicator.think = KillIndicator_Think;
 877                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 878                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 879                         this.killindicator.cnt = ceil(killtime);
 880                         this.killindicator.count = bound(0, ceil(killtime), 10);
 881                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 882
 883                         for(e = world; (e = find(e, classname, "body")) != world; )
 884                         {
 885                                 if(e.enemy != this)
 886                                         continue;
 887                                 e.killindicator = spawn();
 888                                 e.killindicator.owner = e;
 889                                 e.killindicator.scale = 0.5;
 890                                 setattachment(e.killindicator, e, "");
 891                                 setorigin(e.killindicator, '0 0 52');
 892                                 e.killindicator.think = KillIndicator_Think;
 893                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 894                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 895                                 e.killindicator.cnt = ceil(killtime);
 896                         }
 897                         this.lip = 0;
 898                 }
 899         }
 900         if(this.killindicator)
 901         {
 902                 if(targetteam == 0) // just die
 903                 {
 904                         this.killindicator.colormod = '0 0 0';
 905                         if(IS_REAL_CLIENT(this))
 906                         if(this.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 908                 }
 909                 else if(targetteam == -1) // auto
 910                 {
 911                         this.killindicator.colormod = '0 1 0';
 912                         if(IS_REAL_CLIENT(this))
 913                         if(this.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 915                 }
 916                 else if(targetteam == -2) // spectate
 917                 {
 918                         this.killindicator.colormod = '0.5 0.5 0.5';
 919                         if(IS_REAL_CLIENT(this))
 920                         if(this.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 922                 }
 923                 else
 924                 {
 925                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 926                         if(IS_REAL_CLIENT(this))
 927                         if(this.killindicator.cnt > 0)
 928                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 929                 }
 930         }
 931
 932 }
 933
 934 void ClientKill ()
 935 {SELFPARAM();
 936         if(gameover) return;
 937         if(this.player_blocked) return;
 938         if(STAT(FROZEN, this)) return;
 939
 940         ClientKill_TeamChange(0);
 941 }
 942
 943 void FixClientCvars(entity e)
 944 {
 945         // send prediction settings to the client
 946         stuffcmd(e, "\nin_bindmap 0 0\n");
 947         if(autocvar_g_antilag == 3) // client side hitscan
 948                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 949         if(autocvar_sv_gentle)
 950                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 951
 952         MUTATOR_CALLHOOK(FixClientCvars, e);
 953 }
 954
 955 float PlayerInIDList(entity p, string idlist)
 956 {
 957         float n, i;
 958         string s;
 959
 960         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 961         if (!p.crypto_idfp)
 962                 return 0;
 963
 964         // this function allows abbreviated player IDs too!
 965         n = tokenize_console(idlist);
 966         for(i = 0; i < n; ++i)
 967         {
 968                 s = argv(i);
 969                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 970                         return 1;
 971         }
 972
 973         return 0;
 974 }
 975
 976 #ifdef DP_EXT_PRECONNECT
 977 /*
 978 =============
 979 ClientPreConnect
 980
 981 Called once (not at each match start) when a client begins a connection to the server
 982 =============
 983 */
 984 void ClientPreConnect ()
 985 {SELFPARAM();
 986         if(autocvar_sv_eventlog)
 987         {
 988                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 989                         this.playerid,
 990                         etof(this),
 991                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 992                 ));
 993         }
 994 }
 995 #endif
 996
 997 /**
 998 =============
 999 ClientConnect
1000
1001 Called when a client connects to the server
1002 =============
1003 */
1004 void ClientConnect()
1005 {
1006         SELFPARAM();
1007         if (Ban_MaybeEnforceBanOnce(this)) return;
1008         assert(!IS_CLIENT(this), return);
1009         this.flags |= FL_CLIENT;
1010         assert(player_count >= 0, player_count = 0);
1011
1012 #ifdef WATERMARK
1013         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1014 #endif
1015         this.version_nagtime = time + 10 + random() * 10;
1016         TRANSMUTE(Client, this);
1017
1018         // identify the right forced team
1019         if (autocvar_g_campaign)
1020         {
1021                 if (IS_REAL_CLIENT(this)) // only players, not bots
1022                 {
1023                         switch (autocvar_g_campaign_forceteam)
1024                         {
1025                                 case 1: this.team_forced = NUM_TEAM_1; break;
1026                                 case 2: this.team_forced = NUM_TEAM_2; break;
1027                                 case 3: this.team_forced = NUM_TEAM_3; break;
1028                                 case 4: this.team_forced = NUM_TEAM_4; break;
1029                                 default: this.team_forced = 0;
1030                         }
1031                 }
1032         }
1033         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1034         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1035         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1036         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1037         else switch (autocvar_g_forced_team_otherwise)
1038         {
1039                 default: this.team_forced = 0; break;
1040                 case "red": this.team_forced = NUM_TEAM_1; break;
1041                 case "blue": this.team_forced = NUM_TEAM_2; break;
1042                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1043                 case "pink": this.team_forced = NUM_TEAM_4; break;
1044                 case "spectate":
1045                 case "spectator":
1046                         this.team_forced = -1;
1047                         break;
1048         }
1049         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1050
1051     {
1052         int id = this.playerid;
1053         this.playerid = 0; // silent
1054             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1055             this.playerid = id;
1056     }
1057
1058         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1059                 TRANSMUTE(Observer, this);
1060         } else {
1061                 if (!teamplay || autocvar_g_balance_teams) {
1062                         TRANSMUTE(Player, this);
1063                         campaign_bots_may_start = true;
1064                 } else {
1065                         TRANSMUTE(Observer, this); // do it anyway
1066                 }
1067         }
1068
1069         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1070
1071         // always track bots, don't ask for cl_allow_uidtracking
1072     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1073
1074         if (autocvar_sv_eventlog)
1075                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1076
1077         LogTeamchange(this.playerid, this.team, 1);
1078
1079         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1080
1081         this.netname_previous = strzone(this.netname);
1082
1083         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1084
1085         stuffcmd(this, clientstuff, "\n");
1086         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1087
1088         FixClientCvars(this);
1089
1090         // get version info from player
1091         stuffcmd(this, "cmd clientversion $gameversion\n");
1092
1093         // notify about available teams
1094         if (teamplay)
1095         {
1096                 CheckAllowedTeams(this);
1097                 int t = 0;
1098                 if (c1 >= 0) t |= BIT(0);
1099                 if (c2 >= 0) t |= BIT(1);
1100                 if (c3 >= 0) t |= BIT(2);
1101                 if (c4 >= 0) t |= BIT(3);
1102                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1103         }
1104         else
1105         {
1106                 stuffcmd(this, "set _teams_available 0\n");
1107         }
1108
1109         bot_relinkplayerlist();
1110
1111         this.spectatortime = time;
1112         if (blockSpectators)
1113         {
1114                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1115         }
1116
1117         this.jointime = time;
1118         this.allowed_timeouts = autocvar_sv_timeout_number;
1119
1120         if (IS_REAL_CLIENT(this))
1121         {
1122                 if (!autocvar_g_campaign)
1123                 {
1124                         this.motd_actived_time = -1;
1125                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1126                 }
1127
1128                 if (g_weaponarena_weapons == WEPSET(TUBA))
1129                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1130         }
1131
1132         if (!sv_foginterval && world.fog != "")
1133                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1134
1135         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)))
1136                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1137                         send_CSQC_teamnagger();
1138
1139         CSQCMODEL_AUTOINIT(this);
1140
1141         this.model_randomizer = random();
1142
1143         if (IS_REAL_CLIENT(this))
1144                 sv_notice_join(this);
1145
1146         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1147                 WITHSELF(it, it.init_for_player(it));
1148         });
1149
1150         MUTATOR_CALLHOOK(ClientConnect, this);
1151 }
1152 /*
1153 =============
1154 ClientDisconnect
1155
1156 Called when a client disconnects from the server
1157 =============
1158 */
1159 .entity chatbubbleentity;
1160 void ReadyCount();
1161 void ClientDisconnect()
1162 {
1163         SELFPARAM();
1164         assert(IS_CLIENT(this), return);
1165
1166         PlayerStats_GameReport_FinalizePlayer(this);
1167         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
1168         if (this.active_minigame) part_minigame(this);
1169         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1170
1171         if (autocvar_sv_eventlog)
1172                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1173
1174         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1175
1176     MUTATOR_CALLHOOK(ClientDisconnect);
1177
1178         ClientState_detach(this);
1179
1180         Portal_ClearAll(this);
1181
1182         Unfreeze(this);
1183
1184         RemoveGrapplingHook(this);
1185
1186         // Here, everything has been done that requires this player to be a client.
1187
1188         this.flags &= ~FL_CLIENT;
1189
1190         if (this.chatbubbleentity) remove(this.chatbubbleentity);
1191         if (this.killindicator) remove(this.killindicator);
1192
1193         WaypointSprite_PlayerGone();
1194
1195         bot_relinkplayerlist();
1196
1197         if (this.netname_previous) strunzone(this.netname_previous);
1198         if (this.clientstatus) strunzone(this.clientstatus);
1199         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1200         if (this.personal) remove(this.personal);
1201
1202         this.playerid = 0;
1203         ReadyCount();
1204         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1205 }
1206
1207 void ChatBubbleThink()
1208 {SELFPARAM();
1209         this.nextthink = time;
1210         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1211         {
1212                 if(this.owner) // but why can that ever be world?
1213                         this.owner.chatbubbleentity = world;
1214                 remove(this);
1215                 return;
1216         }
1217
1218         this.mdl = "";
1219
1220         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1221         {
1222                 if ( this.owner.active_minigame )
1223                         this.mdl = "models/sprites/minigame_busy.iqm";
1224                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1225                         this.mdl = "models/misc/chatbubble.spr";
1226         }
1227
1228         if ( this.model != this.mdl )
1229                 _setmodel(this, this.mdl);
1230
1231 }
1232
1233 void UpdateChatBubble()
1234 {SELFPARAM();
1235         if (this.alpha < 0)
1236                 return;
1237         // spawn a chatbubble entity if needed
1238         if (!this.chatbubbleentity)
1239         {
1240                 this.chatbubbleentity = new(chatbubbleentity);
1241                 this.chatbubbleentity.owner = this;
1242                 this.chatbubbleentity.exteriormodeltoclient = this;
1243                 this.chatbubbleentity.think = ChatBubbleThink;
1244                 this.chatbubbleentity.nextthink = time;
1245                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1246                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1247                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1248                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1249                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1250                 //this.chatbubbleentity.model = "";
1251                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1252         }
1253 }
1254
1255
1256 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1257 // added to the model skins
1258 /*void UpdateColorModHack()
1259 {
1260         float c;
1261         c = this.clientcolors & 15;
1262         // LordHavoc: only bothering to support white, green, red, yellow, blue
1263              if (!teamplay) this.colormod = '0 0 0';
1264         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1265         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1266         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1267         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1268         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1269         else this.colormod = '1 1 1';
1270 }*/
1271
1272 void respawn()
1273 {SELFPARAM();
1274         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1275         {
1276                 this.solid = SOLID_NOT;
1277                 this.takedamage = DAMAGE_NO;
1278                 this.movetype = MOVETYPE_FLY;
1279                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1280                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1281                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1282                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1283                 if(autocvar_g_respawn_ghosts_maxtime)
1284                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1285         }
1286
1287         CopyBody(this, 1);
1288
1289         this.effects |= EF_NODRAW; // prevent another CopyBody
1290         PutClientInServer();
1291 }
1292
1293 void play_countdown(float finished, Sound samp)
1294 {SELFPARAM();
1295     TC(Sound, samp);
1296         if(IS_REAL_CLIENT(this))
1297                 if(floor(finished - time - frametime) != floor(finished - time))
1298                         if(finished - time < 6)
1299                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1300 }
1301
1302 void player_powerups ()
1303 {SELFPARAM();
1304         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1305         int items_prev = this.items;
1306
1307         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1308                 this.modelflags |= MF_ROCKET;
1309         else
1310                 this.modelflags &= ~MF_ROCKET;
1311
1312         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1313
1314         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1315                 return;
1316
1317         Fire_ApplyDamage(this);
1318         Fire_ApplyEffect(this);
1319
1320         if (!g_instagib)
1321         {
1322                 if (this.items & ITEM_Strength.m_itemid)
1323                 {
1324                         play_countdown(this.strength_finished, SND_POWEROFF);
1325                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1326                         if (time > this.strength_finished)
1327                         {
1328                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1329                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1330                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1331                         }
1332                 }
1333                 else
1334                 {
1335                         if (time < this.strength_finished)
1336                         {
1337                                 this.items = this.items | ITEM_Strength.m_itemid;
1338                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1339                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1340                         }
1341                 }
1342                 if (this.items & ITEM_Shield.m_itemid)
1343                 {
1344                         play_countdown(this.invincible_finished, SND_POWEROFF);
1345                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1346                         if (time > this.invincible_finished)
1347                         {
1348                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1349                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1350                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1351                         }
1352                 }
1353                 else
1354                 {
1355                         if (time < this.invincible_finished)
1356                         {
1357                                 this.items = this.items | ITEM_Shield.m_itemid;
1358                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1359                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1360                         }
1361                 }
1362                 if (this.items & IT_SUPERWEAPON)
1363                 {
1364                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1365                         {
1366                                 this.superweapons_finished = 0;
1367                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1368                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1369                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1370                         }
1371                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1372                         {
1373                                 // don't let them run out
1374                         }
1375                         else
1376                         {
1377                                 play_countdown(this.superweapons_finished, SND_POWEROFF);
1378                                 if (time > this.superweapons_finished)
1379                                 {
1380                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1381                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1382                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1383                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1384                                 }
1385                         }
1386                 }
1387                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1388                 {
1389                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1390                         {
1391                                 this.items = this.items | IT_SUPERWEAPON;
1392                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1393                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1394                         }
1395                         else
1396                         {
1397                                 this.superweapons_finished = 0;
1398                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1399                         }
1400                 }
1401                 else
1402                 {
1403                         this.superweapons_finished = 0;
1404                 }
1405         }
1406
1407         if(autocvar_g_nodepthtestplayers)
1408                 this.effects = this.effects | EF_NODEPTHTEST;
1409
1410         if(autocvar_g_fullbrightplayers)
1411                 this.effects = this.effects | EF_FULLBRIGHT;
1412
1413         if (time >= game_starttime)
1414         if (time < this.spawnshieldtime)
1415                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1416
1417         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1418 }
1419
1420 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1421 {
1422         if(current > stable)
1423                 return current;
1424         else if(current > stable - 0.25) // when close enough, "snap"
1425                 return stable;
1426         else
1427                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1428 }
1429
1430 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1431 {
1432         if(current < stable)
1433                 return current;
1434         else if(current < stable + 0.25) // when close enough, "snap"
1435                 return stable;
1436         else
1437                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1438 }
1439
1440 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1441 {
1442         if(current > rotstable)
1443         {
1444                 if(rotframetime > 0)
1445                 {
1446                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1447                         current = max(rotstable, current - rotlinear * rotframetime);
1448                 }
1449         }
1450         else if(current < regenstable)
1451         {
1452                 if(regenframetime > 0)
1453                 {
1454                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1455                         current = min(regenstable, current + regenlinear * regenframetime);
1456                 }
1457         }
1458
1459         if(current > limit)
1460                 current = limit;
1461
1462         return current;
1463 }
1464
1465 void player_regen ()
1466 {SELFPARAM();
1467         float max_mod, regen_mod, rot_mod, limit_mod;
1468         max_mod = regen_mod = rot_mod = limit_mod = 1;
1469         regen_mod_max = max_mod;
1470         regen_mod_regen = regen_mod;
1471         regen_mod_rot = rot_mod;
1472         regen_mod_limit = limit_mod;
1473
1474         regen_health = autocvar_g_balance_health_regen;
1475         regen_health_linear = autocvar_g_balance_health_regenlinear;
1476         regen_health_rot = autocvar_g_balance_health_rot;
1477         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1478         regen_health_stable = autocvar_g_balance_health_regenstable;
1479         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1480         if(!MUTATOR_CALLHOOK(PlayerRegen))
1481         if(!STAT(FROZEN, this))
1482         {
1483                 float mina, maxa, limith, limita;
1484                 maxa = autocvar_g_balance_armor_rotstable;
1485                 mina = autocvar_g_balance_armor_regenstable;
1486                 limith = autocvar_g_balance_health_limit;
1487                 limita = autocvar_g_balance_armor_limit;
1488
1489                 max_mod = regen_mod_max;
1490                 regen_mod = regen_mod_regen;
1491                 rot_mod = regen_mod_rot;
1492                 limit_mod = regen_mod_limit;
1493
1494                 regen_health_rotstable = regen_health_rotstable * max_mod;
1495                 regen_health_stable = regen_health_stable * max_mod;
1496                 limith = limith * limit_mod;
1497                 limita = limita * limit_mod;
1498
1499                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1500                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1501         }
1502
1503         // if player rotted to death...  die!
1504         // check this outside above checks, as player may still be able to rot to death
1505         if(this.health < 1)
1506         {
1507                 if(this.vehicle)
1508                         vehicles_exit(VHEF_RELEASE);
1509                 if(this.event_damage)
1510                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1511         }
1512
1513         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1514         {
1515                 float minf, maxf, limitf;
1516
1517                 maxf = autocvar_g_balance_fuel_rotstable;
1518                 minf = autocvar_g_balance_fuel_regenstable;
1519                 limitf = autocvar_g_balance_fuel_limit;
1520
1521                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1522         }
1523 }
1524
1525 bool zoomstate_set;
1526 void SetZoomState(float z)
1527 {SELFPARAM();
1528         if(z != this.zoomstate)
1529         {
1530                 this.zoomstate = z;
1531                 ClientData_Touch(this);
1532         }
1533         zoomstate_set = true;
1534 }
1535
1536 void GetPressedKeys()
1537 {
1538         SELFPARAM();
1539         MUTATOR_CALLHOOK(GetPressedKeys);
1540         int keys = this.pressedkeys;
1541         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1542         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1543         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1544         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1545
1546         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1547         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1548         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1549         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1550         this.pressedkeys = keys;
1551 }
1552
1553 /*
1554 ======================
1555 spectate mode routines
1556 ======================
1557 */
1558
1559 void SpectateCopy(entity this, entity spectatee)
1560 {
1561     TC(Client, this); TC(Client, spectatee);
1562
1563         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1564         PS(this) = PS(spectatee);
1565         this.armortype = spectatee.armortype;
1566         this.armorvalue = spectatee.armorvalue;
1567         this.ammo_cells = spectatee.ammo_cells;
1568         this.ammo_plasma = spectatee.ammo_plasma;
1569         this.ammo_shells = spectatee.ammo_shells;
1570         this.ammo_nails = spectatee.ammo_nails;
1571         this.ammo_rockets = spectatee.ammo_rockets;
1572         this.ammo_fuel = spectatee.ammo_fuel;
1573         this.clip_load = spectatee.clip_load;
1574         this.clip_size = spectatee.clip_size;
1575         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1576         this.health = spectatee.health;
1577         this.impulse = 0;
1578         this.items = spectatee.items;
1579         this.last_pickup = spectatee.last_pickup;
1580         this.hit_time = spectatee.hit_time;
1581         this.strength_finished = spectatee.strength_finished;
1582         this.invincible_finished = spectatee.invincible_finished;
1583         this.pressedkeys = spectatee.pressedkeys;
1584         this.weapons = spectatee.weapons;
1585         this.vortex_charge = spectatee.vortex_charge;
1586         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1587         this.hagar_load = spectatee.hagar_load;
1588         this.arc_heat_percent = spectatee.arc_heat_percent;
1589         this.minelayer_mines = spectatee.minelayer_mines;
1590         this.punchangle = spectatee.punchangle;
1591         this.view_ofs = spectatee.view_ofs;
1592         this.velocity = spectatee.velocity;
1593         this.dmg_take = spectatee.dmg_take;
1594         this.dmg_save = spectatee.dmg_save;
1595         this.dmg_inflictor = spectatee.dmg_inflictor;
1596         this.v_angle = spectatee.v_angle;
1597         this.angles = spectatee.v_angle;
1598         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1599         this.revive_progress = spectatee.revive_progress;
1600         if(!PHYS_INPUT_BUTTON_USE(this))
1601                 this.fixangle = true;
1602         setorigin(this, spectatee.origin);
1603         setsize(this, spectatee.mins, spectatee.maxs);
1604         SetZoomState(spectatee.zoomstate);
1605
1606     anticheat_spectatecopy(this, spectatee);
1607         this.hud = spectatee.hud;
1608         if(spectatee.vehicle)
1609     {
1610         this.fixangle = false;
1611         //this.velocity = spectatee.vehicle.velocity;
1612         this.vehicle_health = spectatee.vehicle_health;
1613         this.vehicle_shield = spectatee.vehicle_shield;
1614         this.vehicle_energy = spectatee.vehicle_energy;
1615         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1616         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1617         this.vehicle_reload1 = spectatee.vehicle_reload1;
1618         this.vehicle_reload2 = spectatee.vehicle_reload2;
1619
1620         msg_entity = this;
1621
1622         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1623             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1624             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1625             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1626
1627         //WriteByte (MSG_ONE, SVC_SETVIEW);
1628         //    WriteEntity(MSG_ONE, this);
1629         //makevectors(spectatee.v_angle);
1630         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1631     }
1632 }
1633
1634 bool SpectateUpdate()
1635 {SELFPARAM();
1636         if(!this.enemy)
1637             return false;
1638
1639         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1640         {
1641                 SetSpectatee(this, NULL);
1642                 return false;
1643         }
1644
1645         SpectateCopy(this, this.enemy);
1646
1647         return true;
1648 }
1649
1650 bool SpectateSet()
1651 {SELFPARAM();
1652         if(!IS_PLAYER(this.enemy))
1653                 return false;
1654
1655         msg_entity = this;
1656         WriteByte(MSG_ONE, SVC_SETVIEW);
1657         WriteEntity(MSG_ONE, this.enemy);
1658         this.movetype = MOVETYPE_NONE;
1659         accuracy_resend(this);
1660
1661         if(!SpectateUpdate())
1662                 PutObserverInServer();
1663
1664         return true;
1665 }
1666
1667 void SetSpectatee(entity player, entity spectatee)
1668 {
1669         entity old_spectatee = player.enemy;
1670
1671         player.enemy = spectatee;
1672
1673         // WEAPONTODO
1674         // these are required to fix the spectator bug with arc
1675         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1676         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1677 }
1678
1679 bool Spectate(entity pl)
1680 {SELFPARAM();
1681         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1682                 return false;
1683         pl = spec_player;
1684
1685         SetSpectatee(this, pl);
1686         return SpectateSet();
1687 }
1688
1689 bool SpectateNext()
1690 {SELFPARAM();
1691         other = find(this.enemy, classname, STR_PLAYER);
1692
1693         if (MUTATOR_CALLHOOK(SpectateNext, this, other))
1694                 other = spec_player;
1695         else if (!other)
1696                 other = find(other, classname, STR_PLAYER);
1697
1698         if(other) { SetSpectatee(this, other); }
1699
1700         return SpectateSet();
1701 }
1702
1703 bool SpectatePrev()
1704 {SELFPARAM();
1705         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1706         other = findchain(classname, STR_PLAYER);
1707         if (!other) // no player
1708                 return false;
1709
1710         entity first = other;
1711         // skip players until current spectated player
1712         if(this.enemy)
1713         while(other && other != this.enemy)
1714                 other = other.chain;
1715
1716         switch (MUTATOR_CALLHOOK(SpectatePrev, this, other, first))
1717         {
1718                 case MUT_SPECPREV_FOUND:
1719                     other = spec_player;
1720                     break;
1721                 case MUT_SPECPREV_RETURN:
1722                     other = spec_player;
1723                     return true;
1724                 case MUT_SPECPREV_CONTINUE:
1725                 default:
1726                 {
1727                         if(other.chain)
1728                                 other = other.chain;
1729                         else
1730                                 other = first;
1731                         break;
1732                 }
1733         }
1734
1735         SetSpectatee(this, other);
1736         return SpectateSet();
1737 }
1738
1739 /*
1740 =============
1741 ShowRespawnCountdown()
1742
1743 Update a respawn countdown display.
1744 =============
1745 */
1746 void ShowRespawnCountdown()
1747 {SELFPARAM();
1748         float number;
1749         if(!IS_DEAD(this)) // just respawned?
1750                 return;
1751         else
1752         {
1753                 number = ceil(this.respawn_time - time);
1754                 if(number <= 0)
1755                         return;
1756                 if(number <= this.respawn_countdown)
1757                 {
1758                         this.respawn_countdown = number - 1;
1759                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1760                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1761                 }
1762         }
1763 }
1764
1765 void LeaveSpectatorMode()
1766 {SELFPARAM();
1767         if(this.caplayer)
1768                 return;
1769         if(nJoinAllowed(this, this))
1770         {
1771                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1772                 {
1773                         TRANSMUTE(Player, this);
1774
1775                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1776                                 { JoinBestTeam(this, false, true); }
1777
1778                         if(autocvar_g_campaign)
1779                                 { campaign_bots_may_start = true; }
1780
1781                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1782
1783                         PutClientInServer();
1784
1785                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1786                 }
1787                 else
1788                         stuffcmd(this, "menu_showteamselect\n");
1789         }
1790         else
1791         {
1792                 // Player may not join because g_maxplayers is set
1793                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1794         }
1795 }
1796
1797 /**
1798  * Determines whether the player is allowed to join. This depends on cvar
1799  * g_maxplayers, if it isn't used this function always return true, otherwise
1800  * it checks whether the number of currently playing players exceeds g_maxplayers.
1801  * @return int number of free slots for players, 0 if none
1802  */
1803 bool nJoinAllowed(entity this, entity ignore)
1804 {
1805         if(!ignore)
1806         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1807         // so report 0 free slots if restricted
1808         {
1809                 if(autocvar_g_forced_team_otherwise == "spectate")
1810                         return false;
1811                 if(autocvar_g_forced_team_otherwise == "spectator")
1812                         return false;
1813         }
1814
1815         if(this.team_forced < 0)
1816                 return false; // forced spectators can never join
1817
1818         // TODO simplify this
1819         int totalClients = 0;
1820         int currentlyPlaying = 0;
1821         FOREACH_CLIENT(true, LAMBDA(
1822                 if(it != ignore)
1823                         ++totalClients;
1824                 if(IS_REAL_CLIENT(it))
1825                 if(IS_PLAYER(it) || it.caplayer)
1826                         ++currentlyPlaying;
1827         ));
1828
1829         if (!autocvar_g_maxplayers)
1830                 return maxclients - totalClients;
1831
1832         if(currentlyPlaying < autocvar_g_maxplayers)
1833                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1834
1835         return false;
1836 }
1837
1838 /**
1839  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1840  * g_maxplayers_spectator_blocktime seconds
1841  */
1842 void checkSpectatorBlock()
1843 {SELFPARAM();
1844         if(IS_SPEC(this) || IS_OBSERVER(this))
1845         if(!this.caplayer)
1846         if(IS_REAL_CLIENT(this))
1847         {
1848                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1849                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1850                         dropclient(this);
1851                 }
1852         }
1853 }
1854
1855 void PrintWelcomeMessage(entity this)
1856 {
1857         if(this.motd_actived_time == 0)
1858         {
1859                 if (autocvar_g_campaign) {
1860                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1861                                 this.motd_actived_time = time;
1862                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1863                         }
1864                 } else {
1865                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1866                                 this.motd_actived_time = time;
1867                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1868                         }
1869                 }
1870         }
1871         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1872         {
1873                 if (autocvar_g_campaign) {
1874                         if (PHYS_INPUT_BUTTON_INFO(this))
1875                                 this.motd_actived_time = time;
1876                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1877                                 this.motd_actived_time = 0;
1878                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1879                         }
1880                 } else {
1881                         if (PHYS_INPUT_BUTTON_INFO(this))
1882                                 this.motd_actived_time = time;
1883                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1884                                 this.motd_actived_time = 0;
1885                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1886                         }
1887                 }
1888         }
1889         else //if(this.motd_actived_time < 0) // just connected, motd is active
1890         {
1891                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1892                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1893                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1894                 {
1895                         // instanctly hide MOTD
1896                         this.motd_actived_time = 0;
1897                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1898                 }
1899         }
1900 }
1901
1902 void ObserverThink()
1903 {SELFPARAM();
1904         if ( this.impulse )
1905         {
1906                 MinigameImpulse(this, this.impulse);
1907                 this.impulse = 0;
1908         }
1909         float prefered_movetype;
1910         if (this.flags & FL_JUMPRELEASED) {
1911                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1912                         this.flags &= ~FL_JUMPRELEASED;
1913                         this.flags |= FL_SPAWNING;
1914                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1915                         this.flags &= ~FL_JUMPRELEASED;
1916                         if(SpectateNext()) {
1917                                 TRANSMUTE(Spectator, this);
1918                         }
1919                 } else {
1920                         prefered_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1921                         if (this.movetype != prefered_movetype)
1922                                 this.movetype = prefered_movetype;
1923                 }
1924         } else {
1925                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
1926                         this.flags |= FL_JUMPRELEASED;
1927                         if(this.flags & FL_SPAWNING)
1928                         {
1929                                 this.flags &= ~FL_SPAWNING;
1930                                 LeaveSpectatorMode();
1931                                 return;
1932                         }
1933                 }
1934         }
1935 }
1936
1937 void SpectatorThink()
1938 {SELFPARAM();
1939         if ( this.impulse )
1940         {
1941                 if(MinigameImpulse(this, this.impulse))
1942                         this.impulse = 0;
1943         }
1944         if (this.flags & FL_JUMPRELEASED) {
1945                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1946                         this.flags &= ~FL_JUMPRELEASED;
1947                         this.flags |= FL_SPAWNING;
1948                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
1949                         this.flags &= ~FL_JUMPRELEASED;
1950                         if(SpectateNext()) {
1951                                 TRANSMUTE(Spectator, this);
1952                         } else {
1953                                 TRANSMUTE(Observer, this);
1954                                 PutClientInServer();
1955                         }
1956                         this.impulse = 0;
1957                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
1958                         this.flags &= ~FL_JUMPRELEASED;
1959                         if(SpectatePrev()) {
1960                                 TRANSMUTE(Spectator, this);
1961                         } else {
1962                                 TRANSMUTE(Observer, this);
1963                                 PutClientInServer();
1964                         }
1965                         this.impulse = 0;
1966                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
1967                         this.flags &= ~FL_JUMPRELEASED;
1968                         TRANSMUTE(Observer, this);
1969                         PutClientInServer();
1970                 } else {
1971                         if(!SpectateUpdate())
1972                                 PutObserverInServer();
1973                 }
1974         } else {
1975                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
1976                         this.flags |= FL_JUMPRELEASED;
1977                         if(this.flags & FL_SPAWNING)
1978                         {
1979                                 this.flags &= ~FL_SPAWNING;
1980                                 LeaveSpectatorMode();
1981                                 return;
1982                         }
1983                 }
1984                 if(!SpectateUpdate())
1985                         PutObserverInServer();
1986         }
1987
1988         this.flags |= FL_CLIENT | FL_NOTARGET;
1989 }
1990
1991 void vehicles_enter (entity pl, entity veh);
1992 void PlayerUseKey()
1993 {SELFPARAM();
1994         if (!IS_PLAYER(this))
1995                 return;
1996
1997         if(this.vehicle)
1998         {
1999                 if(!gameover)
2000                 {
2001                         vehicles_exit(VHEF_NORMAL);
2002                         return;
2003                 }
2004         }
2005         else if(autocvar_g_vehicles_enter)
2006         {
2007                 if(!STAT(FROZEN, this))
2008                 if(!IS_DEAD(this))
2009                 if(!gameover)
2010                 {
2011                         entity head, closest_target = world;
2012                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2013
2014                         while(head) // find the closest acceptable target to enter
2015                         {
2016                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2017                                 if(!IS_DEAD(head))
2018                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2019                                 if(head.takedamage != DAMAGE_NO)
2020                                 {
2021                                         if(closest_target)
2022                                         {
2023                                                 if(vlen(this.origin - head.origin) < vlen(this.origin - closest_target.origin))
2024                                                 { closest_target = head; }
2025                                         }
2026                                         else { closest_target = head; }
2027                                 }
2028
2029                                 head = head.chain;
2030                         }
2031
2032                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2033                 }
2034         }
2035
2036         // a use key was pressed; call handlers
2037         MUTATOR_CALLHOOK(PlayerUseKey);
2038 }
2039
2040
2041 /*
2042 =============
2043 PlayerPreThink
2044
2045 Called every frame for each client before the physics are run
2046 =============
2047 */
2048 .float usekeypressed;
2049 void() nexball_setstatus;
2050 .float last_vehiclecheck;
2051 .int items_added;
2052 void PlayerPreThink ()
2053 {
2054     SELFPARAM();
2055         WarpZone_PlayerPhysics_FixVAngle(this);
2056
2057     STAT(GAMESTARTTIME, this) = game_starttime;
2058         STAT(ROUNDSTARTTIME, this) = round_starttime;
2059         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2060         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2061
2062         STAT(WEAPONSINMAP, this) = weaponsInMap;
2063
2064         if (frametime) {
2065                 // physics frames: update anticheat stuff
2066                 anticheat_prethink(this);
2067         }
2068
2069         if (blockSpectators && frametime) {
2070                 // WORKAROUND: only use dropclient in server frames (frametime set).
2071                 // Never use it in cl_movement frames (frametime zero).
2072                 checkSpectatorBlock();
2073     }
2074
2075         zoomstate_set = false;
2076
2077         // Check for nameless players
2078         if (isInvisibleString(this.netname)) {
2079                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2080                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2081         }
2082         if (this.netname != this.netname_previous) {
2083                 if (autocvar_sv_eventlog) {
2084                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2085         }
2086                 if (this.netname_previous) strunzone(this.netname_previous);
2087                 this.netname_previous = strzone(this.netname);
2088         }
2089
2090         // version nagging
2091         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2092         this.version_nagtime = 0;
2093         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2094             // git client
2095         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2096             // git server
2097             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2098         } else {
2099             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2100             if (r < 0) { // old client
2101                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2102             } else if (r > 0) { // old server
2103                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2104             }
2105         }
2106     }
2107
2108         // GOD MODE info
2109         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2110         {
2111                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2112                 this.max_armorvalue = 0;
2113         }
2114
2115         if (STAT(FROZEN, this) == 2)
2116         {
2117                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2118                 this.health = max(1, this.revive_progress * start_health);
2119                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2120
2121                 if (this.revive_progress >= 1)
2122                         Unfreeze(this);
2123         }
2124         else if (STAT(FROZEN, this) == 3)
2125         {
2126                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2127                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2128
2129                 if (this.health < 1)
2130                 {
2131                         if (this.vehicle)
2132                                 vehicles_exit(VHEF_RELEASE);
2133                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2134                 }
2135                 else if (this.revive_progress <= 0)
2136                         Unfreeze(this);
2137         }
2138
2139         MUTATOR_CALLHOOK(PlayerPreThink);
2140
2141         if(autocvar_g_vehicles_enter)
2142         if(time > this.last_vehiclecheck)
2143         if(IS_PLAYER(this))
2144         if(!gameover)
2145         if(!STAT(FROZEN, this))
2146         if(!this.vehicle)
2147         if(!IS_DEAD(this))
2148         {
2149                 entity veh;
2150                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2151                 if(vlen(veh.origin - this.origin) < autocvar_g_vehicles_enter_radius)
2152                 if(!IS_DEAD(veh))
2153                 if(veh.takedamage != DAMAGE_NO)
2154                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, this))
2155                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2156                 else if(!veh.owner)
2157                 if(!veh.team || SAME_TEAM(this, veh))
2158                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2159                 else if(autocvar_g_vehicles_steal)
2160                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2161
2162                 this.last_vehiclecheck = time + 1;
2163         }
2164
2165         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2166         {
2167                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2168                         PlayerUseKey();
2169                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2170         }
2171
2172         if (IS_REAL_CLIENT(this))
2173                 PrintWelcomeMessage(this);
2174
2175         if (IS_PLAYER(this)) {
2176                 CheckRules_Player();
2177
2178                 if (intermission_running) {
2179                         IntermissionThink();
2180                         return;
2181                 }
2182
2183                 if (timeout_status == TIMEOUT_ACTIVE) {
2184             // don't allow the player to turn around while game is paused
2185                         // FIXME turn this into CSQC stuff
2186                         this.v_angle = this.lastV_angle;
2187                         this.angles = this.lastV_angle;
2188                         this.fixangle = true;
2189                 }
2190
2191                 if (frametime) player_powerups();
2192
2193                 if (IS_DEAD(this)) {
2194                         if (this.personal && g_race_qualifying) {
2195                                 if (time > this.respawn_time) {
2196                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2197                                         respawn();
2198                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2199                                 }
2200                         } else {
2201                                 if (frametime) player_anim();
2202                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2203
2204                                 if (this.deadflag == DEAD_DYING) {
2205                                         if ((this.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max) {
2206                                                 this.deadflag = DEAD_RESPAWNING;
2207                                         } else if (!button_pressed) {
2208                                                 this.deadflag = DEAD_DEAD;
2209                     }
2210                                 } else if (this.deadflag == DEAD_DEAD) {
2211                                         if (button_pressed) {
2212                                                 this.deadflag = DEAD_RESPAWNABLE;
2213                                         } else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)) {
2214                                                 this.deadflag = DEAD_RESPAWNING;
2215                     }
2216                                 } else if (this.deadflag == DEAD_RESPAWNABLE) {
2217                                         if (!button_pressed) {
2218                                                 this.deadflag = DEAD_RESPAWNING;
2219                     }
2220                                 } else if (this.deadflag == DEAD_RESPAWNING) {
2221                                         if (time > this.respawn_time) {
2222                                                 this.respawn_time = time + 1; // only retry once a second
2223                                                 this.respawn_time_max = this.respawn_time;
2224                                                 respawn();
2225                                         }
2226                                 }
2227
2228                                 ShowRespawnCountdown();
2229
2230                                 if (this.respawn_flags & RESPAWN_SILENT)
2231                                         STAT(RESPAWN_TIME, this) = 0;
2232                                 else if ((this.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2233                                         STAT(RESPAWN_TIME, this) = this.respawn_time_max;
2234                                 else
2235                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2236                         }
2237
2238                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2239                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2240                                 STAT(RESPAWN_TIME, this) *= -1;
2241
2242                         return;
2243                 }
2244
2245                 this.prevorigin = this.origin;
2246
2247                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2248         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2249                 if (this.hook.state) {
2250                         do_crouch = false;
2251                 } else if (this.vehicle) {
2252                         do_crouch = false;
2253                 } else if (STAT(FROZEN, this)) {
2254                         do_crouch = false;
2255         } else if ((PS(this).m_weapon == WEP_SHOTGUN || PS(this).m_weapon == WEP_SHOCKWAVE) && this.(weaponentity).wframe == WFRAME_FIRE2 && time < this.(weaponentity).weapon_nextthink) {
2256                     // WEAPONTODO: predict
2257                         do_crouch = false;
2258         }
2259
2260                 if (do_crouch) {
2261                         if (!this.crouch) {
2262                                 this.crouch = true;
2263                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2264                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2265                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2266                         }
2267                 } else if (this.crouch) {
2268             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2269             if (!trace_startsolid) {
2270                 this.crouch = false;
2271                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2272                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2273             }
2274                 }
2275
2276                 FixPlayermodel(this);
2277
2278                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2279                 //if(frametime)
2280                 {
2281                         this.items &= ~this.items_added;
2282
2283                         W_WeaponFrame(this);
2284
2285                         this.items_added = 0;
2286                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2287                 this.items_added |= IT_FUEL;
2288
2289                         this.items |= this.items_added;
2290                 }
2291
2292                 player_regen();
2293
2294                 // WEAPONTODO: Add a weapon request for this
2295                 // rot vortex charge to the charge limit
2296                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2297                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2298
2299                 if (frametime) player_anim();
2300
2301                 // secret status
2302                 secrets_setstatus();
2303
2304                 // monsters status
2305                 monsters_setstatus(this);
2306
2307                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2308         }
2309         else if (gameover) {
2310                 if (intermission_running) IntermissionThink();
2311                 return;
2312         }
2313         else if (IS_OBSERVER(this)) {
2314                 ObserverThink();
2315         }
2316         else if (IS_SPEC(this)) {
2317                 SpectatorThink();
2318         }
2319
2320         // WEAPONTODO: Add weapon request for this
2321         if (!zoomstate_set) {
2322                 SetZoomState(
2323                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2324                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2325                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2326                 );
2327     }
2328
2329         int oldspectatee_status = this.spectatee_status;
2330         if (IS_SPEC(this)) {
2331                 this.spectatee_status = etof(this.enemy);
2332         } else if (IS_OBSERVER(this)) {
2333                 this.spectatee_status = etof(this);
2334         } else {
2335                 this.spectatee_status = 0;
2336     }
2337         if (this.spectatee_status != oldspectatee_status) {
2338                 ClientData_Touch(this);
2339                 if (g_race || g_cts) race_InitSpectator();
2340         }
2341
2342         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2343         {
2344                 this.teamkill_soundtime = 0;
2345
2346                 entity e = this.teamkill_soundsource;
2347                 entity oldpusher = e.pusher;
2348                 e.pusher = this;
2349                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2350                 e.pusher = oldpusher;
2351         }
2352
2353         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2354                 this.taunt_soundtime = 0;
2355                 PlayerSound(this, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2356         }
2357
2358         target_voicescript_next(this);
2359
2360         // WEAPONTODO: Move into weaponsystem somehow
2361         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2362         if (PS(this).m_weapon == WEP_Null)
2363                 this.clip_load = this.clip_size = 0;
2364 }
2365
2366 void DrownPlayer(entity this)
2367 {
2368         if(IS_DEAD(this))
2369                 return;
2370
2371         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2372         {
2373                 if(this.air_finished < time)
2374                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2375                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2376                 this.dmg = 2;
2377         }
2378         else if (this.air_finished < time)
2379         {       // drown!
2380                 if (this.pain_finished < time)
2381                 {
2382                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2383                         this.pain_finished = time + 0.5;
2384                 }
2385         }
2386 }
2387
2388 /*
2389 =============
2390 PlayerPostThink
2391
2392 Called every frame for each client after the physics are run
2393 =============
2394 */
2395 .float idlekick_lasttimeleft;
2396 void PlayerPostThink ()
2397 {
2398     SELFPARAM();
2399         if (sv_maxidle > 0)
2400         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2401         if (IS_REAL_CLIENT(this))
2402         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2403         {
2404                 if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2405                 {
2406                         if (this.idlekick_lasttimeleft)
2407                         {
2408                                 this.idlekick_lasttimeleft = 0;
2409                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2410                         }
2411                 }
2412                 else
2413                 {
2414                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2415                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2416                                 if (!this.idlekick_lasttimeleft)
2417                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2418                         }
2419                         if (timeleft <= 0) {
2420                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2421                                 dropclient(this);
2422                                 return;
2423                         }
2424                         else if (timeleft <= 10) {
2425                                 if (timeleft != this.idlekick_lasttimeleft) {
2426                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2427                 }
2428                                 this.idlekick_lasttimeleft = timeleft;
2429                         }
2430                 }
2431         }
2432
2433         CheatFrame();
2434
2435         //CheckPlayerJump();
2436
2437         if (IS_PLAYER(this)) {
2438                 DrownPlayer(this);
2439                 CheckRules_Player();
2440                 UpdateChatBubble();
2441                 if (this.impulse) ImpulseCommands(this);
2442                 if (intermission_running) return; // intermission or finale
2443                 GetPressedKeys();
2444         }
2445
2446         if (this.waypointsprite_attachedforcarrier) {
2447             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2448                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2449     }
2450
2451         playerdemo_write();
2452
2453         CSQCMODEL_AUTOUPDATE(this);
2454 }