qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418             vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.damagedbycontents = FALSE;
 449         self.health = -666;
 450         self.takedamage = DAMAGE_NO;
 451         self.solid = SOLID_NOT;
 452         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 453         self.flags = FL_CLIENT | FL_NOTARGET;
 454         self.armorvalue = 666;
 455         self.effects = 0;
 456         self.armorvalue = autocvar_g_balance_armor_start;
 457         self.pauserotarmor_finished = 0;
 458         self.pauserothealth_finished = 0;
 459         self.pauseregen_finished = 0;
 460         self.damageforcescale = 0;
 461         self.death_time = 0;
 462         self.respawn_time = 0;
 463         self.alpha = 0;
 464         self.scale = 0;
 465         self.fade_time = 0;
 466         self.pain_frame = 0;
 467         self.pain_finished = 0;
 468         self.strength_finished = 0;
 469         self.invincible_finished = 0;
 470         self.superweapons_finished = 0;
 471         self.pushltime = 0;
 472         self.think = SUB_Null;
 473         self.nextthink = 0;
 474         self.hook_time = 0;
 475         self.runes = 0;
 476         self.deadflag = DEAD_NO;
 477         self.angles = spot.angles;
 478         self.angles_z = 0;
 479         self.fixangle = TRUE;
 480         self.crouch = FALSE;
 481
 482         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 483         self.prevorigin = self.origin;
 484         self.items = 0;
 485         self.weapons = 0;
 486         self.model = "";
 487         FixPlayermodel();
 488         setmodel(self, "null");
 489         self.drawonlytoclient = self;
 490
 491         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 492         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 493
 494         self.weapon = 0;
 495         self.weaponname = "";
 496         self.switchingweapon = 0;
 497         self.weaponmodel = "";
 498         self.weaponentity = world;
 499         self.exteriorweaponentity = world;
 500         self.killcount = -666;
 501         self.velocity = '0 0 0';
 502         self.avelocity = '0 0 0';
 503         self.punchangle = '0 0 0';
 504         self.punchvector = '0 0 0';
 505         self.oldvelocity = self.velocity;
 506         self.fire_endtime = -1;
 507
 508         if(g_arena)
 509         {
 510                 if(self.version_mismatch)
 511                 {
 512                         Spawnqueue_Unmark(self);
 513                         Spawnqueue_Remove(self);
 514                 }
 515                 else
 516                 {
 517                         Spawnqueue_Insert(self);
 518                 }
 519         }
 520         else if(g_lms)
 521         {
 522                 // Only if the player cannot play at all
 523                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 524                         self.frags = FRAGS_SPECTATOR;
 525                 else
 526                         self.frags = FRAGS_LMS_LOSER;
 527         }
 528         else if(g_ca)
 529         {
 530                 if(self.caplayer)
 531                         self.frags = FRAGS_LMS_LOSER;
 532                 else
 533                         self.frags = FRAGS_SPECTATOR;
 534         }
 535         else
 536                 self.frags = FRAGS_SPECTATOR;
 537 }
 538
 539 .float model_randomizer;
 540 void FixPlayermodel()
 541 {
 542         string defaultmodel;
 543         float defaultskin, chmdl, oldskin, n, i;
 544         vector m1, m2;
 545
 546         defaultmodel = "";
 547
 548         if(autocvar_sv_defaultcharacter == 1)
 549         {
 550                 defaultskin = 0;
 551
 552                 if(teamplay)
 553                 {
 554                         string s;
 555                         s = Team_ColorNameLowerCase(self.team);
 556                         if(s != "neutral")
 557                         {
 558                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 559                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 560                         }
 561                 }
 562
 563                 if(defaultmodel == "")
 564                 {
 565                         defaultmodel = autocvar_sv_defaultplayermodel;
 566                         defaultskin = autocvar_sv_defaultplayerskin;
 567                 }
 568
 569                 n = tokenize_console(defaultmodel);
 570                 if(n > 0)
 571                         defaultmodel = argv(floor(n * self.model_randomizer));
 572
 573                 i = strstrofs(defaultmodel, ":", 0);
 574                 if(i >= 0)
 575                 {
 576                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 577                         defaultmodel = substring(defaultmodel, 0, i);
 578                 }
 579         }
 580
 581         if(defaultmodel != "")
 582         {
 583                 if (defaultmodel != self.model)
 584                 {
 585                         m1 = self.mins;
 586                         m2 = self.maxs;
 587                         setplayermodel (self, defaultmodel);
 588                         setsize (self, m1, m2);
 589                         chmdl = TRUE;
 590                 }
 591
 592                 oldskin = self.skin;
 593                 self.skin = defaultskin;
 594         } else {
 595                 if (self.playermodel != self.model || self.playermodel == "")
 596                 {
 597                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 598                         m1 = self.mins;
 599                         m2 = self.maxs;
 600                         setplayermodel (self, self.playermodel);
 601                         setsize (self, m1, m2);
 602                         chmdl = TRUE;
 603                 }
 604
 605                 oldskin = self.skin;
 606                 self.skin = stof(self.playerskin);
 607         }
 608
 609         if(chmdl || oldskin != self.skin)
 610                 self.species = player_getspecies(); // model or skin has changed
 611
 612         if(!teamplay)
 613                 if(strlen(autocvar_sv_defaultplayercolors))
 614                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 615                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 616 }
 617
 618 void PlayerTouchExplode(entity p1, entity p2)
 619 {
 620         vector org;
 621         org = (p1.origin + p2.origin) * 0.5;
 622         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 623
 624         te_explosion(org);
 625
 626         entity e;
 627         e = spawn();
 628         setorigin(e, org);
 629         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 630         remove(e);
 631 }
 632
 633 /*
 634 =============
 635 PutClientInServer
 636
 637 Called when a client spawns in the server
 638 =============
 639 */
 640 //void() ctf_playerchanged;
 641
 642 void PutClientInServer (void)
 643 {
 644         if(clienttype(self) == CLIENTTYPE_BOT)
 645         {
 646                 self.classname = "player";
 647                 if(g_ca)
 648                         self.caplayer = 1;
 649         }
 650         else if(clienttype(self) == CLIENTTYPE_REAL)
 651         {
 652                 msg_entity = self;
 653                 WriteByte(MSG_ONE, SVC_SETVIEW);
 654                 WriteEntity(MSG_ONE, self);
 655         }
 656
 657         // reset player keys
 658         self.itemkeys = 0;
 659
 660         // player is dead and becomes observer
 661         // FIXME fix LMS scoring for new system
 662         if(g_lms)
 663         {
 664                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 665                         self.classname = "observer";
 666         }
 667
 668         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 669                 self.classname = "observer";
 670
 671         if(gameover)
 672                 self.classname = "observer";
 673
 674         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 675                 entity spot, oldself;
 676                 float j;
 677
 678                 accuracy_resend(self);
 679
 680                 if(self.team < 0)
 681                         JoinBestTeam(self, FALSE, TRUE);
 682
 683                 race_PreSpawn();
 684
 685                 spot = SelectSpawnPoint (FALSE);
 686                 if(!spot)
 687                 {
 688                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 689                         return; // spawn failed
 690                 }
 691
 692                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 693
 694                 self.classname = "player";
 695                 self.wasplayer = TRUE;
 696                 self.iscreature = TRUE;
 697                 self.damagedbycontents = TRUE;
 698                 self.movetype = MOVETYPE_WALK;
 699                 self.solid = SOLID_SLIDEBOX;
 700                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 701                 if(autocvar_g_playerclip_collisions)
 702                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 703                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 705                 self.frags = FRAGS_PLAYER;
 706                 if(INDEPENDENT_PLAYERS)
 707                         MAKE_INDEPENDENT_PLAYER(self);
 708                 self.flags = FL_CLIENT;
 709                 if(autocvar__notarget)
 710                         self.flags |= FL_NOTARGET;
 711                 self.takedamage = DAMAGE_AIM;
 712                 if(g_minstagib)
 713                         self.effects = EF_FULLBRIGHT;
 714                 else
 715                         self.effects = 0;
 716                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 717                 self.air_finished = time + 12;
 718                 self.dmg = 2;
 719                 if(autocvar_g_balance_nex_charge)
 720                 {
 721                         if(autocvar_g_balance_nex_secondary_chargepool)
 722                                 self.nex_chargepool_ammo = 1;
 723                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 724                 }
 725
 726                 if(inWarmupStage)
 727                 {
 728                         self.ammo_shells = warmup_start_ammo_shells;
 729                         self.ammo_nails = warmup_start_ammo_nails;
 730                         self.ammo_rockets = warmup_start_ammo_rockets;
 731                         self.ammo_cells = warmup_start_ammo_cells;
 732                         self.ammo_fuel = warmup_start_ammo_fuel;
 733                         self.health = warmup_start_health;
 734                         self.armorvalue = warmup_start_armorvalue;
 735                         self.weapons = warmup_start_weapons;
 736                 }
 737                 else
 738                 {
 739                         self.ammo_shells = start_ammo_shells;
 740                         self.ammo_nails = start_ammo_nails;
 741                         self.ammo_rockets = start_ammo_rockets;
 742                         self.ammo_cells = start_ammo_cells;
 743                         self.ammo_fuel = start_ammo_fuel;
 744                         self.health = start_health;
 745                         self.armorvalue = start_armorvalue;
 746                         self.weapons = start_weapons;
 747                 }
 748
 749                 if(self.weapons & WEPBIT_SUPERWEAPONS) // exception for minstagib, as minstanex is a superweapon
 750                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 751                 else
 752                         self.superweapons_finished = 0;
 753
 754                 if(g_weaponarena_random)
 755                 {
 756                         if(g_weaponarena_random_with_laser)
 757                                 self.weapons &~= WEPBIT_LASER;
 758                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 759                         if(g_weaponarena_random_with_laser)
 760                                 self.weapons |= WEPBIT_LASER;
 761                 }
 762
 763                 self.items = start_items;
 764
 765                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 766                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 767                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 768                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 769                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 770                 //extend the pause of rotting if client was reset at the beginning of the countdown
 771                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 772                         self.spawnshieldtime += game_starttime - time;
 773                         self.pauserotarmor_finished += game_starttime - time;
 774                         self.pauserothealth_finished += game_starttime - time;
 775                         self.pauseregen_finished += game_starttime - time;
 776                 }
 777                 self.damageforcescale = 2;
 778                 self.death_time = 0;
 779                 self.respawn_time = 0;
 780                 self.scale = 0;
 781                 self.fade_time = 0;
 782                 self.pain_frame = 0;
 783                 self.pain_finished = 0;
 784                 self.strength_finished = 0;
 785                 self.invincible_finished = 0;
 786                 self.pushltime = 0;
 787                 // players have no think function
 788                 self.think = SUB_Null;
 789                 self.nextthink = 0;
 790                 self.hook_time = 0;
 791                 self.dmg_team = 0;
 792                 self.ballistics_density = autocvar_g_ballistics_density_player;
 793
 794                 self.metertime = 0;
 795
 796                 self.runes = 0;
 797
 798                 self.deadflag = DEAD_NO;
 799
 800                 self.angles = spot.angles;
 801
 802                 self.angles_z = 0; // never spawn tilted even if the spot says to
 803                 self.fixangle = TRUE; // turn this way immediately
 804                 self.velocity = '0 0 0';
 805                 self.avelocity = '0 0 0';
 806                 self.punchangle = '0 0 0';
 807                 self.punchvector = '0 0 0';
 808                 self.oldvelocity = self.velocity;
 809                 self.fire_endtime = -1;
 810
 811                 msg_entity = self;
 812                 WRITESPECTATABLE_MSG_ONE({
 813                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 814                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 815                 });
 816
 817                 self.model = "";
 818                 FixPlayermodel();
 819                 self.drawonlytoclient = world;
 820
 821                 self.crouch = FALSE;
 822                 self.view_ofs = PL_VIEW_OFS;
 823                 setsize (self, PL_MIN, PL_MAX);
 824                 self.spawnorigin = spot.origin;
 825                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 826                 // don't reset back to last position, even if new position is stuck in solid
 827                 self.oldorigin = self.origin;
 828                 self.prevorigin = self.origin;
 829                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 830                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 831         self.hud = HUD_NORMAL;
 832
 833                 if(g_arena)
 834                 {
 835                         Spawnqueue_Remove(self);
 836                         Spawnqueue_Mark(self);
 837                 }
 838                 else if(g_ca)
 839                         self.caplayer = 1;
 840
 841                 self.event_damage = PlayerDamage;
 842
 843                 self.bot_attack = TRUE;
 844
 845                 self.statdraintime = time + 5;
 846                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 847
 848                 if(self.killcount == -666) {
 849                         PlayerScore_Clear(self);
 850                         self.killcount = 0;
 851                 }
 852
 853                 CL_SpawnWeaponentity();
 854                 self.alpha = default_player_alpha;
 855                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 856                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 857
 858                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 859                 self.lms_traveled_distance = 0;
 860                 self.speedrunning = FALSE;
 861
 862                 race_PostSpawn(spot);
 863
 864                 //stuffcmd(self, "chase_active 0");
 865                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 866
 867                 if (autocvar_g_spawnsound)
 868                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 869
 870                 if(g_assault) {
 871                         if(self.team == assault_attacker_team)
 872                                 centerprint(self, "You are attacking!");
 873                         else
 874                                 centerprint(self, "You are defending!");
 875                 }
 876
 877                 target_voicescript_clear(self);
 878
 879                 // reset fields the weapons may use
 880                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 881                 {
 882                         weapon_action(j, WR_RESETPLAYER);
 883
 884                         // all weapons must be fully loaded when we spawn
 885                         entity e;
 886                         e = get_weaponinfo(j);
 887                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 888                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 889                 }
 890
 891                 oldself = self;
 892                 self = spot;
 893                         activator = oldself;
 894                                 string s;
 895                                 s = self.target;
 896                                 self.target = string_null;
 897                                 SUB_UseTargets();
 898                                 self.target = s;
 899                         activator = world;
 900                 self = oldself;
 901
 902                 spawn_spot = spot;
 903                 MUTATOR_CALLHOOK(PlayerSpawn);
 904
 905                 if(autocvar_spawn_debug)
 906                 {
 907                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 908                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 909                 }
 910
 911                 self.switchweapon = w_getbestweapon(self);
 912                 self.cnt = -1; // W_LastWeapon will not complain
 913                 self.weapon = 0;
 914                 self.weaponname = "";
 915                 self.switchingweapon = 0;
 916
 917                 if(!self.alivetime)
 918                         self.alivetime = time;
 919
 920                 antilag_clear(self);
 921         } else if(self.classname == "observer") {
 922                 PutObserverInServer ();
 923         }
 924
 925         //if(g_ctf)
 926         //      ctf_playerchanged();
 927 }
 928
 929 .float ebouncefactor, ebouncestop; // electro's values
 930 // TODO do we need all these fields, or should we stop autodetecting runtime
 931 // changes and just have a console command to update this?
 932 float ClientInit_SendEntity(entity to, float sf)
 933 {
 934         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 935         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 948         if(sv_foginterval && world.fog != "")
 949                 WriteString(MSG_ENTITY, world.fog);
 950         else
 951                 WriteString(MSG_ENTITY, "");
 952         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 953         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 954         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 955         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 956         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 957         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 963         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 965         return TRUE;
 966 }
 967
 968 void ClientInit_CheckUpdate()
 969 {
 970         self.nextthink = time;
 971         if(self.count != autocvar_g_balance_armor_blockpercent)
 972         {
 973                 self.count = autocvar_g_balance_armor_blockpercent;
 974                 self.SendFlags |= 1;
 975         }
 976         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 977         {
 978                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 979                 self.SendFlags |= 1;
 980         }
 981         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 982         {
 983                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 987         {
 988                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 992         {
 993                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 994                 self.SendFlags |= 1;
 995         }
 996         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 997         {
 998                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 999                 self.SendFlags |= 1;
1000         }
1001 }
1002
1003 void ClientInit_Spawn()
1004 {
1005         entity o;
1006         entity e;
1007         e = spawn();
1008         e.classname = "clientinit";
1009         e.think = ClientInit_CheckUpdate;
1010         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1011
1012         o = self;
1013         self = e;
1014         ClientInit_CheckUpdate();
1015         self = o;
1016 }
1017
1018 /*
1019 =============
1020 SetNewParms
1021 =============
1022 */
1023 void SetNewParms (void)
1024 {
1025         // initialize parms for a new player
1026         parm1 = -(86400 * 366);
1027 }
1028
1029 /*
1030 =============
1031 SetChangeParms
1032 =============
1033 */
1034 void SetChangeParms (void)
1035 {
1036         // save parms for level change
1037         parm1 = self.parm_idlesince - time;
1038 }
1039
1040 /*
1041 =============
1042 DecodeLevelParms
1043 =============
1044 */
1045 void DecodeLevelParms (void)
1046 {
1047         // load parms
1048         self.parm_idlesince = parm1;
1049         if(self.parm_idlesince == -(86400 * 366))
1050                 self.parm_idlesince = time;
1051
1052         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1053         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1054 }
1055
1056 /*
1057 =============
1058 ClientKill
1059
1060 Called when a client types 'kill' in the console
1061 =============
1062 */
1063
1064 .float clientkill_nexttime;
1065 void ClientKill_Now_TeamChange()
1066 {
1067         if(self.killindicator_teamchange == -1)
1068         {
1069                 self.team = -1;
1070                 JoinBestTeam( self, FALSE, FALSE );
1071         }
1072         else if(self.killindicator_teamchange == -2)
1073         {
1074                 if(g_ca)
1075                         self.caplayer = 0;
1076                 if(blockSpectators)
1077                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1078                 PutObserverInServer();
1079         }
1080         else
1081                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1082 }
1083
1084 void ClientKill_Now()
1085 {
1086         if(self.vehicle)
1087         {
1088             vehicles_exit(VHEF_RELESE);
1089             if(!self.killindicator_teamchange)
1090             {
1091             self.vehicle_health = -1;
1092             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1093             }
1094         }
1095
1096         if(self.killindicator && !wasfreed(self.killindicator))
1097                 remove(self.killindicator);
1098
1099         self.killindicator = world;
1100
1101         if(self.killindicator_teamchange)
1102                 ClientKill_Now_TeamChange();
1103
1104         // in any case:
1105         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1106
1107         // now I am sure the player IS dead
1108 }
1109 void KillIndicator_Think()
1110 {
1111         if (gameover)
1112         {
1113                 self.owner.killindicator = world;
1114                 remove(self);
1115                 return;
1116         }
1117
1118         if (self.owner.alpha < 0)
1119         {
1120                 self.owner.killindicator = world;
1121                 remove(self);
1122                 return;
1123         }
1124
1125         if(self.cnt <= 0)
1126         {
1127                 self = self.owner;
1128                 ClientKill_Now(); // no oldself needed
1129                 return;
1130         }
1131     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1132     {
1133         self.nextthink = time + 1;
1134         self.cnt -= 1;
1135     }
1136         else
1137         {
1138                 if(self.cnt <= 10)
1139                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1140                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1141                 {
1142                         if(self.cnt <= 10)
1143                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1144                 }
1145                 self.nextthink = time + 1;
1146                 self.cnt -= 1;
1147         }
1148 }
1149
1150 float clientkilltime;
1151 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1152 {
1153         float killtime;
1154         float starttime;
1155         entity e;
1156
1157         if (gameover)
1158                 return;
1159
1160         killtime = autocvar_g_balance_kill_delay;
1161
1162         if(g_race_qualifying || g_cts)
1163                 killtime = 0;
1164
1165     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1166     {
1167                 remove(self.killindicator);
1168                 self.killindicator = world;
1169
1170         ClientKill_Now(); // allow instant kill in this case
1171         return;
1172     }
1173
1174         self.killindicator_teamchange = targetteam;
1175
1176     if(!self.killindicator)
1177         {
1178                 if(self.deadflag == DEAD_NO)
1179                 {
1180                         killtime = max(killtime, self.clientkill_nexttime - time);
1181                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1182                 }
1183
1184                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1185                 {
1186                         ClientKill_Now();
1187                 }
1188                 else
1189                 {
1190                         starttime = max(time, clientkilltime);
1191
1192                         self.killindicator = spawn();
1193                         self.killindicator.owner = self;
1194                         self.killindicator.scale = 0.5;
1195                         setattachment(self.killindicator, self, "");
1196                         setorigin(self.killindicator, '0 0 52');
1197                         self.killindicator.think = KillIndicator_Think;
1198                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1199                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1200                         self.killindicator.cnt = ceil(killtime);
1201                         self.killindicator.count = bound(0, ceil(killtime), 10);
1202                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1203
1204                         for(e = world; (e = find(e, classname, "body")) != world; )
1205                         {
1206                                 if(e.enemy != self)
1207                                         continue;
1208                                 e.killindicator = spawn();
1209                                 e.killindicator.owner = e;
1210                                 e.killindicator.scale = 0.5;
1211                                 setattachment(e.killindicator, e, "");
1212                                 setorigin(e.killindicator, '0 0 52');
1213                                 e.killindicator.think = KillIndicator_Think;
1214                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1215                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1216                                 e.killindicator.cnt = ceil(killtime);
1217                         }
1218                         self.lip = 0;
1219                 }
1220         }
1221         if(self.killindicator)
1222         {
1223                 if(targetteam == 0) // just die
1224                 {
1225                         self.killindicator.colormod = '0 0 0';
1226                         if(clienttype(self) == CLIENTTYPE_REAL)
1227                         if(self.killindicator.cnt > 0)
1228                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1229                 }
1230                 else if(targetteam == -1) // auto
1231                 {
1232                         self.killindicator.colormod = '0 1 0';
1233                         if(clienttype(self) == CLIENTTYPE_REAL)
1234                         if(self.killindicator.cnt > 0)
1235                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1236                 }
1237                 else if(targetteam == -2) // spectate
1238                 {
1239                         self.killindicator.colormod = '0.5 0.5 0.5';
1240                         if(clienttype(self) == CLIENTTYPE_REAL)
1241                         if(self.killindicator.cnt > 0)
1242                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1243                 }
1244                 else
1245                 {
1246                         self.killindicator.colormod = TeamColor(targetteam);
1247                         if(clienttype(self) == CLIENTTYPE_REAL)
1248                         if(self.killindicator.cnt > 0)
1249                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1250                 }
1251         }
1252
1253 }
1254
1255 void ClientKill (void)
1256 {
1257         if (gameover)
1258                 return;
1259
1260         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1261         {
1262                 // do nothing
1263         }
1264     else if(self.freezetag_frozen)
1265     {
1266         // do nothing
1267     }
1268         else
1269                 ClientKill_TeamChange(0);
1270 }
1271
1272 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1273 {
1274     e.killindicator = spawn();
1275     e.killindicator.owner = e;
1276     e.killindicator.think = KillIndicator_Think;
1277     e.killindicator.nextthink = time + (e.lip) * 0.05;
1278     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1279     e.killindicator.health = 1; // this is used to indicate that it should be silent
1280     e.lip = 0;
1281 }
1282
1283 void FixClientCvars(entity e)
1284 {
1285         // send prediction settings to the client
1286         stuffcmd(e, "\nin_bindmap 0 0\n");
1287         if(g_race || g_cts)
1288                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1289         if(autocvar_g_antilag == 3) // client side hitscan
1290                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1291         if(sv_gentle)
1292                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1293         /*
1294          * we no longer need to stuff this. Remove this comment block if you feel
1295          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1296         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1297         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1298         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1301         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1304         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1308         stuffcmd(e, "cl_movement_edgefriction 1\n");
1309          */
1310 }
1311
1312 float PlayerInIDList(entity p, string idlist)
1313 {
1314         float n, i;
1315         string s;
1316
1317         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1318         if not(p.crypto_idfp)
1319                 return 0;
1320
1321         // this function allows abbreviated player IDs too!
1322         n = tokenize_console(idlist);
1323         for(i = 0; i < n; ++i)
1324         {
1325                 s = argv(i);
1326                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1327                         return 1;
1328         }
1329
1330         return 0;
1331 }
1332
1333 /*
1334 =============
1335 ClientConnect
1336
1337 Called when a client connects to the server
1338 =============
1339 */
1340 //void ctf_clientconnect();
1341 string ColoredTeamName(float t);
1342 void DecodeLevelParms (void);
1343 //void dom_player_join_team(entity pl);
1344 void set_dom_state(entity e);
1345 void ClientConnect (void)
1346 {
1347         float t;
1348
1349         if(self.flags & FL_CLIENT)
1350         {
1351                 print("Warning: ClientConnect, but already connected!\n");
1352                 return;
1353         }
1354
1355         if(Ban_MaybeEnforceBan(self))
1356                 return;
1357
1358         DecodeLevelParms();
1359
1360 #ifdef WATERMARK
1361         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1362 #endif
1363
1364         self.classname = "player_joining";
1365
1366         self.flags = FL_CLIENT;
1367         self.version_nagtime = time + 10 + random() * 10;
1368
1369         if(player_count<0)
1370         {
1371                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1372                 player_count = 0;
1373         }
1374
1375         PlayerScore_Attach(self);
1376         ClientData_Attach();
1377         accuracy_init(self);
1378
1379         bot_clientconnect();
1380
1381         playerdemo_init();
1382
1383         anticheat_init();
1384
1385         race_PreSpawnObserver();
1386
1387         //if(g_domination)
1388         //      dom_player_join_team(self);
1389
1390         // identify the right forced team
1391         if(autocvar_g_campaign)
1392         {
1393                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1394                 {
1395                         switch(autocvar_g_campaign_forceteam)
1396                         {
1397                                 case 1: self.team_forced = COLOR_TEAM1; break;
1398                                 case 2: self.team_forced = COLOR_TEAM2; break;
1399                                 case 3: self.team_forced = COLOR_TEAM3; break;
1400                                 case 4: self.team_forced = COLOR_TEAM4; break;
1401                                 default: self.team_forced = 0;
1402                         }
1403                 }
1404         }
1405         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1406                 self.team_forced = COLOR_TEAM1;
1407         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1408                 self.team_forced = COLOR_TEAM2;
1409         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1410                 self.team_forced = COLOR_TEAM3;
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1412                 self.team_forced = COLOR_TEAM4;
1413         else if(autocvar_g_forced_team_otherwise == "red")
1414                 self.team_forced = COLOR_TEAM1;
1415         else if(autocvar_g_forced_team_otherwise == "blue")
1416                 self.team_forced = COLOR_TEAM2;
1417         else if(autocvar_g_forced_team_otherwise == "yellow")
1418                 self.team_forced = COLOR_TEAM3;
1419         else if(autocvar_g_forced_team_otherwise == "pink")
1420                 self.team_forced = COLOR_TEAM4;
1421         else if(autocvar_g_forced_team_otherwise == "spectate")
1422                 self.team_forced = -1;
1423         else if(autocvar_g_forced_team_otherwise == "spectator")
1424                 self.team_forced = -1;
1425         else
1426                 self.team_forced = 0;
1427
1428         if(!teamplay)
1429                 if(self.team_forced > 0)
1430                         self.team_forced = 0;
1431
1432         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1433
1434         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1435                 self.classname = "observer";
1436         } else {
1437                 if(teamplay)
1438                 {
1439                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1440                         {
1441                                 self.classname = "player";
1442                                 campaign_bots_may_start = 1;
1443                         }
1444                         else
1445                         {
1446                                 self.classname = "observer"; // do it anyway
1447                         }
1448                 }
1449                 else
1450                 {
1451                         self.classname = "player";
1452                         campaign_bots_may_start = 1;
1453                 }
1454         }
1455
1456         self.playerid = (playerid_last = playerid_last + 1);
1457
1458         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1459
1460     if(clienttype(self) == CLIENTTYPE_BOT)
1461         PlayerStats_AddPlayer(self);
1462
1463         if(autocvar_sv_eventlog)
1464                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1465
1466         LogTeamchange(self.playerid, self.team, 1);
1467
1468         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1469
1470         self.netname_previous = strzone(self.netname);
1471
1472         bprint("^4", self.netname, "^4 connected");
1473
1474         if(self.classname != "observer" && (g_domination || g_ctf))
1475                 bprint(" and joined the ", ColoredTeamName(self.team));
1476
1477         bprint("\n");
1478
1479         stuffcmd(self, strcat(clientstuff, "\n"));
1480         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1481
1482         FixClientCvars(self);
1483
1484         // spawnfunc_waypoint sprites
1485         WaypointSprite_InitClient(self);
1486
1487         // Wazat's grappling hook
1488         SetGrappleHookBindings();
1489
1490         // get version info from player
1491         stuffcmd(self, "cmd clientversion $gameversion\n");
1492
1493         // get other cvars from player
1494         GetCvars(0);
1495
1496         // notify about available teams
1497         if(teamplay)
1498         {
1499                 CheckAllowedTeams(self);
1500                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1501                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1502         }
1503         else
1504                 stuffcmd(self, "set _teams_available 0\n");
1505
1506         if(g_arena || g_ca)
1507         {
1508                 self.classname = "observer";
1509                 if(g_arena)
1510                         Spawnqueue_Insert(self);
1511         }
1512         /*else if(g_ctf)
1513         {
1514                 ctf_clientconnect();
1515         }*/
1516
1517         attach_entcs();
1518
1519         bot_relinkplayerlist();
1520
1521         self.spectatortime = time;
1522         if(blockSpectators)
1523         {
1524                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1525         }
1526
1527         self.jointime = time;
1528         self.allowed_timeouts = autocvar_sv_timeout_number;
1529
1530         if(clienttype(self) == CLIENTTYPE_REAL)
1531         {
1532                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1533                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1534         }
1535
1536         if(g_lms)
1537         {
1538                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1539                 {
1540                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1541                         self.frags = FRAGS_SPECTATOR;
1542                 }
1543         }
1544
1545         if(!sv_foginterval && world.fog != "")
1546                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1547
1548         SoundEntity_Attach(self);
1549
1550         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1551         {
1552                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1553                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1554         }
1555         else
1556                 self.hitplotfh = -1;
1557
1558         if(g_race || g_cts) {
1559                 string rr;
1560                 if(g_cts)
1561                         rr = CTS_RECORD;
1562                 else
1563                         rr = RACE_RECORD;
1564                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1565
1566                 msg_entity = self;
1567                 race_send_recordtime(MSG_ONE);
1568                 race_send_speedaward(MSG_ONE);
1569
1570                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1571                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1572                 race_send_speedaward_alltimebest(MSG_ONE);
1573
1574                 float i;
1575                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1576                         race_SendRankings(i, 0, 0, MSG_ONE);
1577                 }
1578         }
1579         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1580                 send_CSQC_teamnagger();
1581
1582         if (g_domination)
1583                 set_dom_state(self);
1584
1585         CheatInitClient();
1586
1587         if(!autocvar_g_campaign)
1588                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1589
1590         CSQCMODEL_AUTOINIT();
1591
1592         self.model_randomizer = random();
1593
1594     if(clienttype(self) != CLIENTTYPE_REAL)
1595         return;
1596
1597     sv_notice_join();
1598 }
1599 /*
1600 =============
1601 ClientDisconnect
1602
1603 Called when a client disconnects from the server
1604 =============
1605 */
1606 .entity chatbubbleentity;
1607 void ReadyCount();
1608 void ClientDisconnect (void)
1609 {
1610         if(self.vehicle)
1611             vehicles_exit(VHEF_RELESE);
1612
1613         if not(self.flags & FL_CLIENT)
1614         {
1615                 print("Warning: ClientDisconnect without ClientConnect\n");
1616                 return;
1617         }
1618
1619         PlayerStats_AddGlobalInfo(self);
1620
1621         CheatShutdownClient();
1622
1623         if(self.hitplotfh >= 0)
1624         {
1625                 fclose(self.hitplotfh);
1626                 self.hitplotfh = -1;
1627         }
1628
1629         anticheat_report();
1630         anticheat_shutdown();
1631
1632         playerdemo_shutdown();
1633
1634         bot_clientdisconnect();
1635
1636         if(self.entcs)
1637                 detach_entcs();
1638
1639         if(autocvar_sv_eventlog)
1640                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1641         bprint ("^4",self.netname);
1642         bprint ("^4 disconnected\n");
1643
1644         SoundEntity_Detach(self);
1645
1646         DropAllRunes(self);
1647         MUTATOR_CALLHOOK(ClientDisconnect);
1648
1649         Portal_ClearAll(self);
1650
1651         RemoveGrapplingHook(self);
1652
1653         // Here, everything has been done that requires this player to be a client.
1654
1655         self.flags &~= FL_CLIENT;
1656
1657         if (self.chatbubbleentity)
1658                 remove (self.chatbubbleentity);
1659
1660         if (self.killindicator)
1661                 remove (self.killindicator);
1662
1663         WaypointSprite_PlayerGone();
1664
1665         bot_relinkplayerlist();
1666
1667         if(g_arena)
1668         {
1669                 Spawnqueue_Unmark(self);
1670                 Spawnqueue_Remove(self);
1671         }
1672
1673         accuracy_free(self);
1674         ClientData_Detach();
1675         PlayerScore_Detach(self);
1676
1677         if(self.netname_previous)
1678                 strunzone(self.netname_previous);
1679         if(self.clientstatus)
1680                 strunzone(self.clientstatus);
1681         if(self.weaponorder_byimpulse)
1682                 strunzone(self.weaponorder_byimpulse);
1683
1684         ClearPlayerSounds();
1685
1686         if(self.personal)
1687                 remove(self.personal);
1688
1689         self.playerid = 0;
1690         ReadyCount();
1691
1692         // free cvars
1693         GetCvars(-1);
1694 }
1695
1696 .float BUTTON_CHAT;
1697 void ChatBubbleThink()
1698 {
1699         self.nextthink = time;
1700         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1701         {
1702                 if(self.owner) // but why can that ever be world?
1703                         self.owner.chatbubbleentity = world;
1704                 remove(self);
1705                 return;
1706         }
1707         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1708 #ifdef TETRIS
1709                 || self.owner.tetris_on
1710 #endif
1711         )
1712                 self.model = self.mdl;
1713         else
1714                 self.model = "";
1715 }
1716
1717 void UpdateChatBubble()
1718 {
1719         if (self.alpha < 0)
1720                 return;
1721         // spawn a chatbubble entity if needed
1722         if (!self.chatbubbleentity)
1723         {
1724                 self.chatbubbleentity = spawn();
1725                 self.chatbubbleentity.owner = self;
1726                 self.chatbubbleentity.exteriormodeltoclient = self;
1727                 self.chatbubbleentity.think = ChatBubbleThink;
1728                 self.chatbubbleentity.nextthink = time;
1729                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1730                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1731                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1732                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1733                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1734                 self.chatbubbleentity.model = "";
1735                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1736         }
1737 }
1738
1739
1740 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1741 // added to the model skins
1742 /*void UpdateColorModHack()
1743 {
1744         float c;
1745         c = self.clientcolors & 15;
1746         // LordHavoc: only bothering to support white, green, red, yellow, blue
1747              if (!teamplay) self.colormod = '0 0 0';
1748         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1749         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1750         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1751         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1752         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1753         else self.colormod = '1 1 1';
1754 }*/
1755
1756 void respawn(void)
1757 {
1758         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1759         {
1760                 self.solid = SOLID_NOT;
1761                 self.takedamage = DAMAGE_NO;
1762                 self.movetype = MOVETYPE_FLY;
1763                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1764                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1765                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1766                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1767                 if(autocvar_g_respawn_ghosts_maxtime)
1768                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1769         }
1770
1771         CopyBody(1);
1772
1773         self.effects |= EF_NODRAW; // prevent another CopyBody
1774         PutClientInServer();
1775 }
1776
1777 void play_countdown(float finished, string samp)
1778 {
1779         if(clienttype(self) == CLIENTTYPE_REAL)
1780                 if(floor(finished - time - frametime) != floor(finished - time))
1781                         if(finished - time < 6)
1782                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1783 }
1784
1785 void player_powerups (void)
1786 {
1787         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1788         olditems = self.items;
1789
1790         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1791         {
1792                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1793                 self.modelflags |= MF_ROCKET;
1794         }
1795         else
1796         {
1797                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1798                 self.modelflags &~= MF_ROCKET;
1799         }
1800
1801         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1802
1803         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1804                 return;
1805
1806         Fire_ApplyDamage(self);
1807         Fire_ApplyEffect(self);
1808
1809         if (g_minstagib)
1810         {
1811                 self.effects |= EF_FULLBRIGHT;
1812
1813                 if (self.items & IT_STRENGTH)
1814                 {
1815                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1816                         if (time > self.strength_finished)
1817                         {
1818                                 self.alpha = default_player_alpha;
1819                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1820                                 self.items &~= IT_STRENGTH;
1821                                 sprint(self, "^3Invisibility has worn off\n");
1822                         }
1823                 }
1824                 else
1825                 {
1826                         if (time < self.strength_finished)
1827                         {
1828                                 self.alpha = g_minstagib_invis_alpha;
1829                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1830                                 self.items |= IT_STRENGTH;
1831                                 sprint(self, "^3You are invisible\n");
1832                         }
1833                 }
1834
1835                 if (self.items & IT_INVINCIBLE)
1836                 {
1837                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1838                         if (time > self.invincible_finished)
1839                         {
1840                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1841                                 sprint(self, "^3Speed has worn off\n");
1842                         }
1843                 }
1844                 else
1845                 {
1846                         if (time < self.invincible_finished)
1847                         {
1848                                 self.items = self.items | IT_INVINCIBLE;
1849                                 sprint(self, "^3You are on speed\n");
1850                         }
1851                 }
1852         }
1853         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1854         {
1855                 if (self.items & IT_STRENGTH)
1856                 {
1857                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1858                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1859                         if (time > self.strength_finished)
1860                         {
1861                                 self.items = self.items - (self.items & IT_STRENGTH);
1862                                 sprint(self, "^3Strength has worn off\n");
1863                         }
1864                 }
1865                 else
1866                 {
1867                         if (time < self.strength_finished)
1868                         {
1869                                 self.items = self.items | IT_STRENGTH;
1870                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1871                         }
1872                 }
1873                 if (self.items & IT_INVINCIBLE)
1874                 {
1875                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1876                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1877                         if (time > self.invincible_finished)
1878                         {
1879                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1880                                 sprint(self, "^3Shield has worn off\n");
1881                         }
1882                 }
1883                 else
1884                 {
1885                         if (time < self.invincible_finished)
1886                         {
1887                                 self.items = self.items | IT_INVINCIBLE;
1888                                 sprint(self, "^3Shield surrounds you\n");
1889                         }
1890                 }
1891                 if (self.items & IT_SUPERWEAPON)
1892                 {
1893                         //if(W_WeaponBit(self.weapon) & WEPBIT_SUPERWEAPONS)
1894                         //      self.effects = self.effects | EF_RED;
1895                         if (!(self.weapons & WEPBIT_SUPERWEAPONS))
1896                         {
1897                                 self.superweapons_finished = 0;
1898                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1899                                 sprint(self, "^3Superweapons have been lost\n");
1900                         }
1901                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1902                         {
1903                                 // don't let them run out
1904                         }
1905                         else
1906                         {
1907                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1908                                 if (time > self.superweapons_finished)
1909                                 {
1910                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1911                                         self.weapons &~= WEPBIT_SUPERWEAPONS;
1912                                         sprint(self, "^3Superweapons have broken down\n");
1913                                 }
1914                         }
1915                 }
1916                 else if(self.weapons & WEPBIT_SUPERWEAPONS)
1917                 {
1918                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1919                         {
1920                                 self.items = self.items | IT_SUPERWEAPON;
1921                                 sprint(self, "^3You now have a superweapon\n");
1922                         }
1923                         else
1924                         {
1925                                 self.superweapons_finished = 0;
1926                                 self.weapons &~= WEPBIT_SUPERWEAPONS; // just in case
1927                         }
1928                 }
1929                 else
1930                 {
1931                         self.superweapons_finished = 0;
1932                 }
1933         }
1934
1935         if(autocvar_g_nodepthtestplayers)
1936                 self.effects = self.effects | EF_NODEPTHTEST;
1937
1938         if(autocvar_g_fullbrightplayers)
1939                 self.effects = self.effects | EF_FULLBRIGHT;
1940
1941         // midair gamemode: damage only while in the air
1942         // if in midair mode, being on ground grants temporary invulnerability
1943         // (this is so that multishot weapon don't clear the ground flag on the
1944         // first damage in the frame, leaving the player vulnerable to the
1945         // remaining hits in the same frame)
1946         if (self.flags & FL_ONGROUND)
1947         if (g_midair)
1948                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1949
1950         if (time >= game_starttime)
1951         if (time < self.spawnshieldtime)
1952                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1953
1954         MUTATOR_CALLHOOK(PlayerPowerups);
1955 }
1956
1957 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1958 {
1959         if(current > stable)
1960                 return current;
1961         else if(current > stable - 0.25) // when close enough, "snap"
1962                 return stable;
1963         else
1964                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1965 }
1966
1967 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1968 {
1969         if(current < stable)
1970                 return current;
1971         else if(current < stable + 0.25) // when close enough, "snap"
1972                 return stable;
1973         else
1974                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1975 }
1976
1977 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1978 {
1979         if(current > rotstable)
1980         {
1981                 if(rotframetime > 0)
1982                 {
1983                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1984                         current = max(rotstable, current - rotlinear * rotframetime);
1985                 }
1986         }
1987         else if(current < regenstable)
1988         {
1989                 if(regenframetime > 0)
1990                 {
1991                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1992                         current = min(regenstable, current + regenlinear * regenframetime);
1993                 }
1994         }
1995
1996         if(current > limit)
1997                 current = limit;
1998
1999         return current;
2000 }
2001
2002 void player_regen (void)
2003 {
2004         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2005         maxh = autocvar_g_balance_health_rotstable;
2006         maxa = autocvar_g_balance_armor_rotstable;
2007         maxf = autocvar_g_balance_fuel_rotstable;
2008         minh = autocvar_g_balance_health_regenstable;
2009         mina = autocvar_g_balance_armor_regenstable;
2010         minf = autocvar_g_balance_fuel_regenstable;
2011         limith = autocvar_g_balance_health_limit;
2012         limita = autocvar_g_balance_armor_limit;
2013         limitf = autocvar_g_balance_fuel_limit;
2014
2015         max_mod = regen_mod = rot_mod = limit_mod = 1;
2016
2017         if (self.runes & RUNE_REGEN)
2018         {
2019                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2020                 {
2021                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2022                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2023                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2024                 }
2025                 else
2026                 {
2027                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2028                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2029                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2030                 }
2031         }
2032         else if (self.runes & CURSE_VENOM)
2033         {
2034                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2035                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2036                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2037                 else
2038                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2039                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2040                 //if (!self.runes & RUNE_REGEN)
2041                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2042         }
2043         maxh = maxh * max_mod;
2044         //maxa = maxa * max_mod;
2045         //maxf = maxf * max_mod;
2046         minh = minh * max_mod;
2047         //mina = mina * max_mod;
2048         //minf = minf * max_mod;
2049         limith = limith * limit_mod;
2050         limita = limita * limit_mod;
2051         //limitf = limitf * limit_mod;
2052
2053         if(g_lms && g_ca)
2054                 rot_mod = 0;
2055
2056         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2057         {
2058                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2059                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2060
2061                 // if player rotted to death...  die!
2062                 if(self.health < 1)
2063                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2064         }
2065
2066         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2067                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2068 }
2069
2070 float zoomstate_set;
2071 void SetZoomState(float z)
2072 {
2073         if(z != self.zoomstate)
2074         {
2075                 self.zoomstate = z;
2076                 ClientData_Touch(self);
2077         }
2078         zoomstate_set = 1;
2079 }
2080
2081 void GetPressedKeys(void) {
2082         MUTATOR_CALLHOOK(GetPressedKeys);
2083         if (self.movement_x > 0) // get if movement keys are pressed
2084         {       // forward key pressed
2085                 self.pressedkeys |= KEY_FORWARD;
2086                 self.pressedkeys &~= KEY_BACKWARD;
2087         }
2088         else if (self.movement_x < 0)
2089         {       // backward key pressed
2090                 self.pressedkeys |= KEY_BACKWARD;
2091                 self.pressedkeys &~= KEY_FORWARD;
2092         }
2093         else
2094         {       // no x input
2095                 self.pressedkeys &~= KEY_FORWARD;
2096                 self.pressedkeys &~= KEY_BACKWARD;
2097         }
2098
2099         if (self.movement_y > 0)
2100         {       // right key pressed
2101                 self.pressedkeys |= KEY_RIGHT;
2102                 self.pressedkeys &~= KEY_LEFT;
2103         }
2104         else if (self.movement_y < 0)
2105         {       // left key pressed
2106                 self.pressedkeys |= KEY_LEFT;
2107                 self.pressedkeys &~= KEY_RIGHT;
2108         }
2109         else
2110         {       // no y input
2111                 self.pressedkeys &~= KEY_RIGHT;
2112                 self.pressedkeys &~= KEY_LEFT;
2113         }
2114
2115         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2116                 self.pressedkeys |= KEY_JUMP;
2117         else
2118                 self.pressedkeys &~= KEY_JUMP;
2119         if (self.BUTTON_CROUCH)
2120                 self.pressedkeys |= KEY_CROUCH;
2121         else
2122                 self.pressedkeys &~= KEY_CROUCH;
2123 }
2124
2125 /*
2126 ======================
2127 spectate mode routines
2128 ======================
2129 */
2130
2131 void SpectateCopy(entity spectatee) {
2132         other = spectatee;
2133         MUTATOR_CALLHOOK(SpectateCopy);
2134         self.armortype = spectatee.armortype;
2135         self.armorvalue = spectatee.armorvalue;
2136         self.ammo_cells = spectatee.ammo_cells;
2137         self.ammo_shells = spectatee.ammo_shells;
2138         self.ammo_nails = spectatee.ammo_nails;
2139         self.ammo_rockets = spectatee.ammo_rockets;
2140         self.ammo_fuel = spectatee.ammo_fuel;
2141         self.clip_load = spectatee.clip_load;
2142         self.clip_size = spectatee.clip_size;
2143         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2144         self.health = spectatee.health;
2145         self.impulse = 0;
2146         self.items = spectatee.items;
2147         self.last_pickup = spectatee.last_pickup;
2148         self.hit_time = spectatee.hit_time;
2149         self.metertime = spectatee.metertime;
2150         self.strength_finished = spectatee.strength_finished;
2151         self.invincible_finished = spectatee.invincible_finished;
2152         self.pressedkeys = spectatee.pressedkeys;
2153         self.weapons = spectatee.weapons;
2154         self.switchweapon = spectatee.switchweapon;
2155         self.switchingweapon = spectatee.switchingweapon;
2156         self.weapon = spectatee.weapon;
2157         self.nex_charge = spectatee.nex_charge;
2158         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2159         self.hagar_load = spectatee.hagar_load;
2160         self.minelayer_mines = spectatee.minelayer_mines;
2161         self.punchangle = spectatee.punchangle;
2162         self.view_ofs = spectatee.view_ofs;
2163         self.v_angle = spectatee.v_angle;
2164         self.velocity = spectatee.velocity;
2165         self.dmg_take = spectatee.dmg_take;
2166         self.dmg_save = spectatee.dmg_save;
2167         self.dmg_inflictor = spectatee.dmg_inflictor;
2168         self.angles = spectatee.v_angle;
2169         if(!self.BUTTON_USE)
2170                 self.fixangle = TRUE;
2171         setorigin(self, spectatee.origin);
2172         setsize(self, spectatee.mins, spectatee.maxs);
2173         SetZoomState(spectatee.zoomstate);
2174
2175         anticheat_spectatecopy(spectatee);
2176
2177         //self.vehicle = spectatee.vehicle;
2178
2179         self.hud = spectatee.hud;
2180         if(spectatee.vehicle)
2181     {
2182         setorigin(self, spectatee.origin);
2183         self.velocity = spectatee.vehicle.velocity;
2184         self.v_angle += spectatee.vehicle.angles;
2185         //self.v_angle_x *= -1;
2186         self.vehicle_health = spectatee.vehicle_health;
2187         self.vehicle_shield = spectatee.vehicle_shield;
2188         self.vehicle_energy = spectatee.vehicle_energy;
2189         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2190         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2191         self.vehicle_reload1 = spectatee.vehicle_reload1;
2192         self.vehicle_reload2 = spectatee.vehicle_reload2;
2193
2194         msg_entity = self;
2195         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2196         WriteEntity(MSG_ONE, spectatee);
2197         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2198     }
2199 }
2200
2201 float SpectateUpdate() {
2202         if(!self.enemy)
2203             return 0;
2204
2205         if (self == self.enemy)
2206                 return 0;
2207
2208         if(self.enemy.classname != "player")
2209                 return 0;
2210
2211         SpectateCopy(self.enemy);
2212
2213         return 1;
2214 }
2215
2216
2217 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2218 entity CA_SpectateNext(entity start) {
2219         if (start.team == self.team) {
2220                 return start;
2221         }
2222
2223         other = start;
2224         // continue from current player
2225         while(other && other.team != self.team) {
2226                 other = find(other, classname, "player");
2227         }
2228
2229         if (!other) {
2230                 // restart from begining
2231                 other = find(other, classname, "player");
2232                 while(other && other.team != self.team) {
2233                         other = find(other, classname, "player");
2234                 }
2235         }
2236
2237         return other;
2238 }
2239
2240 float SpectateNext() {
2241         other = find(self.enemy, classname, "player");
2242         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2243                 // CA and ca players when spectating enemies is forbidden
2244                 other = CA_SpectateNext(other);
2245         } else {
2246                 // other modes and ca spectators or spectating enemies is allowed
2247                 if (!other)
2248                         other = find(other, classname, "player");
2249         }
2250
2251         if (other)
2252                 self.enemy = other;
2253
2254         if(self.enemy.classname == "player") {
2255             if(self.enemy.vehicle)
2256             {
2257             msg_entity = self;
2258             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2259             WriteEntity(MSG_ONE, self.enemy);
2260             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2261             self.movetype = MOVETYPE_NONE;
2262             accuracy_resend(self);
2263             }
2264             else
2265             {
2266             msg_entity = self;
2267             WriteByte(MSG_ONE, SVC_SETVIEW);
2268             WriteEntity(MSG_ONE, self.enemy);
2269             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2270             self.movetype = MOVETYPE_NONE;
2271             accuracy_resend(self);
2272
2273             if(!SpectateUpdate())
2274                 PutObserverInServer();
2275         }
2276         return 1;
2277         } else {
2278                 return 0;
2279         }
2280 }
2281
2282 /*
2283 =============
2284 ShowRespawnCountdown()
2285
2286 Update a respawn countdown display.
2287 =============
2288 */
2289 void ShowRespawnCountdown()
2290 {
2291         float number;
2292         if(self.deadflag == DEAD_NO) // just respawned?
2293                 return;
2294         else
2295         {
2296                 number = ceil(self.respawn_time - time);
2297                 if(number <= 0)
2298                         return;
2299                 if(number <= self.respawn_countdown)
2300                 {
2301                         self.respawn_countdown = number - 1;
2302                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2303                                 AnnounceTo(self, strcat(ftos(number), ""));
2304                 }
2305         }
2306 }
2307
2308 .float prevent_join_msgtime;
2309 void LeaveSpectatorMode()
2310 {
2311         if(nJoinAllowed(self)) {
2312                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2313                         self.classname = "player";
2314
2315                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2316                                 JoinBestTeam(self, FALSE, TRUE);
2317
2318                         if(autocvar_g_campaign)
2319                                 campaign_bots_may_start = 1;
2320
2321                         PutClientInServer();
2322
2323                         if(self.classname == "player")
2324                                 bprint ("^4", self.netname, "^4 is playing now\n");
2325
2326                         if(!autocvar_g_campaign)
2327                         if (time < self.jointime + autocvar_welcome_message_time)
2328                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2329
2330                         if (self.prevent_join_msgtime)
2331                         {
2332                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2333                                 self.prevent_join_msgtime = 0;
2334                         }
2335
2336                         return;
2337                 } else {
2338                         if (g_ca && self.caplayer) {
2339                         }       // do nothing
2340                         else
2341                                 stuffcmd(self,"menu_showteamselect\n");
2342                         return;
2343                 }
2344         }
2345         else {
2346                 //player may not join because of g_maxplayers is set
2347                 if (time - self.prevent_join_msgtime > 2)
2348                 {
2349                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2350                         self.prevent_join_msgtime = time;
2351                 }
2352         }
2353 }
2354
2355 /**
2356  * Determines whether the player is allowed to join. This depends on cvar
2357  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2358  * it checks whether the number of currently playing players exceeds g_maxplayers.
2359  * @return int number of free slots for players, 0 if none
2360  */
2361 float nJoinAllowed(entity ignore) {
2362         if(!ignore)
2363         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2364         // so report 0 free slots if restricted
2365         {
2366                 if(autocvar_g_forced_team_otherwise == "spectate")
2367                         return 0;
2368                 if(autocvar_g_forced_team_otherwise == "spectator")
2369                         return 0;
2370         }
2371
2372         if(self.team_forced < 0)
2373                 return 0; // forced spectators can never join
2374
2375         // TODO simplify this
2376         entity e;
2377         float totalClients;
2378         FOR_EACH_CLIENT(e)
2379                 if(e != ignore)
2380                         totalClients += 1;
2381
2382         if (!autocvar_g_maxplayers)
2383                 return maxclients - totalClients;
2384
2385         float currentlyPlaying;
2386         FOR_EACH_REALPLAYER(e)
2387                 currentlyPlaying += 1;
2388
2389         if(currentlyPlaying < autocvar_g_maxplayers)
2390                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2391
2392         return 0;
2393 }
2394
2395 /**
2396  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2397  * g_maxplayers_spectator_blocktime seconds
2398  */
2399 void checkSpectatorBlock() {
2400         if(self.classname == "spectator" || self.classname == "observer") {
2401                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2402                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2403                         dropclient(self);
2404                 }
2405         }
2406 }
2407
2408 .float motd_actived_time; // used for both motd and campaign_message
2409 void PrintWelcomeMessage()
2410 {
2411         if (self.motd_actived_time == 0) { // is there already a message showing?
2412                 if (autocvar_g_campaign) {
2413                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2414                                 self.motd_actived_time = time;
2415                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2416                         }
2417                 } else {
2418                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2419                                 self.motd_actived_time = time;
2420                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2421                         }
2422                 }
2423         } else { // showing MOTD or campaign message
2424                 if (autocvar_g_campaign) {
2425                         if (self.BUTTON_INFO)
2426                                 self.motd_actived_time = time;
2427                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2428                                 self.motd_actived_time = 0;
2429                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2430                         }
2431                 } else {
2432                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2433                                 if (self.BUTTON_INFO)
2434                                         self.motd_actived_time = time;
2435                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2436                                         self.motd_actived_time = 0;
2437                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2438                                 }
2439                         }
2440                 }
2441         }
2442 }
2443
2444 void ObserverThink()
2445 {
2446         float prefered_movetype;
2447         if (self.flags & FL_JUMPRELEASED) {
2448                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2449                         self.flags &~= FL_JUMPRELEASED;
2450                         self.flags |= FL_SPAWNING;
2451                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2452                         self.flags &~= FL_JUMPRELEASED;
2453                         if(SpectateNext() == 1) {
2454                                 self.classname = "spectator";
2455                         }
2456                 } else {
2457                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2458                         if (self.movetype != prefered_movetype)
2459                                 self.movetype = prefered_movetype;
2460                 }
2461         } else {
2462                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2463                         self.flags |= FL_JUMPRELEASED;
2464                         if(self.flags & FL_SPAWNING)
2465                         {
2466                                 self.flags &~= FL_SPAWNING;
2467                                 LeaveSpectatorMode();
2468                                 return;
2469                         }
2470                 }
2471         }
2472
2473         PrintWelcomeMessage();
2474 }
2475
2476 void SpectatorThink()
2477 {
2478         if (self.flags & FL_JUMPRELEASED) {
2479                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2480                         self.flags &~= FL_JUMPRELEASED;
2481                         self.flags |= FL_SPAWNING;
2482                 } else if(self.BUTTON_ATCK) {
2483                         self.flags &~= FL_JUMPRELEASED;
2484                         if(SpectateNext() == 1) {
2485                                 self.classname = "spectator";
2486                         } else {
2487                                 self.classname = "observer";
2488                                 PutClientInServer();
2489                         }
2490                 } else if (self.BUTTON_ATCK2) {
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         self.classname = "observer";
2493                         PutClientInServer();
2494                 } else {
2495                         if(!SpectateUpdate())
2496                                 PutObserverInServer();
2497                 }
2498         } else {
2499                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2500                         self.flags |= FL_JUMPRELEASED;
2501                         if(self.flags & FL_SPAWNING)
2502                         {
2503                                 self.flags &~= FL_SPAWNING;
2504                                 LeaveSpectatorMode();
2505                                 return;
2506                         }
2507                 }
2508                 if(!SpectateUpdate())
2509                         PutObserverInServer();
2510         }
2511
2512         PrintWelcomeMessage();
2513         self.flags |= FL_CLIENT | FL_NOTARGET;
2514 }
2515
2516 void PlayerUseKey()
2517 {
2518         if(self.classname != "player")
2519                 return;
2520
2521         if(self.vehicle)
2522         {
2523         vehicles_exit(VHEF_NORMAL);
2524         return;
2525         }
2526
2527         // a use key was pressed; call handlers
2528         MUTATOR_CALLHOOK(PlayerUseKey);
2529 }
2530
2531 .float touchexplode_time;
2532
2533 /*
2534 =============
2535 PlayerPreThink
2536
2537 Called every frame for each client before the physics are run
2538 =============
2539 */
2540 .float usekeypressed;
2541 //void() ctf_setstatus;
2542 void() nexball_setstatus;
2543 .float items_added;
2544 void PlayerPreThink (void)
2545 {
2546         WarpZone_PlayerPhysics_FixVAngle();
2547
2548         self.stat_game_starttime = game_starttime;
2549         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2550         self.stat_leadlimit = autocvar_leadlimit;
2551
2552         if(frametime)
2553         {
2554                 // physics frames: update anticheat stuff
2555                 anticheat_prethink();
2556         }
2557
2558         if(blockSpectators && frametime)
2559                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2560                 checkSpectatorBlock();
2561
2562         zoomstate_set = 0;
2563
2564         if(self.netname_previous != self.netname)
2565         {
2566                 if(autocvar_sv_eventlog)
2567                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2568                 if(self.netname_previous)
2569                         strunzone(self.netname_previous);
2570                 self.netname_previous = strzone(self.netname);
2571         }
2572
2573         // version nagging
2574         if(self.version_nagtime)
2575                 if(self.cvar_g_xonoticversion)
2576                         if(time > self.version_nagtime)
2577                         {
2578                                 // don't notify git users
2579                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2580                                 {
2581                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2582                                         {
2583                                                 // notify release users if connecting to git
2584                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2585                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2586                                         }
2587                                         else
2588                                         {
2589                                                 float r;
2590                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2591                                                 if(r < 0)
2592                                                 {
2593                                                         // give users new version
2594                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2595                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2596                                                 }
2597                                                 else if(r > 0)
2598                                                 {
2599                                                         // notify users about old server version
2600                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2601                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2602                                                 }
2603                                         }
2604                                 }
2605                                 self.version_nagtime = 0;
2606                         }
2607
2608         // GOD MODE info
2609         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2610         {
2611                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2612                 self.max_armorvalue = 0;
2613         }
2614
2615 #ifdef TETRIS
2616         if (TetrisPreFrame())
2617                 return;
2618 #endif
2619
2620         MUTATOR_CALLHOOK(PlayerPreThink);
2621
2622         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2623         {
2624                 if(self.BUTTON_USE && !self.usekeypressed)
2625                         PlayerUseKey();
2626                 self.usekeypressed = self.BUTTON_USE;
2627         }
2628
2629         PrintWelcomeMessage();
2630
2631         if(self.classname == "player") {
2632 //              if(self.netname == "Wazat")
2633 //                      bprint(self.classname, "\n");
2634
2635                 CheckRules_Player();
2636
2637                 if (intermission_running)
2638                 {
2639                         IntermissionThink ();   // otherwise a button could be missed between
2640                         return;                                 // the think tics
2641                 }
2642
2643                 //don't allow the player to turn around while game is paused!
2644                 if(timeout_status == TIMEOUT_ACTIVE) {
2645                         // FIXME turn this into CSQC stuff
2646                         self.v_angle = self.lastV_angle;
2647                         self.angles = self.lastV_angle;
2648                         self.fixangle = TRUE;
2649                 }
2650
2651                 if(frametime)
2652                 {
2653 #ifndef NO_LEGACY_NETWORKING
2654                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2655 #endif
2656
2657                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2658                         {
2659                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2660                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2661                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2662
2663                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2664                                 {
2665                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2666                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2667                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2668                                 }
2669                         }
2670                         else
2671                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2672
2673                         player_powerups();
2674                 }
2675
2676                 if (g_minstagib)
2677                         minstagib_ammocheck();
2678
2679                 if (self.deadflag != DEAD_NO)
2680                 {
2681                         float button_pressed, force_respawn;
2682                         if(self.personal && g_race_qualifying)
2683                         {
2684                                 if(time > self.respawn_time)
2685                                 {
2686                                         self.respawn_time = time + 1; // only retry once a second
2687                                         respawn();
2688                                         self.impulse = 141;
2689                                 }
2690                         }
2691                         else
2692                         {
2693                                 if(frametime)
2694                                         player_anim();
2695                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2696                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2697                                 if (self.deadflag == DEAD_DYING)
2698                                 {
2699                                         if(force_respawn)
2700                                                 self.deadflag = DEAD_RESPAWNING;
2701                                         else if(!button_pressed)
2702                                                 self.deadflag = DEAD_DEAD;
2703                                 }
2704                                 else if (self.deadflag == DEAD_DEAD)
2705                                 {
2706                                         if(button_pressed)
2707                                                 self.deadflag = DEAD_RESPAWNABLE;
2708                                 }
2709                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2710                                 {
2711                                         if(!button_pressed)
2712                                                 self.deadflag = DEAD_RESPAWNING;
2713                                 }
2714                                 else if (self.deadflag == DEAD_RESPAWNING)
2715                                 {
2716                                         if(time > self.respawn_time)
2717                                         {
2718                                                 self.respawn_time = time + 1; // only retry once a second
2719                                                 respawn();
2720                                         }
2721                                 }
2722                                 ShowRespawnCountdown();
2723                         }
2724                         return;
2725                 }
2726                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2727                 // so (self.deadflag == DEAD_NO) is always true in the code below
2728
2729                 if(g_touchexplode)
2730                 if(time > self.touchexplode_time)
2731                 if(self.classname == "player")
2732                 if(self.deadflag == DEAD_NO)
2733                 if not(IS_INDEPENDENT_PLAYER(self))
2734                 FOR_EACH_PLAYER(other) if(self != other)
2735                 {
2736                         if(time > other.touchexplode_time)
2737                         if(other.deadflag == DEAD_NO)
2738                         if not(IS_INDEPENDENT_PLAYER(other))
2739                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2740                         {
2741                                 PlayerTouchExplode(self, other);
2742                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2743                         }
2744                 }
2745
2746                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2747                 {
2748                         vector dist;
2749
2750                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2751                         dist = self.prevorigin - self.origin;
2752                         dist_z = 0;
2753                         self.lms_traveled_distance += fabs(vlen(dist));
2754
2755                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2756                         {
2757                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2758                                 self.lms_traveled_distance = 0;
2759                         }
2760
2761                         if(time > self.lms_nextcheck)
2762                         {
2763                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2764                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2765                                 {
2766                                         centerprint(self, autocvar_g_lms_campcheck_message);
2767                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2768                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2769                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2770                                 }
2771                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2772                                 self.lms_traveled_distance = 0;
2773                         }
2774                 }
2775
2776                 self.prevorigin = self.origin;
2777
2778                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2779                 {
2780                         if (!self.crouch)
2781                         {
2782                                 self.crouch = TRUE;
2783                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2784                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2785                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2786                         }
2787                 }
2788                 else
2789                 {
2790                         if (self.crouch)
2791                         {
2792                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2793                                 if (!trace_startsolid)
2794                                 {
2795                                         self.crouch = FALSE;
2796                                         self.view_ofs = PL_VIEW_OFS;
2797                                         setsize (self, PL_MIN, PL_MAX);
2798                                 }
2799                         }
2800                 }
2801
2802                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2803                 {
2804                         if(self.bloodloss_timer < time)
2805                         {
2806                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2807                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2808                         }
2809                 }
2810
2811                 FixPlayermodel();
2812
2813                 GrapplingHookFrame();
2814
2815                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2816                 //if(frametime)
2817                 {
2818                         self.items &~= self.items_added;
2819
2820                         W_WeaponFrame();
2821
2822                         self.items_added = 0;
2823                         if(self.items & IT_JETPACK)
2824                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2825                                         self.items_added |= IT_FUEL;
2826
2827                         self.items |= self.items_added;
2828                 }
2829
2830                 player_regen();
2831
2832                 // rot nex charge to the charge limit
2833                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2834                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2835
2836                 if(frametime)
2837                         player_anim();
2838
2839                 //if(g_ctf)
2840                 //      ctf_setstatus();
2841
2842                 if(g_nexball)
2843                         nexball_setstatus();
2844
2845                 // secret status
2846                 secrets_setstatus();
2847
2848                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2849
2850                 //self.angles_y=self.v_angle_y + 90;   // temp
2851         } else if(gameover) {
2852                 if (intermission_running)
2853                         IntermissionThink ();   // otherwise a button could be missed between
2854                 return;
2855         } else if(self.classname == "observer") {
2856                 ObserverThink();
2857         } else if(self.classname == "spectator") {
2858                 SpectatorThink();
2859         }
2860
2861         if(!zoomstate_set)
2862                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2863
2864         float oldspectatee_status;
2865         oldspectatee_status = self.spectatee_status;
2866         if(self.classname == "spectator")
2867                 self.spectatee_status = num_for_edict(self.enemy);
2868         else if(self.classname == "observer")
2869                 self.spectatee_status = num_for_edict(self);
2870         else
2871                 self.spectatee_status = 0;
2872         if(self.spectatee_status != oldspectatee_status)
2873         {
2874                 ClientData_Touch(self);
2875                 if(g_race || g_cts)
2876                         race_InitSpectator();
2877         }
2878
2879         if(self.teamkill_soundtime)
2880         if(time > self.teamkill_soundtime)
2881         {
2882                 self.teamkill_soundtime = 0;
2883
2884                 entity oldpusher, oldself;
2885
2886                 oldself = self; self = self.teamkill_soundsource;
2887                 oldpusher = self.pusher; self.pusher = oldself;
2888
2889                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2890
2891                 self.pusher = oldpusher;
2892                 self = oldself;
2893         }
2894
2895         if(self.taunt_soundtime)
2896         if(time > self.taunt_soundtime)
2897         {
2898                 self.taunt_soundtime = 0;
2899                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2900         }
2901
2902         target_voicescript_next(self);
2903
2904         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2905         if(!self.weapon)
2906                 self.clip_load = self.clip_size = 0;
2907 }
2908
2909 float isInvisibleString(string s)
2910 {
2911         float i, n, c;
2912         s = strdecolorize(s);
2913         for((i = 0), (n = strlen(s)); i < n; ++i)
2914         {
2915                 c = str2chr(s, i);
2916                 switch(c)
2917                 {
2918                         case 0:
2919                         case 32: // space
2920                                 break;
2921                         case 192: // charmap space
2922                                 if (!autocvar_utf8_enable)
2923                                         break;
2924                                 return FALSE;
2925                         case 160: // space in unicode fonts
2926                         case 0xE000 + 192: // utf8 charmap space
2927                                 if (autocvar_utf8_enable)
2928                                         break;
2929                         default:
2930                                 return FALSE;
2931                 }
2932         }
2933         return TRUE;
2934 }
2935
2936 /*
2937 =============
2938 PlayerPostThink
2939
2940 Called every frame for each client after the physics are run
2941 =============
2942 */
2943 .float idlekick_lasttimeleft;
2944 .entity showheadshotbbox;
2945 void showheadshotbbox_think()
2946 {
2947         if(self.owner.showheadshotbbox != self)
2948         {
2949                 remove(self);
2950                 return;
2951         }
2952         self.nextthink = time;
2953         setorigin(self, self.owner.origin);
2954         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2955 }
2956 void PlayerPostThink (void)
2957 {
2958         // Savage: Check for nameless players
2959         if (isInvisibleString(self.netname)) {
2960                 self.netname = "Player";
2961                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2962         }
2963
2964         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2965         {
2966                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2967                 {
2968                         if(self.idlekick_lasttimeleft)
2969                         {
2970                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2971                                 self.idlekick_lasttimeleft = 0;
2972                         }
2973                 }
2974                 else
2975                 {
2976                         float timeleft;
2977                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2978                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2979                         {
2980                                 if(!self.idlekick_lasttimeleft)
2981                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2982                         }
2983                         if(timeleft <= 0)
2984                         {
2985                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2986                                 AnnounceTo(self, "terminated");
2987                                 dropclient(self);
2988                                 return;
2989                         }
2990                         else if(timeleft <= 10)
2991                         {
2992                                 if(timeleft != self.idlekick_lasttimeleft)
2993                                         AnnounceTo(self, ftos(timeleft));
2994                                 self.idlekick_lasttimeleft = timeleft;
2995                         }
2996                 }
2997         }
2998
2999 #ifdef TETRIS
3000         if(self.impulse == 100)
3001                 ImpulseCommands();
3002         if (!TetrisPostFrame())
3003         {
3004 #endif
3005
3006         CheatFrame();
3007
3008         //CheckPlayerJump();
3009
3010         if(self.classname == "player") {
3011                 CheckRules_Player();
3012                 UpdateChatBubble();
3013                 if (self.impulse)
3014                         ImpulseCommands();
3015                 if (intermission_running)
3016                         return;         // intermission or finale
3017                 GetPressedKeys();
3018         } else if (self.classname == "observer") {
3019                 //do nothing
3020         } else if (self.classname == "spectator") {
3021                 //do nothing
3022         }
3023
3024 #ifdef TETRIS
3025         }
3026 #endif
3027
3028         /*
3029         float i;
3030         for(i = 0; i < 1000; ++i)
3031         {
3032                 vector end;
3033                 end = self.origin + '0 0 1024' + 512 * randomvec();
3034                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3035                 if(trace_fraction < 1)
3036                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3037                 {
3038                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3039                         break;
3040                 }
3041         }
3042         */
3043
3044         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3045
3046         if(self.waypointsprite_attachedforcarrier)
3047                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3048
3049         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3050         {
3051                 if(!self.showheadshotbbox)
3052                 {
3053                         self.showheadshotbbox = spawn();
3054                         self.showheadshotbbox.classname = "headshotbbox";
3055                         self.showheadshotbbox.owner = self;
3056                         self.showheadshotbbox.think = showheadshotbbox_think;
3057                         self.showheadshotbbox.nextthink = time;
3058                         self = self.showheadshotbbox;
3059                         self.think();
3060                         self = self.owner;
3061                 }
3062         }
3063         else
3064         {
3065                 if(self.showheadshotbbox)
3066                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3067                 remove(self.showheadshotbbox);
3068         }
3069
3070         playerdemo_write();
3071
3072         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3073         {
3074                 if(!self.stored_netname)
3075                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3076                 if(self.stored_netname != self.netname)
3077                 {
3078                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3079                         strunzone(self.stored_netname);
3080                         self.stored_netname = strzone(self.netname);
3081                 }
3082         }
3083
3084         /*
3085         if(g_race)
3086                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3087         */
3088
3089         CSQCMODEL_AUTOUPDATE();
3090 }