qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         return t;
  18 }
  19
  20 void W_SwitchWeapon_Force(entity e, float w)
  21 {
  22         e.cnt = e.switchweapon;
  23         e.switchweapon = w;
  24         e.selectweapon = w;
  25 }
  26
  27 .float antilag_debug;
  28
  29 // VorteX: static frame globals
  30 float WFRAME_DONTCHANGE = -1;
  31 float WFRAME_FIRE1 = 0;
  32 float WFRAME_FIRE2 = 1;
  33 float WFRAME_IDLE = 2;
  34 float WFRAME_RELOAD = 3;
  35 .float wframe;
  36
  37 void(float fr, float t, void() func) weapon_thinkf;
  38
  39 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  40 {
  41         vector ret;
  42         ret_x = screenright * v;
  43         ret_y = screenup * v;
  44         ret_z = screenforward * v;
  45         return ret;
  46 }
  47
  48 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  49 {
  50         float i, j, k;
  51         vector mi, ma, thisv, myv, ret;
  52
  53         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  54
  55         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  56
  57         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
  58         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  59         {
  60                 thisv = targ.origin;
  61                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  62                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  63                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  64                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  65                 if(i || j || k)
  66                 {
  67                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  68                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  69                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  70                 }
  71                 else
  72                 {
  73                         // first run
  74                         mi = ma = thisv;
  75                 }
  76         }
  77
  78         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  79         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  80         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  81         ret_z = thisv_z - myv_z;
  82         return ret;
  83 }
  84
  85 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  86 {
  87         vector hitplot;
  88         vector org;
  89         float lag;
  90
  91         if(player.hitplotfh >= 0)
  92         {
  93                 lag = ANTILAG_LATENCY(player);
  94                 if(lag < 0.001)
  95                         lag = 0;
  96                 if not(IS_REAL_CLIENT(player))
  97                         lag = 0; // only antilag for clients
  98
  99                 org = player.origin + player.view_ofs;
 100                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 101                 if(IS_CLIENT(trace_ent))
 102                 {
 103                         antilag_takeback(trace_ent, time - lag);
 104                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 105                         antilag_restore(trace_ent);
 106                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 107                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 108                 }
 109         }
 110 }
 111
 112 vector w_shotorg;
 113 vector w_shotdir;
 114 vector w_shotend;
 115
 116 .float prevstrengthsound;
 117 .float prevstrengthsoundattempt;
 118 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
 119 {
 120         if((player.items & IT_STRENGTH)
 121                 && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
 122                 || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
 123                 {
 124                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 125                         player.prevstrengthsound = time;
 126                 }
 127                 player.prevstrengthsoundattempt = time;
 128 }
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 134 {
 135         float nudge = 1; // added to traceline target and subtracted from result
 136         float oldsolid;
 137         vector vecs, dv;
 138         oldsolid = ent.dphitcontentsmask;
 139         if(ent.weapon == WEP_RIFLE)
 140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 141         else
 142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         if(antilag)
 144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 145                 // passing world, because we do NOT want it to touch dphitcontentsmask
 146         else
 147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149
 150         vector vf, vr, vu;
 151         vf = v_forward;
 152         vr = v_right;
 153         vu = v_up;
 154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 155         v_forward = vf;
 156         v_right = vr;
 157         v_up = vu;
 158
 159         // un-adjust trueaim if shotend is too close
 160         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 161                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 162
 163         // track max damage
 164         if(accuracy_canbegooddamage(ent))
 165                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 166
 167         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 168
 169         if(ent.weaponentity.movedir_x > 0)
 170                 vecs = ent.weaponentity.movedir;
 171         else
 172                 vecs = '0 0 0';
 173
 174         dv = v_right * -vecs_y + v_up * vecs_z;
 175         w_shotorg = ent.origin + ent.view_ofs + dv;
 176
 177         // now move the shotorg forward as much as requested if possible
 178         if(antilag)
 179         {
 180                 if(ent.antilag_debug)
 181                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 182                 else
 183                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 184         }
 185         else
 186                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 187         w_shotorg = trace_endpos - v_forward * nudge;
 188         // calculate the shotdir from the chosen shotorg
 189         w_shotdir = normalize(w_shotend - w_shotorg);
 190
 191         if (antilag)
 192         if (!ent.cvar_cl_noantilag)
 193         {
 194                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 195                 {
 196                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 197                         if (!trace_ent.takedamage)
 198                         {
 199                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 200                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 201                                 {
 202                                         entity e;
 203                                         e = trace_ent;
 204                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 205                                         if(trace_ent == e)
 206                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 207                                 }
 208                         }
 209                 }
 210                 else if(autocvar_g_antilag == 3) // client side hitscan
 211                 {
 212                         // this part MUST use prydon cursor
 213                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 214                         if (ent.cursor_trace_ent != ent)         // just to make sure
 215                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 216                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 217                         {
 218                                 // verify that the shot would miss without antilag
 219                                 // (avoids an issue where guns would always shoot at their origin)
 220                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 221                                 if (!trace_ent.takedamage)
 222                                 {
 223                                         // verify that the shot would hit if altered
 224                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 225                                         if (trace_ent == ent.cursor_trace_ent)
 226                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 227                                         else
 228                                                 print("antilag fail\n");
 229                                 }
 230                         }
 231                 }
 232         }
 233
 234         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 235
 236         ent.punchangle_x = recoil * -1;
 237
 238         if (snd != "")
 239         {
 240                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 241                 W_PlayStrengthSound(ent);
 242         }
 243
 244         // nudge w_shotend so a trace to w_shotend hits
 245         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 246 }
 247
 248 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 249 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 250 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 251 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 252 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 253
 254 float CL_Weaponentity_CustomizeEntityForClient()
 255 {
 256         self.viewmodelforclient = self.owner;
 257         if(IS_SPEC(other))
 258                 if(other.enemy == self.owner)
 259                         self.viewmodelforclient = other;
 260         return TRUE;
 261 }
 262
 263 /*
 264  * supported formats:
 265  *
 266  * 1. simple animated model, muzzle flash handling on h_ model:
 267  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 268  *      tags:
 269  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 270  *        shell = casings ejection point (must be on the right hand side of the gun)
 271  *        weapon = attachment for v_tuba.md3
 272  *    v_tuba.md3 - first and third person model
 273  *    g_tuba.md3 - pickup model
 274  *
 275  * 2. simple animated model, muzzle flash handling on v_ model:
 276  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 277  *      tags:
 278  *        weapon = attachment for v_tuba.md3
 279  *    v_tuba.md3 - first and third person model
 280  *      tags:
 281  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 282  *        shell = casings ejection point (must be on the right hand side of the gun)
 283  *    g_tuba.md3 - pickup model
 284  *
 285  * 3. fully animated model, muzzle flash handling on h_ model:
 286  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 287  *      tags:
 288  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 289  *        shell = casings ejection point (must be on the right hand side of the gun)
 290  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 291  *    v_tuba.md3 - third person model
 292  *    g_tuba.md3 - pickup model
 293  *
 294  * 4. fully animated model, muzzle flash handling on v_ model:
 295  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 296  *      tags:
 297  *        shot = muzzle end (shot origin)
 298  *        shell = casings ejection point (must be on the right hand side of the gun)
 299  *    v_tuba.md3 - third person model
 300  *      tags:
 301  *        shot = muzzle end (for muzzle flashes)
 302  *    g_tuba.md3 - pickup model
 303  */
 304
 305 // writes:
 306 //   self.origin, self.angles
 307 //   self.weaponentity
 308 //   self.movedir, self.view_ofs
 309 //   attachment stuff
 310 //   anim stuff
 311 // to free:
 312 //   call again with ""
 313 //   remove the ent
 314 void CL_WeaponEntity_SetModel(string name)
 315 {
 316         float v_shot_idx;
 317         if (name != "")
 318         {
 319                 // if there is a child entity, hide it until we're sure we use it
 320                 if (self.weaponentity)
 321                         self.weaponentity.model = "";
 322                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 323                 v_shot_idx = gettagindex(self, "shot"); // used later
 324                 if(!v_shot_idx)
 325                         v_shot_idx = gettagindex(self, "tag_shot");
 326
 327                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 328                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 329                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
 330                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
 331                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
 332                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
 333
 334                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 335                 // if we don't, this is a "real" animated model
 336                 if(gettagindex(self, "weapon"))
 337                 {
 338                         if (!self.weaponentity)
 339                                 self.weaponentity = spawn();
 340                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 341                         setattachment(self.weaponentity, self, "weapon");
 342                 }
 343                 else if(gettagindex(self, "tag_weapon"))
 344                 {
 345                         if (!self.weaponentity)
 346                                 self.weaponentity = spawn();
 347                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 348                         setattachment(self.weaponentity, self, "tag_weapon");
 349                 }
 350                 else
 351                 {
 352                         if(self.weaponentity)
 353                                 remove(self.weaponentity);
 354                         self.weaponentity = world;
 355                 }
 356
 357                 setorigin(self,'0 0 0');
 358                 self.angles = '0 0 0';
 359                 self.frame = 0;
 360                 self.viewmodelforclient = world;
 361
 362                 float idx;
 363
 364                 if(v_shot_idx) // v_ model attached to invisible h_ model
 365                 {
 366                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 367                 }
 368                 else
 369                 {
 370                         idx = gettagindex(self, "shot");
 371                         if(!idx)
 372                                 idx = gettagindex(self, "tag_shot");
 373                         if(idx)
 374                                 self.movedir = gettaginfo(self, idx);
 375                         else
 376                         {
 377                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 378                                 self.movedir = '0 0 0';
 379                         }
 380                 }
 381
 382                 if(self.weaponentity) // v_ model attached to invisible h_ model
 383                 {
 384                         idx = gettagindex(self.weaponentity, "shell");
 385                         if(!idx)
 386                                 idx = gettagindex(self.weaponentity, "tag_shell");
 387                         if(idx)
 388                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
 389                 }
 390                 else
 391                         idx = 0;
 392                 if(!idx)
 393                 {
 394                         idx = gettagindex(self, "shell");
 395                         if(!idx)
 396                                 idx = gettagindex(self, "tag_shell");
 397                         if(idx)
 398                                 self.spawnorigin = gettaginfo(self, idx);
 399                         else
 400                         {
 401                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 402                                 self.spawnorigin = self.movedir;
 403                         }
 404                 }
 405
 406                 if(v_shot_idx)
 407                 {
 408                         self.oldorigin = '0 0 0'; // use regular attachment
 409                 }
 410                 else
 411                 {
 412                         if(self.weaponentity)
 413                         {
 414                                 idx = gettagindex(self, "weapon");
 415                                 if(!idx)
 416                                         idx = gettagindex(self, "tag_weapon");
 417                         }
 418                         else
 419                         {
 420                                 idx = gettagindex(self, "handle");
 421                                 if(!idx)
 422                                         idx = gettagindex(self, "tag_handle");
 423                         }
 424                         if(idx)
 425                         {
 426                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 427                         }
 428                         else
 429                         {
 430                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 431                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 432                         }
 433                 }
 434
 435                 self.viewmodelforclient = self.owner;
 436         }
 437         else
 438         {
 439                 self.model = "";
 440                 if(self.weaponentity)
 441                         remove(self.weaponentity);
 442                 self.weaponentity = world;
 443                 self.movedir = '0 0 0';
 444                 self.spawnorigin = '0 0 0';
 445                 self.oldorigin = '0 0 0';
 446                 self.anim_fire1  = '0 1 0.01';
 447                 self.anim_fire2  = '0 1 0.01';
 448                 self.anim_idle   = '0 1 0.01';
 449                 self.anim_reload = '0 1 0.01';
 450         }
 451
 452         self.view_ofs = '0 0 0';
 453
 454         if(self.movedir_x >= 0)
 455         {
 456                 vector v0;
 457                 v0 = self.movedir;
 458                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 459                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 460         }
 461         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 462         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 463
 464         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 465
 466         // check if an instant weapon switch occurred
 467         setorigin(self, self.view_ofs);
 468         // reset animstate now
 469         self.wframe = WFRAME_IDLE;
 470         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 471 }
 472
 473 vector CL_Weapon_GetShotOrg(float wpn)
 474 {
 475         entity wi, oldself;
 476         vector ret;
 477         wi = get_weaponinfo(wpn);
 478         oldself = self;
 479         self = spawn();
 480         CL_WeaponEntity_SetModel(wi.mdl);
 481         ret = self.movedir;
 482         CL_WeaponEntity_SetModel("");
 483         remove(self);
 484         self = oldself;
 485         return ret;
 486 }
 487
 488 void CL_Weaponentity_Think()
 489 {
 490         float tb;
 491         self.nextthink = time;
 492         if (intermission_running)
 493                 self.frame = self.anim_idle_x;
 494         if (self.owner.weaponentity != self)
 495         {
 496                 if (self.weaponentity)
 497                         remove(self.weaponentity);
 498                 remove(self);
 499                 return;
 500         }
 501         if (self.owner.deadflag != DEAD_NO)
 502         {
 503                 self.model = "";
 504                 if (self.weaponentity)
 505                         self.weaponentity.model = "";
 506                 return;
 507         }
 508         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 509         {
 510                 self.weaponname = self.owner.weaponname;
 511                 self.dmg = self.owner.modelindex;
 512                 self.deadflag = self.owner.deadflag;
 513
 514                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 515         }
 516
 517         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 518         self.effects = self.owner.effects & EFMASK_CHEAP;
 519         self.effects &~= EF_LOWPRECISION;
 520         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 521         self.effects &~= EF_TELEPORT_BIT;
 522         self.effects &~= EF_RESTARTANIM_BIT;
 523         self.effects |= tb;
 524
 525         if(self.owner.alpha == default_player_alpha)
 526                 self.alpha = default_weapon_alpha;
 527         else if(self.owner.alpha != 0)
 528                 self.alpha = self.owner.alpha;
 529         else
 530                 self.alpha = 1;
 531
 532         self.glowmod = self.owner.weaponentity_glowmod;
 533         self.colormap = self.owner.colormap;
 534         if (self.weaponentity)
 535         {
 536                 self.weaponentity.effects = self.effects;
 537                 self.weaponentity.alpha = self.alpha;
 538                 self.weaponentity.colormap = self.colormap;
 539                 self.weaponentity.glowmod = self.glowmod;
 540         }
 541
 542         self.angles = '0 0 0';
 543
 544         float f = (self.owner.weapon_nextthink - time);
 545         if (self.state == WS_RAISE && !intermission_running)
 546         {
 547                 entity newwep = get_weaponinfo(self.owner.switchweapon);
 548                 f = f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)));
 549                 //print(sprintf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_raise", newwep.netname), cvar(sprintf("g_balance_%s_switchdelay_raise", newwep.netname)), (self.owner.weapon_nextthink - time)));
 550                 self.angles_x = -90 * f * f;
 551         }
 552         else if (self.state == WS_DROP && !intermission_running)
 553         {
 554                 entity oldwep = get_weaponinfo(self.owner.weapon);
 555                 f = 1 - f * g_weaponratefactor / max(f, cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)));
 556                 //print(sprintf("CL_Weaponentity_Think(): cvar: %s, value: %f, nextthink: %f\n", sprintf("g_balance_%s_switchdelay_drop", oldwep.netname), cvar(sprintf("g_balance_%s_switchdelay_drop", oldwep.netname)), (self.owner.weapon_nextthink - time)));
 557                 self.angles_x = -90 * f * f;
 558         }
 559         else if (self.state == WS_CLEAR)
 560         {
 561                 f = 1;
 562                 self.angles_x = -90 * f * f;
 563         }
 564 }
 565
 566 void CL_ExteriorWeaponentity_Think()
 567 {
 568         float tag_found;
 569         self.nextthink = time;
 570         if (self.owner.exteriorweaponentity != self)
 571         {
 572                 remove(self);
 573                 return;
 574         }
 575         if (self.owner.deadflag != DEAD_NO)
 576         {
 577                 self.model = "";
 578                 return;
 579         }
 580         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 581         {
 582                 self.weaponname = self.owner.weaponname;
 583                 self.dmg = self.owner.modelindex;
 584                 self.deadflag = self.owner.deadflag;
 585                 if (self.owner.weaponname != "")
 586                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 587                 else
 588                         self.model = "";
 589
 590                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 591                 {
 592                         self.tag_index = tag_found;
 593                         self.tag_entity = self.owner;
 594                 }
 595                 else
 596                         setattachment(self, self.owner, "bip01 r hand");
 597         }
 598         self.effects = self.owner.effects;
 599         self.effects |= EF_LOWPRECISION;
 600         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 601         if(self.owner.alpha == default_player_alpha)
 602                 self.alpha = default_weapon_alpha;
 603         else if(self.owner.alpha != 0)
 604                 self.alpha = self.owner.alpha;
 605         else
 606                 self.alpha = 1;
 607
 608         self.glowmod = self.owner.weaponentity_glowmod;
 609         self.colormap = self.owner.colormap;
 610
 611         CSQCMODEL_AUTOUPDATE();
 612 }
 613
 614 // spawning weaponentity for client
 615 void CL_SpawnWeaponentity()
 616 {
 617         self.weaponentity = spawn();
 618         self.weaponentity.classname = "weaponentity";
 619         self.weaponentity.solid = SOLID_NOT;
 620         self.weaponentity.owner = self;
 621         setmodel(self.weaponentity, ""); // precision set when changed
 622         setorigin(self.weaponentity, '0 0 0');
 623         self.weaponentity.angles = '0 0 0';
 624         self.weaponentity.viewmodelforclient = self;
 625         self.weaponentity.flags = 0;
 626         self.weaponentity.think = CL_Weaponentity_Think;
 627         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 628         self.weaponentity.nextthink = time;
 629
 630         self.exteriorweaponentity = spawn();
 631         self.exteriorweaponentity.classname = "exteriorweaponentity";
 632         self.exteriorweaponentity.solid = SOLID_NOT;
 633         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 634         self.exteriorweaponentity.owner = self;
 635         setorigin(self.exteriorweaponentity, '0 0 0');
 636         self.exteriorweaponentity.angles = '0 0 0';
 637         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 638         self.exteriorweaponentity.nextthink = time;
 639
 640         {
 641                 entity oldself = self;
 642                 self = self.exteriorweaponentity;
 643                 CSQCMODEL_AUTOINIT();
 644                 self = oldself;
 645         }
 646 }
 647
 648 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 649 {
 650         msg_entity = e;
 651         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 652         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 653         WriteByte(MSG_ONE, wpn);
 654         WriteString(MSG_ONE, wpnname);
 655         WriteByte(MSG_ONE, type);
 656 }
 657
 658 .float hasweapon_complain_spam;
 659
 660 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 661 {
 662         float f;
 663         entity oldself;
 664
 665         if(time < self.hasweapon_complain_spam)
 666                 complain = 0;
 667         if(complain)
 668                 self.hasweapon_complain_spam = time + 0.2;
 669
 670         if(wpn == WEP_HOOK && !g_grappling_hook && autocvar_g_nades && !WEPSET_CONTAINS_EW(cl, wpn) && !WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 671                 complain = 0;
 672
 673         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 674         {
 675                 if (complain)
 676                         sprint(self, "Invalid weapon\n");
 677                 return FALSE;
 678         }
 679         if (WEPSET_CONTAINS_EW(cl, wpn))
 680         {
 681                 if (andammo)
 682                 {
 683                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 684                         {
 685                                 f = 1;
 686                         }
 687                         else
 688                         {
 689                                 oldself = self;
 690                                 self = cl;
 691                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 692                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 693
 694                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 695                                 entity mine;
 696                                 if(wpn == WEP_MINE_LAYER)
 697                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 698                                         f = 1;
 699
 700                                 self = oldself;
 701                         }
 702                         if (!f)
 703                         {
 704                                 if (complain)
 705                                 if(IS_REAL_CLIENT(cl))
 706                                 {
 707                                         play2(cl, "weapons/unavailable.wav");
 708                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 709                                 }
 710                                 return FALSE;
 711                         }
 712                 }
 713                 return TRUE;
 714         }
 715         if (complain)
 716         {
 717                 // DRESK - 3/16/07
 718                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 719                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
 720                 {
 721                         Send_WeaponComplain(cl, wpn, W_Name(wpn), 1);
 722
 723                         if(autocvar_g_showweaponspawns)
 724                         {
 725                                 entity e;
 726                                 string s;
 727
 728                                 e = get_weaponinfo(wpn);
 729                                 s = e.model2;
 730
 731                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
 732                                 {
 733                                         if(e.classname == "droppedweapon")
 734                                                 continue;
 735                                         if not(e.flags & FL_ITEM)
 736                                                 continue;
 737                                         WaypointSprite_Spawn(
 738                                                 s,
 739                                                 1, 0,
 740                                                 world, e.origin,
 741                                                 self, 0,
 742                                                 world, enemy,
 743                                                 0,
 744                                                 RADARICON_NONE, '0 0 0'
 745                                         );
 746                                 }
 747                         }
 748                 }
 749                 else
 750                 {
 751                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 752                 }
 753
 754                 play2(cl, "weapons/unavailable.wav");
 755         }
 756         return FALSE;
 757 }
 758
 759 // Weapon subs
 760 void w_clear()
 761 {
 762         if (self.weapon != -1)
 763         {
 764                 self.weapon = 0;
 765                 self.switchingweapon = 0;
 766         }
 767         if (self.weaponentity)
 768         {
 769                 self.weaponentity.state = WS_CLEAR;
 770                 self.weaponentity.effects = 0;
 771         }
 772 }
 773
 774 void w_ready()
 775 {
 776         if (self.weaponentity)
 777                 self.weaponentity.state = WS_READY;
 778         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 779 }
 780
 781 // Setup weapon for client (after this raise frame will be launched)
 782 void weapon_setup(float windex)
 783 {
 784         entity e;
 785         e = get_weaponinfo(windex);
 786         self.items &~= IT_AMMO;
 787         self.items = self.items | (e.items & IT_AMMO);
 788
 789         // the two weapon entities will notice this has changed and update their models
 790         self.weapon = windex;
 791         self.switchingweapon = windex; // to make sure
 792         self.weaponname = e.mdl;
 793         self.bulletcounter = 0;
 794 }
 795
 796 // perform weapon to attack (weaponstate and attack_finished check is here)
 797 void W_SwitchToOtherWeapon(entity pl)
 798 {
 799         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 800         float w, ww;
 801         w = pl.weapon;
 802         if(WEPSET_CONTAINS_EW(pl, w))
 803         {
 804                 WEPSET_ANDNOT_EW(pl, w);
 805                 ww = w_getbestweapon(pl);
 806                 WEPSET_OR_EW(pl, w);
 807         }
 808         else
 809                 ww = w_getbestweapon(pl);
 810         if(ww)
 811                 W_SwitchWeapon_Force(pl, ww);
 812 }
 813
 814 .float prevdryfire;
 815 .float prevwarntime;
 816 float weapon_prepareattack_checkammo(float secondary)
 817 {
 818         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 819         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 820         {
 821                 // always keep the Mine Layer if we placed mines, so that we can detonate them
 822                 entity mine;
 823                 if(self.weapon == WEP_MINE_LAYER)
 824                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 825                         return FALSE;
 826
 827                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 828                 {
 829                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
 830                         self.prevdryfire = time;
 831                 }
 832
 833                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
 834                 {
 835                         if(time - self.prevwarntime > 1)
 836                         {
 837                                 Send_Notification(
 838                                         NOTIF_ONE,
 839                                         self,
 840                                         MSG_MULTI,
 841                                         ITEM_WEAPON_PRIMORSEC,
 842                                         self.weapon,
 843                                         secondary,
 844                                         (1 - secondary)
 845                                 );
 846                         }
 847                         self.prevwarntime = time;
 848                 }
 849                 else // this weapon is totally unable to fire, switch to another one
 850                 {
 851                         W_SwitchToOtherWeapon(self);
 852                 }
 853
 854                 return FALSE;
 855         }
 856         return TRUE;
 857 }
 858 .float race_penalty;
 859 float weapon_prepareattack_check(float secondary, float attacktime)
 860 {
 861         if(!weapon_prepareattack_checkammo(secondary))
 862                 return FALSE;
 863
 864         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 865         //if all players readied up and the countdown is running
 866         if(time < game_starttime || time < self.race_penalty) {
 867                 return FALSE;
 868         }
 869
 870         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
 871                 return FALSE;
 872
 873         // do not even think about shooting if switching
 874         if(self.switchweapon != self.weapon)
 875                 return FALSE;
 876
 877         if(attacktime >= 0)
 878         {
 879                 // don't fire if previous attack is not finished
 880                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 881                         return FALSE;
 882                 // don't fire while changing weapon
 883                 if (self.weaponentity.state != WS_READY)
 884                         return FALSE;
 885         }
 886
 887         return TRUE;
 888 }
 889 float weapon_prepareattack_do(float secondary, float attacktime)
 890 {
 891         self.weaponentity.state = WS_INUSE;
 892
 893         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 894
 895         // if the weapon hasn't been firing continuously, reset the timer
 896         if(attacktime >= 0)
 897         {
 898                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
 899                 {
 900                         ATTACK_FINISHED(self) = time;
 901                         //dprint("resetting attack finished to ", ftos(time), "\n");
 902                 }
 903                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
 904         }
 905         self.bulletcounter += 1;
 906         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 907         return TRUE;
 908 }
 909 float weapon_prepareattack(float secondary, float attacktime)
 910 {
 911         if(weapon_prepareattack_check(secondary, attacktime))
 912         {
 913                 weapon_prepareattack_do(secondary, attacktime);
 914                 return TRUE;
 915         }
 916         else
 917                 return FALSE;
 918 }
 919
 920 void weapon_thinkf(float fr, float t, void() func)
 921 {
 922         vector a;
 923         vector of, or, ou;
 924         float restartanim;
 925
 926         if(fr == WFRAME_DONTCHANGE)
 927         {
 928                 fr = self.weaponentity.wframe;
 929                 restartanim = FALSE;
 930         }
 931         else if (fr == WFRAME_IDLE)
 932                 restartanim = FALSE;
 933         else
 934                 restartanim = TRUE;
 935
 936         of = v_forward;
 937         or = v_right;
 938         ou = v_up;
 939
 940         if (self.weaponentity)
 941         {
 942                 self.weaponentity.wframe = fr;
 943                 a = '0 0 0';
 944                 if (fr == WFRAME_IDLE)
 945                         a = self.weaponentity.anim_idle;
 946                 else if (fr == WFRAME_FIRE1)
 947                         a = self.weaponentity.anim_fire1;
 948                 else if (fr == WFRAME_FIRE2)
 949                         a = self.weaponentity.anim_fire2;
 950                 else // if (fr == WFRAME_RELOAD)
 951                         a = self.weaponentity.anim_reload;
 952                 a_z *= g_weaponratefactor;
 953                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 954         }
 955
 956         v_forward = of;
 957         v_right = or;
 958         v_up = ou;
 959
 960         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 961         {
 962                 backtrace("Tried to override initial weapon think function - should this really happen?");
 963         }
 964
 965         t *= W_WeaponRateFactor();
 966
 967         // VorteX: haste can be added here
 968         if (self.weapon_think == w_ready)
 969         {
 970                 self.weapon_nextthink = time;
 971                 //dprint("started firing at ", ftos(time), "\n");
 972         }
 973         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
 974         {
 975                 self.weapon_nextthink = time;
 976                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
 977         }
 978         self.weapon_nextthink = self.weapon_nextthink + t;
 979         self.weapon_think = func;
 980         //dprint("next ", ftos(self.weapon_nextthink), "\n");
 981
 982         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 983         {
 984                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
 985                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
 986                 else
 987                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
 988         }
 989         else
 990         {
 991                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
 992                         self.anim_upper_action = 0;
 993         }
 994 }
 995
 996 void weapon_boblayer1(float spd, vector org)
 997 {
 998         // VorteX: haste can be added here
 999 }
1000
1001 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1002 {
1003         vector mdirection;
1004         float mspeed;
1005         vector outvelocity;
1006
1007         mvelocity = mvelocity * g_weaponspeedfactor;
1008
1009         mdirection = normalize(mvelocity);
1010         mspeed = vlen(mvelocity);
1011
1012         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1013
1014         return outvelocity;
1015 }
1016
1017 void W_AttachToShotorg(entity flash, vector offset)
1018 {
1019         entity xflash;
1020         flash.owner = self;
1021         flash.angles_z = random() * 360;
1022
1023         if(gettagindex(self.weaponentity, "shot"))
1024                 setattachment(flash, self.weaponentity, "shot");
1025         else
1026                 setattachment(flash, self.weaponentity, "tag_shot");
1027         setorigin(flash, offset);
1028
1029         xflash = spawn();
1030         copyentity(flash, xflash);
1031
1032         flash.viewmodelforclient = self;
1033
1034         if(self.weaponentity.oldorigin_x > 0)
1035         {
1036                 setattachment(xflash, self.exteriorweaponentity, "");
1037                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1038         }
1039         else
1040         {
1041                 if(gettagindex(self.exteriorweaponentity, "shot"))
1042                         setattachment(xflash, self.exteriorweaponentity, "shot");
1043                 else
1044                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1045                 setorigin(xflash, offset);
1046         }
1047 }
1048
1049 vector cliptoplane(vector v, vector p)
1050 {
1051         return v - (v * p) * p;
1052 }
1053
1054 vector solve_cubic_pq(float p, float q)
1055 {
1056         float D, u, v, a;
1057         D = q*q/4.0 + p*p*p/27.0;
1058         if(D < 0)
1059         {
1060                 // irreducibilis
1061                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1062                 u = sqrt(-4.0/3.0 * p);
1063                 // a in range 0..pi/3
1064                 // cos(a)
1065                 // cos(a + 2pi/3)
1066                 // cos(a + 4pi/3)
1067                 return
1068                         u *
1069                         (
1070                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1071                                 +
1072                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1073                                 +
1074                                 '0 0 1' * cos(a)
1075                         );
1076         }
1077         else if(D == 0)
1078         {
1079                 // simple
1080                 if(p == 0)
1081                         return '0 0 0';
1082                 u = 3*q/p;
1083                 v = -u/2;
1084                 if(u >= v)
1085                         return '1 1 0' * v + '0 0 1' * u;
1086                 else
1087                         return '0 1 1' * v + '1 0 0' * u;
1088         }
1089         else
1090         {
1091                 // cardano
1092                 u = cbrt(-q/2.0 + sqrt(D));
1093                 v = cbrt(-q/2.0 - sqrt(D));
1094                 return '1 1 1' * (u + v);
1095         }
1096 }
1097 vector solve_cubic_abcd(float a, float b, float c, float d)
1098 {
1099         // y = 3*a*x + b
1100         // x = (y - b) / 3a
1101         float p, q;
1102         vector v;
1103         p = (9*a*c - 3*b*b);
1104         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1105         v = solve_cubic_pq(p, q);
1106         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1107         if(a < 0)
1108                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1109         return v;
1110 }
1111
1112 vector findperpendicular(vector v)
1113 {
1114         vector p;
1115         p_x = v_z;
1116         p_y = -v_x;
1117         p_z = v_y;
1118         return normalize(cliptoplane(p, v));
1119 }
1120
1121 vector W_CalculateProjectileSpread(vector forward, float spread)
1122 {
1123         float sigma;
1124         vector v1 = '0 0 0', v2;
1125         float dx, dy, r;
1126         float sstyle;
1127         spread *= g_weaponspreadfactor;
1128         if(spread <= 0)
1129                 return forward;
1130         sstyle = autocvar_g_projectiles_spread_style;
1131
1132         if(sstyle == 0)
1133         {
1134                 // this is the baseline for the spread value!
1135                 // standard deviation: sqrt(2/5)
1136                 // density function: sqrt(1-r^2)
1137                 return forward + randomvec() * spread;
1138         }
1139         else if(sstyle == 1)
1140         {
1141                 // same thing, basically
1142                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1143         }
1144         else if(sstyle == 2)
1145         {
1146                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1147                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1148                 v1 = findperpendicular(forward);
1149                 v2 = cross(forward, v1);
1150                 // random point on unit circle
1151                 dx = random() * 2 * M_PI;
1152                 dy = sin(dx);
1153                 dx = cos(dx);
1154                 // radius in our dist function
1155                 r = random();
1156                 r = sqrt(r);
1157                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1158         }
1159         else if(sstyle == 3) // gauss 3d
1160         {
1161                 sigma = spread * 0.44721359549996; // match baseline stddev
1162                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1163                 v1 = forward;
1164                 v1_x += gsl_ran_gaussian(sigma);
1165                 v1_y += gsl_ran_gaussian(sigma);
1166                 v1_z += gsl_ran_gaussian(sigma);
1167                 return v1;
1168         }
1169         else if(sstyle == 4) // gauss 2d
1170         {
1171                 sigma = spread * 0.44721359549996; // match baseline stddev
1172                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1173                 v1_x = gsl_ran_gaussian(sigma);
1174                 v1_y = gsl_ran_gaussian(sigma);
1175                 v1_z = gsl_ran_gaussian(sigma);
1176                 return normalize(forward + cliptoplane(v1, forward));
1177         }
1178         else if(sstyle == 5) // 1-r
1179         {
1180                 sigma = spread * 1.154700538379252; // match baseline stddev
1181                 v1 = findperpendicular(forward);
1182                 v2 = cross(forward, v1);
1183                 // random point on unit circle
1184                 dx = random() * 2 * M_PI;
1185                 dy = sin(dx);
1186                 dx = cos(dx);
1187                 // radius in our dist function
1188                 r = random();
1189                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1190                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1191         }
1192         else if(sstyle == 6) // 1-r^2
1193         {
1194                 sigma = spread * 1.095445115010332; // match baseline stddev
1195                 v1 = findperpendicular(forward);
1196                 v2 = cross(forward, v1);
1197                 // random point on unit circle
1198                 dx = random() * 2 * M_PI;
1199                 dy = sin(dx);
1200                 dx = cos(dx);
1201                 // radius in our dist function
1202                 r = random();
1203                 r = sqrt(1 - r);
1204                 r = sqrt(1 - r);
1205                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1206         }
1207         else if(sstyle == 7) // (1-r) (2-r)
1208         {
1209                 sigma = spread * 1.224744871391589; // match baseline stddev
1210                 v1 = findperpendicular(forward);
1211                 v2 = cross(forward, v1);
1212                 // random point on unit circle
1213                 dx = random() * 2 * M_PI;
1214                 dy = sin(dx);
1215                 dx = cos(dx);
1216                 // radius in our dist function
1217                 r = random();
1218                 r = 1 - sqrt(r);
1219                 r = 1 - sqrt(r);
1220                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1221         }
1222         else
1223                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1224         return '0 0 0';
1225         /*
1226          * how to derive falloff functions:
1227          * rho(r) := (2-r) * (1-r);
1228          * a : 0;
1229          * b : 1;
1230          * rhor(r) := r * rho(r);
1231          * cr(t) := integrate(rhor(r), r, a, t);
1232          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1233          * variance : scr(b) / cr(b);
1234          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1235          * sqrt(0.4 / variance), numer;
1236          */
1237 }
1238
1239 #if 0
1240 float mspercallsum;
1241 float mspercallsstyle;
1242 float mspercallcount;
1243 #endif
1244 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1245 {
1246         if(missile.owner == world)
1247                 error("Unowned missile");
1248
1249         dir = dir + upDir * (pUpSpeed / pSpeed);
1250         dir_z += pZSpeed / pSpeed;
1251         pSpeed *= vlen(dir);
1252         dir = normalize(dir);
1253
1254 #if 0
1255         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1256         {
1257                 mspercallsum = mspercallcount = 0;
1258                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1259         }
1260         mspercallsum -= gettime(GETTIME_HIRES);
1261 #endif
1262         dir = W_CalculateProjectileSpread(dir, spread);
1263 #if 0
1264         mspercallsum += gettime(GETTIME_HIRES);
1265         mspercallcount += 1;
1266         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1267 #endif
1268
1269         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1270 }
1271
1272 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1273 {
1274         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1275 }
1276
1277 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1278 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1279
1280 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1281 {
1282         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1283                 return;
1284
1285         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1286         if(ammo_reload)
1287         {
1288                 self.clip_load -= ammo_use;
1289                 self.(weapon_load[self.weapon]) = self.clip_load;
1290         }
1291         else
1292                 self.(self.current_ammo) -= ammo_use;
1293 }
1294
1295 // weapon reloading code
1296
1297 .float reload_ammo_amount, reload_ammo_min, reload_time;
1298 .float reload_complain;
1299 .string reload_sound;
1300
1301 void W_ReloadedAndReady()
1302 {
1303         // finish the reloading process, and do the ammo transfer
1304
1305         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1306
1307         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1308         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1309                 self.clip_load = self.reload_ammo_amount;
1310         else
1311         {
1312                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1313                 {
1314                         self.clip_load += 1;
1315                         self.(self.current_ammo) -= 1;
1316                 }
1317         }
1318         self.(weapon_load[self.weapon]) = self.clip_load;
1319
1320         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1321         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1322         // so your weapon is disabled for a few seconds without reason
1323
1324         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1325
1326         w_ready();
1327 }
1328
1329 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1330 {
1331         // set global values to work with
1332
1333         self.reload_ammo_min = sent_ammo_min;
1334         self.reload_ammo_amount = sent_ammo_amount;
1335         self.reload_time = sent_time;
1336         self.reload_sound = sent_sound;
1337
1338         // check if we meet the necessary conditions to reload
1339
1340         entity e;
1341         e = get_weaponinfo(self.weapon);
1342
1343         // don't reload weapons that don't have the RELOADABLE flag
1344         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1345         {
1346                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1347                 return;
1348         }
1349
1350         // return if reloading is disabled for this weapon
1351         if(!self.reload_ammo_amount)
1352                 return;
1353
1354         // our weapon is fully loaded, no need to reload
1355         if (self.clip_load >= self.reload_ammo_amount)
1356                 return;
1357
1358         // no ammo, so nothing to load
1359         if(!self.(self.current_ammo) && self.reload_ammo_min)
1360         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1361         {
1362                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
1363                 {
1364                         play2(self, "weapons/unavailable.wav");
1365                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1366                         self.reload_complain = time + 1;
1367                 }
1368                 // switch away if the amount of ammo is not enough to keep using this weapon
1369                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1370                 {
1371                         self.clip_load = -1; // reload later
1372                         W_SwitchToOtherWeapon(self);
1373                 }
1374                 return;
1375         }
1376
1377         if (self.weaponentity)
1378         {
1379                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1380                         return;
1381
1382                 // allow switching away while reloading, but this will cause a new reload!
1383                 self.weaponentity.state = WS_READY;
1384         }
1385
1386         // now begin the reloading process
1387
1388         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1389
1390         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1391         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1392         // so your weapon is disabled for a few seconds without reason
1393
1394         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1395
1396         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1397
1398         if(self.clip_load < 0)
1399                 self.clip_load = 0;
1400         self.old_clip_load = self.clip_load;
1401         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1402 }