qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         for(int slot = 0; slot < MAX_AXH; ++slot)
 359         {
 360                 entity axh = this.(AuxiliaryXhair[slot]);
 361                 this.(AuxiliaryXhair[slot]) = NULL;
 362
 363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 364                         delete(axh);
 365         }
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         string s = Static_Team_ColorName_Lower(player.team);
 387                         if (s != "neutral")
 388                         {
 389                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 390                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 391                         }
 392                 }
 393
 394                 if(defaultmodel == "")
 395                 {
 396                         defaultmodel = autocvar_sv_defaultplayermodel;
 397                         defaultskin = autocvar_sv_defaultplayerskin;
 398                 }
 399
 400                 int n = tokenize_console(defaultmodel);
 401                 if(n > 0)
 402                 {
 403                         defaultmodel = argv(floor(n * player.model_randomizer));
 404                         // However, do NOT randomize if the player-selected model is in the list.
 405                         for (int i = 0; i < n; ++i)
 406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 407                                         defaultmodel = argv(i);
 408                 }
 409
 410                 int i = strstrofs(defaultmodel, ":", 0);
 411                 if(i >= 0)
 412                 {
 413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 414                         defaultmodel = substring(defaultmodel, 0, i);
 415                 }
 416         }
 417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 418         {
 419                 if(teamplay)
 420                 {
 421                         string s = Static_Team_ColorName_Lower(player.team);
 422                         if (s != "neutral")
 423                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 424                 }
 425
 426                 if(!defaultskin)
 427                         defaultskin = autocvar_sv_defaultplayerskin;
 428         }
 429
 430         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 431         defaultmodel = M_ARGV(0, string);
 432         defaultskin = M_ARGV(1, int);
 433
 434         bool chmdl = false;
 435         int oldskin;
 436         if(defaultmodel != "")
 437         {
 438                 if (defaultmodel != player.model)
 439                 {
 440                         vector m1 = player.mins;
 441                         vector m2 = player.maxs;
 442                         setplayermodel (player, defaultmodel);
 443                         setsize (player, m1, m2);
 444                         chmdl = true;
 445                 }
 446
 447                 oldskin = player.skin;
 448                 player.skin = defaultskin;
 449         } else {
 450                 if (player.playermodel != player.model || player.playermodel == "")
 451                 {
 452                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 453                         vector m1 = player.mins;
 454                         vector m2 = player.maxs;
 455                         setplayermodel (player, player.playermodel);
 456                         setsize (player, m1, m2);
 457                         chmdl = true;
 458                 }
 459
 460                 if(!autocvar_sv_defaultcharacterskin)
 461                 {
 462                         oldskin = player.skin;
 463                         player.skin = stof(player.playerskin);
 464                 }
 465                 else
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = defaultskin;
 469                 }
 470         }
 471
 472         if(chmdl || oldskin != player.skin) // model or skin has changed
 473         {
 474                 player.species = player_getspecies(player); // update species
 475                 if(!autocvar_g_debug_globalsounds)
 476                         UpdatePlayerSounds(player); // update skin sounds
 477         }
 478
 479         if(!teamplay)
 480                 if(strlen(autocvar_sv_defaultplayercolors))
 481                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 482                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 483 }
 484
 485
 486 /** Called when a client spawns in the server */
 487 void PutClientInServer(entity this)
 488 {
 489         if (IS_BOT_CLIENT(this)) {
 490                 TRANSMUTE(Player, this);
 491         } else if (IS_REAL_CLIENT(this)) {
 492                 msg_entity = this;
 493                 WriteByte(MSG_ONE, SVC_SETVIEW);
 494                 WriteEntity(MSG_ONE, this);
 495         }
 496         if (game_stopped)
 497                 TRANSMUTE(Observer, this);
 498
 499         SetSpectatee(this, NULL);
 500
 501         // reset player keys
 502         this.itemkeys = 0;
 503
 504         MUTATOR_CALLHOOK(PutClientInServer, this);
 505
 506         if (IS_OBSERVER(this)) {
 507                 PutObserverInServer(this);
 508         } else if (IS_PLAYER(this)) {
 509                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 510
 511                 PlayerState_attach(this);
 512                 accuracy_resend(this);
 513
 514                 if (this.team < 0)
 515                         JoinBestTeam(this, false, true);
 516
 517                 entity spot = SelectSpawnPoint(this, false);
 518                 if (!spot) {
 519                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 520                         return; // spawn failed
 521                 }
 522
 523                 TRANSMUTE(Player, this);
 524
 525                 this.wasplayer = true;
 526                 this.iscreature = true;
 527                 this.teleportable = TELEPORT_NORMAL;
 528                 if(!this.damagedbycontents)
 529                         IL_PUSH(g_damagedbycontents, this);
 530                 this.damagedbycontents = true;
 531                 set_movetype(this, MOVETYPE_WALK);
 532                 this.solid = SOLID_SLIDEBOX;
 533                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 534                 if (autocvar_g_playerclip_collisions)
 535                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 536                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 537                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 538                 this.frags = FRAGS_PLAYER;
 539                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 540                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 541                 if (autocvar__notarget)
 542                         this.flags |= FL_NOTARGET;
 543                 this.takedamage = DAMAGE_AIM;
 544                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 545                 this.dmg = 2; // WTF
 546
 547                 if (warmup_stage) {
 548                         this.ammo_shells = warmup_start_ammo_shells;
 549                         this.ammo_nails = warmup_start_ammo_nails;
 550                         this.ammo_rockets = warmup_start_ammo_rockets;
 551                         this.ammo_cells = warmup_start_ammo_cells;
 552                         this.ammo_plasma = warmup_start_ammo_plasma;
 553                         this.ammo_fuel = warmup_start_ammo_fuel;
 554                         this.health = warmup_start_health;
 555                         this.armorvalue = warmup_start_armorvalue;
 556                         this.weapons = WARMUP_START_WEAPONS;
 557                 } else {
 558                         this.ammo_shells = start_ammo_shells;
 559                         this.ammo_nails = start_ammo_nails;
 560                         this.ammo_rockets = start_ammo_rockets;
 561                         this.ammo_cells = start_ammo_cells;
 562                         this.ammo_plasma = start_ammo_plasma;
 563                         this.ammo_fuel = start_ammo_fuel;
 564                         this.health = start_health;
 565                         this.armorvalue = start_armorvalue;
 566                         this.weapons = start_weapons;
 567                 }
 568                 SetSpectatee_status(this, 0);
 569
 570                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 571
 572                 this.items = start_items;
 573
 574                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 575                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 576                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 577                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 578                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 579                 // extend the pause of rotting if client was reset at the beginning of the countdown
 580                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 581                         float f = game_starttime - time;
 582                         this.spawnshieldtime += f;
 583                         this.pauserotarmor_finished += f;
 584                         this.pauserothealth_finished += f;
 585                         this.pauseregen_finished += f;
 586                 }
 587                 this.damageforcescale = 2;
 588                 this.death_time = 0;
 589                 this.respawn_flags = 0;
 590                 this.respawn_time = 0;
 591                 this.stat_respawn_time = 0;
 592                 this.scale = autocvar_sv_player_scale;
 593                 this.fade_time = 0;
 594                 this.pain_frame = 0;
 595                 this.pain_finished = 0;
 596                 this.pushltime = 0;
 597                 setthink(this, func_null); // players have no think function
 598                 this.nextthink = 0;
 599                 this.dmg_team = 0;
 600                 this.ballistics_density = autocvar_g_ballistics_density_player;
 601
 602                 this.deadflag = DEAD_NO;
 603
 604                 this.angles = spot.angles;
 605                 this.angles_z = 0; // never spawn tilted even if the spot says to
 606                 if (IS_BOT_CLIENT(this))
 607                         this.v_angle = this.angles;
 608                 this.fixangle = true; // turn this way immediately
 609                 this.oldvelocity = this.velocity = '0 0 0';
 610                 this.avelocity = '0 0 0';
 611                 this.punchangle = '0 0 0';
 612                 this.punchvector = '0 0 0';
 613
 614                 this.strength_finished = 0;
 615                 this.invincible_finished = 0;
 616                 this.fire_endtime = -1;
 617                 this.revive_progress = 0;
 618                 this.revival_time = 0;
 619                 this.air_finished = time + 12;
 620
 621                 entity spawnevent = new_pure(spawnevent);
 622                 spawnevent.owner = this;
 623                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 624
 625                 // Cut off any still running player sounds.
 626                 stopsound(this, CH_PLAYER_SINGLE);
 627
 628                 this.model = "";
 629                 FixPlayermodel(this);
 630                 this.drawonlytoclient = NULL;
 631
 632                 this.viewloc = NULL;
 633
 634                 this.crouch = false;
 635                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 636                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 637                 this.spawnorigin = spot.origin;
 638                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 639                 // don't reset back to last position, even if new position is stuck in solid
 640                 this.oldorigin = this.origin;
 641                 this.prevorigin = this.origin;
 642                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 643                 if(this.conveyor)
 644                         IL_REMOVE(g_conveyed, this);
 645                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 646                 this.hud = HUD_NORMAL;
 647
 648                 this.event_damage = PlayerDamage;
 649
 650                 if(!this.bot_attack)
 651                         IL_PUSH(g_bot_targets, this);
 652                 this.bot_attack = true;
 653                 this.monster_attack = true;
 654                 navigation_dynamicgoal_init(this, false);
 655
 656                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 657
 658                 if (this.killcount == FRAGS_SPECTATOR) {
 659                         PlayerScore_Clear(this);
 660                         this.killcount = 0;
 661                 }
 662
 663                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 664                 {
 665                         .entity weaponentity = weaponentities[slot];
 666                         entity oldwep = this.(weaponentity);
 667                         CL_SpawnWeaponentity(this, weaponentity);
 668                         if(oldwep && oldwep.owner == this)
 669                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 670                 }
 671                 this.alpha = default_player_alpha;
 672                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 673                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 674
 675                 this.speedrunning = false;
 676
 677                 target_voicescript_clear(this);
 678
 679                 // reset fields the weapons may use
 680                 FOREACH(Weapons, true, LAMBDA(
 681                         it.wr_resetplayer(it, this);
 682                         // reload all reloadable weapons
 683                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 684                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 685                                 {
 686                                         .entity weaponentity = weaponentities[slot];
 687                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 688                                 }
 689                         }
 690                 ));
 691
 692                 {
 693                         string s = spot.target;
 694                         spot.target = string_null;
 695                         SUB_UseTargets(spot, this, NULL);
 696                         spot.target = s;
 697                 }
 698
 699                 Unfreeze(this);
 700
 701                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 702
 703                 if (autocvar_spawn_debug)
 704                 {
 705                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 706                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 707                 }
 708
 709                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 710                 {
 711                         .entity weaponentity = weaponentities[slot];
 712                         if(slot == 0)
 713                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 714                         else
 715                                 this.(weaponentity).m_switchweapon = WEP_Null;
 716                         this.(weaponentity).m_weapon = WEP_Null;
 717                         this.(weaponentity).weaponname = "";
 718                         this.(weaponentity).m_switchingweapon = WEP_Null;
 719                         this.(weaponentity).cnt = -1;
 720                 }
 721
 722                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 723
 724                 if (!warmup_stage && !this.alivetime)
 725                         this.alivetime = time;
 726
 727                 antilag_clear(this, CS(this));
 728         }
 729 }
 730
 731 void ClientInit_misc(entity this);
 732
 733 // TODO do we need all these fields, or should we stop autodetecting runtime
 734 // changes and just have a console command to update this?
 735 bool ClientInit_SendEntity(entity this, entity to, int sf)
 736 {
 737         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 738         return = true;
 739         msg_entity = to;
 740         // MSG_INIT replacement
 741         // TODO: make easier to use
 742         Registry_send_all();
 743         W_PROP_reload(MSG_ONE, to);
 744         ClientInit_misc(this);
 745         MUTATOR_CALLHOOK(Ent_Init);
 746 }
 747 void ClientInit_misc(entity this)
 748 {
 749         int channel = MSG_ONE;
 750         WriteHeader(channel, ENT_CLIENT_INIT);
 751         WriteByte(channel, g_nexball_meter_period * 32);
 752         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 753         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 754         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 755         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 756         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 757         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 758         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 759         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 760
 761         if(sv_foginterval && world.fog != "")
 762                 WriteString(channel, world.fog);
 763         else
 764                 WriteString(channel, "");
 765         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 766         WriteByte(channel, serverflags);
 767         WriteCoord(channel, autocvar_g_trueaim_minrange);
 768 }
 769
 770 void ClientInit_CheckUpdate(entity this)
 771 {
 772         this.nextthink = time;
 773         if(this.count != autocvar_g_balance_armor_blockpercent)
 774         {
 775                 this.count = autocvar_g_balance_armor_blockpercent;
 776                 this.SendFlags |= 1;
 777         }
 778 }
 779
 780 void ClientInit_Spawn()
 781 {
 782         entity e = new_pure(clientinit);
 783         setthink(e, ClientInit_CheckUpdate);
 784         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 785
 786         ClientInit_CheckUpdate(e);
 787 }
 788
 789 /*
 790 =============
 791 SetNewParms
 792 =============
 793 */
 794 void SetNewParms ()
 795 {
 796         // initialize parms for a new player
 797         parm1 = -(86400 * 366);
 798
 799         MUTATOR_CALLHOOK(SetNewParms);
 800 }
 801
 802 /*
 803 =============
 804 SetChangeParms
 805 =============
 806 */
 807 void SetChangeParms (entity this)
 808 {
 809         // save parms for level change
 810         parm1 = this.parm_idlesince - time;
 811
 812         MUTATOR_CALLHOOK(SetChangeParms);
 813 }
 814
 815 /*
 816 =============
 817 DecodeLevelParms
 818 =============
 819 */
 820 void DecodeLevelParms(entity this)
 821 {
 822         // load parms
 823         this.parm_idlesince = parm1;
 824         if (this.parm_idlesince == -(86400 * 366))
 825                 this.parm_idlesince = time;
 826
 827         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 828         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 829
 830         MUTATOR_CALLHOOK(DecodeLevelParms);
 831 }
 832
 833 /*
 834 =============
 835 ClientKill
 836
 837 Called when a client types 'kill' in the console
 838 =============
 839 */
 840
 841 .float clientkill_nexttime;
 842 void ClientKill_Now_TeamChange(entity this)
 843 {
 844         if(this.killindicator_teamchange == -1)
 845         {
 846                 JoinBestTeam( this, false, true );
 847         }
 848         else if(this.killindicator_teamchange == -2)
 849         {
 850                 if(blockSpectators)
 851                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 852                 PutObserverInServer(this);
 853         }
 854         else
 855                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 856         this.killindicator_teamchange = 0;
 857 }
 858
 859 void ClientKill_Now(entity this)
 860 {
 861         if(this.vehicle)
 862         {
 863             vehicles_exit(this.vehicle, VHEF_RELEASE);
 864             if(!this.killindicator_teamchange)
 865             {
 866             this.vehicle_health = -1;
 867             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 868             }
 869         }
 870
 871         if(this.killindicator && !wasfreed(this.killindicator))
 872                 delete(this.killindicator);
 873
 874         this.killindicator = NULL;
 875
 876         if(this.killindicator_teamchange)
 877                 ClientKill_Now_TeamChange(this);
 878
 879         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 880                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 881
 882         // now I am sure the player IS dead
 883 }
 884 void KillIndicator_Think(entity this)
 885 {
 886         if (game_stopped)
 887         {
 888                 this.owner.killindicator = NULL;
 889                 delete(this);
 890                 return;
 891         }
 892
 893         if (this.owner.alpha < 0 && !this.owner.vehicle)
 894         {
 895                 this.owner.killindicator = NULL;
 896                 delete(this);
 897                 return;
 898         }
 899
 900         if(this.cnt <= 0)
 901         {
 902                 ClientKill_Now(this.owner);
 903                 return;
 904         }
 905     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 906     {
 907         this.nextthink = time + 1;
 908         this.cnt -= 1;
 909     }
 910         else
 911         {
 912                 if(this.cnt <= 10)
 913                         setmodel(this, MDL_NUM(this.cnt));
 914                 if(IS_REAL_CLIENT(this.owner))
 915                 {
 916                         if(this.cnt <= 10)
 917                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 918                 }
 919                 this.nextthink = time + 1;
 920                 this.cnt -= 1;
 921         }
 922 }
 923
 924 float clientkilltime;
 925 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 926 {
 927         float killtime;
 928         float starttime;
 929
 930         if (game_stopped)
 931                 return;
 932
 933         killtime = autocvar_g_balance_kill_delay;
 934
 935         if(g_race_qualifying || g_cts)
 936                 killtime = 0;
 937
 938     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 939         return;
 940
 941         this.killindicator_teamchange = targetteam;
 942
 943     if(!this.killindicator)
 944         {
 945                 if(!IS_DEAD(this))
 946                 {
 947                         killtime = max(killtime, this.clientkill_nexttime - time);
 948                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 949                 }
 950
 951                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 952                 {
 953                         ClientKill_Now(this);
 954                 }
 955                 else
 956                 {
 957                         starttime = max(time, clientkilltime);
 958
 959                         this.killindicator = spawn();
 960                         this.killindicator.owner = this;
 961                         this.killindicator.scale = 0.5;
 962                         setattachment(this.killindicator, this, "");
 963                         setorigin(this.killindicator, '0 0 52');
 964                         setthink(this.killindicator, KillIndicator_Think);
 965                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 966                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 967                         this.killindicator.cnt = ceil(killtime);
 968                         this.killindicator.count = bound(0, ceil(killtime), 10);
 969                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 970
 971                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 972                         {
 973                                 it.killindicator = spawn();
 974                                 it.killindicator.owner = it;
 975                                 it.killindicator.scale = 0.5;
 976                                 setattachment(it.killindicator, it, "");
 977                                 setorigin(it.killindicator, '0 0 52');
 978                                 setthink(it.killindicator, KillIndicator_Think);
 979                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 980                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 981                                 it.killindicator.cnt = ceil(killtime);
 982                         });
 983                         this.lip = 0;
 984                 }
 985         }
 986         if(this.killindicator)
 987         {
 988                 if(targetteam == 0) // just die
 989                 {
 990                         this.killindicator.colormod = '0 0 0';
 991                         if(IS_REAL_CLIENT(this))
 992                         if(this.killindicator.cnt > 0)
 993                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 994                 }
 995                 else if(targetteam == -1) // auto
 996                 {
 997                         this.killindicator.colormod = '0 1 0';
 998                         if(IS_REAL_CLIENT(this))
 999                         if(this.killindicator.cnt > 0)
1000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1001                 }
1002                 else if(targetteam == -2) // spectate
1003                 {
1004                         this.killindicator.colormod = '0.5 0.5 0.5';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1008                 }
1009                 else
1010                 {
1011                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1015                 }
1016         }
1017
1018 }
1019
1020 void ClientKill (entity this)
1021 {
1022         if(game_stopped) return;
1023         if(this.player_blocked) return;
1024         if(STAT(FROZEN, this)) return;
1025
1026         ClientKill_TeamChange(this, 0);
1027 }
1028
1029 void FixClientCvars(entity e)
1030 {
1031         // send prediction settings to the client
1032         stuffcmd(e, "\nin_bindmap 0 0\n");
1033         if(autocvar_g_antilag == 3) // client side hitscan
1034                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1035         if(autocvar_sv_gentle)
1036                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1037
1038         MUTATOR_CALLHOOK(FixClientCvars, e);
1039 }
1040
1041 float PlayerInIDList(entity p, string idlist)
1042 {
1043         float n, i;
1044         string s;
1045
1046         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1047         if (!p.crypto_idfp)
1048                 return 0;
1049
1050         // this function allows abbreviated player IDs too!
1051         n = tokenize_console(idlist);
1052         for(i = 0; i < n; ++i)
1053         {
1054                 s = argv(i);
1055                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1056                         return 1;
1057         }
1058
1059         return 0;
1060 }
1061
1062 #ifdef DP_EXT_PRECONNECT
1063 /*
1064 =============
1065 ClientPreConnect
1066
1067 Called once (not at each match start) when a client begins a connection to the server
1068 =============
1069 */
1070 void ClientPreConnect(entity this)
1071 {
1072         if(autocvar_sv_eventlog)
1073         {
1074                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1075                         this.playerid,
1076                         etof(this),
1077                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1078                 ));
1079         }
1080 }
1081 #endif
1082
1083 /**
1084 =============
1085 ClientConnect
1086
1087 Called when a client connects to the server
1088 =============
1089 */
1090 void ClientConnect(entity this)
1091 {
1092         if (Ban_MaybeEnforceBanOnce(this)) return;
1093         assert(!IS_CLIENT(this), return);
1094         this.flags |= FL_CLIENT;
1095         assert(player_count >= 0, player_count = 0);
1096
1097 #ifdef WATERMARK
1098         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1099 #endif
1100         this.version_nagtime = time + 10 + random() * 10;
1101         TRANSMUTE(Client, this);
1102
1103         // identify the right forced team
1104         if (autocvar_g_campaign)
1105         {
1106                 if (IS_REAL_CLIENT(this)) // only players, not bots
1107                 {
1108                         switch (autocvar_g_campaign_forceteam)
1109                         {
1110                                 case 1: this.team_forced = NUM_TEAM_1; break;
1111                                 case 2: this.team_forced = NUM_TEAM_2; break;
1112                                 case 3: this.team_forced = NUM_TEAM_3; break;
1113                                 case 4: this.team_forced = NUM_TEAM_4; break;
1114                                 default: this.team_forced = 0;
1115                         }
1116                 }
1117         }
1118         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1119         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1120         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1121         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1122         else switch (autocvar_g_forced_team_otherwise)
1123         {
1124                 default: this.team_forced = 0; break;
1125                 case "red": this.team_forced = NUM_TEAM_1; break;
1126                 case "blue": this.team_forced = NUM_TEAM_2; break;
1127                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1128                 case "pink": this.team_forced = NUM_TEAM_4; break;
1129                 case "spectate":
1130                 case "spectator":
1131                         this.team_forced = -1;
1132                         break;
1133         }
1134         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1135
1136     {
1137         int id = this.playerid;
1138         this.playerid = 0; // silent
1139             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1140             this.playerid = id;
1141     }
1142
1143         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1144                 TRANSMUTE(Observer, this);
1145         } else {
1146                 if (!teamplay || autocvar_g_balance_teams) {
1147                         TRANSMUTE(Player, this);
1148                         campaign_bots_may_start = true;
1149                 } else {
1150                         TRANSMUTE(Observer, this); // do it anyway
1151                 }
1152         }
1153
1154         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1155
1156         // always track bots, don't ask for cl_allow_uidtracking
1157     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1158
1159         if (autocvar_sv_eventlog)
1160                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1161
1162         LogTeamchange(this.playerid, this.team, 1);
1163
1164         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1165
1166         this.netname_previous = strzone(this.netname);
1167
1168         if(teamplay && IS_PLAYER(this))
1169                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1170         else
1171                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1172
1173         stuffcmd(this, clientstuff, "\n");
1174         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1175
1176         FixClientCvars(this);
1177
1178         // get version info from player
1179         stuffcmd(this, "cmd clientversion $gameversion\n");
1180
1181         // notify about available teams
1182         if (teamplay)
1183         {
1184                 CheckAllowedTeams(this);
1185                 int t = 0;
1186                 if (c1 >= 0) t |= BIT(0);
1187                 if (c2 >= 0) t |= BIT(1);
1188                 if (c3 >= 0) t |= BIT(2);
1189                 if (c4 >= 0) t |= BIT(3);
1190                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1191         }
1192         else
1193         {
1194                 stuffcmd(this, "set _teams_available 0\n");
1195         }
1196
1197         bot_relinkplayerlist();
1198
1199         this.spectatortime = time;
1200         if (blockSpectators)
1201         {
1202                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1203         }
1204
1205         this.jointime = time;
1206         this.allowed_timeouts = autocvar_sv_timeout_number;
1207
1208         if (IS_REAL_CLIENT(this))
1209         {
1210                 if (g_weaponarena_weapons == WEPSET(TUBA))
1211                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1212         }
1213
1214         if (!sv_foginterval && world.fog != "")
1215                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1216
1217         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1218                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1219                         send_CSQC_teamnagger();
1220
1221         CSQCMODEL_AUTOINIT(this);
1222
1223         this.model_randomizer = random();
1224
1225         if (IS_REAL_CLIENT(this))
1226                 sv_notice_join(this);
1227
1228         // update physics stats (players can spawn before physics runs)
1229         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1230
1231         IL_EACH(g_initforplayer, it.init_for_player, {
1232                 it.init_for_player(it, this);
1233         });
1234
1235         MUTATOR_CALLHOOK(ClientConnect, this);
1236
1237         if (IS_REAL_CLIENT(this))
1238         {
1239                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1240                 {
1241                         this.motd_actived_time = -1;
1242                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1243                 }
1244         }
1245 }
1246 /*
1247 =============
1248 ClientDisconnect
1249
1250 Called when a client disconnects from the server
1251 =============
1252 */
1253 .entity chatbubbleentity;
1254 void ReadyCount();
1255 void ClientDisconnect(entity this)
1256 {
1257         assert(IS_CLIENT(this), return);
1258
1259         PlayerStats_GameReport_FinalizePlayer(this);
1260         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1261         if (this.active_minigame) part_minigame(this);
1262         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1263
1264         if (autocvar_sv_eventlog)
1265                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1266
1267         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1268
1269         if(IS_SPEC(this))
1270                 SetSpectatee(this, NULL);
1271
1272     MUTATOR_CALLHOOK(ClientDisconnect, this);
1273
1274         ClientState_detach(this);
1275
1276         Portal_ClearAll(this);
1277
1278         Unfreeze(this);
1279
1280         RemoveGrapplingHooks(this);
1281
1282         // Here, everything has been done that requires this player to be a client.
1283
1284         this.flags &= ~FL_CLIENT;
1285
1286         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1287         if (this.killindicator) delete(this.killindicator);
1288
1289         WaypointSprite_PlayerGone(this);
1290
1291         bot_relinkplayerlist();
1292
1293         if (this.netname_previous) strunzone(this.netname_previous);
1294         if (this.clientstatus) strunzone(this.clientstatus);
1295         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1296         if (this.personal) delete(this.personal);
1297
1298         this.playerid = 0;
1299         ReadyCount();
1300         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1301
1302         ONREMOVE(this);
1303 }
1304
1305 void ChatBubbleThink(entity this)
1306 {
1307         this.nextthink = time;
1308         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1309         {
1310                 if(this.owner) // but why can that ever be NULL?
1311                         this.owner.chatbubbleentity = NULL;
1312                 delete(this);
1313                 return;
1314         }
1315
1316         this.mdl = "";
1317
1318         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1319         {
1320                 if ( this.owner.active_minigame )
1321                         this.mdl = "models/sprites/minigame_busy.iqm";
1322                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1323                         this.mdl = "models/misc/chatbubble.spr";
1324         }
1325
1326         if ( this.model != this.mdl )
1327                 _setmodel(this, this.mdl);
1328
1329 }
1330
1331 void UpdateChatBubble(entity this)
1332 {
1333         if (this.alpha < 0)
1334                 return;
1335         // spawn a chatbubble entity if needed
1336         if (!this.chatbubbleentity)
1337         {
1338                 this.chatbubbleentity = new(chatbubbleentity);
1339                 this.chatbubbleentity.owner = this;
1340                 this.chatbubbleentity.exteriormodeltoclient = this;
1341                 setthink(this.chatbubbleentity, ChatBubbleThink);
1342                 this.chatbubbleentity.nextthink = time;
1343                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1344                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1345                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1346                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1347                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1348                 //this.chatbubbleentity.model = "";
1349                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1350         }
1351 }
1352
1353
1354 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1355 // added to the model skins
1356 /*void UpdateColorModHack()
1357 {
1358         float c;
1359         c = this.clientcolors & 15;
1360         // LordHavoc: only bothering to support white, green, red, yellow, blue
1361              if (!teamplay) this.colormod = '0 0 0';
1362         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1363         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1364         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1365         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1366         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1367         else this.colormod = '1 1 1';
1368 }*/
1369
1370 void respawn(entity this)
1371 {
1372         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1373         {
1374                 this.solid = SOLID_NOT;
1375                 this.takedamage = DAMAGE_NO;
1376                 set_movetype(this, MOVETYPE_FLY);
1377                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1378                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1379                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1380                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1381                 if(autocvar_g_respawn_ghosts_maxtime)
1382                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1383         }
1384
1385         CopyBody(this, 1);
1386
1387         this.effects |= EF_NODRAW; // prevent another CopyBody
1388         PutClientInServer(this);
1389 }
1390
1391 void play_countdown(entity this, float finished, Sound samp)
1392 {
1393     TC(Sound, samp);
1394         if(IS_REAL_CLIENT(this))
1395                 if(floor(finished - time - frametime) != floor(finished - time))
1396                         if(finished - time < 6)
1397                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1398 }
1399
1400 void player_powerups(entity this)
1401 {
1402         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1403         int items_prev = this.items;
1404
1405         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1406                 this.modelflags |= MF_ROCKET;
1407         else
1408                 this.modelflags &= ~MF_ROCKET;
1409
1410         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1411
1412         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1413                 return;
1414
1415         Fire_ApplyDamage(this);
1416         Fire_ApplyEffect(this);
1417
1418         if (!g_instagib)
1419         {
1420                 if (this.items & ITEM_Strength.m_itemid)
1421                 {
1422                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1423                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1424                         if (time > this.strength_finished)
1425                         {
1426                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1427                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1428                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1429                         }
1430                 }
1431                 else
1432                 {
1433                         if (time < this.strength_finished)
1434                         {
1435                                 this.items = this.items | ITEM_Strength.m_itemid;
1436                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1438                         }
1439                 }
1440                 if (this.items & ITEM_Shield.m_itemid)
1441                 {
1442                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1443                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1444                         if (time > this.invincible_finished)
1445                         {
1446                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1447                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1448                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1449                         }
1450                 }
1451                 else
1452                 {
1453                         if (time < this.invincible_finished)
1454                         {
1455                                 this.items = this.items | ITEM_Shield.m_itemid;
1456                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1457                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1458                         }
1459                 }
1460                 if (this.items & IT_SUPERWEAPON)
1461                 {
1462                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1463                         {
1464                                 this.superweapons_finished = 0;
1465                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1466                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1468                         }
1469                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1470                         {
1471                                 // don't let them run out
1472                         }
1473                         else
1474                         {
1475                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1476                                 if (time > this.superweapons_finished)
1477                                 {
1478                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1479                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1480                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1481                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1482                                 }
1483                         }
1484                 }
1485                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1486                 {
1487                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1488                         {
1489                                 this.items = this.items | IT_SUPERWEAPON;
1490                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1491                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                         }
1493                         else
1494                         {
1495                                 this.superweapons_finished = 0;
1496                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1497                         }
1498                 }
1499                 else
1500                 {
1501                         this.superweapons_finished = 0;
1502                 }
1503         }
1504
1505         if(autocvar_g_nodepthtestplayers)
1506                 this.effects = this.effects | EF_NODEPTHTEST;
1507
1508         if(autocvar_g_fullbrightplayers)
1509                 this.effects = this.effects | EF_FULLBRIGHT;
1510
1511         if (time >= game_starttime)
1512         if (time < this.spawnshieldtime)
1513                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514
1515         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1526 }
1527
1528 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1529 {
1530         if(current < stable)
1531                 return current;
1532         else if(current < stable + 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1536 }
1537
1538 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1539 {
1540         if(current > rotstable)
1541         {
1542                 if(rotframetime > 0)
1543                 {
1544                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1545                         current = max(rotstable, current - rotlinear * rotframetime);
1546                 }
1547         }
1548         else if(current < regenstable)
1549         {
1550                 if(regenframetime > 0)
1551                 {
1552                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1553                         current = min(regenstable, current + regenlinear * regenframetime);
1554                 }
1555         }
1556
1557         if(current > limit)
1558                 current = limit;
1559
1560         return current;
1561 }
1562
1563 void player_regen(entity this)
1564 {
1565         float max_mod, regen_mod, rot_mod, limit_mod;
1566         max_mod = regen_mod = rot_mod = limit_mod = 1;
1567
1568         float regen_health = autocvar_g_balance_health_regen;
1569         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1570         float regen_health_rot = autocvar_g_balance_health_rot;
1571         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1572         float regen_health_stable = autocvar_g_balance_health_regenstable;
1573         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1574         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1575                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1576         max_mod = M_ARGV(1, float);
1577         regen_mod = M_ARGV(2, float);
1578         rot_mod = M_ARGV(3, float);
1579         limit_mod = M_ARGV(4, float);
1580         regen_health = M_ARGV(5, float);
1581         regen_health_linear = M_ARGV(6, float);
1582         regen_health_rot = M_ARGV(7, float);
1583         regen_health_rotlinear = M_ARGV(8, float);
1584         regen_health_stable = M_ARGV(9, float);
1585         regen_health_rotstable = M_ARGV(10, float);
1586
1587
1588         if(!mutator_returnvalue)
1589         if(!STAT(FROZEN, this))
1590         {
1591                 float mina, maxa, limith, limita;
1592                 maxa = autocvar_g_balance_armor_rotstable;
1593                 mina = autocvar_g_balance_armor_regenstable;
1594                 limith = autocvar_g_balance_health_limit;
1595                 limita = autocvar_g_balance_armor_limit;
1596
1597                 regen_health_rotstable = regen_health_rotstable * max_mod;
1598                 regen_health_stable = regen_health_stable * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1603                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1604         }
1605
1606         // if player rotted to death...  die!
1607         // check this outside above checks, as player may still be able to rot to death
1608         if(this.health < 1)
1609         {
1610                 if(this.vehicle)
1611                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1612                 if(this.event_damage)
1613                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1614         }
1615
1616         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1617         {
1618                 float minf, maxf, limitf;
1619
1620                 maxf = autocvar_g_balance_fuel_rotstable;
1621                 minf = autocvar_g_balance_fuel_regenstable;
1622                 limitf = autocvar_g_balance_fuel_limit;
1623
1624                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1625         }
1626 }
1627
1628 bool zoomstate_set;
1629 void SetZoomState(entity this, float newzoom)
1630 {
1631         if(newzoom != this.zoomstate)
1632         {
1633                 this.zoomstate = newzoom;
1634                 ClientData_Touch(this);
1635         }
1636         zoomstate_set = true;
1637 }
1638
1639 void GetPressedKeys(entity this)
1640 {
1641         MUTATOR_CALLHOOK(GetPressedKeys, this);
1642         int keys = STAT(PRESSED_KEYS, this);
1643         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1644         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1645         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1646         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1647
1648         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1649         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1650         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1651         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1652         this.pressedkeys = keys; // store for other users
1653
1654         STAT(PRESSED_KEYS, this) = keys;
1655 }
1656
1657 /*
1658 ======================
1659 spectate mode routines
1660 ======================
1661 */
1662
1663 void SpectateCopy(entity this, entity spectatee)
1664 {
1665     TC(Client, this); TC(Client, spectatee);
1666
1667         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1668         PS(this) = PS(spectatee);
1669         this.armortype = spectatee.armortype;
1670         this.armorvalue = spectatee.armorvalue;
1671         this.ammo_cells = spectatee.ammo_cells;
1672         this.ammo_plasma = spectatee.ammo_plasma;
1673         this.ammo_shells = spectatee.ammo_shells;
1674         this.ammo_nails = spectatee.ammo_nails;
1675         this.ammo_rockets = spectatee.ammo_rockets;
1676         this.ammo_fuel = spectatee.ammo_fuel;
1677         this.clip_load = spectatee.clip_load;
1678         this.clip_size = spectatee.clip_size;
1679         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1680         this.health = spectatee.health;
1681         this.impulse = 0;
1682         this.items = spectatee.items;
1683         this.last_pickup = spectatee.last_pickup;
1684         this.hit_time = spectatee.hit_time;
1685         this.strength_finished = spectatee.strength_finished;
1686         this.invincible_finished = spectatee.invincible_finished;
1687         this.superweapons_finished = spectatee.superweapons_finished;
1688         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1689         this.weapons = spectatee.weapons;
1690         this.vortex_charge = spectatee.vortex_charge;
1691         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1692         this.hagar_load = spectatee.hagar_load;
1693         this.arc_heat_percent = spectatee.arc_heat_percent;
1694         this.minelayer_mines = spectatee.minelayer_mines;
1695         this.punchangle = spectatee.punchangle;
1696         this.view_ofs = spectatee.view_ofs;
1697         this.velocity = spectatee.velocity;
1698         this.dmg_take = spectatee.dmg_take;
1699         this.dmg_save = spectatee.dmg_save;
1700         this.dmg_inflictor = spectatee.dmg_inflictor;
1701         this.v_angle = spectatee.v_angle;
1702         this.angles = spectatee.v_angle;
1703         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1704         this.revive_progress = spectatee.revive_progress;
1705         this.viewloc = spectatee.viewloc;
1706         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1707                 this.fixangle = true;
1708         setorigin(this, spectatee.origin);
1709         setsize(this, spectatee.mins, spectatee.maxs);
1710         SetZoomState(this, spectatee.zoomstate);
1711
1712         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1713         {
1714                 .entity weaponentity = weaponentities[slot];
1715                 this.(weaponentity) = spectatee.(weaponentity);
1716         }
1717
1718         for(int slot = 0; slot < MAX_AXH; ++slot)
1719         {
1720                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1721         }
1722
1723     anticheat_spectatecopy(this, spectatee);
1724         this.hud = spectatee.hud;
1725         if(spectatee.vehicle)
1726     {
1727         this.angles = spectatee.v_angle;
1728
1729         //this.fixangle = false;
1730         //this.velocity = spectatee.vehicle.velocity;
1731         this.vehicle_health = spectatee.vehicle_health;
1732         this.vehicle_shield = spectatee.vehicle_shield;
1733         this.vehicle_energy = spectatee.vehicle_energy;
1734         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1735         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1736         this.vehicle_reload1 = spectatee.vehicle_reload1;
1737         this.vehicle_reload2 = spectatee.vehicle_reload2;
1738
1739         //msg_entity = this;
1740
1741        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1742             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1743            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1744            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1745
1746         //WriteByte (MSG_ONE, SVC_SETVIEW);
1747         //    WriteEntity(MSG_ONE, this);
1748         //makevectors(spectatee.v_angle);
1749         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1750     }
1751 }
1752
1753 bool SpectateUpdate(entity this)
1754 {
1755         if(!this.enemy)
1756                 return false;
1757
1758         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1759         {
1760                 SetSpectatee(this, NULL);
1761                 return false;
1762         }
1763
1764         SpectateCopy(this, this.enemy);
1765
1766         return true;
1767 }
1768
1769 bool SpectateSet(entity this)
1770 {
1771         if(!IS_PLAYER(this.enemy))
1772                 return false;
1773
1774         ClientData_Touch(this.enemy);
1775
1776         msg_entity = this;
1777         WriteByte(MSG_ONE, SVC_SETVIEW);
1778         WriteEntity(MSG_ONE, this.enemy);
1779         set_movetype(this, MOVETYPE_NONE);
1780         accuracy_resend(this);
1781
1782         if(!SpectateUpdate(this))
1783                 PutObserverInServer(this);
1784
1785         return true;
1786 }
1787
1788 void SetSpectatee_status(entity this, int spectatee_num)
1789 {
1790         int oldspectatee_status = this.spectatee_status;
1791         this.spectatee_status = spectatee_num;
1792
1793         if (this.spectatee_status != oldspectatee_status)
1794         {
1795                 ClientData_Touch(this);
1796                 if (g_race || g_cts) race_InitSpectator();
1797         }
1798 }
1799
1800 void SetSpectatee(entity this, entity spectatee)
1801 {
1802         entity old_spectatee = this.enemy;
1803
1804         this.enemy = spectatee;
1805
1806         // WEAPONTODO
1807         // these are required to fix the spectator bug with arc
1808         if(old_spectatee)
1809         {
1810                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1811                 {
1812                         .entity weaponentity = weaponentities[slot];
1813                         if(old_spectatee.(weaponentity).arc_beam)
1814                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1815                 }
1816         }
1817         if(this.enemy)
1818         {
1819                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1820                 {
1821                         .entity weaponentity = weaponentities[slot];
1822                         if(this.enemy.(weaponentity).arc_beam)
1823                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1824                 }
1825         }
1826
1827         if (this.enemy)
1828                 SetSpectatee_status(this, etof(this.enemy));
1829
1830         // needed to update spectator list
1831         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1832 }
1833
1834 bool Spectate(entity this, entity pl)
1835 {
1836         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1837                 return false;
1838         pl = M_ARGV(1, entity);
1839
1840         SetSpectatee(this, pl);
1841         return SpectateSet(this);
1842 }
1843
1844 bool SpectateNext(entity this)
1845 {
1846         entity ent = find(this.enemy, classname, STR_PLAYER);
1847
1848         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1849                 ent = M_ARGV(1, entity);
1850         else if (!ent)
1851                 ent = find(ent, classname, STR_PLAYER);
1852
1853         if(ent) { SetSpectatee(this, ent); }
1854
1855         return SpectateSet(this);
1856 }
1857
1858 bool SpectatePrev(entity this)
1859 {
1860         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1861         entity ent = findchain(classname, STR_PLAYER);
1862         if (!ent) // no player
1863                 return false;
1864
1865         entity first = ent;
1866         // skip players until current spectated player
1867         if(this.enemy)
1868         while(ent && ent != this.enemy)
1869                 ent = ent.chain;
1870
1871         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1872         {
1873                 case MUT_SPECPREV_FOUND:
1874                     ent = M_ARGV(1, entity);
1875                     break;
1876                 case MUT_SPECPREV_RETURN:
1877                     return true;
1878                 case MUT_SPECPREV_CONTINUE:
1879                 default:
1880                 {
1881                         if(ent.chain)
1882                                 ent = ent.chain;
1883                         else
1884                                 ent = first;
1885                         break;
1886                 }
1887         }
1888
1889         SetSpectatee(this, ent);
1890         return SpectateSet(this);
1891 }
1892
1893 /*
1894 =============
1895 ShowRespawnCountdown()
1896
1897 Update a respawn countdown display.
1898 =============
1899 */
1900 void ShowRespawnCountdown(entity this)
1901 {
1902         float number;
1903         if(!IS_DEAD(this)) // just respawned?
1904                 return;
1905         else
1906         {
1907                 number = ceil(this.respawn_time - time);
1908                 if(number <= 0)
1909                         return;
1910                 if(number <= this.respawn_countdown)
1911                 {
1912                         this.respawn_countdown = number - 1;
1913                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1914                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1915                 }
1916         }
1917 }
1918
1919 .bool team_selected;
1920 bool ShowTeamSelection(entity this)
1921 {
1922         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1923                 return false;
1924         stuffcmd(this, "menu_showteamselect\n");
1925         return true;
1926 }
1927 void Join(entity this)
1928 {
1929         TRANSMUTE(Player, this);
1930
1931         if(!this.team_selected)
1932         if(autocvar_g_campaign || autocvar_g_balance_teams)
1933                 JoinBestTeam(this, false, true);
1934
1935         if(autocvar_g_campaign)
1936                 campaign_bots_may_start = true;
1937
1938         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1939
1940         PutClientInServer(this);
1941
1942         if(teamplay && this.team != -1)
1943                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1944         else
1945                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1946         this.team_selected = false;
1947 }
1948
1949 /**
1950  * Determines whether the player is allowed to join. This depends on cvar
1951  * g_maxplayers, if it isn't used this function always return true, otherwise
1952  * it checks whether the number of currently playing players exceeds g_maxplayers.
1953  * @return int number of free slots for players, 0 if none
1954  */
1955 int nJoinAllowed(entity this, entity ignore)
1956 {
1957         if(!ignore)
1958         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1959         // so report 0 free slots if restricted
1960         {
1961                 if(autocvar_g_forced_team_otherwise == "spectate")
1962                         return 0;
1963                 if(autocvar_g_forced_team_otherwise == "spectator")
1964                         return 0;
1965         }
1966
1967         if(this && this.team_forced < 0)
1968                 return 0; // forced spectators can never join
1969
1970         // TODO simplify this
1971         int totalClients = 0;
1972         int currentlyPlaying = 0;
1973         FOREACH_CLIENT(true, LAMBDA(
1974                 if(it != ignore)
1975                         ++totalClients;
1976                 if(IS_REAL_CLIENT(it))
1977                 if(IS_PLAYER(it) || it.caplayer)
1978                         ++currentlyPlaying;
1979         ));
1980
1981         float free_slots = 0;
1982         if (!autocvar_g_maxplayers)
1983                 free_slots = maxclients - totalClients;
1984         else if(currentlyPlaying < autocvar_g_maxplayers)
1985                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1986
1987         static float join_prevent_msg_time = 0;
1988         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1989         {
1990                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1991                 join_prevent_msg_time = time + 3;
1992         }
1993
1994         return free_slots;
1995 }
1996
1997 /**
1998  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1999  * g_maxplayers_spectator_blocktime seconds
2000  */
2001 void checkSpectatorBlock(entity this)
2002 {
2003         if(IS_SPEC(this) || IS_OBSERVER(this))
2004         if(!this.caplayer)
2005         if(IS_REAL_CLIENT(this))
2006         {
2007                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2008                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2009                         dropclient(this);
2010                 }
2011         }
2012 }
2013
2014 void PrintWelcomeMessage(entity this)
2015 {
2016         if(this.motd_actived_time == 0)
2017         {
2018                 if (autocvar_g_campaign) {
2019                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2020                                 this.motd_actived_time = time;
2021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2022                         }
2023                 } else {
2024                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2025                                 this.motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2027                         }
2028                 }
2029         }
2030         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if (PHYS_INPUT_BUTTON_INFO(this))
2034                                 this.motd_actived_time = time;
2035                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2036                                 this.motd_actived_time = 0;
2037                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2038                         }
2039                 } else {
2040                         if (PHYS_INPUT_BUTTON_INFO(this))
2041                                 this.motd_actived_time = time;
2042                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2043                                 this.motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2045                         }
2046                 }
2047         }
2048         else //if(this.motd_actived_time < 0) // just connected, motd is active
2049         {
2050                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2051                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2052                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2053                 {
2054                         // instanctly hide MOTD
2055                         this.motd_actived_time = 0;
2056                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2057                 }
2058         }
2059 }
2060
2061 bool joinAllowed(entity this)
2062 {
2063         if (this.version_mismatch) return false;
2064         if (!nJoinAllowed(this, this)) return false;
2065         if (teamplay && lockteams) return false;
2066         if (ShowTeamSelection(this)) return false;
2067         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2068         return true;
2069 }
2070
2071 void ObserverThink(entity this)
2072 {
2073         if ( this.impulse )
2074         {
2075                 MinigameImpulse(this, this.impulse);
2076                 this.impulse = 0;
2077         }
2078
2079         if (this.flags & FL_JUMPRELEASED) {
2080                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2081                         this.flags &= ~FL_JUMPRELEASED;
2082                         this.flags |= FL_SPAWNING;
2083                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2084                         this.flags &= ~FL_JUMPRELEASED;
2085                         if(SpectateNext(this)) {
2086                                 TRANSMUTE(Spectator, this);
2087                         }
2088                 } else {
2089                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2090                         set_movetype(this, preferred_movetype);
2091                 }
2092         } else {
2093                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2094                         this.flags |= FL_JUMPRELEASED;
2095                         if(this.flags & FL_SPAWNING)
2096                         {
2097                                 this.flags &= ~FL_SPAWNING;
2098                                 Join(this);
2099                                 return;
2100                         }
2101                 }
2102         }
2103 }
2104
2105 void SpectatorThink(entity this)
2106 {
2107         if ( this.impulse )
2108         {
2109                 if(MinigameImpulse(this, this.impulse))
2110                         this.impulse = 0;
2111
2112                 if (this.impulse == IMP_weapon_drop.impulse)
2113                 {
2114                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2115                         this.impulse = 0;
2116                         return;
2117                 }
2118         }
2119
2120         if (this.flags & FL_JUMPRELEASED) {
2121                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2122                         this.flags &= ~FL_JUMPRELEASED;
2123                         this.flags |= FL_SPAWNING;
2124                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2125                         this.flags &= ~FL_JUMPRELEASED;
2126                         if(SpectateNext(this)) {
2127                                 TRANSMUTE(Spectator, this);
2128                         } else {
2129                                 TRANSMUTE(Observer, this);
2130                                 PutClientInServer(this);
2131                         }
2132                         this.impulse = 0;
2133                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2134                         this.flags &= ~FL_JUMPRELEASED;
2135                         if(SpectatePrev(this)) {
2136                                 TRANSMUTE(Spectator, this);
2137                         } else {
2138                                 TRANSMUTE(Observer, this);
2139                                 PutClientInServer(this);
2140                         }
2141                         this.impulse = 0;
2142                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2143                         this.flags &= ~FL_JUMPRELEASED;
2144                         TRANSMUTE(Observer, this);
2145                         PutClientInServer(this);
2146                 } else {
2147                         if(!SpectateUpdate(this))
2148                                 PutObserverInServer(this);
2149                 }
2150         } else {
2151                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2152                         this.flags |= FL_JUMPRELEASED;
2153                         if(this.flags & FL_SPAWNING)
2154                         {
2155                                 this.flags &= ~FL_SPAWNING;
2156                                 Join(this);
2157                                 return;
2158                         }
2159                 }
2160                 if(!SpectateUpdate(this))
2161                         PutObserverInServer(this);
2162         }
2163
2164         this.flags |= FL_CLIENT | FL_NOTARGET;
2165 }
2166
2167 void vehicles_enter (entity pl, entity veh);
2168 void PlayerUseKey(entity this)
2169 {
2170         if (!IS_PLAYER(this))
2171                 return;
2172
2173         if(this.vehicle)
2174         {
2175                 if(!game_stopped)
2176                 {
2177                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2178                         return;
2179                 }
2180         }
2181         else if(autocvar_g_vehicles_enter)
2182         {
2183                 if(!STAT(FROZEN, this))
2184                 if(!IS_DEAD(this))
2185                 if(!game_stopped)
2186                 {
2187                         entity head, closest_target = NULL;
2188                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2189
2190                         while(head) // find the closest acceptable target to enter
2191                         {
2192                                 if(IS_VEHICLE(head))
2193                                 if(!IS_DEAD(head))
2194                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2195                                 if(head.takedamage != DAMAGE_NO)
2196                                 {
2197                                         if(closest_target)
2198                                         {
2199                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2200                                                 { closest_target = head; }
2201                                         }
2202                                         else { closest_target = head; }
2203                                 }
2204
2205                                 head = head.chain;
2206                         }
2207
2208                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2209                 }
2210         }
2211
2212         // a use key was pressed; call handlers
2213         MUTATOR_CALLHOOK(PlayerUseKey, this);
2214 }
2215
2216
2217 /*
2218 =============
2219 PlayerPreThink
2220
2221 Called every frame for each client before the physics are run
2222 =============
2223 */
2224 .float usekeypressed;
2225 .float last_vehiclecheck;
2226 .int items_added;
2227 void PlayerPreThink (entity this)
2228 {
2229         WarpZone_PlayerPhysics_FixVAngle(this);
2230
2231     STAT(GAMESTARTTIME, this) = game_starttime;
2232         STAT(ROUNDSTARTTIME, this) = round_starttime;
2233         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2234         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2235
2236         STAT(WEAPONSINMAP, this) = weaponsInMap;
2237
2238         if (frametime) {
2239                 // physics frames: update anticheat stuff
2240                 anticheat_prethink(this);
2241         }
2242
2243         if (blockSpectators && frametime) {
2244                 // WORKAROUND: only use dropclient in server frames (frametime set).
2245                 // Never use it in cl_movement frames (frametime zero).
2246                 checkSpectatorBlock(this);
2247     }
2248
2249         zoomstate_set = false;
2250
2251         // Check for nameless players
2252         if (isInvisibleString(this.netname)) {
2253                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2254                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2255         }
2256         if (this.netname != this.netname_previous) {
2257                 if (autocvar_sv_eventlog) {
2258                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2259         }
2260                 if (this.netname_previous) strunzone(this.netname_previous);
2261                 this.netname_previous = strzone(this.netname);
2262         }
2263
2264         // version nagging
2265         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2266         this.version_nagtime = 0;
2267         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2268             // git client
2269         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2270             // git server
2271             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2272         } else {
2273             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2274             if (r < 0) { // old client
2275                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2276             } else if (r > 0) { // old server
2277                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2278             }
2279         }
2280     }
2281
2282         // GOD MODE info
2283         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2284         {
2285                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2286                 this.max_armorvalue = 0;
2287         }
2288
2289         if (STAT(FROZEN, this) == 2)
2290         {
2291                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2292                 this.health = max(1, this.revive_progress * start_health);
2293                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2294
2295                 if (this.revive_progress >= 1)
2296                         Unfreeze(this);
2297         }
2298         else if (STAT(FROZEN, this) == 3)
2299         {
2300                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2301                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2302
2303                 if (this.health < 1)
2304                 {
2305                         if (this.vehicle)
2306                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2307                         if(this.event_damage)
2308                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2309                 }
2310                 else if (this.revive_progress <= 0)
2311                         Unfreeze(this);
2312         }
2313
2314         MUTATOR_CALLHOOK(PlayerPreThink, this);
2315
2316         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2317         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2318         {
2319                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2320                 {
2321                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2322                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2323                         {
2324                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2325                         }
2326                         else if(!it.owner)
2327                         {
2328                                 if(!it.team || SAME_TEAM(this, it))
2329                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2330                                 else if(autocvar_g_vehicles_steal)
2331                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2332                         }
2333                 });
2334
2335                 this.last_vehiclecheck = time + 1;
2336         }
2337
2338         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2339         {
2340                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2341                         PlayerUseKey(this);
2342                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2343         }
2344
2345         if (IS_REAL_CLIENT(this))
2346                 PrintWelcomeMessage(this);
2347
2348         if (IS_PLAYER(this)) {
2349                 CheckRules_Player(this);
2350
2351                 if (game_stopped || intermission_running) {
2352                         this.modelflags &= ~MF_ROCKET;
2353                         if(intermission_running)
2354                                 IntermissionThink(this);
2355                         return;
2356                 }
2357
2358                 if (timeout_status == TIMEOUT_ACTIVE) {
2359             // don't allow the player to turn around while game is paused
2360                         // FIXME turn this into CSQC stuff
2361                         this.v_angle = this.lastV_angle;
2362                         this.angles = this.lastV_angle;
2363                         this.fixangle = true;
2364                 }
2365
2366                 if (frametime) player_powerups(this);
2367
2368                 if (IS_DEAD(this)) {
2369                         if (this.personal && g_race_qualifying) {
2370                                 if (time > this.respawn_time) {
2371                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2372                                         respawn(this);
2373                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2374                                 }
2375                         } else {
2376                                 if (frametime) player_anim(this);
2377                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2378
2379                                 switch(this.deadflag)
2380                                 {
2381                                         case DEAD_DYING:
2382                                         {
2383                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2384                                                         this.deadflag = DEAD_RESPAWNING;
2385                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2386                                                         this.deadflag = DEAD_DEAD;
2387                                                 break;
2388                                         }
2389                                         case DEAD_DEAD:
2390                                         {
2391                                                 if (button_pressed)
2392                                                         this.deadflag = DEAD_RESPAWNABLE;
2393                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2394                                                         this.deadflag = DEAD_RESPAWNING;
2395                                                 break;
2396                                         }
2397                                         case DEAD_RESPAWNABLE:
2398                                         {
2399                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2400                                                         this.deadflag = DEAD_RESPAWNING;
2401                                                 break;
2402                                         }
2403                                         case DEAD_RESPAWNING:
2404                                         {
2405                                                 if (time > this.respawn_time)
2406                                                 {
2407                                                         this.respawn_time = time + 1; // only retry once a second
2408                                                         this.respawn_time_max = this.respawn_time;
2409                                                         respawn(this);
2410                                                 }
2411                                                 break;
2412                                         }
2413                                 }
2414
2415                                 ShowRespawnCountdown(this);
2416
2417                                 if (this.respawn_flags & RESPAWN_SILENT)
2418                                         STAT(RESPAWN_TIME, this) = 0;
2419                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2420                                 {
2421                                         if (time < this.respawn_time)
2422                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2423                                         else if (this.deadflag != DEAD_RESPAWNING)
2424                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2425                                 }
2426                                 else
2427                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2428                         }
2429
2430                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2431                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2432                                 STAT(RESPAWN_TIME, this) *= -1;
2433
2434                         return;
2435                 }
2436
2437                 this.prevorigin = this.origin;
2438
2439                 bool have_hook = false;
2440                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2441                 {
2442                         .entity weaponentity = weaponentities[slot];
2443                         if(this.(weaponentity).hook.state)
2444                         {
2445                                 have_hook = true;
2446                                 break;
2447                         }
2448                 }
2449                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2450                 if (have_hook) {
2451                         do_crouch = false;
2452                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2453                         do_crouch = false;
2454                 } else if (this.vehicle) {
2455                         do_crouch = false;
2456                 } else if (STAT(FROZEN, this)) {
2457                         do_crouch = false;
2458         }
2459
2460                 if (do_crouch) {
2461                         if (!this.crouch) {
2462                                 this.crouch = true;
2463                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2464                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2465                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2466                         }
2467                 } else if (this.crouch) {
2468             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2469             if (!trace_startsolid) {
2470                 this.crouch = false;
2471                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2472                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2473             }
2474                 }
2475
2476                 FixPlayermodel(this);
2477
2478                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2479                 //if(frametime)
2480                 {
2481                         this.items &= ~this.items_added;
2482
2483                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2484                         {
2485                                 .entity weaponentity = weaponentities[slot];
2486                                 W_WeaponFrame(this, weaponentity);
2487
2488                                 if(slot == 0)
2489                                 {
2490                                         this.clip_load = this.(weaponentity).clip_load;
2491                                         this.clip_size = this.(weaponentity).clip_size;
2492                                 }
2493                         }
2494
2495                         this.items_added = 0;
2496                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2497                 this.items_added |= IT_FUEL;
2498
2499                         this.items |= this.items_added;
2500                 }
2501
2502                 player_regen(this);
2503
2504                 // WEAPONTODO: Add a weapon request for this
2505                 // rot vortex charge to the charge limit
2506                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2507                 {
2508                         .entity weaponentity = weaponentities[slot];
2509                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2510                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2511                 }
2512
2513                 if (frametime) player_anim(this);
2514
2515                 // secret status
2516                 secrets_setstatus(this);
2517
2518                 // monsters status
2519                 monsters_setstatus(this);
2520
2521                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2522         }
2523         else if (game_stopped || intermission_running) {
2524                 if(intermission_running)
2525                         IntermissionThink(this);
2526                 return;
2527         }
2528         else if (IS_OBSERVER(this)) {
2529                 ObserverThink(this);
2530         }
2531         else if (IS_SPEC(this)) {
2532                 SpectatorThink(this);
2533         }
2534
2535         // WEAPONTODO: Add weapon request for this
2536         if (!zoomstate_set) {
2537                 bool wep_zoomed = false;
2538                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2539                 {
2540                         .entity weaponentity = weaponentities[slot];
2541                         Weapon thiswep = this.(weaponentity).m_weapon;
2542                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2543                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2544                 }
2545                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2546     }
2547
2548         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2549         {
2550                 this.teamkill_soundtime = 0;
2551
2552                 entity e = this.teamkill_soundsource;
2553                 entity oldpusher = e.pusher;
2554                 e.pusher = this;
2555                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2556                 e.pusher = oldpusher;
2557         }
2558
2559         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2560                 this.taunt_soundtime = 0;
2561                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2562         }
2563
2564         target_voicescript_next(this);
2565
2566         // WEAPONTODO: Move into weaponsystem somehow
2567         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2568         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2569         {
2570                 .entity weaponentity = weaponentities[slot];
2571                 if(this.(weaponentity).m_weapon == WEP_Null)
2572                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2573         }
2574 }
2575
2576 void DrownPlayer(entity this)
2577 {
2578         if(IS_DEAD(this))
2579                 return;
2580
2581         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2582         {
2583                 if(this.air_finished < time)
2584                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2585                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2586                 this.dmg = 2;
2587         }
2588         else if (this.air_finished < time)
2589         {       // drown!
2590                 if (this.pain_finished < time)
2591                 {
2592                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2593                         this.pain_finished = time + 0.5;
2594                 }
2595         }
2596 }
2597
2598 .bool move_qcphysics;
2599
2600 void Player_Physics(entity this)
2601 {
2602         set_movetype(this, this.move_movetype);
2603
2604         if(!this.move_qcphysics)
2605                 return;
2606
2607         if(!frametime && !this.pm_frametime)
2608                 return;
2609
2610         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2611
2612         this.pm_frametime = 0;
2613 }
2614
2615 /*
2616 =============
2617 PlayerPostThink
2618
2619 Called every frame for each client after the physics are run
2620 =============
2621 */
2622 .float idlekick_lasttimeleft;
2623 void PlayerPostThink (entity this)
2624 {
2625         Player_Physics(this);
2626
2627         if (sv_maxidle > 0)
2628         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2629         if (IS_REAL_CLIENT(this))
2630         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2631         {
2632                 int totalClients = 0;
2633                 if(sv_maxidle_slots > 0)
2634                 {
2635                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2636                         {
2637                                 ++totalClients;
2638                         });
2639                 }
2640
2641                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2642                 { /* do nothing */ }
2643                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2644                 {
2645                         if (this.idlekick_lasttimeleft)
2646                         {
2647                                 this.idlekick_lasttimeleft = 0;
2648                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2649                         }
2650                 }
2651                 else
2652                 {
2653                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2654                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2655                                 if (!this.idlekick_lasttimeleft)
2656                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2657                         }
2658                         if (timeleft <= 0) {
2659                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2660                                 dropclient(this);
2661                                 return;
2662                         }
2663                         else if (timeleft <= 10) {
2664                                 if (timeleft != this.idlekick_lasttimeleft) {
2665                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2666                 }
2667                                 this.idlekick_lasttimeleft = timeleft;
2668                         }
2669                 }
2670         }
2671
2672         CheatFrame(this);
2673
2674         //CheckPlayerJump();
2675         if (game_stopped)
2676         {
2677                 this.solid = SOLID_NOT;
2678                 this.takedamage = DAMAGE_NO;
2679                 set_movetype(this, MOVETYPE_NONE);
2680         }
2681
2682         if (IS_PLAYER(this)) {
2683                 DrownPlayer(this);
2684                 CheckRules_Player(this);
2685                 UpdateChatBubble(this);
2686                 if (this.impulse) ImpulseCommands(this);
2687                 if (game_stopped)
2688                 {
2689                         CSQCMODEL_AUTOUPDATE(this);
2690                         return;
2691                 }
2692                 GetPressedKeys(this);
2693         }
2694
2695         if (this.waypointsprite_attachedforcarrier) {
2696             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2697                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2698     }
2699
2700         playerdemo_write(this);
2701
2702         CSQCMODEL_AUTOUPDATE(this);
2703 }