qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include <common/vehicles/sv_vehicles.qh>
  50
  51 #include "../common/items/_mod.qh"
  52
  53 #include "../common/mutators/mutator/waypoints/all.qh"
  54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  55 #include <common/gamemodes/_mod.qh>
  56
  57 #include "../common/mapobjects/subs.qh"
  58 #include "../common/mapobjects/triggers.qh"
  59 #include "../common/mapobjects/trigger/secret.qh"
  60
  61 #include "../common/minigames/sv_minigames.qh"
  62
  63 #include "../common/items/inventory.qh"
  64
  65 #include "../common/monsters/sv_monsters.qh"
  66
  67 #include "../lib/warpzone/server.qh"
  68
  69 #include <common/mutators/mutator/overkill/oknex.qh>
  70
  71 STATIC_METHOD(Client, Add, void(Client this, int _team))
  72 {
  73     ClientConnect(this);
  74     TRANSMUTE(Player, this);
  75     this.frame = 12; // 7
  76     this.team = _team;
  77     PutClientInServer(this);
  78 }
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170
 171 /*
 172 =============
 173 CheckPlayerModel
 174
 175 Checks if the argument string can be a valid playermodel.
 176 Returns a valid one in doubt.
 177 =============
 178 */
 179 string FallbackPlayerModel;
 180 string CheckPlayerModel(string plyermodel) {
 181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 182         {
 183                 // note: we cannot summon Don Strunzone here, some player may
 184                 // still have the model string set. In case anyone manages how
 185                 // to change a cvar default, we'll have a small leak here.
 186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 187         }
 188         // only in right path
 189         if( substring(plyermodel,0,14) != "models/player/")
 190                 return FallbackPlayerModel;
 191         // only good file extensions
 192         if(substring(plyermodel,-4,4) != ".zym")
 193         if(substring(plyermodel,-4,4) != ".dpm")
 194         if(substring(plyermodel,-4,4) != ".iqm")
 195         if(substring(plyermodel,-4,4) != ".md3")
 196         if(substring(plyermodel,-4,4) != ".psk")
 197                 return FallbackPlayerModel;
 198         // forbid the LOD models
 199         if(substring(plyermodel, -9,5) == "_lod1")
 200                 return FallbackPlayerModel;
 201         if(substring(plyermodel, -9,5) == "_lod2")
 202                 return FallbackPlayerModel;
 203         if(plyermodel != strtolower(plyermodel))
 204                 return FallbackPlayerModel;
 205         // also, restrict to server models
 206         if(autocvar_sv_servermodelsonly)
 207         {
 208                 if(!fexists(plyermodel))
 209                         return FallbackPlayerModel;
 210         }
 211         return plyermodel;
 212 }
 213
 214 void setplayermodel(entity e, string modelname)
 215 {
 216         precache_model(modelname);
 217         _setmodel(e, modelname);
 218         player_setupanimsformodel(e);
 219         if(!autocvar_g_debug_globalsounds)
 220                 UpdatePlayerSounds(e);
 221 }
 222
 223 /** putting a client as observer in the server */
 224 void PutObserverInServer(entity this)
 225 {
 226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 227         PlayerState_detach(this);
 228
 229         if (IS_PLAYER(this))
 230         {
 231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 232                 {
 233                         // despawn effect
 234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 235                 }
 236
 237                 // was a player, recount votes and ready status
 238                 if(IS_REAL_CLIENT(this))
 239                 {
 240                         if (vote_called) { VoteCount(false); }
 241                         ReadyCount();
 242                 }
 243     }
 244
 245     {
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254             msg_entity = this;
 255             WriteByte(MSG_ONE, SVC_SETVIEW);
 256             WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269     }
 270
 271     RemoveGrapplingHooks(this);
 272         Portal_ClearAll(this);
 273         Unfreeze(this);
 274         SetSpectatee(this, NULL);
 275
 276         if (this.alivetime)
 277         {
 278                 if (!warmup_stage)
 279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 280                 this.alivetime = 0;
 281         }
 282
 283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 284
 285         WaypointSprite_PlayerDead(this);
 286
 287         if (mutator_returnvalue) {
 288             // mutator prevents resetting teams+score
 289         } else {
 290                 int oldteam = this.team;
 291                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 292                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 293         this.frags = FRAGS_SPECTATOR;
 294         PlayerScore_Clear(this);  // clear scores when needed
 295     }
 296
 297         if (CS(this).killcount != FRAGS_SPECTATOR)
 298         {
 299                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 300                 if(!game_stopped)
 301                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 302                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 303
 304                 if(!CS(this).just_joined)
 305                         LogTeamchange(this.playerid, -1, 4);
 306                 else
 307                         CS(this).just_joined = false;
 308         }
 309
 310         accuracy_resend(this);
 311
 312         CS(this).spectatortime = time;
 313         if(this.bot_attack)
 314                 IL_REMOVE(g_bot_targets, this);
 315         this.bot_attack = false;
 316         if(this.monster_attack)
 317                 IL_REMOVE(g_monster_targets, this);
 318         this.monster_attack = false;
 319     STAT(HUD, this) = HUD_NORMAL;
 320         TRANSMUTE(Observer, this);
 321         this.iscreature = false;
 322         this.teleportable = TELEPORT_SIMPLE;
 323         if(this.damagedbycontents)
 324                 IL_REMOVE(g_damagedbycontents, this);
 325         this.damagedbycontents = false;
 326         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 327         SetSpectatee_status(this, etof(this));
 328         this.takedamage = DAMAGE_NO;
 329         this.solid = SOLID_NOT;
 330         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 331         this.flags = FL_CLIENT | FL_NOTARGET;
 332         this.effects = 0;
 333         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 334         this.pauserotarmor_finished = 0;
 335         this.pauserothealth_finished = 0;
 336         this.pauseregen_finished = 0;
 337         this.damageforcescale = 0;
 338         this.death_time = 0;
 339         this.respawn_flags = 0;
 340         this.respawn_time = 0;
 341         STAT(RESPAWN_TIME, this) = 0;
 342         this.alpha = 0;
 343         this.scale = 0;
 344         this.fade_time = 0;
 345         this.pain_frame = 0;
 346         this.pain_finished = 0;
 347         this.strength_finished = 0;
 348         this.invincible_finished = 0;
 349         this.superweapons_finished = 0;
 350         this.dphitcontentsmask = 0;
 351         this.pushltime = 0;
 352         this.istypefrag = 0;
 353         setthink(this, func_null);
 354         this.nextthink = 0;
 355         this.deadflag = DEAD_NO;
 356         this.crouch = false;
 357         STAT(REVIVE_PROGRESS, this) = 0;
 358         this.revival_time = 0;
 359
 360         this.items = 0;
 361         STAT(WEAPONS, this) = '0 0 0';
 362         this.drawonlytoclient = this;
 363
 364         this.viewloc = NULL;
 365
 366         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 367
 368         this.weaponmodel = "";
 369         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 370         {
 371                 this.weaponentities[slot] = NULL;
 372         }
 373         this.exteriorweaponentity = NULL;
 374         CS(this).killcount = FRAGS_SPECTATOR;
 375         this.velocity = '0 0 0';
 376         this.avelocity = '0 0 0';
 377         this.punchangle = '0 0 0';
 378         this.punchvector = '0 0 0';
 379         this.oldvelocity = this.velocity;
 380         this.fire_endtime = -1;
 381         this.event_damage = func_null;
 382         this.event_heal = func_null;
 383
 384         for(int slot = 0; slot < MAX_AXH; ++slot)
 385         {
 386                 entity axh = this.(AuxiliaryXhair[slot]);
 387                 this.(AuxiliaryXhair[slot]) = NULL;
 388
 389                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 390                         delete(axh);
 391         }
 392 }
 393
 394 int player_getspecies(entity this)
 395 {
 396         get_model_parameters(this.model, this.skin);
 397         int s = get_model_parameters_species;
 398         get_model_parameters(string_null, 0);
 399         if (s < 0) return SPECIES_HUMAN;
 400         return s;
 401 }
 402
 403 .float model_randomizer;
 404 void FixPlayermodel(entity player)
 405 {
 406         string defaultmodel = "";
 407         int defaultskin = 0;
 408         if(autocvar_sv_defaultcharacter)
 409         {
 410                 if(teamplay)
 411                 {
 412                         switch(player.team)
 413                         {
 414                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 415                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 416                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 417                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 418                         }
 419                 }
 420
 421                 if(defaultmodel == "")
 422                 {
 423                         defaultmodel = autocvar_sv_defaultplayermodel;
 424                         defaultskin = autocvar_sv_defaultplayerskin;
 425                 }
 426
 427                 int n = tokenize_console(defaultmodel);
 428                 if(n > 0)
 429                 {
 430                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 431                         // However, do NOT randomize if the player-selected model is in the list.
 432                         for (int i = 0; i < n; ++i)
 433                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 434                                         defaultmodel = argv(i);
 435                 }
 436
 437                 int i = strstrofs(defaultmodel, ":", 0);
 438                 if(i >= 0)
 439                 {
 440                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 441                         defaultmodel = substring(defaultmodel, 0, i);
 442                 }
 443         }
 444         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 445         {
 446                 if(teamplay)
 447                 {
 448                         switch(player.team)
 449                         {
 450                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 451                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 452                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 453                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 454                         }
 455                 }
 456
 457                 if(!defaultskin)
 458                         defaultskin = autocvar_sv_defaultplayerskin;
 459         }
 460
 461         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 462         defaultmodel = M_ARGV(0, string);
 463         defaultskin = M_ARGV(1, int);
 464
 465         bool chmdl = false;
 466         int oldskin;
 467         if(defaultmodel != "")
 468         {
 469                 if (defaultmodel != player.model)
 470                 {
 471                         vector m1 = player.mins;
 472                         vector m2 = player.maxs;
 473                         setplayermodel (player, defaultmodel);
 474                         setsize (player, m1, m2);
 475                         chmdl = true;
 476                 }
 477
 478                 oldskin = player.skin;
 479                 player.skin = defaultskin;
 480         } else {
 481                 if (player.playermodel != player.model || player.playermodel == "")
 482                 {
 483                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 484                         vector m1 = player.mins;
 485                         vector m2 = player.maxs;
 486                         setplayermodel (player, player.playermodel);
 487                         setsize (player, m1, m2);
 488                         chmdl = true;
 489                 }
 490
 491                 if(!autocvar_sv_defaultcharacterskin)
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = stof(player.playerskin);
 495                 }
 496                 else
 497                 {
 498                         oldskin = player.skin;
 499                         player.skin = defaultskin;
 500                 }
 501         }
 502
 503         if(chmdl || oldskin != player.skin) // model or skin has changed
 504         {
 505                 player.species = player_getspecies(player); // update species
 506                 if(!autocvar_g_debug_globalsounds)
 507                         UpdatePlayerSounds(player); // update skin sounds
 508         }
 509
 510         if(!teamplay)
 511                 if(strlen(autocvar_sv_defaultplayercolors))
 512                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 513                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 514 }
 515
 516 void PutPlayerInServer(entity this)
 517 {
 518         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 519
 520         PlayerState_attach(this);
 521         accuracy_resend(this);
 522
 523         if (this.team < 0)
 524                 JoinBestTeam(this, true);
 525
 526         entity spot = SelectSpawnPoint(this, false);
 527         if (!spot) {
 528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 529                 return; // spawn failed
 530         }
 531
 532         TRANSMUTE(Player, this);
 533
 534         CS(this).wasplayer = true;
 535         this.iscreature = true;
 536         this.teleportable = TELEPORT_NORMAL;
 537         if(!this.damagedbycontents)
 538                 IL_PUSH(g_damagedbycontents, this);
 539         this.damagedbycontents = true;
 540         set_movetype(this, MOVETYPE_WALK);
 541         this.solid = SOLID_SLIDEBOX;
 542         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 543         if (autocvar_g_playerclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 545         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 547         this.frags = FRAGS_PLAYER;
 548         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 549         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 550         if (autocvar__notarget)
 551                 this.flags |= FL_NOTARGET;
 552         this.takedamage = DAMAGE_AIM;
 553         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 554
 555         if (warmup_stage) {
 556                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 557                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 558                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 559                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 560                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 561                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 562                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 563                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 564                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 565         } else {
 566                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 567                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 568                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 569                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 570                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 571                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 572                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 573                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 574                 STAT(WEAPONS, this) = start_weapons;
 575                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 576                 {
 577                         GiveRandomWeapons(this, random_start_weapons_count,
 578                                 autocvar_g_random_start_weapons, random_start_ammo);
 579                 }
 580         }
 581         SetSpectatee_status(this, 0);
 582
 583         PS(this).dual_weapons = '0 0 0';
 584
 585         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 586
 587         this.items = start_items;
 588
 589         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 590         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 591         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 592         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 593         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 594         if (!sv_ready_restart_after_countdown && time < game_starttime)
 595         {
 596                 float f = game_starttime - time;
 597                 this.spawnshieldtime += f;
 598                 this.pauserotarmor_finished += f;
 599                 this.pauserothealth_finished += f;
 600                 this.pauseregen_finished += f;
 601         }
 602
 603         this.damageforcescale = 2;
 604         this.death_time = 0;
 605         this.respawn_flags = 0;
 606         this.respawn_time = 0;
 607         STAT(RESPAWN_TIME, this) = 0;
 608         this.scale = autocvar_sv_player_scale;
 609         this.fade_time = 0;
 610         this.pain_frame = 0;
 611         this.pain_finished = 0;
 612         this.pushltime = 0;
 613         setthink(this, func_null); // players have no think function
 614         this.nextthink = 0;
 615         this.dmg_team = 0;
 616         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 617
 618         this.deadflag = DEAD_NO;
 619
 620         this.angles = spot.angles;
 621         this.angles_z = 0; // never spawn tilted even if the spot says to
 622         if (IS_BOT_CLIENT(this))
 623                 this.v_angle = this.angles;
 624         this.fixangle = true; // turn this way immediately
 625         this.oldvelocity = this.velocity = '0 0 0';
 626         this.avelocity = '0 0 0';
 627         this.punchangle = '0 0 0';
 628         this.punchvector = '0 0 0';
 629
 630         this.strength_finished = 0;
 631         this.invincible_finished = 0;
 632         this.fire_endtime = -1;
 633         STAT(REVIVE_PROGRESS, this) = 0;
 634         this.revival_time = 0;
 635
 636         this.air_finished = time + 12;
 637         this.waterlevel = WATERLEVEL_NONE;
 638         this.watertype = CONTENT_EMPTY;
 639
 640         entity spawnevent = new_pure(spawnevent);
 641         spawnevent.owner = this;
 642         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 643
 644         // Cut off any still running player sounds.
 645         stopsound(this, CH_PLAYER_SINGLE);
 646
 647         this.model = "";
 648         FixPlayermodel(this);
 649         this.drawonlytoclient = NULL;
 650
 651         this.viewloc = NULL;
 652
 653         for(int slot = 0; slot < MAX_AXH; ++slot)
 654         {
 655                 entity axh = this.(AuxiliaryXhair[slot]);
 656                 this.(AuxiliaryXhair[slot]) = NULL;
 657
 658                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 659                         delete(axh);
 660         }
 661
 662         this.spawnpoint_targ = NULL;
 663
 664         this.crouch = false;
 665         this.view_ofs = STAT(PL_VIEW_OFS, this);
 666         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 667         this.spawnorigin = spot.origin;
 668         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 669         // don't reset back to last position, even if new position is stuck in solid
 670         this.oldorigin = this.origin;
 671         if(this.conveyor)
 672                 IL_REMOVE(g_conveyed, this);
 673         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 674         STAT(HUD, this) = HUD_NORMAL;
 675
 676         this.event_damage = PlayerDamage;
 677         this.event_heal = PlayerHeal;
 678
 679         if(!this.bot_attack)
 680                 IL_PUSH(g_bot_targets, this);
 681         this.bot_attack = true;
 682         if(!this.monster_attack)
 683                 IL_PUSH(g_monster_targets, this);
 684         this.monster_attack = true;
 685         navigation_dynamicgoal_init(this, false);
 686
 687         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 688
 689         // player was spectator
 690         if (CS(this).killcount == FRAGS_SPECTATOR) {
 691                 PlayerScore_Clear(this);
 692                 CS(this).killcount = 0;
 693                 CS(this).startplaytime = time;
 694         }
 695
 696         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 697         {
 698                 .entity weaponentity = weaponentities[slot];
 699                 entity oldwep = this.(weaponentity);
 700                 CL_SpawnWeaponentity(this, weaponentity);
 701                 if(oldwep && oldwep.owner == this)
 702                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 703         }
 704         this.alpha = default_player_alpha;
 705         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 706         this.exteriorweaponentity.alpha = default_weapon_alpha;
 707
 708         this.speedrunning = false;
 709
 710         target_voicescript_clear(this);
 711
 712         // reset fields the weapons may use
 713         FOREACH(Weapons, true, {
 714                 it.wr_resetplayer(it, this);
 715                         // reload all reloadable weapons
 716                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 717                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718                         {
 719                                 .entity weaponentity = weaponentities[slot];
 720                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 721                         }
 722                 }
 723         });
 724
 725         {
 726                 string s = spot.target;
 727                 spot.target = string_null;
 728                 SUB_UseTargets(spot, this, NULL);
 729                 spot.target = s;
 730         }
 731
 732         Unfreeze(this);
 733
 734         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 735
 736         if (autocvar_spawn_debug)
 737         {
 738                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 739                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 740         }
 741
 742         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743         {
 744                 .entity weaponentity = weaponentities[slot];
 745                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 746                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 747                 else
 748                         this.(weaponentity).m_switchweapon = WEP_Null;
 749                 this.(weaponentity).m_weapon = WEP_Null;
 750                 this.(weaponentity).weaponname = "";
 751                 this.(weaponentity).m_switchingweapon = WEP_Null;
 752                 this.(weaponentity).cnt = -1;
 753         }
 754
 755         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 756
 757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758         {
 759                 .entity weaponentity = weaponentities[slot];
 760                 W_WeaponFrame(this, weaponentity);
 761         }
 762
 763         if (!warmup_stage && !this.alivetime)
 764                 this.alivetime = time;
 765
 766         antilag_clear(this, CS(this));
 767 }
 768
 769 /** Called when a client spawns in the server */
 770 void PutClientInServer(entity this)
 771 {
 772         if (IS_BOT_CLIENT(this)) {
 773                 TRANSMUTE(Player, this);
 774         } else if (IS_REAL_CLIENT(this)) {
 775                 msg_entity = this;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, this);
 778         }
 779         if (game_stopped)
 780                 TRANSMUTE(Observer, this);
 781
 782         SetSpectatee(this, NULL);
 783
 784         // reset player keys
 785         if(PS(this))
 786                 PS(this).itemkeys = 0;
 787
 788         MUTATOR_CALLHOOK(PutClientInServer, this);
 789
 790         if (IS_OBSERVER(this)) {
 791                 PutObserverInServer(this);
 792         } else if (IS_PLAYER(this)) {
 793                 PutPlayerInServer(this);
 794         }
 795 }
 796
 797 // TODO do we need all these fields, or should we stop autodetecting runtime
 798 // changes and just have a console command to update this?
 799 bool ClientInit_SendEntity(entity this, entity to, int sf)
 800 {
 801         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 802         return = true;
 803         msg_entity = to;
 804         // MSG_INIT replacement
 805         // TODO: make easier to use
 806         Registry_send_all();
 807         W_PROP_reload(MSG_ONE, to);
 808         ClientInit_misc(this);
 809         MUTATOR_CALLHOOK(Ent_Init);
 810 }
 811 void ClientInit_misc(entity this)
 812 {
 813         int channel = MSG_ONE;
 814         WriteHeader(channel, ENT_CLIENT_INIT);
 815         WriteByte(channel, g_nexball_meter_period * 32);
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 824
 825         if(sv_foginterval && world.fog != "")
 826                 WriteString(channel, world.fog);
 827         else
 828                 WriteString(channel, "");
 829         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 830         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 831         WriteByte(channel, serverflags);
 832         WriteCoord(channel, autocvar_g_trueaim_minrange);
 833 }
 834
 835 void ClientInit_CheckUpdate(entity this)
 836 {
 837         this.nextthink = time;
 838         if(this.count != autocvar_g_balance_armor_blockpercent)
 839         {
 840                 this.count = autocvar_g_balance_armor_blockpercent;
 841                 this.SendFlags |= 1;
 842         }
 843         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 844         {
 845                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 846                 this.SendFlags |= 1;
 847         }
 848 }
 849
 850 void ClientInit_Spawn()
 851 {
 852         entity e = new_pure(clientinit);
 853         setthink(e, ClientInit_CheckUpdate);
 854         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 855
 856         ClientInit_CheckUpdate(e);
 857 }
 858
 859 /*
 860 =============
 861 SetNewParms
 862 =============
 863 */
 864 void SetNewParms ()
 865 {
 866         // initialize parms for a new player
 867         parm1 = -(86400 * 366);
 868
 869         MUTATOR_CALLHOOK(SetNewParms);
 870 }
 871
 872 /*
 873 =============
 874 SetChangeParms
 875 =============
 876 */
 877 void SetChangeParms (entity this)
 878 {
 879         // save parms for level change
 880         parm1 = CS(this).parm_idlesince - time;
 881
 882         MUTATOR_CALLHOOK(SetChangeParms);
 883 }
 884
 885 /*
 886 =============
 887 DecodeLevelParms
 888 =============
 889 */
 890 void DecodeLevelParms(entity this)
 891 {
 892         // load parms
 893         CS(this).parm_idlesince = parm1;
 894         if (CS(this).parm_idlesince == -(86400 * 366))
 895                 CS(this).parm_idlesince = time;
 896
 897         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 898         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 899
 900         MUTATOR_CALLHOOK(DecodeLevelParms);
 901 }
 902
 903 /*
 904 =============
 905 ClientKill
 906
 907 Called when a client types 'kill' in the console
 908 =============
 909 */
 910
 911 .float clientkill_nexttime;
 912 void ClientKill_Now_TeamChange(entity this)
 913 {
 914         if(this.killindicator_teamchange == -1)
 915         {
 916                 JoinBestTeam( this, true );
 917         }
 918         else if(this.killindicator_teamchange == -2)
 919         {
 920                 if(blockSpectators)
 921                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 922                 PutObserverInServer(this);
 923         }
 924         else
 925                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 926         this.killindicator_teamchange = 0;
 927 }
 928
 929 void ClientKill_Now(entity this)
 930 {
 931         if(this.vehicle)
 932         {
 933             vehicles_exit(this.vehicle, VHEF_RELEASE);
 934             if(!this.killindicator_teamchange)
 935             {
 936             this.vehicle_health = -1;
 937             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 938             }
 939         }
 940
 941         if(this.killindicator && !wasfreed(this.killindicator))
 942                 delete(this.killindicator);
 943
 944         this.killindicator = NULL;
 945
 946         if(this.killindicator_teamchange)
 947                 ClientKill_Now_TeamChange(this);
 948
 949         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 950         {
 951                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 952         }
 953
 954         // now I am sure the player IS dead
 955 }
 956 void KillIndicator_Think(entity this)
 957 {
 958         if (game_stopped)
 959         {
 960                 this.owner.killindicator = NULL;
 961                 delete(this);
 962                 return;
 963         }
 964
 965         if (this.owner.alpha < 0 && !this.owner.vehicle)
 966         {
 967                 this.owner.killindicator = NULL;
 968                 delete(this);
 969                 return;
 970         }
 971
 972         if(this.cnt <= 0)
 973         {
 974                 ClientKill_Now(this.owner);
 975                 return;
 976         }
 977     else if(this.count == 1) // count == 1 means that it's silent
 978     {
 979         this.nextthink = time + 1;
 980         this.cnt -= 1;
 981     }
 982         else
 983         {
 984                 if(this.cnt <= 10)
 985                         setmodel(this, MDL_NUM(this.cnt));
 986                 if(IS_REAL_CLIENT(this.owner))
 987                 {
 988                         if(this.cnt <= 10)
 989                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 990                 }
 991                 this.nextthink = time + 1;
 992                 this.cnt -= 1;
 993         }
 994 }
 995
 996 float clientkilltime;
 997 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 998 {
 999         float killtime;
1000         float starttime;
1001
1002         if (game_stopped)
1003                 return;
1004
1005         killtime = autocvar_g_balance_kill_delay;
1006
1007     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1008         return;
1009     killtime = M_ARGV(1, float);
1010
1011         this.killindicator_teamchange = targetteam;
1012
1013     if(!this.killindicator)
1014         {
1015                 if(!IS_DEAD(this))
1016                 {
1017                         killtime = max(killtime, this.clientkill_nexttime - time);
1018                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1019                 }
1020
1021                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1022                 {
1023                         ClientKill_Now(this);
1024                 }
1025                 else
1026                 {
1027                         starttime = max(time, clientkilltime);
1028
1029                         this.killindicator = spawn();
1030                         this.killindicator.owner = this;
1031                         this.killindicator.scale = 0.5;
1032                         setattachment(this.killindicator, this, "");
1033                         setorigin(this.killindicator, '0 0 52');
1034                         setthink(this.killindicator, KillIndicator_Think);
1035                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1036                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1037                         this.killindicator.cnt = ceil(killtime);
1038                         this.killindicator.count = bound(0, ceil(killtime), 10);
1039                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1040
1041                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1042                         {
1043                                 it.killindicator = spawn();
1044                                 it.killindicator.owner = it;
1045                                 it.killindicator.scale = 0.5;
1046                                 setattachment(it.killindicator, it, "");
1047                                 setorigin(it.killindicator, '0 0 52');
1048                                 setthink(it.killindicator, KillIndicator_Think);
1049                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1050                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1051                                 it.killindicator.cnt = ceil(killtime);
1052                         });
1053                         this.lip = 0;
1054                 }
1055         }
1056         if(this.killindicator)
1057         {
1058                 if(targetteam == 0) // just die
1059                 {
1060                         this.killindicator.colormod = '0 0 0';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1064                 }
1065                 else if(targetteam == -1) // auto
1066                 {
1067                         this.killindicator.colormod = '0 1 0';
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1071                 }
1072                 else if(targetteam == -2) // spectate
1073                 {
1074                         this.killindicator.colormod = '0.5 0.5 0.5';
1075                         if(IS_REAL_CLIENT(this))
1076                         if(this.killindicator.cnt > 0)
1077                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1078                 }
1079                 else
1080                 {
1081                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1082                         if(IS_REAL_CLIENT(this))
1083                         if(this.killindicator.cnt > 0)
1084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1085                 }
1086         }
1087
1088 }
1089
1090 void ClientKill (entity this)
1091 {
1092         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1093
1094         if(game_stopped) return;
1095         if(this.player_blocked) return;
1096         if(STAT(FROZEN, this)) return;
1097
1098         ClientKill_TeamChange(this, 0);
1099 }
1100
1101 void FixClientCvars(entity e)
1102 {
1103         // send prediction settings to the client
1104         stuffcmd(e, "\nin_bindmap 0 0\n");
1105         if(autocvar_g_antilag == 3) // client side hitscan
1106                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1107         if(autocvar_sv_gentle)
1108                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1109
1110         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1111         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1112
1113         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1114
1115         MUTATOR_CALLHOOK(FixClientCvars, e);
1116 }
1117
1118 bool findinlist_abbrev(string tofind, string list)
1119 {
1120         if(list == "" || tofind == "")
1121                 return false; // empty list or search, just return
1122
1123         // this function allows abbreviated strings!
1124         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1125         {
1126                 return true;
1127         });
1128
1129         return false;
1130 }
1131
1132 bool PlayerInIPList(entity p, string iplist)
1133 {
1134         // some safety checks (never allow local?)
1135         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1136                 return false;
1137
1138         return findinlist_abbrev(p.netaddress, iplist);
1139 }
1140
1141 bool PlayerInIDList(entity p, string idlist)
1142 {
1143         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1144         if(!p.crypto_idfp)
1145                 return false;
1146
1147         return findinlist_abbrev(p.crypto_idfp, idlist);
1148 }
1149
1150 bool PlayerInList(entity player, string list)
1151 {
1152         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1153 }
1154
1155 #ifdef DP_EXT_PRECONNECT
1156 /*
1157 =============
1158 ClientPreConnect
1159
1160 Called once (not at each match start) when a client begins a connection to the server
1161 =============
1162 */
1163 void ClientPreConnect(entity this)
1164 {
1165         if(autocvar_sv_eventlog)
1166         {
1167                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1168                         this.playerid,
1169                         etof(this),
1170                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1171                 ));
1172         }
1173 }
1174 #endif
1175
1176 /**
1177 =============
1178 ClientConnect
1179
1180 Called when a client connects to the server
1181 =============
1182 */
1183 void ClientConnect(entity this)
1184 {
1185         if (Ban_MaybeEnforceBanOnce(this)) return;
1186         assert(!IS_CLIENT(this), return);
1187         this.flags |= FL_CLIENT;
1188         assert(player_count >= 0, player_count = 0);
1189
1190 #ifdef WATERMARK
1191         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1192 #endif
1193         TRANSMUTE(Client, this);
1194         CS(this).version_nagtime = time + 10 + random() * 10;
1195
1196         // identify the right forced team
1197         if (autocvar_g_campaign)
1198         {
1199                 if (IS_REAL_CLIENT(this)) // only players, not bots
1200                 {
1201                         switch (autocvar_g_campaign_forceteam)
1202                         {
1203                                 case 1: this.team_forced = NUM_TEAM_1; break;
1204                                 case 2: this.team_forced = NUM_TEAM_2; break;
1205                                 case 3: this.team_forced = NUM_TEAM_3; break;
1206                                 case 4: this.team_forced = NUM_TEAM_4; break;
1207                                 default: this.team_forced = 0;
1208                         }
1209                 }
1210         }
1211         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1212         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1213         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1214         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1215         else switch (autocvar_g_forced_team_otherwise)
1216         {
1217                 default: this.team_forced = 0; break;
1218                 case "red": this.team_forced = NUM_TEAM_1; break;
1219                 case "blue": this.team_forced = NUM_TEAM_2; break;
1220                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1221                 case "pink": this.team_forced = NUM_TEAM_4; break;
1222                 case "spectate":
1223                 case "spectator":
1224                         this.team_forced = -1;
1225                         break;
1226         }
1227         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1228
1229         int playerid_save = this.playerid;
1230         this.playerid = 0; // silent
1231         JoinBestTeam(this, false); // if the team number is valid, keep it
1232         this.playerid = playerid_save;
1233
1234         TRANSMUTE(Observer, this);
1235
1236         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1237
1238         // always track bots, don't ask for cl_allow_uidtracking
1239         if (IS_BOT_CLIENT(this))
1240                 PlayerStats_GameReport_AddPlayer(this);
1241         else
1242                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1243
1244         if (autocvar_sv_eventlog)
1245                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1246
1247         LogTeamchange(this.playerid, this.team, 1);
1248
1249         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1250
1251         if(teamplay && IS_PLAYER(this))
1252                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1253         else
1254                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1255
1256         stuffcmd(this, clientstuff, "\n");
1257         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1258
1259         FixClientCvars(this);
1260
1261         // get version info from player
1262         stuffcmd(this, "cmd clientversion $gameversion\n");
1263
1264         // notify about available teams
1265         if (teamplay)
1266         {
1267                 CheckAllowedTeams(this);
1268                 int t = 0;
1269                 if (c1 >= 0) t |= BIT(0);
1270                 if (c2 >= 0) t |= BIT(1);
1271                 if (c3 >= 0) t |= BIT(2);
1272                 if (c4 >= 0) t |= BIT(3);
1273                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1274         }
1275         else
1276         {
1277                 stuffcmd(this, "set _teams_available 0\n");
1278         }
1279
1280         bot_relinkplayerlist();
1281
1282         CS(this).spectatortime = time;
1283         if (blockSpectators)
1284         {
1285                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1286         }
1287
1288         CS(this).jointime = time;
1289
1290         if (IS_REAL_CLIENT(this))
1291         {
1292                 if (g_weaponarena_weapons == WEPSET(TUBA))
1293                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1294         }
1295
1296         if (!sv_foginterval && world.fog != "")
1297                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1298
1299         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1300                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1301                         send_CSQC_teamnagger();
1302
1303         CSQCMODEL_AUTOINIT(this);
1304
1305         CS(this).model_randomizer = random();
1306
1307         if (IS_REAL_CLIENT(this))
1308                 sv_notice_join(this);
1309
1310         // update physics stats (players can spawn before physics runs)
1311         Physics_UpdateStats(this);
1312
1313         IL_EACH(g_initforplayer, it.init_for_player, {
1314                 it.init_for_player(it, this);
1315         });
1316
1317         Handicap_Initialize(this);
1318
1319         MUTATOR_CALLHOOK(ClientConnect, this);
1320
1321         if (IS_REAL_CLIENT(this))
1322         {
1323                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1324                 {
1325                         CS(this).motd_actived_time = -1;
1326                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1327                 }
1328         }
1329 }
1330 /*
1331 =============
1332 ClientDisconnect
1333
1334 Called when a client disconnects from the server
1335 =============
1336 */
1337 .entity chatbubbleentity;
1338 void ClientDisconnect(entity this)
1339 {
1340         assert(IS_CLIENT(this), return);
1341
1342         PlayerStats_GameReport_FinalizePlayer(this);
1343         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1344         if (CS(this).active_minigame) part_minigame(this);
1345         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1346
1347         if (autocvar_sv_eventlog)
1348                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1349
1350         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1351
1352         if(IS_SPEC(this))
1353                 SetSpectatee(this, NULL);
1354
1355     MUTATOR_CALLHOOK(ClientDisconnect, this);
1356
1357         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1358         strfree(CS(this).weaponorder_byimpulse);
1359         ClientState_detach(this);
1360
1361         Portal_ClearAll(this);
1362
1363         Unfreeze(this);
1364
1365         RemoveGrapplingHooks(this);
1366
1367         // Here, everything has been done that requires this player to be a client.
1368
1369         this.flags &= ~FL_CLIENT;
1370
1371         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1372         if (this.killindicator) delete(this.killindicator);
1373
1374         WaypointSprite_PlayerGone(this);
1375
1376         bot_relinkplayerlist();
1377
1378         strfree(this.clientstatus);
1379         if (this.personal) delete(this.personal);
1380
1381         this.playerid = 0;
1382         ReadyCount();
1383         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1384
1385         ONREMOVE(this);
1386 }
1387
1388 void ChatBubbleThink(entity this)
1389 {
1390         this.nextthink = time;
1391         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1392         {
1393                 if(this.owner) // but why can that ever be NULL?
1394                         this.owner.chatbubbleentity = NULL;
1395                 delete(this);
1396                 return;
1397         }
1398
1399         this.mdl = "";
1400
1401         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1402         {
1403                 if ( CS(this.owner).active_minigame )
1404                         this.mdl = "models/sprites/minigame_busy.iqm";
1405                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1406                         this.mdl = "models/misc/chatbubble.spr";
1407         }
1408
1409         if ( this.model != this.mdl )
1410                 _setmodel(this, this.mdl);
1411
1412 }
1413
1414 void UpdateChatBubble(entity this)
1415 {
1416         if (this.alpha < 0)
1417                 return;
1418         // spawn a chatbubble entity if needed
1419         if (!this.chatbubbleentity)
1420         {
1421                 this.chatbubbleentity = new(chatbubbleentity);
1422                 this.chatbubbleentity.owner = this;
1423                 this.chatbubbleentity.exteriormodeltoclient = this;
1424                 setthink(this.chatbubbleentity, ChatBubbleThink);
1425                 this.chatbubbleentity.nextthink = time;
1426                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1427                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1428                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1429                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1430                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1431                 //this.chatbubbleentity.model = "";
1432                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1433         }
1434 }
1435
1436
1437 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1438 // added to the model skins
1439 /*void UpdateColorModHack()
1440 {
1441         float c;
1442         c = this.clientcolors & 15;
1443         // LordHavoc: only bothering to support white, green, red, yellow, blue
1444              if (!teamplay) this.colormod = '0 0 0';
1445         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1446         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1447         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1448         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1449         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1450         else this.colormod = '1 1 1';
1451 }*/
1452
1453 void respawn(entity this)
1454 {
1455         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1456         {
1457                 this.solid = SOLID_NOT;
1458                 this.takedamage = DAMAGE_NO;
1459                 set_movetype(this, MOVETYPE_FLY);
1460                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1461                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1462                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1463                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1464                 if(autocvar_g_respawn_ghosts_maxtime)
1465                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1466         }
1467
1468         CopyBody(this, 1);
1469
1470         this.effects |= EF_NODRAW; // prevent another CopyBody
1471         PutClientInServer(this);
1472 }
1473
1474 void PrintToChat(entity client, string text)
1475 {
1476         text = strcat("\{1}^7", text, "\n");
1477         sprint(client, text);
1478 }
1479
1480 void DebugPrintToChat(entity client, string text)
1481 {
1482         if (autocvar_developer)
1483         {
1484                 PrintToChat(client, text);
1485         }
1486 }
1487
1488 void PrintToChatAll(string text)
1489 {
1490         text = strcat("\{1}^7", text, "\n");
1491         bprint(text);
1492 }
1493
1494 void DebugPrintToChatAll(string text)
1495 {
1496         if (autocvar_developer)
1497         {
1498                 PrintToChatAll(text);
1499         }
1500 }
1501
1502 void PrintToChatTeam(int team_num, string text)
1503 {
1504         text = strcat("\{1}^7", text, "\n");
1505         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1506         {
1507                 if (it.team == team_num)
1508                 {
1509                         sprint(it, text);
1510                 }
1511         });
1512 }
1513
1514 void DebugPrintToChatTeam(int team_num, string text)
1515 {
1516         if (autocvar_developer)
1517         {
1518                 PrintToChatTeam(team_num, text);
1519         }
1520 }
1521
1522 void play_countdown(entity this, float finished, Sound samp)
1523 {
1524     TC(Sound, samp);
1525         if(IS_REAL_CLIENT(this))
1526                 if(floor(finished - time - frametime) != floor(finished - time))
1527                         if(finished - time < 6)
1528                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1529 }
1530
1531 void player_powerups(entity this)
1532 {
1533         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1534         int items_prev = this.items;
1535
1536         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1537                 this.modelflags |= MF_ROCKET;
1538         else
1539                 this.modelflags &= ~MF_ROCKET;
1540
1541         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1542
1543         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1544                 return;
1545
1546         Fire_ApplyDamage(this);
1547         Fire_ApplyEffect(this);
1548
1549         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1550         {
1551                 if (this.items & ITEM_Strength.m_itemid)
1552                 {
1553                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1554                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1555                         if (time > this.strength_finished)
1556                         {
1557                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1558                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1559                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1560                         }
1561                 }
1562                 else
1563                 {
1564                         if (time < this.strength_finished)
1565                         {
1566                                 this.items = this.items | ITEM_Strength.m_itemid;
1567                                 if(!g_cts)
1568                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1569                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1570                         }
1571                 }
1572                 if (this.items & ITEM_Shield.m_itemid)
1573                 {
1574                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1575                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1576                         if (time > this.invincible_finished)
1577                         {
1578                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1579                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1580                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1581                         }
1582                 }
1583                 else
1584                 {
1585                         if (time < this.invincible_finished)
1586                         {
1587                                 this.items = this.items | ITEM_Shield.m_itemid;
1588                                 if(!g_cts)
1589                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1590                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1591                         }
1592                 }
1593                 if (this.items & IT_SUPERWEAPON)
1594                 {
1595                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1596                         {
1597                                 this.superweapons_finished = 0;
1598                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1599                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1600                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1601                         }
1602                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1603                         {
1604                                 // don't let them run out
1605                         }
1606                         else
1607                         {
1608                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1609                                 if (time > this.superweapons_finished)
1610                                 {
1611                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1612                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1613                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1614                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1615                                 }
1616                         }
1617                 }
1618                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1619                 {
1620                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1621                         {
1622                                 this.items = this.items | IT_SUPERWEAPON;
1623                                 if(!g_cts)
1624                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1625                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1626                         }
1627                         else
1628                         {
1629                                 this.superweapons_finished = 0;
1630                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1631                         }
1632                 }
1633                 else
1634                 {
1635                         this.superweapons_finished = 0;
1636                 }
1637         }
1638
1639         if(autocvar_g_nodepthtestplayers)
1640                 this.effects = this.effects | EF_NODEPTHTEST;
1641
1642         if(autocvar_g_fullbrightplayers)
1643                 this.effects = this.effects | EF_FULLBRIGHT;
1644
1645         if (time >= game_starttime)
1646         if (time < this.spawnshieldtime)
1647                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1648
1649         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1650 }
1651
1652 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1653 {
1654         if(current > stable)
1655                 return current;
1656         else if(current > stable - 0.25) // when close enough, "snap"
1657                 return stable;
1658         else
1659                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1660 }
1661
1662 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1663 {
1664         if(current < stable)
1665                 return current;
1666         else if(current < stable + 0.25) // when close enough, "snap"
1667                 return stable;
1668         else
1669                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1670 }
1671
1672 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1673 {
1674         if(current > rotstable)
1675         {
1676                 if(rotframetime > 0)
1677                 {
1678                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1679                         current = max(rotstable, current - rotlinear * rotframetime);
1680                 }
1681         }
1682         else if(current < regenstable)
1683         {
1684                 if(regenframetime > 0)
1685                 {
1686                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1687                         current = min(regenstable, current + regenlinear * regenframetime);
1688                 }
1689         }
1690
1691         if(current > limit)
1692                 current = limit;
1693
1694         return current;
1695 }
1696
1697 void player_regen(entity this)
1698 {
1699         float max_mod, regen_mod, rot_mod, limit_mod;
1700         max_mod = regen_mod = rot_mod = limit_mod = 1;
1701
1702         float regen_health = autocvar_g_balance_health_regen;
1703         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1704         float regen_health_rot = autocvar_g_balance_health_rot;
1705         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1706         float regen_health_stable = autocvar_g_balance_health_regenstable;
1707         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1708         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1709                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1710         max_mod = M_ARGV(1, float);
1711         regen_mod = M_ARGV(2, float);
1712         rot_mod = M_ARGV(3, float);
1713         limit_mod = M_ARGV(4, float);
1714         regen_health = M_ARGV(5, float);
1715         regen_health_linear = M_ARGV(6, float);
1716         regen_health_rot = M_ARGV(7, float);
1717         regen_health_rotlinear = M_ARGV(8, float);
1718         regen_health_stable = M_ARGV(9, float);
1719         regen_health_rotstable = M_ARGV(10, float);
1720
1721         if(!mutator_returnvalue)
1722         if(!STAT(FROZEN, this))
1723         {
1724                 float mina, maxa, limith, limita;
1725                 maxa = autocvar_g_balance_armor_rotstable;
1726                 mina = autocvar_g_balance_armor_regenstable;
1727                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1728                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1729
1730                 regen_health_rotstable = regen_health_rotstable * max_mod;
1731                 regen_health_stable = regen_health_stable * max_mod;
1732                 limith = limith * limit_mod;
1733                 limita = limita * limit_mod;
1734
1735                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1736                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1737                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1738                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1739                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1740                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1741         }
1742
1743         // if player rotted to death...  die!
1744         // check this outside above checks, as player may still be able to rot to death
1745         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1746         {
1747                 if(this.vehicle)
1748                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1749                 if(this.event_damage)
1750                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1751         }
1752
1753         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1754         {
1755                 float minf, maxf, limitf;
1756
1757                 maxf = autocvar_g_balance_fuel_rotstable;
1758                 minf = autocvar_g_balance_fuel_regenstable;
1759                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1760
1761                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1762                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1763                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1764         }
1765 }
1766
1767 bool zoomstate_set;
1768 void SetZoomState(entity this, float newzoom)
1769 {
1770         if(newzoom != CS(this).zoomstate)
1771         {
1772                 CS(this).zoomstate = newzoom;
1773                 ClientData_Touch(this);
1774         }
1775         zoomstate_set = true;
1776 }
1777
1778 void GetPressedKeys(entity this)
1779 {
1780         MUTATOR_CALLHOOK(GetPressedKeys, this);
1781         int keys = STAT(PRESSED_KEYS, this);
1782         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1783         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1784         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1785         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1786
1787         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1788         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1789         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1790         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1791         CS(this).pressedkeys = keys; // store for other users
1792
1793         STAT(PRESSED_KEYS, this) = keys;
1794 }
1795
1796 /*
1797 ======================
1798 spectate mode routines
1799 ======================
1800 */
1801
1802 void SpectateCopy(entity this, entity spectatee)
1803 {
1804     TC(Client, this); TC(Client, spectatee);
1805
1806         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1807         PS(this) = PS(spectatee);
1808         this.armortype = spectatee.armortype;
1809         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1810         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1811         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1812         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1813         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1814         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1815         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1816         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1817         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1818         CS(this).impulse = 0;
1819         this.items = spectatee.items;
1820         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1821         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1822         this.strength_finished = spectatee.strength_finished;
1823         this.invincible_finished = spectatee.invincible_finished;
1824         this.superweapons_finished = spectatee.superweapons_finished;
1825         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1826         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1827         this.punchangle = spectatee.punchangle;
1828         this.view_ofs = spectatee.view_ofs;
1829         this.velocity = spectatee.velocity;
1830         this.dmg_take = spectatee.dmg_take;
1831         this.dmg_save = spectatee.dmg_save;
1832         this.dmg_inflictor = spectatee.dmg_inflictor;
1833         this.v_angle = spectatee.v_angle;
1834         this.angles = spectatee.v_angle;
1835         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1836         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1837         this.viewloc = spectatee.viewloc;
1838         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1839                 this.fixangle = true;
1840         setorigin(this, spectatee.origin);
1841         setsize(this, spectatee.mins, spectatee.maxs);
1842         SetZoomState(this, CS(spectatee).zoomstate);
1843
1844     anticheat_spectatecopy(this, spectatee);
1845         STAT(HUD, this) = STAT(HUD, spectatee);
1846         if(spectatee.vehicle)
1847     {
1848         this.angles = spectatee.v_angle;
1849
1850         //this.fixangle = false;
1851         //this.velocity = spectatee.vehicle.velocity;
1852         this.vehicle_health = spectatee.vehicle_health;
1853         this.vehicle_shield = spectatee.vehicle_shield;
1854         this.vehicle_energy = spectatee.vehicle_energy;
1855         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1856         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1857         this.vehicle_reload1 = spectatee.vehicle_reload1;
1858         this.vehicle_reload2 = spectatee.vehicle_reload2;
1859
1860         //msg_entity = this;
1861
1862        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1863             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1864            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1865            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1866
1867         //WriteByte (MSG_ONE, SVC_SETVIEW);
1868         //    WriteEntity(MSG_ONE, this);
1869         //makevectors(spectatee.v_angle);
1870         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1871     }
1872 }
1873
1874 bool SpectateUpdate(entity this)
1875 {
1876         if(!this.enemy)
1877                 return false;
1878
1879         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1880         {
1881                 SetSpectatee(this, NULL);
1882                 return false;
1883         }
1884
1885         SpectateCopy(this, this.enemy);
1886
1887         return true;
1888 }
1889
1890 bool SpectateSet(entity this)
1891 {
1892         if(!IS_PLAYER(this.enemy))
1893                 return false;
1894
1895         ClientData_Touch(this.enemy);
1896
1897         msg_entity = this;
1898         WriteByte(MSG_ONE, SVC_SETVIEW);
1899         WriteEntity(MSG_ONE, this.enemy);
1900         set_movetype(this, MOVETYPE_NONE);
1901         accuracy_resend(this);
1902
1903         if(!SpectateUpdate(this))
1904                 PutObserverInServer(this);
1905
1906         return true;
1907 }
1908
1909 void SetSpectatee_status(entity this, int spectatee_num)
1910 {
1911         int oldspectatee_status = CS(this).spectatee_status;
1912         CS(this).spectatee_status = spectatee_num;
1913
1914         if (CS(this).spectatee_status != oldspectatee_status)
1915         {
1916                 ClientData_Touch(this);
1917                 if (g_race || g_cts) race_InitSpectator();
1918         }
1919 }
1920
1921 void SetSpectatee(entity this, entity spectatee)
1922 {
1923         if(IS_BOT_CLIENT(this))
1924                 return; // bots abuse .enemy, this code is useless to them
1925
1926         entity old_spectatee = this.enemy;
1927
1928         this.enemy = spectatee;
1929
1930         // WEAPONTODO
1931         // these are required to fix the spectator bug with arc
1932         if(old_spectatee)
1933         {
1934                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1935                 {
1936                         .entity weaponentity = weaponentities[slot];
1937                         if(old_spectatee.(weaponentity).arc_beam)
1938                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1939                 }
1940         }
1941         if(this.enemy)
1942         {
1943                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1944                 {
1945                         .entity weaponentity = weaponentities[slot];
1946                         if(this.enemy.(weaponentity).arc_beam)
1947                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1948                 }
1949         }
1950
1951         if (this.enemy)
1952                 SetSpectatee_status(this, etof(this.enemy));
1953
1954         // needed to update spectator list
1955         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1956 }
1957
1958 bool Spectate(entity this, entity pl)
1959 {
1960         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1961                 return false;
1962         pl = M_ARGV(1, entity);
1963
1964         SetSpectatee(this, pl);
1965         return SpectateSet(this);
1966 }
1967
1968 bool SpectateNext(entity this)
1969 {
1970         entity ent = find(this.enemy, classname, STR_PLAYER);
1971
1972         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1973                 ent = M_ARGV(1, entity);
1974         else if (!ent)
1975                 ent = find(ent, classname, STR_PLAYER);
1976
1977         if(ent) { SetSpectatee(this, ent); }
1978
1979         return SpectateSet(this);
1980 }
1981
1982 bool SpectatePrev(entity this)
1983 {
1984         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1985         entity ent = findchain(classname, STR_PLAYER);
1986         if (!ent) // no player
1987                 return false;
1988
1989         entity first = ent;
1990         // skip players until current spectated player
1991         if(this.enemy)
1992         while(ent && ent != this.enemy)
1993                 ent = ent.chain;
1994
1995         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1996         {
1997                 case MUT_SPECPREV_FOUND:
1998                     ent = M_ARGV(1, entity);
1999                     break;
2000                 case MUT_SPECPREV_RETURN:
2001                     return true;
2002                 case MUT_SPECPREV_CONTINUE:
2003                 default:
2004                 {
2005                         if(ent.chain)
2006                                 ent = ent.chain;
2007                         else
2008                                 ent = first;
2009                         break;
2010                 }
2011         }
2012
2013         SetSpectatee(this, ent);
2014         return SpectateSet(this);
2015 }
2016
2017 /*
2018 =============
2019 ShowRespawnCountdown()
2020
2021 Update a respawn countdown display.
2022 =============
2023 */
2024 void ShowRespawnCountdown(entity this)
2025 {
2026         float number;
2027         if(!IS_DEAD(this)) // just respawned?
2028                 return;
2029         else
2030         {
2031                 number = ceil(this.respawn_time - time);
2032                 if(number <= 0)
2033                         return;
2034                 if(number <= this.respawn_countdown)
2035                 {
2036                         this.respawn_countdown = number - 1;
2037                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2038                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2039                 }
2040         }
2041 }
2042
2043 .bool team_selected;
2044 bool ShowTeamSelection(entity this)
2045 {
2046         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2047                 return false;
2048         stuffcmd(this, "menu_showteamselect\n");
2049         return true;
2050 }
2051 void Join(entity this)
2052 {
2053         TRANSMUTE(Player, this);
2054
2055         if(!this.team_selected)
2056         if(autocvar_g_campaign || autocvar_g_balance_teams)
2057                 JoinBestTeam(this, true);
2058
2059         if(autocvar_g_campaign)
2060                 campaign_bots_may_start = true;
2061
2062         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2063
2064         PutClientInServer(this);
2065
2066         if(IS_PLAYER(this))
2067         if(teamplay && this.team != -1)
2068                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2069         else
2070                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2071         this.team_selected = false;
2072 }
2073
2074 /**
2075  * Determines whether the player is allowed to join. This depends on cvar
2076  * g_maxplayers, if it isn't used this function always return true, otherwise
2077  * it checks whether the number of currently playing players exceeds g_maxplayers.
2078  * @return int number of free slots for players, 0 if none
2079  */
2080 int nJoinAllowed(entity this, entity ignore)
2081 {
2082         if(!ignore)
2083         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2084         // so report 0 free slots if restricted
2085         {
2086                 if(autocvar_g_forced_team_otherwise == "spectate")
2087                         return 0;
2088                 if(autocvar_g_forced_team_otherwise == "spectator")
2089                         return 0;
2090         }
2091
2092         if(this && this.team_forced < 0)
2093                 return 0; // forced spectators can never join
2094
2095         // TODO simplify this
2096         int totalClients = 0;
2097         int currentlyPlaying = 0;
2098         FOREACH_CLIENT(true, {
2099                 if(it != ignore)
2100                         ++totalClients;
2101                 if(IS_REAL_CLIENT(it))
2102                 if(IS_PLAYER(it) || it.caplayer)
2103                         ++currentlyPlaying;
2104         });
2105
2106         float free_slots = 0;
2107         if (!autocvar_g_maxplayers)
2108                 free_slots = maxclients - totalClients;
2109         else if(currentlyPlaying < autocvar_g_maxplayers)
2110                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2111
2112         static float join_prevent_msg_time = 0;
2113         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2114         {
2115                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2116                 join_prevent_msg_time = time + 3;
2117         }
2118
2119         return free_slots;
2120 }
2121
2122 /**
2123  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2124  * g_maxplayers_spectator_blocktime seconds
2125  */
2126 void checkSpectatorBlock(entity this)
2127 {
2128         if(IS_SPEC(this) || IS_OBSERVER(this))
2129         if(!this.caplayer)
2130         if(IS_REAL_CLIENT(this))
2131         {
2132                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2133                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2134                         dropclient(this);
2135                 }
2136         }
2137 }
2138
2139 void PrintWelcomeMessage(entity this)
2140 {
2141         if(CS(this).motd_actived_time == 0)
2142         {
2143                 if (autocvar_g_campaign) {
2144                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2145                                 CS(this).motd_actived_time = time;
2146                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2147                         }
2148                 } else {
2149                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2150                                 CS(this).motd_actived_time = time;
2151                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2152                         }
2153                 }
2154         }
2155         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2156         {
2157                 if (autocvar_g_campaign) {
2158                         if (PHYS_INPUT_BUTTON_INFO(this))
2159                                 CS(this).motd_actived_time = time;
2160                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2161                                 CS(this).motd_actived_time = 0;
2162                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2163                         }
2164                 } else {
2165                         if (PHYS_INPUT_BUTTON_INFO(this))
2166                                 CS(this).motd_actived_time = time;
2167                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2168                                 CS(this).motd_actived_time = 0;
2169                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2170                         }
2171                 }
2172         }
2173         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2174         {
2175                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2176                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2177                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2178                 {
2179                         // instanctly hide MOTD
2180                         CS(this).motd_actived_time = 0;
2181                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2182                 }
2183         }
2184 }
2185
2186 const int MIN_SPEC_TIME = 1;
2187 bool joinAllowed(entity this)
2188 {
2189         if (CS(this).version_mismatch) return false;
2190         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2191         if (!nJoinAllowed(this, this)) return false;
2192         if (teamplay && lockteams) return false;
2193         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2194         if (ShowTeamSelection(this)) return false;
2195         return true;
2196 }
2197
2198 .int items_added;
2199 .string shootfromfixedorigin;
2200 bool PlayerThink(entity this)
2201 {
2202         if (game_stopped || intermission_running) {
2203                 this.modelflags &= ~MF_ROCKET;
2204                 if(intermission_running)
2205                         IntermissionThink(this);
2206                 return false;
2207         }
2208
2209         if (timeout_status == TIMEOUT_ACTIVE) {
2210         // don't allow the player to turn around while game is paused
2211                 // FIXME turn this into CSQC stuff
2212                 this.v_angle = this.lastV_angle;
2213                 this.angles = this.lastV_angle;
2214                 this.fixangle = true;
2215         }
2216
2217         if (frametime) player_powerups(this);
2218
2219         if (IS_DEAD(this)) {
2220                 if (this.personal && g_race_qualifying) {
2221                         if (time > this.respawn_time) {
2222                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2223                                 respawn(this);
2224                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2225                         }
2226                 } else {
2227                         if (frametime) player_anim(this);
2228
2229                         if (this.respawn_flags & RESPAWN_DENY)
2230                         {
2231                                 STAT(RESPAWN_TIME, this) = 0;
2232                                 return false;
2233                         }
2234
2235                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2236
2237                         switch(this.deadflag)
2238                         {
2239                                 case DEAD_DYING:
2240                                 {
2241                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2242                                                 this.deadflag = DEAD_RESPAWNING;
2243                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2244                                                 this.deadflag = DEAD_DEAD;
2245                                         break;
2246                                 }
2247                                 case DEAD_DEAD:
2248                                 {
2249                                         if (button_pressed)
2250                                                 this.deadflag = DEAD_RESPAWNABLE;
2251                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2252                                                 this.deadflag = DEAD_RESPAWNING;
2253                                         break;
2254                                 }
2255                                 case DEAD_RESPAWNABLE:
2256                                 {
2257                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2258                                                 this.deadflag = DEAD_RESPAWNING;
2259                                         break;
2260                                 }
2261                                 case DEAD_RESPAWNING:
2262                                 {
2263                                         if (time > this.respawn_time)
2264                                         {
2265                                                 this.respawn_time = time + 1; // only retry once a second
2266                                                 this.respawn_time_max = this.respawn_time;
2267                                                 respawn(this);
2268                                         }
2269                                         break;
2270                                 }
2271                         }
2272
2273                         ShowRespawnCountdown(this);
2274
2275                         if (this.respawn_flags & RESPAWN_SILENT)
2276                                 STAT(RESPAWN_TIME, this) = 0;
2277                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2278                         {
2279                                 if (time < this.respawn_time)
2280                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2281                                 else if (this.deadflag != DEAD_RESPAWNING)
2282                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2283                         }
2284                         else
2285                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2286                 }
2287
2288                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2289                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2290                         STAT(RESPAWN_TIME, this) *= -1;
2291
2292                 return false;
2293         }
2294
2295         FixPlayermodel(this);
2296
2297         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2298                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2299                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2300         }
2301
2302         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2303         //if(frametime)
2304         {
2305                 this.items &= ~this.items_added;
2306
2307                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2308                 {
2309                         .entity weaponentity = weaponentities[slot];
2310                         W_WeaponFrame(this, weaponentity);
2311                 }
2312
2313                 this.items_added = 0;
2314                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2315             this.items_added |= IT_FUEL;
2316
2317                 this.items |= this.items_added;
2318         }
2319
2320         player_regen(this);
2321
2322         // WEAPONTODO: Add a weapon request for this
2323         // rot vortex charge to the charge limit
2324         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2325         {
2326                 .entity weaponentity = weaponentities[slot];
2327                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2328                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2329         }
2330
2331         if (frametime) player_anim(this);
2332
2333         // secret status
2334         secrets_setstatus(this);
2335
2336         // monsters status
2337         monsters_setstatus(this);
2338
2339         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2340
2341         return true;
2342 }
2343
2344 .bool would_spectate;
2345 void ObserverThink(entity this)
2346 {
2347         if ( CS(this).impulse )
2348         {
2349                 MinigameImpulse(this, CS(this).impulse);
2350                 CS(this).impulse = 0;
2351         }
2352
2353         if (this.flags & FL_JUMPRELEASED) {
2354                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2355                         this.flags &= ~FL_JUMPRELEASED;
2356                         this.flags |= FL_SPAWNING;
2357                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2358                         this.flags &= ~FL_JUMPRELEASED;
2359                         if(SpectateNext(this)) {
2360                                 TRANSMUTE(Spectator, this);
2361                         }
2362                 } else {
2363                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2364                         set_movetype(this, preferred_movetype);
2365                 }
2366         } else {
2367                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2368                         this.flags |= FL_JUMPRELEASED;
2369                         if(this.flags & FL_SPAWNING)
2370                         {
2371                                 this.flags &= ~FL_SPAWNING;
2372                                 Join(this);
2373                                 return;
2374                         }
2375                 }
2376         }
2377 }
2378
2379 void SpectatorThink(entity this)
2380 {
2381         if ( CS(this).impulse )
2382         {
2383                 if(MinigameImpulse(this, CS(this).impulse))
2384                         CS(this).impulse = 0;
2385
2386                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2387                 {
2388                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2389                         CS(this).impulse = 0;
2390                         return;
2391                 }
2392         }
2393
2394         if (this.flags & FL_JUMPRELEASED) {
2395                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2396                         this.flags &= ~FL_JUMPRELEASED;
2397                         this.flags |= FL_SPAWNING;
2398                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2399                         this.flags &= ~FL_JUMPRELEASED;
2400                         if(SpectateNext(this)) {
2401                                 TRANSMUTE(Spectator, this);
2402                         } else {
2403                                 TRANSMUTE(Observer, this);
2404                                 PutClientInServer(this);
2405                         }
2406                         CS(this).impulse = 0;
2407                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2408                         this.flags &= ~FL_JUMPRELEASED;
2409                         if(SpectatePrev(this)) {
2410                                 TRANSMUTE(Spectator, this);
2411                         } else {
2412                                 TRANSMUTE(Observer, this);
2413                                 PutClientInServer(this);
2414                         }
2415                         CS(this).impulse = 0;
2416                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2417                         this.would_spectate = false;
2418                         this.flags &= ~FL_JUMPRELEASED;
2419                         TRANSMUTE(Observer, this);
2420                         PutClientInServer(this);
2421                 } else {
2422                         if(!SpectateUpdate(this))
2423                         {
2424                                 if(!SpectateNext(this))
2425                                 {
2426                                         PutObserverInServer(this);
2427                                         this.would_spectate = true;
2428                                 }
2429                         }
2430                 }
2431         } else {
2432                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2433                         this.flags |= FL_JUMPRELEASED;
2434                         if(this.flags & FL_SPAWNING)
2435                         {
2436                                 this.flags &= ~FL_SPAWNING;
2437                                 Join(this);
2438                                 return;
2439                         }
2440                 }
2441                 if(!SpectateUpdate(this))
2442                         PutObserverInServer(this);
2443         }
2444
2445         this.flags |= FL_CLIENT | FL_NOTARGET;
2446 }
2447
2448 void PlayerUseKey(entity this)
2449 {
2450         if (!IS_PLAYER(this))
2451                 return;
2452
2453         if(this.vehicle)
2454         {
2455                 if(!game_stopped)
2456                 {
2457                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2458                         return;
2459                 }
2460         }
2461         else if(autocvar_g_vehicles_enter)
2462         {
2463                 if(!STAT(FROZEN, this))
2464                 if(!IS_DEAD(this))
2465                 if(!game_stopped)
2466                 {
2467                         entity head, closest_target = NULL;
2468                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2469
2470                         while(head) // find the closest acceptable target to enter
2471                         {
2472                                 if(IS_VEHICLE(head))
2473                                 if(!IS_DEAD(head))
2474                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2475                                 if(head.takedamage != DAMAGE_NO)
2476                                 {
2477                                         if(closest_target)
2478                                         {
2479                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2480                                                 { closest_target = head; }
2481                                         }
2482                                         else { closest_target = head; }
2483                                 }
2484
2485                                 head = head.chain;
2486                         }
2487
2488                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2489                 }
2490         }
2491
2492         // a use key was pressed; call handlers
2493         MUTATOR_CALLHOOK(PlayerUseKey, this);
2494 }
2495
2496
2497 /*
2498 =============
2499 PlayerPreThink
2500
2501 Called every frame for each client before the physics are run
2502 =============
2503 */
2504 .float last_vehiclecheck;
2505 void PlayerPreThink (entity this)
2506 {
2507         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2508         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2509
2510         WarpZone_PlayerPhysics_FixVAngle(this);
2511
2512         if (frametime) {
2513                 // physics frames: update anticheat stuff
2514                 anticheat_prethink(this);
2515         }
2516
2517         if (blockSpectators && frametime) {
2518                 // WORKAROUND: only use dropclient in server frames (frametime set).
2519                 // Never use it in cl_movement frames (frametime zero).
2520                 checkSpectatorBlock(this);
2521         }
2522
2523         zoomstate_set = false;
2524
2525         // Check for nameless players
2526         if (this.netname == "" || this.netname != CS(this).netname_previous)
2527         {
2528                 bool assume_unchanged = (CS(this).netname_previous == "");
2529                 if (isInvisibleString(this.netname))
2530                 {
2531                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2532                         assume_unchanged = false;
2533                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2534                 }
2535                 if (!assume_unchanged && autocvar_sv_eventlog)
2536                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2537                 strcpy(CS(this).netname_previous, this.netname);
2538         }
2539
2540         // version nagging
2541         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2542         CS(this).version_nagtime = 0;
2543         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2544             // git client
2545         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2546             // git server
2547             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2548         } else {
2549             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2550             if (r < 0) { // old client
2551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2552             } else if (r > 0) { // old server
2553                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554             }
2555         }
2556     }
2557
2558         // GOD MODE info
2559         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2560         {
2561                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2562                 this.max_armorvalue = 0;
2563         }
2564
2565         if(IS_PLAYER(this))
2566         {
2567                 if (STAT(FROZEN, this) == 2)
2568                 {
2569                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2570                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2571                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2572
2573                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2574                                 Unfreeze(this);
2575                 }
2576                 else if (STAT(FROZEN, this) == 3)
2577                 {
2578                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2579                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2580
2581                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2582                         {
2583                                 if (this.vehicle)
2584                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2585                                 if(this.event_damage)
2586                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2587                         }
2588                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2589                                 Unfreeze(this);
2590                 }
2591         }
2592
2593         MUTATOR_CALLHOOK(PlayerPreThink, this);
2594
2595         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2596         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2597         {
2598                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2599                 {
2600                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2601                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2602                         {
2603                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2604                         }
2605                         else if(!it.owner)
2606                         {
2607                                 if(!it.team || SAME_TEAM(this, it))
2608                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2609                                 else if(autocvar_g_vehicles_steal)
2610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2611                         }
2612                 });
2613
2614                 this.last_vehiclecheck = time + 1;
2615         }
2616
2617         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2618         {
2619                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2620                         PlayerUseKey(this);
2621                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2622         }
2623
2624         if (IS_REAL_CLIENT(this))
2625                 PrintWelcomeMessage(this);
2626
2627         if (IS_PLAYER(this)) {
2628                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2629                         error("Client can't be spawned as player on connection!");
2630                 if(!PlayerThink(this))
2631                         return;
2632         }
2633         else if (game_stopped || intermission_running) {
2634                 if(intermission_running)
2635                         IntermissionThink(this);
2636                 return;
2637         }
2638         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2639         {
2640                 CS(this).autojoin_checked = true;
2641                 // don't do this in ClientConnect
2642                 // many things can go wrong if a client is spawned as player on connection
2643                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2644                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2645                                 && (!teamplay || autocvar_g_balance_teams)))
2646                 {
2647                         campaign_bots_may_start = true;
2648                         Join(this);
2649                         return;
2650                 }
2651         }
2652         else if (IS_OBSERVER(this)) {
2653                 ObserverThink(this);
2654         }
2655         else if (IS_SPEC(this)) {
2656                 SpectatorThink(this);
2657         }
2658
2659         // WEAPONTODO: Add weapon request for this
2660         if (!zoomstate_set) {
2661                 bool wep_zoomed = false;
2662                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2663                 {
2664                         .entity weaponentity = weaponentities[slot];
2665                         Weapon thiswep = this.(weaponentity).m_weapon;
2666                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2667                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2668                 }
2669                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2670     }
2671
2672         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2673         {
2674                 CS(this).teamkill_soundtime = 0;
2675
2676                 entity e = CS(this).teamkill_soundsource;
2677                 entity oldpusher = e.pusher;
2678                 e.pusher = this;
2679                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2680                 e.pusher = oldpusher;
2681         }
2682
2683         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2684                 CS(this).taunt_soundtime = 0;
2685                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2686         }
2687
2688         target_voicescript_next(this);
2689
2690         // WEAPONTODO: Move into weaponsystem somehow
2691         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2692         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2693         {
2694                 .entity weaponentity = weaponentities[slot];
2695                 if(this.(weaponentity).m_weapon == WEP_Null)
2696                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2697         }
2698 }
2699
2700 void DrownPlayer(entity this)
2701 {
2702         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2703                 return;
2704
2705         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2706         {
2707                 if(this.air_finished < time)
2708                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2709                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2710         }
2711         else if (this.air_finished < time)
2712         {       // drown!
2713                 if (this.pain_finished < time)
2714                 {
2715                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2716                         this.pain_finished = time + 0.5;
2717                 }
2718         }
2719 }
2720
2721 .bool move_qcphysics;
2722
2723 void Player_Physics(entity this)
2724 {
2725         set_movetype(this, this.move_movetype);
2726
2727         if(!this.move_qcphysics)
2728                 return;
2729
2730         if(!frametime && !CS(this).pm_frametime)
2731                 return;
2732
2733         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2734
2735         CS(this).pm_frametime = 0;
2736 }
2737
2738 /*
2739 =============
2740 PlayerPostThink
2741
2742 Called every frame for each client after the physics are run
2743 =============
2744 */
2745 void PlayerPostThink (entity this)
2746 {
2747         Player_Physics(this);
2748
2749         if (sv_maxidle > 0)
2750         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2751         if (IS_REAL_CLIENT(this))
2752         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2753         {
2754                 int totalClients = 0;
2755                 if(sv_maxidle_slots > 0)
2756                 {
2757                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2758                         {
2759                                 ++totalClients;
2760                         });
2761                 }
2762
2763                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2764                 { /* do nothing */ }
2765                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2766                 {
2767                         if (CS(this).idlekick_lasttimeleft)
2768                         {
2769                                 CS(this).idlekick_lasttimeleft = 0;
2770                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2771                         }
2772                 }
2773                 else
2774                 {
2775                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2776                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2777                                 if (!CS(this).idlekick_lasttimeleft)
2778                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2779                         }
2780                         if (timeleft <= 0) {
2781                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2782                                 dropclient(this);
2783                                 return;
2784                         }
2785                         else if (timeleft <= 10) {
2786                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2787                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2788                 }
2789                                 CS(this).idlekick_lasttimeleft = timeleft;
2790                         }
2791                 }
2792         }
2793
2794         CheatFrame(this);
2795
2796         if (game_stopped)
2797         {
2798                 this.solid = SOLID_NOT;
2799                 this.takedamage = DAMAGE_NO;
2800                 set_movetype(this, MOVETYPE_NONE);
2801         }
2802
2803         if (IS_PLAYER(this)) {
2804                 if(this.death_time == time && IS_DEAD(this))
2805                 {
2806                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2807                         // once all the damage events of this frame have been processed with normal size
2808                         this.maxs.z = 5;
2809                         setsize(this, this.mins, this.maxs);
2810                 }
2811                 DrownPlayer(this);
2812                 UpdateChatBubble(this);
2813                 if (CS(this).impulse) ImpulseCommands(this);
2814                 if (game_stopped)
2815                 {
2816                         CSQCMODEL_AUTOUPDATE(this);
2817                         return;
2818                 }
2819                 GetPressedKeys(this);
2820         }
2821
2822         if (this.waypointsprite_attachedforcarrier) {
2823             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2824                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2825     }
2826
2827         CSQCMODEL_AUTOUPDATE(this);
2828 }
2829
2830 // hack to copy the button fields from the client entity to the Client State
2831 void PM_UpdateButtons(entity this, entity store)
2832 {
2833         if(this.impulse)
2834                 store.impulse = this.impulse;
2835         this.impulse = 0;
2836
2837         bool typing = this.buttonchat;
2838
2839         store.button0 = (typing) ? 0 : this.button0;
2840         //button1?!
2841         store.button2 = (typing) ? 0 : this.button2;
2842         store.button3 = (typing) ? 0 : this.button3;
2843         store.button4 = this.button4;
2844         store.button5 = (typing) ? 0 : this.button5;
2845         store.button6 = this.button6;
2846         store.button7 = this.button7;
2847         store.button8 = this.button8;
2848         store.button9 = this.button9;
2849         store.button10 = this.button10;
2850         store.button11 = this.button11;
2851         store.button12 = this.button12;
2852         store.button13 = this.button13;
2853         store.button14 = this.button14;
2854         store.button15 = this.button15;
2855         store.button16 = this.button16;
2856         store.buttonuse = this.buttonuse;
2857         store.buttonchat = this.buttonchat;
2858
2859         store.cursor_active = this.cursor_active;
2860         store.cursor_screen = this.cursor_screen;
2861         store.cursor_trace_start = this.cursor_trace_start;
2862         store.cursor_trace_endpos = this.cursor_trace_endpos;
2863         store.cursor_trace_ent = this.cursor_trace_ent;
2864
2865         store.ping = this.ping;
2866         store.ping_packetloss = this.ping_packetloss;
2867         store.ping_movementloss = this.ping_movementloss;
2868
2869         store.v_angle = this.v_angle;
2870         store.movement = (typing) ? '0 0 0' : this.movement;
2871 }
2872
2873 NET_HANDLE(fpsreport, bool)
2874 {
2875         int fps = ReadShort();
2876         PlayerScore_Set(sender, SP_FPS, fps);
2877         return true;
2878 }