qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/_mod.qh"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     ClientConnect(this);
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     PutClientInServer(this);
  63 }
  64
  65 void PutObserverInServer(entity this);
  66
  67 STATIC_METHOD(Client, Remove, void(Client this))
  68 {
  69     TRANSMUTE(Observer, this);
  70     PutClientInServer(this);
  71     ClientDisconnect(this);
  72 }
  73
  74 void send_CSQC_teamnagger() {
  75         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  76 }
  77
  78 int CountSpectators(entity player, entity to)
  79 {
  80         if(!player) { return 0; } // not sure how, but best to be safe
  81
  82         int spec_count = 0;
  83
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  85         {
  86                 spec_count++;
  87         });
  88
  89         return spec_count;
  90 }
  91
  92 void WriteSpectators(entity player, entity to)
  93 {
  94         if(!player) { return; } // not sure how, but best to be safe
  95
  96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  97         {
  98                 WriteByte(MSG_ENTITY, num_for_edict(it));
  99         });
 100 }
 101
 102 bool ClientData_Send(entity this, entity to, int sf)
 103 {
 104         assert(to == this.owner, return false);
 105
 106         entity e = to;
 107         if (IS_SPEC(e)) e = e.enemy;
 108
 109         sf = 0;
 110         if (e.race_completed)       sf |= 1; // forced scoreboard
 111         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 112         if (e.zoomstate)            sf |= 4; // zoomed
 113         if (e.porto_v_angle_held)   sf |= 8; // angles held
 114         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 115
 116         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 117         WriteByte(MSG_ENTITY, sf);
 118
 119         if (sf & 2)
 120         {
 121                 WriteByte(MSG_ENTITY, to.spectatee_status);
 122         }
 123         if (sf & 8)
 124         {
 125                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 126                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 127         }
 128
 129         if(sf & 16)
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         this.clientdata.drawonlytoclient = this;
 143         this.clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(this.clientdata);
 149         this.clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         e.clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 158 }
 159
 160 .string netname_previous;
 161
 162 void SetSpectatee(entity player, entity spectatee);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = spot.angles;
 233         this.angles_z = 0;
 234         this.fixangle = true;
 235         // offset it so that the spectator spawns higher off the ground, looks better this way
 236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 237         this.prevorigin = this.origin;
 238         if (IS_REAL_CLIENT(this))
 239         {
 240             msg_entity = this;
 241             WriteByte(MSG_ONE, SVC_SETVIEW);
 242             WriteEntity(MSG_ONE, this);
 243         }
 244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 246         if(!autocvar_g_debug_globalsounds)
 247         {
 248                 // needed for player sounds
 249                 this.model = "";
 250                 FixPlayermodel(this);
 251         }
 252         setmodel(this, MDL_Null);
 253         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 254         this.view_ofs = '0 0 0';
 255     }
 256
 257     RemoveGrapplingHook(this);
 258         Portal_ClearAll(this);
 259         Unfreeze(this);
 260         SetSpectatee(this, NULL);
 261
 262         if (this.alivetime)
 263         {
 264                 if (!warmup_stage)
 265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 266                 this.alivetime = 0;
 267         }
 268
 269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 270
 271         WaypointSprite_PlayerDead(this);
 272
 273         if (mutator_returnvalue) {
 274             // mutator prevents resetting teams+score
 275         } else {
 276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 277         this.frags = FRAGS_SPECTATOR;
 278         PlayerScore_Clear(this);  // clear scores when needed
 279     }
 280
 281         if (this.killcount != FRAGS_SPECTATOR)
 282         {
 283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 284                 if(!intermission_running)
 285                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 287
 288                 if(this.just_joined == false) {
 289                         LogTeamchange(this.playerid, -1, 4);
 290                 } else
 291                         this.just_joined = false;
 292         }
 293
 294         accuracy_resend(this);
 295
 296         this.spectatortime = time;
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         this.damagedbycontents = false;
 303         this.health = FRAGS_SPECTATOR;
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.hook_time = 0;
 332         this.deadflag = DEAD_NO;
 333         this.crouch = false;
 334         this.revival_time = 0;
 335
 336         this.items = 0;
 337         this.weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponname = "";
 341         this.weaponmodel = "";
 342         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 343         {
 344                 this.weaponentities[slot] = NULL;
 345         }
 346         this.exteriorweaponentity = NULL;
 347         this.killcount = FRAGS_SPECTATOR;
 348         this.velocity = '0 0 0';
 349         this.avelocity = '0 0 0';
 350         this.punchangle = '0 0 0';
 351         this.punchvector = '0 0 0';
 352         this.oldvelocity = this.velocity;
 353         this.fire_endtime = -1;
 354         this.event_damage = func_null;
 355
 356         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 357         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 358         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 359 }
 360
 361 int player_getspecies(entity this)
 362 {
 363         get_model_parameters(this.model, this.skin);
 364         int s = get_model_parameters_species;
 365         get_model_parameters(string_null, 0);
 366         if (s < 0) return SPECIES_HUMAN;
 367         return s;
 368 }
 369
 370 .float model_randomizer;
 371 void FixPlayermodel(entity player)
 372 {
 373         string defaultmodel = "";
 374         int defaultskin = 0;
 375         if(autocvar_sv_defaultcharacter)
 376         {
 377                 if(teamplay)
 378                 {
 379                         string s = Static_Team_ColorName_Lower(player.team);
 380                         if (s != "neutral")
 381                         {
 382                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 383                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 384                         }
 385                 }
 386
 387                 if(defaultmodel == "")
 388                 {
 389                         defaultmodel = autocvar_sv_defaultplayermodel;
 390                         defaultskin = autocvar_sv_defaultplayerskin;
 391                 }
 392
 393                 int n = tokenize_console(defaultmodel);
 394                 if(n > 0)
 395                 {
 396                         defaultmodel = argv(floor(n * player.model_randomizer));
 397                         // However, do NOT randomize if the player-selected model is in the list.
 398                         for (int i = 0; i < n; ++i)
 399                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 400                                         defaultmodel = argv(i);
 401                 }
 402
 403                 int i = strstrofs(defaultmodel, ":", 0);
 404                 if(i >= 0)
 405                 {
 406                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 407                         defaultmodel = substring(defaultmodel, 0, i);
 408                 }
 409         }
 410         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 411         {
 412                 if(teamplay)
 413                 {
 414                         string s = Static_Team_ColorName_Lower(player.team);
 415                         if (s != "neutral")
 416                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 417                 }
 418
 419                 if(!defaultskin)
 420                         defaultskin = autocvar_sv_defaultplayerskin;
 421         }
 422
 423         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 424         defaultmodel = M_ARGV(0, string);
 425         defaultskin = M_ARGV(1, int);
 426
 427         bool chmdl = false;
 428         int oldskin;
 429         if(defaultmodel != "")
 430         {
 431                 if (defaultmodel != player.model)
 432                 {
 433                         vector m1 = player.mins;
 434                         vector m2 = player.maxs;
 435                         setplayermodel (player, defaultmodel);
 436                         setsize (player, m1, m2);
 437                         chmdl = true;
 438                 }
 439
 440                 oldskin = player.skin;
 441                 player.skin = defaultskin;
 442         } else {
 443                 if (player.playermodel != player.model || player.playermodel == "")
 444                 {
 445                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, player.playermodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 if(!autocvar_sv_defaultcharacterskin)
 454                 {
 455                         oldskin = player.skin;
 456                         player.skin = stof(player.playerskin);
 457                 }
 458                 else
 459                 {
 460                         oldskin = player.skin;
 461                         player.skin = defaultskin;
 462                 }
 463         }
 464
 465         if(chmdl || oldskin != player.skin) // model or skin has changed
 466         {
 467                 player.species = player_getspecies(player); // update species
 468                 if(!autocvar_g_debug_globalsounds)
 469                         UpdatePlayerSounds(player); // update skin sounds
 470         }
 471
 472         if(!teamplay)
 473                 if(strlen(autocvar_sv_defaultplayercolors))
 474                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 475                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 476 }
 477
 478
 479 /** Called when a client spawns in the server */
 480 void PutClientInServer(entity this)
 481 {
 482         if (IS_BOT_CLIENT(this)) {
 483                 TRANSMUTE(Player, this);
 484         } else if (IS_REAL_CLIENT(this)) {
 485                 msg_entity = this;
 486                 WriteByte(MSG_ONE, SVC_SETVIEW);
 487                 WriteEntity(MSG_ONE, this);
 488         }
 489         if (gameover) {
 490                 TRANSMUTE(Observer, this);
 491         }
 492
 493         SetSpectatee(this, NULL);
 494
 495         // reset player keys
 496         this.itemkeys = 0;
 497
 498         MUTATOR_CALLHOOK(PutClientInServer, this);
 499
 500         if (IS_OBSERVER(this)) {
 501                 PutObserverInServer(this);
 502         } else if (IS_PLAYER(this)) {
 503                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 504
 505                 PlayerState_attach(this);
 506                 accuracy_resend(this);
 507
 508                 if (this.team < 0)
 509                         JoinBestTeam(this, false, true);
 510
 511                 entity spot = SelectSpawnPoint(this, false);
 512                 if (!spot) {
 513                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 514                         return; // spawn failed
 515                 }
 516
 517                 TRANSMUTE(Player, this);
 518                 this.wasplayer = true;
 519                 this.iscreature = true;
 520                 this.teleportable = TELEPORT_NORMAL;
 521                 this.damagedbycontents = true;
 522                 set_movetype(this, MOVETYPE_WALK);
 523                 this.solid = SOLID_SLIDEBOX;
 524                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 525                 if (autocvar_g_playerclip_collisions)
 526                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 527                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 528                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 529                 this.frags = FRAGS_PLAYER;
 530                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 531                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 532                 if (autocvar__notarget)
 533                         this.flags |= FL_NOTARGET;
 534                 this.takedamage = DAMAGE_AIM;
 535                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 536                 this.dmg = 2; // WTF
 537
 538                 if (warmup_stage) {
 539                         this.ammo_shells = warmup_start_ammo_shells;
 540                         this.ammo_nails = warmup_start_ammo_nails;
 541                         this.ammo_rockets = warmup_start_ammo_rockets;
 542                         this.ammo_cells = warmup_start_ammo_cells;
 543                         this.ammo_plasma = warmup_start_ammo_plasma;
 544                         this.ammo_fuel = warmup_start_ammo_fuel;
 545                         this.health = warmup_start_health;
 546                         this.armorvalue = warmup_start_armorvalue;
 547                         this.weapons = WARMUP_START_WEAPONS;
 548                 } else {
 549                         this.ammo_shells = start_ammo_shells;
 550                         this.ammo_nails = start_ammo_nails;
 551                         this.ammo_rockets = start_ammo_rockets;
 552                         this.ammo_cells = start_ammo_cells;
 553                         this.ammo_plasma = start_ammo_plasma;
 554                         this.ammo_fuel = start_ammo_fuel;
 555                         this.health = start_health;
 556                         this.armorvalue = start_armorvalue;
 557                         this.weapons = start_weapons;
 558                 }
 559
 560                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 561
 562                 this.items = start_items;
 563
 564                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 565                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 566                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 567                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 568                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 569                 // extend the pause of rotting if client was reset at the beginning of the countdown
 570                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 571                         float f = game_starttime - time;
 572                         this.spawnshieldtime += f;
 573                         this.pauserotarmor_finished += f;
 574                         this.pauserothealth_finished += f;
 575                         this.pauseregen_finished += f;
 576                 }
 577                 this.damageforcescale = 2;
 578                 this.death_time = 0;
 579                 this.respawn_flags = 0;
 580                 this.respawn_time = 0;
 581                 this.stat_respawn_time = 0;
 582                 this.scale = autocvar_sv_player_scale;
 583                 this.fade_time = 0;
 584                 this.pain_frame = 0;
 585                 this.pain_finished = 0;
 586                 this.pushltime = 0;
 587                 setthink(this, func_null); // players have no think function
 588                 this.nextthink = 0;
 589                 this.dmg_team = 0;
 590                 this.ballistics_density = autocvar_g_ballistics_density_player;
 591
 592                 this.deadflag = DEAD_NO;
 593
 594                 this.angles = spot.angles;
 595                 this.angles_z = 0; // never spawn tilted even if the spot says to
 596                 if (IS_BOT_CLIENT(this))
 597                         this.v_angle = this.angles;
 598                 this.fixangle = true; // turn this way immediately
 599                 this.oldvelocity = this.velocity = '0 0 0';
 600                 this.avelocity = '0 0 0';
 601                 this.punchangle = '0 0 0';
 602                 this.punchvector = '0 0 0';
 603
 604                 this.strength_finished = 0;
 605                 this.invincible_finished = 0;
 606                 this.fire_endtime = -1;
 607                 this.revival_time = 0;
 608                 this.air_finished = time + 12;
 609
 610                 entity spawnevent = new_pure(spawnevent);
 611                 spawnevent.owner = this;
 612                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 613
 614                 // Cut off any still running player sounds.
 615                 stopsound(this, CH_PLAYER_SINGLE);
 616
 617                 this.model = "";
 618                 FixPlayermodel(this);
 619                 this.drawonlytoclient = NULL;
 620
 621                 this.crouch = false;
 622                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 623                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 624                 this.spawnorigin = spot.origin;
 625                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 626                 // don't reset back to last position, even if new position is stuck in solid
 627                 this.oldorigin = this.origin;
 628                 this.prevorigin = this.origin;
 629                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 630                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 631                 this.hud = HUD_NORMAL;
 632
 633                 this.event_damage = PlayerDamage;
 634
 635                 this.bot_attack = true;
 636                 this.monster_attack = true;
 637
 638                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 639
 640                 if (this.killcount == FRAGS_SPECTATOR) {
 641                         PlayerScore_Clear(this);
 642                         this.killcount = 0;
 643                 }
 644
 645                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 646                 {
 647                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 648                 }
 649                 this.alpha = default_player_alpha;
 650                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 651                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 652
 653                 this.speedrunning = false;
 654
 655                 target_voicescript_clear(this);
 656
 657                 // reset fields the weapons may use
 658                 FOREACH(Weapons, true, LAMBDA(
 659                         it.wr_resetplayer(it, this);
 660                         // reload all reloadable weapons
 661                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 662                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 663                         }
 664                 ));
 665
 666                 {
 667                         string s = spot.target;
 668                         spot.target = string_null;
 669                         SUB_UseTargets(spot, this, NULL);
 670                         spot.target = s;
 671                 }
 672
 673                 Unfreeze(this);
 674
 675                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 676
 677                 if (autocvar_spawn_debug)
 678                 {
 679                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 680                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 681                 }
 682
 683                 PS(this).m_switchweapon = w_getbestweapon(this);
 684                 this.cnt = -1; // W_LastWeapon will not complain
 685                 PS(this).m_weapon = WEP_Null;
 686                 this.weaponname = "";
 687                 PS(this).m_switchingweapon = WEP_Null;
 688
 689                 if (!warmup_stage && !this.alivetime)
 690                         this.alivetime = time;
 691
 692                 antilag_clear(this, CS(this));
 693         }
 694 }
 695
 696 void ClientInit_misc(entity this);
 697
 698 .float ebouncefactor, ebouncestop; // electro's values
 699 // TODO do we need all these fields, or should we stop autodetecting runtime
 700 // changes and just have a console command to update this?
 701 bool ClientInit_SendEntity(entity this, entity to, int sf)
 702 {
 703         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 704         return = true;
 705         msg_entity = to;
 706         // MSG_INIT replacement
 707         // TODO: make easier to use
 708         Registry_send_all();
 709         W_PROP_reload(MSG_ONE, to);
 710         ClientInit_misc(this);
 711         MUTATOR_CALLHOOK(Ent_Init);
 712 }
 713 void ClientInit_misc(entity this)
 714 {
 715         int channel = MSG_ONE;
 716         WriteHeader(channel, ENT_CLIENT_INIT);
 717         WriteByte(channel, g_nexball_meter_period * 32);
 718         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 719         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 720         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 721         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 722         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 723         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 724         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 725         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 726
 727         if(sv_foginterval && world.fog != "")
 728                 WriteString(channel, world.fog);
 729         else
 730                 WriteString(channel, "");
 731         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 732         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 733         WriteCoord(channel, autocvar_g_trueaim_minrange);
 734 }
 735
 736 void ClientInit_CheckUpdate(entity this)
 737 {
 738         this.nextthink = time;
 739         if(this.count != autocvar_g_balance_armor_blockpercent)
 740         {
 741                 this.count = autocvar_g_balance_armor_blockpercent;
 742                 this.SendFlags |= 1;
 743         }
 744 }
 745
 746 void ClientInit_Spawn()
 747 {
 748         entity e = new_pure(clientinit);
 749         setthink(e, ClientInit_CheckUpdate);
 750         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 751
 752         ClientInit_CheckUpdate(e);
 753 }
 754
 755 /*
 756 =============
 757 SetNewParms
 758 =============
 759 */
 760 void SetNewParms ()
 761 {
 762         // initialize parms for a new player
 763         parm1 = -(86400 * 366);
 764
 765         MUTATOR_CALLHOOK(SetNewParms);
 766 }
 767
 768 /*
 769 =============
 770 SetChangeParms
 771 =============
 772 */
 773 void SetChangeParms (entity this)
 774 {
 775         // save parms for level change
 776         parm1 = this.parm_idlesince - time;
 777
 778         MUTATOR_CALLHOOK(SetChangeParms);
 779 }
 780
 781 /*
 782 =============
 783 DecodeLevelParms
 784 =============
 785 */
 786 void DecodeLevelParms(entity this)
 787 {
 788         // load parms
 789         this.parm_idlesince = parm1;
 790         if (this.parm_idlesince == -(86400 * 366))
 791                 this.parm_idlesince = time;
 792
 793         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 794         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 795
 796         MUTATOR_CALLHOOK(DecodeLevelParms);
 797 }
 798
 799 /*
 800 =============
 801 ClientKill
 802
 803 Called when a client types 'kill' in the console
 804 =============
 805 */
 806
 807 .float clientkill_nexttime;
 808 void ClientKill_Now_TeamChange(entity this)
 809 {
 810         if(this.killindicator_teamchange == -1)
 811         {
 812                 JoinBestTeam( this, false, true );
 813         }
 814         else if(this.killindicator_teamchange == -2)
 815         {
 816                 if(blockSpectators)
 817                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 818                 PutObserverInServer(this);
 819         }
 820         else
 821                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 822         this.killindicator_teamchange = 0;
 823 }
 824
 825 void ClientKill_Now(entity this)
 826 {
 827         if(this.vehicle)
 828         {
 829             vehicles_exit(this.vehicle, VHEF_RELEASE);
 830             if(!this.killindicator_teamchange)
 831             {
 832             this.vehicle_health = -1;
 833             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 834             }
 835         }
 836
 837         if(this.killindicator && !wasfreed(this.killindicator))
 838                 delete(this.killindicator);
 839
 840         this.killindicator = NULL;
 841
 842         if(this.killindicator_teamchange)
 843                 ClientKill_Now_TeamChange(this);
 844
 845         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 846                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 847
 848         // now I am sure the player IS dead
 849 }
 850 void KillIndicator_Think(entity this)
 851 {
 852         if (gameover)
 853         {
 854                 this.owner.killindicator = NULL;
 855                 delete(this);
 856                 return;
 857         }
 858
 859         if (this.owner.alpha < 0 && !this.owner.vehicle)
 860         {
 861                 this.owner.killindicator = NULL;
 862                 delete(this);
 863                 return;
 864         }
 865
 866         if(this.cnt <= 0)
 867         {
 868                 ClientKill_Now(this.owner);
 869                 return;
 870         }
 871     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 872     {
 873         this.nextthink = time + 1;
 874         this.cnt -= 1;
 875     }
 876         else
 877         {
 878                 if(this.cnt <= 10)
 879                         setmodel(this, MDL_NUM(this.cnt));
 880                 if(IS_REAL_CLIENT(this.owner))
 881                 {
 882                         if(this.cnt <= 10)
 883                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 884                 }
 885                 this.nextthink = time + 1;
 886                 this.cnt -= 1;
 887         }
 888 }
 889
 890 float clientkilltime;
 891 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 892 {
 893         float killtime;
 894         float starttime;
 895
 896         if (gameover)
 897                 return;
 898
 899         killtime = autocvar_g_balance_kill_delay;
 900
 901         if(g_race_qualifying || g_cts)
 902                 killtime = 0;
 903
 904     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 905         return;
 906
 907         this.killindicator_teamchange = targetteam;
 908
 909     if(!this.killindicator)
 910         {
 911                 if(!IS_DEAD(this))
 912                 {
 913                         killtime = max(killtime, this.clientkill_nexttime - time);
 914                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 915                 }
 916
 917                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 918                 {
 919                         ClientKill_Now(this);
 920                 }
 921                 else
 922                 {
 923                         starttime = max(time, clientkilltime);
 924
 925                         this.killindicator = spawn();
 926                         this.killindicator.owner = this;
 927                         this.killindicator.scale = 0.5;
 928                         setattachment(this.killindicator, this, "");
 929                         setorigin(this.killindicator, '0 0 52');
 930                         setthink(this.killindicator, KillIndicator_Think);
 931                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 932                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 933                         this.killindicator.cnt = ceil(killtime);
 934                         this.killindicator.count = bound(0, ceil(killtime), 10);
 935                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 936
 937                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 938                         {
 939                                 it.killindicator = spawn();
 940                                 it.killindicator.owner = it;
 941                                 it.killindicator.scale = 0.5;
 942                                 setattachment(it.killindicator, it, "");
 943                                 setorigin(it.killindicator, '0 0 52');
 944                                 setthink(it.killindicator, KillIndicator_Think);
 945                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 946                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 947                                 it.killindicator.cnt = ceil(killtime);
 948                         });
 949                         this.lip = 0;
 950                 }
 951         }
 952         if(this.killindicator)
 953         {
 954                 if(targetteam == 0) // just die
 955                 {
 956                         this.killindicator.colormod = '0 0 0';
 957                         if(IS_REAL_CLIENT(this))
 958                         if(this.killindicator.cnt > 0)
 959                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 960                 }
 961                 else if(targetteam == -1) // auto
 962                 {
 963                         this.killindicator.colormod = '0 1 0';
 964                         if(IS_REAL_CLIENT(this))
 965                         if(this.killindicator.cnt > 0)
 966                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 967                 }
 968                 else if(targetteam == -2) // spectate
 969                 {
 970                         this.killindicator.colormod = '0.5 0.5 0.5';
 971                         if(IS_REAL_CLIENT(this))
 972                         if(this.killindicator.cnt > 0)
 973                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 974                 }
 975                 else
 976                 {
 977                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 981                 }
 982         }
 983
 984 }
 985
 986 void ClientKill (entity this)
 987 {
 988         if(gameover) return;
 989         if(this.player_blocked) return;
 990         if(STAT(FROZEN, this)) return;
 991
 992         ClientKill_TeamChange(this, 0);
 993 }
 994
 995 void FixClientCvars(entity e)
 996 {
 997         // send prediction settings to the client
 998         stuffcmd(e, "\nin_bindmap 0 0\n");
 999         if(autocvar_g_antilag == 3) // client side hitscan
1000                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1001         if(autocvar_sv_gentle)
1002                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1003
1004         MUTATOR_CALLHOOK(FixClientCvars, e);
1005 }
1006
1007 float PlayerInIDList(entity p, string idlist)
1008 {
1009         float n, i;
1010         string s;
1011
1012         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1013         if (!p.crypto_idfp)
1014                 return 0;
1015
1016         // this function allows abbreviated player IDs too!
1017         n = tokenize_console(idlist);
1018         for(i = 0; i < n; ++i)
1019         {
1020                 s = argv(i);
1021                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1022                         return 1;
1023         }
1024
1025         return 0;
1026 }
1027
1028 #ifdef DP_EXT_PRECONNECT
1029 /*
1030 =============
1031 ClientPreConnect
1032
1033 Called once (not at each match start) when a client begins a connection to the server
1034 =============
1035 */
1036 void ClientPreConnect ()
1037 {ENGINE_EVENT();
1038         if(autocvar_sv_eventlog)
1039         {
1040                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1041                         this.playerid,
1042                         etof(this),
1043                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1044                 ));
1045         }
1046 }
1047 #endif
1048
1049 /**
1050 =============
1051 ClientConnect
1052
1053 Called when a client connects to the server
1054 =============
1055 */
1056 void ClientConnect(entity this)
1057 {
1058         if (Ban_MaybeEnforceBanOnce(this)) return;
1059         assert(!IS_CLIENT(this), return);
1060         this.flags |= FL_CLIENT;
1061         assert(player_count >= 0, player_count = 0);
1062
1063 #ifdef WATERMARK
1064         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1065 #endif
1066         this.version_nagtime = time + 10 + random() * 10;
1067         TRANSMUTE(Client, this);
1068
1069         // identify the right forced team
1070         if (autocvar_g_campaign)
1071         {
1072                 if (IS_REAL_CLIENT(this)) // only players, not bots
1073                 {
1074                         switch (autocvar_g_campaign_forceteam)
1075                         {
1076                                 case 1: this.team_forced = NUM_TEAM_1; break;
1077                                 case 2: this.team_forced = NUM_TEAM_2; break;
1078                                 case 3: this.team_forced = NUM_TEAM_3; break;
1079                                 case 4: this.team_forced = NUM_TEAM_4; break;
1080                                 default: this.team_forced = 0;
1081                         }
1082                 }
1083         }
1084         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1085         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1086         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1087         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1088         else switch (autocvar_g_forced_team_otherwise)
1089         {
1090                 default: this.team_forced = 0; break;
1091                 case "red": this.team_forced = NUM_TEAM_1; break;
1092                 case "blue": this.team_forced = NUM_TEAM_2; break;
1093                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1094                 case "pink": this.team_forced = NUM_TEAM_4; break;
1095                 case "spectate":
1096                 case "spectator":
1097                         this.team_forced = -1;
1098                         break;
1099         }
1100         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1101
1102     {
1103         int id = this.playerid;
1104         this.playerid = 0; // silent
1105             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1106             this.playerid = id;
1107     }
1108
1109         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1110                 TRANSMUTE(Observer, this);
1111         } else {
1112                 if (!teamplay || autocvar_g_balance_teams) {
1113                         TRANSMUTE(Player, this);
1114                         campaign_bots_may_start = true;
1115                 } else {
1116                         TRANSMUTE(Observer, this); // do it anyway
1117                 }
1118         }
1119
1120         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1121
1122         // always track bots, don't ask for cl_allow_uidtracking
1123     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1124
1125         if (autocvar_sv_eventlog)
1126                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1127
1128         LogTeamchange(this.playerid, this.team, 1);
1129
1130         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1131
1132         this.netname_previous = strzone(this.netname);
1133
1134         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1135
1136         stuffcmd(this, clientstuff, "\n");
1137         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1138
1139         FixClientCvars(this);
1140
1141         // get version info from player
1142         stuffcmd(this, "cmd clientversion $gameversion\n");
1143
1144         // notify about available teams
1145         if (teamplay)
1146         {
1147                 CheckAllowedTeams(this);
1148                 int t = 0;
1149                 if (c1 >= 0) t |= BIT(0);
1150                 if (c2 >= 0) t |= BIT(1);
1151                 if (c3 >= 0) t |= BIT(2);
1152                 if (c4 >= 0) t |= BIT(3);
1153                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1154         }
1155         else
1156         {
1157                 stuffcmd(this, "set _teams_available 0\n");
1158         }
1159
1160         bot_relinkplayerlist();
1161
1162         this.spectatortime = time;
1163         if (blockSpectators)
1164         {
1165                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1166         }
1167
1168         this.jointime = time;
1169         this.allowed_timeouts = autocvar_sv_timeout_number;
1170
1171         if (IS_REAL_CLIENT(this))
1172         {
1173                 if (!autocvar_g_campaign)
1174                 {
1175                         this.motd_actived_time = -1;
1176                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1177                 }
1178
1179                 if (g_weaponarena_weapons == WEPSET(TUBA))
1180                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1181         }
1182
1183         if (!sv_foginterval && world.fog != "")
1184                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1185
1186         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1187                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1188                         send_CSQC_teamnagger();
1189
1190         CSQCMODEL_AUTOINIT(this);
1191
1192         this.model_randomizer = random();
1193
1194         if (IS_REAL_CLIENT(this))
1195                 sv_notice_join(this);
1196
1197         IL_EACH(g_initforplayer, it.init_for_player, {
1198                 it.init_for_player(it, this);
1199         });
1200
1201         MUTATOR_CALLHOOK(ClientConnect, this);
1202 }
1203 /*
1204 =============
1205 ClientDisconnect
1206
1207 Called when a client disconnects from the server
1208 =============
1209 */
1210 .entity chatbubbleentity;
1211 void ReadyCount();
1212 void ClientDisconnect(entity this)
1213 {
1214         assert(IS_CLIENT(this), return);
1215
1216         PlayerStats_GameReport_FinalizePlayer(this);
1217         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1218         if (this.active_minigame) part_minigame(this);
1219         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1220
1221         if (autocvar_sv_eventlog)
1222                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1223
1224         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1225
1226         SetSpectatee(this, NULL);
1227
1228     MUTATOR_CALLHOOK(ClientDisconnect, this);
1229
1230         ClientState_detach(this);
1231
1232         Portal_ClearAll(this);
1233
1234         Unfreeze(this);
1235
1236         RemoveGrapplingHook(this);
1237
1238         // Here, everything has been done that requires this player to be a client.
1239
1240         this.flags &= ~FL_CLIENT;
1241
1242         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1243         if (this.killindicator) delete(this.killindicator);
1244
1245         WaypointSprite_PlayerGone(this);
1246
1247         bot_relinkplayerlist();
1248
1249         if (this.netname_previous) strunzone(this.netname_previous);
1250         if (this.clientstatus) strunzone(this.clientstatus);
1251         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1252         if (this.personal) delete(this.personal);
1253
1254         this.playerid = 0;
1255         ReadyCount();
1256         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( this.owner.active_minigame )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307
1308 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1309 // added to the model skins
1310 /*void UpdateColorModHack()
1311 {
1312         float c;
1313         c = this.clientcolors & 15;
1314         // LordHavoc: only bothering to support white, green, red, yellow, blue
1315              if (!teamplay) this.colormod = '0 0 0';
1316         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1317         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1318         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1319         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1320         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1321         else this.colormod = '1 1 1';
1322 }*/
1323
1324 void respawn(entity this)
1325 {
1326         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1327         {
1328                 this.solid = SOLID_NOT;
1329                 this.takedamage = DAMAGE_NO;
1330                 set_movetype(this, MOVETYPE_FLY);
1331                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1332                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1333                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1334                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1335                 if(autocvar_g_respawn_ghosts_maxtime)
1336                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1337         }
1338
1339         CopyBody(this, 1);
1340
1341         this.effects |= EF_NODRAW; // prevent another CopyBody
1342         PutClientInServer(this);
1343 }
1344
1345 void play_countdown(entity this, float finished, Sound samp)
1346 {
1347     TC(Sound, samp);
1348         if(IS_REAL_CLIENT(this))
1349                 if(floor(finished - time - frametime) != floor(finished - time))
1350                         if(finished - time < 6)
1351                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1352 }
1353
1354 void player_powerups(entity this)
1355 {
1356         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1357         int items_prev = this.items;
1358
1359         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1360                 this.modelflags |= MF_ROCKET;
1361         else
1362                 this.modelflags &= ~MF_ROCKET;
1363
1364         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1365
1366         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1367                 return;
1368
1369         Fire_ApplyDamage(this);
1370         Fire_ApplyEffect(this);
1371
1372         if (!g_instagib)
1373         {
1374                 if (this.items & ITEM_Strength.m_itemid)
1375                 {
1376                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1377                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1378                         if (time > this.strength_finished)
1379                         {
1380                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1381                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1382                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1383                         }
1384                 }
1385                 else
1386                 {
1387                         if (time < this.strength_finished)
1388                         {
1389                                 this.items = this.items | ITEM_Strength.m_itemid;
1390                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1391                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1392                         }
1393                 }
1394                 if (this.items & ITEM_Shield.m_itemid)
1395                 {
1396                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1397                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1398                         if (time > this.invincible_finished)
1399                         {
1400                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1401                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1402                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1403                         }
1404                 }
1405                 else
1406                 {
1407                         if (time < this.invincible_finished)
1408                         {
1409                                 this.items = this.items | ITEM_Shield.m_itemid;
1410                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1411                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1412                         }
1413                 }
1414                 if (this.items & IT_SUPERWEAPON)
1415                 {
1416                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1417                         {
1418                                 this.superweapons_finished = 0;
1419                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1420                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1422                         }
1423                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1424                         {
1425                                 // don't let them run out
1426                         }
1427                         else
1428                         {
1429                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1430                                 if (time > this.superweapons_finished)
1431                                 {
1432                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1433                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1434                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1435                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1436                                 }
1437                         }
1438                 }
1439                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1440                 {
1441                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1442                         {
1443                                 this.items = this.items | IT_SUPERWEAPON;
1444                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1446                         }
1447                         else
1448                         {
1449                                 this.superweapons_finished = 0;
1450                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1451                         }
1452                 }
1453                 else
1454                 {
1455                         this.superweapons_finished = 0;
1456                 }
1457         }
1458
1459         if(autocvar_g_nodepthtestplayers)
1460                 this.effects = this.effects | EF_NODEPTHTEST;
1461
1462         if(autocvar_g_fullbrightplayers)
1463                 this.effects = this.effects | EF_FULLBRIGHT;
1464
1465         if (time >= game_starttime)
1466         if (time < this.spawnshieldtime)
1467                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1468
1469         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1470 }
1471
1472 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1473 {
1474         if(current > stable)
1475                 return current;
1476         else if(current > stable - 0.25) // when close enough, "snap"
1477                 return stable;
1478         else
1479                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1480 }
1481
1482 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1483 {
1484         if(current < stable)
1485                 return current;
1486         else if(current < stable + 0.25) // when close enough, "snap"
1487                 return stable;
1488         else
1489                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1490 }
1491
1492 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1493 {
1494         if(current > rotstable)
1495         {
1496                 if(rotframetime > 0)
1497                 {
1498                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1499                         current = max(rotstable, current - rotlinear * rotframetime);
1500                 }
1501         }
1502         else if(current < regenstable)
1503         {
1504                 if(regenframetime > 0)
1505                 {
1506                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1507                         current = min(regenstable, current + regenlinear * regenframetime);
1508                 }
1509         }
1510
1511         if(current > limit)
1512                 current = limit;
1513
1514         return current;
1515 }
1516
1517 void player_regen(entity this)
1518 {
1519         float max_mod, regen_mod, rot_mod, limit_mod;
1520         max_mod = regen_mod = rot_mod = limit_mod = 1;
1521
1522         float regen_health = autocvar_g_balance_health_regen;
1523         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1524         float regen_health_rot = autocvar_g_balance_health_rot;
1525         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1526         float regen_health_stable = autocvar_g_balance_health_regenstable;
1527         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1528         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1529                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1530         max_mod = M_ARGV(1, float);
1531         regen_mod = M_ARGV(2, float);
1532         rot_mod = M_ARGV(3, float);
1533         limit_mod = M_ARGV(4, float);
1534         regen_health = M_ARGV(5, float);
1535         regen_health_linear = M_ARGV(6, float);
1536         regen_health_rot = M_ARGV(7, float);
1537         regen_health_rotlinear = M_ARGV(8, float);
1538         regen_health_stable = M_ARGV(9, float);
1539         regen_health_rotstable = M_ARGV(10, float);
1540
1541
1542         if(!mutator_returnvalue)
1543         if(!STAT(FROZEN, this))
1544         {
1545                 float mina, maxa, limith, limita;
1546                 maxa = autocvar_g_balance_armor_rotstable;
1547                 mina = autocvar_g_balance_armor_regenstable;
1548                 limith = autocvar_g_balance_health_limit;
1549                 limita = autocvar_g_balance_armor_limit;
1550
1551                 regen_health_rotstable = regen_health_rotstable * max_mod;
1552                 regen_health_stable = regen_health_stable * max_mod;
1553                 limith = limith * limit_mod;
1554                 limita = limita * limit_mod;
1555
1556                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1557                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1558         }
1559
1560         // if player rotted to death...  die!
1561         // check this outside above checks, as player may still be able to rot to death
1562         if(this.health < 1)
1563         {
1564                 if(this.vehicle)
1565                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1566                 if(this.event_damage)
1567                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1568         }
1569
1570         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1571         {
1572                 float minf, maxf, limitf;
1573
1574                 maxf = autocvar_g_balance_fuel_rotstable;
1575                 minf = autocvar_g_balance_fuel_regenstable;
1576                 limitf = autocvar_g_balance_fuel_limit;
1577
1578                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1579         }
1580 }
1581
1582 bool zoomstate_set;
1583 void SetZoomState(entity this, float z)
1584 {
1585         if(z != this.zoomstate)
1586         {
1587                 this.zoomstate = z;
1588                 ClientData_Touch(this);
1589         }
1590         zoomstate_set = true;
1591 }
1592
1593 void GetPressedKeys(entity this)
1594 {
1595         MUTATOR_CALLHOOK(GetPressedKeys, this);
1596         int keys = this.pressedkeys;
1597         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1598         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1599         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1600         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1601
1602         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1603         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1604         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1605         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1606         this.pressedkeys = keys;
1607 }
1608
1609 /*
1610 ======================
1611 spectate mode routines
1612 ======================
1613 */
1614
1615 void SpectateCopy(entity this, entity spectatee)
1616 {
1617     TC(Client, this); TC(Client, spectatee);
1618
1619         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1620         PS(this) = PS(spectatee);
1621         this.armortype = spectatee.armortype;
1622         this.armorvalue = spectatee.armorvalue;
1623         this.ammo_cells = spectatee.ammo_cells;
1624         this.ammo_plasma = spectatee.ammo_plasma;
1625         this.ammo_shells = spectatee.ammo_shells;
1626         this.ammo_nails = spectatee.ammo_nails;
1627         this.ammo_rockets = spectatee.ammo_rockets;
1628         this.ammo_fuel = spectatee.ammo_fuel;
1629         this.clip_load = spectatee.clip_load;
1630         this.clip_size = spectatee.clip_size;
1631         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1632         this.health = spectatee.health;
1633         this.impulse = 0;
1634         this.items = spectatee.items;
1635         this.last_pickup = spectatee.last_pickup;
1636         this.hit_time = spectatee.hit_time;
1637         this.strength_finished = spectatee.strength_finished;
1638         this.invincible_finished = spectatee.invincible_finished;
1639         this.pressedkeys = spectatee.pressedkeys;
1640         this.weapons = spectatee.weapons;
1641         this.vortex_charge = spectatee.vortex_charge;
1642         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1643         this.hagar_load = spectatee.hagar_load;
1644         this.arc_heat_percent = spectatee.arc_heat_percent;
1645         this.minelayer_mines = spectatee.minelayer_mines;
1646         this.punchangle = spectatee.punchangle;
1647         this.view_ofs = spectatee.view_ofs;
1648         this.velocity = spectatee.velocity;
1649         this.dmg_take = spectatee.dmg_take;
1650         this.dmg_save = spectatee.dmg_save;
1651         this.dmg_inflictor = spectatee.dmg_inflictor;
1652         this.v_angle = spectatee.v_angle;
1653         this.angles = spectatee.v_angle;
1654         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1655         this.revive_progress = spectatee.revive_progress;
1656         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1657                 this.fixangle = true;
1658         setorigin(this, spectatee.origin);
1659         setsize(this, spectatee.mins, spectatee.maxs);
1660         SetZoomState(this, spectatee.zoomstate);
1661
1662     anticheat_spectatecopy(this, spectatee);
1663         this.hud = spectatee.hud;
1664         if(spectatee.vehicle)
1665     {
1666         this.angles = spectatee.v_angle;
1667
1668         //this.fixangle = false;
1669         //this.velocity = spectatee.vehicle.velocity;
1670         this.vehicle_health = spectatee.vehicle_health;
1671         this.vehicle_shield = spectatee.vehicle_shield;
1672         this.vehicle_energy = spectatee.vehicle_energy;
1673         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1674         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1675         this.vehicle_reload1 = spectatee.vehicle_reload1;
1676         this.vehicle_reload2 = spectatee.vehicle_reload2;
1677
1678         //msg_entity = this;
1679
1680        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1681             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1682            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1683            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1684
1685         //WriteByte (MSG_ONE, SVC_SETVIEW);
1686         //    WriteEntity(MSG_ONE, this);
1687         //makevectors(spectatee.v_angle);
1688         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1689     }
1690 }
1691
1692 bool SpectateUpdate(entity this)
1693 {
1694         if(!this.enemy)
1695             return false;
1696
1697         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1698         {
1699                 SetSpectatee(this, NULL);
1700                 return false;
1701         }
1702
1703         SpectateCopy(this, this.enemy);
1704
1705         return true;
1706 }
1707
1708 bool SpectateSet(entity this)
1709 {
1710         if(!IS_PLAYER(this.enemy))
1711                 return false;
1712
1713         ClientData_Touch(this.enemy);
1714
1715         msg_entity = this;
1716         WriteByte(MSG_ONE, SVC_SETVIEW);
1717         WriteEntity(MSG_ONE, this.enemy);
1718         set_movetype(this, MOVETYPE_NONE);
1719         accuracy_resend(this);
1720
1721         if(!SpectateUpdate(this))
1722                 PutObserverInServer(this);
1723
1724         return true;
1725 }
1726
1727 void SetSpectatee(entity this, entity spectatee)
1728 {
1729         entity old_spectatee = this.enemy;
1730
1731         this.enemy = spectatee;
1732
1733         // WEAPONTODO
1734         // these are required to fix the spectator bug with arc
1735         if(old_spectatee)
1736         {
1737                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1738                 {
1739                         .entity weaponentity = weaponentities[slot];
1740                         if(old_spectatee.(weaponentity).arc_beam)
1741                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1742                 }
1743         }
1744         if(this.enemy)
1745         {
1746                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1747                 {
1748                         .entity weaponentity = weaponentities[slot];
1749                         if(this.enemy.(weaponentity).arc_beam)
1750                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1751                 }
1752         }
1753
1754         // needed to update spectator list
1755         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1756 }
1757
1758 bool Spectate(entity this, entity pl)
1759 {
1760         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1761                 return false;
1762         pl = M_ARGV(1, entity);
1763
1764         SetSpectatee(this, pl);
1765         return SpectateSet(this);
1766 }
1767
1768 bool SpectateNext(entity this)
1769 {
1770         entity ent = find(this.enemy, classname, STR_PLAYER);
1771
1772         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1773                 ent = M_ARGV(1, entity);
1774         else if (!ent)
1775                 ent = find(ent, classname, STR_PLAYER);
1776
1777         if(ent) { SetSpectatee(this, ent); }
1778
1779         return SpectateSet(this);
1780 }
1781
1782 bool SpectatePrev(entity this)
1783 {
1784         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1785         entity ent = findchain(classname, STR_PLAYER);
1786         if (!ent) // no player
1787                 return false;
1788
1789         entity first = ent;
1790         // skip players until current spectated player
1791         if(this.enemy)
1792         while(ent && ent != this.enemy)
1793                 ent = ent.chain;
1794
1795         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1796         {
1797                 case MUT_SPECPREV_FOUND:
1798                     ent = M_ARGV(1, entity);
1799                     break;
1800                 case MUT_SPECPREV_RETURN:
1801                     return true;
1802                 case MUT_SPECPREV_CONTINUE:
1803                 default:
1804                 {
1805                         if(ent.chain)
1806                                 ent = ent.chain;
1807                         else
1808                                 ent = first;
1809                         break;
1810                 }
1811         }
1812
1813         SetSpectatee(this, ent);
1814         return SpectateSet(this);
1815 }
1816
1817 /*
1818 =============
1819 ShowRespawnCountdown()
1820
1821 Update a respawn countdown display.
1822 =============
1823 */
1824 void ShowRespawnCountdown(entity this)
1825 {
1826         float number;
1827         if(!IS_DEAD(this)) // just respawned?
1828                 return;
1829         else
1830         {
1831                 number = ceil(this.respawn_time - time);
1832                 if(number <= 0)
1833                         return;
1834                 if(number <= this.respawn_countdown)
1835                 {
1836                         this.respawn_countdown = number - 1;
1837                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1838                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1839                 }
1840         }
1841 }
1842
1843 .float caplayer;
1844
1845 void LeaveSpectatorMode(entity this)
1846 {
1847         if(this.caplayer)
1848                 return;
1849         if(nJoinAllowed(this, this))
1850         {
1851                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1852                 {
1853                         TRANSMUTE(Player, this);
1854
1855                         SetSpectatee(this, NULL);
1856
1857                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1858                                 { JoinBestTeam(this, false, true); }
1859
1860                         if(autocvar_g_campaign)
1861                                 { campaign_bots_may_start = true; }
1862
1863                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1864
1865                         PutClientInServer(this);
1866
1867                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1868                 }
1869                 else
1870                         stuffcmd(this, "menu_showteamselect\n");
1871         }
1872         else
1873         {
1874                 // Player may not join because g_maxplayers is set
1875                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1876         }
1877 }
1878
1879 /**
1880  * Determines whether the player is allowed to join. This depends on cvar
1881  * g_maxplayers, if it isn't used this function always return true, otherwise
1882  * it checks whether the number of currently playing players exceeds g_maxplayers.
1883  * @return int number of free slots for players, 0 if none
1884  */
1885 bool nJoinAllowed(entity this, entity ignore)
1886 {
1887         if(!ignore)
1888         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1889         // so report 0 free slots if restricted
1890         {
1891                 if(autocvar_g_forced_team_otherwise == "spectate")
1892                         return false;
1893                 if(autocvar_g_forced_team_otherwise == "spectator")
1894                         return false;
1895         }
1896
1897         if(this.team_forced < 0)
1898                 return false; // forced spectators can never join
1899
1900         // TODO simplify this
1901         int totalClients = 0;
1902         int currentlyPlaying = 0;
1903         FOREACH_CLIENT(true, LAMBDA(
1904                 if(it != ignore)
1905                         ++totalClients;
1906                 if(IS_REAL_CLIENT(it))
1907                 if(IS_PLAYER(it) || it.caplayer)
1908                         ++currentlyPlaying;
1909         ));
1910
1911         if (!autocvar_g_maxplayers)
1912                 return maxclients - totalClients;
1913
1914         if(currentlyPlaying < autocvar_g_maxplayers)
1915                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1916
1917         return false;
1918 }
1919
1920 /**
1921  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1922  * g_maxplayers_spectator_blocktime seconds
1923  */
1924 void checkSpectatorBlock(entity this)
1925 {
1926         if(IS_SPEC(this) || IS_OBSERVER(this))
1927         if(!this.caplayer)
1928         if(IS_REAL_CLIENT(this))
1929         {
1930                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1931                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1932                         dropclient(this);
1933                 }
1934         }
1935 }
1936
1937 void PrintWelcomeMessage(entity this)
1938 {
1939         if(this.motd_actived_time == 0)
1940         {
1941                 if (autocvar_g_campaign) {
1942                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1943                                 this.motd_actived_time = time;
1944                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1945                         }
1946                 } else {
1947                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1948                                 this.motd_actived_time = time;
1949                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1950                         }
1951                 }
1952         }
1953         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1954         {
1955                 if (autocvar_g_campaign) {
1956                         if (PHYS_INPUT_BUTTON_INFO(this))
1957                                 this.motd_actived_time = time;
1958                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1959                                 this.motd_actived_time = 0;
1960                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1961                         }
1962                 } else {
1963                         if (PHYS_INPUT_BUTTON_INFO(this))
1964                                 this.motd_actived_time = time;
1965                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1966                                 this.motd_actived_time = 0;
1967                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1968                         }
1969                 }
1970         }
1971         else //if(this.motd_actived_time < 0) // just connected, motd is active
1972         {
1973                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1974                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1975                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1976                 {
1977                         // instanctly hide MOTD
1978                         this.motd_actived_time = 0;
1979                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1980                 }
1981         }
1982 }
1983
1984 void ObserverThink(entity this)
1985 {
1986         if ( this.impulse )
1987         {
1988                 MinigameImpulse(this, this.impulse);
1989                 this.impulse = 0;
1990         }
1991         if (this.flags & FL_JUMPRELEASED) {
1992                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1993                         this.flags &= ~FL_JUMPRELEASED;
1994                         this.flags |= FL_SPAWNING;
1995                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1996                         this.flags &= ~FL_JUMPRELEASED;
1997                         if(SpectateNext(this)) {
1998                                 TRANSMUTE(Spectator, this);
1999                         }
2000                 } else {
2001                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2002                         set_movetype(this, preferred_movetype);
2003                 }
2004         } else {
2005                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2006                         this.flags |= FL_JUMPRELEASED;
2007                         if(this.flags & FL_SPAWNING)
2008                         {
2009                                 this.flags &= ~FL_SPAWNING;
2010                                 LeaveSpectatorMode(this);
2011                                 return;
2012                         }
2013                 }
2014         }
2015 }
2016
2017 void SpectatorThink(entity this)
2018 {
2019         if ( this.impulse )
2020         {
2021                 if(MinigameImpulse(this, this.impulse))
2022                         this.impulse = 0;
2023
2024                 if (this.impulse == IMP_weapon_drop.impulse)
2025                 {
2026                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2027                         this.impulse = 0;
2028                         return;
2029                 }
2030         }
2031         if (this.flags & FL_JUMPRELEASED) {
2032                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2033                         this.flags &= ~FL_JUMPRELEASED;
2034                         this.flags |= FL_SPAWNING;
2035                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2036                         this.flags &= ~FL_JUMPRELEASED;
2037                         if(SpectateNext(this)) {
2038                                 TRANSMUTE(Spectator, this);
2039                         } else {
2040                                 TRANSMUTE(Observer, this);
2041                                 PutClientInServer(this);
2042                         }
2043                         this.impulse = 0;
2044                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2045                         this.flags &= ~FL_JUMPRELEASED;
2046                         if(SpectatePrev(this)) {
2047                                 TRANSMUTE(Spectator, this);
2048                         } else {
2049                                 TRANSMUTE(Observer, this);
2050                                 PutClientInServer(this);
2051                         }
2052                         this.impulse = 0;
2053                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2054                         this.flags &= ~FL_JUMPRELEASED;
2055                         TRANSMUTE(Observer, this);
2056                         PutClientInServer(this);
2057                 } else {
2058                         if(!SpectateUpdate(this))
2059                                 PutObserverInServer(this);
2060                 }
2061         } else {
2062                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2063                         this.flags |= FL_JUMPRELEASED;
2064                         if(this.flags & FL_SPAWNING)
2065                         {
2066                                 this.flags &= ~FL_SPAWNING;
2067                                 LeaveSpectatorMode(this);
2068                                 return;
2069                         }
2070                 }
2071                 if(!SpectateUpdate(this))
2072                         PutObserverInServer(this);
2073         }
2074
2075         this.flags |= FL_CLIENT | FL_NOTARGET;
2076 }
2077
2078 void vehicles_enter (entity pl, entity veh);
2079 void PlayerUseKey(entity this)
2080 {
2081         if (!IS_PLAYER(this))
2082                 return;
2083
2084         if(this.vehicle)
2085         {
2086                 if(!gameover)
2087                 {
2088                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2089                         return;
2090                 }
2091         }
2092         else if(autocvar_g_vehicles_enter)
2093         {
2094                 if(!STAT(FROZEN, this))
2095                 if(!IS_DEAD(this))
2096                 if(!gameover)
2097                 {
2098                         entity head, closest_target = NULL;
2099                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2100
2101                         while(head) // find the closest acceptable target to enter
2102                         {
2103                                 if(IS_VEHICLE(head))
2104                                 if(!IS_DEAD(head))
2105                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2106                                 if(head.takedamage != DAMAGE_NO)
2107                                 {
2108                                         if(closest_target)
2109                                         {
2110                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2111                                                 { closest_target = head; }
2112                                         }
2113                                         else { closest_target = head; }
2114                                 }
2115
2116                                 head = head.chain;
2117                         }
2118
2119                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2120                 }
2121         }
2122
2123         // a use key was pressed; call handlers
2124         MUTATOR_CALLHOOK(PlayerUseKey, this);
2125 }
2126
2127
2128 /*
2129 =============
2130 PlayerPreThink
2131
2132 Called every frame for each client before the physics are run
2133 =============
2134 */
2135 .float usekeypressed;
2136 .float last_vehiclecheck;
2137 .int items_added;
2138 void PlayerPreThink (entity this)
2139 {
2140         WarpZone_PlayerPhysics_FixVAngle(this);
2141
2142     STAT(GAMESTARTTIME, this) = game_starttime;
2143         STAT(ROUNDSTARTTIME, this) = round_starttime;
2144         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2145         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2146
2147         STAT(WEAPONSINMAP, this) = weaponsInMap;
2148
2149         if (frametime) {
2150                 // physics frames: update anticheat stuff
2151                 anticheat_prethink(this);
2152         }
2153
2154         if (blockSpectators && frametime) {
2155                 // WORKAROUND: only use dropclient in server frames (frametime set).
2156                 // Never use it in cl_movement frames (frametime zero).
2157                 checkSpectatorBlock(this);
2158     }
2159
2160         zoomstate_set = false;
2161
2162         // Check for nameless players
2163         if (isInvisibleString(this.netname)) {
2164                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2165                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2166         }
2167         if (this.netname != this.netname_previous) {
2168                 if (autocvar_sv_eventlog) {
2169                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2170         }
2171                 if (this.netname_previous) strunzone(this.netname_previous);
2172                 this.netname_previous = strzone(this.netname);
2173         }
2174
2175         // version nagging
2176         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2177         this.version_nagtime = 0;
2178         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2179             // git client
2180         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2181             // git server
2182             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2183         } else {
2184             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2185             if (r < 0) { // old client
2186                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2187             } else if (r > 0) { // old server
2188                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2189             }
2190         }
2191     }
2192
2193         // GOD MODE info
2194         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2195         {
2196                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2197                 this.max_armorvalue = 0;
2198         }
2199
2200         if (STAT(FROZEN, this) == 2)
2201         {
2202                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2203                 this.health = max(1, this.revive_progress * start_health);
2204                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2205
2206                 if (this.revive_progress >= 1)
2207                         Unfreeze(this);
2208         }
2209         else if (STAT(FROZEN, this) == 3)
2210         {
2211                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2212                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2213
2214                 if (this.health < 1)
2215                 {
2216                         if (this.vehicle)
2217                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2218                         if(this.event_damage)
2219                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2220                 }
2221                 else if (this.revive_progress <= 0)
2222                         Unfreeze(this);
2223         }
2224
2225         MUTATOR_CALLHOOK(PlayerPreThink, this);
2226
2227         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2228         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2229         {
2230                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2231                 {
2232                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2233                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2234                         {
2235                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2236                         }
2237                         else if(!it.owner)
2238                         {
2239                                 if(!it.team || SAME_TEAM(this, it))
2240                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2241                                 else if(autocvar_g_vehicles_steal)
2242                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2243                         }
2244                 });
2245
2246                 this.last_vehiclecheck = time + 1;
2247         }
2248
2249         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2250         {
2251                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2252                         PlayerUseKey(this);
2253                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2254         }
2255
2256         if (IS_REAL_CLIENT(this))
2257                 PrintWelcomeMessage(this);
2258
2259         if (IS_PLAYER(this)) {
2260                 CheckRules_Player(this);
2261
2262                 if (intermission_running) {
2263                         IntermissionThink(this);
2264                         return;
2265                 }
2266
2267                 if (timeout_status == TIMEOUT_ACTIVE) {
2268             // don't allow the player to turn around while game is paused
2269                         // FIXME turn this into CSQC stuff
2270                         this.v_angle = this.lastV_angle;
2271                         this.angles = this.lastV_angle;
2272                         this.fixangle = true;
2273                 }
2274
2275                 if (frametime) player_powerups(this);
2276
2277                 if (IS_DEAD(this)) {
2278                         if (this.personal && g_race_qualifying) {
2279                                 if (time > this.respawn_time) {
2280                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2281                                         respawn(this);
2282                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2283                                 }
2284                         } else {
2285                                 if (frametime) player_anim(this);
2286                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2287
2288                                 switch(this.deadflag)
2289                                 {
2290                                         case DEAD_DYING:
2291                                         {
2292                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2293                                                         this.deadflag = DEAD_RESPAWNING;
2294                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2295                                                         this.deadflag = DEAD_DEAD;
2296                                                 break;
2297                                         }
2298                                         case DEAD_DEAD:
2299                                         {
2300                                                 if (button_pressed)
2301                                                         this.deadflag = DEAD_RESPAWNABLE;
2302                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2303                                                         this.deadflag = DEAD_RESPAWNING;
2304                                                 break;
2305                                         }
2306                                         case DEAD_RESPAWNABLE:
2307                                         {
2308                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2309                                                         this.deadflag = DEAD_RESPAWNING;
2310                                                 break;
2311                                         }
2312                                         case DEAD_RESPAWNING:
2313                                         {
2314                                                 if (time > this.respawn_time)
2315                                                 {
2316                                                         this.respawn_time = time + 1; // only retry once a second
2317                                                         this.respawn_time_max = this.respawn_time;
2318                                                         respawn(this);
2319                                                 }
2320                                                 break;
2321                                         }
2322                                 }
2323
2324                                 ShowRespawnCountdown(this);
2325
2326                                 if (this.respawn_flags & RESPAWN_SILENT)
2327                                         STAT(RESPAWN_TIME, this) = 0;
2328                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2329                                 {
2330                                         if (time < this.respawn_time)
2331                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2332                                         else if (this.deadflag != DEAD_RESPAWNING)
2333                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2334                                 }
2335                                 else
2336                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2337                         }
2338
2339                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2340                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2341                                 STAT(RESPAWN_TIME, this) *= -1;
2342
2343                         return;
2344                 }
2345
2346                 this.prevorigin = this.origin;
2347
2348                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2349                 if (this.hook.state) {
2350                         do_crouch = false;
2351                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2352                         do_crouch = false;
2353                 } else if (this.vehicle) {
2354                         do_crouch = false;
2355                 } else if (STAT(FROZEN, this)) {
2356                         do_crouch = false;
2357         }
2358
2359                 if (do_crouch) {
2360                         if (!this.crouch) {
2361                                 this.crouch = true;
2362                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2363                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2364                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2365                         }
2366                 } else if (this.crouch) {
2367             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2368             if (!trace_startsolid) {
2369                 this.crouch = false;
2370                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2371                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2372             }
2373                 }
2374
2375                 FixPlayermodel(this);
2376
2377                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2378                 //if(frametime)
2379                 {
2380                         this.items &= ~this.items_added;
2381
2382                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2383                         //{
2384                                 //.entity weaponentity = weaponentities[slot];
2385                                 //W_WeaponFrame(this, weaponentity);
2386                         //}
2387                         .entity weaponentity = weaponentities[0]; // TODO
2388                         W_WeaponFrame(this, weaponentity);
2389
2390                         this.items_added = 0;
2391                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2392                 this.items_added |= IT_FUEL;
2393
2394                         this.items |= this.items_added;
2395                 }
2396
2397                 player_regen(this);
2398
2399                 // WEAPONTODO: Add a weapon request for this
2400                 // rot vortex charge to the charge limit
2401                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2402                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2403
2404                 if (frametime) player_anim(this);
2405
2406                 // secret status
2407                 secrets_setstatus(this);
2408
2409                 // monsters status
2410                 monsters_setstatus(this);
2411
2412                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2413         }
2414         else if (gameover) {
2415                 if (intermission_running) IntermissionThink(this);
2416                 return;
2417         }
2418         else if (IS_OBSERVER(this)) {
2419                 ObserverThink(this);
2420         }
2421         else if (IS_SPEC(this)) {
2422                 SpectatorThink(this);
2423         }
2424
2425         // WEAPONTODO: Add weapon request for this
2426         if (!zoomstate_set) {
2427                 SetZoomState(this,
2428                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2429                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2430                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2431                 );
2432     }
2433
2434         int oldspectatee_status = this.spectatee_status;
2435         if (IS_SPEC(this)) {
2436                 this.spectatee_status = etof(this.enemy);
2437         } else if (IS_OBSERVER(this)) {
2438                 this.spectatee_status = etof(this);
2439         } else {
2440                 this.spectatee_status = 0;
2441     }
2442         if (this.spectatee_status != oldspectatee_status) {
2443                 ClientData_Touch(this);
2444                 if (g_race || g_cts) race_InitSpectator();
2445         }
2446
2447         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2448         {
2449                 this.teamkill_soundtime = 0;
2450
2451                 entity e = this.teamkill_soundsource;
2452                 entity oldpusher = e.pusher;
2453                 e.pusher = this;
2454                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2455                 e.pusher = oldpusher;
2456         }
2457
2458         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2459                 this.taunt_soundtime = 0;
2460                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2461         }
2462
2463         target_voicescript_next(this);
2464
2465         // WEAPONTODO: Move into weaponsystem somehow
2466         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2467         if (PS(this).m_weapon == WEP_Null)
2468                 this.clip_load = this.clip_size = 0;
2469 }
2470
2471 void DrownPlayer(entity this)
2472 {
2473         if(IS_DEAD(this))
2474                 return;
2475
2476         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2477         {
2478                 if(this.air_finished < time)
2479                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2480                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2481                 this.dmg = 2;
2482         }
2483         else if (this.air_finished < time)
2484         {       // drown!
2485                 if (this.pain_finished < time)
2486                 {
2487                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2488                         this.pain_finished = time + 0.5;
2489                 }
2490         }
2491 }
2492
2493 .bool move_qcphysics;
2494
2495 void Player_Physics(entity this)
2496 {
2497         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2498
2499         if(!this.move_qcphysics)
2500                 return;
2501
2502         int mt = this.move_movetype;
2503
2504         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2505         {
2506                 this.move_qcphysics = false;
2507                 set_movetype(this, mt);
2508                 return;
2509         }
2510
2511         if(!frametime && !this.pm_frametime)
2512                 return;
2513
2514         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2515
2516         this.pm_frametime = 0;
2517 }
2518
2519 /*
2520 =============
2521 PlayerPostThink
2522
2523 Called every frame for each client after the physics are run
2524 =============
2525 */
2526 .float idlekick_lasttimeleft;
2527 void PlayerPostThink (entity this)
2528 {
2529         Player_Physics(this);
2530
2531         if (sv_maxidle > 0)
2532         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2533         if (IS_REAL_CLIENT(this))
2534         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2535         {
2536                 int totalClients = 0;
2537                 if(sv_maxidle_slots > 0)
2538                 {
2539                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2540                         {
2541                                 ++totalClients;
2542                         });
2543                 }
2544
2545                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2546                 { /* do nothing */ }
2547                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2548                 {
2549                         if (this.idlekick_lasttimeleft)
2550                         {
2551                                 this.idlekick_lasttimeleft = 0;
2552                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2553                         }
2554                 }
2555                 else
2556                 {
2557                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2558                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2559                                 if (!this.idlekick_lasttimeleft)
2560                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2561                         }
2562                         if (timeleft <= 0) {
2563                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2564                                 dropclient(this);
2565                                 return;
2566                         }
2567                         else if (timeleft <= 10) {
2568                                 if (timeleft != this.idlekick_lasttimeleft) {
2569                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2570                 }
2571                                 this.idlekick_lasttimeleft = timeleft;
2572                         }
2573                 }
2574         }
2575
2576         CheatFrame(this);
2577
2578         //CheckPlayerJump();
2579
2580         if (IS_PLAYER(this)) {
2581                 DrownPlayer(this);
2582                 CheckRules_Player(this);
2583                 UpdateChatBubble(this);
2584                 if (this.impulse) ImpulseCommands(this);
2585                 if (intermission_running) return; // intermission or finale
2586                 GetPressedKeys(this);
2587         }
2588
2589         if (this.waypointsprite_attachedforcarrier) {
2590             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2591                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2592     }
2593
2594         playerdemo_write(this);
2595
2596         CSQCMODEL_AUTOUPDATE(this);
2597 }