qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include <common/vehicles/sv_vehicles.qh>
  50
  51 #include "../common/items/_mod.qh"
  52
  53 #include "../common/mutators/mutator/waypoints/all.qh"
  54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  55 #include <common/gamemodes/_mod.qh>
  56
  57 #include "../common/mapobjects/subs.qh"
  58 #include "../common/mapobjects/triggers.qh"
  59 #include "../common/mapobjects/trigger/secret.qh"
  60
  61 #include "../common/minigames/sv_minigames.qh"
  62
  63 #include "../common/items/inventory.qh"
  64
  65 #include "../common/monsters/sv_monsters.qh"
  66
  67 #include "../lib/warpzone/server.qh"
  68
  69 #include <common/mutators/mutator/overkill/oknex.qh>
  70
  71 STATIC_METHOD(Client, Add, void(Client this, int _team))
  72 {
  73     ClientConnect(this);
  74     TRANSMUTE(Player, this);
  75     this.frame = 12; // 7
  76     this.team = _team;
  77     PutClientInServer(this);
  78 }
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170
 171 /*
 172 =============
 173 CheckPlayerModel
 174
 175 Checks if the argument string can be a valid playermodel.
 176 Returns a valid one in doubt.
 177 =============
 178 */
 179 string FallbackPlayerModel;
 180 string CheckPlayerModel(string plyermodel) {
 181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 182         {
 183                 // note: we cannot summon Don Strunzone here, some player may
 184                 // still have the model string set. In case anyone manages how
 185                 // to change a cvar default, we'll have a small leak here.
 186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 187         }
 188         // only in right path
 189         if( substring(plyermodel,0,14) != "models/player/")
 190                 return FallbackPlayerModel;
 191         // only good file extensions
 192         if(substring(plyermodel,-4,4) != ".zym")
 193         if(substring(plyermodel,-4,4) != ".dpm")
 194         if(substring(plyermodel,-4,4) != ".iqm")
 195         if(substring(plyermodel,-4,4) != ".md3")
 196         if(substring(plyermodel,-4,4) != ".psk")
 197                 return FallbackPlayerModel;
 198         // forbid the LOD models
 199         if(substring(plyermodel, -9,5) == "_lod1")
 200                 return FallbackPlayerModel;
 201         if(substring(plyermodel, -9,5) == "_lod2")
 202                 return FallbackPlayerModel;
 203         if(plyermodel != strtolower(plyermodel))
 204                 return FallbackPlayerModel;
 205         // also, restrict to server models
 206         if(autocvar_sv_servermodelsonly)
 207         {
 208                 if(!fexists(plyermodel))
 209                         return FallbackPlayerModel;
 210         }
 211         return plyermodel;
 212 }
 213
 214 void setplayermodel(entity e, string modelname)
 215 {
 216         precache_model(modelname);
 217         _setmodel(e, modelname);
 218         player_setupanimsformodel(e);
 219         if(!autocvar_g_debug_globalsounds)
 220                 UpdatePlayerSounds(e);
 221 }
 222
 223 /** putting a client as observer in the server */
 224 void PutObserverInServer(entity this)
 225 {
 226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 227         PlayerState_detach(this);
 228
 229         if (IS_PLAYER(this))
 230         {
 231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 232                 {
 233                         // despawn effect
 234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 235                 }
 236
 237                 // was a player, recount votes and ready status
 238                 if(IS_REAL_CLIENT(this))
 239                 {
 240                         if (vote_called) { VoteCount(false); }
 241                         ReadyCount();
 242                 }
 243     }
 244
 245     {
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254             msg_entity = this;
 255             WriteByte(MSG_ONE, SVC_SETVIEW);
 256             WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269     }
 270
 271     RemoveGrapplingHooks(this);
 272         Portal_ClearAll(this);
 273         Unfreeze(this);
 274         SetSpectatee(this, NULL);
 275
 276         if (this.alivetime)
 277         {
 278                 if (!warmup_stage)
 279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 280                 this.alivetime = 0;
 281         }
 282
 283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 284
 285         WaypointSprite_PlayerDead(this);
 286
 287         if (mutator_returnvalue) {
 288             // mutator prevents resetting teams+score
 289         } else {
 290                 Player_SetTeamIndex(this, -1);
 291                 this.frags = FRAGS_SPECTATOR;
 292         PlayerScore_Clear(this);  // clear scores when needed
 293     }
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR)
 296         {
 297                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 298                 if(!game_stopped)
 299                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 300                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302                 if(!CS(this).just_joined)
 303                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 304                 else
 305                         CS(this).just_joined = false;
 306         }
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317     STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_frame = 0;
 344         this.pain_finished = 0;
 345         this.strength_finished = 0;
 346         this.invincible_finished = 0;
 347         this.superweapons_finished = 0;
 348         this.dphitcontentsmask = 0;
 349         this.pushltime = 0;
 350         this.istypefrag = 0;
 351         setthink(this, func_null);
 352         this.nextthink = 0;
 353         this.deadflag = DEAD_NO;
 354         this.crouch = false;
 355         STAT(REVIVE_PROGRESS, this) = 0;
 356         this.revival_time = 0;
 357
 358         this.items = 0;
 359         STAT(WEAPONS, this) = '0 0 0';
 360         this.drawonlytoclient = this;
 361
 362         this.viewloc = NULL;
 363
 364         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 365
 366         this.weaponmodel = "";
 367         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 368         {
 369                 this.weaponentities[slot] = NULL;
 370         }
 371         this.exteriorweaponentity = NULL;
 372         CS(this).killcount = FRAGS_SPECTATOR;
 373         this.velocity = '0 0 0';
 374         this.avelocity = '0 0 0';
 375         this.punchangle = '0 0 0';
 376         this.punchvector = '0 0 0';
 377         this.oldvelocity = this.velocity;
 378         this.fire_endtime = -1;
 379         this.event_damage = func_null;
 380         this.event_heal = func_null;
 381
 382         for(int slot = 0; slot < MAX_AXH; ++slot)
 383         {
 384                 entity axh = this.(AuxiliaryXhair[slot]);
 385                 this.(AuxiliaryXhair[slot]) = NULL;
 386
 387                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 388                         delete(axh);
 389         }
 390 }
 391
 392 int player_getspecies(entity this)
 393 {
 394         get_model_parameters(this.model, this.skin);
 395         int s = get_model_parameters_species;
 396         get_model_parameters(string_null, 0);
 397         if (s < 0) return SPECIES_HUMAN;
 398         return s;
 399 }
 400
 401 .float model_randomizer;
 402 void FixPlayermodel(entity player)
 403 {
 404         string defaultmodel = "";
 405         int defaultskin = 0;
 406         if(autocvar_sv_defaultcharacter)
 407         {
 408                 if(teamplay)
 409                 {
 410                         switch(player.team)
 411                         {
 412                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 413                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 414                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 415                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 416                         }
 417                 }
 418
 419                 if(defaultmodel == "")
 420                 {
 421                         defaultmodel = autocvar_sv_defaultplayermodel;
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423                 }
 424
 425                 int n = tokenize_console(defaultmodel);
 426                 if(n > 0)
 427                 {
 428                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 429                         // However, do NOT randomize if the player-selected model is in the list.
 430                         for (int i = 0; i < n; ++i)
 431                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 432                                         defaultmodel = argv(i);
 433                 }
 434
 435                 int i = strstrofs(defaultmodel, ":", 0);
 436                 if(i >= 0)
 437                 {
 438                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 439                         defaultmodel = substring(defaultmodel, 0, i);
 440                 }
 441         }
 442         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 443         {
 444                 if(teamplay)
 445                 {
 446                         switch(player.team)
 447                         {
 448                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 449                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 450                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 451                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 452                         }
 453                 }
 454
 455                 if(!defaultskin)
 456                         defaultskin = autocvar_sv_defaultplayerskin;
 457         }
 458
 459         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 460         defaultmodel = M_ARGV(0, string);
 461         defaultskin = M_ARGV(1, int);
 462
 463         bool chmdl = false;
 464         int oldskin;
 465         if(defaultmodel != "")
 466         {
 467                 if (defaultmodel != player.model)
 468                 {
 469                         vector m1 = player.mins;
 470                         vector m2 = player.maxs;
 471                         setplayermodel (player, defaultmodel);
 472                         setsize (player, m1, m2);
 473                         chmdl = true;
 474                 }
 475
 476                 oldskin = player.skin;
 477                 player.skin = defaultskin;
 478         } else {
 479                 if (player.playermodel != player.model || player.playermodel == "")
 480                 {
 481                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, player.playermodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 if(!autocvar_sv_defaultcharacterskin)
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = stof(player.playerskin);
 493                 }
 494                 else
 495                 {
 496                         oldskin = player.skin;
 497                         player.skin = defaultskin;
 498                 }
 499         }
 500
 501         if(chmdl || oldskin != player.skin) // model or skin has changed
 502         {
 503                 player.species = player_getspecies(player); // update species
 504                 if(!autocvar_g_debug_globalsounds)
 505                         UpdatePlayerSounds(player); // update skin sounds
 506         }
 507
 508         if(!teamplay)
 509                 if(strlen(autocvar_sv_defaultplayercolors))
 510                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 511                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 512 }
 513
 514 void PutPlayerInServer(entity this)
 515 {
 516         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518         PlayerState_attach(this);
 519         accuracy_resend(this);
 520
 521         if (this.team < 0)
 522                 TeamBalance_JoinBestTeam(this);
 523
 524         entity spot = SelectSpawnPoint(this, false);
 525         if (!spot) {
 526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                 return; // spawn failed
 528         }
 529
 530         TRANSMUTE(Player, this);
 531
 532         CS(this).wasplayer = true;
 533         this.iscreature = true;
 534         this.teleportable = TELEPORT_NORMAL;
 535         if(!this.damagedbycontents)
 536                 IL_PUSH(g_damagedbycontents, this);
 537         this.damagedbycontents = true;
 538         set_movetype(this, MOVETYPE_WALK);
 539         this.solid = SOLID_SLIDEBOX;
 540         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541         if (autocvar_g_playerclip_collisions)
 542                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545         this.frags = FRAGS_PLAYER;
 546         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548         if (autocvar__notarget)
 549                 this.flags |= FL_NOTARGET;
 550         this.takedamage = DAMAGE_AIM;
 551         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552
 553         if (warmup_stage) {
 554                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 555                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 556                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 557                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 558                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 559                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 560                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 561                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 562                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 563         } else {
 564                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 565                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 566                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 567                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 568                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 569                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 570                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 571                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 572                 STAT(WEAPONS, this) = start_weapons;
 573                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 574                 {
 575                         GiveRandomWeapons(this, random_start_weapons_count,
 576                                 autocvar_g_random_start_weapons, random_start_ammo);
 577                 }
 578         }
 579         SetSpectatee_status(this, 0);
 580
 581         PS(this).dual_weapons = '0 0 0';
 582
 583         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 584
 585         this.items = start_items;
 586
 587         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 588         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 589         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 590         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 591         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 592         if (!sv_ready_restart_after_countdown && time < game_starttime)
 593         {
 594                 float f = game_starttime - time;
 595                 this.spawnshieldtime += f;
 596                 this.pauserotarmor_finished += f;
 597                 this.pauserothealth_finished += f;
 598                 this.pauseregen_finished += f;
 599         }
 600
 601         this.damageforcescale = 2;
 602         this.death_time = 0;
 603         this.respawn_flags = 0;
 604         this.respawn_time = 0;
 605         STAT(RESPAWN_TIME, this) = 0;
 606         this.scale = autocvar_sv_player_scale;
 607         this.fade_time = 0;
 608         this.pain_frame = 0;
 609         this.pain_finished = 0;
 610         this.pushltime = 0;
 611         setthink(this, func_null); // players have no think function
 612         this.nextthink = 0;
 613         this.dmg_team = 0;
 614         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 615
 616         this.deadflag = DEAD_NO;
 617
 618         this.angles = spot.angles;
 619         this.angles_z = 0; // never spawn tilted even if the spot says to
 620         if (IS_BOT_CLIENT(this))
 621                 this.v_angle = this.angles;
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         this.strength_finished = 0;
 629         this.invincible_finished = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         this.air_finished = time + 12;
 635         this.waterlevel = WATERLEVEL_NONE;
 636         this.watertype = CONTENT_EMPTY;
 637
 638         entity spawnevent = new_pure(spawnevent);
 639         spawnevent.owner = this;
 640         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 641
 642         // Cut off any still running player sounds.
 643         stopsound(this, CH_PLAYER_SINGLE);
 644
 645         this.model = "";
 646         FixPlayermodel(this);
 647         this.drawonlytoclient = NULL;
 648
 649         this.viewloc = NULL;
 650
 651         for(int slot = 0; slot < MAX_AXH; ++slot)
 652         {
 653                 entity axh = this.(AuxiliaryXhair[slot]);
 654                 this.(AuxiliaryXhair[slot]) = NULL;
 655
 656                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 657                         delete(axh);
 658         }
 659
 660         this.spawnpoint_targ = NULL;
 661
 662         this.crouch = false;
 663         this.view_ofs = STAT(PL_VIEW_OFS, this);
 664         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 665         this.spawnorigin = spot.origin;
 666         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 667         // don't reset back to last position, even if new position is stuck in solid
 668         this.oldorigin = this.origin;
 669         if(this.conveyor)
 670                 IL_REMOVE(g_conveyed, this);
 671         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 672         STAT(HUD, this) = HUD_NORMAL;
 673
 674         this.event_damage = PlayerDamage;
 675         this.event_heal = PlayerHeal;
 676
 677         if(!this.bot_attack)
 678                 IL_PUSH(g_bot_targets, this);
 679         this.bot_attack = true;
 680         if(!this.monster_attack)
 681                 IL_PUSH(g_monster_targets, this);
 682         this.monster_attack = true;
 683         navigation_dynamicgoal_init(this, false);
 684
 685         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 686
 687         // player was spectator
 688         if (CS(this).killcount == FRAGS_SPECTATOR) {
 689                 PlayerScore_Clear(this);
 690                 CS(this).killcount = 0;
 691                 CS(this).startplaytime = time;
 692         }
 693
 694         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695         {
 696                 .entity weaponentity = weaponentities[slot];
 697                 entity oldwep = this.(weaponentity);
 698                 CL_SpawnWeaponentity(this, weaponentity);
 699                 if(oldwep && oldwep.owner == this)
 700                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 701         }
 702         this.alpha = default_player_alpha;
 703         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 704         this.exteriorweaponentity.alpha = default_weapon_alpha;
 705
 706         this.speedrunning = false;
 707
 708         target_voicescript_clear(this);
 709
 710         // reset fields the weapons may use
 711         FOREACH(Weapons, true, {
 712                 it.wr_resetplayer(it, this);
 713                         // reload all reloadable weapons
 714                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 715                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716                         {
 717                                 .entity weaponentity = weaponentities[slot];
 718                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 719                         }
 720                 }
 721         });
 722
 723         {
 724                 string s = spot.target;
 725                 spot.target = string_null;
 726                 SUB_UseTargets(spot, this, NULL);
 727                 spot.target = s;
 728         }
 729
 730         Unfreeze(this);
 731
 732         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 733
 734         if (autocvar_spawn_debug)
 735         {
 736                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 738         }
 739
 740         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 744                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 745                 else
 746                         this.(weaponentity).m_switchweapon = WEP_Null;
 747                 this.(weaponentity).m_weapon = WEP_Null;
 748                 this.(weaponentity).weaponname = "";
 749                 this.(weaponentity).m_switchingweapon = WEP_Null;
 750                 this.(weaponentity).cnt = -1;
 751         }
 752
 753         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 754
 755         if (CS(this).impulse) ImpulseCommands(this);
 756
 757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758         {
 759                 .entity weaponentity = weaponentities[slot];
 760                 W_WeaponFrame(this, weaponentity);
 761         }
 762
 763         if (!warmup_stage && !this.alivetime)
 764                 this.alivetime = time;
 765
 766         antilag_clear(this, CS(this));
 767 }
 768
 769 /** Called when a client spawns in the server */
 770 void PutClientInServer(entity this)
 771 {
 772         if (IS_BOT_CLIENT(this)) {
 773                 TRANSMUTE(Player, this);
 774         } else if (IS_REAL_CLIENT(this)) {
 775                 msg_entity = this;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, this);
 778         }
 779         if (game_stopped)
 780                 TRANSMUTE(Observer, this);
 781
 782         SetSpectatee(this, NULL);
 783
 784         // reset player keys
 785         if(PS(this))
 786                 PS(this).itemkeys = 0;
 787
 788         MUTATOR_CALLHOOK(PutClientInServer, this);
 789
 790         if (IS_OBSERVER(this)) {
 791                 PutObserverInServer(this);
 792         } else if (IS_PLAYER(this)) {
 793                 PutPlayerInServer(this);
 794         }
 795 }
 796
 797 // TODO do we need all these fields, or should we stop autodetecting runtime
 798 // changes and just have a console command to update this?
 799 bool ClientInit_SendEntity(entity this, entity to, int sf)
 800 {
 801         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 802         return = true;
 803         msg_entity = to;
 804         // MSG_INIT replacement
 805         // TODO: make easier to use
 806         Registry_send_all();
 807         W_PROP_reload(MSG_ONE, to);
 808         ClientInit_misc(this);
 809         MUTATOR_CALLHOOK(Ent_Init);
 810 }
 811 void ClientInit_misc(entity this)
 812 {
 813         int channel = MSG_ONE;
 814         WriteHeader(channel, ENT_CLIENT_INIT);
 815         WriteByte(channel, g_nexball_meter_period * 32);
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 824
 825         if(sv_foginterval && world.fog != "")
 826                 WriteString(channel, world.fog);
 827         else
 828                 WriteString(channel, "");
 829         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 830         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 831         WriteByte(channel, serverflags);
 832         WriteCoord(channel, autocvar_g_trueaim_minrange);
 833 }
 834
 835 void ClientInit_CheckUpdate(entity this)
 836 {
 837         this.nextthink = time;
 838         if(this.count != autocvar_g_balance_armor_blockpercent)
 839         {
 840                 this.count = autocvar_g_balance_armor_blockpercent;
 841                 this.SendFlags |= 1;
 842         }
 843         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 844         {
 845                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 846                 this.SendFlags |= 1;
 847         }
 848 }
 849
 850 void ClientInit_Spawn()
 851 {
 852         entity e = new_pure(clientinit);
 853         setthink(e, ClientInit_CheckUpdate);
 854         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 855
 856         ClientInit_CheckUpdate(e);
 857 }
 858
 859 /*
 860 =============
 861 SetNewParms
 862 =============
 863 */
 864 void SetNewParms ()
 865 {
 866         // initialize parms for a new player
 867         parm1 = -(86400 * 366);
 868
 869         MUTATOR_CALLHOOK(SetNewParms);
 870 }
 871
 872 /*
 873 =============
 874 SetChangeParms
 875 =============
 876 */
 877 void SetChangeParms (entity this)
 878 {
 879         // save parms for level change
 880         parm1 = CS(this).parm_idlesince - time;
 881
 882         MUTATOR_CALLHOOK(SetChangeParms);
 883 }
 884
 885 /*
 886 =============
 887 DecodeLevelParms
 888 =============
 889 */
 890 void DecodeLevelParms(entity this)
 891 {
 892         // load parms
 893         CS(this).parm_idlesince = parm1;
 894         if (CS(this).parm_idlesince == -(86400 * 366))
 895                 CS(this).parm_idlesince = time;
 896
 897         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 898         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 899
 900         MUTATOR_CALLHOOK(DecodeLevelParms);
 901 }
 902
 903 /*
 904 =============
 905 ClientKill
 906
 907 Called when a client types 'kill' in the console
 908 =============
 909 */
 910
 911 .float clientkill_nexttime;
 912 void ClientKill_Now_TeamChange(entity this)
 913 {
 914         if(this.killindicator_teamchange == -1)
 915         {
 916                 TeamBalance_JoinBestTeam(this);
 917         }
 918         else if(this.killindicator_teamchange == -2)
 919         {
 920                 if(blockSpectators)
 921                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 922                 PutObserverInServer(this);
 923         }
 924         else
 925                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 926         this.killindicator_teamchange = 0;
 927 }
 928
 929 void ClientKill_Now(entity this)
 930 {
 931         if(this.vehicle)
 932         {
 933             vehicles_exit(this.vehicle, VHEF_RELEASE);
 934             if(!this.killindicator_teamchange)
 935             {
 936             this.vehicle_health = -1;
 937             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 938             }
 939         }
 940
 941         if(this.killindicator && !wasfreed(this.killindicator))
 942                 delete(this.killindicator);
 943
 944         this.killindicator = NULL;
 945
 946         if(this.killindicator_teamchange)
 947                 ClientKill_Now_TeamChange(this);
 948
 949         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 950         {
 951                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 952         }
 953
 954         // now I am sure the player IS dead
 955 }
 956 void KillIndicator_Think(entity this)
 957 {
 958         if (game_stopped)
 959         {
 960                 this.owner.killindicator = NULL;
 961                 delete(this);
 962                 return;
 963         }
 964
 965         if (this.owner.alpha < 0 && !this.owner.vehicle)
 966         {
 967                 this.owner.killindicator = NULL;
 968                 delete(this);
 969                 return;
 970         }
 971
 972         if(this.cnt <= 0)
 973         {
 974                 ClientKill_Now(this.owner);
 975                 return;
 976         }
 977     else if(this.count == 1) // count == 1 means that it's silent
 978     {
 979         this.nextthink = time + 1;
 980         this.cnt -= 1;
 981     }
 982         else
 983         {
 984                 if(this.cnt <= 10)
 985                         setmodel(this, MDL_NUM(this.cnt));
 986                 if(IS_REAL_CLIENT(this.owner))
 987                 {
 988                         if(this.cnt <= 10)
 989                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 990                 }
 991                 this.nextthink = time + 1;
 992                 this.cnt -= 1;
 993         }
 994 }
 995
 996 float clientkilltime;
 997 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 998 {
 999         float killtime;
1000         float starttime;
1001
1002         if (game_stopped)
1003                 return;
1004
1005         killtime = autocvar_g_balance_kill_delay;
1006
1007     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1008         return;
1009     killtime = M_ARGV(1, float);
1010
1011         this.killindicator_teamchange = targetteam;
1012
1013     if(!this.killindicator)
1014         {
1015                 if(!IS_DEAD(this))
1016                 {
1017                         killtime = max(killtime, this.clientkill_nexttime - time);
1018                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1019                 }
1020
1021                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1022                 {
1023                         ClientKill_Now(this);
1024                 }
1025                 else
1026                 {
1027                         starttime = max(time, clientkilltime);
1028
1029                         this.killindicator = spawn();
1030                         this.killindicator.owner = this;
1031                         this.killindicator.scale = 0.5;
1032                         setattachment(this.killindicator, this, "");
1033                         setorigin(this.killindicator, '0 0 52');
1034                         setthink(this.killindicator, KillIndicator_Think);
1035                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1036                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1037                         this.killindicator.cnt = ceil(killtime);
1038                         this.killindicator.count = bound(0, ceil(killtime), 10);
1039                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1040
1041                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1042                         {
1043                                 it.killindicator = spawn();
1044                                 it.killindicator.owner = it;
1045                                 it.killindicator.scale = 0.5;
1046                                 setattachment(it.killindicator, it, "");
1047                                 setorigin(it.killindicator, '0 0 52');
1048                                 setthink(it.killindicator, KillIndicator_Think);
1049                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1050                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1051                                 it.killindicator.cnt = ceil(killtime);
1052                         });
1053                         this.lip = 0;
1054                 }
1055         }
1056         if(this.killindicator)
1057         {
1058                 if(targetteam == 0) // just die
1059                 {
1060                         this.killindicator.colormod = '0 0 0';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1064                 }
1065                 else if(targetteam == -1) // auto
1066                 {
1067                         this.killindicator.colormod = '0 1 0';
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1071                 }
1072                 else if(targetteam == -2) // spectate
1073                 {
1074                         this.killindicator.colormod = '0.5 0.5 0.5';
1075                         if(IS_REAL_CLIENT(this))
1076                         if(this.killindicator.cnt > 0)
1077                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1078                 }
1079                 else
1080                 {
1081                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1082                         if(IS_REAL_CLIENT(this))
1083                         if(this.killindicator.cnt > 0)
1084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1085                 }
1086         }
1087
1088 }
1089
1090 void ClientKill (entity this)
1091 {
1092         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1093
1094         if(game_stopped) return;
1095         if(this.player_blocked) return;
1096         if(STAT(FROZEN, this)) return;
1097
1098         ClientKill_TeamChange(this, 0);
1099 }
1100
1101 void FixClientCvars(entity e)
1102 {
1103         // send prediction settings to the client
1104         stuffcmd(e, "\nin_bindmap 0 0\n");
1105         if(autocvar_g_antilag == 3) // client side hitscan
1106                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1107         if(autocvar_sv_gentle)
1108                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1109
1110         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1111         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1112
1113         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1114
1115         MUTATOR_CALLHOOK(FixClientCvars, e);
1116 }
1117
1118 bool findinlist_abbrev(string tofind, string list)
1119 {
1120         if(list == "" || tofind == "")
1121                 return false; // empty list or search, just return
1122
1123         // this function allows abbreviated strings!
1124         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1125         {
1126                 return true;
1127         });
1128
1129         return false;
1130 }
1131
1132 bool PlayerInIPList(entity p, string iplist)
1133 {
1134         // some safety checks (never allow local?)
1135         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1136                 return false;
1137
1138         return findinlist_abbrev(p.netaddress, iplist);
1139 }
1140
1141 bool PlayerInIDList(entity p, string idlist)
1142 {
1143         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1144         if(!p.crypto_idfp)
1145                 return false;
1146
1147         return findinlist_abbrev(p.crypto_idfp, idlist);
1148 }
1149
1150 bool PlayerInList(entity player, string list)
1151 {
1152         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1153 }
1154
1155 #ifdef DP_EXT_PRECONNECT
1156 /*
1157 =============
1158 ClientPreConnect
1159
1160 Called once (not at each match start) when a client begins a connection to the server
1161 =============
1162 */
1163 void ClientPreConnect(entity this)
1164 {
1165         if(autocvar_sv_eventlog)
1166         {
1167                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1168                         this.playerid,
1169                         etof(this),
1170                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1171                 ));
1172         }
1173 }
1174 #endif
1175
1176 string GetClientVersionMessage(entity this)
1177 {
1178         if (CS(this).version_mismatch) {
1179                 if(CS(this).version < autocvar_gameversion) {
1180                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1181                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1182                 } else {
1183                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1184                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1185                 }
1186         } else {
1187                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1188         }
1189 }
1190
1191 string getwelcomemessage(entity this)
1192 {
1193         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1194         string modifications = M_ARGV(0, string);
1195
1196         if(g_weaponarena)
1197         {
1198                 if(g_weaponarena_random)
1199                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1200                 else
1201                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1202         }
1203         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1204                 modifications = strcat(modifications, ", No start weapons");
1205         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1206                 modifications = strcat(modifications, ", Low gravity");
1207         if(g_weapon_stay && !g_cts)
1208                 modifications = strcat(modifications, ", Weapons stay");
1209         if(g_jetpack)
1210                 modifications = strcat(modifications, ", Jet pack");
1211         if(autocvar_g_powerups == 0)
1212                 modifications = strcat(modifications, ", No powerups");
1213         if(autocvar_g_powerups > 0)
1214                 modifications = strcat(modifications, ", Powerups");
1215         modifications = substring(modifications, 2, strlen(modifications) - 2);
1216
1217         string versionmessage = GetClientVersionMessage(this);
1218         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1219
1220         if(modifications != "")
1221                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1222
1223         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1224         {
1225                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1226                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1227         }
1228
1229         if (cache_mutatormsg != "") {
1230                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1231         }
1232
1233         string mutator_msg = "";
1234         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1235         mutator_msg = M_ARGV(0, string);
1236
1237         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1238
1239         string motd = autocvar_sv_motd;
1240         if (motd != "") {
1241                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1242         }
1243         return s;
1244 }
1245
1246 /**
1247 =============
1248 ClientConnect
1249
1250 Called when a client connects to the server
1251 =============
1252 */
1253 void ClientConnect(entity this)
1254 {
1255         if (Ban_MaybeEnforceBanOnce(this)) return;
1256         assert(!IS_CLIENT(this), return);
1257         this.flags |= FL_CLIENT;
1258         assert(player_count >= 0, player_count = 0);
1259
1260 #ifdef WATERMARK
1261         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1262 #endif
1263         TRANSMUTE(Client, this);
1264         CS(this).version_nagtime = time + 10 + random() * 10;
1265
1266         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1267
1268         bot_clientconnect(this);
1269
1270         // identify the right forced team
1271         if (autocvar_g_campaign)
1272         {
1273                 if (IS_REAL_CLIENT(this)) // only players, not bots
1274                 {
1275                         switch (autocvar_g_campaign_forceteam)
1276                         {
1277                                 case 1: this.team_forced = NUM_TEAM_1; break;
1278                                 case 2: this.team_forced = NUM_TEAM_2; break;
1279                                 case 3: this.team_forced = NUM_TEAM_3; break;
1280                                 case 4: this.team_forced = NUM_TEAM_4; break;
1281                                 default: this.team_forced = 0;
1282                         }
1283                 }
1284         }
1285         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1286         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1287         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1288         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1289         else switch (autocvar_g_forced_team_otherwise)
1290         {
1291                 default: this.team_forced = 0; break;
1292                 case "red": this.team_forced = NUM_TEAM_1; break;
1293                 case "blue": this.team_forced = NUM_TEAM_2; break;
1294                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1295                 case "pink": this.team_forced = NUM_TEAM_4; break;
1296                 case "spectate":
1297                 case "spectator":
1298                         this.team_forced = -1;
1299                         break;
1300         }
1301         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1302
1303         TRANSMUTE(Observer, this);
1304
1305         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1306
1307         // always track bots, don't ask for cl_allow_uidtracking
1308         if (IS_BOT_CLIENT(this))
1309                 PlayerStats_GameReport_AddPlayer(this);
1310         else
1311                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1312
1313         if (autocvar_sv_eventlog)
1314                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1315
1316         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1317
1318         stuffcmd(this, clientstuff, "\n");
1319         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1320
1321         FixClientCvars(this);
1322
1323         // get version info from player
1324         stuffcmd(this, "cmd clientversion $gameversion\n");
1325
1326         // notify about available teams
1327         if (teamplay)
1328         {
1329                 entity balance = TeamBalance_CheckAllowedTeams(this);
1330                 int t = TeamBalance_GetAllowedTeams(balance);
1331                 TeamBalance_Destroy(balance);
1332                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1333         }
1334         else
1335         {
1336                 stuffcmd(this, "set _teams_available 0\n");
1337         }
1338
1339         bot_relinkplayerlist();
1340
1341         CS(this).spectatortime = time;
1342         if (blockSpectators)
1343         {
1344                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1345         }
1346
1347         CS(this).jointime = time;
1348
1349         if (IS_REAL_CLIENT(this))
1350         {
1351                 if (g_weaponarena_weapons == WEPSET(TUBA))
1352                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1353         }
1354
1355         if (!sv_foginterval && world.fog != "")
1356                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1357
1358         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1359                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1360                         send_CSQC_teamnagger();
1361
1362         CSQCMODEL_AUTOINIT(this);
1363
1364         CS(this).model_randomizer = random();
1365
1366         if (IS_REAL_CLIENT(this))
1367                 sv_notice_join(this);
1368
1369         // update physics stats (players can spawn before physics runs)
1370         Physics_UpdateStats(this);
1371
1372         IL_EACH(g_initforplayer, it.init_for_player, {
1373                 it.init_for_player(it, this);
1374         });
1375
1376         Handicap_Initialize(this);
1377
1378         MUTATOR_CALLHOOK(ClientConnect, this);
1379
1380         if (IS_REAL_CLIENT(this))
1381         {
1382                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1383                 {
1384                         CS(this).motd_actived_time = -1;
1385                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1386                 }
1387         }
1388 }
1389 /*
1390 =============
1391 ClientDisconnect
1392
1393 Called when a client disconnects from the server
1394 =============
1395 */
1396 .entity chatbubbleentity;
1397 void ClientDisconnect(entity this)
1398 {
1399         assert(IS_CLIENT(this), return);
1400
1401         PlayerStats_GameReport_FinalizePlayer(this);
1402         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1403         if (CS(this).active_minigame) part_minigame(this);
1404         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1405
1406         if (autocvar_sv_eventlog)
1407                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1408
1409         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1410
1411         if(IS_SPEC(this))
1412                 SetSpectatee(this, NULL);
1413
1414     MUTATOR_CALLHOOK(ClientDisconnect, this);
1415
1416         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1417         strfree(CS(this).weaponorder_byimpulse);
1418         ClientState_detach(this);
1419
1420         Portal_ClearAll(this);
1421
1422         Unfreeze(this);
1423
1424         RemoveGrapplingHooks(this);
1425
1426         // Here, everything has been done that requires this player to be a client.
1427
1428         this.flags &= ~FL_CLIENT;
1429
1430         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1431         if (this.killindicator) delete(this.killindicator);
1432
1433         WaypointSprite_PlayerGone(this);
1434
1435         bot_relinkplayerlist();
1436
1437         strfree(this.clientstatus);
1438         if (this.personal) delete(this.personal);
1439
1440         this.playerid = 0;
1441         ReadyCount();
1442         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1443
1444         ONREMOVE(this);
1445 }
1446
1447 void ChatBubbleThink(entity this)
1448 {
1449         this.nextthink = time;
1450         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1451         {
1452                 if(this.owner) // but why can that ever be NULL?
1453                         this.owner.chatbubbleentity = NULL;
1454                 delete(this);
1455                 return;
1456         }
1457
1458         this.mdl = "";
1459
1460         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1461         {
1462                 if ( CS(this.owner).active_minigame )
1463                         this.mdl = "models/sprites/minigame_busy.iqm";
1464                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1465                         this.mdl = "models/misc/chatbubble.spr";
1466         }
1467
1468         if ( this.model != this.mdl )
1469                 _setmodel(this, this.mdl);
1470
1471 }
1472
1473 void UpdateChatBubble(entity this)
1474 {
1475         if (this.alpha < 0)
1476                 return;
1477         // spawn a chatbubble entity if needed
1478         if (!this.chatbubbleentity)
1479         {
1480                 this.chatbubbleentity = new(chatbubbleentity);
1481                 this.chatbubbleentity.owner = this;
1482                 this.chatbubbleentity.exteriormodeltoclient = this;
1483                 setthink(this.chatbubbleentity, ChatBubbleThink);
1484                 this.chatbubbleentity.nextthink = time;
1485                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1486                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1487                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1488                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1489                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1490                 //this.chatbubbleentity.model = "";
1491                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1492         }
1493 }
1494
1495
1496 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1497 // added to the model skins
1498 /*void UpdateColorModHack()
1499 {
1500         float c;
1501         c = this.clientcolors & 15;
1502         // LordHavoc: only bothering to support white, green, red, yellow, blue
1503              if (!teamplay) this.colormod = '0 0 0';
1504         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1505         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1506         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1507         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1508         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1509         else this.colormod = '1 1 1';
1510 }*/
1511
1512 void respawn(entity this)
1513 {
1514         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1515         {
1516                 this.solid = SOLID_NOT;
1517                 this.takedamage = DAMAGE_NO;
1518                 set_movetype(this, MOVETYPE_FLY);
1519                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1520                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1521                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1522                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1523                 if(autocvar_g_respawn_ghosts_maxtime)
1524                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1525         }
1526
1527         CopyBody(this, 1);
1528
1529         this.effects |= EF_NODRAW; // prevent another CopyBody
1530         PutClientInServer(this);
1531 }
1532
1533 void PrintToChat(entity client, string text)
1534 {
1535         text = strcat("\{1}^7", text, "\n");
1536         sprint(client, text);
1537 }
1538
1539 void DebugPrintToChat(entity client, string text)
1540 {
1541         if (autocvar_developer)
1542         {
1543                 PrintToChat(client, text);
1544         }
1545 }
1546
1547 void PrintToChatAll(string text)
1548 {
1549         text = strcat("\{1}^7", text, "\n");
1550         bprint(text);
1551 }
1552
1553 void DebugPrintToChatAll(string text)
1554 {
1555         if (autocvar_developer)
1556         {
1557                 PrintToChatAll(text);
1558         }
1559 }
1560
1561 void PrintToChatTeam(int team_num, string text)
1562 {
1563         text = strcat("\{1}^7", text, "\n");
1564         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1565         {
1566                 if (it.team == team_num)
1567                 {
1568                         sprint(it, text);
1569                 }
1570         });
1571 }
1572
1573 void DebugPrintToChatTeam(int team_num, string text)
1574 {
1575         if (autocvar_developer)
1576         {
1577                 PrintToChatTeam(team_num, text);
1578         }
1579 }
1580
1581 void play_countdown(entity this, float finished, Sound samp)
1582 {
1583         TC(Sound, samp);
1584         if(IS_REAL_CLIENT(this))
1585                 if(floor(finished - time - frametime) != floor(finished - time))
1586                         if(finished - time < 6)
1587                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1588 }
1589
1590 void player_powerups(entity this)
1591 {
1592         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1593         int items_prev = this.items;
1594
1595         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1596                 this.modelflags |= MF_ROCKET;
1597         else
1598                 this.modelflags &= ~MF_ROCKET;
1599
1600         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1601
1602         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1603                 return;
1604
1605         Fire_ApplyDamage(this);
1606         Fire_ApplyEffect(this);
1607
1608         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1609         {
1610                 if (this.items & ITEM_Strength.m_itemid)
1611                 {
1612                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1613                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1614                         if (time > this.strength_finished)
1615                         {
1616                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1617                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1618                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1619                         }
1620                 }
1621                 else
1622                 {
1623                         if (time < this.strength_finished)
1624                         {
1625                                 this.items = this.items | ITEM_Strength.m_itemid;
1626                                 if(!g_cts)
1627                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1628                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1629                         }
1630                 }
1631                 if (this.items & ITEM_Shield.m_itemid)
1632                 {
1633                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1634                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1635                         if (time > this.invincible_finished)
1636                         {
1637                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1638                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1639                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1640                         }
1641                 }
1642                 else
1643                 {
1644                         if (time < this.invincible_finished)
1645                         {
1646                                 this.items = this.items | ITEM_Shield.m_itemid;
1647                                 if(!g_cts)
1648                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1649                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1650                         }
1651                 }
1652                 if (this.items & IT_SUPERWEAPON)
1653                 {
1654                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1655                         {
1656                                 this.superweapons_finished = 0;
1657                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1658                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1659                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1660                         }
1661                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1662                         {
1663                                 // don't let them run out
1664                         }
1665                         else
1666                         {
1667                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1668                                 if (time > this.superweapons_finished)
1669                                 {
1670                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1671                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1672                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1673                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1674                                 }
1675                         }
1676                 }
1677                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1678                 {
1679                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1680                         {
1681                                 this.items = this.items | IT_SUPERWEAPON;
1682                                 if(!g_cts)
1683                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1684                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1685                         }
1686                         else
1687                         {
1688                                 this.superweapons_finished = 0;
1689                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1690                         }
1691                 }
1692                 else
1693                 {
1694                         this.superweapons_finished = 0;
1695                 }
1696         }
1697
1698         if(autocvar_g_nodepthtestplayers)
1699                 this.effects = this.effects | EF_NODEPTHTEST;
1700
1701         if(autocvar_g_fullbrightplayers)
1702                 this.effects = this.effects | EF_FULLBRIGHT;
1703
1704         if (time >= game_starttime)
1705         if (time < this.spawnshieldtime)
1706                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1707
1708         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1709 }
1710
1711 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1712 {
1713         if(current > stable)
1714                 return current;
1715         else if(current > stable - 0.25) // when close enough, "snap"
1716                 return stable;
1717         else
1718                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1719 }
1720
1721 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1722 {
1723         if(current < stable)
1724                 return current;
1725         else if(current < stable + 0.25) // when close enough, "snap"
1726                 return stable;
1727         else
1728                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1729 }
1730
1731 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1732 {
1733         if(current > rotstable)
1734         {
1735                 if(rotframetime > 0)
1736                 {
1737                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1738                         current = max(rotstable, current - rotlinear * rotframetime);
1739                 }
1740         }
1741         else if(current < regenstable)
1742         {
1743                 if(regenframetime > 0)
1744                 {
1745                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1746                         current = min(regenstable, current + regenlinear * regenframetime);
1747                 }
1748         }
1749
1750         if(current > limit)
1751                 current = limit;
1752
1753         return current;
1754 }
1755
1756 void player_regen(entity this)
1757 {
1758         float max_mod, regen_mod, rot_mod, limit_mod;
1759         max_mod = regen_mod = rot_mod = limit_mod = 1;
1760
1761         float regen_health = autocvar_g_balance_health_regen;
1762         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1763         float regen_health_rot = autocvar_g_balance_health_rot;
1764         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1765         float regen_health_stable = autocvar_g_balance_health_regenstable;
1766         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1767         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1768                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1769         max_mod = M_ARGV(1, float);
1770         regen_mod = M_ARGV(2, float);
1771         rot_mod = M_ARGV(3, float);
1772         limit_mod = M_ARGV(4, float);
1773         regen_health = M_ARGV(5, float);
1774         regen_health_linear = M_ARGV(6, float);
1775         regen_health_rot = M_ARGV(7, float);
1776         regen_health_rotlinear = M_ARGV(8, float);
1777         regen_health_stable = M_ARGV(9, float);
1778         regen_health_rotstable = M_ARGV(10, float);
1779
1780         if(!mutator_returnvalue)
1781         if(!STAT(FROZEN, this))
1782         {
1783                 float mina, maxa, limith, limita;
1784                 maxa = autocvar_g_balance_armor_rotstable;
1785                 mina = autocvar_g_balance_armor_regenstable;
1786                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1787                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1788
1789                 regen_health_rotstable = regen_health_rotstable * max_mod;
1790                 regen_health_stable = regen_health_stable * max_mod;
1791                 limith = limith * limit_mod;
1792                 limita = limita * limit_mod;
1793
1794                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1795                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1796                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1797                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1798                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1799                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1800         }
1801
1802         // if player rotted to death...  die!
1803         // check this outside above checks, as player may still be able to rot to death
1804         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1805         {
1806                 if(this.vehicle)
1807                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1808                 if(this.event_damage)
1809                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1810         }
1811
1812         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1813         {
1814                 float minf, maxf, limitf;
1815
1816                 maxf = autocvar_g_balance_fuel_rotstable;
1817                 minf = autocvar_g_balance_fuel_regenstable;
1818                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1819
1820                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1821                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1822                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1823         }
1824 }
1825
1826 bool zoomstate_set;
1827 void SetZoomState(entity this, float newzoom)
1828 {
1829         if(newzoom != CS(this).zoomstate)
1830         {
1831                 CS(this).zoomstate = newzoom;
1832                 ClientData_Touch(this);
1833         }
1834         zoomstate_set = true;
1835 }
1836
1837 void GetPressedKeys(entity this)
1838 {
1839         MUTATOR_CALLHOOK(GetPressedKeys, this);
1840         int keys = STAT(PRESSED_KEYS, this);
1841         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1842         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1843         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1844         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1845
1846         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1847         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1848         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1849         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1850         CS(this).pressedkeys = keys; // store for other users
1851
1852         STAT(PRESSED_KEYS, this) = keys;
1853 }
1854
1855 /*
1856 ======================
1857 spectate mode routines
1858 ======================
1859 */
1860
1861 void SpectateCopy(entity this, entity spectatee)
1862 {
1863         TC(Client, this); TC(Client, spectatee);
1864
1865         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1866         PS(this) = PS(spectatee);
1867         this.armortype = spectatee.armortype;
1868         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1869         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1870         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1871         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1872         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1873         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1874         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1875         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1876         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1877         CS(this).impulse = 0;
1878         this.items = spectatee.items;
1879         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1880         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1881         this.strength_finished = spectatee.strength_finished;
1882         this.invincible_finished = spectatee.invincible_finished;
1883         this.superweapons_finished = spectatee.superweapons_finished;
1884         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1885         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1886         this.punchangle = spectatee.punchangle;
1887         this.view_ofs = spectatee.view_ofs;
1888         this.velocity = spectatee.velocity;
1889         this.dmg_take = spectatee.dmg_take;
1890         this.dmg_save = spectatee.dmg_save;
1891         this.dmg_inflictor = spectatee.dmg_inflictor;
1892         this.v_angle = spectatee.v_angle;
1893         this.angles = spectatee.v_angle;
1894         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1895         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1896         this.viewloc = spectatee.viewloc;
1897         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1898                 this.fixangle = true;
1899         setorigin(this, spectatee.origin);
1900         setsize(this, spectatee.mins, spectatee.maxs);
1901         SetZoomState(this, CS(spectatee).zoomstate);
1902
1903     anticheat_spectatecopy(this, spectatee);
1904         STAT(HUD, this) = STAT(HUD, spectatee);
1905         if(spectatee.vehicle)
1906     {
1907         this.angles = spectatee.v_angle;
1908
1909         //this.fixangle = false;
1910         //this.velocity = spectatee.vehicle.velocity;
1911         this.vehicle_health = spectatee.vehicle_health;
1912         this.vehicle_shield = spectatee.vehicle_shield;
1913         this.vehicle_energy = spectatee.vehicle_energy;
1914         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1915         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1916         this.vehicle_reload1 = spectatee.vehicle_reload1;
1917         this.vehicle_reload2 = spectatee.vehicle_reload2;
1918
1919         //msg_entity = this;
1920
1921        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1922             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1923            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1924            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1925
1926         //WriteByte (MSG_ONE, SVC_SETVIEW);
1927         //    WriteEntity(MSG_ONE, this);
1928         //makevectors(spectatee.v_angle);
1929         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1930     }
1931 }
1932
1933 bool SpectateUpdate(entity this)
1934 {
1935         if(!this.enemy)
1936                 return false;
1937
1938         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1939         {
1940                 SetSpectatee(this, NULL);
1941                 return false;
1942         }
1943
1944         SpectateCopy(this, this.enemy);
1945
1946         return true;
1947 }
1948
1949 bool SpectateSet(entity this)
1950 {
1951         if(!IS_PLAYER(this.enemy))
1952                 return false;
1953
1954         ClientData_Touch(this.enemy);
1955
1956         msg_entity = this;
1957         WriteByte(MSG_ONE, SVC_SETVIEW);
1958         WriteEntity(MSG_ONE, this.enemy);
1959         set_movetype(this, MOVETYPE_NONE);
1960         accuracy_resend(this);
1961
1962         if(!SpectateUpdate(this))
1963                 PutObserverInServer(this);
1964
1965         return true;
1966 }
1967
1968 void SetSpectatee_status(entity this, int spectatee_num)
1969 {
1970         int oldspectatee_status = CS(this).spectatee_status;
1971         CS(this).spectatee_status = spectatee_num;
1972
1973         if (CS(this).spectatee_status != oldspectatee_status)
1974         {
1975                 ClientData_Touch(this);
1976                 if (g_race || g_cts) race_InitSpectator();
1977         }
1978 }
1979
1980 void SetSpectatee(entity this, entity spectatee)
1981 {
1982         if(IS_BOT_CLIENT(this))
1983                 return; // bots abuse .enemy, this code is useless to them
1984
1985         entity old_spectatee = this.enemy;
1986
1987         this.enemy = spectatee;
1988
1989         // WEAPONTODO
1990         // these are required to fix the spectator bug with arc
1991         if(old_spectatee)
1992         {
1993                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1994                 {
1995                         .entity weaponentity = weaponentities[slot];
1996                         if(old_spectatee.(weaponentity).arc_beam)
1997                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1998                 }
1999         }
2000         if(this.enemy)
2001         {
2002                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2003                 {
2004                         .entity weaponentity = weaponentities[slot];
2005                         if(this.enemy.(weaponentity).arc_beam)
2006                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
2007                 }
2008         }
2009
2010         if (this.enemy)
2011                 SetSpectatee_status(this, etof(this.enemy));
2012
2013         // needed to update spectator list
2014         if(old_spectatee) { ClientData_Touch(old_spectatee); }
2015 }
2016
2017 bool Spectate(entity this, entity pl)
2018 {
2019         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
2020                 return false;
2021         pl = M_ARGV(1, entity);
2022
2023         SetSpectatee(this, pl);
2024         return SpectateSet(this);
2025 }
2026
2027 bool SpectateNext(entity this)
2028 {
2029         entity ent = find(this.enemy, classname, STR_PLAYER);
2030
2031         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2032                 ent = M_ARGV(1, entity);
2033         else if (!ent)
2034                 ent = find(ent, classname, STR_PLAYER);
2035
2036         if(ent) { SetSpectatee(this, ent); }
2037
2038         return SpectateSet(this);
2039 }
2040
2041 bool SpectatePrev(entity this)
2042 {
2043         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2044         entity ent = findchain(classname, STR_PLAYER);
2045         if (!ent) // no player
2046                 return false;
2047
2048         entity first = ent;
2049         // skip players until current spectated player
2050         if(this.enemy)
2051         while(ent && ent != this.enemy)
2052                 ent = ent.chain;
2053
2054         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2055         {
2056                 case MUT_SPECPREV_FOUND:
2057                     ent = M_ARGV(1, entity);
2058                     break;
2059                 case MUT_SPECPREV_RETURN:
2060                     return true;
2061                 case MUT_SPECPREV_CONTINUE:
2062                 default:
2063                 {
2064                         if(ent.chain)
2065                                 ent = ent.chain;
2066                         else
2067                                 ent = first;
2068                         break;
2069                 }
2070         }
2071
2072         SetSpectatee(this, ent);
2073         return SpectateSet(this);
2074 }
2075
2076 /*
2077 =============
2078 ShowRespawnCountdown()
2079
2080 Update a respawn countdown display.
2081 =============
2082 */
2083 void ShowRespawnCountdown(entity this)
2084 {
2085         float number;
2086         if(!IS_DEAD(this)) // just respawned?
2087                 return;
2088         else
2089         {
2090                 number = ceil(this.respawn_time - time);
2091                 if(number <= 0)
2092                         return;
2093                 if(number <= this.respawn_countdown)
2094                 {
2095                         this.respawn_countdown = number - 1;
2096                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2097                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2098                 }
2099         }
2100 }
2101
2102 .bool team_selected;
2103 bool ShowTeamSelection(entity this)
2104 {
2105         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2106                 return false;
2107         stuffcmd(this, "menu_showteamselect\n");
2108         return true;
2109 }
2110 void Join(entity this)
2111 {
2112         TRANSMUTE(Player, this);
2113
2114         if(!this.team_selected)
2115         if(autocvar_g_campaign || autocvar_g_balance_teams)
2116                 TeamBalance_JoinBestTeam(this);
2117
2118         if(autocvar_g_campaign)
2119                 campaign_bots_may_start = true;
2120
2121         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2122
2123         PutClientInServer(this);
2124
2125         if(IS_PLAYER(this))
2126         if(teamplay && this.team != -1)
2127         {
2128                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2129         }
2130         else
2131                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2132         this.team_selected = false;
2133 }
2134
2135 /**
2136  * Determines whether the player is allowed to join. This depends on cvar
2137  * g_maxplayers, if it isn't used this function always return true, otherwise
2138  * it checks whether the number of currently playing players exceeds g_maxplayers.
2139  * @return int number of free slots for players, 0 if none
2140  */
2141 int nJoinAllowed(entity this, entity ignore)
2142 {
2143         if(!ignore)
2144         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2145         // so report 0 free slots if restricted
2146         {
2147                 if(autocvar_g_forced_team_otherwise == "spectate")
2148                         return 0;
2149                 if(autocvar_g_forced_team_otherwise == "spectator")
2150                         return 0;
2151         }
2152
2153         if(this && this.team_forced < 0)
2154                 return 0; // forced spectators can never join
2155
2156         // TODO simplify this
2157         int totalClients = 0;
2158         int currentlyPlaying = 0;
2159         FOREACH_CLIENT(true, {
2160                 if(it != ignore)
2161                         ++totalClients;
2162                 if(IS_REAL_CLIENT(it))
2163                 if(IS_PLAYER(it) || it.caplayer)
2164                         ++currentlyPlaying;
2165         });
2166
2167         float free_slots = 0;
2168         if (!autocvar_g_maxplayers)
2169                 free_slots = maxclients - totalClients;
2170         else if(currentlyPlaying < autocvar_g_maxplayers)
2171                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2172
2173         static float join_prevent_msg_time = 0;
2174         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2175         {
2176                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2177                 join_prevent_msg_time = time + 3;
2178         }
2179
2180         return free_slots;
2181 }
2182
2183 /**
2184  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2185  * g_maxplayers_spectator_blocktime seconds
2186  */
2187 void checkSpectatorBlock(entity this)
2188 {
2189         if(IS_SPEC(this) || IS_OBSERVER(this))
2190         if(!this.caplayer)
2191         if(IS_REAL_CLIENT(this))
2192         {
2193                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2194                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2195                         dropclient(this);
2196                 }
2197         }
2198 }
2199
2200 void PrintWelcomeMessage(entity this)
2201 {
2202         if(CS(this).motd_actived_time == 0)
2203         {
2204                 if (autocvar_g_campaign) {
2205                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2206                                 CS(this).motd_actived_time = time;
2207                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2208                         }
2209                 } else {
2210                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2211                                 CS(this).motd_actived_time = time;
2212                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2213                         }
2214                 }
2215         }
2216         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2217         {
2218                 if (autocvar_g_campaign) {
2219                         if (PHYS_INPUT_BUTTON_INFO(this))
2220                                 CS(this).motd_actived_time = time;
2221                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2222                                 CS(this).motd_actived_time = 0;
2223                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2224                         }
2225                 } else {
2226                         if (PHYS_INPUT_BUTTON_INFO(this))
2227                                 CS(this).motd_actived_time = time;
2228                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2229                                 CS(this).motd_actived_time = 0;
2230                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2231                         }
2232                 }
2233         }
2234         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2235         {
2236                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2237                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2238                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2239                 {
2240                         // instanctly hide MOTD
2241                         CS(this).motd_actived_time = 0;
2242                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2243                 }
2244         }
2245 }
2246
2247 const int MIN_SPEC_TIME = 1;
2248 bool joinAllowed(entity this)
2249 {
2250         if (CS(this).version_mismatch) return false;
2251         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2252         if (!nJoinAllowed(this, this)) return false;
2253         if (teamplay && lockteams) return false;
2254         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2255         if (ShowTeamSelection(this)) return false;
2256         return true;
2257 }
2258
2259 .int items_added;
2260 .string shootfromfixedorigin;
2261 bool PlayerThink(entity this)
2262 {
2263         if (game_stopped || intermission_running) {
2264                 this.modelflags &= ~MF_ROCKET;
2265                 if(intermission_running)
2266                         IntermissionThink(this);
2267                 return false;
2268         }
2269
2270         if (timeout_status == TIMEOUT_ACTIVE) {
2271         // don't allow the player to turn around while game is paused
2272                 // FIXME turn this into CSQC stuff
2273                 this.v_angle = this.lastV_angle;
2274                 this.angles = this.lastV_angle;
2275                 this.fixangle = true;
2276         }
2277
2278         if (frametime) player_powerups(this);
2279
2280         if (IS_DEAD(this)) {
2281                 if (this.personal && g_race_qualifying) {
2282                         if (time > this.respawn_time) {
2283                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2284                                 respawn(this);
2285                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2286                         }
2287                 } else {
2288                         if (frametime) player_anim(this);
2289
2290                         if (this.respawn_flags & RESPAWN_DENY)
2291                         {
2292                                 STAT(RESPAWN_TIME, this) = 0;
2293                                 return false;
2294                         }
2295
2296                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2297
2298                         switch(this.deadflag)
2299                         {
2300                                 case DEAD_DYING:
2301                                 {
2302                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2303                                                 this.deadflag = DEAD_RESPAWNING;
2304                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2305                                                 this.deadflag = DEAD_DEAD;
2306                                         break;
2307                                 }
2308                                 case DEAD_DEAD:
2309                                 {
2310                                         if (button_pressed)
2311                                                 this.deadflag = DEAD_RESPAWNABLE;
2312                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2313                                                 this.deadflag = DEAD_RESPAWNING;
2314                                         break;
2315                                 }
2316                                 case DEAD_RESPAWNABLE:
2317                                 {
2318                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2319                                                 this.deadflag = DEAD_RESPAWNING;
2320                                         break;
2321                                 }
2322                                 case DEAD_RESPAWNING:
2323                                 {
2324                                         if (time > this.respawn_time)
2325                                         {
2326                                                 this.respawn_time = time + 1; // only retry once a second
2327                                                 this.respawn_time_max = this.respawn_time;
2328                                                 respawn(this);
2329                                         }
2330                                         break;
2331                                 }
2332                         }
2333
2334                         ShowRespawnCountdown(this);
2335
2336                         if (this.respawn_flags & RESPAWN_SILENT)
2337                                 STAT(RESPAWN_TIME, this) = 0;
2338                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2339                         {
2340                                 if (time < this.respawn_time)
2341                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2342                                 else if (this.deadflag != DEAD_RESPAWNING)
2343                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2344                         }
2345                         else
2346                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2347                 }
2348
2349                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2350                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2351                         STAT(RESPAWN_TIME, this) *= -1;
2352
2353                 return false;
2354         }
2355
2356         FixPlayermodel(this);
2357
2358         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2359                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2360                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2361         }
2362
2363         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2364         //if(frametime)
2365         {
2366                 this.items &= ~this.items_added;
2367
2368                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2369                 {
2370                         .entity weaponentity = weaponentities[slot];
2371                         W_WeaponFrame(this, weaponentity);
2372                 }
2373
2374                 this.items_added = 0;
2375                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2376             this.items_added |= IT_FUEL;
2377
2378                 this.items |= this.items_added;
2379         }
2380
2381         player_regen(this);
2382
2383         // WEAPONTODO: Add a weapon request for this
2384         // rot vortex charge to the charge limit
2385         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2386         {
2387                 .entity weaponentity = weaponentities[slot];
2388                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2389                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2390         }
2391
2392         if (frametime) player_anim(this);
2393
2394         // secret status
2395         secrets_setstatus(this);
2396
2397         // monsters status
2398         monsters_setstatus(this);
2399
2400         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2401
2402         return true;
2403 }
2404
2405 .bool would_spectate;
2406 void ObserverThink(entity this)
2407 {
2408         if ( CS(this).impulse )
2409         {
2410                 MinigameImpulse(this, CS(this).impulse);
2411                 CS(this).impulse = 0;
2412         }
2413
2414         if (this.flags & FL_JUMPRELEASED) {
2415                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2416                         this.flags &= ~FL_JUMPRELEASED;
2417                         this.flags |= FL_SPAWNING;
2418                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2419                         this.flags &= ~FL_JUMPRELEASED;
2420                         if(SpectateNext(this)) {
2421                                 TRANSMUTE(Spectator, this);
2422                         }
2423                 } else {
2424                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2425                         set_movetype(this, preferred_movetype);
2426                 }
2427         } else {
2428                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2429                         this.flags |= FL_JUMPRELEASED;
2430                         if(this.flags & FL_SPAWNING)
2431                         {
2432                                 this.flags &= ~FL_SPAWNING;
2433                                 Join(this);
2434                                 return;
2435                         }
2436                 }
2437         }
2438 }
2439
2440 void SpectatorThink(entity this)
2441 {
2442         if ( CS(this).impulse )
2443         {
2444                 if(MinigameImpulse(this, CS(this).impulse))
2445                         CS(this).impulse = 0;
2446
2447                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2448                 {
2449                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2450                         CS(this).impulse = 0;
2451                         return;
2452                 }
2453         }
2454
2455         if (this.flags & FL_JUMPRELEASED) {
2456                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2457                         this.flags &= ~FL_JUMPRELEASED;
2458                         this.flags |= FL_SPAWNING;
2459                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2460                         this.flags &= ~FL_JUMPRELEASED;
2461                         if(SpectateNext(this)) {
2462                                 TRANSMUTE(Spectator, this);
2463                         } else {
2464                                 TRANSMUTE(Observer, this);
2465                                 PutClientInServer(this);
2466                         }
2467                         CS(this).impulse = 0;
2468                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2469                         this.flags &= ~FL_JUMPRELEASED;
2470                         if(SpectatePrev(this)) {
2471                                 TRANSMUTE(Spectator, this);
2472                         } else {
2473                                 TRANSMUTE(Observer, this);
2474                                 PutClientInServer(this);
2475                         }
2476                         CS(this).impulse = 0;
2477                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2478                         this.would_spectate = false;
2479                         this.flags &= ~FL_JUMPRELEASED;
2480                         TRANSMUTE(Observer, this);
2481                         PutClientInServer(this);
2482                 } else {
2483                         if(!SpectateUpdate(this))
2484                         {
2485                                 if(!SpectateNext(this))
2486                                 {
2487                                         PutObserverInServer(this);
2488                                         this.would_spectate = true;
2489                                 }
2490                         }
2491                 }
2492         } else {
2493                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2494                         this.flags |= FL_JUMPRELEASED;
2495                         if(this.flags & FL_SPAWNING)
2496                         {
2497                                 this.flags &= ~FL_SPAWNING;
2498                                 Join(this);
2499                                 return;
2500                         }
2501                 }
2502                 if(!SpectateUpdate(this))
2503                         PutObserverInServer(this);
2504         }
2505
2506         this.flags |= FL_CLIENT | FL_NOTARGET;
2507 }
2508
2509 void PlayerUseKey(entity this)
2510 {
2511         if (!IS_PLAYER(this))
2512                 return;
2513
2514         if(this.vehicle)
2515         {
2516                 if(!game_stopped)
2517                 {
2518                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2519                         return;
2520                 }
2521         }
2522         else if(autocvar_g_vehicles_enter)
2523         {
2524                 if(!STAT(FROZEN, this))
2525                 if(!IS_DEAD(this))
2526                 if(!game_stopped)
2527                 {
2528                         entity head, closest_target = NULL;
2529                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2530
2531                         while(head) // find the closest acceptable target to enter
2532                         {
2533                                 if(IS_VEHICLE(head))
2534                                 if(!IS_DEAD(head))
2535                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2536                                 if(head.takedamage != DAMAGE_NO)
2537                                 {
2538                                         if(closest_target)
2539                                         {
2540                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2541                                                 { closest_target = head; }
2542                                         }
2543                                         else { closest_target = head; }
2544                                 }
2545
2546                                 head = head.chain;
2547                         }
2548
2549                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2550                 }
2551         }
2552
2553         // a use key was pressed; call handlers
2554         MUTATOR_CALLHOOK(PlayerUseKey, this);
2555 }
2556
2557
2558 /*
2559 =============
2560 PlayerPreThink
2561
2562 Called every frame for each client before the physics are run
2563 =============
2564 */
2565 .float last_vehiclecheck;
2566 void PlayerPreThink (entity this)
2567 {
2568         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2569         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2570
2571         WarpZone_PlayerPhysics_FixVAngle(this);
2572
2573         if (frametime) {
2574                 // physics frames: update anticheat stuff
2575                 anticheat_prethink(this);
2576         }
2577
2578         if (blockSpectators && frametime) {
2579                 // WORKAROUND: only use dropclient in server frames (frametime set).
2580                 // Never use it in cl_movement frames (frametime zero).
2581                 checkSpectatorBlock(this);
2582         }
2583
2584         zoomstate_set = false;
2585
2586         // Check for nameless players
2587         if (this.netname == "" || this.netname != CS(this).netname_previous)
2588         {
2589                 bool assume_unchanged = (CS(this).netname_previous == "");
2590                 if (isInvisibleString(this.netname))
2591                 {
2592                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2593                         assume_unchanged = false;
2594                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2595                 }
2596                 if (!assume_unchanged && autocvar_sv_eventlog)
2597                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2598                 strcpy(CS(this).netname_previous, this.netname);
2599         }
2600
2601         // version nagging
2602         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2603         CS(this).version_nagtime = 0;
2604         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2605             // git client
2606         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2607             // git server
2608             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2609         } else {
2610             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2611             if (r < 0) { // old client
2612                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2613             } else if (r > 0) { // old server
2614                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2615             }
2616         }
2617     }
2618
2619         // GOD MODE info
2620         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2621         {
2622                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2623                 this.max_armorvalue = 0;
2624         }
2625
2626         if(IS_PLAYER(this))
2627         {
2628                 if (STAT(FROZEN, this) == 2)
2629                 {
2630                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2631                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2632                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2633
2634                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2635                                 Unfreeze(this);
2636                 }
2637                 else if (STAT(FROZEN, this) == 3)
2638                 {
2639                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2640                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2641
2642                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2643                         {
2644                                 if (this.vehicle)
2645                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2646                                 if(this.event_damage)
2647                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2648                         }
2649                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2650                                 Unfreeze(this);
2651                 }
2652         }
2653
2654         MUTATOR_CALLHOOK(PlayerPreThink, this);
2655
2656         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2657         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2658         {
2659                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2660                 {
2661                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2662                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2663                         {
2664                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2665                         }
2666                         else if(!it.owner)
2667                         {
2668                                 if(!it.team || SAME_TEAM(this, it))
2669                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2670                                 else if(autocvar_g_vehicles_steal)
2671                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2672                         }
2673                 });
2674
2675                 this.last_vehiclecheck = time + 1;
2676         }
2677
2678         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2679         {
2680                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2681                         PlayerUseKey(this);
2682                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2683         }
2684
2685         if (IS_REAL_CLIENT(this))
2686                 PrintWelcomeMessage(this);
2687
2688         if (IS_PLAYER(this)) {
2689                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2690                         error("Client can't be spawned as player on connection!");
2691                 if(!PlayerThink(this))
2692                         return;
2693         }
2694         else if (game_stopped || intermission_running) {
2695                 if(intermission_running)
2696                         IntermissionThink(this);
2697                 return;
2698         }
2699         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2700         {
2701                 CS(this).autojoin_checked = true;
2702                 // don't do this in ClientConnect
2703                 // many things can go wrong if a client is spawned as player on connection
2704                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2705                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2706                                 && (!teamplay || autocvar_g_balance_teams)))
2707                 {
2708                         campaign_bots_may_start = true;
2709                         Join(this);
2710                         return;
2711                 }
2712         }
2713         else if (IS_OBSERVER(this)) {
2714                 ObserverThink(this);
2715         }
2716         else if (IS_SPEC(this)) {
2717                 SpectatorThink(this);
2718         }
2719
2720         // WEAPONTODO: Add weapon request for this
2721         if (!zoomstate_set) {
2722                 bool wep_zoomed = false;
2723                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2724                 {
2725                         .entity weaponentity = weaponentities[slot];
2726                         Weapon thiswep = this.(weaponentity).m_weapon;
2727                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2728                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2729                 }
2730                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2731     }
2732
2733         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2734         {
2735                 CS(this).teamkill_soundtime = 0;
2736
2737                 entity e = CS(this).teamkill_soundsource;
2738                 entity oldpusher = e.pusher;
2739                 e.pusher = this;
2740                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2741                 e.pusher = oldpusher;
2742         }
2743
2744         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2745                 CS(this).taunt_soundtime = 0;
2746                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2747         }
2748
2749         target_voicescript_next(this);
2750
2751         // WEAPONTODO: Move into weaponsystem somehow
2752         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2753         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2754         {
2755                 .entity weaponentity = weaponentities[slot];
2756                 if(this.(weaponentity).m_weapon == WEP_Null)
2757                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2758         }
2759 }
2760
2761 void DrownPlayer(entity this)
2762 {
2763         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2764                 return;
2765
2766         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2767         {
2768                 if(this.air_finished < time)
2769                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2770                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2771         }
2772         else if (this.air_finished < time)
2773         {       // drown!
2774                 if (this.pain_finished < time)
2775                 {
2776                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2777                         this.pain_finished = time + 0.5;
2778                 }
2779         }
2780 }
2781
2782 .bool move_qcphysics;
2783
2784 void Player_Physics(entity this)
2785 {
2786         set_movetype(this, this.move_movetype);
2787
2788         if(!this.move_qcphysics)
2789                 return;
2790
2791         if(!frametime && !CS(this).pm_frametime)
2792                 return;
2793
2794         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2795
2796         CS(this).pm_frametime = 0;
2797 }
2798
2799 /*
2800 =============
2801 PlayerPostThink
2802
2803 Called every frame for each client after the physics are run
2804 =============
2805 */
2806 void PlayerPostThink (entity this)
2807 {
2808         Player_Physics(this);
2809
2810         if (sv_maxidle > 0)
2811         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2812         if (IS_REAL_CLIENT(this))
2813         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2814         {
2815                 int totalClients = 0;
2816                 if(sv_maxidle_slots > 0)
2817                 {
2818                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2819                         {
2820                                 ++totalClients;
2821                         });
2822                 }
2823
2824                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2825                 { /* do nothing */ }
2826                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2827                 {
2828                         if (CS(this).idlekick_lasttimeleft)
2829                         {
2830                                 CS(this).idlekick_lasttimeleft = 0;
2831                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2832                         }
2833                 }
2834                 else
2835                 {
2836                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2837                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2838                                 if (!CS(this).idlekick_lasttimeleft)
2839                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2840                         }
2841                         if (timeleft <= 0) {
2842                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2843                                 dropclient(this);
2844                                 return;
2845                         }
2846                         else if (timeleft <= 10) {
2847                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2848                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2849                 }
2850                                 CS(this).idlekick_lasttimeleft = timeleft;
2851                         }
2852                 }
2853         }
2854
2855         CheatFrame(this);
2856
2857         if (game_stopped)
2858         {
2859                 this.solid = SOLID_NOT;
2860                 this.takedamage = DAMAGE_NO;
2861                 set_movetype(this, MOVETYPE_NONE);
2862         }
2863
2864         if (IS_PLAYER(this)) {
2865                 if(this.death_time == time && IS_DEAD(this))
2866                 {
2867                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2868                         // once all the damage events of this frame have been processed with normal size
2869                         this.maxs.z = 5;
2870                         setsize(this, this.mins, this.maxs);
2871                 }
2872                 DrownPlayer(this);
2873                 UpdateChatBubble(this);
2874                 if (CS(this).impulse) ImpulseCommands(this);
2875                 if (game_stopped)
2876                 {
2877                         CSQCMODEL_AUTOUPDATE(this);
2878                         return;
2879                 }
2880                 GetPressedKeys(this);
2881         }
2882
2883         if (this.waypointsprite_attachedforcarrier) {
2884             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2885                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2886     }
2887
2888         CSQCMODEL_AUTOUPDATE(this);
2889 }
2890
2891 // hack to copy the button fields from the client entity to the Client State
2892 void PM_UpdateButtons(entity this, entity store)
2893 {
2894         if(this.impulse)
2895                 store.impulse = this.impulse;
2896         this.impulse = 0;
2897
2898         bool typing = this.buttonchat;
2899
2900         store.button0 = (typing) ? 0 : this.button0;
2901         //button1?!
2902         store.button2 = (typing) ? 0 : this.button2;
2903         store.button3 = (typing) ? 0 : this.button3;
2904         store.button4 = this.button4;
2905         store.button5 = (typing) ? 0 : this.button5;
2906         store.button6 = this.button6;
2907         store.button7 = this.button7;
2908         store.button8 = this.button8;
2909         store.button9 = this.button9;
2910         store.button10 = this.button10;
2911         store.button11 = this.button11;
2912         store.button12 = this.button12;
2913         store.button13 = this.button13;
2914         store.button14 = this.button14;
2915         store.button15 = this.button15;
2916         store.button16 = this.button16;
2917         store.buttonuse = this.buttonuse;
2918         store.buttonchat = this.buttonchat;
2919
2920         store.cursor_active = this.cursor_active;
2921         store.cursor_screen = this.cursor_screen;
2922         store.cursor_trace_start = this.cursor_trace_start;
2923         store.cursor_trace_endpos = this.cursor_trace_endpos;
2924         store.cursor_trace_ent = this.cursor_trace_ent;
2925
2926         store.ping = this.ping;
2927         store.ping_packetloss = this.ping_packetloss;
2928         store.ping_movementloss = this.ping_movementloss;
2929
2930         store.v_angle = this.v_angle;
2931         store.movement = (typing) ? '0 0 0' : this.movement;
2932 }
2933
2934 NET_HANDLE(fpsreport, bool)
2935 {
2936         int fps = ReadShort();
2937         PlayerScore_Set(sender, SP_FPS, fps);
2938         return true;
2939 }