qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24 #include "scores_rules.qh"
  25
  26 #include "bot/api.qh"
  27
  28 #include "../common/ent_cs.qh"
  29 #include "../common/wepent.qh"
  30 #include <common/state.qh>
  31
  32 #include <common/effects/qc/globalsound.qh>
  33
  34 #include "../common/triggers/func/conveyor.qh"
  35 #include "../common/triggers/teleporters.qh"
  36
  37 #include "../common/vehicles/all.qh"
  38
  39 #include "weapons/hitplot.qh"
  40 #include "weapons/weaponsystem.qh"
  41
  42 #include "../common/net_notice.qh"
  43 #include "../common/net_linked.qh"
  44 #include "../common/physics/player.qh"
  45
  46 #include "../common/items/_mod.qh"
  47
  48 #include "../common/mutators/mutator/waypoints/all.qh"
  49
  50 #include "../common/triggers/subs.qh"
  51 #include "../common/triggers/triggers.qh"
  52 #include "../common/triggers/trigger/secret.qh"
  53
  54 #include "../common/minigames/sv_minigames.qh"
  55
  56 #include "../common/items/inventory.qh"
  57
  58 #include "../common/monsters/sv_monsters.qh"
  59
  60 #include "../lib/warpzone/server.qh"
  61
  62 STATIC_METHOD(Client, Add, void(Client this, int _team))
  63 {
  64     ClientConnect(this);
  65     TRANSMUTE(Player, this);
  66     this.frame = 12; // 7
  67     this.team = _team;
  68     PutClientInServer(this);
  69 }
  70
  71 void PutObserverInServer(entity this);
  72
  73 STATIC_METHOD(Client, Remove, void(Client this))
  74 {
  75     TRANSMUTE(Observer, this);
  76     PutClientInServer(this);
  77     ClientDisconnect(this);
  78 }
  79
  80 void send_CSQC_teamnagger() {
  81         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  82 }
  83
  84 int CountSpectators(entity player, entity to)
  85 {
  86         if(!player) { return 0; } // not sure how, but best to be safe
  87
  88         int spec_count = 0;
  89
  90         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  91         {
  92                 spec_count++;
  93         });
  94
  95         return spec_count;
  96 }
  97
  98 void WriteSpectators(entity player, entity to)
  99 {
 100         if(!player) { return; } // not sure how, but best to be safe
 101
 102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 103         {
 104                 WriteByte(MSG_ENTITY, num_for_edict(it));
 105         });
 106 }
 107
 108 bool ClientData_Send(entity this, entity to, int sf)
 109 {
 110         assert(to == this.owner, return false);
 111
 112         entity e = to;
 113         if (IS_SPEC(e)) e = e.enemy;
 114
 115         sf = 0;
 116         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 117         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 118         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 119         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 120
 121         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 122         WriteByte(MSG_ENTITY, sf);
 123
 124         if (sf & BIT(1))
 125                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 126
 127         if(sf & BIT(4))
 128         {
 129                 float specs = CountSpectators(e, to);
 130                 WriteByte(MSG_ENTITY, specs);
 131                 WriteSpectators(e, to);
 132         }
 133
 134         return true;
 135 }
 136
 137 void ClientData_Attach(entity this)
 138 {
 139         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 140         CS(this).clientdata.drawonlytoclient = this;
 141         CS(this).clientdata.owner = this;
 142 }
 143
 144 void ClientData_Detach(entity this)
 145 {
 146         delete(CS(this).clientdata);
 147         CS(this).clientdata = NULL;
 148 }
 149
 150 void ClientData_Touch(entity e)
 151 {
 152         CS(e).clientdata.SendFlags = 1;
 153
 154         // make it spectatable
 155         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 156 }
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = vec2(spot.angles);
 230         this.fixangle = true;
 231         // offset it so that the spectator spawns higher off the ground, looks better this way
 232         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 233         if (IS_REAL_CLIENT(this))
 234         {
 235             msg_entity = this;
 236             WriteByte(MSG_ONE, SVC_SETVIEW);
 237             WriteEntity(MSG_ONE, this);
 238         }
 239         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 240         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 241         if(!autocvar_g_debug_globalsounds)
 242         {
 243                 // needed for player sounds
 244                 this.model = "";
 245                 FixPlayermodel(this);
 246         }
 247         setmodel(this, MDL_Null);
 248         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 249         this.view_ofs = '0 0 0';
 250     }
 251
 252     RemoveGrapplingHooks(this);
 253         Portal_ClearAll(this);
 254         Unfreeze(this);
 255         SetSpectatee(this, NULL);
 256
 257         if (this.alivetime)
 258         {
 259                 if (!warmup_stage)
 260                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 261                 this.alivetime = 0;
 262         }
 263
 264         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 265
 266         WaypointSprite_PlayerDead(this);
 267
 268         if (mutator_returnvalue) {
 269             // mutator prevents resetting teams+score
 270         } else {
 271                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 272         this.frags = FRAGS_SPECTATOR;
 273         PlayerScore_Clear(this);  // clear scores when needed
 274     }
 275
 276         if (CS(this).killcount != FRAGS_SPECTATOR)
 277         {
 278                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 279                 if(!game_stopped)
 280                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 281                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 282
 283                 if(!CS(this).just_joined)
 284                         LogTeamchange(this.playerid, -1, 4);
 285                 else
 286                         CS(this).just_joined = false;
 287         }
 288
 289         accuracy_resend(this);
 290
 291         CS(this).spectatortime = time;
 292         if(this.bot_attack)
 293                 IL_REMOVE(g_bot_targets, this);
 294         this.bot_attack = false;
 295     this.hud = HUD_NORMAL;
 296         TRANSMUTE(Observer, this);
 297         this.iscreature = false;
 298         this.teleportable = TELEPORT_SIMPLE;
 299         if(this.damagedbycontents)
 300                 IL_REMOVE(g_damagedbycontents, this);
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revive_progress = 0;
 334         this.revival_time = 0;
 335
 336         this.items = 0;
 337         this.weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponmodel = "";
 341         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 342         {
 343                 this.weaponentities[slot] = NULL;
 344         }
 345         this.exteriorweaponentity = NULL;
 346         CS(this).killcount = FRAGS_SPECTATOR;
 347         this.velocity = '0 0 0';
 348         this.avelocity = '0 0 0';
 349         this.punchangle = '0 0 0';
 350         this.punchvector = '0 0 0';
 351         this.oldvelocity = this.velocity;
 352         this.fire_endtime = -1;
 353         this.event_damage = func_null;
 354
 355         for(int slot = 0; slot < MAX_AXH; ++slot)
 356         {
 357                 entity axh = this.(AuxiliaryXhair[slot]);
 358                 this.(AuxiliaryXhair[slot]) = NULL;
 359
 360                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 361                         delete(axh);
 362         }
 363 }
 364
 365 int player_getspecies(entity this)
 366 {
 367         get_model_parameters(this.model, this.skin);
 368         int s = get_model_parameters_species;
 369         get_model_parameters(string_null, 0);
 370         if (s < 0) return SPECIES_HUMAN;
 371         return s;
 372 }
 373
 374 .float model_randomizer;
 375 void FixPlayermodel(entity player)
 376 {
 377         string defaultmodel = "";
 378         int defaultskin = 0;
 379         if(autocvar_sv_defaultcharacter)
 380         {
 381                 if(teamplay)
 382                 {
 383                         switch(player.team)
 384                         {
 385                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 386                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 387                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 388                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 389                         }
 390                 }
 391
 392                 if(defaultmodel == "")
 393                 {
 394                         defaultmodel = autocvar_sv_defaultplayermodel;
 395                         defaultskin = autocvar_sv_defaultplayerskin;
 396                 }
 397
 398                 int n = tokenize_console(defaultmodel);
 399                 if(n > 0)
 400                 {
 401                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 402                         // However, do NOT randomize if the player-selected model is in the list.
 403                         for (int i = 0; i < n; ++i)
 404                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 405                                         defaultmodel = argv(i);
 406                 }
 407
 408                 int i = strstrofs(defaultmodel, ":", 0);
 409                 if(i >= 0)
 410                 {
 411                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 412                         defaultmodel = substring(defaultmodel, 0, i);
 413                 }
 414         }
 415         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(!defaultskin)
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430         }
 431
 432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 433         defaultmodel = M_ARGV(0, string);
 434         defaultskin = M_ARGV(1, int);
 435
 436         bool chmdl = false;
 437         int oldskin;
 438         if(defaultmodel != "")
 439         {
 440                 if (defaultmodel != player.model)
 441                 {
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, defaultmodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 oldskin = player.skin;
 450                 player.skin = defaultskin;
 451         } else {
 452                 if (player.playermodel != player.model || player.playermodel == "")
 453                 {
 454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 455                         vector m1 = player.mins;
 456                         vector m2 = player.maxs;
 457                         setplayermodel (player, player.playermodel);
 458                         setsize (player, m1, m2);
 459                         chmdl = true;
 460                 }
 461
 462                 if(!autocvar_sv_defaultcharacterskin)
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = stof(player.playerskin);
 466                 }
 467                 else
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = defaultskin;
 471                 }
 472         }
 473
 474         if(chmdl || oldskin != player.skin) // model or skin has changed
 475         {
 476                 player.species = player_getspecies(player); // update species
 477                 if(!autocvar_g_debug_globalsounds)
 478                         UpdatePlayerSounds(player); // update skin sounds
 479         }
 480
 481         if(!teamplay)
 482                 if(strlen(autocvar_sv_defaultplayercolors))
 483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 485 }
 486
 487 void PutPlayerInServer(entity this)
 488 {
 489         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 490
 491         PlayerState_attach(this);
 492         accuracy_resend(this);
 493
 494         if (this.team < 0)
 495                 JoinBestTeam(this, false, true);
 496
 497         entity spot = SelectSpawnPoint(this, false);
 498         if (!spot) {
 499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 500                 return; // spawn failed
 501         }
 502
 503         TRANSMUTE(Player, this);
 504
 505         CS(this).wasplayer = true;
 506         this.iscreature = true;
 507         this.teleportable = TELEPORT_NORMAL;
 508         if(!this.damagedbycontents)
 509                 IL_PUSH(g_damagedbycontents, this);
 510         this.damagedbycontents = true;
 511         set_movetype(this, MOVETYPE_WALK);
 512         this.solid = SOLID_SLIDEBOX;
 513         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 514         if (autocvar_g_playerclip_collisions)
 515                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 516         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 518         this.frags = FRAGS_PLAYER;
 519         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 520         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 521         if (autocvar__notarget)
 522                 this.flags |= FL_NOTARGET;
 523         this.takedamage = DAMAGE_AIM;
 524         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 525         this.dmg = 2; // WTF
 526
 527         if (warmup_stage) {
 528                 this.ammo_shells = warmup_start_ammo_shells;
 529                 this.ammo_nails = warmup_start_ammo_nails;
 530                 this.ammo_rockets = warmup_start_ammo_rockets;
 531                 this.ammo_cells = warmup_start_ammo_cells;
 532                 this.ammo_plasma = warmup_start_ammo_plasma;
 533                 this.ammo_fuel = warmup_start_ammo_fuel;
 534                 this.health = warmup_start_health;
 535                 this.armorvalue = warmup_start_armorvalue;
 536                 this.weapons = WARMUP_START_WEAPONS;
 537         } else {
 538                 this.ammo_shells = start_ammo_shells;
 539                 this.ammo_nails = start_ammo_nails;
 540                 this.ammo_rockets = start_ammo_rockets;
 541                 this.ammo_cells = start_ammo_cells;
 542                 this.ammo_plasma = start_ammo_plasma;
 543                 this.ammo_fuel = start_ammo_fuel;
 544                 this.health = start_health;
 545                 this.armorvalue = start_armorvalue;
 546                 this.weapons = start_weapons;
 547         }
 548         SetSpectatee_status(this, 0);
 549
 550         PS(this).dual_weapons = '0 0 0';
 551
 552         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 553
 554         this.items = start_items;
 555
 556         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 557         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 558         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 559         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 560         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 561         // extend the pause of rotting if client was reset at the beginning of the countdown
 562         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 563                 float f = game_starttime - time;
 564                 this.spawnshieldtime += f;
 565                 this.pauserotarmor_finished += f;
 566                 this.pauserothealth_finished += f;
 567                 this.pauseregen_finished += f;
 568         }
 569         this.damageforcescale = 2;
 570         this.death_time = 0;
 571         this.respawn_flags = 0;
 572         this.respawn_time = 0;
 573         this.stat_respawn_time = 0;
 574         this.scale = autocvar_sv_player_scale;
 575         this.fade_time = 0;
 576         this.pain_frame = 0;
 577         this.pain_finished = 0;
 578         this.pushltime = 0;
 579         setthink(this, func_null); // players have no think function
 580         this.nextthink = 0;
 581         this.dmg_team = 0;
 582         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 583
 584         this.deadflag = DEAD_NO;
 585
 586         this.angles = spot.angles;
 587         this.angles_z = 0; // never spawn tilted even if the spot says to
 588         if (IS_BOT_CLIENT(this))
 589                 this.v_angle = this.angles;
 590         this.fixangle = true; // turn this way immediately
 591         this.oldvelocity = this.velocity = '0 0 0';
 592         this.avelocity = '0 0 0';
 593         this.punchangle = '0 0 0';
 594         this.punchvector = '0 0 0';
 595
 596         this.strength_finished = 0;
 597         this.invincible_finished = 0;
 598         this.fire_endtime = -1;
 599         this.revive_progress = 0;
 600         this.revival_time = 0;
 601         this.air_finished = time + 12;
 602
 603         entity spawnevent = new_pure(spawnevent);
 604         spawnevent.owner = this;
 605         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 606
 607         // Cut off any still running player sounds.
 608         stopsound(this, CH_PLAYER_SINGLE);
 609
 610         this.model = "";
 611         FixPlayermodel(this);
 612         this.drawonlytoclient = NULL;
 613
 614         this.viewloc = NULL;
 615
 616         this.crouch = false;
 617         this.view_ofs = STAT(PL_VIEW_OFS, this);
 618         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 619         this.spawnorigin = spot.origin;
 620         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 621         // don't reset back to last position, even if new position is stuck in solid
 622         this.oldorigin = this.origin;
 623         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 624         if(this.conveyor)
 625                 IL_REMOVE(g_conveyed, this);
 626         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 627         this.hud = HUD_NORMAL;
 628
 629         this.event_damage = PlayerDamage;
 630
 631         if(!this.bot_attack)
 632                 IL_PUSH(g_bot_targets, this);
 633         this.bot_attack = true;
 634         if(!this.monster_attack)
 635                 IL_PUSH(g_monster_targets, this);
 636         this.monster_attack = true;
 637         navigation_dynamicgoal_init(this, false);
 638
 639         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 640
 641         if (CS(this).killcount == FRAGS_SPECTATOR) {
 642                 PlayerScore_Clear(this);
 643                 CS(this).killcount = 0;
 644         }
 645
 646         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 647         {
 648                 .entity weaponentity = weaponentities[slot];
 649                 entity oldwep = this.(weaponentity);
 650                 CL_SpawnWeaponentity(this, weaponentity);
 651                 if(oldwep && oldwep.owner == this)
 652                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 653         }
 654         this.alpha = default_player_alpha;
 655         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 656         this.exteriorweaponentity.alpha = default_weapon_alpha;
 657
 658         this.speedrunning = false;
 659
 660         target_voicescript_clear(this);
 661
 662         // reset fields the weapons may use
 663         FOREACH(Weapons, true, {
 664                 it.wr_resetplayer(it, this);
 665                         // reload all reloadable weapons
 666                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 667                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 668                         {
 669                                 .entity weaponentity = weaponentities[slot];
 670                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 671                         }
 672                 }
 673         });
 674
 675         {
 676                 string s = spot.target;
 677                 spot.target = string_null;
 678                 SUB_UseTargets(spot, this, NULL);
 679                 spot.target = s;
 680         }
 681
 682         Unfreeze(this);
 683
 684         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 685
 686         if (autocvar_spawn_debug)
 687         {
 688                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 689                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 690         }
 691
 692         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693         {
 694                 .entity weaponentity = weaponentities[slot];
 695                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 696                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 697                 else
 698                         this.(weaponentity).m_switchweapon = WEP_Null;
 699                 this.(weaponentity).m_weapon = WEP_Null;
 700                 this.(weaponentity).weaponname = "";
 701                 this.(weaponentity).m_switchingweapon = WEP_Null;
 702                 this.(weaponentity).cnt = -1;
 703         }
 704
 705         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 706
 707         if (!warmup_stage && !this.alivetime)
 708                 this.alivetime = time;
 709
 710         antilag_clear(this, CS(this));
 711 }
 712
 713 /** Called when a client spawns in the server */
 714 void PutClientInServer(entity this)
 715 {
 716         if (IS_BOT_CLIENT(this)) {
 717                 TRANSMUTE(Player, this);
 718         } else if (IS_REAL_CLIENT(this)) {
 719                 msg_entity = this;
 720                 WriteByte(MSG_ONE, SVC_SETVIEW);
 721                 WriteEntity(MSG_ONE, this);
 722         }
 723         if (game_stopped)
 724                 TRANSMUTE(Observer, this);
 725
 726         SetSpectatee(this, NULL);
 727
 728         // reset player keys
 729         if(PS(this))
 730                 PS(this).itemkeys = 0;
 731
 732         MUTATOR_CALLHOOK(PutClientInServer, this);
 733
 734         if (IS_OBSERVER(this)) {
 735                 PutObserverInServer(this);
 736         } else if (IS_PLAYER(this)) {
 737                 PutPlayerInServer(this);
 738         }
 739 }
 740
 741 void ClientInit_misc(entity this);
 742
 743 // TODO do we need all these fields, or should we stop autodetecting runtime
 744 // changes and just have a console command to update this?
 745 bool ClientInit_SendEntity(entity this, entity to, int sf)
 746 {
 747         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 748         return = true;
 749         msg_entity = to;
 750         // MSG_INIT replacement
 751         // TODO: make easier to use
 752         Registry_send_all();
 753         W_PROP_reload(MSG_ONE, to);
 754         ClientInit_misc(this);
 755         MUTATOR_CALLHOOK(Ent_Init);
 756 }
 757 void ClientInit_misc(entity this)
 758 {
 759         int channel = MSG_ONE;
 760         WriteHeader(channel, ENT_CLIENT_INIT);
 761         WriteByte(channel, g_nexball_meter_period * 32);
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 770
 771         if(sv_foginterval && world.fog != "")
 772                 WriteString(channel, world.fog);
 773         else
 774                 WriteString(channel, "");
 775         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 776         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 777         WriteByte(channel, serverflags);
 778         WriteCoord(channel, autocvar_g_trueaim_minrange);
 779 }
 780
 781 void ClientInit_CheckUpdate(entity this)
 782 {
 783         this.nextthink = time;
 784         if(this.count != autocvar_g_balance_armor_blockpercent)
 785         {
 786                 this.count = autocvar_g_balance_armor_blockpercent;
 787                 this.SendFlags |= 1;
 788         }
 789         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 790         {
 791                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 792                 this.SendFlags |= 1;
 793         }
 794 }
 795
 796 void ClientInit_Spawn()
 797 {
 798         entity e = new_pure(clientinit);
 799         setthink(e, ClientInit_CheckUpdate);
 800         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 801
 802         ClientInit_CheckUpdate(e);
 803 }
 804
 805 /*
 806 =============
 807 SetNewParms
 808 =============
 809 */
 810 void SetNewParms ()
 811 {
 812         // initialize parms for a new player
 813         parm1 = -(86400 * 366);
 814
 815         MUTATOR_CALLHOOK(SetNewParms);
 816 }
 817
 818 /*
 819 =============
 820 SetChangeParms
 821 =============
 822 */
 823 void SetChangeParms (entity this)
 824 {
 825         // save parms for level change
 826         parm1 = CS(this).parm_idlesince - time;
 827
 828         MUTATOR_CALLHOOK(SetChangeParms);
 829 }
 830
 831 /*
 832 =============
 833 DecodeLevelParms
 834 =============
 835 */
 836 void DecodeLevelParms(entity this)
 837 {
 838         // load parms
 839         CS(this).parm_idlesince = parm1;
 840         if (CS(this).parm_idlesince == -(86400 * 366))
 841                 CS(this).parm_idlesince = time;
 842
 843         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 844         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 845
 846         MUTATOR_CALLHOOK(DecodeLevelParms);
 847 }
 848
 849 /*
 850 =============
 851 ClientKill
 852
 853 Called when a client types 'kill' in the console
 854 =============
 855 */
 856
 857 .float clientkill_nexttime;
 858 void ClientKill_Now_TeamChange(entity this)
 859 {
 860         if(CS(this).killindicator_teamchange == -1)
 861         {
 862                 JoinBestTeam( this, false, true );
 863         }
 864         else if(CS(this).killindicator_teamchange == -2)
 865         {
 866                 if(blockSpectators)
 867                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 868                 PutObserverInServer(this);
 869         }
 870         else
 871                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 872         CS(this).killindicator_teamchange = 0;
 873 }
 874
 875 void ClientKill_Now(entity this)
 876 {
 877         if(this.vehicle)
 878         {
 879             vehicles_exit(this.vehicle, VHEF_RELEASE);
 880             if(!CS(this).killindicator_teamchange)
 881             {
 882             this.vehicle_health = -1;
 883             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 884             }
 885         }
 886
 887         if(this.killindicator && !wasfreed(this.killindicator))
 888                 delete(this.killindicator);
 889
 890         this.killindicator = NULL;
 891
 892         if(CS(this).killindicator_teamchange)
 893                 ClientKill_Now_TeamChange(this);
 894
 895         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 896                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 897
 898         // now I am sure the player IS dead
 899 }
 900 void KillIndicator_Think(entity this)
 901 {
 902         if (game_stopped)
 903         {
 904                 this.owner.killindicator = NULL;
 905                 delete(this);
 906                 return;
 907         }
 908
 909         if (this.owner.alpha < 0 && !this.owner.vehicle)
 910         {
 911                 this.owner.killindicator = NULL;
 912                 delete(this);
 913                 return;
 914         }
 915
 916         if(this.cnt <= 0)
 917         {
 918                 ClientKill_Now(this.owner);
 919                 return;
 920         }
 921     else if(this.health == 1) // health == 1 means that it's silent
 922     {
 923         this.nextthink = time + 1;
 924         this.cnt -= 1;
 925     }
 926         else
 927         {
 928                 if(this.cnt <= 10)
 929                         setmodel(this, MDL_NUM(this.cnt));
 930                 if(IS_REAL_CLIENT(this.owner))
 931                 {
 932                         if(this.cnt <= 10)
 933                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 934                 }
 935                 this.nextthink = time + 1;
 936                 this.cnt -= 1;
 937         }
 938 }
 939
 940 float clientkilltime;
 941 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 942 {
 943         float killtime;
 944         float starttime;
 945
 946         if (game_stopped)
 947                 return;
 948
 949         killtime = autocvar_g_balance_kill_delay;
 950
 951     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 952         return;
 953     killtime = M_ARGV(1, float);
 954
 955         CS(this).killindicator_teamchange = targetteam;
 956
 957     if(!this.killindicator)
 958         {
 959                 if(!IS_DEAD(this))
 960                 {
 961                         killtime = max(killtime, this.clientkill_nexttime - time);
 962                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 963                 }
 964
 965                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 966                 {
 967                         ClientKill_Now(this);
 968                 }
 969                 else
 970                 {
 971                         starttime = max(time, clientkilltime);
 972
 973                         this.killindicator = spawn();
 974                         this.killindicator.owner = this;
 975                         this.killindicator.scale = 0.5;
 976                         setattachment(this.killindicator, this, "");
 977                         setorigin(this.killindicator, '0 0 52');
 978                         setthink(this.killindicator, KillIndicator_Think);
 979                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 980                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 981                         this.killindicator.cnt = ceil(killtime);
 982                         this.killindicator.count = bound(0, ceil(killtime), 10);
 983                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 984
 985                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 986                         {
 987                                 it.killindicator = spawn();
 988                                 it.killindicator.owner = it;
 989                                 it.killindicator.scale = 0.5;
 990                                 setattachment(it.killindicator, it, "");
 991                                 setorigin(it.killindicator, '0 0 52');
 992                                 setthink(it.killindicator, KillIndicator_Think);
 993                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 994                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 995                                 it.killindicator.cnt = ceil(killtime);
 996                         });
 997                         this.lip = 0;
 998                 }
 999         }
1000         if(this.killindicator)
1001         {
1002                 if(targetteam == 0) // just die
1003                 {
1004                         this.killindicator.colormod = '0 0 0';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1008                 }
1009                 else if(targetteam == -1) // auto
1010                 {
1011                         this.killindicator.colormod = '0 1 0';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1015                 }
1016                 else if(targetteam == -2) // spectate
1017                 {
1018                         this.killindicator.colormod = '0.5 0.5 0.5';
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1022                 }
1023                 else
1024                 {
1025                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1026                         if(IS_REAL_CLIENT(this))
1027                         if(this.killindicator.cnt > 0)
1028                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1029                 }
1030         }
1031
1032 }
1033
1034 void ClientKill (entity this)
1035 {
1036         if(game_stopped) return;
1037         if(this.player_blocked) return;
1038         if(STAT(FROZEN, this)) return;
1039
1040         ClientKill_TeamChange(this, 0);
1041 }
1042
1043 void FixClientCvars(entity e)
1044 {
1045         // send prediction settings to the client
1046         stuffcmd(e, "\nin_bindmap 0 0\n");
1047         if(autocvar_g_antilag == 3) // client side hitscan
1048                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1049         if(autocvar_sv_gentle)
1050                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1051
1052         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1053         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1054
1055         MUTATOR_CALLHOOK(FixClientCvars, e);
1056 }
1057
1058 bool findinlist_abbrev(string tofind, string list)
1059 {
1060         if(list == "" || tofind == "")
1061                 return false; // empty list or search, just return
1062
1063         // this function allows abbreviated strings!
1064         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1065         {
1066                 return true;
1067         });
1068
1069         return false;
1070 }
1071
1072 bool PlayerInIPList(entity p, string iplist)
1073 {
1074         // some safety checks (never allow local?)
1075         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1076                 return false;
1077
1078         return findinlist_abbrev(p.netaddress, iplist);
1079 }
1080
1081 bool PlayerInIDList(entity p, string idlist)
1082 {
1083         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1084         if(!p.crypto_idfp)
1085                 return false;
1086
1087         return findinlist_abbrev(p.crypto_idfp, idlist);
1088 }
1089
1090 bool PlayerInList(entity player, string list)
1091 {
1092         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1093 }
1094
1095 #ifdef DP_EXT_PRECONNECT
1096 /*
1097 =============
1098 ClientPreConnect
1099
1100 Called once (not at each match start) when a client begins a connection to the server
1101 =============
1102 */
1103 void ClientPreConnect(entity this)
1104 {
1105         if(autocvar_sv_eventlog)
1106         {
1107                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1108                         this.playerid,
1109                         etof(this),
1110                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1111                 ));
1112         }
1113 }
1114 #endif
1115
1116 /**
1117 =============
1118 ClientConnect
1119
1120 Called when a client connects to the server
1121 =============
1122 */
1123 void ClientConnect(entity this)
1124 {
1125         if (Ban_MaybeEnforceBanOnce(this)) return;
1126         assert(!IS_CLIENT(this), return);
1127         this.flags |= FL_CLIENT;
1128         assert(player_count >= 0, player_count = 0);
1129
1130 #ifdef WATERMARK
1131         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1132 #endif
1133         TRANSMUTE(Client, this);
1134         CS(this).version_nagtime = time + 10 + random() * 10;
1135
1136         // identify the right forced team
1137         if (autocvar_g_campaign)
1138         {
1139                 if (IS_REAL_CLIENT(this)) // only players, not bots
1140                 {
1141                         switch (autocvar_g_campaign_forceteam)
1142                         {
1143                                 case 1: this.team_forced = NUM_TEAM_1; break;
1144                                 case 2: this.team_forced = NUM_TEAM_2; break;
1145                                 case 3: this.team_forced = NUM_TEAM_3; break;
1146                                 case 4: this.team_forced = NUM_TEAM_4; break;
1147                                 default: this.team_forced = 0;
1148                         }
1149                 }
1150         }
1151         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1152         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1153         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1154         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1155         else switch (autocvar_g_forced_team_otherwise)
1156         {
1157                 default: this.team_forced = 0; break;
1158                 case "red": this.team_forced = NUM_TEAM_1; break;
1159                 case "blue": this.team_forced = NUM_TEAM_2; break;
1160                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1161                 case "pink": this.team_forced = NUM_TEAM_4; break;
1162                 case "spectate":
1163                 case "spectator":
1164                         this.team_forced = -1;
1165                         break;
1166         }
1167         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1168
1169     {
1170         int id = this.playerid;
1171         this.playerid = 0; // silent
1172             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1173             this.playerid = id;
1174     }
1175
1176         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1177                 TRANSMUTE(Observer, this);
1178         } else {
1179                 if (!teamplay || autocvar_g_balance_teams) {
1180                         TRANSMUTE(Player, this);
1181                         campaign_bots_may_start = true;
1182                 } else {
1183                         TRANSMUTE(Observer, this); // do it anyway
1184                 }
1185         }
1186
1187         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1188
1189         // always track bots, don't ask for cl_allow_uidtracking
1190         if (IS_BOT_CLIENT(this))
1191                 PlayerStats_GameReport_AddPlayer(this);
1192         else
1193                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if (autocvar_sv_eventlog)
1196                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1197
1198         LogTeamchange(this.playerid, this.team, 1);
1199
1200         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1201
1202         CS(this).netname_previous = strzone(this.netname);
1203
1204         if(teamplay && IS_PLAYER(this))
1205                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1206         else
1207                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1208
1209         stuffcmd(this, clientstuff, "\n");
1210         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1211
1212         FixClientCvars(this);
1213
1214         // get version info from player
1215         stuffcmd(this, "cmd clientversion $gameversion\n");
1216
1217         // notify about available teams
1218         if (teamplay)
1219         {
1220                 CheckAllowedTeams(this);
1221                 int t = 0;
1222                 if (c1 >= 0) t |= BIT(0);
1223                 if (c2 >= 0) t |= BIT(1);
1224                 if (c3 >= 0) t |= BIT(2);
1225                 if (c4 >= 0) t |= BIT(3);
1226                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1227         }
1228         else
1229         {
1230                 stuffcmd(this, "set _teams_available 0\n");
1231         }
1232
1233         bot_relinkplayerlist();
1234
1235         CS(this).spectatortime = time;
1236         if (blockSpectators)
1237         {
1238                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1239         }
1240
1241         CS(this).jointime = time;
1242
1243         if (IS_REAL_CLIENT(this))
1244         {
1245                 if (g_weaponarena_weapons == WEPSET(TUBA))
1246                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1247         }
1248
1249         if (!sv_foginterval && world.fog != "")
1250                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1251
1252         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1253                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1254                         send_CSQC_teamnagger();
1255
1256         CSQCMODEL_AUTOINIT(this);
1257
1258         CS(this).model_randomizer = random();
1259
1260         if (IS_REAL_CLIENT(this))
1261                 sv_notice_join(this);
1262
1263         // update physics stats (players can spawn before physics runs)
1264         Physics_UpdateStats(this);
1265
1266         IL_EACH(g_initforplayer, it.init_for_player, {
1267                 it.init_for_player(it, this);
1268         });
1269
1270         MUTATOR_CALLHOOK(ClientConnect, this);
1271
1272         if (IS_REAL_CLIENT(this))
1273         {
1274                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1275                 {
1276                         CS(this).motd_actived_time = -1;
1277                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1278                 }
1279         }
1280 }
1281 /*
1282 =============
1283 ClientDisconnect
1284
1285 Called when a client disconnects from the server
1286 =============
1287 */
1288 .entity chatbubbleentity;
1289 void ReadyCount();
1290 void ClientDisconnect(entity this)
1291 {
1292         assert(IS_CLIENT(this), return);
1293
1294         PlayerStats_GameReport_FinalizePlayer(this);
1295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1296         if (CS(this).active_minigame) part_minigame(this);
1297         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1298
1299         if (autocvar_sv_eventlog)
1300                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1301
1302         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1303
1304         if(IS_SPEC(this))
1305                 SetSpectatee(this, NULL);
1306
1307     MUTATOR_CALLHOOK(ClientDisconnect, this);
1308
1309         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1310         ClientState_detach(this);
1311
1312         Portal_ClearAll(this);
1313
1314         Unfreeze(this);
1315
1316         RemoveGrapplingHooks(this);
1317
1318         // Here, everything has been done that requires this player to be a client.
1319
1320         this.flags &= ~FL_CLIENT;
1321
1322         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1323         if (this.killindicator) delete(this.killindicator);
1324
1325         WaypointSprite_PlayerGone(this);
1326
1327         bot_relinkplayerlist();
1328
1329         if (this.clientstatus) strunzone(this.clientstatus);
1330         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1331         if (this.personal) delete(this.personal);
1332
1333         this.playerid = 0;
1334         ReadyCount();
1335         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1336
1337         ONREMOVE(this);
1338 }
1339
1340 void ChatBubbleThink(entity this)
1341 {
1342         this.nextthink = time;
1343         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1344         {
1345                 if(this.owner) // but why can that ever be NULL?
1346                         this.owner.chatbubbleentity = NULL;
1347                 delete(this);
1348                 return;
1349         }
1350
1351         this.mdl = "";
1352
1353         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1354         {
1355                 if ( CS(this.owner).active_minigame )
1356                         this.mdl = "models/sprites/minigame_busy.iqm";
1357                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1358                         this.mdl = "models/misc/chatbubble.spr";
1359         }
1360
1361         if ( this.model != this.mdl )
1362                 _setmodel(this, this.mdl);
1363
1364 }
1365
1366 void UpdateChatBubble(entity this)
1367 {
1368         if (this.alpha < 0)
1369                 return;
1370         // spawn a chatbubble entity if needed
1371         if (!this.chatbubbleentity)
1372         {
1373                 this.chatbubbleentity = new(chatbubbleentity);
1374                 this.chatbubbleentity.owner = this;
1375                 this.chatbubbleentity.exteriormodeltoclient = this;
1376                 setthink(this.chatbubbleentity, ChatBubbleThink);
1377                 this.chatbubbleentity.nextthink = time;
1378                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1379                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1380                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1381                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1382                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1383                 //this.chatbubbleentity.model = "";
1384                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1385         }
1386 }
1387
1388
1389 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1390 // added to the model skins
1391 /*void UpdateColorModHack()
1392 {
1393         float c;
1394         c = this.clientcolors & 15;
1395         // LordHavoc: only bothering to support white, green, red, yellow, blue
1396              if (!teamplay) this.colormod = '0 0 0';
1397         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1398         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1399         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1400         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1401         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1402         else this.colormod = '1 1 1';
1403 }*/
1404
1405 void respawn(entity this)
1406 {
1407         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1408         {
1409                 this.solid = SOLID_NOT;
1410                 this.takedamage = DAMAGE_NO;
1411                 set_movetype(this, MOVETYPE_FLY);
1412                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1413                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1414                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1415                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1416                 if(autocvar_g_respawn_ghosts_maxtime)
1417                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1418         }
1419
1420         CopyBody(this, 1);
1421
1422         this.effects |= EF_NODRAW; // prevent another CopyBody
1423         PutClientInServer(this);
1424 }
1425
1426 void play_countdown(entity this, float finished, Sound samp)
1427 {
1428     TC(Sound, samp);
1429         if(IS_REAL_CLIENT(this))
1430                 if(floor(finished - time - frametime) != floor(finished - time))
1431                         if(finished - time < 6)
1432                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1433 }
1434
1435 void player_powerups(entity this)
1436 {
1437         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1438         int items_prev = this.items;
1439
1440         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1441                 this.modelflags |= MF_ROCKET;
1442         else
1443                 this.modelflags &= ~MF_ROCKET;
1444
1445         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1446
1447         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1448                 return;
1449
1450         Fire_ApplyDamage(this);
1451         Fire_ApplyEffect(this);
1452
1453         if (!g_instagib)
1454         {
1455                 if (this.items & ITEM_Strength.m_itemid)
1456                 {
1457                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1458                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1459                         if (time > this.strength_finished)
1460                         {
1461                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1462                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1463                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < this.strength_finished)
1469                         {
1470                                 this.items = this.items | ITEM_Strength.m_itemid;
1471                                 if(!g_cts)
1472                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1473                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1474                         }
1475                 }
1476                 if (this.items & ITEM_Shield.m_itemid)
1477                 {
1478                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1479                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1480                         if (time > this.invincible_finished)
1481                         {
1482                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1483                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1485                         }
1486                 }
1487                 else
1488                 {
1489                         if (time < this.invincible_finished)
1490                         {
1491                                 this.items = this.items | ITEM_Shield.m_itemid;
1492                                 if(!g_cts)
1493                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1494                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1495                         }
1496                 }
1497                 if (this.items & IT_SUPERWEAPON)
1498                 {
1499                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1500                         {
1501                                 this.superweapons_finished = 0;
1502                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1503                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1505                         }
1506                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1507                         {
1508                                 // don't let them run out
1509                         }
1510                         else
1511                         {
1512                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1513                                 if (time > this.superweapons_finished)
1514                                 {
1515                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1516                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1517                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1518                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1519                                 }
1520                         }
1521                 }
1522                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1523                 {
1524                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1525                         {
1526                                 this.items = this.items | IT_SUPERWEAPON;
1527                                 if(!g_cts)
1528                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1530                         }
1531                         else
1532                         {
1533                                 this.superweapons_finished = 0;
1534                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1535                         }
1536                 }
1537                 else
1538                 {
1539                         this.superweapons_finished = 0;
1540                 }
1541         }
1542
1543         if(autocvar_g_nodepthtestplayers)
1544                 this.effects = this.effects | EF_NODEPTHTEST;
1545
1546         if(autocvar_g_fullbrightplayers)
1547                 this.effects = this.effects | EF_FULLBRIGHT;
1548
1549         if (time >= game_starttime)
1550         if (time < this.spawnshieldtime)
1551                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1552
1553         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1554 }
1555
1556 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1557 {
1558         if(current > stable)
1559                 return current;
1560         else if(current > stable - 0.25) // when close enough, "snap"
1561                 return stable;
1562         else
1563                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1564 }
1565
1566 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1567 {
1568         if(current < stable)
1569                 return current;
1570         else if(current < stable + 0.25) // when close enough, "snap"
1571                 return stable;
1572         else
1573                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1574 }
1575
1576 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1577 {
1578         if(current > rotstable)
1579         {
1580                 if(rotframetime > 0)
1581                 {
1582                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1583                         current = max(rotstable, current - rotlinear * rotframetime);
1584                 }
1585         }
1586         else if(current < regenstable)
1587         {
1588                 if(regenframetime > 0)
1589                 {
1590                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1591                         current = min(regenstable, current + regenlinear * regenframetime);
1592                 }
1593         }
1594
1595         if(current > limit)
1596                 current = limit;
1597
1598         return current;
1599 }
1600
1601 void player_regen(entity this)
1602 {
1603         float max_mod, regen_mod, rot_mod, limit_mod;
1604         max_mod = regen_mod = rot_mod = limit_mod = 1;
1605
1606         float regen_health = autocvar_g_balance_health_regen;
1607         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1608         float regen_health_rot = autocvar_g_balance_health_rot;
1609         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1610         float regen_health_stable = autocvar_g_balance_health_regenstable;
1611         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1612         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1613                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1614         max_mod = M_ARGV(1, float);
1615         regen_mod = M_ARGV(2, float);
1616         rot_mod = M_ARGV(3, float);
1617         limit_mod = M_ARGV(4, float);
1618         regen_health = M_ARGV(5, float);
1619         regen_health_linear = M_ARGV(6, float);
1620         regen_health_rot = M_ARGV(7, float);
1621         regen_health_rotlinear = M_ARGV(8, float);
1622         regen_health_stable = M_ARGV(9, float);
1623         regen_health_rotstable = M_ARGV(10, float);
1624
1625         if(!mutator_returnvalue)
1626         if(!STAT(FROZEN, this))
1627         {
1628                 float mina, maxa, limith, limita;
1629                 maxa = autocvar_g_balance_armor_rotstable;
1630                 mina = autocvar_g_balance_armor_regenstable;
1631                 limith = autocvar_g_balance_health_limit;
1632                 limita = autocvar_g_balance_armor_limit;
1633
1634                 regen_health_rotstable = regen_health_rotstable * max_mod;
1635                 regen_health_stable = regen_health_stable * max_mod;
1636                 limith = limith * limit_mod;
1637                 limita = limita * limit_mod;
1638
1639                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1640                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1641         }
1642
1643         // if player rotted to death...  die!
1644         // check this outside above checks, as player may still be able to rot to death
1645         if(this.health < 1)
1646         {
1647                 if(this.vehicle)
1648                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1649                 if(this.event_damage)
1650                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1651         }
1652
1653         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1654         {
1655                 float minf, maxf, limitf;
1656
1657                 maxf = autocvar_g_balance_fuel_rotstable;
1658                 minf = autocvar_g_balance_fuel_regenstable;
1659                 limitf = autocvar_g_balance_fuel_limit;
1660
1661                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1662         }
1663         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1664         // TODO: Remove this hack when all code uses GivePlayerHealth and
1665         // GivePlayerArmor.
1666         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1667         {
1668                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1669         }
1670         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1671         {
1672                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1673         }
1674         // End hack.
1675 }
1676
1677 bool zoomstate_set;
1678 void SetZoomState(entity this, float newzoom)
1679 {
1680         if(newzoom != CS(this).zoomstate)
1681         {
1682                 CS(this).zoomstate = newzoom;
1683                 ClientData_Touch(this);
1684         }
1685         zoomstate_set = true;
1686 }
1687
1688 void GetPressedKeys(entity this)
1689 {
1690         MUTATOR_CALLHOOK(GetPressedKeys, this);
1691         int keys = STAT(PRESSED_KEYS, this);
1692         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1693         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1694         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1695         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1696
1697         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1698         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1699         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1700         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1701         CS(this).pressedkeys = keys; // store for other users
1702
1703         STAT(PRESSED_KEYS, this) = keys;
1704 }
1705
1706 /*
1707 ======================
1708 spectate mode routines
1709 ======================
1710 */
1711
1712 void SpectateCopy(entity this, entity spectatee)
1713 {
1714     TC(Client, this); TC(Client, spectatee);
1715
1716         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1717         PS(this) = PS(spectatee);
1718         this.armortype = spectatee.armortype;
1719         this.armorvalue = spectatee.armorvalue;
1720         this.ammo_cells = spectatee.ammo_cells;
1721         this.ammo_plasma = spectatee.ammo_plasma;
1722         this.ammo_shells = spectatee.ammo_shells;
1723         this.ammo_nails = spectatee.ammo_nails;
1724         this.ammo_rockets = spectatee.ammo_rockets;
1725         this.ammo_fuel = spectatee.ammo_fuel;
1726         this.clip_load = spectatee.clip_load;
1727         this.clip_size = spectatee.clip_size;
1728         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1729         this.health = spectatee.health;
1730         CS(this).impulse = 0;
1731         this.items = spectatee.items;
1732         this.last_pickup = spectatee.last_pickup;
1733         this.hit_time = spectatee.hit_time;
1734         this.strength_finished = spectatee.strength_finished;
1735         this.invincible_finished = spectatee.invincible_finished;
1736         this.superweapons_finished = spectatee.superweapons_finished;
1737         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1738         this.weapons = spectatee.weapons;
1739         this.vortex_charge = spectatee.vortex_charge;
1740         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1741         this.hagar_load = spectatee.hagar_load;
1742         this.arc_heat_percent = spectatee.arc_heat_percent;
1743         this.minelayer_mines = spectatee.minelayer_mines;
1744         this.punchangle = spectatee.punchangle;
1745         this.view_ofs = spectatee.view_ofs;
1746         this.velocity = spectatee.velocity;
1747         this.dmg_take = spectatee.dmg_take;
1748         this.dmg_save = spectatee.dmg_save;
1749         this.dmg_inflictor = spectatee.dmg_inflictor;
1750         this.v_angle = spectatee.v_angle;
1751         this.angles = spectatee.v_angle;
1752         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1753         this.revive_progress = spectatee.revive_progress;
1754         this.viewloc = spectatee.viewloc;
1755         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1756                 this.fixangle = true;
1757         setorigin(this, spectatee.origin);
1758         setsize(this, spectatee.mins, spectatee.maxs);
1759         SetZoomState(this, CS(spectatee).zoomstate);
1760
1761         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1762         {
1763                 .entity weaponentity = weaponentities[slot];
1764                 this.(weaponentity) = spectatee.(weaponentity);
1765         }
1766
1767         for(int slot = 0; slot < MAX_AXH; ++slot)
1768         {
1769                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1770         }
1771
1772     anticheat_spectatecopy(this, spectatee);
1773         this.hud = spectatee.hud;
1774         if(spectatee.vehicle)
1775     {
1776         this.angles = spectatee.v_angle;
1777
1778         //this.fixangle = false;
1779         //this.velocity = spectatee.vehicle.velocity;
1780         this.vehicle_health = spectatee.vehicle_health;
1781         this.vehicle_shield = spectatee.vehicle_shield;
1782         this.vehicle_energy = spectatee.vehicle_energy;
1783         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1784         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1785         this.vehicle_reload1 = spectatee.vehicle_reload1;
1786         this.vehicle_reload2 = spectatee.vehicle_reload2;
1787
1788         //msg_entity = this;
1789
1790        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1791             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1792            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1793            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1794
1795         //WriteByte (MSG_ONE, SVC_SETVIEW);
1796         //    WriteEntity(MSG_ONE, this);
1797         //makevectors(spectatee.v_angle);
1798         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1799     }
1800 }
1801
1802 bool SpectateUpdate(entity this)
1803 {
1804         if(!this.enemy)
1805                 return false;
1806
1807         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1808         {
1809                 SetSpectatee(this, NULL);
1810                 return false;
1811         }
1812
1813         SpectateCopy(this, this.enemy);
1814
1815         return true;
1816 }
1817
1818 bool SpectateSet(entity this)
1819 {
1820         if(!IS_PLAYER(this.enemy))
1821                 return false;
1822
1823         ClientData_Touch(this.enemy);
1824
1825         msg_entity = this;
1826         WriteByte(MSG_ONE, SVC_SETVIEW);
1827         WriteEntity(MSG_ONE, this.enemy);
1828         set_movetype(this, MOVETYPE_NONE);
1829         accuracy_resend(this);
1830
1831         if(!SpectateUpdate(this))
1832                 PutObserverInServer(this);
1833
1834         return true;
1835 }
1836
1837 void SetSpectatee_status(entity this, int spectatee_num)
1838 {
1839         int oldspectatee_status = CS(this).spectatee_status;
1840         CS(this).spectatee_status = spectatee_num;
1841
1842         if (CS(this).spectatee_status != oldspectatee_status)
1843         {
1844                 ClientData_Touch(this);
1845                 if (g_race || g_cts) race_InitSpectator();
1846         }
1847 }
1848
1849 void SetSpectatee(entity this, entity spectatee)
1850 {
1851         if(IS_BOT_CLIENT(this))
1852                 return; // bots abuse .enemy, this code is useless to them
1853
1854         entity old_spectatee = this.enemy;
1855
1856         this.enemy = spectatee;
1857
1858         // WEAPONTODO
1859         // these are required to fix the spectator bug with arc
1860         if(old_spectatee)
1861         {
1862                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863                 {
1864                         .entity weaponentity = weaponentities[slot];
1865                         if(old_spectatee.(weaponentity).arc_beam)
1866                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1867                 }
1868         }
1869         if(this.enemy)
1870         {
1871                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1872                 {
1873                         .entity weaponentity = weaponentities[slot];
1874                         if(this.enemy.(weaponentity).arc_beam)
1875                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1876                 }
1877         }
1878
1879         if (this.enemy)
1880                 SetSpectatee_status(this, etof(this.enemy));
1881
1882         // needed to update spectator list
1883         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1884 }
1885
1886 bool Spectate(entity this, entity pl)
1887 {
1888         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1889                 return false;
1890         pl = M_ARGV(1, entity);
1891
1892         SetSpectatee(this, pl);
1893         return SpectateSet(this);
1894 }
1895
1896 bool SpectateNext(entity this)
1897 {
1898         entity ent = find(this.enemy, classname, STR_PLAYER);
1899
1900         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1901                 ent = M_ARGV(1, entity);
1902         else if (!ent)
1903                 ent = find(ent, classname, STR_PLAYER);
1904
1905         if(ent) { SetSpectatee(this, ent); }
1906
1907         return SpectateSet(this);
1908 }
1909
1910 bool SpectatePrev(entity this)
1911 {
1912         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1913         entity ent = findchain(classname, STR_PLAYER);
1914         if (!ent) // no player
1915                 return false;
1916
1917         entity first = ent;
1918         // skip players until current spectated player
1919         if(this.enemy)
1920         while(ent && ent != this.enemy)
1921                 ent = ent.chain;
1922
1923         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1924         {
1925                 case MUT_SPECPREV_FOUND:
1926                     ent = M_ARGV(1, entity);
1927                     break;
1928                 case MUT_SPECPREV_RETURN:
1929                     return true;
1930                 case MUT_SPECPREV_CONTINUE:
1931                 default:
1932                 {
1933                         if(ent.chain)
1934                                 ent = ent.chain;
1935                         else
1936                                 ent = first;
1937                         break;
1938                 }
1939         }
1940
1941         SetSpectatee(this, ent);
1942         return SpectateSet(this);
1943 }
1944
1945 /*
1946 =============
1947 ShowRespawnCountdown()
1948
1949 Update a respawn countdown display.
1950 =============
1951 */
1952 void ShowRespawnCountdown(entity this)
1953 {
1954         float number;
1955         if(!IS_DEAD(this)) // just respawned?
1956                 return;
1957         else
1958         {
1959                 number = ceil(this.respawn_time - time);
1960                 if(number <= 0)
1961                         return;
1962                 if(number <= this.respawn_countdown)
1963                 {
1964                         this.respawn_countdown = number - 1;
1965                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1966                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1967                 }
1968         }
1969 }
1970
1971 .bool team_selected;
1972 bool ShowTeamSelection(entity this)
1973 {
1974         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1975                 return false;
1976         stuffcmd(this, "menu_showteamselect\n");
1977         return true;
1978 }
1979 void Join(entity this)
1980 {
1981         TRANSMUTE(Player, this);
1982
1983         if(!this.team_selected)
1984         if(autocvar_g_campaign || autocvar_g_balance_teams)
1985                 JoinBestTeam(this, false, true);
1986
1987         if(autocvar_g_campaign)
1988                 campaign_bots_may_start = true;
1989
1990         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1991
1992         PutClientInServer(this);
1993
1994         if(IS_PLAYER(this))
1995         if(teamplay && this.team != -1)
1996                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1997         else
1998                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1999         this.team_selected = false;
2000 }
2001
2002 /**
2003  * Determines whether the player is allowed to join. This depends on cvar
2004  * g_maxplayers, if it isn't used this function always return true, otherwise
2005  * it checks whether the number of currently playing players exceeds g_maxplayers.
2006  * @return int number of free slots for players, 0 if none
2007  */
2008 int nJoinAllowed(entity this, entity ignore)
2009 {
2010         if(!ignore)
2011         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2012         // so report 0 free slots if restricted
2013         {
2014                 if(autocvar_g_forced_team_otherwise == "spectate")
2015                         return 0;
2016                 if(autocvar_g_forced_team_otherwise == "spectator")
2017                         return 0;
2018         }
2019
2020         if(this && this.team_forced < 0)
2021                 return 0; // forced spectators can never join
2022
2023         // TODO simplify this
2024         int totalClients = 0;
2025         int currentlyPlaying = 0;
2026         FOREACH_CLIENT(true, {
2027                 if(it != ignore)
2028                         ++totalClients;
2029                 if(IS_REAL_CLIENT(it))
2030                 if(IS_PLAYER(it) || it.caplayer)
2031                         ++currentlyPlaying;
2032         });
2033
2034         float free_slots = 0;
2035         if (!autocvar_g_maxplayers)
2036                 free_slots = maxclients - totalClients;
2037         else if(currentlyPlaying < autocvar_g_maxplayers)
2038                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2039
2040         static float join_prevent_msg_time = 0;
2041         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2042         {
2043                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2044                 join_prevent_msg_time = time + 3;
2045         }
2046
2047         return free_slots;
2048 }
2049
2050 /**
2051  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2052  * g_maxplayers_spectator_blocktime seconds
2053  */
2054 void checkSpectatorBlock(entity this)
2055 {
2056         if(IS_SPEC(this) || IS_OBSERVER(this))
2057         if(!this.caplayer)
2058         if(IS_REAL_CLIENT(this))
2059         {
2060                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2061                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2062                         dropclient(this);
2063                 }
2064         }
2065 }
2066
2067 void PrintWelcomeMessage(entity this)
2068 {
2069         if(CS(this).motd_actived_time == 0)
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2073                                 CS(this).motd_actived_time = time;
2074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2075                         }
2076                 } else {
2077                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2078                                 CS(this).motd_actived_time = time;
2079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2080                         }
2081                 }
2082         }
2083         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2084         {
2085                 if (autocvar_g_campaign) {
2086                         if (PHYS_INPUT_BUTTON_INFO(this))
2087                                 CS(this).motd_actived_time = time;
2088                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2089                                 CS(this).motd_actived_time = 0;
2090                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2091                         }
2092                 } else {
2093                         if (PHYS_INPUT_BUTTON_INFO(this))
2094                                 CS(this).motd_actived_time = time;
2095                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2096                                 CS(this).motd_actived_time = 0;
2097                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2098                         }
2099                 }
2100         }
2101         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2102         {
2103                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2104                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2105                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2106                 {
2107                         // instanctly hide MOTD
2108                         CS(this).motd_actived_time = 0;
2109                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2110                 }
2111         }
2112 }
2113
2114 bool joinAllowed(entity this)
2115 {
2116         if (CS(this).version_mismatch) return false;
2117         if (!nJoinAllowed(this, this)) return false;
2118         if (teamplay && lockteams) return false;
2119         if (ShowTeamSelection(this)) return false;
2120         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2121         return true;
2122 }
2123
2124 .int items_added;
2125 bool PlayerThink(entity this)
2126 {
2127         if (game_stopped || intermission_running) {
2128                 this.modelflags &= ~MF_ROCKET;
2129                 if(intermission_running)
2130                         IntermissionThink(this);
2131                 return false;
2132         }
2133
2134         if (timeout_status == TIMEOUT_ACTIVE) {
2135         // don't allow the player to turn around while game is paused
2136                 // FIXME turn this into CSQC stuff
2137                 this.v_angle = this.lastV_angle;
2138                 this.angles = this.lastV_angle;
2139                 this.fixangle = true;
2140         }
2141
2142         if (frametime) player_powerups(this);
2143
2144         if (IS_DEAD(this)) {
2145                 if (this.personal && g_race_qualifying) {
2146                         if (time > this.respawn_time) {
2147                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2148                                 respawn(this);
2149                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2150                         }
2151                 } else {
2152                         if (frametime) player_anim(this);
2153
2154                         if (this.respawn_flags & RESPAWN_DENY)
2155                         {
2156                                 STAT(RESPAWN_TIME, this) = 0;
2157                                 return false;
2158                         }
2159
2160                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2161
2162                         switch(this.deadflag)
2163                         {
2164                                 case DEAD_DYING:
2165                                 {
2166                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2167                                                 this.deadflag = DEAD_RESPAWNING;
2168                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2169                                                 this.deadflag = DEAD_DEAD;
2170                                         break;
2171                                 }
2172                                 case DEAD_DEAD:
2173                                 {
2174                                         if (button_pressed)
2175                                                 this.deadflag = DEAD_RESPAWNABLE;
2176                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2177                                                 this.deadflag = DEAD_RESPAWNING;
2178                                         break;
2179                                 }
2180                                 case DEAD_RESPAWNABLE:
2181                                 {
2182                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2183                                                 this.deadflag = DEAD_RESPAWNING;
2184                                         break;
2185                                 }
2186                                 case DEAD_RESPAWNING:
2187                                 {
2188                                         if (time > this.respawn_time)
2189                                         {
2190                                                 this.respawn_time = time + 1; // only retry once a second
2191                                                 this.respawn_time_max = this.respawn_time;
2192                                                 respawn(this);
2193                                         }
2194                                         break;
2195                                 }
2196                         }
2197
2198                         ShowRespawnCountdown(this);
2199
2200                         if (this.respawn_flags & RESPAWN_SILENT)
2201                                 STAT(RESPAWN_TIME, this) = 0;
2202                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2203                         {
2204                                 if (time < this.respawn_time)
2205                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2206                                 else if (this.deadflag != DEAD_RESPAWNING)
2207                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2208                         }
2209                         else
2210                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2211                 }
2212
2213                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2214                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2215                         STAT(RESPAWN_TIME, this) *= -1;
2216
2217                 return false;
2218         }
2219
2220         bool have_hook = false;
2221         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2222         {
2223                 .entity weaponentity = weaponentities[slot];
2224                 if(this.(weaponentity).hook.state)
2225                 {
2226                         have_hook = true;
2227                         break;
2228                 }
2229         }
2230         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2231         if (have_hook) {
2232                 do_crouch = false;
2233         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2234                 do_crouch = false;
2235         } else if (this.vehicle) {
2236                 do_crouch = false;
2237         } else if (STAT(FROZEN, this)) {
2238                 do_crouch = false;
2239     }
2240
2241         if (do_crouch) {
2242                 if (!this.crouch) {
2243                         this.crouch = true;
2244                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2245                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2246                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2247                 }
2248         } else if (this.crouch) {
2249         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2250         if (!trace_startsolid) {
2251             this.crouch = false;
2252             this.view_ofs = STAT(PL_VIEW_OFS, this);
2253             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2254         }
2255         }
2256
2257         FixPlayermodel(this);
2258
2259         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2260         //if(frametime)
2261         {
2262                 this.items &= ~this.items_added;
2263
2264                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2265                 {
2266                         .entity weaponentity = weaponentities[slot];
2267                         W_WeaponFrame(this, weaponentity);
2268
2269                         if(slot == 0)
2270                         {
2271                                 this.clip_load = this.(weaponentity).clip_load;
2272                                 this.clip_size = this.(weaponentity).clip_size;
2273                         }
2274                 }
2275
2276                 this.items_added = 0;
2277                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2278             this.items_added |= IT_FUEL;
2279
2280                 this.items |= this.items_added;
2281         }
2282
2283         player_regen(this);
2284
2285         // WEAPONTODO: Add a weapon request for this
2286         // rot vortex charge to the charge limit
2287         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2288         {
2289                 .entity weaponentity = weaponentities[slot];
2290                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2291                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2292         }
2293
2294         if (frametime) player_anim(this);
2295
2296         // secret status
2297         secrets_setstatus(this);
2298
2299         // monsters status
2300         monsters_setstatus(this);
2301
2302         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2303
2304         return true;
2305 }
2306
2307 void ObserverThink(entity this)
2308 {
2309         if ( CS(this).impulse )
2310         {
2311                 MinigameImpulse(this, CS(this).impulse);
2312                 CS(this).impulse = 0;
2313         }
2314
2315         if (this.flags & FL_JUMPRELEASED) {
2316                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2317                         this.flags &= ~FL_JUMPRELEASED;
2318                         this.flags |= FL_SPAWNING;
2319                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2320                         this.flags &= ~FL_JUMPRELEASED;
2321                         if(SpectateNext(this)) {
2322                                 TRANSMUTE(Spectator, this);
2323                         }
2324                 } else {
2325                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2326                         set_movetype(this, preferred_movetype);
2327                 }
2328         } else {
2329                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2330                         this.flags |= FL_JUMPRELEASED;
2331                         if(this.flags & FL_SPAWNING)
2332                         {
2333                                 this.flags &= ~FL_SPAWNING;
2334                                 Join(this);
2335                                 return;
2336                         }
2337                 }
2338         }
2339 }
2340
2341 void SpectatorThink(entity this)
2342 {
2343         if ( CS(this).impulse )
2344         {
2345                 if(MinigameImpulse(this, CS(this).impulse))
2346                         CS(this).impulse = 0;
2347
2348                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2349                 {
2350                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2351                         CS(this).impulse = 0;
2352                         return;
2353                 }
2354         }
2355
2356         if (this.flags & FL_JUMPRELEASED) {
2357                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2358                         this.flags &= ~FL_JUMPRELEASED;
2359                         this.flags |= FL_SPAWNING;
2360                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         if(SpectateNext(this)) {
2363                                 TRANSMUTE(Spectator, this);
2364                         } else {
2365                                 TRANSMUTE(Observer, this);
2366                                 PutClientInServer(this);
2367                         }
2368                         CS(this).impulse = 0;
2369                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2370                         this.flags &= ~FL_JUMPRELEASED;
2371                         if(SpectatePrev(this)) {
2372                                 TRANSMUTE(Spectator, this);
2373                         } else {
2374                                 TRANSMUTE(Observer, this);
2375                                 PutClientInServer(this);
2376                         }
2377                         CS(this).impulse = 0;
2378                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2379                         this.flags &= ~FL_JUMPRELEASED;
2380                         TRANSMUTE(Observer, this);
2381                         PutClientInServer(this);
2382                 } else {
2383                         if(!SpectateUpdate(this))
2384                                 PutObserverInServer(this);
2385                 }
2386         } else {
2387                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2388                         this.flags |= FL_JUMPRELEASED;
2389                         if(this.flags & FL_SPAWNING)
2390                         {
2391                                 this.flags &= ~FL_SPAWNING;
2392                                 Join(this);
2393                                 return;
2394                         }
2395                 }
2396                 if(!SpectateUpdate(this))
2397                         PutObserverInServer(this);
2398         }
2399
2400         this.flags |= FL_CLIENT | FL_NOTARGET;
2401 }
2402
2403 void vehicles_enter (entity pl, entity veh);
2404 void PlayerUseKey(entity this)
2405 {
2406         if (!IS_PLAYER(this))
2407                 return;
2408
2409         if(this.vehicle)
2410         {
2411                 if(!game_stopped)
2412                 {
2413                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2414                         return;
2415                 }
2416         }
2417         else if(autocvar_g_vehicles_enter)
2418         {
2419                 if(!STAT(FROZEN, this))
2420                 if(!IS_DEAD(this))
2421                 if(!game_stopped)
2422                 {
2423                         entity head, closest_target = NULL;
2424                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2425
2426                         while(head) // find the closest acceptable target to enter
2427                         {
2428                                 if(IS_VEHICLE(head))
2429                                 if(!IS_DEAD(head))
2430                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2431                                 if(head.takedamage != DAMAGE_NO)
2432                                 {
2433                                         if(closest_target)
2434                                         {
2435                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2436                                                 { closest_target = head; }
2437                                         }
2438                                         else { closest_target = head; }
2439                                 }
2440
2441                                 head = head.chain;
2442                         }
2443
2444                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2445                 }
2446         }
2447
2448         // a use key was pressed; call handlers
2449         MUTATOR_CALLHOOK(PlayerUseKey, this);
2450 }
2451
2452
2453 /*
2454 =============
2455 PlayerPreThink
2456
2457 Called every frame for each client before the physics are run
2458 =============
2459 */
2460 .float last_vehiclecheck;
2461 void PlayerPreThink (entity this)
2462 {
2463         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2464         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2465
2466         WarpZone_PlayerPhysics_FixVAngle(this);
2467
2468         if (frametime) {
2469                 // physics frames: update anticheat stuff
2470                 anticheat_prethink(this);
2471         }
2472
2473         if (blockSpectators && frametime) {
2474                 // WORKAROUND: only use dropclient in server frames (frametime set).
2475                 // Never use it in cl_movement frames (frametime zero).
2476                 checkSpectatorBlock(this);
2477     }
2478
2479         zoomstate_set = false;
2480
2481         // Check for nameless players
2482         if (isInvisibleString(this.netname)) {
2483                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2484                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2485         }
2486         if (this.netname != CS(this).netname_previous) {
2487                 if (autocvar_sv_eventlog) {
2488                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2489         }
2490                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2491                 CS(this).netname_previous = strzone(this.netname);
2492         }
2493
2494         // version nagging
2495         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2496         CS(this).version_nagtime = 0;
2497         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2498             // git client
2499         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2500             // git server
2501             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2502         } else {
2503             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2504             if (r < 0) { // old client
2505                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2506             } else if (r > 0) { // old server
2507                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2508             }
2509         }
2510     }
2511
2512         // GOD MODE info
2513         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2514         {
2515                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2516                 this.max_armorvalue = 0;
2517         }
2518
2519         if(IS_PLAYER(this))
2520         {
2521                 if (STAT(FROZEN, this) == 2)
2522                 {
2523                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2524                         this.health = max(1, this.revive_progress * start_health);
2525                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2526
2527                         if (this.revive_progress >= 1)
2528                                 Unfreeze(this);
2529                 }
2530                 else if (STAT(FROZEN, this) == 3)
2531                 {
2532                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2533                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2534
2535                         if (this.health < 1)
2536                         {
2537                                 if (this.vehicle)
2538                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2539                                 if(this.event_damage)
2540                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2541                         }
2542                         else if (this.revive_progress <= 0)
2543                                 Unfreeze(this);
2544                 }
2545         }
2546
2547         MUTATOR_CALLHOOK(PlayerPreThink, this);
2548
2549         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2550         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2551         {
2552                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2553                 {
2554                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2555                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2556                         {
2557                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2558                         }
2559                         else if(!it.owner)
2560                         {
2561                                 if(!it.team || SAME_TEAM(this, it))
2562                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2563                                 else if(autocvar_g_vehicles_steal)
2564                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2565                         }
2566                 });
2567
2568                 this.last_vehiclecheck = time + 1;
2569         }
2570
2571         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2572         {
2573                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2574                         PlayerUseKey(this);
2575                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2576         }
2577
2578         if (IS_REAL_CLIENT(this))
2579                 PrintWelcomeMessage(this);
2580
2581         if (IS_PLAYER(this)) {
2582                 if(!PlayerThink(this))
2583                         return;
2584         }
2585         else if (game_stopped || intermission_running) {
2586                 if(intermission_running)
2587                         IntermissionThink(this);
2588                 return;
2589         }
2590         else if (IS_OBSERVER(this)) {
2591                 ObserverThink(this);
2592         }
2593         else if (IS_SPEC(this)) {
2594                 SpectatorThink(this);
2595         }
2596
2597         // WEAPONTODO: Add weapon request for this
2598         if (!zoomstate_set) {
2599                 bool wep_zoomed = false;
2600                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2601                 {
2602                         .entity weaponentity = weaponentities[slot];
2603                         Weapon thiswep = this.(weaponentity).m_weapon;
2604                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2605                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2606                 }
2607                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2608     }
2609
2610         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2611         {
2612                 CS(this).teamkill_soundtime = 0;
2613
2614                 entity e = CS(this).teamkill_soundsource;
2615                 entity oldpusher = e.pusher;
2616                 e.pusher = this;
2617                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2618                 e.pusher = oldpusher;
2619         }
2620
2621         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2622                 CS(this).taunt_soundtime = 0;
2623                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2624         }
2625
2626         target_voicescript_next(this);
2627
2628         // WEAPONTODO: Move into weaponsystem somehow
2629         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2630         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2631         {
2632                 .entity weaponentity = weaponentities[slot];
2633                 if(this.(weaponentity).m_weapon == WEP_Null)
2634                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2635         }
2636 }
2637
2638 void DrownPlayer(entity this)
2639 {
2640         if(IS_DEAD(this))
2641                 return;
2642
2643         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2644         {
2645                 if(this.air_finished < time)
2646                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2647                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2648                 this.dmg = 2;
2649         }
2650         else if (this.air_finished < time)
2651         {       // drown!
2652                 if (this.pain_finished < time)
2653                 {
2654                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2655                         this.pain_finished = time + 0.5;
2656                 }
2657         }
2658 }
2659
2660 .bool move_qcphysics;
2661
2662 void Player_Physics(entity this)
2663 {
2664         set_movetype(this, this.move_movetype);
2665
2666         if(!this.move_qcphysics)
2667                 return;
2668
2669         if(!frametime && !CS(this).pm_frametime)
2670                 return;
2671
2672         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2673
2674         CS(this).pm_frametime = 0;
2675 }
2676
2677 /*
2678 =============
2679 PlayerPostThink
2680
2681 Called every frame for each client after the physics are run
2682 =============
2683 */
2684 void PlayerPostThink (entity this)
2685 {
2686         Player_Physics(this);
2687
2688         if (sv_maxidle > 0)
2689         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2690         if (IS_REAL_CLIENT(this))
2691         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2692         {
2693                 int totalClients = 0;
2694                 if(sv_maxidle_slots > 0)
2695                 {
2696                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2697                         {
2698                                 ++totalClients;
2699                         });
2700                 }
2701
2702                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2703                 { /* do nothing */ }
2704                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2705                 {
2706                         if (CS(this).idlekick_lasttimeleft)
2707                         {
2708                                 CS(this).idlekick_lasttimeleft = 0;
2709                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2710                         }
2711                 }
2712                 else
2713                 {
2714                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2715                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2716                                 if (!CS(this).idlekick_lasttimeleft)
2717                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2718                         }
2719                         if (timeleft <= 0) {
2720                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2721                                 dropclient(this);
2722                                 return;
2723                         }
2724                         else if (timeleft <= 10) {
2725                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2726                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2727                 }
2728                                 CS(this).idlekick_lasttimeleft = timeleft;
2729                         }
2730                 }
2731         }
2732
2733         CheatFrame(this);
2734
2735         if (game_stopped)
2736         {
2737                 this.solid = SOLID_NOT;
2738                 this.takedamage = DAMAGE_NO;
2739                 set_movetype(this, MOVETYPE_NONE);
2740         }
2741
2742         if (IS_PLAYER(this)) {
2743                 DrownPlayer(this);
2744                 UpdateChatBubble(this);
2745                 if (CS(this).impulse) ImpulseCommands(this);
2746                 if (game_stopped)
2747                 {
2748                         CSQCMODEL_AUTOUPDATE(this);
2749                         return;
2750                 }
2751                 GetPressedKeys(this);
2752         }
2753
2754         if (this.waypointsprite_attachedforcarrier) {
2755             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2756                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2757     }
2758
2759         playerdemo_write(this);
2760
2761         CSQCMODEL_AUTOUPDATE(this);
2762 }
2763
2764 // hack to copy the button fields from the client entity to the Client State
2765 void PM_UpdateButtons(entity this, entity store)
2766 {
2767         if(this.impulse)
2768                 store.impulse = this.impulse;
2769         this.impulse = 0;
2770
2771         store.button0 = this.button0;
2772         store.button2 = this.button2;
2773         store.button3 = this.button3;
2774         store.button4 = this.button4;
2775         store.button5 = this.button5;
2776         store.button6 = this.button6;
2777         store.button7 = this.button7;
2778         store.button8 = this.button8;
2779         store.button9 = this.button9;
2780         store.button10 = this.button10;
2781         store.button11 = this.button11;
2782         store.button12 = this.button12;
2783         store.button13 = this.button13;
2784         store.button14 = this.button14;
2785         store.button15 = this.button15;
2786         store.button16 = this.button16;
2787         store.buttonuse = this.buttonuse;
2788         store.buttonchat = this.buttonchat;
2789
2790         store.cursor_active = this.cursor_active;
2791         store.cursor_screen = this.cursor_screen;
2792         store.cursor_trace_start = this.cursor_trace_start;
2793         store.cursor_trace_endpos = this.cursor_trace_endpos;
2794         store.cursor_trace_ent = this.cursor_trace_ent;
2795
2796         store.ping = this.ping;
2797         store.ping_packetloss = this.ping_packetloss;
2798         store.ping_movementloss = this.ping_movementloss;
2799
2800         store.v_angle = this.v_angle;
2801         store.movement = this.movement;
2802 }