qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/chat.qh>
   6 #include <server/miscfunctions.qh>
   7 #include <common/effects/all.qh>
   8 #include "anticheat.qh"
   9 #include "impulse.qh"
  10 #include "player.qh"
  11 #include "ipban.qh"
  12 #include "miscfunctions.qh"
  13 #include "portals.qh"
  14 #include "teamplay.qh"
  15 #include "spawnpoints.qh"
  16 #include "resources.qh"
  17 #include "damage.qh"
  18 #include "handicap.qh"
  19 #include "hook.qh"
  20 #include <server/intermission.qh>
  21 #include "command/common.qh"
  22 #include "command/vote.qh"
  23 #include "clientkill.qh"
  24 #include "cheats.qh"
  25 #include "world.qh"
  26 #include <server/gamelog.qh>
  27 #include "race.qh"
  28 #include <server/main.qh>
  29 #include "antilag.qh"
  30 #include "campaign.qh"
  31 #include "command/common.qh"
  32 #include "scores_rules.qh"
  33 #include "weapons/common.qh"
  34
  35 #include "bot/api.qh"
  36
  37 #include "../common/ent_cs.qh"
  38 #include "../common/wepent.qh"
  39 #include <common/state.qh>
  40
  41 #include "compat/quake3.qh"
  42
  43 #include <common/effects/qc/globalsound.qh>
  44
  45 #include "../common/mapobjects/func/conveyor.qh"
  46 #include <common/mapobjects/func/ladder.qh>
  47 #include "../common/mapobjects/teleporters.qh"
  48 #include "../common/mapobjects/target/spawnpoint.qh"
  49 #include <common/mapobjects/trigger/counter.qh>
  50 #include <common/mapobjects/trigger/swamp.qh>
  51
  52 #include "../common/vehicles/all.qh"
  53
  54 #include "weapons/hitplot.qh"
  55 #include "weapons/selection.qh"
  56 #include "weapons/weaponsystem.qh"
  57
  58 #include "../common/net_notice.qh"
  59 #include "../common/net_linked.qh"
  60 #include "../common/physics/player.qh"
  61
  62 #include <common/vehicles/sv_vehicles.qh>
  63
  64 #include "../common/items/_mod.qh"
  65
  66 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  67
  68 #include "../common/mutators/mutator/waypoints/all.qh"
  69 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  70 #include <common/gamemodes/_mod.qh>
  71
  72 #include "../common/mapobjects/subs.qh"
  73 #include "../common/mapobjects/triggers.qh"
  74 #include "../common/mapobjects/trigger/secret.qh"
  75
  76 #include "../common/minigames/sv_minigames.qh"
  77
  78 #include "../common/items/inventory.qh"
  79
  80 #include "../common/monsters/sv_monsters.qh"
  81
  82 #include "../lib/warpzone/server.qh"
  83
  84 #include <common/mutators/mutator/overkill/oknex.qh>
  85
  86 #include <common/weapons/weapon/vortex.qh>
  87
  88 STATIC_METHOD(Client, Add, void(Client this, int _team))
  89 {
  90     ClientConnect(this);
  91     TRANSMUTE(Player, this);
  92     this.frame = 12; // 7
  93     this.team = _team;
  94     PutClientInServer(this);
  95 }
  96
  97 STATIC_METHOD(Client, Remove, void(Client this))
  98 {
  99     TRANSMUTE(Observer, this);
 100     PutClientInServer(this);
 101     ClientDisconnect(this);
 102 }
 103
 104 void send_CSQC_teamnagger() {
 105         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 106 }
 107
 108 int CountSpectators(entity player, entity to)
 109 {
 110         if(!player) { return 0; } // not sure how, but best to be safe
 111
 112         int spec_count = 0;
 113
 114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 115         {
 116                 spec_count++;
 117         });
 118
 119         return spec_count;
 120 }
 121
 122 void WriteSpectators(entity player, entity to)
 123 {
 124         if(!player) { return; } // not sure how, but best to be safe
 125
 126         int spec_count = 0;
 127         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 128         {
 129                 if(spec_count >= MAX_SPECTATORS)
 130                         break;
 131                 WriteByte(MSG_ENTITY, num_for_edict(it));
 132                 ++spec_count;
 133         });
 134 }
 135
 136 bool ClientData_Send(entity this, entity to, int sf)
 137 {
 138         assert(to == this.owner, return false);
 139
 140         entity e = to;
 141         if (IS_SPEC(e)) e = e.enemy;
 142
 143         sf = 0;
 144         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 145         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 146         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 147         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 148
 149         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 150         WriteByte(MSG_ENTITY, sf);
 151
 152         if (sf & BIT(1))
 153                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 154
 155         if(sf & BIT(4))
 156         {
 157                 float specs = CountSpectators(e, to);
 158                 WriteByte(MSG_ENTITY, specs);
 159                 WriteSpectators(e, to);
 160         }
 161
 162         return true;
 163 }
 164
 165 void ClientData_Attach(entity this)
 166 {
 167         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 168         CS(this).clientdata.drawonlytoclient = this;
 169         CS(this).clientdata.owner = this;
 170 }
 171
 172 void ClientData_Detach(entity this)
 173 {
 174         delete(CS(this).clientdata);
 175         CS(this).clientdata = NULL;
 176 }
 177
 178 void ClientData_Touch(entity e)
 179 {
 180         entity cd = CS(e).clientdata;
 181         if (cd) { cd.SendFlags = 1; }
 182
 183         // make it spectatable
 184         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 185         {
 186                 entity cd = CS(it).clientdata;
 187                 if (cd) { cd.SendFlags = 1; }
 188         });
 189 }
 190
 191
 192 /*
 193 =============
 194 CheckPlayerModel
 195
 196 Checks if the argument string can be a valid playermodel.
 197 Returns a valid one in doubt.
 198 =============
 199 */
 200 string FallbackPlayerModel;
 201 string CheckPlayerModel(string plyermodel) {
 202         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 203         {
 204                 // note: we cannot summon Don Strunzone here, some player may
 205                 // still have the model string set. In case anyone manages how
 206                 // to change a cvar default, we'll have a small leak here.
 207                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 208         }
 209         // only in right path
 210         if( substring(plyermodel,0,14) != "models/player/")
 211                 return FallbackPlayerModel;
 212         // only good file extensions
 213         if(substring(plyermodel,-4,4) != ".zym")
 214         if(substring(plyermodel,-4,4) != ".dpm")
 215         if(substring(plyermodel,-4,4) != ".iqm")
 216         if(substring(plyermodel,-4,4) != ".md3")
 217         if(substring(plyermodel,-4,4) != ".psk")
 218                 return FallbackPlayerModel;
 219         // forbid the LOD models
 220         if(substring(plyermodel, -9,5) == "_lod1")
 221                 return FallbackPlayerModel;
 222         if(substring(plyermodel, -9,5) == "_lod2")
 223                 return FallbackPlayerModel;
 224         if(plyermodel != strtolower(plyermodel))
 225                 return FallbackPlayerModel;
 226         // also, restrict to server models
 227         if(autocvar_sv_servermodelsonly)
 228         {
 229                 if(!fexists(plyermodel))
 230                         return FallbackPlayerModel;
 231         }
 232         return plyermodel;
 233 }
 234
 235 void setplayermodel(entity e, string modelname)
 236 {
 237         precache_model(modelname);
 238         _setmodel(e, modelname);
 239         player_setupanimsformodel(e);
 240         if(!autocvar_g_debug_globalsounds)
 241                 UpdatePlayerSounds(e);
 242 }
 243
 244 /** putting a client as observer in the server */
 245 void PutObserverInServer(entity this)
 246 {
 247         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 248         PlayerState_detach(this);
 249
 250         if (IS_PLAYER(this))
 251         {
 252                 if(GetResource(this, RES_HEALTH) >= 1)
 253                 {
 254                         // despawn effect
 255                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 256                 }
 257
 258                 // was a player, recount votes and ready status
 259                 if(IS_REAL_CLIENT(this))
 260                 {
 261                         if (vote_called) { VoteCount(false); }
 262                         ReadyCount();
 263                 }
 264         }
 265
 266         entity spot = SelectSpawnPoint(this, true);
 267         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268         this.angles = vec2(spot.angles);
 269         this.fixangle = true;
 270         // offset it so that the spectator spawns higher off the ground, looks better this way
 271         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 272         if (IS_REAL_CLIENT(this))
 273         {
 274                 msg_entity = this;
 275                 WriteByte(MSG_ONE, SVC_SETVIEW);
 276                 WriteEntity(MSG_ONE, this);
 277         }
 278         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 279         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 280         if(!autocvar_g_debug_globalsounds)
 281         {
 282                 // needed for player sounds
 283                 this.model = "";
 284                 FixPlayermodel(this);
 285         }
 286         setmodel(this, MDL_Null);
 287         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 288         this.view_ofs = '0 0 0';
 289
 290         RemoveGrapplingHooks(this);
 291         Portal_ClearAll(this);
 292         Unfreeze(this, false);
 293         SetSpectatee(this, NULL);
 294
 295         if (this.alivetime)
 296         {
 297                 if (!warmup_stage)
 298                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 299                 this.alivetime = 0;
 300         }
 301
 302         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 303
 304         WaypointSprite_PlayerDead(this);
 305
 306         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 307                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 308
 309         accuracy_resend(this);
 310
 311         CS(this).spectatortime = time;
 312         if(this.bot_attack)
 313                 IL_REMOVE(g_bot_targets, this);
 314         this.bot_attack = false;
 315         if(this.monster_attack)
 316                 IL_REMOVE(g_monster_targets, this);
 317         this.monster_attack = false;
 318         STAT(HUD, this) = HUD_NORMAL;
 319         TRANSMUTE(Observer, this);
 320         this.iscreature = false;
 321         this.teleportable = TELEPORT_SIMPLE;
 322         if(this.damagedbycontents)
 323                 IL_REMOVE(g_damagedbycontents, this);
 324         this.damagedbycontents = false;
 325         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 326         SetSpectatee_status(this, etof(this));
 327         this.takedamage = DAMAGE_NO;
 328         this.solid = SOLID_NOT;
 329         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 330         this.flags = FL_CLIENT | FL_NOTARGET;
 331         this.effects = 0;
 332         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 333         this.pauserotarmor_finished = 0;
 334         this.pauserothealth_finished = 0;
 335         this.pauseregen_finished = 0;
 336         this.damageforcescale = 0;
 337         this.death_time = 0;
 338         this.respawn_flags = 0;
 339         this.respawn_time = 0;
 340         STAT(RESPAWN_TIME, this) = 0;
 341         this.alpha = 0;
 342         this.scale = 0;
 343         this.fade_time = 0;
 344         this.pain_finished = 0;
 345         STAT(STRENGTH_FINISHED, this) = 0;
 346         STAT(INVINCIBLE_FINISHED, this) = 0;
 347         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 348         STAT(AIR_FINISHED, this) = 0;
 349         //this.dphitcontentsmask = 0;
 350         this.dphitcontentsmask = DPCONTENTS_SOLID;
 351         if (autocvar_g_playerclip_collisions)
 352                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 353         this.pushltime = 0;
 354         this.istypefrag = 0;
 355         setthink(this, func_null);
 356         this.nextthink = 0;
 357         this.deadflag = DEAD_NO;
 358         UNSET_DUCKED(this);
 359         STAT(REVIVE_PROGRESS, this) = 0;
 360         this.revival_time = 0;
 361         this.draggable = drag_undraggable;
 362
 363         this.items = 0;
 364         STAT(WEAPONS, this) = '0 0 0';
 365         this.drawonlytoclient = this;
 366
 367         this.viewloc = NULL;
 368
 369         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 370
 371         this.weaponmodel = "";
 372         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         {
 374                 this.weaponentities[slot] = NULL;
 375         }
 376         this.exteriorweaponentity = NULL;
 377         CS(this).killcount = FRAGS_SPECTATOR;
 378         this.velocity = '0 0 0';
 379         this.avelocity = '0 0 0';
 380         this.punchangle = '0 0 0';
 381         this.punchvector = '0 0 0';
 382         this.oldvelocity = this.velocity;
 383         this.fire_endtime = -1;
 384         this.event_damage = func_null;
 385         this.event_heal = func_null;
 386
 387         for(int slot = 0; slot < MAX_AXH; ++slot)
 388         {
 389                 entity axh = this.(AuxiliaryXhair[slot]);
 390                 this.(AuxiliaryXhair[slot]) = NULL;
 391
 392                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 393                         delete(axh);
 394         }
 395
 396         if (mutator_returnvalue)
 397         {
 398                 // mutator prevents resetting teams+score
 399         }
 400         else
 401         {
 402                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 403                 this.frags = FRAGS_SPECTATOR;
 404         }
 405         if (CS(this).just_joined)
 406                 CS(this).just_joined = false;
 407 }
 408
 409 int player_getspecies(entity this)
 410 {
 411         get_model_parameters(this.model, this.skin);
 412         int s = get_model_parameters_species;
 413         get_model_parameters(string_null, 0);
 414         if (s < 0) return SPECIES_HUMAN;
 415         return s;
 416 }
 417
 418 .float model_randomizer;
 419 void FixPlayermodel(entity player)
 420 {
 421         string defaultmodel = "";
 422         int defaultskin = 0;
 423         if(autocvar_sv_defaultcharacter)
 424         {
 425                 if(teamplay)
 426                 {
 427                         switch(player.team)
 428                         {
 429                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 430                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 431                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 432                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 433                         }
 434                 }
 435
 436                 if(defaultmodel == "")
 437                 {
 438                         defaultmodel = autocvar_sv_defaultplayermodel;
 439                         defaultskin = autocvar_sv_defaultplayerskin;
 440                 }
 441
 442                 int n = tokenize_console(defaultmodel);
 443                 if(n > 0)
 444                 {
 445                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 446                         // However, do NOT randomize if the player-selected model is in the list.
 447                         for (int i = 0; i < n; ++i)
 448                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 449                                         defaultmodel = argv(i);
 450                 }
 451
 452                 int i = strstrofs(defaultmodel, ":", 0);
 453                 if(i >= 0)
 454                 {
 455                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 456                         defaultmodel = substring(defaultmodel, 0, i);
 457                 }
 458         }
 459         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 460         {
 461                 if(teamplay)
 462                 {
 463                         switch(player.team)
 464                         {
 465                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 466                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 467                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 468                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 469                         }
 470                 }
 471
 472                 if(!defaultskin)
 473                         defaultskin = autocvar_sv_defaultplayerskin;
 474         }
 475
 476         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 477         defaultmodel = M_ARGV(0, string);
 478         defaultskin = M_ARGV(1, int);
 479
 480         bool chmdl = false;
 481         int oldskin;
 482         if(defaultmodel != "")
 483         {
 484                 if (defaultmodel != player.model)
 485                 {
 486                         vector m1 = player.mins;
 487                         vector m2 = player.maxs;
 488                         setplayermodel (player, defaultmodel);
 489                         setsize (player, m1, m2);
 490                         chmdl = true;
 491                 }
 492
 493                 oldskin = player.skin;
 494                 player.skin = defaultskin;
 495         } else {
 496                 if (player.playermodel != player.model || player.playermodel == "")
 497                 {
 498                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 499                         vector m1 = player.mins;
 500                         vector m2 = player.maxs;
 501                         setplayermodel (player, player.playermodel);
 502                         setsize (player, m1, m2);
 503                         chmdl = true;
 504                 }
 505
 506                 if(!autocvar_sv_defaultcharacterskin)
 507                 {
 508                         oldskin = player.skin;
 509                         player.skin = stof(player.playerskin);
 510                 }
 511                 else
 512                 {
 513                         oldskin = player.skin;
 514                         player.skin = defaultskin;
 515                 }
 516         }
 517
 518         if(chmdl || oldskin != player.skin) // model or skin has changed
 519         {
 520                 player.species = player_getspecies(player); // update species
 521                 if(!autocvar_g_debug_globalsounds)
 522                         UpdatePlayerSounds(player); // update skin sounds
 523         }
 524
 525         if(!teamplay)
 526                 if(strlen(autocvar_sv_defaultplayercolors))
 527                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 528                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 529 }
 530
 531 void PutPlayerInServer(entity this)
 532 {
 533         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 534
 535         PlayerState_attach(this);
 536         accuracy_resend(this);
 537
 538         if (this.team < 0)
 539                 TeamBalance_JoinBestTeam(this);
 540
 541         entity spot = SelectSpawnPoint(this, false);
 542         if (!spot) {
 543                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 544                 return; // spawn failed
 545         }
 546
 547         TRANSMUTE(Player, this);
 548
 549         CS(this).wasplayer = true;
 550         this.iscreature = true;
 551         this.teleportable = TELEPORT_NORMAL;
 552         if(!this.damagedbycontents)
 553                 IL_PUSH(g_damagedbycontents, this);
 554         this.damagedbycontents = true;
 555         set_movetype(this, MOVETYPE_WALK);
 556         this.solid = SOLID_SLIDEBOX;
 557         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 558         if (autocvar_g_playerclip_collisions)
 559                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 560         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 561                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 562         this.frags = FRAGS_PLAYER;
 563         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 564         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 565         if (autocvar__notarget)
 566                 this.flags |= FL_NOTARGET;
 567         this.takedamage = DAMAGE_AIM;
 568         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 569
 570         if (warmup_stage) {
 571                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 572                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 573                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 574                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 575                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 576                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 577                 SetResource(this, RES_HEALTH, warmup_start_health);
 578                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 579                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 580         } else {
 581                 SetResource(this, RES_SHELLS, start_ammo_shells);
 582                 SetResource(this, RES_BULLETS, start_ammo_nails);
 583                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 584                 SetResource(this, RES_CELLS, start_ammo_cells);
 585                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 586                 SetResource(this, RES_FUEL, start_ammo_fuel);
 587                 SetResource(this, RES_HEALTH, start_health);
 588                 SetResource(this, RES_ARMOR, start_armorvalue);
 589                 STAT(WEAPONS, this) = start_weapons;
 590                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 591                 {
 592                         GiveRandomWeapons(this, random_start_weapons_count,
 593                                 autocvar_g_random_start_weapons, random_start_ammo);
 594                 }
 595         }
 596         SetSpectatee_status(this, 0);
 597
 598         PS(this).dual_weapons = '0 0 0';
 599
 600         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 601
 602         this.items = start_items;
 603
 604         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 605         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 606         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 607         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 608         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 609         if (!sv_ready_restart_after_countdown && time < game_starttime)
 610         {
 611                 float f = game_starttime - time;
 612                 this.spawnshieldtime += f;
 613                 this.pauserotarmor_finished += f;
 614                 this.pauserothealth_finished += f;
 615                 this.pauseregen_finished += f;
 616         }
 617
 618         this.damageforcescale = autocvar_g_player_damageforcescale;
 619         this.death_time = 0;
 620         this.respawn_flags = 0;
 621         this.respawn_time = 0;
 622         STAT(RESPAWN_TIME, this) = 0;
 623         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 624         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 625         this.fade_time = 0;
 626         this.pain_finished = 0;
 627         this.pushltime = 0;
 628         setthink(this, func_null); // players have no think function
 629         this.nextthink = 0;
 630         this.dmg_team = 0;
 631         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 632
 633         this.deadflag = DEAD_NO;
 634
 635         this.angles = spot.angles;
 636         this.angles_z = 0; // never spawn tilted even if the spot says to
 637         if (IS_BOT_CLIENT(this))
 638         {
 639                 this.v_angle = this.angles;
 640                 bot_aim_reset(this);
 641         }
 642         this.fixangle = true; // turn this way immediately
 643         this.oldvelocity = this.velocity = '0 0 0';
 644         this.avelocity = '0 0 0';
 645         this.punchangle = '0 0 0';
 646         this.punchvector = '0 0 0';
 647
 648         STAT(STRENGTH_FINISHED, this) = 0;
 649         STAT(INVINCIBLE_FINISHED, this) = 0;
 650         this.fire_endtime = -1;
 651         STAT(REVIVE_PROGRESS, this) = 0;
 652         this.revival_time = 0;
 653
 654         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 655         STAT(BUFFS, this) = 0;
 656         STAT(BUFF_TIME, this) = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         {
 761                 string s = spot.target;
 762                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 763                         spot.target = string_null;
 764                 SUB_UseTargets(spot, this, NULL);
 765                 if(g_assault || g_race)
 766                         spot.target = s;
 767         }
 768
 769         Unfreeze(this, false);
 770
 771         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 783                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 784                 else
 785                         this.(weaponentity).m_switchweapon = WEP_Null;
 786                 this.(weaponentity).m_weapon = WEP_Null;
 787                 this.(weaponentity).weaponname = "";
 788                 this.(weaponentity).m_switchingweapon = WEP_Null;
 789                 this.(weaponentity).cnt = -1;
 790         }
 791
 792         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 793
 794         if (CS(this).impulse) ImpulseCommands(this);
 795
 796         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 797         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 798         {
 799                 .entity weaponentity = weaponentities[slot];
 800                 W_WeaponFrame(this, weaponentity);
 801         }
 802
 803         if (!warmup_stage && !this.alivetime)
 804                 this.alivetime = time;
 805
 806         antilag_clear(this, CS(this));
 807 }
 808
 809 /** Called when a client spawns in the server */
 810 void PutClientInServer(entity this)
 811 {
 812         if (IS_BOT_CLIENT(this)) {
 813                 TRANSMUTE(Player, this);
 814         } else if (IS_REAL_CLIENT(this)) {
 815                 msg_entity = this;
 816                 WriteByte(MSG_ONE, SVC_SETVIEW);
 817                 WriteEntity(MSG_ONE, this);
 818         }
 819         if (game_stopped)
 820                 TRANSMUTE(Observer, this);
 821
 822         SetSpectatee(this, NULL);
 823
 824         // reset player keys
 825         if(PS(this))
 826                 PS(this).itemkeys = 0;
 827
 828         MUTATOR_CALLHOOK(PutClientInServer, this);
 829
 830         if (IS_OBSERVER(this)) {
 831                 PutObserverInServer(this);
 832         } else if (IS_PLAYER(this)) {
 833                 PutPlayerInServer(this);
 834         }
 835 }
 836
 837 // TODO do we need all these fields, or should we stop autodetecting runtime
 838 // changes and just have a console command to update this?
 839 bool ClientInit_SendEntity(entity this, entity to, int sf)
 840 {
 841         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 842         return = true;
 843         msg_entity = to;
 844         // MSG_INIT replacement
 845         // TODO: make easier to use
 846         Registry_send_all();
 847         W_PROP_reload(MSG_ONE, to);
 848         ClientInit_misc(this);
 849         MUTATOR_CALLHOOK(Ent_Init);
 850 }
 851 void ClientInit_misc(entity this)
 852 {
 853         int channel = MSG_ONE;
 854         WriteHeader(channel, ENT_CLIENT_INIT);
 855         WriteByte(channel, g_nexball_meter_period * 32);
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 864
 865         if(autocvar_sv_foginterval && world.fog != "")
 866                 WriteString(channel, world.fog);
 867         else
 868                 WriteString(channel, "");
 869         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 870         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 871         WriteByte(channel, serverflags);
 872         WriteCoord(channel, autocvar_g_trueaim_minrange);
 873 }
 874
 875 void ClientInit_CheckUpdate(entity this)
 876 {
 877         this.nextthink = time;
 878         if(this.count != autocvar_g_balance_armor_blockpercent)
 879         {
 880                 this.count = autocvar_g_balance_armor_blockpercent;
 881                 this.SendFlags |= 1;
 882         }
 883         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 884         {
 885                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 886                 this.SendFlags |= 1;
 887         }
 888 }
 889
 890 void ClientInit_Spawn()
 891 {
 892         entity e = new_pure(clientinit);
 893         setthink(e, ClientInit_CheckUpdate);
 894         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 895
 896         ClientInit_CheckUpdate(e);
 897 }
 898
 899 /*
 900 =============
 901 SetNewParms
 902 =============
 903 */
 904 void SetNewParms ()
 905 {
 906         // initialize parms for a new player
 907         parm1 = -(86400 * 366);
 908
 909         MUTATOR_CALLHOOK(SetNewParms);
 910 }
 911
 912 /*
 913 =============
 914 SetChangeParms
 915 =============
 916 */
 917 void SetChangeParms (entity this)
 918 {
 919         // save parms for level change
 920         parm1 = CS(this).parm_idlesince - time;
 921
 922         MUTATOR_CALLHOOK(SetChangeParms);
 923 }
 924
 925 /*
 926 =============
 927 DecodeLevelParms
 928 =============
 929 */
 930 void DecodeLevelParms(entity this)
 931 {
 932         // load parms
 933         CS(this).parm_idlesince = parm1;
 934         if (CS(this).parm_idlesince == -(86400 * 366))
 935                 CS(this).parm_idlesince = time;
 936
 937         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 938         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 939
 940         MUTATOR_CALLHOOK(DecodeLevelParms);
 941 }
 942
 943 void FixClientCvars(entity e)
 944 {
 945         // send prediction settings to the client
 946         stuffcmd(e, "\nin_bindmap 0 0\n");
 947         if(autocvar_g_antilag == 3) // client side hitscan
 948                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 949         if(autocvar_sv_gentle)
 950                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 951
 952         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 953         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 954
 955         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 956
 957         MUTATOR_CALLHOOK(FixClientCvars, e);
 958 }
 959
 960 bool findinlist_abbrev(string tofind, string list)
 961 {
 962         if(list == "" || tofind == "")
 963                 return false; // empty list or search, just return
 964
 965         // this function allows abbreviated strings!
 966         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 967         {
 968                 return true;
 969         });
 970
 971         return false;
 972 }
 973
 974 bool PlayerInIPList(entity p, string iplist)
 975 {
 976         // some safety checks (never allow local?)
 977         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 978                 return false;
 979
 980         return findinlist_abbrev(p.netaddress, iplist);
 981 }
 982
 983 bool PlayerInIDList(entity p, string idlist)
 984 {
 985         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 986         if(!p.crypto_idfp)
 987                 return false;
 988
 989         return findinlist_abbrev(p.crypto_idfp, idlist);
 990 }
 991
 992 bool PlayerInList(entity player, string list)
 993 {
 994         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 995 }
 996
 997 #ifdef DP_EXT_PRECONNECT
 998 /*
 999 =============
1000 ClientPreConnect
1001
1002 Called once (not at each match start) when a client begins a connection to the server
1003 =============
1004 */
1005 void ClientPreConnect(entity this)
1006 {
1007         if(autocvar_sv_eventlog)
1008         {
1009                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1010                         this.playerid,
1011                         etof(this),
1012                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1013                 ));
1014         }
1015 }
1016 #endif
1017
1018 string GetClientVersionMessage(entity this)
1019 {
1020         if (CS(this).version_mismatch) {
1021                 if(CS(this).version < autocvar_gameversion) {
1022                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1023                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1024                 } else {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1027                 }
1028         } else {
1029                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1030         }
1031 }
1032
1033 string getwelcomemessage(entity this)
1034 {
1035         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1036         string modifications = M_ARGV(0, string);
1037
1038         if(g_weaponarena)
1039         {
1040                 if(g_weaponarena_random)
1041                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1042                 else
1043                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1044         }
1045         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1046                 modifications = strcat(modifications, ", No start weapons");
1047         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1048                 modifications = strcat(modifications, ", Low gravity");
1049         if(g_weapon_stay && !g_cts)
1050                 modifications = strcat(modifications, ", Weapons stay");
1051         if(autocvar_g_jetpack)
1052                 modifications = strcat(modifications, ", Jet pack");
1053         if(autocvar_g_powerups == 0)
1054                 modifications = strcat(modifications, ", No powerups");
1055         if(autocvar_g_powerups > 0)
1056                 modifications = strcat(modifications, ", Powerups");
1057         modifications = substring(modifications, 2, strlen(modifications) - 2);
1058
1059         string versionmessage = GetClientVersionMessage(this);
1060         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1061
1062         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1063
1064         if(modifications != "")
1065                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1066
1067         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1068         {
1069                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1070                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1071         }
1072
1073         if (cache_mutatormsg != "") {
1074                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1075         }
1076
1077         string mutator_msg = "";
1078         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1079         mutator_msg = M_ARGV(0, string);
1080
1081         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1082
1083         string motd = autocvar_sv_motd;
1084         if (motd != "") {
1085                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1086         }
1087         return s;
1088 }
1089
1090 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1091
1092 /**
1093 =============
1094 ClientConnect
1095
1096 Called when a client connects to the server
1097 =============
1098 */
1099 void ClientConnect(entity this)
1100 {
1101         if (Ban_MaybeEnforceBanOnce(this)) return;
1102         assert(!IS_CLIENT(this), return);
1103         this.flags |= FL_CLIENT;
1104         assert(player_count >= 0, player_count = 0);
1105
1106         TRANSMUTE(Client, this);
1107         CS(this).version_nagtime = time + 10 + random() * 10;
1108
1109         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1110
1111         bot_clientconnect(this);
1112
1113         Player_DetermineForcedTeam(this);
1114
1115         TRANSMUTE(Observer, this);
1116
1117         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1118
1119         // always track bots, don't ask for cl_allow_uidtracking
1120         if (IS_BOT_CLIENT(this))
1121                 PlayerStats_GameReport_AddPlayer(this);
1122         else
1123                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1124
1125         if (autocvar_sv_eventlog)
1126                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1127
1128         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1129
1130         stuffcmd(this, clientstuff, "\n");
1131         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1132
1133         FixClientCvars(this);
1134
1135         // get version info from player
1136         stuffcmd(this, "cmd clientversion $gameversion\n");
1137
1138         // notify about available teams
1139         if (teamplay)
1140         {
1141                 entity balance = TeamBalance_CheckAllowedTeams(this);
1142                 int t = TeamBalance_GetAllowedTeams(balance);
1143                 TeamBalance_Destroy(balance);
1144                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1145         }
1146         else
1147         {
1148                 stuffcmd(this, "set _teams_available 0\n");
1149         }
1150
1151         bot_relinkplayerlist();
1152
1153         CS(this).spectatortime = time;
1154         if (blockSpectators)
1155         {
1156                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1157         }
1158
1159         CS(this).jointime = time;
1160
1161         if (IS_REAL_CLIENT(this))
1162         {
1163                 if (g_weaponarena_weapons == WEPSET(TUBA))
1164                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1165         }
1166
1167         if (!autocvar_sv_foginterval && world.fog != "")
1168                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1169
1170         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1171                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1172                         send_CSQC_teamnagger();
1173
1174         CSQCMODEL_AUTOINIT(this);
1175
1176         CS(this).model_randomizer = random();
1177
1178         if (IS_REAL_CLIENT(this))
1179                 sv_notice_join(this);
1180
1181         this.move_qcphysics = autocvar_sv_qcphysics;
1182
1183         // update physics stats (players can spawn before physics runs)
1184         Physics_UpdateStats(this);
1185
1186         IL_EACH(g_initforplayer, it.init_for_player, {
1187                 it.init_for_player(it, this);
1188         });
1189
1190         Handicap_Initialize(this);
1191
1192         MUTATOR_CALLHOOK(ClientConnect, this);
1193
1194         if (IS_REAL_CLIENT(this))
1195         {
1196                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1197                 {
1198                         CS(this).motd_actived_time = -1;
1199                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1200                 }
1201         }
1202 }
1203 /*
1204 =============
1205 ClientDisconnect
1206
1207 Called when a client disconnects from the server
1208 =============
1209 */
1210 .entity chatbubbleentity;
1211 void ClientDisconnect(entity this)
1212 {
1213         assert(IS_CLIENT(this), return);
1214
1215         PlayerStats_GameReport_FinalizePlayer(this);
1216         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1217         if (CS(this).active_minigame) part_minigame(this);
1218         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1219
1220         if (autocvar_sv_eventlog)
1221                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1222
1223         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1224
1225         if(IS_SPEC(this))
1226                 SetSpectatee(this, NULL);
1227
1228         MUTATOR_CALLHOOK(ClientDisconnect, this);
1229
1230         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1231         strfree(CS(this).weaponorder_byimpulse);
1232         ClientState_detach(this);
1233
1234         Portal_ClearAll(this);
1235
1236         Unfreeze(this, false);
1237
1238         RemoveGrapplingHooks(this);
1239
1240         // Here, everything has been done that requires this player to be a client.
1241
1242         this.flags &= ~FL_CLIENT;
1243
1244         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1245         if (this.killindicator) delete(this.killindicator);
1246
1247         IL_EACH(g_counters, it.realowner == this,
1248         {
1249                 delete(it);
1250         });
1251
1252         WaypointSprite_PlayerGone(this);
1253
1254         bot_relinkplayerlist();
1255
1256         strfree(this.clientstatus);
1257         if (this.personal) delete(this.personal);
1258
1259         this.playerid = 0;
1260         ReadyCount();
1261         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1262
1263         ONREMOVE(this);
1264 }
1265
1266 void ChatBubbleThink(entity this)
1267 {
1268         this.nextthink = time;
1269         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1270         {
1271                 if(this.owner) // but why can that ever be NULL?
1272                         this.owner.chatbubbleentity = NULL;
1273                 delete(this);
1274                 return;
1275         }
1276
1277         this.mdl = "";
1278
1279         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1280         {
1281                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1282                         this.mdl = "models/sprites/minigame_busy.iqm";
1283                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1284                         this.mdl = "models/misc/chatbubble.spr";
1285         }
1286
1287         if ( this.model != this.mdl )
1288                 _setmodel(this, this.mdl);
1289
1290 }
1291
1292 void UpdateChatBubble(entity this)
1293 {
1294         if (this.alpha < 0)
1295                 return;
1296         // spawn a chatbubble entity if needed
1297         if (!this.chatbubbleentity)
1298         {
1299                 this.chatbubbleentity = new(chatbubbleentity);
1300                 this.chatbubbleentity.owner = this;
1301                 this.chatbubbleentity.exteriormodeltoclient = this;
1302                 setthink(this.chatbubbleentity, ChatBubbleThink);
1303                 this.chatbubbleentity.nextthink = time;
1304                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1305                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1306                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1307                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1308                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1309                 //this.chatbubbleentity.model = "";
1310                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1311         }
1312 }
1313
1314 void calculate_player_respawn_time(entity this)
1315 {
1316         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1317                 return;
1318
1319         float gametype_setting_tmp;
1320         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1321         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1322         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1323         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1324         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1325         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1326
1327         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1328         if (teamplay)
1329         {
1330                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1331                         if(it.team == this.team)
1332                                 ++pcount;
1333                 });
1334                 if (sdelay_small_count == 0)
1335                         sdelay_small_count = 1;
1336                 if (sdelay_large_count == 0)
1337                         sdelay_large_count = 1;
1338         }
1339         else
1340         {
1341                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1342                         ++pcount;
1343                 });
1344                 if (sdelay_small_count == 0)
1345                 {
1346                         if (IS_INDEPENDENT_PLAYER(this))
1347                         {
1348                                 // Players play independently. No point in requiring enemies.
1349                                 sdelay_small_count = 1;
1350                         }
1351                         else
1352                         {
1353                                 // Players play AGAINST each other. Enemies required.
1354                                 sdelay_small_count = 2;
1355                         }
1356                 }
1357                 if (sdelay_large_count == 0)
1358                 {
1359                         if (IS_INDEPENDENT_PLAYER(this))
1360                         {
1361                                 // Players play independently. No point in requiring enemies.
1362                                 sdelay_large_count = 1;
1363                         }
1364                         else
1365                         {
1366                                 // Players play AGAINST each other. Enemies required.
1367                                 sdelay_large_count = 2;
1368                         }
1369                 }
1370         }
1371
1372         float sdelay;
1373
1374         if (pcount <= sdelay_small_count)
1375                 sdelay = sdelay_small;
1376         else if (pcount >= sdelay_large_count)
1377                 sdelay = sdelay_large;
1378         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1379                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1380
1381         if(waves)
1382                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1383         else
1384                 this.respawn_time = time + sdelay;
1385
1386         if(sdelay < sdelay_max)
1387                 this.respawn_time_max = time + sdelay_max;
1388         else
1389                 this.respawn_time_max = this.respawn_time;
1390
1391         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1392                 this.respawn_countdown = 10; // first number to count down from is 10
1393         else
1394                 this.respawn_countdown = -1; // do not count down
1395
1396         if(autocvar_g_forced_respawn)
1397                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1398 }
1399
1400 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1401 // added to the model skins
1402 /*void UpdateColorModHack()
1403 {
1404         float c;
1405         c = this.clientcolors & 15;
1406         // LordHavoc: only bothering to support white, green, red, yellow, blue
1407              if (!teamplay) this.colormod = '0 0 0';
1408         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1409         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1410         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1411         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1412         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1413         else this.colormod = '1 1 1';
1414 }*/
1415
1416 void respawn(entity this)
1417 {
1418         bool damagedbycontents_prev = this.damagedbycontents;
1419         if(this.alpha >= 0)
1420         {
1421                 if(autocvar_g_respawn_ghosts)
1422                 {
1423                         this.solid = SOLID_NOT;
1424                         this.takedamage = DAMAGE_NO;
1425                         this.damagedbycontents = false;
1426                         set_movetype(this, MOVETYPE_FLY);
1427                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1428                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1429                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1430                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1431                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1432                         if(autocvar_g_respawn_ghosts_time > 0)
1433                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1434                 }
1435                 else
1436                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1437         }
1438
1439         CopyBody(this, 1);
1440         this.damagedbycontents = damagedbycontents_prev;
1441
1442         this.effects |= EF_NODRAW; // prevent another CopyBody
1443         PutClientInServer(this);
1444 }
1445
1446 void play_countdown(entity this, float finished, Sound samp)
1447 {
1448         TC(Sound, samp);
1449         if(IS_REAL_CLIENT(this))
1450                 if(floor(finished - time - frametime) != floor(finished - time))
1451                         if(finished - time < 6)
1452                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1453 }
1454
1455 void player_powerups(entity this)
1456 {
1457         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1458                 this.modelflags |= MF_ROCKET;
1459         else
1460                 this.modelflags &= ~MF_ROCKET;
1461
1462         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1463
1464         if (IS_DEAD(this))
1465         {
1466                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1467                 {
1468                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1469                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1470                         this.items &= ~ITEM_Strength.m_itemid;
1471                         this.items &= ~ITEM_Shield.m_itemid;
1472                         this.items -= (this.items & IT_SUPERWEAPON);
1473                 }
1474         }
1475
1476         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1477                 return;
1478
1479         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1480         int items_prev = this.items;
1481
1482         Fire_ApplyDamage(this);
1483         Fire_ApplyEffect(this);
1484
1485         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1486         {
1487                 if (this.items & ITEM_Strength.m_itemid)
1488                 {
1489                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1490                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1491                         if (time > STAT(STRENGTH_FINISHED, this))
1492                         {
1493                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1494                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1496                         }
1497                 }
1498                 else
1499                 {
1500                         if (time < STAT(STRENGTH_FINISHED, this))
1501                         {
1502                                 this.items = this.items | ITEM_Strength.m_itemid;
1503                                 if(!g_cts)
1504                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1505                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1506                         }
1507                 }
1508                 if (this.items & ITEM_Shield.m_itemid)
1509                 {
1510                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1511                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1512                         if (time > STAT(INVINCIBLE_FINISHED, this))
1513                         {
1514                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1515                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1516                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1517                         }
1518                 }
1519                 else
1520                 {
1521                         if (time < STAT(INVINCIBLE_FINISHED, this))
1522                         {
1523                                 this.items = this.items | ITEM_Shield.m_itemid;
1524                                 if(!g_cts)
1525                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1527                         }
1528                 }
1529                 if (this.items & IT_SUPERWEAPON)
1530                 {
1531                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1532                         {
1533                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1534                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1535                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1536                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1537                         }
1538                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1539                         {
1540                                 // don't let them run out
1541                         }
1542                         else
1543                         {
1544                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1545                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1546                                 {
1547                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1548                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1549                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1550                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1551                                 }
1552                         }
1553                 }
1554                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1555                 {
1556                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1557                         {
1558                                 this.items = this.items | IT_SUPERWEAPON;
1559                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1560                                 {
1561                                         if(!g_cts)
1562                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1563                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1564                                 }
1565                         }
1566                         else
1567                         {
1568                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1569                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1570                         }
1571                 }
1572                 else
1573                 {
1574                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1575                 }
1576         }
1577
1578         if(autocvar_g_nodepthtestplayers)
1579                 this.effects = this.effects | EF_NODEPTHTEST;
1580
1581         if(autocvar_g_fullbrightplayers)
1582                 this.effects = this.effects | EF_FULLBRIGHT;
1583
1584         if (time >= game_starttime)
1585         if (time < this.spawnshieldtime)
1586                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1587
1588         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1589 }
1590
1591 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1592 {
1593         if(current > stable)
1594                 return current;
1595         else if(current > stable - 0.25) // when close enough, "snap"
1596                 return stable;
1597         else
1598                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1599 }
1600
1601 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1602 {
1603         if(current < stable)
1604                 return current;
1605         else if(current < stable + 0.25) // when close enough, "snap"
1606                 return stable;
1607         else
1608                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1609 }
1610
1611 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1612 {
1613         float old = GetResource(this, res);
1614         float current = old;
1615         if(current > rotstable)
1616         {
1617                 if(rotframetime > 0)
1618                 {
1619                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1620                         current = max(rotstable, current - rotlinear * rotframetime);
1621                 }
1622         }
1623         else if(current < regenstable)
1624         {
1625                 if(regenframetime > 0)
1626                 {
1627                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1628                         current = min(regenstable, current + regenlinear * regenframetime);
1629                 }
1630         }
1631
1632         float limit = GetResourceLimit(this, res) * limit_mod;
1633         if(current > limit)
1634                 current = limit;
1635
1636         if (current != old)
1637                 SetResource(this, res, current);
1638 }
1639
1640 void player_regen(entity this)
1641 {
1642         float max_mod, regen_mod, rot_mod, limit_mod;
1643         max_mod = regen_mod = rot_mod = limit_mod = 1;
1644
1645         float regen_health = autocvar_g_balance_health_regen;
1646         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1647         float regen_health_rot = autocvar_g_balance_health_rot;
1648         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1649         float regen_health_stable = autocvar_g_balance_health_regenstable;
1650         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1651         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1652                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1653         max_mod = M_ARGV(1, float);
1654         regen_mod = M_ARGV(2, float);
1655         rot_mod = M_ARGV(3, float);
1656         limit_mod = M_ARGV(4, float);
1657         regen_health = M_ARGV(5, float);
1658         regen_health_linear = M_ARGV(6, float);
1659         regen_health_rot = M_ARGV(7, float);
1660         regen_health_rotlinear = M_ARGV(8, float);
1661         regen_health_stable = M_ARGV(9, float);
1662         regen_health_rotstable = M_ARGV(10, float);
1663
1664         if(!mutator_returnvalue)
1665         if(!STAT(FROZEN, this))
1666         {
1667                 float maxa = autocvar_g_balance_armor_rotstable;
1668                 float mina = autocvar_g_balance_armor_regenstable;
1669
1670                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1671                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1672                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1673
1674                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1675                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1676                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1677         }
1678
1679         // if player rotted to death...  die!
1680         // check this outside above checks, as player may still be able to rot to death
1681         if(GetResource(this, RES_HEALTH) < 1)
1682         {
1683                 if(this.vehicle)
1684                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1685                 if(this.event_damage)
1686                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1687         }
1688
1689         if (!(this.items & IT_UNLIMITED_AMMO))
1690         {
1691                 float maxf = autocvar_g_balance_fuel_rotstable;
1692                 float minf = autocvar_g_balance_fuel_regenstable;
1693
1694                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1695                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1696                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1697         }
1698 }
1699
1700 bool zoomstate_set;
1701 void SetZoomState(entity this, float newzoom)
1702 {
1703         if(newzoom != CS(this).zoomstate)
1704         {
1705                 CS(this).zoomstate = newzoom;
1706                 ClientData_Touch(this);
1707         }
1708         zoomstate_set = true;
1709 }
1710
1711 void GetPressedKeys(entity this)
1712 {
1713         MUTATOR_CALLHOOK(GetPressedKeys, this);
1714         int keys = STAT(PRESSED_KEYS, this);
1715         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1716         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1717         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1718         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1719
1720         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1721         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1722         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1723         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1724         CS(this).pressedkeys = keys; // store for other users
1725
1726         STAT(PRESSED_KEYS, this) = keys;
1727 }
1728
1729 /*
1730 ======================
1731 spectate mode routines
1732 ======================
1733 */
1734
1735 void SpectateCopy(entity this, entity spectatee)
1736 {
1737         TC(Client, this); TC(Client, spectatee);
1738
1739         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1740         PS(this) = PS(spectatee);
1741         this.armortype = spectatee.armortype;
1742         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1743         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1744         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1745         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1746         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1747         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1748         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1749         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1750         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1751         CS(this).impulse = 0;
1752         this.disableclientprediction = 1; // no need to run prediction on a spectator
1753         this.items = spectatee.items;
1754         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1755         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1756         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1757         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1758         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1759         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1760         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1761         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1762         this.punchangle = spectatee.punchangle;
1763         this.view_ofs = spectatee.view_ofs;
1764         this.velocity = spectatee.velocity;
1765         this.dmg_take = spectatee.dmg_take;
1766         this.dmg_save = spectatee.dmg_save;
1767         this.dmg_inflictor = spectatee.dmg_inflictor;
1768         this.v_angle = spectatee.v_angle;
1769         this.angles = spectatee.v_angle;
1770         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1771         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1772         this.viewloc = spectatee.viewloc;
1773         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1774                 this.fixangle = true;
1775         setorigin(this, spectatee.origin);
1776         setsize(this, spectatee.mins, spectatee.maxs);
1777         SetZoomState(this, CS(spectatee).zoomstate);
1778
1779     anticheat_spectatecopy(this, spectatee);
1780         STAT(HUD, this) = STAT(HUD, spectatee);
1781         if(spectatee.vehicle)
1782     {
1783         this.angles = spectatee.v_angle;
1784
1785         //this.fixangle = false;
1786         //this.velocity = spectatee.vehicle.velocity;
1787         this.vehicle_health = spectatee.vehicle_health;
1788         this.vehicle_shield = spectatee.vehicle_shield;
1789         this.vehicle_energy = spectatee.vehicle_energy;
1790         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1791         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1792         this.vehicle_reload1 = spectatee.vehicle_reload1;
1793         this.vehicle_reload2 = spectatee.vehicle_reload2;
1794
1795         //msg_entity = this;
1796
1797        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1798             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1799            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1800            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1801
1802         //WriteByte (MSG_ONE, SVC_SETVIEW);
1803         //    WriteEntity(MSG_ONE, this);
1804         //makevectors(spectatee.v_angle);
1805         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1806     }
1807 }
1808
1809 bool SpectateUpdate(entity this)
1810 {
1811         if(!this.enemy)
1812                 return false;
1813
1814         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1815         {
1816                 SetSpectatee(this, NULL);
1817                 return false;
1818         }
1819
1820         SpectateCopy(this, this.enemy);
1821
1822         return true;
1823 }
1824
1825 bool SpectateSet(entity this)
1826 {
1827         if(!IS_PLAYER(this.enemy))
1828                 return false;
1829
1830         ClientData_Touch(this.enemy);
1831
1832         msg_entity = this;
1833         WriteByte(MSG_ONE, SVC_SETVIEW);
1834         WriteEntity(MSG_ONE, this.enemy);
1835         set_movetype(this, MOVETYPE_NONE);
1836         accuracy_resend(this);
1837
1838         if(!SpectateUpdate(this))
1839                 PutObserverInServer(this);
1840
1841         return true;
1842 }
1843
1844 void SetSpectatee_status(entity this, int spectatee_num)
1845 {
1846         int oldspectatee_status = CS(this).spectatee_status;
1847         CS(this).spectatee_status = spectatee_num;
1848
1849         if (CS(this).spectatee_status != oldspectatee_status)
1850         {
1851                 if (STAT(PRESSED_KEYS, this))
1852                 {
1853                         CS(this).pressedkeys = 0;
1854                         STAT(PRESSED_KEYS, this) = 0;
1855                 }
1856                 ClientData_Touch(this);
1857                 if (g_race || g_cts) race_InitSpectator();
1858         }
1859 }
1860
1861 void SetSpectatee(entity this, entity spectatee)
1862 {
1863         if(IS_BOT_CLIENT(this))
1864                 return; // bots abuse .enemy, this code is useless to them
1865
1866         entity old_spectatee = this.enemy;
1867
1868         this.enemy = spectatee;
1869
1870         // WEAPONTODO
1871         // these are required to fix the spectator bug with arc
1872         if(old_spectatee)
1873         {
1874                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1875                 {
1876                         .entity weaponentity = weaponentities[slot];
1877                         if(old_spectatee.(weaponentity).arc_beam)
1878                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1879                 }
1880         }
1881         if(this.enemy)
1882         {
1883                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1884                 {
1885                         .entity weaponentity = weaponentities[slot];
1886                         if(this.enemy.(weaponentity).arc_beam)
1887                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1888                 }
1889         }
1890
1891         if (this.enemy)
1892                 SetSpectatee_status(this, etof(this.enemy));
1893
1894         // needed to update spectator list
1895         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1896 }
1897
1898 bool Spectate(entity this, entity pl)
1899 {
1900         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1901                 return false;
1902         pl = M_ARGV(1, entity);
1903
1904         SetSpectatee(this, pl);
1905         return SpectateSet(this);
1906 }
1907
1908 bool SpectateNext(entity this)
1909 {
1910         entity ent = find(this.enemy, classname, STR_PLAYER);
1911
1912         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1913                 ent = M_ARGV(1, entity);
1914         else if (!ent)
1915                 ent = find(ent, classname, STR_PLAYER);
1916
1917         if(ent) { SetSpectatee(this, ent); }
1918
1919         return SpectateSet(this);
1920 }
1921
1922 bool SpectatePrev(entity this)
1923 {
1924         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1925         entity ent = findchain(classname, STR_PLAYER);
1926         if (!ent) // no player
1927                 return false;
1928
1929         entity first = ent;
1930         // skip players until current spectated player
1931         if(this.enemy)
1932         while(ent && ent != this.enemy)
1933                 ent = ent.chain;
1934
1935         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1936         {
1937                 case MUT_SPECPREV_FOUND:
1938                         ent = M_ARGV(1, entity);
1939                         break;
1940                 case MUT_SPECPREV_RETURN:
1941                         return true;
1942                 case MUT_SPECPREV_CONTINUE:
1943                 default:
1944                 {
1945                         if(ent.chain)
1946                                 ent = ent.chain;
1947                         else
1948                                 ent = first;
1949                         break;
1950                 }
1951         }
1952
1953         SetSpectatee(this, ent);
1954         return SpectateSet(this);
1955 }
1956
1957 /*
1958 =============
1959 ShowRespawnCountdown()
1960
1961 Update a respawn countdown display.
1962 =============
1963 */
1964 void ShowRespawnCountdown(entity this)
1965 {
1966         float number;
1967         if(!IS_DEAD(this)) // just respawned?
1968                 return;
1969         else
1970         {
1971                 number = ceil(this.respawn_time - time);
1972                 if(number <= 0)
1973                         return;
1974                 if(number <= this.respawn_countdown)
1975                 {
1976                         this.respawn_countdown = number - 1;
1977                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1978                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1979                 }
1980         }
1981 }
1982
1983 .bool team_selected;
1984 bool ShowTeamSelection(entity this)
1985 {
1986         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1987                 return false;
1988         stuffcmd(this, "menu_showteamselect\n");
1989         return true;
1990 }
1991 void Join(entity this)
1992 {
1993         TRANSMUTE(Player, this);
1994
1995         if(!this.team_selected)
1996         if(autocvar_g_campaign || autocvar_g_balance_teams)
1997                 TeamBalance_JoinBestTeam(this);
1998
1999         if(autocvar_g_campaign)
2000                 campaign_bots_may_start = true;
2001
2002         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2003
2004         PutClientInServer(this);
2005
2006         if(IS_PLAYER(this))
2007         if(teamplay && this.team != -1)
2008         {
2009         }
2010         else
2011                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2012         this.team_selected = false;
2013 }
2014
2015 int GetPlayerLimit()
2016 {
2017         if(g_duel)
2018                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2019         int player_limit = autocvar_g_maxplayers;
2020         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2021         player_limit = M_ARGV(0, int);
2022         return player_limit;
2023 }
2024
2025 /**
2026  * Determines whether the player is allowed to join. This depends on cvar
2027  * g_maxplayers, if it isn't used this function always return true, otherwise
2028  * it checks whether the number of currently playing players exceeds g_maxplayers.
2029  * @return int number of free slots for players, 0 if none
2030  */
2031 int nJoinAllowed(entity this, entity ignore)
2032 {
2033         if(!ignore)
2034         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2035         // so report 0 free slots if restricted
2036         {
2037                 if(autocvar_g_forced_team_otherwise == "spectate")
2038                         return 0;
2039                 if(autocvar_g_forced_team_otherwise == "spectator")
2040                         return 0;
2041         }
2042
2043         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2044                 return 0; // forced spectators can never join
2045
2046         // TODO simplify this
2047         int totalClients = 0;
2048         int currentlyPlaying = 0;
2049         FOREACH_CLIENT(true, {
2050                 if(it != ignore)
2051                         ++totalClients;
2052                 if(IS_REAL_CLIENT(it))
2053                 if(IS_PLAYER(it) || it.caplayer)
2054                         ++currentlyPlaying;
2055         });
2056
2057         int player_limit = GetPlayerLimit();
2058
2059         int free_slots = 0;
2060         if (!player_limit)
2061                 free_slots = maxclients - totalClients;
2062         else if(player_limit > 0 && currentlyPlaying < player_limit)
2063                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2064
2065         static float msg_time = 0;
2066         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2067         {
2068                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2069                 msg_time = time + 0.5;
2070         }
2071
2072         return free_slots;
2073 }
2074
2075 /**
2076  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2077  * g_maxplayers_spectator_blocktime seconds
2078  */
2079 void checkSpectatorBlock(entity this)
2080 {
2081         if(IS_SPEC(this) || IS_OBSERVER(this))
2082         if(!this.caplayer)
2083         if(IS_REAL_CLIENT(this))
2084         {
2085                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2086                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2087                         dropclient(this);
2088                 }
2089         }
2090 }
2091
2092 void PrintWelcomeMessage(entity this)
2093 {
2094         if(CS(this).motd_actived_time == 0)
2095         {
2096                 if (autocvar_g_campaign) {
2097                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2098                                 CS(this).motd_actived_time = time;
2099                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2100                         }
2101                 } else {
2102                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2103                                 CS(this).motd_actived_time = time;
2104                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2105                         }
2106                 }
2107         }
2108         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2109         {
2110                 if (autocvar_g_campaign) {
2111                         if (PHYS_INPUT_BUTTON_INFO(this))
2112                                 CS(this).motd_actived_time = time;
2113                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2114                                 CS(this).motd_actived_time = 0;
2115                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2116                         }
2117                 } else {
2118                         if (PHYS_INPUT_BUTTON_INFO(this))
2119                                 CS(this).motd_actived_time = time;
2120                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2121                                 CS(this).motd_actived_time = 0;
2122                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2123                         }
2124                 }
2125         }
2126         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2127         {
2128                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2129                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2130                 else if (CS(this).motd_actived_time == -2)
2131                 {
2132                         // instantly hide MOTD
2133                         CS(this).motd_actived_time = 0;
2134                         if (autocvar_g_campaign)
2135                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2136                         else
2137                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2138                 }
2139                 else if (IS_PLAYER(this) || IS_SPEC(this))
2140                 {
2141                         // FIXME occasionally for some reason MOTD never goes away
2142                         // delay MOTD removal a little bit in the hope it fixes this bug
2143                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2144                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2145                         else //if (CS(this).motd_actived_time < -2)
2146                                 CS(this).motd_actived_time++;
2147                 }
2148         }
2149 }
2150
2151 bool joinAllowed(entity this)
2152 {
2153         if (CS(this).version_mismatch) return false;
2154         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2155         if (!nJoinAllowed(this, this)) return false;
2156         if (teamplay && lockteams) return false;
2157         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2158         if (ShowTeamSelection(this)) return false;
2159         return true;
2160 }
2161
2162 .string shootfromfixedorigin;
2163 .bool dualwielding_prev;
2164 bool PlayerThink(entity this)
2165 {
2166         if (game_stopped || intermission_running) {
2167                 this.modelflags &= ~MF_ROCKET;
2168                 if(intermission_running)
2169                         IntermissionThink(this);
2170                 return false;
2171         }
2172
2173         if (timeout_status == TIMEOUT_ACTIVE) {
2174                 // don't allow the player to turn around while game is paused
2175                 // FIXME turn this into CSQC stuff
2176                 this.v_angle = this.lastV_angle;
2177                 this.angles = this.lastV_angle;
2178                 this.fixangle = true;
2179         }
2180
2181         if (frametime) player_powerups(this);
2182
2183         if (IS_DEAD(this)) {
2184                 if (this.personal && g_race_qualifying) {
2185                         if (time > this.respawn_time) {
2186                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2187                                 respawn(this);
2188                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2189                         }
2190                 } else {
2191                         if (frametime) player_anim(this);
2192
2193                         if (this.respawn_flags & RESPAWN_DENY)
2194                         {
2195                                 STAT(RESPAWN_TIME, this) = 0;
2196                                 return false;
2197                         }
2198
2199                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2200
2201                         switch(this.deadflag)
2202                         {
2203                                 case DEAD_DYING:
2204                                 {
2205                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2206                                                 this.deadflag = DEAD_RESPAWNING;
2207                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2208                                                 this.deadflag = DEAD_DEAD;
2209                                         break;
2210                                 }
2211                                 case DEAD_DEAD:
2212                                 {
2213                                         if (button_pressed)
2214                                                 this.deadflag = DEAD_RESPAWNABLE;
2215                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2216                                                 this.deadflag = DEAD_RESPAWNING;
2217                                         break;
2218                                 }
2219                                 case DEAD_RESPAWNABLE:
2220                                 {
2221                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2222                                                 this.deadflag = DEAD_RESPAWNING;
2223                                         break;
2224                                 }
2225                                 case DEAD_RESPAWNING:
2226                                 {
2227                                         if (time > this.respawn_time)
2228                                         {
2229                                                 this.respawn_time = time + 1; // only retry once a second
2230                                                 this.respawn_time_max = this.respawn_time;
2231                                                 respawn(this);
2232                                         }
2233                                         break;
2234                                 }
2235                         }
2236
2237                         ShowRespawnCountdown(this);
2238
2239                         if (this.respawn_flags & RESPAWN_SILENT)
2240                                 STAT(RESPAWN_TIME, this) = 0;
2241                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2242                         {
2243                                 if (time < this.respawn_time)
2244                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2245                                 else if (this.deadflag != DEAD_RESPAWNING)
2246                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2247                         }
2248                         else
2249                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2250                 }
2251
2252                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2253                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2254                         STAT(RESPAWN_TIME, this) *= -1;
2255
2256                 return false;
2257         }
2258
2259         FixPlayermodel(this);
2260
2261         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2262                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2263                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2264         }
2265
2266         // reset gun alignment when dual wielding status changes
2267         // to ensure guns are always aligned right and left
2268         bool dualwielding = W_DualWielding(this);
2269         if(this.dualwielding_prev != dualwielding)
2270         {
2271                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2272                 this.dualwielding_prev = dualwielding;
2273         }
2274
2275         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2276         //if(frametime)
2277         {
2278                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2279                 {
2280                         .entity weaponentity = weaponentities[slot];
2281                         if(WEP_CVAR(vortex, charge_always))
2282                                 W_Vortex_Charge(this, weaponentity, frametime);
2283                         W_WeaponFrame(this, weaponentity);
2284                 }
2285         }
2286
2287         if (frametime)
2288         {
2289                 // WEAPONTODO: Add a weapon request for this
2290                 // rot vortex charge to the charge limit
2291                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2292                 {
2293                         .entity weaponentity = weaponentities[slot];
2294                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2295                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2296                 }
2297
2298                 player_regen(this);
2299                 player_anim(this);
2300                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2301         }
2302
2303         monsters_setstatus(this);
2304
2305         return true;
2306 }
2307
2308 .bool would_spectate;
2309 void ObserverOrSpectatorThink(entity this)
2310 {
2311         bool is_spec = IS_SPEC(this);
2312         if ( CS(this).impulse )
2313         {
2314                 int r = MinigameImpulse(this, CS(this).impulse);
2315                 if (!is_spec || r)
2316                         CS(this).impulse = 0;
2317
2318                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2319                 {
2320                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2321                         CS(this).impulse = 0;
2322                         return;
2323                 }
2324         }
2325
2326         if (this.flags & FL_JUMPRELEASED) {
2327                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2328                         this.flags &= ~FL_JUMPRELEASED;
2329                         this.flags |= FL_SPAWNING;
2330                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2331                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2332                         this.flags &= ~FL_JUMPRELEASED;
2333                         if(SpectateNext(this)) {
2334                                 TRANSMUTE(Spectator, this);
2335                         } else if (is_spec) {
2336                                 TRANSMUTE(Observer, this);
2337                                 PutClientInServer(this);
2338                         }
2339                         if (is_spec)
2340                                 CS(this).impulse = 0;
2341                 } else if (is_spec) {
2342                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2343                                 this.flags &= ~FL_JUMPRELEASED;
2344                                 if(SpectatePrev(this)) {
2345                                         TRANSMUTE(Spectator, this);
2346                                 } else {
2347                                         TRANSMUTE(Observer, this);
2348                                         PutClientInServer(this);
2349                                 }
2350                                 CS(this).impulse = 0;
2351                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2352                                 this.would_spectate = false;
2353                                 this.flags &= ~FL_JUMPRELEASED;
2354                                 TRANSMUTE(Observer, this);
2355                                 PutClientInServer(this);
2356                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2357                                 PutObserverInServer(this);
2358                                 this.would_spectate = true;
2359                         }
2360                 }
2361                 else {
2362                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2363                         set_movetype(this, preferred_movetype);
2364                 }
2365         } else {
2366                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2367                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2368                         this.flags |= FL_JUMPRELEASED;
2369                         if(this.flags & FL_SPAWNING)
2370                         {
2371                                 this.flags &= ~FL_SPAWNING;
2372                                 if(joinAllowed(this))
2373                                         Join(this);
2374                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2375                                         CS(this).autojoin_checked = -1;
2376                                 return;
2377                         }
2378                 }
2379                 if(is_spec && !SpectateUpdate(this))
2380                         PutObserverInServer(this);
2381         }
2382         if (is_spec)
2383                 this.flags |= FL_CLIENT | FL_NOTARGET;
2384 }
2385
2386 void PlayerUseKey(entity this)
2387 {
2388         if (!IS_PLAYER(this))
2389                 return;
2390
2391         if(this.vehicle)
2392         {
2393                 if(!game_stopped)
2394                 {
2395                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2396                         return;
2397                 }
2398         }
2399         else if(autocvar_g_vehicles_enter)
2400         {
2401                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2402                 {
2403                         entity head, closest_target = NULL;
2404                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2405
2406                         while(head) // find the closest acceptable target to enter
2407                         {
2408                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2409                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2410                                 {
2411                                         if(closest_target)
2412                                         {
2413                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2414                                                 { closest_target = head; }
2415                                         }
2416                                         else { closest_target = head; }
2417                                 }
2418
2419                                 head = head.chain;
2420                         }
2421
2422                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2423                 }
2424         }
2425
2426         // a use key was pressed; call handlers
2427         MUTATOR_CALLHOOK(PlayerUseKey, this);
2428 }
2429
2430
2431 /*
2432 =============
2433 PlayerPreThink
2434
2435 Called every frame for each client before the physics are run
2436 =============
2437 */
2438 .float last_vehiclecheck;
2439 void PlayerPreThink (entity this)
2440 {
2441         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2442         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2443
2444         WarpZone_PlayerPhysics_FixVAngle(this);
2445
2446         if (frametime) {
2447                 // physics frames: update anticheat stuff
2448                 anticheat_prethink(this);
2449         }
2450
2451         if (blockSpectators && frametime) {
2452                 // WORKAROUND: only use dropclient in server frames (frametime set).
2453                 // Never use it in cl_movement frames (frametime zero).
2454                 checkSpectatorBlock(this);
2455         }
2456
2457         zoomstate_set = false;
2458
2459         // Check for nameless players
2460         if (this.netname == "" || this.netname != CS(this).netname_previous)
2461         {
2462                 bool assume_unchanged = (CS(this).netname_previous == "");
2463                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2464                 {
2465                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2466                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2467                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2468                         assume_unchanged = false;
2469                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2470                 }
2471                 if (isInvisibleString(this.netname))
2472                 {
2473                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2474                         sprint(this, "Warning: invisible names are not allowed.\n");
2475                         assume_unchanged = false;
2476                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2477                 }
2478                 if (!assume_unchanged && autocvar_sv_eventlog)
2479                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2480                 strcpy(CS(this).netname_previous, this.netname);
2481         }
2482
2483         // version nagging
2484         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2485         CS(this).version_nagtime = 0;
2486         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2487             // git client
2488         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2489             // git server
2490             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2491         } else {
2492             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2493             if (r < 0) { // old client
2494                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2495             } else if (r > 0) { // old server
2496                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2497             }
2498         }
2499     }
2500
2501         // GOD MODE info
2502         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2503         {
2504                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2505                 this.max_armorvalue = 0;
2506         }
2507
2508         if (frametime && IS_PLAYER(this))
2509         {
2510                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2511                 {
2512                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2513                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2514                         if (this.iceblock)
2515                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2516
2517                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2518                                 Unfreeze(this, false);
2519                 }
2520                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2521                 {
2522                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2523                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2524
2525                         if (GetResource(this, RES_HEALTH) < 1)
2526                         {
2527                                 if (this.vehicle)
2528                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2529                                 if(this.event_damage)
2530                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2531                         }
2532                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2533                                 Unfreeze(this, false);
2534                 }
2535         }
2536
2537         MUTATOR_CALLHOOK(PlayerPreThink, this);
2538
2539         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2540         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2541         {
2542                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2543                 {
2544                         if(!it.owner)
2545                         {
2546                                 if(!it.team || SAME_TEAM(this, it))
2547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2548                                 else if(autocvar_g_vehicles_steal)
2549                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2550                         }
2551                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2552                         {
2553                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2554                         }
2555                 });
2556
2557                 this.last_vehiclecheck = time + 1;
2558         }
2559
2560         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2561         {
2562                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2563                         PlayerUseKey(this);
2564                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2565         }
2566
2567         if (IS_REAL_CLIENT(this))
2568                 PrintWelcomeMessage(this);
2569
2570         if (IS_PLAYER(this)) {
2571                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2572                         error("Client can't be spawned as player on connection!");
2573                 if(!PlayerThink(this))
2574                         return;
2575         }
2576         else if (game_stopped || intermission_running) {
2577                 if(intermission_running)
2578                         IntermissionThink(this);
2579                 return;
2580         }
2581         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2582         {
2583                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2584                 CS(this).autojoin_checked = 1;
2585                 // don't do this in ClientConnect
2586                 // many things can go wrong if a client is spawned as player on connection
2587                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2588                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2589                                 && (!teamplay || autocvar_g_balance_teams)))
2590                 {
2591                         campaign_bots_may_start = true;
2592                         if(joinAllowed(this))
2593                                 Join(this);
2594                         return;
2595                 }
2596         }
2597         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2598                 ObserverOrSpectatorThink(this);
2599         }
2600
2601         // WEAPONTODO: Add weapon request for this
2602         if (!zoomstate_set) {
2603                 bool wep_zoomed = false;
2604                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2605                 {
2606                         .entity weaponentity = weaponentities[slot];
2607                         Weapon thiswep = this.(weaponentity).m_weapon;
2608                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2609                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2610                 }
2611                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2612         }
2613
2614         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2615         {
2616                 CS(this).teamkill_soundtime = 0;
2617
2618                 entity e = CS(this).teamkill_soundsource;
2619                 entity oldpusher = e.pusher;
2620                 e.pusher = this;
2621                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2622                 e.pusher = oldpusher;
2623         }
2624
2625         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2626                 CS(this).taunt_soundtime = 0;
2627                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2628         }
2629
2630         target_voicescript_next(this);
2631
2632         // WEAPONTODO: Move into weaponsystem somehow
2633         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2634         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2635         {
2636                 .entity weaponentity = weaponentities[slot];
2637                 if(this.(weaponentity).m_weapon == WEP_Null)
2638                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2639         }
2640 }
2641
2642 void DrownPlayer(entity this)
2643 {
2644         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2645                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2646         {
2647                 STAT(AIR_FINISHED, this) = 0;
2648                 return;
2649         }
2650
2651         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2652         {
2653                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2654                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2655                 STAT(AIR_FINISHED, this) = 0;
2656         }
2657         else
2658         {
2659                 if (!STAT(AIR_FINISHED, this))
2660                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2661                 if (STAT(AIR_FINISHED, this) < time)
2662                 {       // drown!
2663                         if (this.pain_finished < time)
2664                         {
2665                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2666                                 this.pain_finished = time + 0.5;
2667                         }
2668                 }
2669         }
2670 }
2671
2672 .bool move_qcphysics;
2673
2674 void Player_Physics(entity this)
2675 {
2676         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2677
2678         if(!this.move_qcphysics)
2679                 return;
2680
2681         if(!frametime && !CS(this).pm_frametime)
2682                 return;
2683
2684         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2685
2686         CS(this).pm_frametime = 0;
2687 }
2688
2689 /*
2690 =============
2691 PlayerPostThink
2692
2693 Called every frame for each client after the physics are run
2694 =============
2695 */
2696 void PlayerPostThink (entity this)
2697 {
2698         Player_Physics(this);
2699
2700         if (autocvar_sv_maxidle > 0)
2701         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2702         if (IS_REAL_CLIENT(this))
2703         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2704         {
2705                 int totalClients = 0;
2706                 if(autocvar_sv_maxidle_slots > 0)
2707                 {
2708                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2709                         {
2710                                 ++totalClients;
2711                         });
2712                 }
2713
2714                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2715                 { /* do nothing */ }
2716                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2717                 {
2718                         if (CS(this).idlekick_lasttimeleft)
2719                         {
2720                                 CS(this).idlekick_lasttimeleft = 0;
2721                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2722                         }
2723                 }
2724                 else
2725                 {
2726                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2727                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2728                                 if (!CS(this).idlekick_lasttimeleft)
2729                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2730                         }
2731                         if (timeleft <= 0) {
2732                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2733                                 dropclient(this);
2734                                 return;
2735                         }
2736                         else if (timeleft <= 10) {
2737                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2738                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2739                                 CS(this).idlekick_lasttimeleft = timeleft;
2740                         }
2741                 }
2742         }
2743
2744         CheatFrame(this);
2745
2746         if (game_stopped)
2747         {
2748                 this.solid = SOLID_NOT;
2749                 this.takedamage = DAMAGE_NO;
2750                 set_movetype(this, MOVETYPE_NONE);
2751                 CS(this).teamkill_complain = 0;
2752                 CS(this).teamkill_soundtime = 0;
2753                 CS(this).teamkill_soundsource = NULL;
2754         }
2755
2756         if (IS_PLAYER(this)) {
2757                 if(this.death_time == time && IS_DEAD(this))
2758                 {
2759                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2760                         // once all the damage events of this frame have been processed with normal size
2761                         this.maxs.z = 5;
2762                         setsize(this, this.mins, this.maxs);
2763                 }
2764                 DrownPlayer(this);
2765                 UpdateChatBubble(this);
2766                 if (CS(this).impulse) ImpulseCommands(this);
2767                 if (game_stopped)
2768                 {
2769                         CSQCMODEL_AUTOUPDATE(this);
2770                         return;
2771                 }
2772                 GetPressedKeys(this);
2773         }
2774         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2775         {
2776                 CS(this).pressedkeys = 0;
2777                 STAT(PRESSED_KEYS, this) = 0;
2778         }
2779
2780         if (this.waypointsprite_attachedforcarrier) {
2781                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2782                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2783         }
2784
2785         CSQCMODEL_AUTOUPDATE(this);
2786 }
2787
2788 // hack to copy the button fields from the client entity to the Client State
2789 void PM_UpdateButtons(entity this, entity store)
2790 {
2791         if(this.impulse)
2792                 store.impulse = this.impulse;
2793         this.impulse = 0;
2794
2795         bool typing = this.buttonchat || this.button12;
2796
2797         store.button0 = (typing) ? 0 : this.button0;
2798         //button1?!
2799         store.button2 = (typing) ? 0 : this.button2;
2800         store.button3 = (typing) ? 0 : this.button3;
2801         store.button4 = this.button4;
2802         store.button5 = (typing) ? 0 : this.button5;
2803         store.button6 = this.button6;
2804         store.button7 = this.button7;
2805         store.button8 = this.button8;
2806         store.button9 = this.button9;
2807         store.button10 = this.button10;
2808         store.button11 = this.button11;
2809         store.button12 = this.button12;
2810         store.button13 = this.button13;
2811         store.button14 = this.button14;
2812         store.button15 = this.button15;
2813         store.button16 = this.button16;
2814         store.buttonuse = this.buttonuse;
2815         store.buttonchat = this.buttonchat;
2816
2817         store.cursor_active = this.cursor_active;
2818         store.cursor_screen = this.cursor_screen;
2819         store.cursor_trace_start = this.cursor_trace_start;
2820         store.cursor_trace_endpos = this.cursor_trace_endpos;
2821         store.cursor_trace_ent = this.cursor_trace_ent;
2822
2823         store.ping = this.ping;
2824         store.ping_packetloss = this.ping_packetloss;
2825         store.ping_movementloss = this.ping_movementloss;
2826
2827         store.v_angle = this.v_angle;
2828         store.movement = this.movement;
2829 }
2830
2831 NET_HANDLE(fpsreport, bool)
2832 {
2833         int fps = ReadShort();
2834         PlayerScore_Set(sender, SP_FPS, fps);
2835         return true;
2836 }