qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/mutators_include.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if(readycount)
  44         {
  45                 nags |= 1;
  46                 if(to.ready == 0)
  47                         nags |= 2;
  48         }
  49         if(vote_called)
  50         {
  51                 nags |= 4;
  52                 if(to.vote_selection == 0)
  53                         nags |= 8;
  54         }
  55         if(warmup_stage)
  56                 nags |= 16;
  57
  58         if(sendflags & 64)
  59                 nags |= 64;
  60
  61         if(sendflags & 128)
  62                 nags |= 128;
  63
  64         if(!(nags & 4)) // no vote called? send no string
  65                 nags &= ~(64 | 128);
  66
  67         WriteByte(MSG_ENTITY, nags);
  68
  69         if(nags & 64)
  70         {
  71                 WriteByte(MSG_ENTITY, vote_accept_count);
  72                 WriteByte(MSG_ENTITY, vote_reject_count);
  73                 WriteByte(MSG_ENTITY, vote_needed_overall);
  74                 WriteChar(MSG_ENTITY, to.vote_selection);
  75         }
  76
  77         if(nags & 128)
  78                 WriteString(MSG_ENTITY, vote_called_display);
  79
  80         if(nags & 1)
  81         {
  82                 for(i = 1; i <= maxclients; i += 8)
  83                 {
  84                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  85                                 if(!IS_REAL_CLIENT(e) || e.ready)
  86                                         f |= b;
  87                         WriteByte(MSG_ENTITY, f);
  88                 }
  89         }
  90
  91         return true;
  92 }
  93
  94 void Nagger_Init()
  95 {
  96         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  97 }
  98
  99 void Nagger_VoteChanged()
 100 {
 101         if(nagger)
 102                 nagger.SendFlags |= 128;
 103 }
 104
 105 void Nagger_VoteCountChanged()
 106 {
 107         if(nagger)
 108                 nagger.SendFlags |= 64;
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if(nagger)
 114                 nagger.SendFlags |= 1;
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller))
 121                 return vote_caller.netname;
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         entity tmp_player;
 132
 133         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 134
 135         if(vote_called)
 136         {
 137                 strunzone(vote_called_command);
 138                 strunzone(vote_called_display);
 139                 strunzone(vote_caller_name);
 140         }
 141
 142         vote_called = VOTE_NULL;
 143         vote_caller = world;
 144         vote_caller_name = string_null;
 145         vote_endtime = 0;
 146
 147         vote_called_command = string_null;
 148         vote_called_display = string_null;
 149
 150         vote_parsed_command = string_null;
 151         vote_parsed_display = string_null;
 152
 153         Nagger_VoteChanged();
 154 }
 155
 156 void VoteStop(entity stopper)
 157 {
 158         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 159         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 160
 161         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 162         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 163
 164         VoteReset();
 165 }
 166
 167 void VoteAccept()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 170
 171         if((vote_called == VOTE_MASTER) && vote_caller)
 172                 vote_caller.vote_master = 1;
 173         else
 174                 localcmd(strcat(vote_called_command, "\n"));
 175
 176         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 177
 178         VoteReset();
 179         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 180 }
 181
 182 void VoteReject()
 183 {
 184         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 185         VoteReset();
 186         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 187 }
 188
 189 void VoteTimeout()
 190 {
 191         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 192         VoteReset();
 193         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 194 }
 195
 196 void VoteSpam(float notvoters, float mincount, string result)
 197 {
 198         bprint(strcat(
 199                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 200                 strcat("^2:^1", ftos(vote_reject_count)),
 201                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 202                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 203                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 204
 205         if(autocvar_sv_eventlog)
 206         {
 207                 GameLogEcho(strcat(
 208                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 209                         strcat(":", ftos(vote_reject_count)),
 210                         strcat(":", ftos(vote_abstain_count)),
 211                         strcat(":", ftos(notvoters)),
 212                         strcat(":", ftos(mincount))));
 213         }
 214 }
 215
 216 void VoteCount(float first_count)
 217 {
 218         // declarations
 219         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 220
 221         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 222                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 223                                 || (autocvar_sv_vote_nospectators == 0));
 224
 225         float vote_player_count = 0, notvoters = 0;
 226         float vote_real_player_count = 0, vote_real_accept_count = 0;
 227         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 228         float vote_needed_of_voted, final_needed_votes;
 229         float vote_factor_overall, vote_factor_of_voted;
 230
 231         entity tmp_player;
 232
 233         Nagger_VoteCountChanged();
 234
 235         // add up all the votes from each connected client
 236         FOR_EACH_REALCLIENT(tmp_player)
 237         {
 238                 ++vote_player_count;
 239                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 240
 241                 switch(tmp_player.vote_selection)
 242                 {
 243                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 244                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 245                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 246                         default: break;
 247                 }
 248         }
 249
 250         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 251         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 252         {
 253                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 254                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 255                 VoteReset();
 256                 return;
 257         }
 258
 259         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 260         if(!spectators_allowed && (vote_real_player_count > 0))
 261         {
 262                 vote_accept_count = vote_real_accept_count;
 263                 vote_reject_count = vote_real_reject_count;
 264                 vote_abstain_count = vote_real_abstain_count;
 265                 vote_player_count = vote_real_player_count;
 266         }
 267
 268         // people who have no opinion in any way :D
 269         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 270
 271         // determine the goal for the vote to be passed or rejected normally
 272         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 273         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 274
 275         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 276         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 277         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 278
 279         // are there any players at all on the server? it could be an admin vote
 280         if(vote_player_count == 0 && first_count)
 281         {
 282                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         // since there ARE players, finally calculate the result of the vote
 288         if(vote_accept_count >= vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 291                 VoteAccept();
 292                 return;
 293         }
 294
 295         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 296         {
 297                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 298                 VoteReject();
 299                 return;
 300         }
 301
 302         // there is not enough votes in either direction, now lets just calculate what the voters have said
 303         if(time > vote_endtime)
 304         {
 305                 final_needed_votes = vote_needed_overall;
 306
 307                 if(autocvar_sv_vote_majority_factor_of_voted)
 308                 {
 309                         if(vote_accept_count >= vote_needed_of_voted)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 312                                 VoteAccept();
 313                                 return;
 314                         }
 315
 316                         if(vote_accept_count + vote_reject_count > 0)
 317                         {
 318                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 319                                 VoteReject();
 320                                 return;
 321                         }
 322
 323                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 324                 }
 325
 326                 // it didn't pass or fail, so not enough votes to even make a decision.
 327                 VoteSpam(notvoters, final_needed_votes, "timeout");
 328                 VoteTimeout();
 329         }
 330 }
 331
 332 void VoteThink()
 333 {
 334         if(vote_endtime > 0) // a vote was called
 335         if(time > vote_endtime) // time is up
 336         {
 337                 VoteCount(false);
 338         }
 339
 340         return;
 341 }
 342
 343
 344 // =======================
 345 //  Game logic for warmup
 346 // =======================
 347
 348 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 349 void reset_map(float dorespawn)
 350 {SELFPARAM();
 351
 352         if(time <= game_starttime && round_handler_IsActive())
 353                 round_handler_Reset(game_starttime);
 354
 355         MUTATOR_CALLHOOK(reset_map_global);
 356
 357         for(entity e = world; (e = nextent(e)); )
 358         {
 359                 setself(e);
 360                 if(IS_NOT_A_CLIENT(self))
 361                 {
 362                         if(self.reset)
 363                         {
 364                                 self.reset();
 365                                 continue;
 366                         }
 367
 368                         if(self.team_saved)
 369                                 self.team = self.team_saved;
 370
 371                         if(self.flags & FL_PROJECTILE) // remove any projectiles left
 372                                 remove(self);
 373                 }
 374         }
 375
 376         // Waypoints and assault start come LAST
 377         for(entity e = world; (e = nextent(e)); )
 378         {
 379                 setself(e);
 380                 if(IS_NOT_A_CLIENT(self))
 381                 {
 382                         if(self.reset2)
 383                         {
 384                                 self.reset2();
 385                                 continue;
 386                         }
 387                 }
 388         }
 389
 390         entity e;
 391         FOR_EACH_PLAYER(e)
 392         if(e.frozen)
 393         {
 394                 WITH(entity, self, e, Unfreeze(self));
 395         }
 396
 397         // Moving the player reset code here since the player-reset depends
 398         // on spawnpoint entities which have to be reset first --blub
 399         if(dorespawn)
 400         if(!MUTATOR_CALLHOOK(reset_map_players))
 401         FOR_EACH_CLIENT(e) // reset all players
 402         {
 403                 setself(e);
 404                 /*
 405                 only reset players if a restart countdown is active
 406                 this can either be due to cvar sv_ready_restart_after_countdown having set
 407                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 408                 sv_ready_restart_after_countdown is not used and countdown is still running
 409                 */
 410                 if (restart_mapalreadyrestarted || (time < game_starttime))
 411                 {
 412                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 413                         if (IS_PLAYER(self)) {
 414                                 //PlayerScore_Clear(self);
 415                                 self.killcount = 0;
 416                                 //stop the player from moving so that he stands still once he gets respawned
 417                                 self.velocity = '0 0 0';
 418                                 self.avelocity = '0 0 0';
 419                                 self.movement = '0 0 0';
 420                                 PutClientInServer();
 421                         }
 422                 }
 423         }
 424
 425         setself(this);
 426 }
 427
 428 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 429 void ReadyRestart_think()
 430 {SELFPARAM();
 431         restart_mapalreadyrestarted = 1;
 432         reset_map(true);
 433         Score_ClearAll();
 434         remove(self);
 435
 436         return;
 437 }
 438
 439 // Forces a restart of the game without actually reloading the map // this is a mess...
 440 void ReadyRestart_force()
 441 {
 442         entity tmp_player, restart_timer;
 443
 444         bprint("^1Server is restarting...\n");
 445
 446         VoteReset();
 447
 448         // clear overtime, we have to decrease timelimit to its original value again.
 449         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 450
 451         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 452
 453         readyrestart_happened = 1;
 454         game_starttime = time + RESTART_COUNTDOWN;
 455
 456         // clear player attributes
 457         FOR_EACH_CLIENT(tmp_player)
 458         {
 459                 tmp_player.alivetime = 0;
 460                 tmp_player.killcount = 0;
 461                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 462         }
 463
 464         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 465
 466         // disable the warmup global for the server
 467         warmup_stage = 0; // once the game is restarted the game is in match stage
 468
 469         // reset the .ready status of all players (also spectators)
 470         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 471         readycount = 0;
 472         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 473
 474         // lock teams with lockonrestart
 475         if(autocvar_teamplay_lockonrestart && teamplay)
 476         {
 477                 lockteams = 1;
 478                 bprint("^1The teams are now locked.\n");
 479         }
 480
 481         //initiate the restart-countdown-announcer entity
 482         if(autocvar_sv_ready_restart_after_countdown)
 483         {
 484                 restart_timer = spawn();
 485                 restart_timer.think = ReadyRestart_think;
 486                 restart_timer.nextthink = game_starttime;
 487         }
 488
 489         // after a restart every players number of allowed timeouts gets reset, too
 490         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 491
 492         //reset map immediately if this cvar is not set
 493         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 494
 495         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 496 }
 497
 498 void ReadyRestart()
 499 {
 500         // no assault support yet...
 501         if(g_assault | gameover | intermission_running | race_completing)
 502                 localcmd("restart\n");
 503         else
 504                 localcmd("\nsv_hook_gamerestart\n");
 505
 506         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 507         // Otherwise scores could be manipulated during the countdown.
 508         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 509
 510         ReadyRestart_force();
 511
 512         return;
 513 }
 514
 515 // Count the players who are ready and determine whether or not to restart the match
 516 void ReadyCount()
 517 {
 518         entity tmp_player;
 519         float ready_needed_factor, ready_needed_count;
 520         float t_ready = 0, t_players = 0;
 521
 522         FOR_EACH_REALCLIENT(tmp_player)
 523         {
 524                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 525                 {
 526                         ++t_players;
 527                         if(tmp_player.ready) { ++t_ready; }
 528                 }
 529         }
 530
 531         readycount = t_ready;
 532
 533         Nagger_ReadyCounted();
 534
 535         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 536         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 537
 538         if(readycount >= ready_needed_count)
 539         {
 540                 ReadyRestart();
 541         }
 542
 543         return;
 544 }
 545
 546
 547 // ======================================
 548 //  Supporting functions for VoteCommand
 549 // ======================================
 550
 551 float Votecommand_check_assignment(entity caller, float assignment)
 552 {
 553         float from_server = (!caller);
 554
 555         if((assignment == VC_ASGNMNT_BOTH)
 556                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 557                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 558         {
 559                 return true;
 560         }
 561
 562         return false;
 563 }
 564
 565 string VoteCommand_extractcommand(string input, float startpos, float argc)
 566 {
 567         string output;
 568
 569         if((argc - 1) < startpos)
 570                 output = "";
 571         else
 572                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 573
 574         return output;
 575 }
 576
 577 float VoteCommand_checknasty(string vote_command)
 578 {
 579         if((strstrofs(vote_command, ";", 0) >= 0)
 580                 || (strstrofs(vote_command, "\n", 0) >= 0)
 581                 || (strstrofs(vote_command, "\r", 0) >= 0)
 582                 || (strstrofs(vote_command, "$", 0) >= 0))
 583                 return false;
 584
 585         return true;
 586 }
 587
 588 float VoteCommand_checkinlist(string vote_command, string list)
 589 {
 590         string l = strcat(" ", list, " ");
 591
 592         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 593                 return true;
 594
 595         return false;
 596 }
 597
 598 string ValidateMap(string validated_map, entity caller)
 599 {
 600         validated_map = MapInfo_FixName(validated_map);
 601
 602         if (!validated_map)
 603         {
 604                 print_to(caller, "This map is not available on this server.");
 605                 return string_null;
 606         }
 607
 608         if(!autocvar_sv_vote_override_mostrecent && caller)
 609         {
 610                 if(Map_IsRecent(validated_map))
 611                 {
 612                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 613                         return string_null;
 614                 }
 615         }
 616
 617         if(!MapInfo_CheckMap(validated_map))
 618         {
 619                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 620                 return string_null;
 621         }
 622
 623         return validated_map;
 624 }
 625
 626 float VoteCommand_checkargs(float startpos, float argc)
 627 {
 628         float p, q, check, minargs;
 629         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 630         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 631         string charlist, arg;
 632         float checkmate;
 633
 634         if(cmdrestriction == "")
 635                 return true;
 636
 637         ++startpos; // skip command name
 638
 639         // check minimum arg count
 640
 641         // 0 args: argc == startpos
 642         // 1 args: argc == startpos + 1
 643         // ...
 644
 645         minargs = stof(cmdrestriction);
 646         if(argc - startpos < minargs)
 647                 return false;
 648
 649         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 650
 651         for (;;)
 652         {
 653                 // we know that at any time, startpos <= argc - minargs
 654                 // so this means: argc-minargs >= startpos >= argc, thus
 655                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 656                 // have been seen already
 657
 658                 if(startpos >= argc) // all args checked? GOOD
 659                         break;
 660
 661                 if(p < 0) // no more args? FAIL
 662                 {
 663                         // exception: exactly minargs left, this one included
 664                         if(argc - startpos == minargs)
 665                                 break;
 666
 667                         // otherwise fail
 668                         return false;
 669                 }
 670
 671                 // cut to next semicolon
 672                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 673                 if(q < 0)
 674                         charlist = substring(cmdrestriction, p+1, -1);
 675                 else
 676                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 677
 678                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 679                 // charlist = strreplace("^^", ";", charlist);
 680
 681                 if(charlist != "")
 682                 {
 683                         // verify the arg only contains allowed chars
 684                         arg = argv(startpos);
 685                         checkmate = strlen(arg);
 686                         for(check = 0; check < checkmate; ++check)
 687                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 688                                         return false; // not allowed character
 689                         // all characters are allowed. FINE.
 690                 }
 691
 692                 ++startpos;
 693                 --minargs;
 694                 p = q;
 695         }
 696
 697         return true;
 698 }
 699
 700 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 701 {
 702         string first_command;
 703
 704         first_command = argv(startpos);
 705
 706         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 707                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 708                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 709         );*/
 710
 711         if(
 712                 (autocvar_sv_vote_limit > 0)
 713                 &&
 714                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 715         )
 716                 return false;
 717
 718         if (!VoteCommand_checkinlist(first_command, vote_list))
 719                 return false;
 720
 721         if (!VoteCommand_checkargs(startpos, argc))
 722                 return false;
 723
 724         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 725         {
 726                 case "kick":
 727                 case "kickban": // catch all kick/kickban commands
 728                 {
 729                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 730                         float accepted = VerifyClientEntity(victim, true, false);
 731
 732                         if(accepted > 0)
 733                         {
 734                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 735                                 string command_arguments;
 736
 737                                 if(first_command == "kickban")
 738                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 739                                 else
 740                                         command_arguments = reason;
 741
 742                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 743                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 744                         }
 745                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 746
 747                         break;
 748                 }
 749
 750                 case "map":
 751                 case "chmap":
 752                 case "gotomap": // re-direct all map selection commands to gotomap
 753                 {
 754                         vote_command = ValidateMap(argv(startpos + 1), caller);
 755                         if (!vote_command) { return false; }
 756                         vote_parsed_command = strcat("gotomap ", vote_command);
 757                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 758
 759                         break;
 760                 }
 761
 762                 default:
 763                 {
 764                         vote_parsed_command = vote_command;
 765                         vote_parsed_display = strzone(strcat("^1", vote_command));
 766
 767                         break;
 768                 }
 769         }
 770
 771         return true;
 772 }
 773
 774
 775 // =======================
 776 //  Command Sub-Functions
 777 // =======================
 778
 779 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 780 {
 781         switch(request)
 782         {
 783                 case CMD_REQUEST_COMMAND:
 784                 {
 785                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 786                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 787
 788                         else // everything went okay, continue changing vote
 789                         {
 790                                 print_to(caller, "^1You abstained from your vote.");
 791                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 792                                 msg_entity = caller;
 793                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 794                         }
 795
 796                         return;
 797                 }
 798
 799                 default:
 800                 case CMD_REQUEST_USAGE:
 801                 {
 802                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 803                         print_to(caller, "  No arguments required.");
 804                         return;
 805                 }
 806         }
 807 }
 808
 809 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 810 {
 811         switch(request)
 812         {
 813                 case CMD_REQUEST_COMMAND:
 814                 {
 815                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 816                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 817                                 || (autocvar_sv_vote_nospectators == 0));
 818
 819                         float tmp_playercount = 0;
 820                         entity tmp_player;
 821
 822                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 823
 824                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 825                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 826                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 827                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 828                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 829                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 830                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 831                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 832                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 833
 834                         else // everything went okay, continue with calling the vote
 835                         {
 836                                 vote_caller = caller; // remember who called the vote
 837                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 838                                 vote_called = VOTE_NORMAL;
 839                                 vote_called_command = strzone(vote_parsed_command);
 840                                 vote_called_display = strzone(vote_parsed_display);
 841                                 vote_endtime = time + autocvar_sv_vote_timeout;
 842
 843                                 if(caller)
 844                                 {
 845                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 846                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 847                                         msg_entity = caller;
 848                                 }
 849
 850                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 851                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 852
 853                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 854                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 855                                 Nagger_VoteChanged();
 856                                 VoteCount(true); // needed if you are the only one
 857                         }
 858
 859                         return;
 860                 }
 861
 862                 default:
 863                 case CMD_REQUEST_USAGE:
 864                 {
 865                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 866                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 867                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 868                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 869                         return;
 870                 }
 871         }
 872 }
 873
 874 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 875 {
 876         switch(request)
 877         {
 878                 case CMD_REQUEST_COMMAND:
 879                 {
 880                         if(autocvar_sv_vote_master)
 881                         {
 882                                 switch(strtolower(argv(2)))
 883                                 {
 884                                         case "do":
 885                                         {
 886                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 887
 888                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 889                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 890                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 891
 892                                                 else // everything went okay, proceed with command
 893                                                 {
 894                                                         localcmd(strcat(vote_parsed_command, "\n"));
 895                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 896                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 897                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 898                                                 }
 899
 900                                                 return;
 901                                         }
 902
 903                                         case "login":
 904                                         {
 905                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 906                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 907                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 908
 909                                                 else // everything went okay, proceed with giving this player master privilages
 910                                                 {
 911                                                         caller.vote_master = true;
 912                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 913                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 914                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 915                                                 }
 916
 917                                                 return;
 918                                         }
 919
 920                                         default: // calling a vote for master
 921                                         {
 922                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 923                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 924                                                         || (autocvar_sv_vote_nospectators == 0));
 925
 926                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 927                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 928                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 929                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 930
 931                                                 else // everything went okay, continue with creating vote
 932                                                 {
 933                                                         vote_caller = caller;
 934                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 935                                                         vote_called = VOTE_MASTER;
 936                                                         vote_called_command = strzone("XXX");
 937                                                         vote_called_display = strzone("^3master");
 938                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 939
 940                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 941                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 942
 943                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 944                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 945                                                         Nagger_VoteChanged();
 946                                                         VoteCount(true); // needed if you are the only one
 947                                                 }
 948
 949                                                 return;
 950                                         }
 951                                 }
 952                         }
 953                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 954
 955                         return;
 956                 }
 957
 958                 default:
 959                 case CMD_REQUEST_USAGE:
 960                 {
 961                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 962                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 963                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 964                         return;
 965                 }
 966         }
 967 }
 968
 969 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 970 {
 971         switch(request)
 972         {
 973                 case CMD_REQUEST_COMMAND:
 974                 {
 975                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 976                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 977                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 978
 979                         else // everything went okay, continue changing vote
 980                         {
 981                                 print_to(caller, "^1You rejected the vote.");
 982                                 caller.vote_selection = VOTE_SELECT_REJECT;
 983                                 msg_entity = caller;
 984                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 985                         }
 986
 987                         return;
 988                 }
 989
 990                 default:
 991                 case CMD_REQUEST_USAGE:
 992                 {
 993                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 994                         print_to(caller, "  No arguments required.");
 995                         return;
 996                 }
 997         }
 998 }
 999
1000 void VoteCommand_status(float request, entity caller) // BOTH
1001 {
1002         switch(request)
1003         {
1004                 case CMD_REQUEST_COMMAND:
1005                 {
1006                         if(vote_called)
1007                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1008                         else
1009                                 print_to(caller, "^1No vote called.");
1010
1011                         return;
1012                 }
1013
1014                 default:
1015                 case CMD_REQUEST_USAGE:
1016                 {
1017                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1018                         print_to(caller, "  No arguments required.");
1019                         return;
1020                 }
1021         }
1022 }
1023
1024 void VoteCommand_stop(float request, entity caller) // BOTH
1025 {
1026         switch(request)
1027         {
1028                 case CMD_REQUEST_COMMAND:
1029                 {
1030                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1031                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1032                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1033
1034                         return;
1035                 }
1036
1037                 default:
1038                 case CMD_REQUEST_USAGE:
1039                 {
1040                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1041                         print_to(caller, "  No arguments required.");
1042                         return;
1043                 }
1044         }
1045 }
1046
1047 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1048 {
1049         switch(request)
1050         {
1051                 case CMD_REQUEST_COMMAND:
1052                 {
1053                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1054                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1055
1056                         else // everything went okay, continue changing vote
1057                         {
1058                                 print_to(caller, "^1You accepted the vote.");
1059                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1060                                 msg_entity = caller;
1061                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1062                         }
1063
1064                         return;
1065                 }
1066
1067                 default:
1068                 case CMD_REQUEST_USAGE:
1069                 {
1070                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1071                         print_to(caller, "  No arguments required.");
1072                         return;
1073                 }
1074         }
1075 }
1076
1077 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1078 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1079 void VoteCommand_(float request)
1080 {
1081         switch(request)
1082         {
1083                 case CMD_REQUEST_COMMAND:
1084                 {
1085
1086                         return;
1087                 }
1088
1089                 default:
1090                 case CMD_REQUEST_USAGE:
1091                 {
1092                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1093                         print_to(caller, "  No arguments required.");
1094                         return;
1095                 }
1096         }
1097 }
1098 */
1099
1100
1101 // ================================
1102 //  Macro system for vote commands
1103 // ================================
1104
1105 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1106 #define VOTE_COMMANDS(request,caller,arguments,command) \
1107         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1108         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1109         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1110         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1111         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1112         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1113         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1114         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1115         /* nothing */
1116
1117 void VoteCommand_macro_help(entity caller, float argc)
1118 {
1119         string command_origin = GetCommandPrefix(caller);
1120
1121         if(argc == 2 || argv(2) == "help") // help display listing all commands
1122         {
1123                 print_to(caller, "\nVoting commands:\n");
1124                 #define VOTE_COMMAND(name,function,description,assignment) \
1125                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1126
1127                 VOTE_COMMANDS(0, caller, 0, "");
1128                 #undef VOTE_COMMAND
1129
1130                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1131                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1132                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1133         }
1134         else // usage for individual command
1135         {
1136                 #define VOTE_COMMAND(name,function,description,assignment) \
1137                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1138
1139                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1140                 #undef VOTE_COMMAND
1141         }
1142
1143         return;
1144 }
1145
1146 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1147 {
1148         #define VOTE_COMMAND(name,function,description,assignment) \
1149                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1150
1151         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1152         #undef VOTE_COMMAND
1153
1154         return false;
1155 }
1156
1157
1158 // ======================================
1159 //  Main function handling vote commands
1160 // ======================================
1161
1162 void VoteCommand(float request, entity caller, float argc, string vote_command)
1163 {
1164         // Guide for working with argc arguments by example:
1165         // argc:   1    - 2      - 3     - 4
1166         // argv:   0    - 1      - 2     - 3
1167         // cmd     vote - master - login - password
1168
1169         switch(request)
1170         {
1171                 case CMD_REQUEST_COMMAND:
1172                 {
1173                         if(VoteCommand_macro_command(caller, argc, vote_command))
1174                                 return;
1175                 }
1176
1177                 default:
1178                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1179                 case CMD_REQUEST_USAGE:
1180                 {
1181                         VoteCommand_macro_help(caller, argc);
1182                         return;
1183                 }
1184         }
1185 }