qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/world.qh>
  27
  28 // =============================================
  29 //  Server side voting code, reworked by Samual
  30 //  Last updated: December 27th, 2011
  31 // =============================================
  32
  33 //  Nagger for players to know status of voting
  34 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  35 {
  36         int nags, i, f, b;
  37         entity e;
  38         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  39
  40         // bits:
  41         //   1 = ready
  42         //   2 = player needs to ready up
  43         //   4 = vote
  44         //   8 = player needs to vote
  45         //  16 = warmup
  46         // sendflags:
  47         //  64 = vote counts
  48         // 128 = vote string
  49
  50         nags = 0;
  51         if (readycount)
  52         {
  53                 nags |= BIT(0);
  54                 if (to.ready == 0) nags |= BIT(1);
  55         }
  56         if (vote_called)
  57         {
  58                 nags |= BIT(2);
  59                 if (to.vote_selection == 0) nags |= BIT(3);
  60         }
  61         if (warmup_stage) nags |= BIT(4);
  62
  63         if (sendflags & BIT(6)) nags |= BIT(6);
  64
  65         if (sendflags & BIT(7)) nags |= BIT(7);
  66
  67         if (!(nags & 4))  // no vote called? send no string
  68                 nags &= ~(BIT(6) | BIT(7));
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & 1)
  83         {
  84                 for (i = 1; i <= maxclients; i += 8)
  85                 {
  86                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  87                                 if (!IS_REAL_CLIENT(e) || e.ready)
  88                                         f |= b;
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it))   ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                         { ++vote_reject_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 228                         }
 229                         case VOTE_SELECT_ACCEPT:
 230                         { ++vote_accept_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 232                         }
 233                         case VOTE_SELECT_ABSTAIN:
 234                         { ++vote_abstain_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 236                         }
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool dorespawn)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344                 if (round_handler_IsActive())
 345                         round_handler_Reset(game_starttime);
 346         }
 347
 348         if (shuffleteams_on_reset_map)
 349         {
 350                 shuffleteams();
 351                 shuffleteams_on_reset_map = false;
 352         }
 353
 354         FOREACH_CLIENT(IS_PLAYER(it),
 355         {
 356                 if (STAT(FROZEN, it))
 357                         Unfreeze(it, false);
 358                 player_powerups_remove_all(it);
 359                 entity store = PS(it);
 360                 if (store)
 361                 {
 362                         Inventory_clear(store.inventory);
 363                         Inventory_update(store);
 364                 }
 365         });
 366
 367         MUTATOR_CALLHOOK(reset_map_global);
 368
 369         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 370         {
 371                 if(IS_CLIENT(it))
 372                         continue;
 373                 if (it.reset)
 374                 {
 375                         it.reset(it);
 376                         continue;
 377                 }
 378                 if (it.team_saved) it.team = it.team_saved;
 379                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 380         });
 381
 382         // Waypoints and assault start come LAST
 383         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 384                 if (it.reset2) it.reset2(it);
 385         });
 386
 387         // Moving the player reset code here since the player-reset depends
 388         // on spawnpoint entities which have to be reset first --blub
 389         if (dorespawn)
 390         {
 391                 if (!MUTATOR_CALLHOOK(reset_map_players))
 392                 {
 393                         if (restart_mapalreadyrestarted || (time < game_starttime))
 394                         {
 395                                 FOREACH_CLIENT(IS_PLAYER(it),
 396                                 {
 397                                         /*
 398                                         only reset players if a restart countdown is active
 399                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 400                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 401                                         sv_ready_restart_after_countdown is not used and countdown is still running
 402                                         */
 403                                         // PlayerScore_Clear(it);
 404                                         CS(it).killcount = 0;
 405                                         // stop the player from moving so that he stands still once he gets respawned
 406                                         it.velocity = '0 0 0';
 407                                         it.avelocity = '0 0 0';
 408                                         CS(it).movement = '0 0 0';
 409                                         PutClientInServer(it);
 410                                 });
 411                         }
 412                 }
 413         }
 414 }
 415
 416 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 417 void ReadyRestart_think(entity this)
 418 {
 419         restart_mapalreadyrestarted = true;
 420         reset_map(true);
 421         Score_ClearAll();
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force()
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430
 431         bprint("^1Server is restarting...\n");
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 439
 440         readyrestart_happened = true;
 441         game_starttime = time + RESTART_COUNTDOWN;
 442
 443         // clear player attributes
 444         FOREACH_CLIENT(true, {
 445                 accuracy_reset(it);
 446                 if (!IS_PLAYER(it))
 447                         continue;
 448                 it.alivetime = 0;
 449                 CS(it).killcount = 0;
 450                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 451                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 452         });
 453
 454         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 455
 456         // disable the warmup global for the server
 457         if(warmup_stage)
 458                 localcmd("\nsv_hook_warmupend\n");
 459         warmup_stage = 0;                // once the game is restarted the game is in match stage
 460
 461         // reset the .ready status of all players (also spectators)
 462         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 463         readycount = 0;
 464         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 465
 466         // lock teams with lockonrestart
 467         if (autocvar_teamplay_lockonrestart && teamplay)
 468         {
 469                 lockteams = true;
 470                 bprint("^1The teams are now locked.\n");
 471         }
 472
 473         // initiate the restart-countdown-announcer entity
 474         if (sv_ready_restart_after_countdown)
 475         {
 476                 entity restart_timer = new_pure(restart_timer);
 477                 setthink(restart_timer, ReadyRestart_think);
 478                 restart_timer.nextthink = game_starttime;
 479         }
 480
 481         // after a restart every players number of allowed timeouts gets reset, too
 482         if (autocvar_sv_timeout)
 483         {
 484                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 485         }
 486
 487         if (!sv_ready_restart_after_countdown) reset_map(true);
 488         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 489 }
 490
 491 void ReadyRestart()
 492 {
 493         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 494         else localcmd("\nsv_hook_readyrestart\n");
 495
 496         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 497         // Otherwise scores could be manipulated during the countdown.
 498         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 499         ReadyRestart_force();
 500 }
 501
 502 // Count the players who are ready and determine whether or not to restart the match
 503 void ReadyCount()
 504 {
 505         float ready_needed_factor, ready_needed_count;
 506         float t_ready = 0, t_players = 0;
 507
 508         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 509                 ++t_players;
 510                 if (it.ready) ++t_ready;
 511         });
 512
 513         readycount = t_ready;
 514
 515         Nagger_ReadyCounted();
 516
 517         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 518         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 519
 520         if (readycount >= ready_needed_count) ReadyRestart();
 521 }
 522
 523
 524 // ======================================
 525 //  Supporting functions for VoteCommand
 526 // ======================================
 527
 528 float Votecommand_check_assignment(entity caller, float assignment)
 529 {
 530         float from_server = (!caller);
 531
 532         if ((assignment == VC_ASGNMNT_BOTH)
 533             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 534             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 535
 536         return false;
 537 }
 538
 539 string VoteCommand_extractcommand(string input, float startpos, int argc)
 540 {
 541         string output;
 542
 543         if ((argc - 1) < startpos) output = "";
 544         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 545
 546         return output;
 547 }
 548
 549 float VoteCommand_checknasty(string vote_command)
 550 {
 551         if ((strstrofs(vote_command, ";", 0) >= 0)
 552             || (strstrofs(vote_command, "\n", 0) >= 0)
 553             || (strstrofs(vote_command, "\r", 0) >= 0)
 554             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 555
 556         return true;
 557 }
 558
 559 // NOTE: requires input to be surrounded by spaces
 560 string VoteCommand_checkreplacements(string input)
 561 {
 562         string output = input;
 563         // allow gotomap replacements
 564         output = strreplace(" map ", " gotomap ", output);
 565         output = strreplace(" chmap ", " gotomap ", output);
 566         return output;
 567 }
 568
 569 float VoteCommand_checkinlist(string vote_command, string list)
 570 {
 571         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 572
 573         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 574
 575         return false;
 576 }
 577
 578 string ValidateMap(string validated_map, entity caller)
 579 {
 580         validated_map = MapInfo_FixName(validated_map);
 581
 582         if (!validated_map)
 583         {
 584                 print_to(caller, "This map is not available on this server.");
 585                 return string_null;
 586         }
 587
 588         if (!autocvar_sv_vote_override_mostrecent && caller)
 589         {
 590                 if (Map_IsRecent(validated_map))
 591                 {
 592                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 593                         return string_null;
 594                 }
 595         }
 596
 597         if (!MapInfo_CheckMap(validated_map))
 598         {
 599                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 600                 return string_null;
 601         }
 602
 603         return validated_map;
 604 }
 605
 606 float VoteCommand_checkargs(float startpos, int argc)
 607 {
 608         float p, q, check, minargs;
 609         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 610         string cmdrestriction = "";  // No we don't.
 611         string charlist, arg;
 612         float checkmate;
 613
 614         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 615                 cmdrestriction = cvar_string(cvarname);
 616         else
 617                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 618
 619         if (cmdrestriction == "") return true;
 620
 621         ++startpos;  // skip command name
 622
 623         // check minimum arg count
 624
 625         // 0 args: argc == startpos
 626         // 1 args: argc == startpos + 1
 627         // ...
 628
 629         minargs = stof(cmdrestriction);
 630         if (argc - startpos < minargs) return false;
 631
 632         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 633
 634         for ( ; ; )
 635         {
 636                 // we know that at any time, startpos <= argc - minargs
 637                 // so this means: argc-minargs >= startpos >= argc, thus
 638                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 639                 // have been seen already
 640
 641                 if (startpos >= argc) // all args checked? GOOD
 642                         break;
 643
 644                 if (p < 0)            // no more args? FAIL
 645                 {
 646                         // exception: exactly minargs left, this one included
 647                         if (argc - startpos == minargs) break;
 648
 649                         // otherwise fail
 650                         return false;
 651                 }
 652
 653                 // cut to next semicolon
 654                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 655                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 656                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 657
 658                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 659                 // charlist = strreplace("^^", ";", charlist);
 660
 661                 if (charlist != "")
 662                 {
 663                         // verify the arg only contains allowed chars
 664                         arg = argv(startpos);
 665                         checkmate = strlen(arg);
 666                         for (check = 0; check < checkmate; ++check)
 667                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 668                         // not allowed character
 669                         // all characters are allowed. FINE.
 670                 }
 671
 672                 ++startpos;
 673                 --minargs;
 674                 p = q;
 675         }
 676
 677         return true;
 678 }
 679
 680 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 681 {
 682         string first_command = argv(startpos);
 683         int missing_chars = argv_start_index(startpos);
 684
 685         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 686                 return 0;
 687
 688         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 689
 690         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 691
 692         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 693         {
 694                 case MUT_VOTEPARSE_CONTINUE: { break; }
 695                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 696                 case MUT_VOTEPARSE_INVALID: { return -1; }
 697                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 698         }
 699
 700         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 701         {
 702                 case "kick":
 703                 case "kickban":    // catch all kick/kickban commands
 704                 {
 705                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 706                         float accepted = VerifyClientEntity(victim, true, false);
 707
 708                         if (accepted > 0)
 709                         {
 710                                 string reason = "No reason provided";
 711                                 if(argc > next_token)
 712                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 713
 714                                 string command_arguments = reason;
 715                                 if (first_command == "kickban")
 716                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 717
 718                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 719                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 720                         }
 721                         else
 722                         {
 723                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 724                                 return 0;
 725                         }
 726
 727                         break;
 728                 }
 729
 730                 case "map":
 731                 case "chmap":
 732                 case "gotomap":  // re-direct all map selection commands to gotomap
 733                 {
 734                         vote_command = ValidateMap(argv(startpos + 1), caller);
 735                         if (!vote_command)  return -1;
 736                         vote_parsed_command = strcat("gotomap ", vote_command);
 737                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 738
 739                         break;
 740                 }
 741
 742                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 743                 // maybe fallback instead of aborting if map name is invalid?
 744                 case "nextmap":
 745                 {
 746                         vote_command = ValidateMap(argv(startpos + 1), caller);
 747                         if (!vote_command)  return -1;
 748                         vote_parsed_command = strcat("nextmap ", vote_command);
 749                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 750
 751                         break;
 752                 }
 753
 754                 case "timelimit": // include restrictions on the maximum votable time limit
 755                 {
 756                         float timelimit_vote = stof(argv(startpos + 1));
 757                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 758                         {
 759                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 760                                 return -1;
 761                         }
 762                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 763                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 764                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 765
 766                         break;
 767                 }
 768
 769                 case "restart":
 770                 {
 771                         // add a delay so that vote result can be seen and announcer can be heard
 772                         // if the vote is accepted
 773                         vote_parsed_command = strcat("defer 1 ", vote_command);
 774                         vote_parsed_display = strzone(strcat("^1", vote_command));
 775
 776                         break;
 777                 }
 778
 779                 default:
 780                 {
 781                         vote_parsed_command = vote_command;
 782                         vote_parsed_display = strzone(strcat("^1", vote_command));
 783
 784                         break;
 785                 }
 786         }
 787
 788         return 1;
 789 }
 790
 791
 792 // =======================
 793 //  Command Sub-Functions
 794 // =======================
 795
 796 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 797 {
 798         switch (request)
 799         {
 800                 case CMD_REQUEST_COMMAND:
 801                 {
 802                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 803                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 804                         {
 805                                 print_to(caller, "^1You have already voted.");
 806                         }
 807
 808                         else  // everything went okay, continue changing vote
 809                         {
 810                                 print_to(caller, "^1You abstained from your vote.");
 811                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 812                                 msg_entity = caller;
 813                                 if (!autocvar_sv_vote_singlecount)
 814                                         VoteCount(false);
 815                         }
 816
 817                         return;
 818                 }
 819
 820                 default:
 821                 case CMD_REQUEST_USAGE:
 822                 {
 823                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 824                         print_to(caller, "  No arguments required.");
 825                         return;
 826                 }
 827         }
 828 }
 829
 830 void print_available_commands_to(entity caller)
 831 {
 832         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 833 }
 834
 835 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 836 {
 837         switch (request)
 838         {
 839                 case CMD_REQUEST_COMMAND:
 840                 {
 841                         float tmp_playercount = 0;
 842                         int parse_error;
 843
 844                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 845
 846                         if (!autocvar_sv_vote_call && caller)
 847                         {
 848                                 print_to(caller, "^1Vote calling is not allowed.");
 849                         }
 850                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 851                         {
 852                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 853                         }
 854                         else if (vote_called)
 855                         {
 856                                 print_to(caller, "^1There is already a vote called.");
 857                         }
 858                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 859                         {
 860                                 print_to(caller, "^1Only players can call a vote.");
 861                         }
 862                         else if (caller && !IS_CLIENT(caller))
 863                         {
 864                                 print_to(caller, "^1Only connected clients can vote.");
 865                         }
 866                         else if (timeout_status && vote_command != "timein")
 867                         {
 868                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 869                         }
 870                         else if (caller && (time < caller.vote_waittime))
 871                         {
 872                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 873                         }
 874                         else if (!VoteCommand_checknasty(vote_command))
 875                         {
 876                                 print_to(caller, "^1Syntax error in command.");
 877                         }
 878                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 879                         {
 880                                 if(parse_error == 0)
 881                                 {
 882                                         if (vote_called_command == "")
 883                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 884                                         else
 885                                                 print_to(caller, "^1This command is not acceptable or not available.");
 886                                 }
 887                         }
 888                         else  // everything went okay, continue with calling the vote
 889                         {
 890                                 vote_caller = caller;  // remember who called the vote
 891                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 892                                 vote_called = VOTE_NORMAL;
 893                                 vote_called_command = strzone(vote_parsed_command);
 894                                 vote_called_display = strzone(vote_parsed_display);
 895                                 vote_endtime = time + autocvar_sv_vote_timeout;
 896
 897                                 if (caller)
 898                                 {
 899                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 900                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 901                                         msg_entity = caller;
 902                                 }
 903
 904                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 905
 906                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 907                                 if (autocvar_sv_eventlog)
 908                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 909                                 Nagger_VoteChanged();
 910                                 VoteCount(true);  // needed if you are the only one
 911
 912                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 913                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 914                         }
 915
 916                         return;
 917                 }
 918
 919                 default:
 920                 case CMD_REQUEST_USAGE:
 921                 {
 922                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 923                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 924                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 925                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 926                         print_available_commands_to(caller);
 927                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 928                         return;
 929                 }
 930         }
 931 }
 932
 933 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 934 {
 935         switch (request)
 936         {
 937                 case CMD_REQUEST_COMMAND:
 938                 {
 939                         if (autocvar_sv_vote_master)
 940                         {
 941                                 switch (strtolower(argv(2)))
 942                                 {
 943                                         case "do":
 944                                         {
 945                                                 int parse_error;
 946                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 947
 948                                                 if (!caller.vote_master)
 949                                                         print_to(caller, "^1You do not have vote master privileges.");
 950                                                 else if (!VoteCommand_checknasty(vote_command))
 951                                                 {
 952                                                         print_to(caller, "^1Syntax error in command.");
 953                                                 }
 954                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 955                                                 {
 956                                                         if(parse_error == 0)
 957                                                         {
 958                                                                 if (vote_called_command == "")
 959                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 960                                                                 else
 961                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 962                                                         }
 963                                                 }
 964                                                 else  // everything went okay, proceed with command
 965                                                 {
 966                                                         localcmd(strcat(vote_parsed_command, "\n"));
 967                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 968                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 969                                                         if (autocvar_sv_eventlog)
 970                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 971                                                 }
 972
 973                                                 return;
 974                                         }
 975
 976                                         case "login":
 977                                         {
 978                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 979                                                 else if (caller.vote_master)
 980                                                 {
 981                                                         print_to(caller, "^1You are already logged in as vote master.");
 982                                                 }
 983                                                 else if (autocvar_sv_vote_master_password != argv(3))
 984                                                 {
 985                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 986                                                 }
 987                                                 else  // everything went okay, proceed with giving this player master privilages
 988                                                 {
 989                                                         caller.vote_master = true;
 990                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 991                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 992                                                         if (autocvar_sv_eventlog)
 993                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 994                                                 }
 995
 996                                                 return;
 997                                         }
 998
 999                                         default:  // calling a vote for master
1000                                         {
1001                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1002                                                 else if (vote_called)
1003                                                 {
1004                                                         print_to(caller, "^1There is already a vote called.");
1005                                                 }
1006                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1007                                                 {
1008                                                         print_to(caller, "^1Only players can call a vote.");
1009                                                 }
1010                                                 else if (timeout_status)
1011                                                 {
1012                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1013                                                 }
1014                                                 else  // everything went okay, continue with creating vote
1015                                                 {
1016                                                         vote_caller = caller;
1017                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1018                                                         vote_called = VOTE_MASTER;
1019                                                         vote_called_command = strzone("XXX");
1020                                                         vote_called_display = strzone("^3master");
1021                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1022
1023                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1024                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1025
1026                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1027                                                         if (autocvar_sv_eventlog)
1028                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1029                                                         Nagger_VoteChanged();
1030                                                         VoteCount(true);  // needed if you are the only one
1031                                                 }
1032
1033                                                 return;
1034                                         }
1035                                 }
1036                         }
1037                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1038
1039                         return;
1040                 }
1041
1042                 default:
1043                 case CMD_REQUEST_USAGE:
1044                 {
1045                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1046                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1047                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1048                         return;
1049                 }
1050         }
1051 }
1052
1053 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1054 {
1055         switch (request)
1056         {
1057                 case CMD_REQUEST_COMMAND:
1058                 {
1059                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1060                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1061                         {
1062                                 print_to(caller, "^1You have already voted.");
1063                         }
1064                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1065                         {
1066                                 VoteStop(caller);
1067                         }
1068
1069                         else  // everything went okay, continue changing vote
1070                         {
1071                                 print_to(caller, "^1You rejected the vote.");
1072                                 caller.vote_selection = VOTE_SELECT_REJECT;
1073                                 msg_entity = caller;
1074                                 if (!autocvar_sv_vote_singlecount)
1075                                         VoteCount(false);
1076                         }
1077
1078                         return;
1079                 }
1080
1081                 default:
1082                 case CMD_REQUEST_USAGE:
1083                 {
1084                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1085                         print_to(caller, "  No arguments required.");
1086                         return;
1087                 }
1088         }
1089 }
1090
1091 void VoteCommand_status(int request, entity caller)  // BOTH
1092 {
1093         switch (request)
1094         {
1095                 case CMD_REQUEST_COMMAND:
1096                 {
1097                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1098                         else print_to(caller, "^1No vote called.");
1099
1100                         return;
1101                 }
1102
1103                 default:
1104                 case CMD_REQUEST_USAGE:
1105                 {
1106                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1107                         print_to(caller, "  No arguments required.");
1108                         return;
1109                 }
1110         }
1111 }
1112
1113 void VoteCommand_stop(int request, entity caller)  // BOTH
1114 {
1115         switch (request)
1116         {
1117                 case CMD_REQUEST_COMMAND:
1118                 {
1119                         if (!vote_called)   print_to(caller, "^1No vote called.");
1120                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1121                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1122                         return;
1123                 }
1124
1125                 default:
1126                 case CMD_REQUEST_USAGE:
1127                 {
1128                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1129                         print_to(caller, "  No arguments required.");
1130                         return;
1131                 }
1132         }
1133 }
1134
1135 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1136 {
1137         switch (request)
1138         {
1139                 case CMD_REQUEST_COMMAND:
1140                 {
1141                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1142                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1143                         {
1144                                 print_to(caller, "^1You have already voted.");
1145                         }
1146                         else  // everything went okay, continue changing vote
1147                         {
1148                                 print_to(caller, "^1You accepted the vote.");
1149                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1150                                 msg_entity = caller;
1151                                 if (!autocvar_sv_vote_singlecount)
1152                                         VoteCount(false);
1153                         }
1154
1155                         return;
1156                 }
1157
1158                 default:
1159                 case CMD_REQUEST_USAGE:
1160                 {
1161                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1162                         print_to(caller, "  No arguments required.");
1163                         return;
1164                 }
1165         }
1166 }
1167
1168 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1169 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1170 void VoteCommand_(int request)
1171 {
1172     switch(request)
1173     {
1174         case CMD_REQUEST_COMMAND:
1175         {
1176
1177             return;
1178         }
1179
1180         default:
1181         case CMD_REQUEST_USAGE:
1182         {
1183             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1184             print_to(caller, "  No arguments required.");
1185             return;
1186         }
1187     }
1188 }
1189 */
1190
1191
1192 // ================================
1193 //  Macro system for vote commands
1194 // ================================
1195
1196 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1197 #define VOTE_COMMANDS(request, caller, arguments, command) \
1198         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1199         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1200         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1201         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1202         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1203         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1204         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1205         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1206         /* nothing */
1207
1208 void VoteCommand_macro_help(entity caller, int argc)
1209 {
1210         string command_origin = GetCommandPrefix(caller);
1211
1212         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1213         {
1214                 print_to(caller, "\nVoting commands:\n");
1215                 #define VOTE_COMMAND(name, function, description, assignment) \
1216                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1217
1218                 VOTE_COMMANDS(0, caller, 0, "");
1219                 #undef VOTE_COMMAND
1220
1221                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1222                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1223                 print_available_commands_to(caller);
1224         }
1225         else  // usage for individual command
1226         {
1227                 #define VOTE_COMMAND(name, function, description, assignment) \
1228                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1229
1230                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1231                 #undef VOTE_COMMAND
1232
1233                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1234                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1235                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1236                 else if (argv(2) != "")
1237                         print_to(caller, "No documentation exists for this vote");
1238         }
1239 }
1240
1241 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1242 {
1243         #define VOTE_COMMAND(name, function, description, assignment) \
1244                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1245
1246         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1247         #undef VOTE_COMMAND
1248
1249         return false;
1250 }
1251
1252
1253 // ======================================
1254 //  Main function handling vote commands
1255 // ======================================
1256
1257 void VoteCommand(int request, entity caller, int argc, string vote_command)
1258 {
1259         // Guide for working with argc arguments by example:
1260         // argc:   1    - 2      - 3     - 4
1261         // argv:   0    - 1      - 2     - 3
1262         // cmd     vote - master - login - password
1263
1264         switch (request)
1265         {
1266                 case CMD_REQUEST_COMMAND:
1267                 {
1268                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1269                 }
1270
1271                 default:
1272                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1273                 case CMD_REQUEST_USAGE:
1274                 {
1275                         VoteCommand_macro_help(caller, argc);
1276                         return;
1277                 }
1278         }
1279 }