qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn, bool is_fake_round_start)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346
 347                 if (!is_fake_round_start)
 348                 {
 349                         Score_ClearAll();
 350                         PlayerStats_GameReport_Reset_All();
 351                 }
 352
 353                 if (round_handler_IsActive())
 354                         round_handler_Reset(game_starttime);
 355         }
 356
 357         if (shuffleteams_on_reset_map)
 358         {
 359                 shuffleteams();
 360                 shuffleteams_on_reset_map = false;
 361         }
 362
 363         FOREACH_CLIENT(true, {
 364                 if (time <= game_starttime)
 365                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 366                 if (!IS_PLAYER(it))
 367                         continue;
 368                 if (STAT(FROZEN, it))
 369                         Unfreeze(it, false);
 370                 player_powerups_remove_all(it);
 371                 entity store = PS(it);
 372                 if (store)
 373                 {
 374                         Inventory_clear(store.inventory);
 375                         Inventory_update(store);
 376                 }
 377         });
 378
 379         MUTATOR_CALLHOOK(reset_map_global);
 380
 381         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 382         {
 383                 if(IS_CLIENT(it))
 384                         continue;
 385                 if (it.reset)
 386                 {
 387                         it.reset(it);
 388                         continue;
 389                 }
 390                 if (it.team_saved) it.team = it.team_saved;
 391                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 392         });
 393
 394         // Waypoints and assault start come LAST
 395         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 396                 if (it.reset2) it.reset2(it);
 397         });
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if (dorespawn)
 402         {
 403                 if (!MUTATOR_CALLHOOK(reset_map_players))
 404                 {
 405                         FOREACH_CLIENT(IS_PLAYER(it),
 406                         {
 407                                 // PlayerScore_Clear(it);
 408                                 CS(it).killcount = 0;
 409                                 // stop the player from moving so that he stands still once he gets respawned
 410                                 it.velocity = '0 0 0';
 411                                 it.avelocity = '0 0 0';
 412                                 CS(it).movement = '0 0 0';
 413                                 PutClientInServer(it);
 414                         });
 415                 }
 416         }
 417 }
 418
 419 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 420 void ReadyRestart_think(entity this)
 421 {
 422         reset_map(true, false);
 423         delete(this);
 424 }
 425
 426 // Forces a restart of the game without actually reloading the map // this is a mess...
 427 void ReadyRestart_force(bool is_fake_round_start)
 428 {
 429         if (time <= game_starttime && game_stopped)
 430                 return;
 431         if (!is_fake_round_start)
 432                 bprint("^1Match is restarting...\n");
 433
 434         VoteReset();
 435
 436         // clear overtime, we have to decrease timelimit to its original value again.
 437         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 438                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 439         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 440
 441         if(warmup_stage)
 442                 game_starttime = time; // Warmup: No countdown in warmup
 443         else if (autocvar_g_campaign)
 444                 game_starttime = time + 3;
 445         else
 446                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 447
 448         // clear player attributes
 449         FOREACH_CLIENT(IS_PLAYER(it), {
 450                 it.alivetime = 0;
 451                 CS(it).killcount = 0;
 452         });
 453
 454         // if we're ending the warmup stage call the corresponding hook
 455         if(!is_fake_round_start && !warmup_stage)
 456                 localcmd("\nsv_hook_warmupend\n");
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465                 lockteams = !warmup_stage;
 466
 467         // initiate the restart-countdown-announcer entity
 468         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 469         {
 470                 entity restart_timer = new_pure(restart_timer);
 471                 setthink(restart_timer, ReadyRestart_think);
 472                 restart_timer.nextthink = game_starttime;
 473         }
 474
 475         // after a restart every players number of allowed timeouts gets reset, too
 476         if (autocvar_sv_timeout)
 477         {
 478                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 479         }
 480
 481         if (!sv_ready_restart_after_countdown || warmup_stage)
 482                 reset_map(true, is_fake_round_start);
 483
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart(bool forceWarmupEnd)
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 490         {
 491                 // NOTE: ReadyRestart support is mandatory in campaign
 492                 if (autocvar_g_campaign)
 493                         error("ReadyRestart must be supported in campaign mode!");
 494                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 495         }
 496         else localcmd("\nsv_hook_readyrestart\n");
 497
 498         if(forceWarmupEnd || autocvar_g_campaign)
 499                 warmup_stage = 0; // forcefully end warmup and go to match stage
 500         else
 501                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 502
 503         ReadyRestart_force(false);
 504 }
 505
 506 // Count the players who are ready and determine whether or not to restart the match
 507 void ReadyCount()
 508 {
 509         // cannot reset the game while a timeout is active or pending
 510         if (timeout_status) return;
 511
 512         float ready_needed_factor, ready_needed_count;
 513         float t_players = 0;
 514         readycount = 0;
 515
 516         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 517                 ++t_players;
 518                 if (it.ready) ++readycount;
 519         });
 520
 521         Nagger_ReadyCounted();
 522
 523         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 524         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 525
 526         if (readycount >= ready_needed_count) ReadyRestart(true);
 527 }
 528
 529
 530 // ======================================
 531 //  Supporting functions for VoteCommand
 532 // ======================================
 533
 534 float Votecommand_check_assignment(entity caller, float assignment)
 535 {
 536         float from_server = (!caller);
 537
 538         if ((assignment == VC_ASGNMNT_BOTH)
 539             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 540             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 541
 542         return false;
 543 }
 544
 545 string VoteCommand_extractcommand(string input, float startpos, int argc)
 546 {
 547         string output;
 548
 549         if ((argc - 1) < startpos) output = "";
 550         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 551
 552         return output;
 553 }
 554
 555 float VoteCommand_checknasty(string vote_command)
 556 {
 557         if ((strstrofs(vote_command, ";", 0) >= 0)
 558             || (strstrofs(vote_command, "\n", 0) >= 0)
 559             || (strstrofs(vote_command, "\r", 0) >= 0)
 560             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 561
 562         return true;
 563 }
 564
 565 // NOTE: requires input to be surrounded by spaces
 566 string VoteCommand_checkreplacements(string input)
 567 {
 568         string output = input;
 569         // allow gotomap replacements
 570         output = strreplace(" map ", " gotomap ", output);
 571         output = strreplace(" chmap ", " gotomap ", output);
 572         return output;
 573 }
 574
 575 float VoteCommand_checkinlist(string vote_command, string list)
 576 {
 577         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 578
 579         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 580
 581         return false;
 582 }
 583
 584 string ValidateMap(string validated_map, entity caller)
 585 {
 586         validated_map = MapInfo_FixName(validated_map);
 587
 588         if (!validated_map)
 589         {
 590                 print_to(caller, "This map is not available on this server.");
 591                 return string_null;
 592         }
 593
 594         if (!autocvar_sv_vote_override_mostrecent && caller)
 595         {
 596                 if (Map_IsRecent(validated_map))
 597                 {
 598                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 599                         return string_null;
 600                 }
 601         }
 602
 603         if (!MapInfo_CheckMap(validated_map))
 604         {
 605                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 606                 return string_null;
 607         }
 608
 609         return validated_map;
 610 }
 611
 612 float VoteCommand_checkargs(float startpos, int argc)
 613 {
 614         float p, q, check, minargs;
 615         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 616         string cmdrestriction = "";  // No we don't.
 617         string charlist, arg;
 618         float checkmate;
 619
 620         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 621                 cmdrestriction = cvar_string(cvarname);
 622         else
 623                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 624
 625         if (cmdrestriction == "") return true;
 626
 627         ++startpos;  // skip command name
 628
 629         // check minimum arg count
 630
 631         // 0 args: argc == startpos
 632         // 1 args: argc == startpos + 1
 633         // ...
 634
 635         minargs = stof(cmdrestriction);
 636         if (argc - startpos < minargs) return false;
 637
 638         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 639
 640         for ( ; ; )
 641         {
 642                 // we know that at any time, startpos <= argc - minargs
 643                 // so this means: argc-minargs >= startpos >= argc, thus
 644                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 645                 // have been seen already
 646
 647                 if (startpos >= argc) // all args checked? GOOD
 648                         break;
 649
 650                 if (p < 0)            // no more args? FAIL
 651                 {
 652                         // exception: exactly minargs left, this one included
 653                         if (argc - startpos == minargs) break;
 654
 655                         // otherwise fail
 656                         return false;
 657                 }
 658
 659                 // cut to next semicolon
 660                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 661                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 662                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 663
 664                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 665                 // charlist = strreplace("^^", ";", charlist);
 666
 667                 if (charlist != "")
 668                 {
 669                         // verify the arg only contains allowed chars
 670                         arg = argv(startpos);
 671                         checkmate = strlen(arg);
 672                         for (check = 0; check < checkmate; ++check)
 673                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 674                         // not allowed character
 675                         // all characters are allowed. FINE.
 676                 }
 677
 678                 ++startpos;
 679                 --minargs;
 680                 p = q;
 681         }
 682
 683         return true;
 684 }
 685
 686 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 687 {
 688         string first_command = argv(startpos);
 689         int missing_chars = argv_start_index(startpos);
 690
 691         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 692                 return 0;
 693
 694         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 695
 696         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 697
 698         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 699         {
 700                 case MUT_VOTEPARSE_CONTINUE: { break; }
 701                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 702                 case MUT_VOTEPARSE_INVALID: { return -1; }
 703                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 704         }
 705
 706         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 707         {
 708                 case "kick":
 709                 case "kickban":    // catch all kick/kickban commands
 710                 {
 711                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 712                         float accepted = VerifyClientEntity(victim, true, false);
 713
 714                         if (accepted > 0)
 715                         {
 716                                 string reason = "No reason provided";
 717                                 if(argc > next_token)
 718                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 719
 720                                 string command_arguments = reason;
 721                                 if (first_command == "kickban")
 722                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 723
 724                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 725                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 726                         }
 727                         else
 728                         {
 729                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 730                                 return 0;
 731                         }
 732
 733                         break;
 734                 }
 735
 736                 case "map":
 737                 case "chmap":
 738                 case "gotomap":  // re-direct all map selection commands to gotomap
 739                 {
 740                         vote_command = ValidateMap(argv(startpos + 1), caller);
 741                         if (!vote_command)  return -1;
 742                         vote_parsed_command = strcat("gotomap ", vote_command);
 743                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 744
 745                         break;
 746                 }
 747
 748                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 749                 // maybe fallback instead of aborting if map name is invalid?
 750                 case "nextmap":
 751                 {
 752                         vote_command = ValidateMap(argv(startpos + 1), caller);
 753                         if (!vote_command)  return -1;
 754                         vote_parsed_command = strcat("nextmap ", vote_command);
 755                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 756
 757                         break;
 758                 }
 759
 760                 case "timelimit": // include restrictions on the maximum votable time limit
 761                 {
 762                         float timelimit_vote = stof(argv(startpos + 1));
 763                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 764                         {
 765                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 766                                 return -1;
 767                         }
 768                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 769                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 770                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 771
 772                         break;
 773                 }
 774
 775                 case "restart":
 776                 {
 777                         // add a delay so that vote result can be seen and announcer can be heard
 778                         // if the vote is accepted
 779                         vote_parsed_command = strcat("defer 1 ", vote_command);
 780                         vote_parsed_display = strzone(strcat("^1", vote_command));
 781
 782                         break;
 783                 }
 784
 785                 case "allready":
 786                 {
 787                         if(!warmup_stage) {
 788                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 789                                 return -1;
 790                         }
 791
 792                         vote_parsed_command = vote_command;
 793                         vote_parsed_display = strzone(strcat("^1", vote_command));
 794                         break;
 795                 }
 796
 797                 default:
 798                 {
 799                         vote_parsed_command = vote_command;
 800                         vote_parsed_display = strzone(strcat("^1", vote_command));
 801
 802                         break;
 803                 }
 804         }
 805
 806         return 1;
 807 }
 808
 809
 810 // =======================
 811 //  Command Sub-Functions
 812 // =======================
 813
 814 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 815 {
 816         switch (request)
 817         {
 818                 case CMD_REQUEST_COMMAND:
 819                 {
 820                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 821                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 822                         {
 823                                 print_to(caller, "^1You have already voted.");
 824                         }
 825
 826                         else  // everything went okay, continue changing vote
 827                         {
 828                                 print_to(caller, "^1You abstained from your vote.");
 829                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 830                                 msg_entity = caller;
 831                                 if (!autocvar_sv_vote_singlecount)
 832                                         VoteCount(false);
 833                         }
 834
 835                         return;
 836                 }
 837
 838                 default:
 839                 case CMD_REQUEST_USAGE:
 840                 {
 841                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 842                         print_to(caller, "  No arguments required.");
 843                         return;
 844                 }
 845         }
 846 }
 847
 848 void print_available_commands_to(entity caller)
 849 {
 850         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 851 }
 852
 853 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 854 {
 855         switch (request)
 856         {
 857                 case CMD_REQUEST_COMMAND:
 858                 {
 859                         float tmp_playercount = 0;
 860                         int parse_error;
 861
 862                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 863
 864                         if (!autocvar_sv_vote_call && caller)
 865                         {
 866                                 print_to(caller, "^1Vote calling is not allowed.");
 867                         }
 868                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 869                         {
 870                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 871                         }
 872                         else if (vote_called)
 873                         {
 874                                 print_to(caller, "^1There is already a vote called.");
 875                         }
 876                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 877                         {
 878                                 print_to(caller, "^1Only players can call a vote.");
 879                         }
 880                         else if (caller && !IS_CLIENT(caller))
 881                         {
 882                                 print_to(caller, "^1Only connected clients can vote.");
 883                         }
 884                         else if (timeout_status && vote_command != "timein")
 885                         {
 886                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 887                         }
 888                         else if (caller && (time < caller.vote_waittime))
 889                         {
 890                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 891                         }
 892                         else if (!VoteCommand_checknasty(vote_command))
 893                         {
 894                                 print_to(caller, "^1Syntax error in command.");
 895                         }
 896                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 897                         {
 898                                 if(parse_error == 0)
 899                                 {
 900                                         if (vote_called_command == "")
 901                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 902                                         else
 903                                                 print_to(caller, "^1This command is not acceptable or not available.");
 904                                 }
 905                         }
 906                         else  // everything went okay, continue with calling the vote
 907                         {
 908                                 vote_caller = caller;  // remember who called the vote
 909                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 910                                 vote_called = VOTE_NORMAL;
 911                                 vote_called_command = strzone(vote_parsed_command);
 912                                 vote_called_display = strzone(vote_parsed_display);
 913                                 vote_endtime = time + autocvar_sv_vote_timeout;
 914
 915                                 if (caller)
 916                                 {
 917                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 918                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 919                                         msg_entity = caller;
 920                                 }
 921
 922                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 923
 924                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 925                                 if (autocvar_sv_eventlog)
 926                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 927                                 Nagger_VoteChanged();
 928                                 VoteCount(true);  // needed if you are the only one
 929
 930                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 931                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 932                         }
 933
 934                         return;
 935                 }
 936
 937                 default:
 938                 case CMD_REQUEST_USAGE:
 939                 {
 940                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 941                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 942                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 943                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 944                         print_available_commands_to(caller);
 945                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 946                         return;
 947                 }
 948         }
 949 }
 950
 951 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 952 {
 953         switch (request)
 954         {
 955                 case CMD_REQUEST_COMMAND:
 956                 {
 957                         if (autocvar_sv_vote_master)
 958                         {
 959                                 switch (strtolower(argv(2)))
 960                                 {
 961                                         case "do":
 962                                         {
 963                                                 int parse_error;
 964                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 965
 966                                                 if (!caller.vote_master)
 967                                                         print_to(caller, "^1You do not have vote master privileges.");
 968                                                 else if (!VoteCommand_checknasty(vote_command))
 969                                                 {
 970                                                         print_to(caller, "^1Syntax error in command.");
 971                                                 }
 972                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 973                                                 {
 974                                                         if(parse_error == 0)
 975                                                         {
 976                                                                 if (vote_called_command == "")
 977                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 978                                                                 else
 979                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 980                                                         }
 981                                                 }
 982                                                 else  // everything went okay, proceed with command
 983                                                 {
 984                                                         localcmd(strcat(vote_parsed_command, "\n"));
 985                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 986                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 987                                                         if (autocvar_sv_eventlog)
 988                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 989                                                 }
 990
 991                                                 return;
 992                                         }
 993
 994                                         case "login":
 995                                         {
 996                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 997                                                 else if (caller.vote_master)
 998                                                 {
 999                                                         print_to(caller, "^1You are already logged in as vote master.");
1000                                                 }
1001                                                 else if (autocvar_sv_vote_master_password != argv(3))
1002                                                 {
1003                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1004                                                 }
1005                                                 else  // everything went okay, proceed with giving this player master privilages
1006                                                 {
1007                                                         caller.vote_master = true;
1008                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1009                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1010                                                         if (autocvar_sv_eventlog)
1011                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1012                                                 }
1013
1014                                                 return;
1015                                         }
1016
1017                                         default:  // calling a vote for master
1018                                         {
1019                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1020                                                 else if (vote_called)
1021                                                 {
1022                                                         print_to(caller, "^1There is already a vote called.");
1023                                                 }
1024                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1025                                                 {
1026                                                         print_to(caller, "^1Only players can call a vote.");
1027                                                 }
1028                                                 else if (timeout_status)
1029                                                 {
1030                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1031                                                 }
1032                                                 else  // everything went okay, continue with creating vote
1033                                                 {
1034                                                         vote_caller = caller;
1035                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1036                                                         vote_called = VOTE_MASTER;
1037                                                         vote_called_command = strzone("XXX");
1038                                                         vote_called_display = strzone("^3master");
1039                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1040
1041                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1042                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1043
1044                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1045                                                         if (autocvar_sv_eventlog)
1046                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1047                                                         Nagger_VoteChanged();
1048                                                         VoteCount(true);  // needed if you are the only one
1049                                                 }
1050
1051                                                 return;
1052                                         }
1053                                 }
1054                         }
1055                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1056
1057                         return;
1058                 }
1059
1060                 default:
1061                 case CMD_REQUEST_USAGE:
1062                 {
1063                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1064                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1065                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1066                         return;
1067                 }
1068         }
1069 }
1070
1071 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1072 {
1073         switch (request)
1074         {
1075                 case CMD_REQUEST_COMMAND:
1076                 {
1077                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1078                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1079                         {
1080                                 print_to(caller, "^1You have already voted.");
1081                         }
1082                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1083                         {
1084                                 VoteStop(caller);
1085                         }
1086
1087                         else  // everything went okay, continue changing vote
1088                         {
1089                                 print_to(caller, "^1You rejected the vote.");
1090                                 caller.vote_selection = VOTE_SELECT_REJECT;
1091                                 msg_entity = caller;
1092                                 if (!autocvar_sv_vote_singlecount)
1093                                         VoteCount(false);
1094                         }
1095
1096                         return;
1097                 }
1098
1099                 default:
1100                 case CMD_REQUEST_USAGE:
1101                 {
1102                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1103                         print_to(caller, "  No arguments required.");
1104                         return;
1105                 }
1106         }
1107 }
1108
1109 void VoteCommand_status(int request, entity caller)  // BOTH
1110 {
1111         switch (request)
1112         {
1113                 case CMD_REQUEST_COMMAND:
1114                 {
1115                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1116                         else print_to(caller, "^1No vote called.");
1117
1118                         return;
1119                 }
1120
1121                 default:
1122                 case CMD_REQUEST_USAGE:
1123                 {
1124                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1125                         print_to(caller, "  No arguments required.");
1126                         return;
1127                 }
1128         }
1129 }
1130
1131 void VoteCommand_stop(int request, entity caller)  // BOTH
1132 {
1133         switch (request)
1134         {
1135                 case CMD_REQUEST_COMMAND:
1136                 {
1137                         if (!vote_called)   print_to(caller, "^1No vote called.");
1138                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1139                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1140                         return;
1141                 }
1142
1143                 default:
1144                 case CMD_REQUEST_USAGE:
1145                 {
1146                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1147                         print_to(caller, "  No arguments required.");
1148                         return;
1149                 }
1150         }
1151 }
1152
1153 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1154 {
1155         switch (request)
1156         {
1157                 case CMD_REQUEST_COMMAND:
1158                 {
1159                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1160                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1161                         {
1162                                 print_to(caller, "^1You have already voted.");
1163                         }
1164                         else  // everything went okay, continue changing vote
1165                         {
1166                                 print_to(caller, "^1You accepted the vote.");
1167                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1168                                 msg_entity = caller;
1169                                 if (!autocvar_sv_vote_singlecount)
1170                                         VoteCount(false);
1171                         }
1172
1173                         return;
1174                 }
1175
1176                 default:
1177                 case CMD_REQUEST_USAGE:
1178                 {
1179                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1180                         print_to(caller, "  No arguments required.");
1181                         return;
1182                 }
1183         }
1184 }
1185
1186 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1187 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1188 void VoteCommand_(int request)
1189 {
1190     switch(request)
1191     {
1192         case CMD_REQUEST_COMMAND:
1193         {
1194
1195             return;
1196         }
1197
1198         default:
1199         case CMD_REQUEST_USAGE:
1200         {
1201             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1202             print_to(caller, "  No arguments required.");
1203             return;
1204         }
1205     }
1206 }
1207 */
1208
1209
1210 // ================================
1211 //  Macro system for vote commands
1212 // ================================
1213
1214 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1215 #define VOTE_COMMANDS(request, caller, arguments, command) \
1216         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1217         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1218         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1219         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1220         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1221         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1222         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1223         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1224         /* nothing */
1225
1226 void VoteCommand_macro_help(entity caller, int argc)
1227 {
1228         string command_origin = GetCommandPrefix(caller);
1229
1230         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1231         {
1232                 print_to(caller, "\nVoting commands:\n");
1233                 #define VOTE_COMMAND(name, function, description, assignment) \
1234                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1235
1236                 VOTE_COMMANDS(0, caller, 0, "");
1237                 #undef VOTE_COMMAND
1238
1239                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1240                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1241                 print_available_commands_to(caller);
1242         }
1243         else  // usage for individual command
1244         {
1245                 #define VOTE_COMMAND(name, function, description, assignment) \
1246                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1247
1248                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1249                 #undef VOTE_COMMAND
1250
1251                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1252                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1253                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1254                 else if (argv(2) != "")
1255                         print_to(caller, "No documentation exists for this vote");
1256         }
1257 }
1258
1259 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1260 {
1261         #define VOTE_COMMAND(name, function, description, assignment) \
1262                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1263
1264         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1265         #undef VOTE_COMMAND
1266
1267         return false;
1268 }
1269
1270
1271 // ======================================
1272 //  Main function handling vote commands
1273 // ======================================
1274
1275 void VoteCommand(int request, entity caller, int argc, string vote_command)
1276 {
1277         // Guide for working with argc arguments by example:
1278         // argc:   1    - 2      - 3     - 4
1279         // argv:   0    - 1      - 2     - 3
1280         // cmd     vote - master - login - password
1281
1282         switch (request)
1283         {
1284                 case CMD_REQUEST_COMMAND:
1285                 {
1286                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1287                 }
1288
1289                 default:
1290                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         VoteCommand_macro_help(caller, argc);
1294                         return;
1295                 }
1296         }
1297 }