qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/weapons/selection.qh>
  29 #include <server/world.qh>
  30
  31 // =============================================
  32 //  Server side voting code, reworked by Samual
  33 //  Last updated: December 27th, 2011
  34 // =============================================
  35
  36 //  Nagger for players to know status of voting
  37 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  38 {
  39         int nags = 0;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         if (warmup_stage)
  53         {
  54                 if (readycount)
  55                 {
  56                         nags |= BIT(0);
  57                         if (!to.ready) nags |= BIT(1);
  58                 }
  59                 nags |= BIT(4);
  60         }
  61
  62         if (vote_called)
  63         {
  64                 nags |= BIT(2);
  65                 if (to.vote_selection == 0) nags |= BIT(3);
  66                 nags |= sendflags & BIT(6);
  67                 nags |= sendflags & BIT(7);
  68         }
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & BIT(0))
  83         {
  84                 for (int i = 1; i <= maxclients;)
  85                 {
  86                         int f = 0;
  87                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  88                                 if (edict_num(i).ready)
  89                                         f |= BIT(b);
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteStop(entity stopper, bool show_name);
 129 void VoteReset(bool verbose)
 130 {
 131         if (verbose && vote_called)
 132         {
 133                 VoteStop(NULL, true);
 134                 return;
 135         }
 136
 137         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 138
 139         if (vote_called)
 140         {
 141                 strfree(vote_called_command);
 142                 strfree(vote_called_display);
 143                 strfree(vote_caller_name);
 144         }
 145
 146         vote_called = VOTE_NULL;
 147         vote_caller = NULL;
 148         vote_endtime = 0;
 149
 150         vote_parsed_command = string_null;
 151         vote_parsed_display = string_null;
 152
 153         Nagger_VoteChanged();
 154 }
 155
 156 void VoteStop(entity stopper, bool canceled)
 157 {
 158         if (canceled)
 159                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
 160         else
 161                 bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 162         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 163         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 164         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 165         VoteReset(false);
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 173         else localcmd(strcat(vote_called_command, "\n"));
 174
 175         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 176
 177         VoteReset(false);
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 179 }
 180
 181 void VoteReject()
 182 {
 183         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 184         VoteReset(false);
 185         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 186 }
 187
 188 void VoteTimeout()
 189 {
 190         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 191         VoteReset(false);
 192         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 193 }
 194
 195 void VoteSpam(float notvoters, float mincount, string result)
 196 {
 197         bprint(strcat(
 198                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 199                 strcat("^2:^1", ftos(vote_reject_count)),
 200                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 201                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 202                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 203
 204         if (autocvar_sv_eventlog)
 205         {
 206                 GameLogEcho(strcat(
 207                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 208                         strcat(":", ftos(vote_reject_count)),
 209                         strcat(":", ftos(vote_abstain_count)),
 210                         strcat(":", ftos(notvoters)),
 211                         strcat(":", ftos(mincount))));
 212         }
 213 }
 214
 215 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 216
 217 void VoteCount(float first_count)
 218 {
 219         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 220
 221         float vote_player_count = 0, notvoters = 0;
 222         float vote_real_player_count = 0, vote_real_accept_count = 0;
 223         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 224         float vote_needed_of_voted, final_needed_votes;
 225         float vote_factor_overall, vote_factor_of_voted;
 226
 227         Nagger_VoteCountChanged();
 228
 229         // add up all the votes from each connected client
 230         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_vote_debug, {
 231                 ++vote_player_count;
 232                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 233                 switch (it.vote_selection)
 234                 {
 235                         case VOTE_SELECT_REJECT:
 236                                 ++vote_reject_count;
 237                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 238                                 break;
 239                         case VOTE_SELECT_ACCEPT:
 240                                 ++vote_accept_count;
 241                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 242                                 break;
 243                         case VOTE_SELECT_ABSTAIN:
 244                                 ++vote_abstain_count;
 245                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 246                                 break;
 247                         default: break;
 248                 }
 249         });
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if (vote_caller)   vote_caller.vote_waittime = 0;
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset(false);
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if (!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if (vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if (vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if (time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if (autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if (vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if (vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if (vote_endtime > 0)        // a vote was called
 336         {
 337                 if (time > vote_endtime) // time is up
 338                         VoteCount(false);
 339         }
 340 }
 341
 342
 343 // =======================
 344 //  Game logic for warmup
 345 // =======================
 346
 347 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 348 void reset_map(bool is_fake_round_start)
 349 {
 350         if (time <= game_starttime)
 351         {
 352                 if (game_stopped)
 353                         return;
 354
 355                 if (!is_fake_round_start)
 356                 {
 357                         Score_ClearAll();
 358                         PlayerStats_GameReport_Reset_All();
 359                 }
 360
 361                 if (round_handler_IsActive())
 362                         round_handler_Reset(game_starttime);
 363         }
 364
 365         if (shuffleteams_on_reset_map)
 366         {
 367                 shuffleteams();
 368                 shuffleteams_on_reset_map = false;
 369         }
 370
 371         FOREACH_CLIENT(true, {
 372                 if (time <= game_starttime)
 373                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 374                 if (!IS_PLAYER(it))
 375                         continue;
 376                 if (STAT(FROZEN, it))
 377                         Unfreeze(it, false);
 378                 player_powerups_remove_all(it);
 379                 entity store = PS(it);
 380                 if (store)
 381                 {
 382                         Inventory_clear(store.inventory);
 383                         Inventory_update(store);
 384                 }
 385         });
 386
 387         MUTATOR_CALLHOOK(reset_map_global);
 388
 389         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 390         {
 391                 if(IS_CLIENT(it))
 392                         continue;
 393                 if (it.reset)
 394                 {
 395                         it.reset(it);
 396                         continue;
 397                 }
 398                 if (it.team_saved) it.team = it.team_saved;
 399                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 400         });
 401
 402         // Waypoints and assault start come LAST
 403         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 404                 if (it.reset2) it.reset2(it);
 405         });
 406
 407         // Moving the player reset code here since the player-reset depends
 408         // on spawnpoint entities which have to be reset first --blub
 409         if (!MUTATOR_CALLHOOK(reset_map_players))
 410         {
 411                 FOREACH_CLIENT(IS_PLAYER(it),
 412                 {
 413                         // PlayerScore_Clear(it);
 414                         CS(it).killcount = 0;
 415                         // stop the player from moving so that they stand still once they get respawned
 416                         it.velocity = '0 0 0';
 417                         it.avelocity = '0 0 0';
 418                         CS(it).movement = '0 0 0';
 419                         PutClientInServer(it);
 420
 421                         if(IS_BOT_CLIENT(it))
 422                         {
 423                                 .entity weaponentity = weaponentities[0];
 424                                 if(it.(weaponentity).m_weapon == WEP_Null)
 425                                         W_NextWeapon(it, 0, weaponentity);
 426                         }
 427                 });
 428         }
 429 }
 430
 431 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 432 void ReadyRestart_think(entity this)
 433 {
 434         if (!warmup_stage) // if the countdown was not aborted
 435                 reset_map(false);
 436         delete(this);
 437 }
 438
 439 // Forces a restart of the game without actually reloading the map // this is a mess...
 440 void ReadyRestart_force(bool is_fake_round_start)
 441 {
 442         if (time <= game_starttime && game_stopped)
 443                 return;
 444         if (!is_fake_round_start && !autocvar_g_campaign)
 445                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 446
 447         VoteReset(true);
 448
 449         // clear overtime, we have to decrease timelimit to its original value again.
 450         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 451                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 452         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 453
 454         if(warmup_stage)
 455                 game_starttime = time; // Warmup: No countdown in warmup
 456         else if (autocvar_g_campaign)
 457                 game_starttime = time + 3;
 458         else
 459                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 460
 461         // clear player attributes
 462         FOREACH_CLIENT(IS_PLAYER(it), {
 463                 it.alivetime = 0;
 464                 CS(it).killcount = 0;
 465         });
 466
 467         // if we're ending the warmup stage call the corresponding hook
 468         if(!is_fake_round_start && !warmup_stage)
 469                 localcmd("\nsv_hook_warmupend\n");
 470
 471         // reset the .ready status of all clients (including spectators and bots)
 472         FOREACH_CLIENT(true, { it.ready = false; });
 473         readycount = 0;
 474         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 475
 476         // lock teams with lockonrestart
 477         if (autocvar_teamplay_lockonrestart && teamplay)
 478                 lockteams = !warmup_stage;
 479
 480         // initiate the restart-countdown-announcer entity
 481         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 482         {
 483                 entity restart_timer = new_pure(restart_timer);
 484                 setthink(restart_timer, ReadyRestart_think);
 485                 restart_timer.nextthink = game_starttime;
 486         }
 487
 488         // after a restart every players number of allowed timeouts gets reset, too
 489         if (autocvar_sv_timeout)
 490         {
 491                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 492         }
 493
 494         if (!sv_ready_restart_after_countdown || warmup_stage)
 495                 reset_map(is_fake_round_start);
 496
 497         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 498 }
 499
 500 void ReadyRestart(bool forceWarmupEnd)
 501 {
 502         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 503         {
 504                 // NOTE: ReadyRestart support is mandatory in campaign
 505                 if (autocvar_g_campaign)
 506                         error("ReadyRestart must be supported in campaign mode!");
 507                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 508         }
 509         else localcmd("\nsv_hook_readyrestart\n");
 510
 511         if(forceWarmupEnd || autocvar_g_campaign)
 512                 warmup_stage = 0; // forcefully end warmup and go to match stage
 513         else
 514                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 515
 516         ReadyRestart_force(false);
 517 }
 518
 519 /* Count the players who are ready and determine whether or not to restart the match when:
 520  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 521  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 522  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 523  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 524 void ReadyCount()
 525 {
 526         // cannot reset the game while a timeout is active or pending
 527         if (timeout_status) return;
 528
 529         int total_players = 0, human_players = 0, humans_ready = 0;
 530         readycount = 0;
 531
 532         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 533                 ++total_players;
 534                 if (it.ready) ++readycount;
 535                 if (IS_REAL_CLIENT(it))
 536                 {
 537                         ++human_players;
 538                         if (it.ready) ++humans_ready;
 539                 }
 540         });
 541
 542         Nagger_ReadyCounted();
 543
 544         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 545         // and we need to use this when checking if we should abort the countdown
 546         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 547         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 548
 549         if (total_players < minplayers)
 550         {
 551                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 552                 {
 553                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 554                         game_starttime = time;
 555                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 556                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 557                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 558                 }
 559                 if (warmup_limit > 0)
 560                         warmup_limit = -1;
 561                 return; // don't ReadyRestart if players are ready but too few
 562         }
 563         else if (minplayers && warmup_limit <= 0)
 564         {
 565                 // there's enough players now but we're still in infinite warmup
 566                 warmup_limit = cvar("g_warmup_limit");
 567                 if (warmup_limit == 0)
 568                         warmup_limit = autocvar_timelimit * 60;
 569                 if (warmup_limit > 0)
 570                         game_starttime = time;
 571                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 572                 // warmup continues until enough players AND enough RUPs (no time limit)
 573         }
 574
 575         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 576                 ReadyRestart(true);
 577 }
 578
 579
 580 // ======================================
 581 //  Supporting functions for VoteCommand
 582 // ======================================
 583
 584 bool Votecommand_check_assignment(entity caller, float assignment)
 585 {
 586         bool from_server = (!caller);
 587
 588         if ((assignment == VC_ASGNMNT_BOTH)
 589             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 590             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 591
 592         return false;
 593 }
 594
 595 string VoteCommand_extractcommand(string input, float startpos, int argc)
 596 {
 597         string output;
 598
 599         if ((argc - 1) < startpos) output = "";
 600         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 601
 602         return output;
 603 }
 604
 605 bool VoteCommand_checknasty(string vote_command)
 606 {
 607         return !((strstrofs(vote_command, ";", 0) >= 0)
 608             || (strstrofs(vote_command, "\n", 0) >= 0)
 609             || (strstrofs(vote_command, "\r", 0) >= 0)
 610             || (strstrofs(vote_command, "$", 0) >= 0));
 611 }
 612
 613 // NOTE: requires input to be surrounded by spaces
 614 string VoteCommand_checkreplacements(string input)
 615 {
 616         // add a space around the input so the start and end of the list is captured
 617         string output = strcat(" ", input, " ");
 618         // allow gotomap replacements
 619         output = strreplace(" map ", " gotomap ", output);
 620         output = strreplace(" chmap ", " gotomap ", output);
 621         return output;
 622 }
 623
 624 bool VoteCommand_checkinlist(string vote_command, string list)
 625 {
 626         if (vote_command == "" || list == "")
 627                 return false;
 628
 629         string l = VoteCommand_checkreplacements(list);
 630         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 631 }
 632
 633 string ValidateMap(string validated_map, entity caller)
 634 {
 635         validated_map = MapInfo_FixName(validated_map);
 636
 637         if (!validated_map)
 638         {
 639                 print_to(caller, "This map is not available on this server.");
 640                 return string_null;
 641         }
 642
 643         if (!autocvar_sv_vote_override_mostrecent && caller)
 644         {
 645                 if (Map_IsRecent(validated_map))
 646                 {
 647                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 648                         return string_null;
 649                 }
 650         }
 651
 652         if (!MapInfo_CheckMap(validated_map))
 653         {
 654                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 655                 return string_null;
 656         }
 657
 658         return validated_map;
 659 }
 660
 661 float VoteCommand_checkargs(float startpos, int argc)
 662 {
 663         float p, q, check, minargs;
 664         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 665         string cmdrestriction = "";  // No we don't.
 666         string charlist, arg;
 667         float checkmate;
 668
 669         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 670                 cmdrestriction = cvar_string(cvarname);
 671         else
 672                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 673
 674         if (cmdrestriction == "") return true;
 675
 676         ++startpos;  // skip command name
 677
 678         // check minimum arg count
 679
 680         // 0 args: argc == startpos
 681         // 1 args: argc == startpos + 1
 682         // ...
 683
 684         minargs = stof(cmdrestriction);
 685         if (argc - startpos < minargs) return false;
 686
 687         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 688
 689         for ( ; ; )
 690         {
 691                 // we know that at any time, startpos <= argc - minargs
 692                 // so this means: argc-minargs >= startpos >= argc, thus
 693                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 694                 // have been seen already
 695
 696                 if (startpos >= argc) // all args checked? GOOD
 697                         break;
 698
 699                 if (p < 0)            // no more args? FAIL
 700                 {
 701                         // exception: exactly minargs left, this one included
 702                         if (argc - startpos == minargs) break;
 703
 704                         // otherwise fail
 705                         return false;
 706                 }
 707
 708                 // cut to next semicolon
 709                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 710                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 711                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 712
 713                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 714                 // charlist = strreplace("^^", ";", charlist);
 715
 716                 if (charlist != "")
 717                 {
 718                         // verify the arg only contains allowed chars
 719                         arg = argv(startpos);
 720                         checkmate = strlen(arg);
 721                         for (check = 0; check < checkmate; ++check)
 722                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 723                         // not allowed character
 724                         // all characters are allowed. FINE.
 725                 }
 726
 727                 ++startpos;
 728                 --minargs;
 729                 p = q;
 730         }
 731
 732         return true;
 733 }
 734
 735 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 736 {
 737         string first_command = argv(startpos);
 738         int missing_chars = argv_start_index(startpos);
 739
 740         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 741                 return 0;
 742
 743         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 744
 745         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 746
 747         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 748         {
 749                 case MUT_VOTEPARSE_CONTINUE: { break; }
 750                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 751                 case MUT_VOTEPARSE_INVALID: { return -1; }
 752                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 753         }
 754
 755         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 756         {
 757                 case "movetoauto":
 758                 case "movetored":
 759                 case "movetoblue":
 760                 case "movetoyellow":
 761                 case "movetopink":
 762                 case "movetospec":
 763                 {
 764                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 765                         float accepted = VerifyClientEntity(victim, true, false);
 766                         if (accepted > 0)
 767                         {
 768                                 vote_parsed_command = vote_command;
 769                                 vote_parsed_display = sprintf("^1%s #%d ^7%s", first_command, etof(victim), victim.netname);
 770                         }
 771                         else
 772                         {
 773                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 774                                 return 0;
 775                         }
 776
 777                         break;
 778                 }
 779
 780                 case "kick":
 781                 case "kickban":    // catch all kick/kickban commands
 782                 {
 783                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 784                         float accepted = VerifyClientEntity(victim, true, false);
 785
 786                         if (accepted > 0)
 787                         {
 788                                 string reason = "No reason provided";
 789                                 if(argc > next_token)
 790                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 791
 792                                 string command_arguments = reason;
 793                                 if (first_command == "kickban")
 794                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 795
 796                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 797                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 798                         }
 799                         else
 800                         {
 801                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 802                                 return 0;
 803                         }
 804
 805                         break;
 806                 }
 807
 808                 case "map":
 809                 case "chmap":
 810                 case "gotomap":  // re-direct all map selection commands to gotomap
 811                 {
 812                         vote_command = ValidateMap(argv(startpos + 1), caller);
 813                         if (!vote_command)  return -1;
 814                         vote_parsed_command = strcat("gotomap ", vote_command);
 815                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 816
 817                         break;
 818                 }
 819
 820                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 821                 // maybe fallback instead of aborting if map name is invalid?
 822                 case "nextmap":
 823                 {
 824                         vote_command = ValidateMap(argv(startpos + 1), caller);
 825                         if (!vote_command)  return -1;
 826                         vote_parsed_command = strcat("nextmap ", vote_command);
 827                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 828
 829                         break;
 830                 }
 831
 832                 case "fraglimit": // include restrictions on the maximum votable frag limit
 833                 {
 834                         float fraglimit_vote = stof(argv(startpos + 1));
 835                         float fraglimit_min = 0;
 836                         float fraglimit_max = 999999;
 837                         if(fraglimit_vote > fraglimit_max || fraglimit_vote < fraglimit_min)
 838                         {
 839                                 print_to(caller, strcat("Invalid fraglimit vote, accepted values are between ", ftos(fraglimit_min), " and ", ftos(fraglimit_max), "."));
 840                                 return -1;
 841                         }
 842                         vote_parsed_command = strcat("fraglimit ", ftos(fraglimit_vote));
 843                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 844
 845                         break;
 846                 }
 847
 848                 case "timelimit": // include restrictions on the maximum votable time limit
 849                 {
 850                         float timelimit_vote = stof(argv(startpos + 1));
 851                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 852                         {
 853                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 854                                 return -1;
 855                         }
 856                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 857                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 858
 859                         break;
 860                 }
 861
 862                 case "restart":
 863                 {
 864                         // add a delay so that vote result can be seen and announcer can be heard
 865                         // if the vote is accepted
 866                         vote_parsed_command = strcat("defer 1 ", vote_command);
 867                         vote_parsed_display = strzone(strcat("^1", vote_command));
 868
 869                         break;
 870                 }
 871
 872                 case "allready":
 873                 {
 874                         if(!warmup_stage) {
 875                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 876                                 return -1;
 877                         }
 878
 879                         vote_parsed_command = vote_command;
 880                         vote_parsed_display = strzone(strcat("^1", vote_command));
 881                         break;
 882                 }
 883
 884                 default:
 885                 {
 886                         vote_parsed_command = vote_command;
 887                         vote_parsed_display = strzone(strcat("^1", vote_command));
 888
 889                         break;
 890                 }
 891         }
 892
 893         return 1;
 894 }
 895
 896
 897 // =======================
 898 //  Command Sub-Functions
 899 // =======================
 900
 901 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 902 {
 903         switch (request)
 904         {
 905                 case CMD_REQUEST_COMMAND:
 906                 {
 907                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 908                         {
 909                                 print_to(caller, "^1You are banned from voting.");
 910                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 911                                 return;
 912                         }
 913
 914                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 915                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 916                         {
 917                                 print_to(caller, "^1You have already voted.");
 918                         }
 919
 920                         else  // everything went okay, continue changing vote
 921                         {
 922                                 print_to(caller, "^1You abstained from your vote.");
 923                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 924                                 msg_entity = caller;
 925                                 if (!autocvar_sv_vote_singlecount)
 926                                         VoteCount(false);
 927                         }
 928
 929                         return;
 930                 }
 931
 932                 default:
 933                 case CMD_REQUEST_USAGE:
 934                 {
 935                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 936                         print_to(caller, "  No arguments required.");
 937                         return;
 938                 }
 939         }
 940 }
 941
 942 void print_available_commands_to(entity caller)
 943 {
 944         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 945 }
 946
 947 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 948 {
 949         switch (request)
 950         {
 951                 case CMD_REQUEST_COMMAND:
 952                 {
 953                         float tmp_playercount = 0;
 954                         int parse_error;
 955
 956                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 957                         {
 958                                 print_to(caller, "^1You are banned from calling a vote.");
 959                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
 960                                 return;
 961                         }
 962
 963                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 964
 965                         if (!autocvar_sv_vote_call && caller)
 966                         {
 967                                 print_to(caller, "^1Vote calling is not allowed.");
 968                         }
 969                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 970                         {
 971                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 972                         }
 973                         else if (vote_called)
 974                         {
 975                                 print_to(caller, "^1There is already a vote called.");
 976                         }
 977                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 978                         {
 979                                 print_to(caller, "^1Only players can call a vote.");
 980                         }
 981                         else if (caller && !IS_CLIENT(caller))
 982                         {
 983                                 print_to(caller, "^1Only connected clients can vote.");
 984                         }
 985                         else if (timeout_status && vote_command != "timein")
 986                         {
 987                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 988                         }
 989                         else if (caller && (time < caller.vote_waittime))
 990                         {
 991                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 992                         }
 993                         else if (!VoteCommand_checknasty(vote_command))
 994                         {
 995                                 print_to(caller, "^1Syntax error in command.");
 996                         }
 997                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 998                         {
 999                                 if(parse_error == 0)
1000                                 {
1001                                         if (vote_called_command == "")
1002                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
1003                                         else
1004                                                 print_to(caller, "^1This command is not acceptable or not available.");
1005                                 }
1006                         }
1007                         else  // everything went okay, continue with calling the vote
1008                         {
1009                                 vote_caller = caller;  // remember who called the vote
1010                                 vote_caller_name = strzone(GetCallerName(vote_caller));
1011                                 vote_called = VOTE_NORMAL;
1012                                 vote_called_command = strzone(vote_parsed_command);
1013                                 vote_called_display = strzone(vote_parsed_display);
1014                                 vote_endtime = time + autocvar_sv_vote_timeout;
1015
1016                                 if (caller)
1017                                 {
1018                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1019                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1020                                         msg_entity = caller;
1021                                 }
1022
1023                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
1024
1025                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
1026                                 if (autocvar_sv_vote_debug)
1027                                         bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
1028                                 if (autocvar_sv_eventlog)
1029                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1030                                 Nagger_VoteChanged();
1031                                 VoteCount(true);  // needed if you are the only one
1032
1033                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
1034                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
1035                         }
1036
1037                         return;
1038                 }
1039
1040                 default:
1041                 case CMD_REQUEST_USAGE:
1042                 {
1043                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
1044                         print_to(caller, "  Where <command> is the command to request a vote upon.");
1045                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
1046                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
1047                         print_available_commands_to(caller);
1048                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
1049                         return;
1050                 }
1051         }
1052 }
1053
1054 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
1055 {
1056         switch (request)
1057         {
1058                 case CMD_REQUEST_COMMAND:
1059                 {
1060                         if (autocvar_sv_vote_master)
1061                         {
1062                                 switch (strtolower(argv(2)))
1063                                 {
1064                                         case "do":
1065                                         {
1066                                                 int parse_error;
1067                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1068
1069                                                 if (!caller.vote_master)
1070                                                         print_to(caller, "^1You do not have vote master privileges.");
1071                                                 else if (!VoteCommand_checknasty(vote_command))
1072                                                 {
1073                                                         print_to(caller, "^1Syntax error in command.");
1074                                                 }
1075                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1076                                                 {
1077                                                         if(parse_error == 0)
1078                                                         {
1079                                                                 if (vote_called_command == "")
1080                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1081                                                                 else
1082                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1083                                                         }
1084                                                 }
1085                                                 else  // everything went okay, proceed with command
1086                                                 {
1087                                                         localcmd(strcat(vote_parsed_command, "\n"));
1088                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1089                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1090                                                         if (autocvar_sv_eventlog)
1091                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1092                                                 }
1093
1094                                                 return;
1095                                         }
1096
1097                                         case "login":
1098                                         {
1099                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1100                                                 else if (caller.vote_master)
1101                                                 {
1102                                                         print_to(caller, "^1You are already logged in as vote master.");
1103                                                 }
1104                                                 else if (autocvar_sv_vote_master_password != argv(3))
1105                                                 {
1106                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1107                                                 }
1108                                                 else  // everything went okay, proceed with giving this player master privilages
1109                                                 {
1110                                                         caller.vote_master = true;
1111                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1112                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1113                                                         if (autocvar_sv_eventlog)
1114                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1115                                                 }
1116
1117                                                 return;
1118                                         }
1119
1120                                         default:  // calling a vote for master
1121                                         {
1122                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1123                                                 else if (vote_called)
1124                                                 {
1125                                                         print_to(caller, "^1There is already a vote called.");
1126                                                 }
1127                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1128                                                 {
1129                                                         print_to(caller, "^1Only players can call a vote.");
1130                                                 }
1131                                                 else if (timeout_status)
1132                                                 {
1133                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1134                                                 }
1135                                                 else  // everything went okay, continue with creating vote
1136                                                 {
1137                                                         vote_caller = caller;
1138                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1139                                                         vote_called = VOTE_MASTER;
1140                                                         vote_called_command = strzone("XXX");
1141                                                         vote_called_display = strzone("^3master");
1142                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1143
1144                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1145                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1146
1147                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1148                                                         if (autocvar_sv_eventlog)
1149                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1150                                                         Nagger_VoteChanged();
1151                                                         VoteCount(true);  // needed if you are the only one
1152                                                 }
1153
1154                                                 return;
1155                                         }
1156                                 }
1157                         }
1158                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1159
1160                         return;
1161                 }
1162
1163                 default:
1164                 case CMD_REQUEST_USAGE:
1165                 {
1166                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1167                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1168                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1169                         return;
1170                 }
1171         }
1172 }
1173
1174 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1175 {
1176         switch (request)
1177         {
1178                 case CMD_REQUEST_COMMAND:
1179                 {
1180                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1181                         {
1182                                 print_to(caller, "^1You are banned from voting.");
1183                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1184                                 return;
1185                         }
1186
1187                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1188                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1189                         {
1190                                 print_to(caller, "^1You have already voted.");
1191                         }
1192                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1193                         {
1194                                 VoteStop(caller, true);
1195                         }
1196
1197                         else  // everything went okay, continue changing vote
1198                         {
1199                                 print_to(caller, "^1You rejected the vote.");
1200                                 caller.vote_selection = VOTE_SELECT_REJECT;
1201                                 msg_entity = caller;
1202                                 if (!autocvar_sv_vote_singlecount)
1203                                         VoteCount(false);
1204                         }
1205
1206                         return;
1207                 }
1208
1209                 default:
1210                 case CMD_REQUEST_USAGE:
1211                 {
1212                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1213                         print_to(caller, "  No arguments required.");
1214                         return;
1215                 }
1216         }
1217 }
1218
1219 void VoteCommand_status(int request, entity caller)  // BOTH
1220 {
1221         switch (request)
1222         {
1223                 case CMD_REQUEST_COMMAND:
1224                 {
1225                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1226                         else print_to(caller, "^1No vote called.");
1227
1228                         return;
1229                 }
1230
1231                 default:
1232                 case CMD_REQUEST_USAGE:
1233                 {
1234                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1235                         print_to(caller, "  No arguments required.");
1236                         return;
1237                 }
1238         }
1239 }
1240
1241 void VoteCommand_stop(int request, entity caller)  // BOTH
1242 {
1243         switch (request)
1244         {
1245                 case CMD_REQUEST_COMMAND:
1246                 {
1247                         if (!vote_called)   print_to(caller, "^1No vote called.");
1248                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
1249                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1250                         return;
1251                 }
1252
1253                 default:
1254                 case CMD_REQUEST_USAGE:
1255                 {
1256                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1257                         print_to(caller, "  No arguments required.");
1258                         return;
1259                 }
1260         }
1261 }
1262
1263 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1264 {
1265         switch (request)
1266         {
1267                 case CMD_REQUEST_COMMAND:
1268                 {
1269                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1270                         {
1271                                 print_to(caller, "^1You are banned from voting.");
1272                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1273                                 return;
1274                         }
1275
1276                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1277                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1278                         {
1279                                 print_to(caller, "^1You have already voted.");
1280                         }
1281                         else  // everything went okay, continue changing vote
1282                         {
1283                                 print_to(caller, "^1You accepted the vote.");
1284                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1285                                 msg_entity = caller;
1286                                 if (!autocvar_sv_vote_singlecount)
1287                                         VoteCount(false);
1288                         }
1289
1290                         return;
1291                 }
1292
1293                 default:
1294                 case CMD_REQUEST_USAGE:
1295                 {
1296                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1297                         print_to(caller, "  No arguments required.");
1298                         return;
1299                 }
1300         }
1301 }
1302
1303 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1304 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1305 void VoteCommand_(int request)
1306 {
1307     switch(request)
1308     {
1309         case CMD_REQUEST_COMMAND:
1310         {
1311
1312             return;
1313         }
1314
1315         default:
1316         case CMD_REQUEST_USAGE:
1317         {
1318             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1319             print_to(caller, "  No arguments required.");
1320             return;
1321         }
1322     }
1323 }
1324 */
1325
1326
1327 // ================================
1328 //  Macro system for vote commands
1329 // ================================
1330
1331 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1332 #define VOTE_COMMANDS(request, caller, arguments, command) \
1333         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1334         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1335         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1336         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1337         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1338         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1339         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1340         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1341         /* nothing */
1342
1343 void VoteCommand_macro_help(entity caller, int argc)
1344 {
1345         string command_origin = GetCommandPrefix(caller);
1346
1347         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1348         {
1349                 print_to(caller, "\nVoting commands:\n");
1350                 #define VOTE_COMMAND(name, function, description, assignment) \
1351                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1352
1353                 VOTE_COMMANDS(0, caller, 0, "");
1354                 #undef VOTE_COMMAND
1355
1356                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1357                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1358                 print_available_commands_to(caller);
1359         }
1360         else  // usage for individual command
1361         {
1362                 #define VOTE_COMMAND(name, function, description, assignment) \
1363                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1364
1365                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1366                 #undef VOTE_COMMAND
1367
1368                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1369                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1370                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1371                 else if (argv(2) != "")
1372                         print_to(caller, "No documentation exists for this vote");
1373         }
1374 }
1375
1376 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1377 {
1378         #define VOTE_COMMAND(name, function, description, assignment) \
1379                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1380
1381         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1382         #undef VOTE_COMMAND
1383
1384         return false;
1385 }
1386
1387
1388 // ======================================
1389 //  Main function handling vote commands
1390 // ======================================
1391
1392 void VoteCommand(int request, entity caller, int argc, string vote_command)
1393 {
1394         // Guide for working with argc arguments by example:
1395         // argc:   1    - 2      - 3     - 4
1396         // argv:   0    - 1      - 2     - 3
1397         // cmd     vote - master - login - password
1398
1399         switch (request)
1400         {
1401                 case CMD_REQUEST_COMMAND:
1402                 {
1403                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1404                 }
1405
1406                 default:
1407                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1408                 case CMD_REQUEST_USAGE:
1409                 {
1410                         VoteCommand_macro_help(caller, argc);
1411                         return;
1412                 }
1413         }
1414 }