qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/world.qh>
  29
  30 // =============================================
  31 //  Server side voting code, reworked by Samual
  32 //  Last updated: December 27th, 2011
  33 // =============================================
  34
  35 //  Nagger for players to know status of voting
  36 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  37 {
  38         int nags, i, f, b;
  39         entity e;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         nags = 0;
  53         if (readycount)
  54         {
  55                 nags |= BIT(0);
  56                 if (to.ready == 0) nags |= BIT(1);
  57         }
  58         if (vote_called)
  59         {
  60                 nags |= BIT(2);
  61                 if (to.vote_selection == 0) nags |= BIT(3);
  62         }
  63         if (warmup_stage) nags |= BIT(4);
  64
  65         if (sendflags & BIT(6)) nags |= BIT(6);
  66
  67         if (sendflags & BIT(7)) nags |= BIT(7);
  68
  69         if (!(nags & 4))  // no vote called? send no string
  70                 nags &= ~(BIT(6) | BIT(7));
  71
  72         WriteByte(MSG_ENTITY, nags);
  73
  74         if (nags & BIT(6))
  75         {
  76                 WriteByte(MSG_ENTITY, vote_accept_count);
  77                 WriteByte(MSG_ENTITY, vote_reject_count);
  78                 WriteByte(MSG_ENTITY, vote_needed_overall);
  79                 WriteChar(MSG_ENTITY, to.vote_selection);
  80         }
  81
  82         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  83
  84         if (nags & 1)
  85         {
  86                 for (i = 1; i <= maxclients; i += 8)
  87                 {
  88                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  89                                 if (!IS_REAL_CLIENT(e) || e.ready)
  90                                         f |= b;
  91                         WriteByte(MSG_ENTITY, f);
  92                 }
  93         }
  94
  95         return true;
  96 }
  97
  98 void Nagger_Init()
  99 {
 100         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 101 }
 102
 103 void Nagger_VoteChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(7);
 106 }
 107
 108 void Nagger_VoteCountChanged()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(6);
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if (nagger) nagger.SendFlags |= BIT(0);
 116 }
 117
 118 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 119 string OriginalCallerName()
 120 {
 121         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 122         return vote_caller_name;
 123 }
 124
 125 // =======================
 126 //  Game logic for voting
 127 // =======================
 128
 129 void VoteReset()
 130 {
 131         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 132
 133         if (vote_called)
 134         {
 135                 strfree(vote_called_command);
 136                 strfree(vote_called_display);
 137                 strfree(vote_caller_name);
 138         }
 139
 140         vote_called = VOTE_NULL;
 141         vote_caller = NULL;
 142         vote_endtime = 0;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn, bool is_fake_round_start)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346
 347                 if (!is_fake_round_start)
 348                 {
 349                         Score_ClearAll();
 350                         PlayerStats_GameReport_Reset_All();
 351                 }
 352
 353                 if (round_handler_IsActive())
 354                         round_handler_Reset(game_starttime);
 355         }
 356
 357         if (shuffleteams_on_reset_map)
 358         {
 359                 shuffleteams();
 360                 shuffleteams_on_reset_map = false;
 361         }
 362
 363         FOREACH_CLIENT(true, {
 364                 if (time <= game_starttime)
 365                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 366                 if (!IS_PLAYER(it))
 367                         continue;
 368                 if (STAT(FROZEN, it))
 369                         Unfreeze(it, false);
 370                 player_powerups_remove_all(it);
 371                 entity store = PS(it);
 372                 if (store)
 373                 {
 374                         Inventory_clear(store.inventory);
 375                         Inventory_update(store);
 376                 }
 377         });
 378
 379         MUTATOR_CALLHOOK(reset_map_global);
 380
 381         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 382         {
 383                 if(IS_CLIENT(it))
 384                         continue;
 385                 if (it.reset)
 386                 {
 387                         it.reset(it);
 388                         continue;
 389                 }
 390                 if (it.team_saved) it.team = it.team_saved;
 391                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 392         });
 393
 394         // Waypoints and assault start come LAST
 395         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 396                 if (it.reset2) it.reset2(it);
 397         });
 398
 399         // Moving the player reset code here since the player-reset depends
 400         // on spawnpoint entities which have to be reset first --blub
 401         if (dorespawn)
 402         {
 403                 if (!MUTATOR_CALLHOOK(reset_map_players))
 404                 {
 405                         FOREACH_CLIENT(IS_PLAYER(it),
 406                         {
 407                                 // PlayerScore_Clear(it);
 408                                 CS(it).killcount = 0;
 409                                 // stop the player from moving so that he stands still once he gets respawned
 410                                 it.velocity = '0 0 0';
 411                                 it.avelocity = '0 0 0';
 412                                 CS(it).movement = '0 0 0';
 413                                 PutClientInServer(it);
 414                         });
 415                 }
 416         }
 417 }
 418
 419 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 420 void ReadyRestart_think(entity this)
 421 {
 422         reset_map(true, false);
 423         delete(this);
 424 }
 425
 426 // Forces a restart of the game without actually reloading the map // this is a mess...
 427 void ReadyRestart_force(bool is_fake_round_start)
 428 {
 429         if (time <= game_starttime && game_stopped)
 430                 return;
 431         if (!is_fake_round_start)
 432                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 433
 434         VoteReset();
 435
 436         // clear overtime, we have to decrease timelimit to its original value again.
 437         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 438                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 439         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 440
 441         if(warmup_stage)
 442                 game_starttime = time; // Warmup: No countdown in warmup
 443         else if (autocvar_g_campaign)
 444                 game_starttime = time + 3;
 445         else
 446                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 447
 448         // clear player attributes
 449         FOREACH_CLIENT(IS_PLAYER(it), {
 450                 it.alivetime = 0;
 451                 CS(it).killcount = 0;
 452         });
 453
 454         // if we're ending the warmup stage call the corresponding hook
 455         if(!is_fake_round_start && !warmup_stage)
 456                 localcmd("\nsv_hook_warmupend\n");
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465                 lockteams = !warmup_stage;
 466
 467         // initiate the restart-countdown-announcer entity
 468         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 469         {
 470                 entity restart_timer = new_pure(restart_timer);
 471                 setthink(restart_timer, ReadyRestart_think);
 472                 restart_timer.nextthink = game_starttime;
 473         }
 474
 475         // after a restart every players number of allowed timeouts gets reset, too
 476         if (autocvar_sv_timeout)
 477         {
 478                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 479         }
 480
 481         if (!sv_ready_restart_after_countdown || warmup_stage)
 482                 reset_map(true, is_fake_round_start);
 483
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart(bool forceWarmupEnd)
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing)
 490         {
 491                 // NOTE: ReadyRestart support is mandatory in campaign
 492                 if (autocvar_g_campaign)
 493                         error("ReadyRestart must be supported in campaign mode!");
 494                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 495         }
 496         else localcmd("\nsv_hook_readyrestart\n");
 497
 498         if(forceWarmupEnd || autocvar_g_campaign)
 499                 warmup_stage = 0; // forcefully end warmup and go to match stage
 500         else
 501                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 502
 503         ReadyRestart_force(false);
 504 }
 505
 506 /* Count the players who are ready and determine whether or not to restart the match when:
 507  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 508  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 509  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 510  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 511 void ReadyCount()
 512 {
 513         // cannot reset the game while a timeout is active or pending
 514         if (timeout_status) return;
 515
 516         float ready_needed_factor, ready_needed_count;
 517         float t_players = 0;
 518         readycount = 0;
 519
 520         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 521                 ++t_players;
 522                 if (it.ready) ++readycount;
 523         });
 524
 525         Nagger_ReadyCounted();
 526
 527         if (t_players < map_minplayers) // map_minplayers will only be set if g_warmup -1 at worldspawn
 528         {
 529                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 530                 {
 531                         warmup_stage = -1; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 532                         game_starttime = time;
 533                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, map_minplayers);
 534                 }
 535                 if (warmup_limit > 0)
 536                         warmup_limit = -1;
 537                 return; // don't ReadyRestart if players are ready but too few
 538         }
 539         else if (map_minplayers && warmup_limit <= 0)
 540         {
 541                 // there's enough players now but we're still in infinite warmup
 542                 warmup_limit = cvar("g_warmup_limit");
 543                 if (warmup_limit == 0)
 544                         warmup_limit = autocvar_timelimit * 60;
 545                 if (warmup_limit > 0)
 546                         game_starttime = time;
 547                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 548                 // warmup continues until enough players AND enough RUPs (no time limit)
 549         }
 550
 551         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 1);
 552         ready_needed_count = ceil(t_players * ready_needed_factor);
 553
 554         if (readycount >= ready_needed_count) ReadyRestart(true);
 555 }
 556
 557
 558 // ======================================
 559 //  Supporting functions for VoteCommand
 560 // ======================================
 561
 562 bool Votecommand_check_assignment(entity caller, float assignment)
 563 {
 564         bool from_server = (!caller);
 565
 566         if ((assignment == VC_ASGNMNT_BOTH)
 567             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 568             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 569
 570         return false;
 571 }
 572
 573 string VoteCommand_extractcommand(string input, float startpos, int argc)
 574 {
 575         string output;
 576
 577         if ((argc - 1) < startpos) output = "";
 578         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 579
 580         return output;
 581 }
 582
 583 bool VoteCommand_checknasty(string vote_command)
 584 {
 585         return !((strstrofs(vote_command, ";", 0) >= 0)
 586             || (strstrofs(vote_command, "\n", 0) >= 0)
 587             || (strstrofs(vote_command, "\r", 0) >= 0)
 588             || (strstrofs(vote_command, "$", 0) >= 0));
 589 }
 590
 591 // NOTE: requires input to be surrounded by spaces
 592 string VoteCommand_checkreplacements(string input)
 593 {
 594         // add a space around the input so the start and end of the list is captured
 595         string output = strcat(" ", input, " ");
 596         // allow gotomap replacements
 597         output = strreplace(" map ", " gotomap ", output);
 598         output = strreplace(" chmap ", " gotomap ", output);
 599         return output;
 600 }
 601
 602 bool VoteCommand_checkinlist(string vote_command, string list)
 603 {
 604         if (vote_command == "" || list == "")
 605                 return false;
 606
 607         string l = VoteCommand_checkreplacements(list);
 608         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 609 }
 610
 611 string ValidateMap(string validated_map, entity caller)
 612 {
 613         validated_map = MapInfo_FixName(validated_map);
 614
 615         if (!validated_map)
 616         {
 617                 print_to(caller, "This map is not available on this server.");
 618                 return string_null;
 619         }
 620
 621         if (!autocvar_sv_vote_override_mostrecent && caller)
 622         {
 623                 if (Map_IsRecent(validated_map))
 624                 {
 625                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 626                         return string_null;
 627                 }
 628         }
 629
 630         if (!MapInfo_CheckMap(validated_map))
 631         {
 632                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 633                 return string_null;
 634         }
 635
 636         return validated_map;
 637 }
 638
 639 float VoteCommand_checkargs(float startpos, int argc)
 640 {
 641         float p, q, check, minargs;
 642         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 643         string cmdrestriction = "";  // No we don't.
 644         string charlist, arg;
 645         float checkmate;
 646
 647         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 648                 cmdrestriction = cvar_string(cvarname);
 649         else
 650                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 651
 652         if (cmdrestriction == "") return true;
 653
 654         ++startpos;  // skip command name
 655
 656         // check minimum arg count
 657
 658         // 0 args: argc == startpos
 659         // 1 args: argc == startpos + 1
 660         // ...
 661
 662         minargs = stof(cmdrestriction);
 663         if (argc - startpos < minargs) return false;
 664
 665         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 666
 667         for ( ; ; )
 668         {
 669                 // we know that at any time, startpos <= argc - minargs
 670                 // so this means: argc-minargs >= startpos >= argc, thus
 671                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 672                 // have been seen already
 673
 674                 if (startpos >= argc) // all args checked? GOOD
 675                         break;
 676
 677                 if (p < 0)            // no more args? FAIL
 678                 {
 679                         // exception: exactly minargs left, this one included
 680                         if (argc - startpos == minargs) break;
 681
 682                         // otherwise fail
 683                         return false;
 684                 }
 685
 686                 // cut to next semicolon
 687                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 688                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 689                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 690
 691                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 692                 // charlist = strreplace("^^", ";", charlist);
 693
 694                 if (charlist != "")
 695                 {
 696                         // verify the arg only contains allowed chars
 697                         arg = argv(startpos);
 698                         checkmate = strlen(arg);
 699                         for (check = 0; check < checkmate; ++check)
 700                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 701                         // not allowed character
 702                         // all characters are allowed. FINE.
 703                 }
 704
 705                 ++startpos;
 706                 --minargs;
 707                 p = q;
 708         }
 709
 710         return true;
 711 }
 712
 713 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 714 {
 715         string first_command = argv(startpos);
 716         int missing_chars = argv_start_index(startpos);
 717
 718         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 719                 return 0;
 720
 721         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 722
 723         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 724
 725         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 726         {
 727                 case MUT_VOTEPARSE_CONTINUE: { break; }
 728                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 729                 case MUT_VOTEPARSE_INVALID: { return -1; }
 730                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 731         }
 732
 733         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 734         {
 735                 case "kick":
 736                 case "kickban":    // catch all kick/kickban commands
 737                 {
 738                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 739                         float accepted = VerifyClientEntity(victim, true, false);
 740
 741                         if (accepted > 0)
 742                         {
 743                                 string reason = "No reason provided";
 744                                 if(argc > next_token)
 745                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 746
 747                                 string command_arguments = reason;
 748                                 if (first_command == "kickban")
 749                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 750
 751                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 752                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 753                         }
 754                         else
 755                         {
 756                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 757                                 return 0;
 758                         }
 759
 760                         break;
 761                 }
 762
 763                 case "map":
 764                 case "chmap":
 765                 case "gotomap":  // re-direct all map selection commands to gotomap
 766                 {
 767                         vote_command = ValidateMap(argv(startpos + 1), caller);
 768                         if (!vote_command)  return -1;
 769                         vote_parsed_command = strcat("gotomap ", vote_command);
 770                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 771
 772                         break;
 773                 }
 774
 775                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 776                 // maybe fallback instead of aborting if map name is invalid?
 777                 case "nextmap":
 778                 {
 779                         vote_command = ValidateMap(argv(startpos + 1), caller);
 780                         if (!vote_command)  return -1;
 781                         vote_parsed_command = strcat("nextmap ", vote_command);
 782                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 783
 784                         break;
 785                 }
 786
 787                 case "timelimit": // include restrictions on the maximum votable time limit
 788                 {
 789                         float timelimit_vote = stof(argv(startpos + 1));
 790                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 791                         {
 792                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 793                                 return -1;
 794                         }
 795                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 796                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 797                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 798
 799                         break;
 800                 }
 801
 802                 case "restart":
 803                 {
 804                         // add a delay so that vote result can be seen and announcer can be heard
 805                         // if the vote is accepted
 806                         vote_parsed_command = strcat("defer 1 ", vote_command);
 807                         vote_parsed_display = strzone(strcat("^1", vote_command));
 808
 809                         break;
 810                 }
 811
 812                 case "allready":
 813                 {
 814                         if(!warmup_stage) {
 815                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 816                                 return -1;
 817                         }
 818
 819                         vote_parsed_command = vote_command;
 820                         vote_parsed_display = strzone(strcat("^1", vote_command));
 821                         break;
 822                 }
 823
 824                 default:
 825                 {
 826                         vote_parsed_command = vote_command;
 827                         vote_parsed_display = strzone(strcat("^1", vote_command));
 828
 829                         break;
 830                 }
 831         }
 832
 833         return 1;
 834 }
 835
 836
 837 // =======================
 838 //  Command Sub-Functions
 839 // =======================
 840
 841 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 842 {
 843         switch (request)
 844         {
 845                 case CMD_REQUEST_COMMAND:
 846                 {
 847                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 848                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 849                         {
 850                                 print_to(caller, "^1You have already voted.");
 851                         }
 852
 853                         else  // everything went okay, continue changing vote
 854                         {
 855                                 print_to(caller, "^1You abstained from your vote.");
 856                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 857                                 msg_entity = caller;
 858                                 if (!autocvar_sv_vote_singlecount)
 859                                         VoteCount(false);
 860                         }
 861
 862                         return;
 863                 }
 864
 865                 default:
 866                 case CMD_REQUEST_USAGE:
 867                 {
 868                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 869                         print_to(caller, "  No arguments required.");
 870                         return;
 871                 }
 872         }
 873 }
 874
 875 void print_available_commands_to(entity caller)
 876 {
 877         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 878 }
 879
 880 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 881 {
 882         switch (request)
 883         {
 884                 case CMD_REQUEST_COMMAND:
 885                 {
 886                         float tmp_playercount = 0;
 887                         int parse_error;
 888
 889                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 890
 891                         if (!autocvar_sv_vote_call && caller)
 892                         {
 893                                 print_to(caller, "^1Vote calling is not allowed.");
 894                         }
 895                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 896                         {
 897                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 898                         }
 899                         else if (vote_called)
 900                         {
 901                                 print_to(caller, "^1There is already a vote called.");
 902                         }
 903                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 904                         {
 905                                 print_to(caller, "^1Only players can call a vote.");
 906                         }
 907                         else if (caller && !IS_CLIENT(caller))
 908                         {
 909                                 print_to(caller, "^1Only connected clients can vote.");
 910                         }
 911                         else if (timeout_status && vote_command != "timein")
 912                         {
 913                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 914                         }
 915                         else if (caller && (time < caller.vote_waittime))
 916                         {
 917                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 918                         }
 919                         else if (!VoteCommand_checknasty(vote_command))
 920                         {
 921                                 print_to(caller, "^1Syntax error in command.");
 922                         }
 923                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 924                         {
 925                                 if(parse_error == 0)
 926                                 {
 927                                         if (vote_called_command == "")
 928                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 929                                         else
 930                                                 print_to(caller, "^1This command is not acceptable or not available.");
 931                                 }
 932                         }
 933                         else  // everything went okay, continue with calling the vote
 934                         {
 935                                 vote_caller = caller;  // remember who called the vote
 936                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 937                                 vote_called = VOTE_NORMAL;
 938                                 vote_called_command = strzone(vote_parsed_command);
 939                                 vote_called_display = strzone(vote_parsed_display);
 940                                 vote_endtime = time + autocvar_sv_vote_timeout;
 941
 942                                 if (caller)
 943                                 {
 944                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 945                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 946                                         msg_entity = caller;
 947                                 }
 948
 949                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 950
 951                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 952                                 if (autocvar_sv_eventlog)
 953                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 954                                 Nagger_VoteChanged();
 955                                 VoteCount(true);  // needed if you are the only one
 956
 957                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 958                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 959                         }
 960
 961                         return;
 962                 }
 963
 964                 default:
 965                 case CMD_REQUEST_USAGE:
 966                 {
 967                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 968                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 969                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 970                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 971                         print_available_commands_to(caller);
 972                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 973                         return;
 974                 }
 975         }
 976 }
 977
 978 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 979 {
 980         switch (request)
 981         {
 982                 case CMD_REQUEST_COMMAND:
 983                 {
 984                         if (autocvar_sv_vote_master)
 985                         {
 986                                 switch (strtolower(argv(2)))
 987                                 {
 988                                         case "do":
 989                                         {
 990                                                 int parse_error;
 991                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 992
 993                                                 if (!caller.vote_master)
 994                                                         print_to(caller, "^1You do not have vote master privileges.");
 995                                                 else if (!VoteCommand_checknasty(vote_command))
 996                                                 {
 997                                                         print_to(caller, "^1Syntax error in command.");
 998                                                 }
 999                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1000                                                 {
1001                                                         if(parse_error == 0)
1002                                                         {
1003                                                                 if (vote_called_command == "")
1004                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1005                                                                 else
1006                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1007                                                         }
1008                                                 }
1009                                                 else  // everything went okay, proceed with command
1010                                                 {
1011                                                         localcmd(strcat(vote_parsed_command, "\n"));
1012                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1013                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1014                                                         if (autocvar_sv_eventlog)
1015                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1016                                                 }
1017
1018                                                 return;
1019                                         }
1020
1021                                         case "login":
1022                                         {
1023                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1024                                                 else if (caller.vote_master)
1025                                                 {
1026                                                         print_to(caller, "^1You are already logged in as vote master.");
1027                                                 }
1028                                                 else if (autocvar_sv_vote_master_password != argv(3))
1029                                                 {
1030                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1031                                                 }
1032                                                 else  // everything went okay, proceed with giving this player master privilages
1033                                                 {
1034                                                         caller.vote_master = true;
1035                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1036                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1037                                                         if (autocvar_sv_eventlog)
1038                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1039                                                 }
1040
1041                                                 return;
1042                                         }
1043
1044                                         default:  // calling a vote for master
1045                                         {
1046                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1047                                                 else if (vote_called)
1048                                                 {
1049                                                         print_to(caller, "^1There is already a vote called.");
1050                                                 }
1051                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1052                                                 {
1053                                                         print_to(caller, "^1Only players can call a vote.");
1054                                                 }
1055                                                 else if (timeout_status)
1056                                                 {
1057                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1058                                                 }
1059                                                 else  // everything went okay, continue with creating vote
1060                                                 {
1061                                                         vote_caller = caller;
1062                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1063                                                         vote_called = VOTE_MASTER;
1064                                                         vote_called_command = strzone("XXX");
1065                                                         vote_called_display = strzone("^3master");
1066                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1067
1068                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1069                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1070
1071                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1072                                                         if (autocvar_sv_eventlog)
1073                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1074                                                         Nagger_VoteChanged();
1075                                                         VoteCount(true);  // needed if you are the only one
1076                                                 }
1077
1078                                                 return;
1079                                         }
1080                                 }
1081                         }
1082                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1083
1084                         return;
1085                 }
1086
1087                 default:
1088                 case CMD_REQUEST_USAGE:
1089                 {
1090                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1091                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1092                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1093                         return;
1094                 }
1095         }
1096 }
1097
1098 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1099 {
1100         switch (request)
1101         {
1102                 case CMD_REQUEST_COMMAND:
1103                 {
1104                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1105                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1106                         {
1107                                 print_to(caller, "^1You have already voted.");
1108                         }
1109                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1110                         {
1111                                 VoteStop(caller);
1112                         }
1113
1114                         else  // everything went okay, continue changing vote
1115                         {
1116                                 print_to(caller, "^1You rejected the vote.");
1117                                 caller.vote_selection = VOTE_SELECT_REJECT;
1118                                 msg_entity = caller;
1119                                 if (!autocvar_sv_vote_singlecount)
1120                                         VoteCount(false);
1121                         }
1122
1123                         return;
1124                 }
1125
1126                 default:
1127                 case CMD_REQUEST_USAGE:
1128                 {
1129                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1130                         print_to(caller, "  No arguments required.");
1131                         return;
1132                 }
1133         }
1134 }
1135
1136 void VoteCommand_status(int request, entity caller)  // BOTH
1137 {
1138         switch (request)
1139         {
1140                 case CMD_REQUEST_COMMAND:
1141                 {
1142                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1143                         else print_to(caller, "^1No vote called.");
1144
1145                         return;
1146                 }
1147
1148                 default:
1149                 case CMD_REQUEST_USAGE:
1150                 {
1151                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1152                         print_to(caller, "  No arguments required.");
1153                         return;
1154                 }
1155         }
1156 }
1157
1158 void VoteCommand_stop(int request, entity caller)  // BOTH
1159 {
1160         switch (request)
1161         {
1162                 case CMD_REQUEST_COMMAND:
1163                 {
1164                         if (!vote_called)   print_to(caller, "^1No vote called.");
1165                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1166                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1167                         return;
1168                 }
1169
1170                 default:
1171                 case CMD_REQUEST_USAGE:
1172                 {
1173                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1174                         print_to(caller, "  No arguments required.");
1175                         return;
1176                 }
1177         }
1178 }
1179
1180 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1181 {
1182         switch (request)
1183         {
1184                 case CMD_REQUEST_COMMAND:
1185                 {
1186                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1187                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1188                         {
1189                                 print_to(caller, "^1You have already voted.");
1190                         }
1191                         else  // everything went okay, continue changing vote
1192                         {
1193                                 print_to(caller, "^1You accepted the vote.");
1194                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1195                                 msg_entity = caller;
1196                                 if (!autocvar_sv_vote_singlecount)
1197                                         VoteCount(false);
1198                         }
1199
1200                         return;
1201                 }
1202
1203                 default:
1204                 case CMD_REQUEST_USAGE:
1205                 {
1206                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1207                         print_to(caller, "  No arguments required.");
1208                         return;
1209                 }
1210         }
1211 }
1212
1213 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1214 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1215 void VoteCommand_(int request)
1216 {
1217     switch(request)
1218     {
1219         case CMD_REQUEST_COMMAND:
1220         {
1221
1222             return;
1223         }
1224
1225         default:
1226         case CMD_REQUEST_USAGE:
1227         {
1228             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1229             print_to(caller, "  No arguments required.");
1230             return;
1231         }
1232     }
1233 }
1234 */
1235
1236
1237 // ================================
1238 //  Macro system for vote commands
1239 // ================================
1240
1241 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1242 #define VOTE_COMMANDS(request, caller, arguments, command) \
1243         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1244         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1245         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1246         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1247         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1248         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1249         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1250         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1251         /* nothing */
1252
1253 void VoteCommand_macro_help(entity caller, int argc)
1254 {
1255         string command_origin = GetCommandPrefix(caller);
1256
1257         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1258         {
1259                 print_to(caller, "\nVoting commands:\n");
1260                 #define VOTE_COMMAND(name, function, description, assignment) \
1261                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1262
1263                 VOTE_COMMANDS(0, caller, 0, "");
1264                 #undef VOTE_COMMAND
1265
1266                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1267                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1268                 print_available_commands_to(caller);
1269         }
1270         else  // usage for individual command
1271         {
1272                 #define VOTE_COMMAND(name, function, description, assignment) \
1273                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1274
1275                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1276                 #undef VOTE_COMMAND
1277
1278                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1279                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1280                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1281                 else if (argv(2) != "")
1282                         print_to(caller, "No documentation exists for this vote");
1283         }
1284 }
1285
1286 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1287 {
1288         #define VOTE_COMMAND(name, function, description, assignment) \
1289                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1290
1291         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1292         #undef VOTE_COMMAND
1293
1294         return false;
1295 }
1296
1297
1298 // ======================================
1299 //  Main function handling vote commands
1300 // ======================================
1301
1302 void VoteCommand(int request, entity caller, int argc, string vote_command)
1303 {
1304         // Guide for working with argc arguments by example:
1305         // argc:   1    - 2      - 3     - 4
1306         // argv:   0    - 1      - 2     - 3
1307         // cmd     vote - master - login - password
1308
1309         switch (request)
1310         {
1311                 case CMD_REQUEST_COMMAND:
1312                 {
1313                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1314                 }
1315
1316                 default:
1317                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1318                 case CMD_REQUEST_USAGE:
1319                 {
1320                         VoteCommand_macro_help(caller, argc);
1321                         return;
1322                 }
1323         }
1324 }