qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "antilag.qh"
   3 #include "command/common.qh"
   4 #include "constants.qh"
   5 #include "g_hook.qh"
   6 #include "ipban.qh"
   7 #include "mutators/all.qh"
   8 #include "t_items.qh"
   9 #include "weapons/accuracy.qh"
  10 #include "weapons/csqcprojectile.qh"
  11 #include "weapons/selection.qh"
  12 #include "../common/command/generic.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/notifications.qh"
  17 #include "../common/playerstats.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/triggers/subs.qh"
  20 #include "../common/util.qh"
  21 #include "../common/turrets/sv_turrets.qh"
  22 #include "../common/weapons/all.qh"
  23 #include "../common/vehicles/sv_vehicles.qh"
  24 #include "../common/vehicles/vehicle.qh"
  25 #include "../common/items/all.qc"
  26 #include "../lib/csqcmodel/sv_model.qh"
  27 #include "../lib/warpzone/anglestransform.qh"
  28 #include "../lib/warpzone/server.qh"
  29
  30 void crosshair_trace(entity pl)
  31 {
  32         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  33 }
  34 void crosshair_trace_plusvisibletriggers(entity pl)
  35 {
  36         entity first;
  37         entity e;
  38         first = findchainfloat(solid, SOLID_TRIGGER);
  39
  40         for (e = first; e; e = e.chain)
  41                 if (e.model != "")
  42                         e.solid = SOLID_BSP;
  43
  44         crosshair_trace(pl);
  45
  46         for (e = first; e; e = e.chain)
  47                 e.solid = SOLID_TRIGGER;
  48 }
  49 void WarpZone_crosshair_trace(entity pl)
  50 {
  51         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  52 }
  53
  54
  55 string admin_name()
  56 {
  57         if(autocvar_sv_adminnick != "")
  58                 return autocvar_sv_adminnick;
  59         else
  60                 return "SERVER ADMIN";
  61 }
  62
  63
  64 void GameLogEcho(string s)
  65 {
  66     string fn;
  67     int matches;
  68
  69     if (autocvar_sv_eventlog_files)
  70     {
  71         if (!logfile_open)
  72         {
  73             logfile_open = true;
  74             matches = autocvar_sv_eventlog_files_counter + 1;
  75             cvar_set("sv_eventlog_files_counter", itos(matches));
  76             fn = ftos(matches);
  77             if (strlen(fn) < 8)
  78                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
  79             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
  80             logfile = fopen(fn, FILE_APPEND);
  81             fputs(logfile, ":logversion:3\n");
  82         }
  83         if (logfile >= 0)
  84         {
  85             if (autocvar_sv_eventlog_files_timestamps)
  86                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
  87             else
  88                 fputs(logfile, strcat(s, "\n"));
  89         }
  90     }
  91     if (autocvar_sv_eventlog_console)
  92     {
  93         LOG_INFO(s, "\n");
  94     }
  95 }
  96
  97 void GameLogInit()
  98 {
  99     logfile_open = 0;
 100     // will be opened later
 101 }
 102
 103 void GameLogClose()
 104 {
 105     if (logfile_open && logfile >= 0)
 106     {
 107         fclose(logfile);
 108         logfile = -1;
 109     }
 110 }
 111
 112 entity findnearest(vector point, .string field, string value, vector axismod)
 113 {
 114     entity localhead;
 115     float i;
 116     float j;
 117     float len;
 118     vector dist;
 119
 120     float num_nearest;
 121     num_nearest = 0;
 122
 123     localhead = find(world, field, value);
 124     while (localhead)
 125     {
 126         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 127             dist = localhead.oldorigin;
 128         else
 129             dist = localhead.origin;
 130         dist = dist - point;
 131         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 132         len = vlen(dist);
 133
 134         for (i = 0; i < num_nearest; ++i)
 135         {
 136             if (len < nearest_length[i])
 137                 break;
 138         }
 139
 140         // now i tells us where to insert at
 141         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 142         if (i < NUM_NEAREST_ENTITIES)
 143         {
 144             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 145             {
 146                 nearest_length[j + 1] = nearest_length[j];
 147                 nearest_entity[j + 1] = nearest_entity[j];
 148             }
 149             nearest_length[i] = len;
 150             nearest_entity[i] = localhead;
 151             if (num_nearest < NUM_NEAREST_ENTITIES)
 152                 num_nearest = num_nearest + 1;
 153         }
 154
 155         localhead = find(localhead, field, value);
 156     }
 157
 158     // now use the first one from our list that we can see
 159     for (i = 0; i < num_nearest; ++i)
 160     {
 161         traceline(point, nearest_entity[i].origin, true, world);
 162         if (trace_fraction == 1)
 163         {
 164             if (i != 0)
 165             {
 166                 LOG_TRACE("Nearest point (");
 167                 LOG_TRACE(nearest_entity[0].netname);
 168                 LOG_TRACE(") is not visible, using a visible one.\n");
 169             }
 170             return nearest_entity[i];
 171         }
 172     }
 173
 174     if (num_nearest == 0)
 175         return world;
 176
 177     LOG_TRACE("Not seeing any location point, using nearest as fallback.\n");
 178     /* DEBUGGING CODE:
 179     dprint("Candidates were: ");
 180     for(j = 0; j < num_nearest; ++j)
 181     {
 182         if(j != 0)
 183                 dprint(", ");
 184         dprint(nearest_entity[j].netname);
 185     }
 186     dprint("\n");
 187     */
 188
 189     return nearest_entity[0];
 190 }
 191
 192 string NearestLocation(vector p)
 193 {
 194     entity loc;
 195     string ret;
 196     ret = "somewhere";
 197     loc = findnearest(p, classname, "target_location", '1 1 1');
 198     if (loc)
 199     {
 200         ret = loc.message;
 201     }
 202     else
 203     {
 204         loc = findnearest(p, target, "###item###", '1 1 4');
 205         if (loc)
 206             ret = loc.netname;
 207     }
 208     return ret;
 209 }
 210
 211 string formatmessage(string msg)
 212 {SELFPARAM();
 213         float p, p1, p2;
 214         float n;
 215         vector cursor;
 216         entity cursor_ent;
 217         string escape;
 218         string replacement;
 219         string ammoitems;
 220         p = 0;
 221         n = 7;
 222
 223         ammoitems = "batteries";
 224         if(self.items & ITEM_Plasma.m_itemid) ammoitems = ITEM_Plasma.m_name;
 225         if(self.items & ITEM_Cells.m_itemid) ammoitems = ITEM_Cells.m_name;
 226         if(self.items & ITEM_Rockets.m_itemid) ammoitems = ITEM_Rockets.m_name;
 227         if(self.items & ITEM_Shells.m_itemid) ammoitems = ITEM_Shells.m_name;
 228
 229         WarpZone_crosshair_trace(self);
 230         cursor = trace_endpos;
 231         cursor_ent = trace_ent;
 232
 233         while (1) {
 234                 if (n < 1)
 235                         break; // too many replacements
 236
 237                 n = n - 1;
 238                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 239                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 240
 241                 if (p1 < 0)
 242                         p1 = p2;
 243
 244                 if (p2 < 0)
 245                         p2 = p1;
 246
 247                 p = min(p1, p2);
 248
 249                 if (p < 0)
 250                         break;
 251
 252                 replacement = substring(msg, p, 2);
 253                 escape = substring(msg, p + 1, 1);
 254
 255                 switch(escape)
 256                 {
 257                         case "%": replacement = "%"; break;
 258                         case "\\":replacement = "\\"; break;
 259                         case "n": replacement = "\n"; break;
 260                         case "a": replacement = ftos(floor(self.armorvalue)); break;
 261                         case "h": replacement = ftos(floor(self.health)); break;
 262                         case "l": replacement = NearestLocation(self.origin); break;
 263                         case "y": replacement = NearestLocation(cursor); break;
 264                         case "d": replacement = NearestLocation(self.death_origin); break;
 265                         case "w": replacement = WEP_NAME(((!self.weapon) ? (!self.switchweapon ? self.cnt : self.switchweapon) : self.weapon)); break;
 266                         case "W": replacement = ammoitems; break;
 267                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 268                         case "s": replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1')); break;
 269                         case "S": replacement = ftos(vlen(self.velocity)); break;
 270                         case "t": replacement = seconds_tostring(ceil(max(0, autocvar_timelimit * 60 + game_starttime - time))); break;
 271                         case "T": replacement = seconds_tostring(floor(time - game_starttime)); break;
 272                         default:
 273                         {
 274                                 MUTATOR_CALLHOOK(FormatMessage, escape, replacement, msg);
 275                                 escape = format_escape;
 276                                 replacement = format_replacement;
 277                                 break;
 278                         }
 279                 }
 280
 281                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 282                 p = p + strlen(replacement);
 283         }
 284         return msg;
 285 }
 286
 287 /*
 288 =============
 289 GetCvars
 290 =============
 291 Called with:
 292   0:  sends the request
 293   >0: receives a cvar from name=argv(f) value=argv(f+1)
 294 */
 295 void GetCvars_handleString(string thisname, float f, .string field, string name)
 296 {SELFPARAM();
 297         if (f < 0)
 298         {
 299                 if (self.(field))
 300                         strunzone(self.(field));
 301                 self.(field) = string_null;
 302         }
 303         else if (f > 0)
 304         {
 305                 if (thisname == name)
 306                 {
 307                         if (self.(field))
 308                                 strunzone(self.(field));
 309                         self.(field) = strzone(argv(f + 1));
 310                 }
 311         }
 312         else
 313                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 314 }
 315 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 316 {SELFPARAM();
 317         GetCvars_handleString(thisname, f, field, name);
 318         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 319                 if (thisname == name)
 320                 {
 321                         string s = func(strcat1(self.(field)));
 322                         if (s != self.(field))
 323                         {
 324                                 strunzone(self.(field));
 325                                 self.(field) = strzone(s);
 326                         }
 327                 }
 328 }
 329 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 330 {SELFPARAM();
 331         if (f < 0)
 332         {
 333         }
 334         else if (f > 0)
 335         {
 336                 if (thisname == name)
 337                         self.(field) = stof(argv(f + 1));
 338         }
 339         else
 340                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 341 }
 342 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 343 {SELFPARAM();
 344         if (f < 0)
 345         {
 346         }
 347         else if (f > 0)
 348         {
 349                 if (thisname == name)
 350                 {
 351                         if (!self.(field))
 352                         {
 353                                 self.(field) = stof(argv(f + 1));
 354                                 if (!self.(field))
 355                                         self.(field) = -1;
 356                         }
 357                 }
 358         }
 359         else
 360         {
 361                 if (!self.(field))
 362                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 363         }
 364 }
 365 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 366 {SELFPARAM();
 367         string o;
 368         o = W_FixWeaponOrder_ForceComplete(wo);
 369         if(self.weaponorder_byimpulse)
 370         {
 371                 strunzone(self.weaponorder_byimpulse);
 372                 self.weaponorder_byimpulse = string_null;
 373         }
 374         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 375         return o;
 376 }
 377 void GetCvars(float f)
 378 {SELFPARAM();
 379         string s = string_null;
 380
 381         if (f > 0)
 382                 s = strcat1(argv(f));
 383
 384         get_cvars_f = f;
 385         get_cvars_s = s;
 386         MUTATOR_CALLHOOK(GetCvars);
 387
 388         Notification_GetCvars();
 389
 390         ReplicateVars(this, s, f);
 391
 392         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 393         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 394         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 395         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 396         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 397         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 398         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 399         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 400         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 401         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 402         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 403         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 404         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 405         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 406         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 407         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 408         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 409         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 410         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 411         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 412         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 413         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 414         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 415
 416         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 417         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 418         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 419         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 420         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 421
 422         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 423         if (f > 0)
 424         {
 425                 if (s == "cl_weaponpriority")
 426                         self.switchweapon = w_getbestweapon(self);
 427                 if (s == "cl_allow_uidtracking")
 428                         PlayerStats_GameReport_AddPlayer(self);
 429         }
 430 }
 431
 432 // decolorizes and team colors the player name when needed
 433 string playername(entity p)
 434 {
 435     string t;
 436     if (teamplay && !intermission_running && IS_PLAYER(p))
 437     {
 438         t = Team_ColorCode(p.team);
 439         return strcat(t, strdecolorize(p.netname));
 440     }
 441     else
 442         return p.netname;
 443 }
 444
 445 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 446 {
 447         int i = weaponinfo.weapon;
 448         int d = 0;
 449         bool allow_mutatorblocked = false;
 450
 451         if(!i)
 452                 return 0;
 453
 454         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
 455         d = ret_float;
 456         allguns = want_allguns;
 457         allow_mutatorblocked = false;
 458
 459         if(allguns)
 460         {
 461                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 462                         d = true;
 463                 else
 464                         d = false;
 465         }
 466         else if(!mutator_returnvalue)
 467                 d = !(!weaponinfo.weaponstart);
 468
 469         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 470                 d = 0;
 471
 472         float t = weaponinfo.weaponstartoverride;
 473
 474         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 475
 476         // bit order in t:
 477         // 1: want or not
 478         // 2: is default?
 479         // 4: is set by default?
 480         if(t < 0)
 481                 t = 4 | (3 * d);
 482         else
 483                 t |= (2 * d);
 484
 485         return t;
 486 }
 487
 488 void readplayerstartcvars()
 489 {
 490         entity e;
 491         float i, j, t;
 492         string s;
 493
 494         // initialize starting values for players
 495         start_weapons = '0 0 0';
 496         start_weapons_default = '0 0 0';
 497         start_weapons_defaultmask = '0 0 0';
 498         start_items = 0;
 499         start_ammo_shells = 0;
 500         start_ammo_nails = 0;
 501         start_ammo_rockets = 0;
 502         start_ammo_cells = 0;
 503         start_ammo_plasma = 0;
 504         start_health = cvar("g_balance_health_start");
 505         start_armorvalue = cvar("g_balance_armor_start");
 506
 507         g_weaponarena = 0;
 508         g_weaponarena_weapons = '0 0 0';
 509
 510         s = cvar_string("g_weaponarena");
 511
 512         MUTATOR_CALLHOOK(SetWeaponArena, s);
 513         s = ret_string;
 514
 515         if (s == "0" || s == "")
 516         {
 517                 // no arena
 518         }
 519         else if (s == "off")
 520         {
 521                 // forcibly turn off weaponarena
 522         }
 523         else if (s == "all" || s == "1")
 524         {
 525                 g_weaponarena = 1;
 526                 g_weaponarena_list = "All Weapons";
 527                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 528                 {
 529                         e = get_weaponinfo(j);
 530                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 531                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 532                 }
 533         }
 534         else if (s == "most")
 535         {
 536                 g_weaponarena = 1;
 537                 g_weaponarena_list = "Most Weapons";
 538                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 539                 {
 540                         e = get_weaponinfo(j);
 541                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 542                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 543                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 544                 }
 545         }
 546         else if (s == "none")
 547         {
 548                 g_weaponarena = 1;
 549                 g_weaponarena_list = "No Weapons";
 550         }
 551         else
 552         {
 553                 g_weaponarena = 1;
 554                 t = tokenize_console(s);
 555                 g_weaponarena_list = "";
 556                 for (i = 0; i < t; ++i)
 557                 {
 558                         s = argv(i);
 559                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 560                         {
 561                                 e = get_weaponinfo(j);
 562                                 if (e.netname == s)
 563                                 {
 564                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 565                                         g_weaponarena_list = strcat(g_weaponarena_list, e.m_name, " & ");
 566                                         break;
 567                                 }
 568                         }
 569                         if (j > WEP_LAST)
 570                         {
 571                                 LOG_INFO("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 572                         }
 573                 }
 574                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 575         }
 576
 577         if(g_weaponarena)
 578                 g_weaponarena_random = cvar("g_weaponarena_random");
 579         else
 580                 g_weaponarena_random = 0;
 581         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 582
 583         if (g_weaponarena)
 584         {
 585                 g_weapon_stay = 0; // incompatible
 586                 start_weapons = g_weaponarena_weapons;
 587                 start_items |= IT_UNLIMITED_AMMO;
 588         }
 589         else
 590         {
 591                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 592                 {
 593                         e = get_weaponinfo(i);
 594                         int w = want_weapon(e, false);
 595                         if(w & 1)
 596                                 start_weapons |= WepSet_FromWeapon(i);
 597                         if(w & 2)
 598                                 start_weapons_default |= WepSet_FromWeapon(i);
 599                         if(w & 4)
 600                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 601                 }
 602         }
 603
 604         if(!cvar("g_use_ammunition"))
 605                 start_items |= IT_UNLIMITED_AMMO;
 606
 607         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 608         {
 609                 start_ammo_shells = 999;
 610                 start_ammo_nails = 999;
 611                 start_ammo_rockets = 999;
 612                 start_ammo_cells = 999;
 613                 start_ammo_plasma = 999;
 614                 start_ammo_fuel = 999;
 615         }
 616         else
 617         {
 618                 start_ammo_shells = cvar("g_start_ammo_shells");
 619                 start_ammo_nails = cvar("g_start_ammo_nails");
 620                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 621                 start_ammo_cells = cvar("g_start_ammo_cells");
 622                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 623                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 624         }
 625
 626         if (warmup_stage)
 627         {
 628                 warmup_start_ammo_shells = start_ammo_shells;
 629                 warmup_start_ammo_nails = start_ammo_nails;
 630                 warmup_start_ammo_rockets = start_ammo_rockets;
 631                 warmup_start_ammo_cells = start_ammo_cells;
 632                 warmup_start_ammo_plasma = start_ammo_plasma;
 633                 warmup_start_ammo_fuel = start_ammo_fuel;
 634                 warmup_start_health = start_health;
 635                 warmup_start_armorvalue = start_armorvalue;
 636                 warmup_start_weapons = start_weapons;
 637                 warmup_start_weapons_default = start_weapons_default;
 638                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 639
 640                 if (!g_weaponarena && !g_ca && !g_freezetag)
 641                 {
 642                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 643                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 644                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 645                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 646                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 647                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 648                         warmup_start_health = cvar("g_warmup_start_health");
 649                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 650                         warmup_start_weapons = '0 0 0';
 651                         warmup_start_weapons_default = '0 0 0';
 652                         warmup_start_weapons_defaultmask = '0 0 0';
 653                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 654                         {
 655                                 e = get_weaponinfo(i);
 656                                 int w = want_weapon(e, g_warmup_allguns);
 657                                 if(w & 1)
 658                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 659                                 if(w & 2)
 660                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 661                                 if(w & 4)
 662                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 663                         }
 664                 }
 665         }
 666
 667         if (g_jetpack)
 668                 start_items |= ITEM_Jetpack.m_itemid;
 669
 670         MUTATOR_CALLHOOK(SetStartItems);
 671
 672         if (start_items & ITEM_Jetpack.m_itemid)
 673         {
 674                 start_items |= ITEM_JetpackRegen.m_itemid;
 675                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 676                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 677         }
 678
 679         WepSet precache_weapons = start_weapons;
 680         if (g_warmup_allguns != 1)
 681                 precache_weapons |= warmup_start_weapons;
 682         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 683         {
 684                 e = get_weaponinfo(i);
 685                 if(precache_weapons & WepSet_FromWeapon(i)) {
 686                         Weapon w = get_weaponinfo(i);
 687                         w.wr_init(w);
 688                 }
 689         }
 690
 691         start_ammo_shells = max(0, start_ammo_shells);
 692         start_ammo_nails = max(0, start_ammo_nails);
 693         start_ammo_rockets = max(0, start_ammo_rockets);
 694         start_ammo_cells = max(0, start_ammo_cells);
 695         start_ammo_plasma = max(0, start_ammo_plasma);
 696         start_ammo_fuel = max(0, start_ammo_fuel);
 697
 698         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 699         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 700         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 701         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 702         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 703         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 704 }
 705
 706 void PrecachePlayerSounds(string f);
 707 void precache_playermodel(string m)
 708 {
 709         float globhandle, i, n;
 710         string f;
 711
 712         if(substring(m, -9,5) == "_lod1")
 713                 return;
 714         if(substring(m, -9,5) == "_lod2")
 715                 return;
 716         precache_model(m);
 717         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 718         if(fexists(f))
 719                 precache_model(f);
 720         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 721         if(fexists(f))
 722                 precache_model(f);
 723
 724         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 725         if (globhandle < 0)
 726                 return;
 727         n = search_getsize(globhandle);
 728         for (i = 0; i < n; ++i)
 729         {
 730                 //print(search_getfilename(globhandle, i), "\n");
 731                 f = search_getfilename(globhandle, i);
 732                 PrecachePlayerSounds(f);
 733         }
 734         search_end(globhandle);
 735 }
 736 void precache_all_playermodels(string pattern)
 737 {
 738         float globhandle, i, n;
 739         string f;
 740
 741         globhandle = search_begin(pattern, true, false);
 742         if (globhandle < 0)
 743                 return;
 744         n = search_getsize(globhandle);
 745         for (i = 0; i < n; ++i)
 746         {
 747                 //print(search_getfilename(globhandle, i), "\n");
 748                 f = search_getfilename(globhandle, i);
 749                 precache_playermodel(f);
 750         }
 751         search_end(globhandle);
 752 }
 753
 754 void precache_playermodels(string s)
 755 {
 756         if(s != "")
 757         {
 758                 int n = tokenize_console(s);
 759                 precache_playermodel(argv(0));
 760
 761                 for (int i = 1; i < n; ++i)
 762                         precache_model(argv(i));
 763         }
 764 }
 765
 766 void precache()
 767 {SELFPARAM();
 768     // gamemode related things
 769
 770     // Precache all player models if desired
 771     if (autocvar_sv_precacheplayermodels)
 772     {
 773         PrecachePlayerSounds("sound/player/default.sounds");
 774         precache_all_playermodels("models/player/*.zym");
 775         precache_all_playermodels("models/player/*.dpm");
 776         precache_all_playermodels("models/player/*.md3");
 777         precache_all_playermodels("models/player/*.psk");
 778         precache_all_playermodels("models/player/*.iqm");
 779     }
 780
 781     if (autocvar_sv_defaultcharacter)
 782     {
 783                 precache_playermodels(autocvar_sv_defaultplayermodel_red);
 784                 precache_playermodels(autocvar_sv_defaultplayermodel_blue);
 785                 precache_playermodels(autocvar_sv_defaultplayermodel_yellow);
 786                 precache_playermodels(autocvar_sv_defaultplayermodel_pink);
 787                 precache_playermodels(autocvar_sv_defaultplayermodel);
 788     }
 789
 790 #if 0
 791     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
 792
 793     if (!self.noise && self.music) // quake 3 uses the music field
 794         self.noise = self.music;
 795
 796     // plays music for the level if there is any
 797     if (self.noise)
 798     {
 799         precache_sound (self.noise);
 800         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
 801     }
 802 #endif
 803 }
 804
 805
 806 void make_safe_for_remove(entity e)
 807 {
 808     if (e.initialize_entity)
 809     {
 810         entity ent, prev = world;
 811         for (ent = initialize_entity_first; ent; )
 812         {
 813             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 814             {
 815                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 816                 // skip it in linked list
 817                 if (prev)
 818                 {
 819                     prev.initialize_entity_next = ent.initialize_entity_next;
 820                     ent = prev.initialize_entity_next;
 821                 }
 822                 else
 823                 {
 824                     initialize_entity_first = ent.initialize_entity_next;
 825                     ent = initialize_entity_first;
 826                 }
 827             }
 828             else
 829             {
 830                 prev = ent;
 831                 ent = ent.initialize_entity_next;
 832             }
 833         }
 834     }
 835 }
 836
 837 void objerror(string s)
 838 {SELFPARAM();
 839     make_safe_for_remove(self);
 840     builtin_objerror(s);
 841 }
 842
 843 .float remove_except_protected_forbidden;
 844 void remove_except_protected(entity e)
 845 {
 846         if(e.remove_except_protected_forbidden)
 847                 error("not allowed to remove this at this point");
 848         builtin_remove(e);
 849 }
 850
 851 void remove_unsafely(entity e)
 852 {
 853     if(e.classname == "spike")
 854         error("Removing spikes is forbidden (crylink bug), please report");
 855     builtin_remove(e);
 856 }
 857
 858 void remove_safely(entity e)
 859 {
 860     make_safe_for_remove(e);
 861     builtin_remove(e);
 862 }
 863
 864 void InitializeEntity(entity e, void() func, float order)
 865 {
 866     entity prev, cur;
 867
 868     if (!e || e.initialize_entity)
 869     {
 870         // make a proxy initializer entity
 871         entity e_old = e;
 872         e = new(initialize_entity);
 873         e.enemy = e_old;
 874     }
 875
 876     e.initialize_entity = func;
 877     e.initialize_entity_order = order;
 878
 879     cur = initialize_entity_first;
 880     prev = world;
 881     for (;;)
 882     {
 883         if (!cur || cur.initialize_entity_order > order)
 884         {
 885             // insert between prev and cur
 886             if (prev)
 887                 prev.initialize_entity_next = e;
 888             else
 889                 initialize_entity_first = e;
 890             e.initialize_entity_next = cur;
 891             return;
 892         }
 893         prev = cur;
 894         cur = cur.initialize_entity_next;
 895     }
 896 }
 897 void InitializeEntitiesRun()
 898 {SELFPARAM();
 899     entity startoflist = initialize_entity_first;
 900     initialize_entity_first = NULL;
 901     remove = remove_except_protected;
 902     for (entity e = startoflist; e; e = e.initialize_entity_next)
 903     {
 904                 e.remove_except_protected_forbidden = 1;
 905     }
 906     for (entity e = startoflist; e; )
 907     {
 908                 e.remove_except_protected_forbidden = 0;
 909         e.initialize_entity_order = 0;
 910         entity next = e.initialize_entity_next;
 911         e.initialize_entity_next = NULL;
 912         var void() func = e.initialize_entity;
 913         e.initialize_entity = func_null;
 914         if (e.classname == "initialize_entity")
 915         {
 916             entity wrappee = e.enemy;
 917             builtin_remove(e);
 918             e = wrappee;
 919         }
 920         //dprint("Delayed initialization: ", e.classname, "\n");
 921         if (func)
 922         {
 923                 WITH(entity, self, e, func());
 924         }
 925         else
 926         {
 927             eprint(e);
 928             backtrace(strcat("Null function in: ", e.classname, "\n"));
 929         }
 930         e = next;
 931     }
 932     remove = remove_unsafely;
 933 }
 934
 935 .float(entity) isEliminated;
 936 bool EliminatedPlayers_SendEntity(entity this, entity to, float sendflags)
 937 {
 938         float i, f, b;
 939         entity e;
 940         WriteHeader(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
 941         WriteByte(MSG_ENTITY, sendflags);
 942
 943         if(sendflags & 1)
 944         {
 945                 for(i = 1; i <= maxclients; i += 8)
 946                 {
 947                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
 948                         {
 949                                 if(eliminatedPlayers.isEliminated(e))
 950                                         f |= b;
 951                         }
 952                         WriteByte(MSG_ENTITY, f);
 953                 }
 954         }
 955
 956         return true;
 957 }
 958
 959 void EliminatedPlayers_Init(float(entity) isEliminated_func)
 960 {
 961         if(eliminatedPlayers)
 962         {
 963                 backtrace("Can't spawn eliminatedPlayers again!");
 964                 return;
 965         }
 966         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
 967         eliminatedPlayers.isEliminated = isEliminated_func;
 968 }
 969
 970
 971 void adaptor_think2touch()
 972 {SELFPARAM();
 973     entity o;
 974     o = other;
 975     other = world;
 976     self.touch();
 977     other = o;
 978 }
 979
 980 void adaptor_think2use()
 981 {SELFPARAM();
 982     entity o, a;
 983     o = other;
 984     a = activator;
 985     activator = world;
 986     other = world;
 987     self.use();
 988     other = o;
 989     activator = a;
 990 }
 991
 992 void adaptor_think2use_hittype_splash() // for timed projectile detonation
 993 {SELFPARAM();
 994         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
 995                 self.projectiledeathtype |= HITTYPE_SPLASH;
 996         adaptor_think2use();
 997 }
 998
 999 // deferred dropping
1000 void DropToFloor_Handler()
1001 {SELFPARAM();
1002     builtin_droptofloor();
1003     self.dropped_origin = self.origin;
1004 }
1005
1006 void droptofloor()
1007 {SELFPARAM();
1008     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1009 }
1010
1011
1012
1013 float trace_hits_box_a0, trace_hits_box_a1;
1014
1015 float trace_hits_box_1d(float end, float thmi, float thma)
1016 {
1017     if (end == 0)
1018     {
1019         // just check if x is in range
1020         if (0 < thmi)
1021             return false;
1022         if (0 > thma)
1023             return false;
1024     }
1025     else
1026     {
1027         // do the trace with respect to x
1028         // 0 -> end has to stay in thmi -> thma
1029         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1030         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1031         if (trace_hits_box_a0 > trace_hits_box_a1)
1032             return false;
1033     }
1034     return true;
1035 }
1036
1037 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1038 {
1039     end -= start;
1040     thmi -= start;
1041     thma -= start;
1042     // now it is a trace from 0 to end
1043
1044     trace_hits_box_a0 = 0;
1045     trace_hits_box_a1 = 1;
1046
1047     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1048         return false;
1049     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1050         return false;
1051     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1052         return false;
1053
1054     return true;
1055 }
1056
1057 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1058 {
1059     return trace_hits_box(start, end, thmi - ma, thma - mi);
1060 }
1061
1062 float SUB_NoImpactCheck()
1063 {SELFPARAM();
1064         // zero hitcontents = this is not the real impact, but either the
1065         // mirror-impact of something hitting the projectile instead of the
1066         // projectile hitting the something, or a touchareagrid one. Neither of
1067         // these stop the projectile from moving, so...
1068         if(trace_dphitcontents == 0)
1069         {
1070                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1071                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1072                 checkclient();
1073         }
1074     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1075         return 1;
1076     if (other == world && self.size != '0 0 0')
1077     {
1078         vector tic;
1079         tic = self.velocity * sys_frametime;
1080         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1081         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1082         if (trace_fraction >= 1)
1083         {
1084             LOG_TRACE("Odd... did not hit...?\n");
1085         }
1086         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1087         {
1088             LOG_TRACE("Detected and prevented the sky-grapple bug.\n");
1089             return 1;
1090         }
1091     }
1092
1093     return 0;
1094 }
1095
1096 #define SUB_OwnerCheck() (other && (other == self.owner))
1097
1098 void W_Crylink_Dequeue(entity e);
1099 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1100 {SELFPARAM();
1101         if(SUB_OwnerCheck())
1102                 return true;
1103         if(SUB_NoImpactCheck())
1104         {
1105                 if(self.classname == "nade")
1106                         return false; // no checks here
1107                 else if(self.classname == "grapplinghook")
1108                         RemoveGrapplingHook(self.realowner);
1109                 else if(self.classname == "spike")
1110                 {
1111                         W_Crylink_Dequeue(self);
1112                         remove(self);
1113                 }
1114                 else
1115                         remove(self);
1116                 return true;
1117         }
1118         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1119                 UpdateCSQCProjectile(self);
1120         return false;
1121 }
1122
1123 /** engine callback */
1124 void URI_Get_Callback(float id, float status, string data)
1125 {
1126         if(url_URI_Get_Callback(id, status, data))
1127         {
1128                 // handled
1129         }
1130         else if (id == URI_GET_DISCARD)
1131         {
1132                 // discard
1133         }
1134         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1135         {
1136                 // sv_cmd curl
1137                 Curl_URI_Get_Callback(id, status, data);
1138         }
1139         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1140         {
1141                 // online ban list
1142                 OnlineBanList_URI_Get_Callback(id, status, data);
1143         }
1144         else
1145         {
1146                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1147         }
1148 }
1149
1150 string uid2name(string myuid) {
1151         string s;
1152         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1153
1154         // FIXME remove this later after 0.6 release
1155         // convert old style broken records to correct style
1156         if(s == "")
1157         {
1158                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1159                 if(s != "")
1160                 {
1161                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1162                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1163                 }
1164         }
1165
1166         if(s == "")
1167                 s = "^1Unregistered Player";
1168         return s;
1169 }
1170
1171 float MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1172 {
1173     float m, i;
1174     vector start, org, delta, end, enddown, mstart;
1175     entity sp;
1176
1177     m = e.dphitcontentsmask;
1178     e.dphitcontentsmask = goodcontents | badcontents;
1179
1180     org = boundmin;
1181     delta = boundmax - boundmin;
1182
1183     start = end = org;
1184
1185     for (i = 0; i < attempts; ++i)
1186     {
1187         start.x = org.x + random() * delta.x;
1188         start.y = org.y + random() * delta.y;
1189         start.z = org.z + random() * delta.z;
1190
1191         // rule 1: start inside world bounds, and outside
1192         // solid, and don't start from somewhere where you can
1193         // fall down to evil
1194         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1195         if (trace_fraction >= 1)
1196             continue;
1197         if (trace_startsolid)
1198             continue;
1199         if (trace_dphitcontents & badcontents)
1200             continue;
1201         if (trace_dphitq3surfaceflags & badsurfaceflags)
1202             continue;
1203
1204         // rule 2: if we are too high, lower the point
1205         if (trace_fraction * delta.z > maxaboveground)
1206             start = trace_endpos + '0 0 1' * maxaboveground;
1207         enddown = trace_endpos;
1208
1209         // rule 3: make sure we aren't outside the map. This only works
1210         // for somewhat well formed maps. A good rule of thumb is that
1211         // the map should have a convex outside hull.
1212         // these can be traceLINES as we already verified the starting box
1213         mstart = start + 0.5 * (e.mins + e.maxs);
1214         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1215         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1216             continue;
1217         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1218         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1219             continue;
1220         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1221         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1222             continue;
1223         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1224         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1225             continue;
1226         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1227         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1228             continue;
1229
1230         // rule 4: we must "see" some spawnpoint or item
1231         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1232                 if(checkpvs(mstart, sp))
1233                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1234                                 break;
1235         if(!sp)
1236         {
1237                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1238                         if(checkpvs(mstart, sp))
1239                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1240                                         break;
1241                 if(!sp)
1242                         continue;
1243         }
1244
1245         // find a random vector to "look at"
1246         end.x = org.x + random() * delta.x;
1247         end.y = org.y + random() * delta.y;
1248         end.z = org.z + random() * delta.z;
1249         end = start + normalize(end - start) * vlen(delta);
1250
1251         // rule 4: start TO end must not be too short
1252         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1253         if (trace_startsolid)
1254             continue;
1255         if (trace_fraction < minviewdistance / vlen(delta))
1256             continue;
1257
1258         // rule 5: don't want to look at sky
1259         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1260             continue;
1261
1262         // rule 6: we must not end up in trigger_hurt
1263         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1264             continue;
1265
1266         break;
1267     }
1268
1269     e.dphitcontentsmask = m;
1270
1271     if (i < attempts)
1272     {
1273         setorigin(e, start);
1274         e.angles = vectoangles(end - start);
1275         LOG_TRACE("Needed ", ftos(i + 1), " attempts\n");
1276         return true;
1277     }
1278     else
1279         return false;
1280 }
1281
1282 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1283 {
1284         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1285 }
1286
1287 void write_recordmarker(entity pl, float tstart, float dt)
1288 {
1289     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1290
1291     // also write a marker into demo files for demotc-race-record-extractor to find
1292     stuffcmd(pl,
1293              strcat(
1294                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1295                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1296 }
1297
1298 void attach_sameorigin(entity e, entity to, string tag)
1299 {
1300     vector org, t_forward, t_left, t_up, e_forward, e_up;
1301     float tagscale;
1302
1303     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1304     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1305     t_forward = v_forward * tagscale;
1306     t_left = v_right * -tagscale;
1307     t_up = v_up * tagscale;
1308
1309     e.origin_x = org * t_forward;
1310     e.origin_y = org * t_left;
1311     e.origin_z = org * t_up;
1312
1313     // current forward and up directions
1314     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1315                 e.angles = AnglesTransform_FromVAngles(e.angles);
1316         else
1317                 e.angles = AnglesTransform_FromAngles(e.angles);
1318     fixedmakevectors(e.angles);
1319
1320     // untransform forward, up!
1321     e_forward.x = v_forward * t_forward;
1322     e_forward.y = v_forward * t_left;
1323     e_forward.z = v_forward * t_up;
1324     e_up.x = v_up * t_forward;
1325     e_up.y = v_up * t_left;
1326     e_up.z = v_up * t_up;
1327
1328     e.angles = fixedvectoangles2(e_forward, e_up);
1329     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1330                 e.angles = AnglesTransform_ToVAngles(e.angles);
1331         else
1332                 e.angles = AnglesTransform_ToAngles(e.angles);
1333
1334     setattachment(e, to, tag);
1335     setorigin(e, e.origin);
1336 }
1337
1338 void detach_sameorigin(entity e)
1339 {
1340     vector org;
1341     org = gettaginfo(e, 0);
1342     e.angles = fixedvectoangles2(v_forward, v_up);
1343     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1344                 e.angles = AnglesTransform_ToVAngles(e.angles);
1345         else
1346                 e.angles = AnglesTransform_ToAngles(e.angles);
1347     setorigin(e, org);
1348     setattachment(e, world, "");
1349     setorigin(e, e.origin);
1350 }
1351
1352 void follow_sameorigin(entity e, entity to)
1353 {
1354     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1355     e.aiment = to; // make the hole follow bmodel
1356     e.punchangle = to.angles; // the original angles of bmodel
1357     e.view_ofs = e.origin - to.origin; // relative origin
1358     e.v_angle = e.angles - to.angles; // relative angles
1359 }
1360
1361 void unfollow_sameorigin(entity e)
1362 {
1363     e.movetype = MOVETYPE_NONE;
1364 }
1365
1366 entity gettaginfo_relative_ent;
1367 vector gettaginfo_relative(entity e, float tag)
1368 {
1369     if (!gettaginfo_relative_ent)
1370     {
1371         gettaginfo_relative_ent = spawn();
1372         gettaginfo_relative_ent.effects = EF_NODRAW;
1373     }
1374     gettaginfo_relative_ent.model = e.model;
1375     gettaginfo_relative_ent.modelindex = e.modelindex;
1376     gettaginfo_relative_ent.frame = e.frame;
1377     return gettaginfo(gettaginfo_relative_ent, tag);
1378 }
1379
1380 .string aiment_classname;
1381 .float aiment_deadflag;
1382 void SetMovetypeFollow(entity ent, entity e)
1383 {
1384         // FIXME this may not be warpzone aware
1385         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1386         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1387         ent.aiment = e; // make the hole follow bmodel
1388         ent.punchangle = e.angles; // the original angles of bmodel
1389         ent.view_ofs = ent.origin - e.origin; // relative origin
1390         ent.v_angle = ent.angles - e.angles; // relative angles
1391         ent.aiment_classname = strzone(e.classname);
1392         ent.aiment_deadflag = e.deadflag;
1393 }
1394 void UnsetMovetypeFollow(entity ent)
1395 {
1396         ent.movetype = MOVETYPE_FLY;
1397         PROJECTILE_MAKETRIGGER(ent);
1398         ent.aiment = world;
1399 }
1400 float LostMovetypeFollow(entity ent)
1401 {
1402 /*
1403         if(ent.movetype != MOVETYPE_FOLLOW)
1404                 if(ent.aiment)
1405                         error("???");
1406 */
1407         if(ent.aiment)
1408         {
1409                 if(ent.aiment.classname != ent.aiment_classname)
1410                         return 1;
1411                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1412                         return 1;
1413         }
1414         return 0;
1415 }
1416
1417 float isPushable(entity e)
1418 {
1419         if(e.pushable)
1420                 return true;
1421         if(IS_VEHICLE(e))
1422                 return false;
1423         if(e.iscreature)
1424                 return true;
1425         switch(e.classname)
1426         {
1427                 case "body":
1428                 case "droppedweapon":
1429                 case "keepawayball":
1430                 case "nexball_basketball":
1431                 case "nexball_football":
1432                         return true;
1433                 case "bullet": // antilagged bullets can't hit this either
1434                         return false;
1435         }
1436         if (e.projectiledeathtype)
1437                 return true;
1438         return false;
1439 }