qcsrc/server/mutators/gamemode_lms.qc

   1 // main functions
   2 float LMS_NewPlayerLives()
   3 {
   4         float fl;
   5         fl = autocvar_fraglimit;
   6         if(fl == 0)
   7                 fl = 999;
   8
   9         // first player has left the game for dying too much? Nobody else can get in.
  10         if(lms_lowest_lives < 1)
  11                 return 0;
  12
  13         if(!autocvar_g_lms_join_anytime)
  14                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  15                         return 0;
  16
  17         return bound(1, lms_lowest_lives, fl);
  18 }
  19
  20 // mutator hooks
  21 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  22 {
  23         // Only if the player cannot play at all
  24         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  25                 self.frags = FRAGS_SPECTATOR;
  26         else
  27                 self.frags = FRAGS_LMS_LOSER;
  28
  29         return FALSE;
  30 }
  31
  32 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  33 {
  34         self.classname = "player";
  35         campaign_bots_may_start = 1;
  36
  37         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  38         {
  39                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  40                 self.frags = FRAGS_SPECTATOR;
  41         }
  42
  43         return FALSE;
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
  47 {
  48         if(self.deadflag == DEAD_DYING)
  49                 self.deadflag = DEAD_RESPAWNING;
  50
  51         return FALSE;
  52 }
  53
  54 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
  55 {
  56         // forbode!
  57         return TRUE;
  58 }
  59
  60 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
  61 {
  62         // remove a life
  63         float tl;
  64         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
  65         if(tl < lms_lowest_lives)
  66                 lms_lowest_lives = tl;
  67         if(tl <= 0)
  68         {
  69                 if(!lms_next_place)
  70                         lms_next_place = player_count;
  71                 else
  72                         lms_next_place = min(lms_next_place, player_count);
  73                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
  74                 --lms_next_place;
  75         }
  76         frag_score = 0;
  77
  78         return TRUE;
  79 }
  80
  81 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
  82 {
  83         start_items &~= IT_UNLIMITED_AMMO;
  84         start_ammo_shells = cvar("g_lms_start_ammo_shells");
  85         start_ammo_nails = cvar("g_lms_start_ammo_nails");
  86         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
  87         start_ammo_cells = cvar("g_lms_start_ammo_cells");
  88         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
  89         start_health = cvar("g_lms_start_health");
  90         start_armorvalue = cvar("g_lms_start_armor");
  91
  92         return FALSE;
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(lms_KeepScore)
  96 {
  97         // don't clear player score
  98         return TRUE;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 102 {
 103         // no items in LMS
 104         return TRUE;
 105 }
 106
 107 MUTATOR_HOOKFUNCTION(lms_BotSpawn)
 108 {
 109         // temporary hack to give bots lives
 110         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 111         {
 112                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 113                 self.frags = FRAGS_SPECTATOR;
 114         }
 115
 116         return FALSE;
 117 }
 118
 119 // scoreboard stuff
 120 void lms_ScoreRules()
 121 {
 122         ScoreRules_basics(0, 0, 0, FALSE);
 123         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 124         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 125         ScoreRules_basics_end();
 126 }
 127
 128 void lms_Initialize()
 129 {
 130         lms_lowest_lives = 9999;
 131         lms_next_place = 0;
 132
 133         lms_ScoreRules();
 134 }
 135
 136 MUTATOR_DEFINITION(gamemode_lms)
 137 {
 138         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 139         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 140         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 141         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 142         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 143         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 144         MUTATOR_HOOK(PlayerClearScore, lms_KeepScore, CBC_ORDER_ANY);
 145         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 146         MUTATOR_HOOK(HavocBot_ChooseRule, lms_BotSpawn, CBC_ORDER_ANY);
 147
 148         MUTATOR_ONADD
 149         {
 150                 if(time > 1) // game loads at time 1
 151                         error("This is a game type and it cannot be added at runtime.");
 152                 lms_Initialize();
 153         }
 154
 155         MUTATOR_ONROLLBACK_OR_REMOVE
 156         {
 157                 // we actually cannot roll back lms_Initialize here
 158                 // BUT: we don't need to! If this gets called, adding always
 159                 // succeeds.
 160         }
 161
 162         MUTATOR_ONREMOVE
 163         {
 164                 print("This is a game type and it cannot be removed at runtime.");
 165                 return -1;
 166         }
 167
 168         return 0;
 169 }