qcsrc/server/mutators/mutator/gamemode_freezetag.qc

   1 #include "gamemode_freezetag.qh"
   2 #ifndef GAMEMODE_FREEZETAG_H
   3 #define GAMEMODE_FREEZETAG_H
   4
   5 int autocvar_g_freezetag_point_limit;
   6 int autocvar_g_freezetag_point_leadlimit;
   7 bool autocvar_g_freezetag_team_spawns;
   8 void freezetag_Initialize();
   9
  10 REGISTER_MUTATOR(ft, false)
  11 {
  12         MUTATOR_ONADD
  13         {
  14                 if (time > 1) // game loads at time 1
  15                         error("This is a game type and it cannot be added at runtime.");
  16                 freezetag_Initialize();
  17
  18                 ActivateTeamplay();
  19                 SetLimits(autocvar_g_freezetag_point_limit, autocvar_g_freezetag_point_leadlimit, -1, -1);
  20
  21                 if (autocvar_g_freezetag_team_spawns)
  22                         have_team_spawns = -1; // request team spawns
  23         }
  24
  25         MUTATOR_ONROLLBACK_OR_REMOVE
  26         {
  27                 // we actually cannot roll back freezetag_Initialize here
  28                 // BUT: we don't need to! If this gets called, adding always
  29                 // succeeds.
  30         }
  31
  32         MUTATOR_ONREMOVE
  33         {
  34                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  35                 return -1;
  36         }
  37
  38         return 0;
  39 }
  40
  41 .float freezetag_frozen_time;
  42 .float freezetag_frozen_timeout;
  43 const float ICE_MAX_ALPHA = 1;
  44 const float ICE_MIN_ALPHA = 0.1;
  45 float freezetag_teams;
  46
  47 .float reviving; // temp var
  48
  49 float autocvar_g_freezetag_revive_extra_size;
  50 float autocvar_g_freezetag_revive_speed;
  51 bool autocvar_g_freezetag_revive_nade;
  52 float autocvar_g_freezetag_revive_nade_health;
  53
  54 #endif
  55 #ifdef IMPLEMENTATION
  56
  57 float autocvar_g_freezetag_frozen_maxtime;
  58 float autocvar_g_freezetag_revive_clearspeed;
  59 float autocvar_g_freezetag_round_timelimit;
  60 int autocvar_g_freezetag_teams;
  61 int autocvar_g_freezetag_teams_override;
  62 float autocvar_g_freezetag_warmup;
  63
  64 const float SP_FREEZETAG_REVIVALS = 4;
  65 void freezetag_ScoreRules(float teams)
  66 {
  67         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true); // SFL_SORT_PRIO_PRIMARY
  68         ScoreInfo_SetLabel_PlayerScore(SP_FREEZETAG_REVIVALS, "revivals", 0);
  69         ScoreRules_basics_end();
  70 }
  71
  72 void freezetag_count_alive_players()
  73 {
  74         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  75         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  76                 switch(it.team)
  77                 {
  78                         case NUM_TEAM_1: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++redalive; break;
  79                         case NUM_TEAM_2: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++bluealive; break;
  80                         case NUM_TEAM_3: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++yellowalive; break;
  81                         case NUM_TEAM_4: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++pinkalive; break;
  82                 }
  83         ));
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  85                 it.redalive_stat = redalive;
  86                 it.bluealive_stat = bluealive;
  87                 it.yellowalive_stat = yellowalive;
  88                 it.pinkalive_stat = pinkalive;
  89         ));
  90
  91         eliminatedPlayers.SendFlags |= 1;
  92 }
  93 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  94 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  95
  96 float freezetag_CheckTeams()
  97 {
  98         static float prev_missing_teams_mask;
  99         if(FREEZETAG_ALIVE_TEAMS_OK())
 100         {
 101                 if(prev_missing_teams_mask > 0)
 102                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 103                 prev_missing_teams_mask = -1;
 104                 return 1;
 105         }
 106         if(total_players == 0)
 107         {
 108                 if(prev_missing_teams_mask > 0)
 109                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 110                 prev_missing_teams_mask = -1;
 111                 return 0;
 112         }
 113         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 114         if(freezetag_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 115         if(freezetag_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 116         if(prev_missing_teams_mask != missing_teams_mask)
 117         {
 118                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 119                 prev_missing_teams_mask = missing_teams_mask;
 120         }
 121         return 0;
 122 }
 123
 124 float freezetag_getWinnerTeam()
 125 {
 126         float winner_team = 0;
 127         if(redalive >= 1)
 128                 winner_team = NUM_TEAM_1;
 129         if(bluealive >= 1)
 130         {
 131                 if(winner_team) return 0;
 132                 winner_team = NUM_TEAM_2;
 133         }
 134         if(yellowalive >= 1)
 135         {
 136                 if(winner_team) return 0;
 137                 winner_team = NUM_TEAM_3;
 138         }
 139         if(pinkalive >= 1)
 140         {
 141                 if(winner_team) return 0;
 142                 winner_team = NUM_TEAM_4;
 143         }
 144         if(winner_team)
 145                 return winner_team;
 146         return -1; // no player left
 147 }
 148
 149 float freezetag_CheckWinner()
 150 {
 151         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 152         {
 153                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 154                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 155                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 156                         it.freezetag_frozen_timeout = 0;
 157                         nades_Clear(it);
 158                 ));
 159                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 160                 return 1;
 161         }
 162
 163         if(FREEZETAG_ALIVE_TEAMS() > 1)
 164                 return 0;
 165
 166         int winner_team = freezetag_getWinnerTeam();
 167         if(winner_team > 0)
 168         {
 169                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 170                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 171                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 172         }
 173         else if(winner_team == -1)
 174         {
 175                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 177         }
 178
 179         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 180                 it.freezetag_frozen_timeout = 0;
 181                 nades_Clear(it);
 182         ));
 183         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 184         return 1;
 185 }
 186
 187 entity freezetag_LastPlayerForTeam()
 188 {SELFPARAM();
 189         entity last_pl = world;
 190         FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
 191                 if(it.health >= 1)
 192                 if(!STAT(FROZEN, it))
 193                 if(SAME_TEAM(it, self))
 194                 if(!last_pl)
 195                         last_pl = it;
 196                 else
 197                         return world;
 198         ));
 199         return last_pl;
 200 }
 201
 202 void freezetag_LastPlayerForTeam_Notify()
 203 {
 204         if(round_handler_IsActive())
 205         if(round_handler_IsRoundStarted())
 206         {
 207                 entity pl = freezetag_LastPlayerForTeam();
 208                 if(pl)
 209                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 210         }
 211 }
 212
 213 void freezetag_Add_Score(entity attacker)
 214 {SELFPARAM();
 215         if(attacker == self)
 216         {
 217                 // you froze your own dumb self
 218                 // counted as "suicide" already
 219                 PlayerScore_Add(self, SP_SCORE, -1);
 220         }
 221         else if(IS_PLAYER(attacker))
 222         {
 223                 // got frozen by an enemy
 224                 // counted as "kill" and "death" already
 225                 PlayerScore_Add(self, SP_SCORE, -1);
 226                 PlayerScore_Add(attacker, SP_SCORE, +1);
 227         }
 228         // else nothing - got frozen by the game type rules themselves
 229 }
 230
 231 void freezetag_Freeze(entity attacker)
 232 {SELFPARAM();
 233         if(STAT(FROZEN, self))
 234                 return;
 235
 236         if(autocvar_g_freezetag_frozen_maxtime > 0)
 237                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 238
 239         Freeze(self, 0, 1, true);
 240
 241         freezetag_count_alive_players();
 242
 243         freezetag_Add_Score(attacker);
 244 }
 245
 246 void freezetag_Unfreeze(entity attacker)
 247 {SELFPARAM();
 248         self.freezetag_frozen_time = 0;
 249         self.freezetag_frozen_timeout = 0;
 250
 251         Unfreeze(self);
 252 }
 253
 254 float freezetag_isEliminated(entity e)
 255 {
 256         if(IS_PLAYER(e) && (STAT(FROZEN, e) == 1 || IS_DEAD(e)))
 257                 return true;
 258         return false;
 259 }
 260
 261
 262 // ================
 263 // Bot player logic
 264 // ================
 265
 266 void() havocbot_role_ft_freeing;
 267 void() havocbot_role_ft_offense;
 268
 269 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 270 {SELFPARAM();
 271         float distance;
 272
 273         FOREACH_CLIENT(IS_PLAYER(it) && it != self && SAME_TEAM(it, self), LAMBDA(
 274                 if (STAT(FROZEN, it) == 1)
 275                 {
 276                         distance = vlen(it.origin - org);
 277                         if (distance > sradius)
 278                                 continue;
 279                         navigation_routerating(it, ratingscale, 2000);
 280                 }
 281                 else
 282                 {
 283                         // If teamate is not frozen still seek them out as fight better
 284                         // in a group.
 285                         navigation_routerating(it, ratingscale/3, 2000);
 286                 }
 287         ));
 288 }
 289
 290 void havocbot_role_ft_offense()
 291 {SELFPARAM();
 292         if(IS_DEAD(self))
 293                 return;
 294
 295         if (!self.havocbot_role_timeout)
 296                 self.havocbot_role_timeout = time + random() * 10 + 20;
 297
 298         // Count how many players on team are unfrozen.
 299         int unfrozen = 0;
 300         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, self) && !(STAT(FROZEN, it) != 1), LAMBDA(unfrozen++));
 301
 302         // If only one left on team or if role has timed out then start trying to free players.
 303         if (((unfrozen == 0) && (!STAT(FROZEN, self))) || (time > self.havocbot_role_timeout))
 304         {
 305                 LOG_TRACE("changing role to freeing\n");
 306                 self.havocbot_role = havocbot_role_ft_freeing;
 307                 self.havocbot_role_timeout = 0;
 308                 return;
 309         }
 310
 311         if (time > self.bot_strategytime)
 312         {
 313                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 314
 315                 navigation_goalrating_start();
 316                 havocbot_goalrating_items(10000, self.origin, 10000);
 317                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 318                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 319                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 320                 navigation_goalrating_end();
 321         }
 322 }
 323
 324 void havocbot_role_ft_freeing()
 325 {SELFPARAM();
 326         if(IS_DEAD(self))
 327                 return;
 328
 329         if (!self.havocbot_role_timeout)
 330                 self.havocbot_role_timeout = time + random() * 10 + 20;
 331
 332         if (time > self.havocbot_role_timeout)
 333         {
 334                 LOG_TRACE("changing role to offense\n");
 335                 self.havocbot_role = havocbot_role_ft_offense;
 336                 self.havocbot_role_timeout = 0;
 337                 return;
 338         }
 339
 340         if (time > self.bot_strategytime)
 341         {
 342                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 343
 344                 navigation_goalrating_start();
 345                 havocbot_goalrating_items(8000, self.origin, 10000);
 346                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 347                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 348                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 349                 navigation_goalrating_end();
 350         }
 351 }
 352
 353
 354 // ==============
 355 // Hook Functions
 356 // ==============
 357
 358 void ft_RemovePlayer()
 359 {SELFPARAM();
 360         self.health = 0; // neccessary to update correctly alive stats
 361         if(!STAT(FROZEN, self))
 362                 freezetag_LastPlayerForTeam_Notify();
 363         freezetag_Unfreeze(world);
 364         freezetag_count_alive_players();
 365 }
 366
 367 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 368 {SELFPARAM();
 369         ft_RemovePlayer();
 370         return 1;
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 374 {SELFPARAM();
 375         ft_RemovePlayer();
 376         return false;
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 380 {
 381     SELFPARAM();
 382         if(round_handler_IsActive())
 383         if(round_handler_CountdownRunning())
 384         {
 385                 if(STAT(FROZEN, frag_target))
 386                         WITH(entity, self, frag_target, freezetag_Unfreeze(world));
 387                 freezetag_count_alive_players();
 388                 return 1; // let the player die so that he can respawn whenever he wants
 389         }
 390
 391         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 392         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 393         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 394                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 395         {
 396                 // let the player die, he will be automatically frozen when he respawns
 397                 if(STAT(FROZEN, frag_target) != 1)
 398                 {
 399                         freezetag_Add_Score(frag_attacker);
 400                         freezetag_count_alive_players();
 401                         freezetag_LastPlayerForTeam_Notify();
 402                 }
 403                 else
 404                         WITH(entity, self, frag_target, freezetag_Unfreeze(world)); // remove ice
 405                 frag_target.health = 0; // Unfreeze resets health
 406                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 407                 return 1;
 408         }
 409
 410         if(STAT(FROZEN, frag_target))
 411                 return 1;
 412
 413         WITH(entity, self, frag_target, freezetag_Freeze(frag_attacker));
 414         freezetag_LastPlayerForTeam_Notify();
 415
 416         if(frag_attacker == frag_target || frag_attacker == world)
 417         {
 418                 if(IS_PLAYER(frag_target))
 419                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 420                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 421         }
 422         else
 423         {
 424                 if(IS_PLAYER(frag_target))
 425                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_FROZEN, frag_attacker.netname);
 426                 if(IS_PLAYER(frag_attacker))
 427                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_FREEZETAG_FREEZE, frag_target.netname);
 428                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 429         }
 430
 431         return 1;
 432 }
 433
 434 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 435 {SELFPARAM();
 436         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 437                 return 1; // do nothing, round is starting right now
 438
 439         if(self.freezetag_frozen_timeout == -2) // player was dead
 440         {
 441                 freezetag_Freeze(world);
 442                 return 1;
 443         }
 444
 445         freezetag_count_alive_players();
 446
 447         if(round_handler_IsActive())
 448         if(round_handler_IsRoundStarted())
 449         {
 450                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 451                 freezetag_Freeze(world);
 452         }
 453
 454         return 1;
 455 }
 456
 457 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 458 {SELFPARAM();
 459         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 460                 it.killcount = 0;
 461                 it.freezetag_frozen_timeout = -1;
 462                 setself(it);
 463                 PutClientInServer();
 464                 it.freezetag_frozen_timeout = 0;
 465         ));
 466         freezetag_count_alive_players();
 467         return 1;
 468 }
 469
 470 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 471 {
 472         frag_score = 0; // no frags counted in Freeze Tag
 473         return 1;
 474 }
 475
 476 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 477 {SELFPARAM();
 478         if(gameover)
 479                 return 1;
 480
 481         if(STAT(FROZEN, self) == 1)
 482         {
 483                 // keep health = 1
 484                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 485         }
 486
 487         if(round_handler_IsActive())
 488         if(!round_handler_IsRoundStarted())
 489                 return 1;
 490
 491         int n;
 492
 493         entity o;
 494         o = world;
 495         //if(STAT(FROZEN, self))
 496         //if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 497                 //self.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 498
 499         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 500                 n = -1;
 501         else
 502         {
 503                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 504                 n = 0;
 505                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
 506                         if(STAT(FROZEN, it) == 0)
 507                         if(!IS_DEAD(it))
 508                         if(SAME_TEAM(it, self))
 509                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, it.absmin, it.absmax))
 510                         {
 511                                 if(!o)
 512                                         o = it;
 513                                 if(STAT(FROZEN, self) == 1)
 514                                         it.reviving = true;
 515                                 ++n;
 516                         }
 517                 ));
 518
 519         }
 520
 521         if(n && STAT(FROZEN, self) == 1) // OK, there is at least one teammate reviving us
 522         {
 523                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 524                 self.health = max(1, self.revive_progress * ((warmup_stage) ? warmup_start_health : start_health));
 525
 526                 if(self.revive_progress >= 1)
 527                 {
 528                         freezetag_Unfreeze(self);
 529                         freezetag_count_alive_players();
 530
 531                         if(n == -1)
 532                         {
 533                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 534                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, self.netname, autocvar_g_freezetag_frozen_maxtime);
 535                                 return 1;
 536                         }
 537
 538                         // EVERY team mate nearby gets a point (even if multiple!)
 539                         FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
 540                                 PlayerScore_Add(it, SP_FREEZETAG_REVIVALS, +1);
 541                                 PlayerScore_Add(it, SP_SCORE, +1);
 542                                 nades_GiveBonus(it,autocvar_g_nades_bonus_score_low);
 543                         ));
 544
 545                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 546                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 547                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED, self.netname, o.netname);
 548                 }
 549
 550                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
 551                         it.revive_progress = self.revive_progress;
 552                         it.reviving = false;
 553                 ));
 554         }
 555         else if(!n && STAT(FROZEN, self) == 1) // only if no teammate is nearby will we reset
 556         {
 557                 self.revive_progress = bound(0, self.revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 558                 self.health = max(1, self.revive_progress * ((warmup_stage) ? warmup_start_health : start_health));
 559         }
 560         else if(!n && !STAT(FROZEN, self))
 561         {
 562                 self.revive_progress = 0; // thawing nobody
 563         }
 564
 565         return 1;
 566 }
 567
 568 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 569 {
 570         start_items &= ~IT_UNLIMITED_AMMO;
 571         //start_health       = warmup_start_health       = cvar("g_lms_start_health");
 572         //start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 573         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 574         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 575         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 576         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 577         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 578         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 579
 580         return 0;
 581 }
 582
 583 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 584 {SELFPARAM();
 585         if (!IS_DEAD(self))
 586         {
 587                 if (random() < 0.5)
 588                         self.havocbot_role = havocbot_role_ft_freeing;
 589                 else
 590                         self.havocbot_role = havocbot_role_ft_offense;
 591         }
 592
 593         return true;
 594 }
 595
 596 MUTATOR_HOOKFUNCTION(ft, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 597 {
 598         ret_float = freezetag_teams;
 599         return false;
 600 }
 601
 602 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 603 {
 604         // most weapons arena
 605         if(ret_string == "0" || ret_string == "")
 606                 ret_string = "most";
 607         return false;
 608 }
 609
 610 void freezetag_Initialize()
 611 {
 612         freezetag_teams = autocvar_g_freezetag_teams_override;
 613         if(freezetag_teams < 2)
 614                 freezetag_teams = autocvar_g_freezetag_teams;
 615         freezetag_teams = bound(2, freezetag_teams, 4);
 616         freezetag_ScoreRules(freezetag_teams);
 617
 618         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 619         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 620
 621         EliminatedPlayers_Init(freezetag_isEliminated);
 622 }
 623
 624 #endif