qcsrc/server/mutators/mutator_superspec.qc

   1 #include "../_all.qh"
   2
   3 #include "mutator.qh"
   4
   5 #define _SSMAGIX "SUPERSPEC_OPTIONSFILE_V1"
   6 #define _ISLOCAL ((edict_num(1) == self) ? true : false)
   7
   8 const float ASF_STRENGTH                = 1;
   9 const float ASF_SHIELD                  = 2;
  10 const float ASF_MEGA_AR                 = 4;
  11 const float ASF_MEGA_HP                 = 8;
  12 const float ASF_FLAG_GRAB               = 16;
  13 const float ASF_OBSERVER_ONLY   = 32;
  14 const float ASF_SHOWWHAT                = 64;
  15 const float ASF_SSIM                    = 128;
  16 const float ASF_FOLLOWKILLER    = 256;
  17 const float ASF_ALL                     = 0xFFFFFF;
  18 .float autospec_flags;
  19
  20 const float SSF_SILENT = 1;
  21 const float SSF_VERBOSE = 2;
  22 const float SSF_ITEMMSG = 4;
  23 .float superspec_flags;
  24
  25 .string superspec_itemfilter; //"classname1 classname2 ..."
  26
  27 float _spectate(entity _player)
  28 {SELFPARAM();
  29         if(Spectate(_player) == 1)
  30                 self.classname = "spectator";
  31
  32         return true;
  33 }
  34
  35 void superspec_save_client_conf()
  36 {SELFPARAM();
  37         string fn = "superspec-local.options";
  38         float fh;
  39
  40         if (!_ISLOCAL)
  41         {
  42                 if(self.crypto_idfp == "")
  43                         return;
  44
  45                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
  46         }
  47
  48         fh = fopen(fn, FILE_WRITE);
  49         if(fh < 0)
  50         {
  51                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for writing.\n");
  52         }
  53         else
  54         {
  55                 fputs(fh, _SSMAGIX);
  56                 fputs(fh, "\n");
  57                 fputs(fh, ftos(self.autospec_flags));
  58                 fputs(fh, "\n");
  59                 fputs(fh, ftos(self.superspec_flags));
  60                 fputs(fh, "\n");
  61                 fputs(fh, self.superspec_itemfilter);
  62                 fputs(fh, "\n");
  63                 fclose(fh);
  64         }
  65 }
  66
  67 void superspec_msg(string _center_title, string _con_title, entity _to, string _msg, float _spamlevel)
  68 {
  69         sprint(_to, strcat(_con_title, _msg));
  70
  71         if(_to.superspec_flags & SSF_SILENT)
  72                 return;
  73
  74         if(_spamlevel > 1)
  75                 if (!(_to.superspec_flags & SSF_VERBOSE))
  76                         return;
  77
  78         centerprint(_to, strcat(_center_title, _msg));
  79 }
  80
  81 float superspec_filteritem(entity _for, entity _item)
  82 {
  83         float i;
  84
  85         if(_for.superspec_itemfilter == "")
  86                 return true;
  87
  88         if(_for.superspec_itemfilter == "")
  89                 return true;
  90
  91         float l = tokenize_console(_for.superspec_itemfilter);
  92         for(i = 0; i < l; ++i)
  93         {
  94                 if(argv(i) == _item.classname)
  95                         return true;
  96         }
  97
  98         return false;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(superspec_ItemTouch)
 102 {SELFPARAM();
 103         entity _oldself = self;
 104         entity _item = self;
 105
 106         entity e;
 107         FOR_EACH_SPEC(e)
 108         {
 109                 setself(e);
 110                 if(self.superspec_flags & SSF_ITEMMSG)
 111                         if(superspec_filteritem(self, _item))
 112                         {
 113                                 if(self.superspec_flags & SSF_VERBOSE)
 114                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n", other.netname, _item.netname), 1);
 115                                 else
 116                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n^8(%s^8)\n", other.netname, _item.netname, _item.classname), 1);
 117                                 if((self.autospec_flags & ASF_SSIM) && self.enemy != other)
 118                                 {
 119                                         _spectate(other);
 120
 121                                         setself(_oldself);
 122                                         return MUT_ITEMTOUCH_CONTINUE;
 123                                 }
 124                         }
 125
 126                 if((self.autospec_flags & ASF_SHIELD && _item.invincible_finished) ||
 127                         (self.autospec_flags & ASF_STRENGTH && _item.strength_finished) ||
 128                         (self.autospec_flags & ASF_MEGA_AR && _item.itemdef == ITEM_ArmorMega) ||
 129                         (self.autospec_flags & ASF_MEGA_HP && _item.itemdef == ITEM_HealthMega) ||
 130                         (self.autospec_flags & ASF_FLAG_GRAB && _item.classname == "item_flag_team"))
 131                 {
 132
 133                         if((self.enemy != other) || IS_OBSERVER(self))
 134                         {
 135                                 if(self.autospec_flags & ASF_OBSERVER_ONLY && !IS_OBSERVER(self))
 136                                 {
 137                                         if(self.superspec_flags & SSF_VERBOSE)
 138                                                 superspec_msg("", "", self, sprintf("^8Ignored that ^7%s^8 grabbed %s^8 since the observer_only option is ON\n", other.netname, _item.netname), 2);
 139                                 }
 140                                 else
 141                                 {
 142                                         if(self.autospec_flags & ASF_SHOWWHAT)
 143                                                 superspec_msg("", "", self, sprintf("^7Following %s^7 due to picking up %s\n", other.netname, _item.netname), 2);
 144
 145                                         _spectate(other);
 146                                 }
 147                         }
 148                 }
 149         }
 150
 151         setself(_oldself);
 152
 153         return MUT_ITEMTOUCH_CONTINUE;
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(superspec_SV_ParseClientCommand)
 157 {SELFPARAM();
 158 #define OPTIONINFO(flag,var,test,text,long,short) \
 159     var = strcat(var, ((flag & test) ? "^2[ON]  ^7" : "^1[OFF] ^7")); \
 160     var = strcat(var, text," ^7(^3 ", long, "^7 | ^3", short, " ^7)\n")
 161
 162         if(MUTATOR_RETURNVALUE) // command was already handled?
 163                 return false;
 164
 165         if(IS_PLAYER(self))
 166                 return false;
 167
 168         if(cmd_name == "superspec_itemfilter")
 169         {
 170                 if(argv(1) == "help")
 171                 {
 172                         string _aspeco;
 173                         _aspeco = "^7 superspec_itemfilter ^3\"item_classname1 item_classname2\"^7 only show thise items when ^2superspec ^3item_message^7 is on\n";
 174                         _aspeco = strcat(_aspeco, "^3 clear^7 Remove the filter (show all pickups)\n");
 175                         _aspeco = strcat(_aspeco, "^3 show ^7 Display current filter\n");
 176                         superspec_msg("^3superspec_itemfilter help:\n\n\n", "\n^3superspec_itemfilter help:\n", self, _aspeco, 1);
 177                 }
 178                 else if(argv(1) == "clear")
 179                 {
 180                         if(self.superspec_itemfilter != "")
 181                                 strunzone(self.superspec_itemfilter);
 182
 183                         self.superspec_itemfilter = "";
 184                 }
 185                 else if(argv(1) == "show" || argv(1) == "")
 186                 {
 187                         if(self.superspec_itemfilter == "")
 188                         {
 189                                 superspec_msg("^3superspec_itemfilter^7 is ^1not^7 set", "\n^3superspec_itemfilter^7 is ^1not^7 set\n", self, "", 1);
 190                                 return true;
 191                         }
 192                         float i;
 193                         float l = tokenize_console(self.superspec_itemfilter);
 194                         string _msg = "";
 195                         for(i = 0; i < l; ++i)
 196                                 _msg = strcat(_msg, "^3#", ftos(i), " ^7", argv(i), "\n");
 197                                 //_msg = sprintf("^3#%d^7 %s\n%s", i, _msg, argv(i));
 198
 199                         _msg = strcat(_msg,"\n");
 200
 201                         superspec_msg("^3superspec_itemfilter is:\n\n\n", "\n^3superspec_itemfilter is:\n", self, _msg, 1);
 202                 }
 203                 else
 204                 {
 205                         if(self.superspec_itemfilter != "")
 206                                 strunzone(self.superspec_itemfilter);
 207
 208                         self.superspec_itemfilter = strzone(argv(1));
 209                 }
 210
 211                 return true;
 212         }
 213
 214         if(cmd_name == "superspec")
 215         {
 216                 string _aspeco;
 217
 218                 if(cmd_argc > 1)
 219                 {
 220                         float i, _bits = 0, _start = 1;
 221                         if(argv(1) == "help")
 222                         {
 223                                 _aspeco = "use cmd superspec [option] [on|off] to set options\n\n";
 224                                 _aspeco = strcat(_aspeco, "^3 silent ^7(short^5 si^7) supresses ALL messages from superspectate.\n");
 225                                 _aspeco = strcat(_aspeco, "^3 verbose ^7(short^5 ve^7) makes superspectate print some additional information.\n");
 226                                 _aspeco = strcat(_aspeco, "^3 item_message ^7(short^5 im^7) makes superspectate print items that were picked up.\n");
 227                                 _aspeco = strcat(_aspeco, "^7    Use cmd superspec_itemfilter \"item_class1 item_class2\" to set up a filter of what to show with ^3item_message.\n");
 228                                 superspec_msg("^2Available Super Spectate ^3options:\n\n\n", "\n^2Available Super Spectate ^3options:\n", self, _aspeco, 1);
 229                                 return true;
 230                         }
 231
 232                         if(argv(1) == "clear")
 233                         {
 234                                 self.superspec_flags = 0;
 235                                 _start = 2;
 236                         }
 237
 238                         for(i = _start; i < cmd_argc; ++i)
 239                         {
 240                                 if(argv(i) == "on" || argv(i) == "1")
 241                                 {
 242                                         self.superspec_flags |= _bits;
 243                                         _bits = 0;
 244                                 }
 245                                 else if(argv(i) == "off" || argv(i) == "0")
 246                                 {
 247                                         if(_start == 1)
 248                                                 self.superspec_flags &= ~_bits;
 249
 250                                         _bits = 0;
 251                                 }
 252                                 else
 253                                 {
 254                                         if((argv(i) == "silent") || (argv(i) == "si")) _bits |= SSF_SILENT ;
 255                                         if((argv(i) == "verbose") || (argv(i) == "ve")) _bits |= SSF_VERBOSE;
 256                                         if((argv(i) == "item_message") || (argv(i) == "im")) _bits |= SSF_ITEMMSG;
 257                                 }
 258                         }
 259                 }
 260
 261                 _aspeco = "";
 262                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_SILENT, "Silent", "silent", "si");
 263                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_VERBOSE, "Verbose", "verbose", "ve");
 264                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_ITEMMSG, "Item pickup messages", "item_message", "im");
 265
 266                 superspec_msg("^3Current Super Spectate options are:\n\n\n\n\n", "\n^3Current Super Spectate options are:\n", self, _aspeco, 1);
 267
 268                 return true;
 269         }
 270
 271 /////////////////////
 272
 273         if(cmd_name == "autospec")
 274         {
 275                 string _aspeco;
 276                 if(cmd_argc > 1)
 277                 {
 278                         if(argv(1) == "help")
 279                         {
 280                                 _aspeco = "use cmd autospec [option] [on|off] to set options\n\n";
 281                                 _aspeco = strcat(_aspeco, "^3 strength ^7(short^5 st^7) for automatic spectate on strength powerup\n");
 282                                 _aspeco = strcat(_aspeco, "^3 shield ^7(short^5 sh^7) for automatic spectate on shield powerup\n");
 283                                 _aspeco = strcat(_aspeco, "^3 mega_health ^7(short^5 mh^7) for automatic spectate on mega health\n");
 284                                 _aspeco = strcat(_aspeco, "^3 mega_armor ^7(short^5 ma^7) for automatic spectate on mega armor\n");
 285                                 _aspeco = strcat(_aspeco, "^3 flag_grab ^7(short^5 fg^7) for automatic spectate on CTF flag grab\n");
 286                                 _aspeco = strcat(_aspeco, "^3 observer_only ^7(short^5 oo^7) for automatic spectate only if in observer mode\n");
 287                                 _aspeco = strcat(_aspeco, "^3 show_what ^7(short^5 sw^7) to display what event triggered autospectate\n");
 288                                 _aspeco = strcat(_aspeco, "^3 item_msg ^7(short^5 im^7) to autospec when item_message in superspectate is triggered\n");
 289                                 _aspeco = strcat(_aspeco, "^3 followkiller ^7(short ^5fk^7) to autospec the killer/off\n");
 290                                 _aspeco = strcat(_aspeco, "^3 all ^7(short ^5aa^7) to turn everything on/off\n");
 291                                 superspec_msg("^2Available Auto Spectate ^3options:\n\n\n", "\n^2Available Auto Spectate ^3options:\n", self, _aspeco, 1);
 292                                 return true;
 293                         }
 294
 295                         float i, _bits = 0, _start = 1;
 296                         if(argv(1) == "clear")
 297                         {
 298                                 self.autospec_flags = 0;
 299                                 _start = 2;
 300                         }
 301
 302                         for(i = _start; i < cmd_argc; ++i)
 303                         {
 304                                 if(argv(i) == "on" || argv(i) == "1")
 305                                 {
 306                                         self.autospec_flags |= _bits;
 307                                         _bits = 0;
 308                                 }
 309                                 else if(argv(i) == "off" || argv(i) == "0")
 310                                 {
 311                                         if(_start == 1)
 312                                                 self.autospec_flags &= ~_bits;
 313
 314                                         _bits = 0;
 315                                 }
 316                                 else
 317                                 {
 318                                         if((argv(i) == "strength") || (argv(i) == "st")) _bits |= ASF_STRENGTH;
 319                                         if((argv(i) == "shield") || (argv(i) == "sh")) _bits |= ASF_SHIELD;
 320                                         if((argv(i) == "mega_health") || (argv(i) == "mh")) _bits |= ASF_MEGA_HP;
 321                                         if((argv(i) == "mega_armor") || (argv(i) == "ma")) _bits |= ASF_MEGA_AR;
 322                                         if((argv(i) == "flag_grab") || (argv(i) == "fg")) _bits |= ASF_FLAG_GRAB;
 323                                         if((argv(i) == "observer_only") || (argv(i) == "oo")) _bits |= ASF_OBSERVER_ONLY;
 324                                         if((argv(i) == "show_what") || (argv(i) == "sw")) _bits |= ASF_SHOWWHAT;
 325                                         if((argv(i) == "item_msg") || (argv(i) == "im")) _bits |= ASF_SSIM;
 326                                         if((argv(i) == "followkiller") || (argv(i) == "fk")) _bits |= ASF_FOLLOWKILLER;
 327                                         if((argv(i) == "all") || (argv(i) == "aa")) _bits |= ASF_ALL;
 328                                 }
 329                         }
 330                 }
 331
 332                 _aspeco = "";
 333                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_STRENGTH, "Strength", "strength", "st");
 334                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHIELD, "Shield", "shield", "sh");
 335                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_HP, "Mega Health", "mega_health", "mh");
 336                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_AR, "Mega Armor", "mega_armor", "ma");
 337                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FLAG_GRAB, "Flag grab", "flag_grab","fg");
 338                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_OBSERVER_ONLY, "Only switch if observer", "observer_only", "oo");
 339                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHOWWHAT, "Show what item triggered spectate", "show_what", "sw");
 340                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SSIM, "Switch on superspec item message", "item_msg", "im");
 341                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FOLLOWKILLER, "Followkiller", "followkiller", "fk");
 342
 343                 superspec_msg("^3Current auto spectate options are:\n\n\n\n\n", "\n^3Current auto spectate options are:\n", self, _aspeco, 1);
 344                 return true;
 345         }
 346
 347         if(cmd_name == "followpowerup")
 348         {
 349                 entity _player;
 350                 FOR_EACH_PLAYER(_player)
 351                 {
 352                         if(_player.strength_finished > time || _player.invincible_finished > time)
 353                                 return _spectate(_player);
 354                 }
 355
 356                 superspec_msg("", "", self, "No active powerup\n", 1);
 357                 return true;
 358         }
 359
 360         if(cmd_name == "followstrength")
 361         {
 362                 entity _player;
 363                 FOR_EACH_PLAYER(_player)
 364                 {
 365                         if(_player.strength_finished > time)
 366                                 return _spectate(_player);
 367                 }
 368
 369                 superspec_msg("", "", self, "No active Strength\n", 1);
 370                 return true;
 371         }
 372
 373         if(cmd_name == "followshield")
 374         {
 375                 entity _player;
 376                 FOR_EACH_PLAYER(_player)
 377                 {
 378                         if(_player.invincible_finished > time)
 379                                 return _spectate(_player);
 380                 }
 381
 382                 superspec_msg("", "", self, "No active Shield\n", 1);
 383                 return true;
 384         }
 385
 386         if(cmd_name == "followfc")
 387         {
 388                 if(!g_ctf)
 389                         return true;
 390
 391                 entity _player;
 392                 float _team = 0;
 393                 float found = false;
 394
 395                 if(cmd_argc == 2)
 396                 {
 397                         if(argv(1) == "red")
 398                                 _team = NUM_TEAM_1;
 399                         else
 400                                 _team = NUM_TEAM_2;
 401                 }
 402
 403                 FOR_EACH_PLAYER(_player)
 404                 {
 405                         if(_player.flagcarried && (_player.team == _team || _team == 0))
 406                         {
 407                                 found = true;
 408                                 if(_team == 0 && IS_SPEC(self) && self.enemy == _player)
 409                                         continue; // already spectating a fc, try to find the other fc
 410                                 return _spectate(_player);
 411                         }
 412                 }
 413
 414                 if(!found)
 415                         superspec_msg("", "", self, "No active flag carrier\n", 1);
 416                 return true;
 417         }
 418
 419         return false;
 420 #undef OPTIONINFO
 421 }
 422
 423 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsString)
 424 {
 425         ret_string = strcat(ret_string, ":SS");
 426         return 0;
 427 }
 428
 429 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsPrettyString)
 430 {
 431         ret_string = strcat(ret_string, ", Super Spectators");
 432         return 0;
 433 }
 434
 435 void superspec_hello()
 436 {SELFPARAM();
 437         if(self.enemy.crypto_idfp == "")
 438                 Send_Notification(NOTIF_ONE_ONLY, self.enemy, MSG_INFO, INFO_SUPERSPEC_MISSING_UID);
 439
 440         remove(self);
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(superspec_ClientConnect)
 444 {SELFPARAM();
 445         if(!IS_REAL_CLIENT(self))
 446                 return false;
 447
 448         string fn = "superspec-local.options";
 449         float fh;
 450
 451         self.superspec_flags = SSF_VERBOSE;
 452         self.superspec_itemfilter = "";
 453
 454         entity _hello = spawn();
 455         _hello.enemy = self;
 456         _hello.think = superspec_hello;
 457         _hello.nextthink = time + 5;
 458
 459         if (!_ISLOCAL)
 460         {
 461                 if(self.crypto_idfp == "")
 462                         return false;
 463
 464                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
 465         }
 466
 467         fh = fopen(fn, FILE_READ);
 468         if(fh < 0)
 469         {
 470                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for reading.\n");
 471         }
 472         else
 473         {
 474                 string _magic = fgets(fh);
 475                 if(_magic != _SSMAGIX)
 476                 {
 477                         LOG_TRACE("^1ERROR^7 While reading superspec options file: unknown magic\n");
 478                 }
 479                 else
 480                 {
 481                         self.autospec_flags = stof(fgets(fh));
 482                         self.superspec_flags = stof(fgets(fh));
 483                         self.superspec_itemfilter = strzone(fgets(fh));
 484                 }
 485                 fclose(fh);
 486         }
 487
 488         return false;
 489 }
 490
 491 MUTATOR_HOOKFUNCTION(superspec_PlayerDies)
 492 {SELFPARAM();
 493         entity e;
 494         FOR_EACH_SPEC(e)
 495         {
 496                 setself(e);
 497                 if(self.autospec_flags & ASF_FOLLOWKILLER && IS_PLAYER(frag_attacker) && self.enemy == this)
 498                 {
 499                         if(self.autospec_flags & ASF_SHOWWHAT)
 500                                 superspec_msg("", "", self, sprintf("^7Following %s^7 due to followkiller\n", frag_attacker.netname), 2);
 501
 502                         _spectate(frag_attacker);
 503                 }
 504         }
 505
 506         setself(this);
 507         return false;
 508 }
 509
 510 MUTATOR_HOOKFUNCTION(superspec_ClientDisconnect)
 511 {
 512         superspec_save_client_conf();
 513         return false;
 514 }
 515
 516 MUTATOR_DEFINITION(mutator_superspec)
 517 {
 518
 519         MUTATOR_HOOK(BuildMutatorsString, superspec_BuildMutatorsString, CBC_ORDER_ANY);
 520         MUTATOR_HOOK(BuildMutatorsPrettyString, superspec_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 521         MUTATOR_HOOK(SV_ParseClientCommand, superspec_SV_ParseClientCommand, CBC_ORDER_ANY);
 522         MUTATOR_HOOK(ItemTouch, superspec_ItemTouch, CBC_ORDER_ANY);
 523         MUTATOR_HOOK(ClientConnect, superspec_ClientConnect, CBC_ORDER_ANY);
 524         MUTATOR_HOOK(ClientDisconnect, superspec_ClientDisconnect, CBC_ORDER_ANY);
 525         MUTATOR_HOOK(PlayerDies, superspec_PlayerDies, CBC_ORDER_ANY);
 526
 527         return 0;
 528 }