qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_lms)
 281                         return FALSE;
 282                 if(g_ca)
 283                         return FALSE;
 284                 if(g_arena)
 285                         return FALSE;
 286         }
 287         else
 288         {
 289                 if(autocvar_g_pickup_items > 0)
 290                         return TRUE;
 291                 if(autocvar_g_pickup_items == 0)
 292                         return FALSE;
 293                 if(g_lms)
 294                         return FALSE;
 295                 if(g_ca)
 296                         return FALSE;
 297                 if(g_weaponarena)
 298                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 299                                 return FALSE;
 300         }
 301         return TRUE;
 302 }
 303
 304 #define ITEM_RESPAWN_TICKS 10
 305
 306 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 307         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 308 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 309         // range: 10 .. respawntime + respawntimejitter
 310
 311 floatfield Item_CounterField(float it)
 312 {
 313         switch(it)
 314         {
 315                 case IT_SHELLS:      return ammo_shells;
 316                 case IT_NAILS:       return ammo_nails;
 317                 case IT_ROCKETS:     return ammo_rockets;
 318                 case IT_CELLS:       return ammo_cells;
 319                 case IT_FUEL:        return ammo_fuel;
 320                 case IT_5HP:         return health;
 321                 case IT_25HP:        return health;
 322                 case IT_HEALTH:      return health;
 323                 case IT_ARMOR_SHARD: return armorvalue;
 324                 case IT_ARMOR:       return armorvalue;
 325                 // add more things here (health, armor)
 326                 default:             error("requested item has no counter field");
 327         }
 328 #ifdef GMQCC
 329         // should never happen
 330         return health;
 331 #endif
 332 }
 333
 334 string Item_CounterFieldName(float it)
 335 {
 336         switch(it)
 337         {
 338                 case IT_SHELLS:      return "shells";
 339                 case IT_NAILS:       return "nails";
 340                 case IT_ROCKETS:     return "rockets";
 341                 case IT_CELLS:       return "cells";
 342                 case IT_FUEL:        return "fuel";
 343
 344                 // add more things here (health, armor)
 345                 default:             error("requested item has no counter field name");
 346         }
 347 #ifdef GMQCC
 348         // should never happen
 349         return string_null;
 350 #endif
 351 }
 352
 353 .float max_armorvalue;
 354 .float pickup_anyway;
 355 /*
 356 float Item_Customize()
 357 {
 358         if(self.spawnshieldtime)
 359                 return TRUE;
 360         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 361         {
 362                 self.colormod = '0 0 0';
 363                 self.glowmod = self.colormod;
 364                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 365                 return TRUE;
 366         }
 367         else
 368         {
 369                 if(g_ghost_items)
 370                 {
 371                         self.colormod = stov(autocvar_g_ghost_items_color);
 372                         self.glowmod = self.colormod;
 373                         self.alpha = g_ghost_items;
 374                         return TRUE;
 375                 }
 376                 else
 377                         return FALSE;
 378         }
 379 }
 380 */
 381
 382 void Item_Show (entity e, float mode)
 383 {
 384         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 385         e.ItemStatus &~= ITS_STAYWEP;
 386         if (mode > 0)
 387         {
 388                 // make the item look normal, and be touchable
 389                 e.model = e.mdl;
 390                 e.solid = SOLID_TRIGGER;
 391                 e.spawnshieldtime = 1;
 392                 e.ItemStatus |= ITS_AVAILABLE;
 393         }
 394         else if (mode < 0)
 395         {
 396                 // hide the item completely
 397                 e.model = string_null;
 398                 e.solid = SOLID_NOT;
 399                 e.spawnshieldtime = 1;
 400                 e.ItemStatus &~= ITS_AVAILABLE;
 401         }
 402         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 403         {
 404                 // make the item translucent and not touchable
 405                 e.model = e.mdl;
 406                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 407                 e.effects |= EF_STARDUST;
 408                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 409                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 410         }
 411         else
 412         {
 413                 //setmodel(e, "null");
 414                 e.solid = SOLID_NOT;
 415                 e.colormod = '0 0 0';
 416                 e.glowmod = e.colormod;
 417                 e.spawnshieldtime = 1;
 418                 e.ItemStatus &~= ITS_AVAILABLE;
 419         }
 420
 421         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 422             e.ItemStatus |= ITS_POWERUP;
 423
 424         if (autocvar_g_nodepthtestitems)
 425                 e.effects |= EF_NODEPTHTEST;
 426
 427
 428     if (autocvar_g_fullbrightitems)
 429                 e.ItemStatus |= ITS_ALLOWFB;
 430
 431         if (autocvar_sv_simple_items)
 432         e.ItemStatus |= ITS_ALLOWSI;
 433
 434         // relink entity (because solid may have changed)
 435         setorigin(e, e.origin);
 436     e.SendFlags |= ISF_STATUS;
 437 }
 438
 439 void Item_Respawn (void)
 440 {
 441         Item_Show(self, 1);
 442         // this is ugly...
 443         if(self.items == IT_STRENGTH)
 444                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 445         else if(self.items == IT_INVINCIBLE)
 446                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 449         setorigin (self, self.origin);
 450
 451         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 452         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 453 }
 454
 455 void Item_RespawnCountdown (void)
 456 {
 457         if(self.count >= ITEM_RESPAWN_TICKS)
 458         {
 459                 if(self.waypointsprite_attached)
 460                         WaypointSprite_Kill(self.waypointsprite_attached);
 461                 Item_Respawn();
 462         }
 463         else
 464         {
 465                 self.nextthink = time + 1;
 466                 self.count += 1;
 467                 if(self.count == 1)
 468                 {
 469                         string name;
 470                         vector rgb = '1 0 1';
 471                         name = string_null;
 472                         switch(self.items)
 473                         {
 474                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 475                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 476                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 477                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 478                         }
 479                         item_name = name;
 480                         item_color = rgb;
 481                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 482                         name = item_name;
 483                         rgb = item_color;
 484                         if(self.flags & FL_WEAPON)
 485                         {
 486                                 entity wi = get_weaponinfo(self.weapon);
 487                                 if(wi)
 488                                 {
 489                                         name = wi.model2;
 490                                         rgb = '1 0 0';
 491                                 }
 492                         }
 493                         if(name)
 494                         {
 495                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 496                                 if(self.waypointsprite_attached)
 497                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 498                         }
 499                         else
 500                         {
 501                                 print("Unknown powerup-marked item is wanting to respawn\n");
 502                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 503                         }
 504                 }
 505                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 506                 if(self.waypointsprite_attached)
 507                 {
 508                         WaypointSprite_Ping(self.waypointsprite_attached);
 509                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 510                 }
 511         }
 512 }
 513
 514 void Item_ScheduleRespawnIn(entity e, float t)
 515 {
 516         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 517         {
 518                 e.think = Item_RespawnCountdown;
 519                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 520                 e.count = 0;
 521         }
 522         else
 523         {
 524                 e.think = Item_Respawn;
 525                 e.nextthink = time + t;
 526         }
 527 }
 528
 529 void Item_ScheduleRespawn(entity e)
 530 {
 531         if(e.respawntime > 0)
 532         {
 533                 Item_Show(e, 0);
 534                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 535         }
 536         else // if respawntime is -1, this item does not respawn
 537                 Item_Show(e, -1);
 538 }
 539
 540 void Item_ScheduleInitialRespawn(entity e)
 541 {
 542         Item_Show(e, 0);
 543         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 544 }
 545
 546 float ITEM_MODE_NONE = 0;
 547 float ITEM_MODE_HEALTH = 1;
 548 float ITEM_MODE_ARMOR = 2;
 549 float ITEM_MODE_FUEL = 3;
 550 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 551 {
 552         if (!item.ammofield)
 553                 return FALSE;
 554
 555         if (item.spawnshieldtime)
 556         {
 557                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 558                 {
 559                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 560                         goto YEAH;
 561                 }
 562         }
 563         else if(g_weapon_stay == 2)
 564         {
 565                 float mi = min(item.ammofield, ammomax);
 566                 if (player.ammofield < mi)
 567                 {
 568                         player.ammofield = mi;
 569                         goto YEAH;
 570                 }
 571         }
 572
 573         return FALSE;
 574
 575 :YEAH
 576         switch(mode)
 577         {
 578                 case ITEM_MODE_FUEL:
 579                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 580                         break;
 581                 case ITEM_MODE_HEALTH:
 582                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 583                         break;
 584                 case ITEM_MODE_ARMOR:
 585                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 586                         break;
 587                 default:
 588                         break;
 589         }
 590         return TRUE;
 591 }
 592
 593 float Item_GiveTo(entity item, entity player)
 594 {
 595         float _switchweapon;
 596         float pickedup;
 597         float it;
 598         float i;
 599
 600         // if nothing happens to player, just return without taking the item
 601         pickedup = FALSE;
 602         _switchweapon = FALSE;
 603         // in case the player has autoswitch enabled do the following:
 604         // if the player is using their best weapon before items are given, they
 605         // probably want to switch to an even better weapon after items are given
 606         if (player.autoswitch)
 607         if (player.switchweapon == w_getbestweapon(player))
 608                 _switchweapon = TRUE;
 609
 610         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 611                 _switchweapon = TRUE;
 612
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 614         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 615         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 616         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 617         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 618         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 619         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 620
 621         if (item.flags & FL_WEAPON)
 622         {
 623                 WEPSET_DECLARE_A(it);
 624                 WEPSET_COPY_AE(it, item);
 625                 WEPSET_ANDNOT_AE(it, player);
 626
 627                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 628                 {
 629                 pickedup = TRUE;
 630                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 631                         if(WEPSET_CONTAINS_AW(it, i))
 632                         W_GiveWeapon(player, i);
 633                 }
 634         }
 635
 636         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 637         {
 638                 pickedup = TRUE;
 639                 player.items |= it;
 640                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 641         }
 642
 643         if (item.strength_finished)
 644         {
 645                 pickedup = TRUE;
 646                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 647         }
 648         if (item.invincible_finished)
 649         {
 650                 pickedup = TRUE;
 651                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 652         }
 653         if (item.superweapons_finished)
 654         {
 655                 pickedup = TRUE;
 656                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 657         }
 658
 659 :skip
 660
 661         other = player;
 662         giveitem = item;
 663         player_wswitch = _switchweapon;
 664         player_pickedup = pickedup;
 665         MUTATOR_CALLHOOK(Item_GiveTo);
 666         _switchweapon = player_wswitch;
 667         pickedup = player_pickedup;
 668
 669         // always eat teamed entities
 670         if(item.team)
 671                 pickedup = TRUE;
 672
 673         if (!pickedup)
 674                 return 0;
 675
 676         if (_switchweapon)
 677                 if (player.switchweapon != w_getbestweapon(player))
 678                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 679
 680         return 1;
 681 }
 682
 683 void Item_Touch (void)
 684 {
 685         entity e, head;
 686
 687         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 688         if(self.classname == "droppedweapon")
 689         {
 690                 if (ITEM_TOUCH_NEEDKILL())
 691                 {
 692                         remove(self);
 693                         return;
 694                 }
 695         }
 696
 697         if (other.classname != "player")
 698                 return;
 699         if (other.deadflag)
 700                 return;
 701         if (self.solid != SOLID_TRIGGER)
 702                 return;
 703         if (self.owner == other)
 704                 return;
 705         if(MUTATOR_CALLHOOK(ItemTouch))
 706                 return;
 707
 708         if (self.classname == "droppedweapon")
 709         {
 710                 self.strength_finished = max(0, self.strength_finished - time);
 711                 self.invincible_finished = max(0, self.invincible_finished - time);
 712                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 713         }
 714
 715         if(!Item_GiveTo(self, other))
 716         {
 717                 if (self.classname == "droppedweapon")
 718                 {
 719                         // undo what we did above
 720                         self.strength_finished += time;
 721                         self.invincible_finished += time;
 722                         self.superweapons_finished += time;
 723                 }
 724                 return;
 725         }
 726
 727         other.last_pickup = time;
 728
 729         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 730         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 731
 732         if (self.classname == "droppedweapon")
 733                 remove (self);
 734         else if not(self.spawnshieldtime)
 735                 return;
 736         else
 737         {
 738                 if(self.team)
 739                 {
 740                         RandomSelection_Init();
 741                         for(head = world; (head = findfloat(head, team, self.team)); )
 742                         {
 743                                 if(head.flags & FL_ITEM)
 744                                 {
 745                                         Item_Show(head, -1);
 746                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 747                                 }
 748                         }
 749                         e = RandomSelection_chosen_ent;
 750
 751                 }
 752                 else
 753                         e = self;
 754                 Item_ScheduleRespawn(e);
 755         }
 756 }
 757
 758 void Item_Reset()
 759 {
 760         Item_Show(self, !self.state);
 761         setorigin (self, self.origin);
 762
 763         if(self.classname != "droppedweapon")
 764         {
 765                 self.think = func_null;
 766                 self.nextthink = 0;
 767
 768                 if(self.waypointsprite_attached)
 769                         WaypointSprite_Kill(self.waypointsprite_attached);
 770
 771                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 772                         Item_ScheduleInitialRespawn(self);
 773         }
 774 }
 775
 776 void Item_FindTeam()
 777 {
 778         entity head, e;
 779
 780         if(self.effects & EF_NODRAW)
 781         {
 782                 // marker for item team search
 783                 dprint("Initializing item team ", ftos(self.team), "\n");
 784                 RandomSelection_Init();
 785                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 786                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 787                 e = RandomSelection_chosen_ent;
 788                 e.state = 0;
 789                 Item_Show(e, 1);
 790
 791                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 792                 {
 793                         if(head != e)
 794                         {
 795                                 // make it a non-spawned item
 796                                 Item_Show(head, -1);
 797                                 head.state = 1; // state 1 = initially hidden item
 798                         }
 799                         head.effects &~= EF_NODRAW;
 800                 }
 801
 802                 Item_Reset();
 803         }
 804 }
 805
 806 // Savage: used for item garbage-collection
 807 // TODO: perhaps nice special effect?
 808 void RemoveItem(void)
 809 {
 810         remove(self);
 811 }
 812
 813 // pickup evaluation functions
 814 // these functions decide how desirable an item is to the bots
 815
 816 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 817
 818 float weapon_pickupevalfunc(entity player, entity item)
 819 {
 820         float c, j, position;
 821
 822         // See if I have it already
 823         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 824         {
 825                 // If I can pick it up
 826                 if(!item.spawnshieldtime)
 827                         c = 0;
 828                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 829                 {
 830                         // Skilled bots will grab more
 831                         c = bound(0, skill / 10, 1) * 0.5;
 832                 }
 833                 else
 834                         c = 0;
 835         }
 836         else
 837                 c = 1;
 838
 839         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 840         if( bot_custom_weapon && c )
 841         {
 842                 // Find the highest position on any range
 843                 position = -1;
 844                 for(j = 0; j < WEP_LAST ; ++j){
 845                         if(
 846                                         bot_weapons_far[j] == item.weapon ||
 847                                         bot_weapons_mid[j] == item.weapon ||
 848                                         bot_weapons_close[j] == item.weapon
 849                           )
 850                         {
 851                                 position = j;
 852                                 break;
 853                         }
 854                 }
 855
 856                 // Rate it
 857                 if (position >= 0 )
 858                 {
 859                         position = WEP_LAST - position;
 860                         // item.bot_pickupbasevalue is overwritten here
 861                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 862                 }
 863         }
 864
 865         return item.bot_pickupbasevalue * c;
 866 }
 867
 868 float commodity_pickupevalfunc(entity player, entity item)
 869 {
 870         float c, i;
 871         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 872         entity wi;
 873         c = 0;
 874
 875         // Detect needed ammo
 876         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 877         {
 878                 wi = get_weaponinfo(i);
 879
 880                 if not(WEPSET_CONTAINS_EW(player, i))
 881                         continue;
 882
 883                 if(wi.items & IT_SHELLS)
 884                         need_shells = TRUE;
 885                 else if(wi.items & IT_NAILS)
 886                         need_nails = TRUE;
 887                 else if(wi.items & IT_ROCKETS)
 888                         need_rockets = TRUE;
 889                 else if(wi.items & IT_CELLS)
 890                         need_cells = TRUE;
 891                 else if(wi.items & IT_FUEL)
 892                         need_cells = TRUE;
 893         }
 894
 895         // TODO: figure out if the player even has the weapon this ammo is for?
 896         // may not affect strategy much though...
 897         // find out how much more ammo/armor/health the player can hold
 898         if (need_shells)
 899         if (item.ammo_shells)
 900         if (player.ammo_shells < g_pickup_shells_max)
 901                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 902         if (need_nails)
 903         if (item.ammo_nails)
 904         if (player.ammo_nails < g_pickup_nails_max)
 905                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 906         if (need_rockets)
 907         if (item.ammo_rockets)
 908         if (player.ammo_rockets < g_pickup_rockets_max)
 909                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 910         if (need_cells)
 911         if (item.ammo_cells)
 912         if (player.ammo_cells < g_pickup_cells_max)
 913                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 914         if (need_fuel)
 915         if (item.ammo_fuel)
 916         if (player.ammo_fuel < g_pickup_fuel_max)
 917                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 918         if (item.armorvalue)
 919         if (player.armorvalue < item.max_armorvalue)
 920                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 921         if (item.health)
 922         if (player.health < item.max_health)
 923                 c = c + max(0, 1 - player.health / item.max_health);
 924
 925         return item.bot_pickupbasevalue * c;
 926 }
 927
 928 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 929 {
 930         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 931                 RemoveItem();
 932 }
 933
 934 .float is_item;
 935 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 936 {
 937         startitem_failed = FALSE;
 938
 939         if(self.model == "")
 940                 self.model = itemmodel;
 941
 942         if(self.model == "")
 943     {
 944         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 945         return;
 946     }
 947
 948         if(self.item_pickupsound == "")
 949                 self.item_pickupsound = pickupsound;
 950
 951         if(!self.respawntime) // both need to be set
 952         {
 953                 self.respawntime = defaultrespawntime;
 954                 self.respawntimejitter = defaultrespawntimejitter;
 955         }
 956
 957         self.items = itemid;
 958         self.weapon = weaponid;
 959
 960         if(weaponid)
 961                 WEPSET_COPY_EW(self, weaponid);
 962
 963         self.flags = FL_ITEM | itemflags;
 964
 965         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 966         {
 967                 startitem_failed = TRUE;
 968                 remove(self);
 969                 return;
 970         }
 971
 972         // is it a dropped weapon?
 973         if (self.classname == "droppedweapon")
 974         {
 975                 self.reset = SUB_Remove;
 976                 // it's a dropped weapon
 977                 self.movetype = MOVETYPE_TOSS;
 978
 979                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 980                 self.think = RemoveItem;
 981                 self.nextthink = time + 20;
 982
 983                 self.takedamage = DAMAGE_YES;
 984                 self.event_damage = Item_Damage;
 985
 986                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 987                 /*
 988                 if(self.items == 0)
 989                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 990                 if(self.ammo_nails == 0)
 991                 if(self.ammo_cells == 0)
 992                 if(self.ammo_rockets == 0)
 993                 if(self.ammo_shells == 0)
 994                 if(self.ammo_fuel == 0)
 995                 if(self.health == 0)
 996                 if(self.armorvalue == 0)
 997                 */
 998                 {
 999                         // if item is worthless after a timer, have it expire then
1000                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1001                 }
1002
1003                 // don't drop if in a NODROP zone (such as lava)
1004                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1005                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1006                 {
1007                         startitem_failed = TRUE;
1008                         remove(self);
1009                         return;
1010                 }
1011         }
1012         else
1013         {
1014                 if(!have_pickup_item())
1015                 {
1016                         startitem_failed = TRUE;
1017                         remove (self);
1018                         return;
1019                 }
1020
1021                 if(self.angles != '0 0 0')
1022             self.SendFlags |= ISF_ANGLES;
1023
1024                 self.reset = Item_Reset;
1025                 // it's a level item
1026                 if(self.spawnflags & 1)
1027                         self.noalign = 1;
1028                 if (self.noalign)
1029                         self.movetype = MOVETYPE_NONE;
1030                 else
1031                         self.movetype = MOVETYPE_TOSS;
1032                 // do item filtering according to game mode and other things
1033                 if (!self.noalign)
1034                 {
1035                         // first nudge it off the floor a little bit to avoid math errors
1036                         setorigin(self, self.origin + '0 0 1');
1037                         // set item size before we spawn a spawnfunc_waypoint
1038                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1039                                 setsize (self, '-16 -16 0', '16 16 48');
1040                         else
1041                                 setsize (self, '-16 -16 0', '16 16 32');
1042                         // note droptofloor returns FALSE if stuck/or would fall too far
1043                         droptofloor();
1044                         waypoint_spawnforitem(self);
1045                 }
1046
1047                 /*
1048                  * can't do it that way, as it would break maps
1049                  * TODO make a target_give like entity another way, that perhaps has
1050                  * the weapon name in a key
1051                 if(self.targetname)
1052                 {
1053                         // target_give not yet supported; maybe later
1054                         print("removed targeted ", self.classname, "\n");
1055                         startitem_failed = TRUE;
1056                         remove (self);
1057                         return;
1058                 }
1059                 */
1060
1061                 if(autocvar_spawn_debug >= 2)
1062                 {
1063                         entity otheritem;
1064                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1065                         {
1066                             // why not flags & fl_item?
1067                                 if(otheritem.is_item)
1068                                 {
1069                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1070                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1071                                         error("Mapper sucks.");
1072                                 }
1073                         }
1074                         self.is_item = TRUE;
1075                 }
1076
1077                 WEPSET_OR_AW(weaponsInMap, weaponid);
1078
1079                 precache_model (self.model);
1080                 precache_sound (self.item_pickupsound);
1081
1082                 precache_sound ("misc/itemrespawncountdown.wav");
1083                 if(itemid == IT_STRENGTH)
1084                         precache_sound ("misc/strength_respawn.wav");
1085                 else if(itemid == IT_INVINCIBLE)
1086                         precache_sound ("misc/shield_respawn.wav");
1087                 else
1088                         precache_sound ("misc/itemrespawn.wav");
1089
1090                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1091                         self.target = "###item###"; // for finding the nearest item using find()
1092         }
1093
1094         self.bot_pickup = TRUE;
1095         self.bot_pickupevalfunc = pickupevalfunc;
1096         self.bot_pickupbasevalue = pickupbasevalue;
1097         self.mdl = self.model;
1098         self.netname = itemname;
1099         self.touch = Item_Touch;
1100         setmodel(self, "null"); // precision set below
1101         //self.effects |= EF_LOWPRECISION;
1102
1103         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1104     {
1105         self.pos1 = '-16 -16 0';
1106         self.pos2 = '16 16 48';
1107     }
1108         else
1109     {
1110         self.pos1 = '-16 -16 0';
1111         self.pos2 = '16 16 32';
1112     }
1113     setsize (self, self.pos1, self.pos2);
1114
1115     if(itemflags & FL_POWERUP)
1116         self.ItemStatus |= ITS_ANIMATE1;
1117
1118         if(self.armorvalue || self.health)
1119         self.ItemStatus |= ITS_ANIMATE2;
1120
1121         if(itemflags & FL_WEAPON)
1122         {
1123                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1124             self.colormap = 1024; // color shirt=0 pants=0 grey
1125         else
1126             self.gravity = 1;
1127
1128                 self.ItemStatus |= ITS_ANIMATE1;
1129                 self.ItemStatus |= ISF_COLORMAP;
1130         }
1131
1132         self.state = 0;
1133         if(self.team) // broken, no idea why.
1134         {
1135                 if(!self.cnt)
1136                         self.cnt = 1; // item probability weight
1137
1138                 self.effects |= EF_NODRAW; // marker for item team search
1139                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1140         }
1141         else
1142                 Item_Reset();
1143
1144     Net_LinkEntity(self, FALSE, 0, ItemSend);
1145
1146         // call this hook after everything else has been done
1147         if(MUTATOR_CALLHOOK(Item_Spawn))
1148         {
1149                 startitem_failed = TRUE;
1150                 remove(self);
1151                 return;
1152         }
1153 }
1154
1155 float weaponswapping;
1156 float internalteam;
1157
1158 void weapon_defaultspawnfunc(float wpn)
1159 {
1160         entity e;
1161         float t;
1162         var .float ammofield;
1163         string s;
1164         entity oldself;
1165         float i, j;
1166         float f;
1167
1168         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1169         {
1170                 e = get_weaponinfo(wpn);
1171
1172                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1173                 {
1174                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1175                         /*
1176                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1177                         startitem_failed = TRUE;
1178                         return;
1179                         */
1180                 }
1181
1182                 s = W_Apply_Weaponreplace(e.netname);
1183                 ret_string = s;
1184                 other = e;
1185                 MUTATOR_CALLHOOK(SetWeaponreplace);
1186                 s = ret_string;
1187                 if(s == "")
1188                 {
1189                         remove(self);
1190                         startitem_failed = TRUE;
1191                         return;
1192                 }
1193                 t = tokenize_console(s);
1194                 if(t >= 2)
1195                 {
1196                         self.team = --internalteam;
1197                         oldself = self;
1198                         for(i = 1; i < t; ++i)
1199                         {
1200                                 s = argv(i);
1201                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1202                                 {
1203                                         e = get_weaponinfo(j);
1204                                         if(e.netname == s)
1205                                         {
1206                                                 self = spawn();
1207                                                 copyentity(oldself, self);
1208                                                 self.classname = "replacedweapon";
1209                                                 weapon_defaultspawnfunc(j);
1210                                                 break;
1211                                         }
1212                                 }
1213                                 if(j > WEP_LAST)
1214                                 {
1215                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1216                                 }
1217                         }
1218                         self = oldself;
1219                 }
1220                 if(t >= 1) // always the case!
1221                 {
1222                         s = argv(0);
1223                         wpn = 0;
1224                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1225                         {
1226                                 e = get_weaponinfo(j);
1227                                 if(e.netname == s)
1228                                 {
1229                                         wpn = j;
1230                                         break;
1231                                 }
1232                         }
1233                         if(j > WEP_LAST)
1234                         {
1235                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1236                         }
1237                 }
1238                 if(wpn == 0)
1239                 {
1240                         remove(self);
1241                         startitem_failed = TRUE;
1242                         return;
1243                 }
1244         }
1245
1246         e = get_weaponinfo(wpn);
1247
1248         if(!self.respawntime)
1249         {
1250                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1251                 {
1252                         self.respawntime = g_pickup_respawntime_superweapon;
1253                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1254                 }
1255                 else
1256                 {
1257                         self.respawntime = g_pickup_respawntime_weapon;
1258                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1259                 }
1260         }
1261
1262         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1263                 if(!self.superweapons_finished)
1264                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1265
1266         if(e.items)
1267         {
1268                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1269                 {
1270                         if(e.items & j)
1271                         {
1272                                 ammofield = Item_CounterField(j);
1273                                 if(!self.ammofield)
1274                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1275                         }
1276                 }
1277         }
1278
1279         // pickup anyway
1280         if(g_pickup_weapons_anyway)
1281                 self.pickup_anyway = TRUE;
1282
1283         f = FL_WEAPON;
1284
1285         // no weapon-stay on superweapons
1286         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1287                 f |= FL_NO_WEAPON_STAY;
1288
1289         // weapon stay isn't supported for teamed weapons
1290         if(self.team)
1291                 f |= FL_NO_WEAPON_STAY;
1292
1293         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1294         if (self.modelindex) // don't precache if self was removed
1295                 weapon_action(e.weapon, WR_PRECACHE);
1296 }
1297
1298 void spawnfunc_weapon_shotgun (void);
1299 void spawnfunc_weapon_uzi (void) {
1300         if(autocvar_sv_q3acompat_machineshotgunswap)
1301         if(self.classname != "droppedweapon")
1302         {
1303                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1304                 return;
1305         }
1306         weapon_defaultspawnfunc(WEP_UZI);
1307 }
1308
1309 void spawnfunc_weapon_shotgun (void) {
1310         if(autocvar_sv_q3acompat_machineshotgunswap)
1311         if(self.classname != "droppedweapon")
1312         {
1313                 weapon_defaultspawnfunc(WEP_UZI);
1314                 return;
1315         }
1316         weapon_defaultspawnfunc(WEP_SHOTGUN);
1317 }
1318
1319 void spawnfunc_weapon_nex (void)
1320 {
1321         weapon_defaultspawnfunc(WEP_NEX);
1322 }
1323
1324 void spawnfunc_weapon_minstanex (void)
1325 {
1326         weapon_defaultspawnfunc(WEP_MINSTANEX);
1327 }
1328
1329 void spawnfunc_weapon_rocketlauncher (void)
1330 {
1331         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1332 }
1333
1334 void spawnfunc_item_rockets (void) {
1335         if(!self.ammo_rockets)
1336                 self.ammo_rockets = g_pickup_rockets;
1337         if(!self.pickup_anyway)
1338                 self.pickup_anyway = g_pickup_ammo_anyway;
1339         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1340 }
1341
1342 void spawnfunc_item_shells (void);
1343 void spawnfunc_item_bullets (void) {
1344         if(!weaponswapping)
1345         if(autocvar_sv_q3acompat_machineshotgunswap)
1346         if(self.classname != "droppedweapon")
1347         {
1348                 weaponswapping = TRUE;
1349                 spawnfunc_item_shells();
1350                 weaponswapping = FALSE;
1351                 return;
1352         }
1353
1354         if(!self.ammo_nails)
1355                 self.ammo_nails = g_pickup_nails;
1356         if(!self.pickup_anyway)
1357                 self.pickup_anyway = g_pickup_ammo_anyway;
1358         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1359 }
1360
1361 void spawnfunc_item_cells (void) {
1362         if(!self.ammo_cells)
1363                 self.ammo_cells = g_pickup_cells;
1364         if(!self.pickup_anyway)
1365                 self.pickup_anyway = g_pickup_ammo_anyway;
1366         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1367 }
1368
1369 void spawnfunc_item_shells (void) {
1370         if(!weaponswapping)
1371         if(autocvar_sv_q3acompat_machineshotgunswap)
1372         if(self.classname != "droppedweapon")
1373         {
1374                 weaponswapping = TRUE;
1375                 spawnfunc_item_bullets();
1376                 weaponswapping = FALSE;
1377                 return;
1378         }
1379
1380         if(!self.ammo_shells)
1381                 self.ammo_shells = g_pickup_shells;
1382         if(!self.pickup_anyway)
1383                 self.pickup_anyway = g_pickup_ammo_anyway;
1384         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1385 }
1386
1387 void spawnfunc_item_armor_small (void) {
1388         if(!self.armorvalue)
1389                 self.armorvalue = g_pickup_armorsmall;
1390         if(!self.max_armorvalue)
1391                 self.max_armorvalue = g_pickup_armorsmall_max;
1392         if(!self.pickup_anyway)
1393                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1394         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1395 }
1396
1397 void spawnfunc_item_armor_medium (void) {
1398         if(!self.armorvalue)
1399                 self.armorvalue = g_pickup_armormedium;
1400         if(!self.max_armorvalue)
1401                 self.max_armorvalue = g_pickup_armormedium_max;
1402         if(!self.pickup_anyway)
1403                 self.pickup_anyway = g_pickup_armormedium_anyway;
1404         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1405 }
1406
1407 void spawnfunc_item_armor_big (void) {
1408         if(!self.armorvalue)
1409                 self.armorvalue = g_pickup_armorbig;
1410         if(!self.max_armorvalue)
1411                 self.max_armorvalue = g_pickup_armorbig_max;
1412         if(!self.pickup_anyway)
1413                 self.pickup_anyway = g_pickup_armorbig_anyway;
1414         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1415 }
1416
1417 void spawnfunc_item_armor_large (void) {
1418         if(!self.armorvalue)
1419                 self.armorvalue = g_pickup_armorlarge;
1420         if(!self.max_armorvalue)
1421                 self.max_armorvalue = g_pickup_armorlarge_max;
1422         if(!self.pickup_anyway)
1423                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1424         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1425 }
1426
1427 void spawnfunc_item_health_small (void) {
1428         if(!self.max_health)
1429                 self.max_health = g_pickup_healthsmall_max;
1430         if(!self.health)
1431                 self.health = g_pickup_healthsmall;
1432         if(!self.pickup_anyway)
1433                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1434         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1435 }
1436
1437 void spawnfunc_item_health_medium (void) {
1438         if(!self.max_health)
1439                 self.max_health = g_pickup_healthmedium_max;
1440         if(!self.health)
1441                 self.health = g_pickup_healthmedium;
1442         if(!self.pickup_anyway)
1443                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1444         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1445 }
1446
1447 void spawnfunc_item_health_large (void) {
1448         if(!self.max_health)
1449                 self.max_health = g_pickup_healthlarge_max;
1450         if(!self.health)
1451                 self.health = g_pickup_healthlarge;
1452         if(!self.pickup_anyway)
1453                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1454         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1455 }
1456
1457 void spawnfunc_item_health_mega (void) {
1458                 if(!self.max_health)
1459                         self.max_health = g_pickup_healthmega_max;
1460                 if(!self.health)
1461                         self.health = g_pickup_healthmega;
1462                 if(!self.pickup_anyway)
1463                         self.pickup_anyway = g_pickup_healthmega_anyway;
1464                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1465 }
1466
1467 // support old misnamed entities
1468 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1469 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1470 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1471 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1472 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1473
1474 void spawnfunc_item_strength (void) {
1475                 precache_sound("weapons/strength_fire.wav");
1476                 if(!self.strength_finished)
1477                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1478                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1479 }
1480
1481 void spawnfunc_item_invincible (void) {
1482                 if(!self.invincible_finished)
1483                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1484                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1485 }
1486
1487 // compatibility:
1488 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1489
1490 float GiveItems(entity e, float beginarg, float endarg);
1491 void target_items_use (void)
1492 {
1493         if(activator.classname == "droppedweapon")
1494         {
1495                 EXACTTRIGGER_TOUCH;
1496                 remove(activator);
1497                 return;
1498         }
1499
1500         if(activator.classname != "player")
1501                 return;
1502         if(activator.deadflag != DEAD_NO)
1503                 return;
1504         EXACTTRIGGER_TOUCH;
1505
1506         entity e;
1507         for(e = world; (e = find(e, classname, "droppedweapon")); )
1508                 if(e.enemy == activator)
1509                         remove(e);
1510
1511         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1512                 centerprint(activator, self.message);
1513 }
1514
1515 void spawnfunc_target_items (void)
1516 {
1517         float n, i, j;
1518         entity e;
1519
1520         self.use = target_items_use;
1521         if(!self.strength_finished)
1522                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1523         if(!self.invincible_finished)
1524                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1525         if(!self.superweapons_finished)
1526                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1527
1528         precache_sound("misc/itempickup.wav");
1529         precache_sound("misc/megahealth.wav");
1530         precache_sound("misc/armor25.wav");
1531         precache_sound("misc/powerup.wav");
1532         precache_sound("misc/poweroff.wav");
1533         precache_sound("weapons/weaponpickup.wav");
1534
1535         n = tokenize_console(self.netname);
1536         if(argv(0) == "give")
1537         {
1538                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1539         }
1540         else
1541         {
1542                 for(i = 0; i < n; ++i)
1543                 {
1544                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1545                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1546                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1547                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1548                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1549                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1550                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1551                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1552                         else
1553                         {
1554                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1555                                 {
1556                                         e = get_weaponinfo(j);
1557                                         if(argv(i) == e.netname)
1558                                         {
1559                                                 WEPSET_OR_EW(self, j);
1560                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1561                                                         weapon_action(e.weapon, WR_PRECACHE);
1562                                                 break;
1563                                         }
1564                                 }
1565                                 if(j > WEP_LAST)
1566                                         print("target_items: invalid item ", argv(i), "\n");
1567                         }
1568                 }
1569
1570                 string itemprefix, valueprefix;
1571                 if(self.spawnflags == 0)
1572                 {
1573                         itemprefix = "";
1574                         valueprefix = "";
1575                 }
1576                 else if(self.spawnflags == 1)
1577                 {
1578                         itemprefix = "max ";
1579                         valueprefix = "max ";
1580                 }
1581                 else if(self.spawnflags == 2)
1582                 {
1583                         itemprefix = "min ";
1584                         valueprefix = "min ";
1585                 }
1586                 else if(self.spawnflags == 4)
1587                 {
1588                         itemprefix = "minus ";
1589                         valueprefix = "max ";
1590                 }
1591                 else
1592                 {
1593                         error("invalid spawnflags");
1594 #ifdef GMQCC
1595                         itemprefix = string_null;
1596                         valueprefix = string_null;
1597 #endif
1598                 }
1599
1600                 self.netname = "";
1601                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1602                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1603                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1604                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1605                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1606                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1607                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1608                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1609                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1610                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1611                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1612                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1613                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1614                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1615                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1616                 {
1617                         e = get_weaponinfo(j);
1618                         if(e.weapon)
1619                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1620                 }
1621         }
1622         self.netname = strzone(self.netname);
1623         //print(self.netname, "\n");
1624
1625         n = tokenize_console(self.netname);
1626         for(i = 0; i < n; ++i)
1627         {
1628                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1629                 {
1630                         e = get_weaponinfo(j);
1631                         if(argv(i) == e.netname)
1632                         {
1633                                 weapon_action(e.weapon, WR_PRECACHE);
1634                                 break;
1635                         }
1636                 }
1637         }
1638 }
1639
1640 void spawnfunc_item_fuel(void)
1641 {
1642         if(!self.ammo_fuel)
1643                 self.ammo_fuel = g_pickup_fuel;
1644         if(!self.pickup_anyway)
1645                 self.pickup_anyway = g_pickup_ammo_anyway;
1646         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1647 }
1648
1649 void spawnfunc_item_fuel_regen(void)
1650 {
1651         if(start_items & IT_FUEL_REGEN)
1652         {
1653                 spawnfunc_item_fuel();
1654                 return;
1655         }
1656         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1657 }
1658
1659 void spawnfunc_item_jetpack(void)
1660 {
1661         if(g_grappling_hook)
1662                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1663         if(!self.ammo_fuel)
1664                 self.ammo_fuel = g_pickup_fuel_jetpack;
1665         if(start_items & IT_JETPACK)
1666         {
1667                 spawnfunc_item_fuel();
1668                 return;
1669         }
1670         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1671 }
1672
1673
1674 #define OP_SET 0
1675 #define OP_MIN 1
1676 #define OP_MAX 2
1677 #define OP_PLUS 3
1678 #define OP_MINUS 4
1679
1680 float GiveWeapon(entity e, float wpn, float op, float val)
1681 {
1682         float v0, v1;
1683         v0 = WEPSET_CONTAINS_EW(e, wpn);
1684         switch(op)
1685         {
1686                 case OP_SET:
1687                         if(val > 0)
1688                                 WEPSET_OR_EW(e, wpn);
1689                         else
1690                                 WEPSET_ANDNOT_EW(e, wpn);
1691                         break;
1692                 case OP_MIN:
1693                 case OP_PLUS:
1694                         if(val > 0)
1695                                 WEPSET_OR_EW(e, wpn);
1696                         break;
1697                 case OP_MAX:
1698                         if(val <= 0)
1699                                 WEPSET_ANDNOT_EW(e, wpn);
1700                         break;
1701                 case OP_MINUS:
1702                         if(val > 0)
1703                                 WEPSET_ANDNOT_EW(e, wpn);
1704                         break;
1705         }
1706         v1 = WEPSET_CONTAINS_EW(e, wpn);
1707         return (v0 != v1);
1708 }
1709
1710 float GiveBit(entity e, .float fld, float bit, float op, float val)
1711 {
1712         float v0, v1;
1713         v0 = (e.fld & bit);
1714         switch(op)
1715         {
1716                 case OP_SET:
1717                         if(val > 0)
1718                                 e.fld |= bit;
1719                         else
1720                                 e.fld &~= bit;
1721                         break;
1722                 case OP_MIN:
1723                 case OP_PLUS:
1724                         if(val > 0)
1725                                 e.fld |= bit;
1726                         break;
1727                 case OP_MAX:
1728                         if(val <= 0)
1729                                 e.fld &~= bit;
1730                         break;
1731                 case OP_MINUS:
1732                         if(val > 0)
1733                                 e.fld &~= bit;
1734                         break;
1735         }
1736         v1 = (e.fld & bit);
1737         return (v0 != v1);
1738 }
1739
1740 float GiveValue(entity e, .float fld, float op, float val)
1741 {
1742         float v0, v1;
1743         v0 = e.fld;
1744         switch(op)
1745         {
1746                 case OP_SET:
1747                         e.fld = val;
1748                         break;
1749                 case OP_MIN:
1750                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1751                         break;
1752                 case OP_MAX:
1753                         e.fld = min(e.fld, val);
1754                         break;
1755                 case OP_PLUS:
1756                         e.fld += val;
1757                         break;
1758                 case OP_MINUS:
1759                         e.fld -= val;
1760                         break;
1761         }
1762         v1 = e.fld;
1763         return (v0 != v1);
1764 }
1765
1766 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1767 {
1768         if(v1 == v0)
1769                 return;
1770         if(v1 <= v0 - t)
1771         {
1772                 if(snd_decr != "")
1773                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1774         }
1775         else if(v0 >= v0 + t)
1776         {
1777                 if(snd_incr != "")
1778                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1779         }
1780 }
1781
1782 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1783 {
1784         if(v0 < v1)
1785                 e.rotfield = max(e.rotfield, time + rottime);
1786         else if(v0 > v1)
1787                 e.regenfield = max(e.regenfield, time + regentime);
1788 }
1789
1790 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1791 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1792 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1793 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1794 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1795 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1796
1797 float GiveItems(entity e, float beginarg, float endarg)
1798 {
1799         float got, i, j, val, op;
1800         float _switchweapon;
1801         entity wi;
1802         string cmd;
1803
1804         val = 999;
1805         op = OP_SET;
1806
1807         got = 0;
1808
1809         _switchweapon = FALSE;
1810         if (e.autoswitch)
1811                 if (e.switchweapon == w_getbestweapon(e))
1812                         _switchweapon = TRUE;
1813
1814         e.strength_finished = max(0, e.strength_finished - time);
1815         e.invincible_finished = max(0, e.invincible_finished - time);
1816         e.superweapons_finished = max(0, e.superweapons_finished - time);
1817
1818         PREGIVE(e, items);
1819         PREGIVE_WEAPONS(e);
1820         PREGIVE(e, strength_finished);
1821         PREGIVE(e, invincible_finished);
1822         PREGIVE(e, superweapons_finished);
1823         PREGIVE(e, ammo_nails);
1824         PREGIVE(e, ammo_cells);
1825         PREGIVE(e, ammo_shells);
1826         PREGIVE(e, ammo_rockets);
1827         PREGIVE(e, ammo_fuel);
1828         PREGIVE(e, armorvalue);
1829         PREGIVE(e, health);
1830
1831         for(i = beginarg; i < endarg; ++i)
1832         {
1833                 cmd = argv(i);
1834
1835                 if(cmd == "0" || stof(cmd))
1836                 {
1837                         val = stof(cmd);
1838                         continue;
1839                 }
1840                 switch(cmd)
1841                 {
1842                         case "no":
1843                                 op = OP_MAX;
1844                                 val = 0;
1845                                 continue;
1846                         case "max":
1847                                 op = OP_MAX;
1848                                 continue;
1849                         case "min":
1850                                 op = OP_MIN;
1851                                 continue;
1852                         case "plus":
1853                                 op = OP_PLUS;
1854                                 continue;
1855                         case "minus":
1856                                 op = OP_MINUS;
1857                                 continue;
1858                         case "ALL":
1859                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1860                                 got += GiveValue(e, strength_finished, op, val);
1861                                 got += GiveValue(e, invincible_finished, op, val);
1862                                 got += GiveValue(e, superweapons_finished, op, val);
1863                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1864                         case "all":
1865                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1866                                 got += GiveValue(e, health, op, val);
1867                                 got += GiveValue(e, armorvalue, op, val);
1868                         case "allweapons":
1869                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1870                                 {
1871                                         wi = get_weaponinfo(j);
1872                                         if(wi.weapon)
1873                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1874                                                         got += GiveWeapon(e, j, op, val);
1875                                 }
1876                         case "allammo":
1877                                 got += GiveValue(e, ammo_cells, op, val);
1878                                 got += GiveValue(e, ammo_shells, op, val);
1879                                 got += GiveValue(e, ammo_nails, op, val);
1880                                 got += GiveValue(e, ammo_rockets, op, val);
1881                                 got += GiveValue(e, ammo_fuel, op, val);
1882                                 break;
1883                         case "unlimited_ammo":
1884                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1885                                 break;
1886                         case "unlimited_weapon_ammo":
1887                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1888                                 break;
1889                         case "unlimited_superweapons":
1890                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1891                                 break;
1892                         case "jetpack":
1893                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1894                                 break;
1895                         case "fuel_regen":
1896                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1897                                 break;
1898                         case "strength":
1899                                 got += GiveValue(e, strength_finished, op, val);
1900                                 break;
1901                         case "invincible":
1902                                 got += GiveValue(e, invincible_finished, op, val);
1903                                 break;
1904                         case "superweapons":
1905                                 got += GiveValue(e, superweapons_finished, op, val);
1906                                 break;
1907                         case "cells":
1908                                 got += GiveValue(e, ammo_cells, op, val);
1909                                 break;
1910                         case "shells":
1911                                 got += GiveValue(e, ammo_shells, op, val);
1912                                 break;
1913                         case "nails":
1914                         case "bullets":
1915                                 got += GiveValue(e, ammo_nails, op, val);
1916                                 break;
1917                         case "rockets":
1918                                 got += GiveValue(e, ammo_rockets, op, val);
1919                                 break;
1920                         case "health":
1921                                 got += GiveValue(e, health, op, val);
1922                                 break;
1923                         case "armor":
1924                                 got += GiveValue(e, armorvalue, op, val);
1925                                 break;
1926                         case "fuel":
1927                                 got += GiveValue(e, ammo_fuel, op, val);
1928                                 break;
1929                         default:
1930                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1931                                 {
1932                                         wi = get_weaponinfo(j);
1933                                         if(cmd == wi.netname)
1934                                         {
1935                                                 got += GiveWeapon(e, j, op, val);
1936                                                 break;
1937                                         }
1938                                 }
1939                                 if(j > WEP_LAST)
1940                                         print("give: invalid item ", cmd, "\n");
1941                                 break;
1942                 }
1943                 val = 999;
1944                 op = OP_SET;
1945         }
1946
1947         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1948         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1949         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1950         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1951         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1952         {
1953                 wi = get_weaponinfo(j);
1954                 if(wi.weapon)
1955                 {
1956                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1957                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1958                                 if(WEPSET_CONTAINS_EW(e, j))
1959                                         weapon_action(wi.weapon, WR_PRECACHE);
1960                 }
1961         }
1962         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1963         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1964         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1965         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1966         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1967         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1968         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1969         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1970         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1971
1972         if(e.superweapons_finished <= 0)
1973                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1974                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1975
1976         if(e.strength_finished <= 0)
1977                 e.strength_finished = 0;
1978         else
1979                 e.strength_finished += time;
1980         if(e.invincible_finished <= 0)
1981                 e.invincible_finished = 0;
1982         else
1983                 e.invincible_finished += time;
1984         if(e.superweapons_finished <= 0)
1985                 e.superweapons_finished = 0;
1986         else
1987                 e.superweapons_finished += time;
1988
1989         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1990                 _switchweapon = TRUE;
1991         if(_switchweapon)
1992                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1993
1994         return got;
1995 }
1996 #endif