qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "bot/bot.qh"
   9     #include "bot/waypoints.qh"
  10
  11     #include "mutators/mutators_include.qh"
  12
  13     #include "weapons/common.qh"
  14     #include "weapons/selection.qh"
  15     #include "weapons/weaponsystem.qh"
  16
  17     #include "../common/constants.qh"
  18     #include "../common/deathtypes.qh"
  19     #include "../common/notifications.qh"
  20         #include "../common/triggers/subs.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/all.qh"
  24
  25     #include "../common/weapons/all.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {SELFPARAM();
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {SELFPARAM();
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void ItemRead(float _IsNew)
  79 {SELFPARAM();
  80     int sf = ReadByte();
  81
  82     if(sf & ISF_LOCATION)
  83     {
  84         self.origin_x = ReadCoord();
  85         self.origin_y = ReadCoord();
  86         self.origin_z = ReadCoord();
  87         setorigin(self, self.origin);
  88         self.oldorigin = self.origin;
  89     }
  90
  91     if(sf & ISF_ANGLES)
  92     {
  93         self.angles_x = ReadCoord();
  94         self.angles_y = ReadCoord();
  95         self.angles_z = ReadCoord();
  96         self.move_angles = self.angles;
  97     }
  98
  99     if(sf & ISF_SIZE)
 100     {
 101         self.mins_x = ReadCoord();
 102         self.mins_y = ReadCoord();
 103         self.mins_z = ReadCoord();
 104         self.maxs_x = ReadCoord();
 105         self.maxs_y = ReadCoord();
 106         self.maxs_z = ReadCoord();
 107         setsize(self, self.mins, self.maxs);
 108     }
 109
 110     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 111     {
 112         self.ItemStatus = ReadByte();
 113
 114         if(self.ItemStatus & ITS_AVAILABLE)
 115         {
 116             self.alpha = 1;
 117             self.colormod = self.glowmod = '1 1 1';
 118         }
 119         else
 120         {
 121             if (autocvar_cl_ghost_items_color)
 122             {
 123                 self.alpha = autocvar_cl_ghost_items;
 124                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 125             }
 126             else
 127                 self.alpha = -1;
 128         }
 129
 130         if(autocvar_cl_fullbright_items)
 131             if(self.ItemStatus & ITS_ALLOWFB)
 132                 self.effects |= EF_FULLBRIGHT;
 133
 134         if(self.ItemStatus & ITS_STAYWEP)
 135         {
 136             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 137             self.alpha = autocvar_cl_weapon_stay_alpha;
 138
 139         }
 140
 141         if(self.ItemStatus & ITS_POWERUP)
 142         {
 143             if(self.ItemStatus & ITS_AVAILABLE)
 144                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 145             else
 146                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 147         }
 148     }
 149
 150     if(sf & ISF_MODEL)
 151     {
 152         self.drawmask  = MASK_NORMAL;
 153         self.movetype  = MOVETYPE_TOSS;
 154         self.draw       = ItemDraw;
 155
 156         if(self.mdl)
 157             strunzone(self.mdl);
 158
 159         self.mdl = "";
 160         string _fn = ReadString();
 161
 162         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 163         {
 164             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 165             self.draw = ItemDrawSimple;
 166
 167
 168
 169             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 170                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 171             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 177             else
 178             {
 179                 self.draw = ItemDraw;
 180                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 181             }
 182         }
 183
 184         if(self.draw != ItemDrawSimple)
 185             self.mdl = strzone(_fn);
 186
 187
 188         if(self.mdl == "")
 189             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 190
 191         precache_model(self.mdl);
 192         setmodel(self, self.mdl);
 193     }
 194
 195     if(sf & ISF_COLORMAP)
 196         self.colormap = ReadShort();
 197
 198     if(sf & ISF_DROP)
 199     {
 200         self.gravity = 1;
 201         //self.move_angles = '0 0 0';
 202         self.move_movetype = MOVETYPE_TOSS;
 203         self.move_velocity_x = ReadCoord();
 204         self.move_velocity_y = ReadCoord();
 205         self.move_velocity_z = ReadCoord();
 206         self.velocity = self.move_velocity;
 207         self.move_origin = self.oldorigin;
 208
 209         if(!self.move_time)
 210         {
 211             self.move_time = time;
 212             self.spawntime = time;
 213         }
 214         else
 215             self.move_time = max(self.move_time, time);
 216     }
 217
 218     if(autocvar_cl_animate_items)
 219     {
 220         if(self.ItemStatus & ITS_ANIMATE1)
 221             self.move_avelocity = '0 180 0';
 222
 223         if(self.ItemStatus & ITS_ANIMATE2)
 224             self.move_avelocity = '0 -90 0';
 225     }
 226 }
 227
 228 #endif
 229
 230 #ifdef SVQC
 231 bool ItemSend(entity to, int sf)
 232 {SELFPARAM();
 233     if(self.gravity)
 234         sf |= ISF_DROP;
 235     else
 236         sf &= ~ISF_DROP;
 237
 238         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 239         WriteByte(MSG_ENTITY, sf);
 240
 241         //WriteByte(MSG_ENTITY, self.cnt);
 242     if(sf & ISF_LOCATION)
 243     {
 244         WriteCoord(MSG_ENTITY, self.origin.x);
 245         WriteCoord(MSG_ENTITY, self.origin.y);
 246         WriteCoord(MSG_ENTITY, self.origin.z);
 247     }
 248
 249     if(sf & ISF_ANGLES)
 250     {
 251         WriteCoord(MSG_ENTITY, self.angles.x);
 252         WriteCoord(MSG_ENTITY, self.angles.y);
 253         WriteCoord(MSG_ENTITY, self.angles.z);
 254     }
 255
 256     if(sf & ISF_SIZE)
 257     {
 258         WriteCoord(MSG_ENTITY, self.mins.x);
 259         WriteCoord(MSG_ENTITY, self.mins.y);
 260         WriteCoord(MSG_ENTITY, self.mins.z);
 261         WriteCoord(MSG_ENTITY, self.maxs.x);
 262         WriteCoord(MSG_ENTITY, self.maxs.y);
 263         WriteCoord(MSG_ENTITY, self.maxs.z);
 264     }
 265
 266     if(sf & ISF_STATUS)
 267         WriteByte(MSG_ENTITY, self.ItemStatus);
 268
 269     if(sf & ISF_MODEL)
 270     {
 271
 272         if(self.mdl == "")
 273             LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 274
 275         WriteString(MSG_ENTITY, self.mdl);
 276     }
 277
 278
 279     if(sf & ISF_COLORMAP)
 280         WriteShort(MSG_ENTITY, self.colormap);
 281
 282     if(sf & ISF_DROP)
 283     {
 284         WriteCoord(MSG_ENTITY, self.velocity.x);
 285         WriteCoord(MSG_ENTITY, self.velocity.y);
 286         WriteCoord(MSG_ENTITY, self.velocity.z);
 287     }
 288
 289     return true;
 290 }
 291
 292 void ItemUpdate(entity item)
 293 {
 294         item.SendFlags |= ISF_LOCATION;
 295 }
 296
 297 float have_pickup_item(void)
 298 {SELFPARAM();
 299         if(self.flags & FL_POWERUP)
 300         {
 301                 if(autocvar_g_powerups > 0)
 302                         return true;
 303                 if(autocvar_g_powerups == 0)
 304                         return false;
 305         }
 306         else
 307         {
 308                 if(autocvar_g_pickup_items > 0)
 309                         return true;
 310                 if(autocvar_g_pickup_items == 0)
 311                         return false;
 312                 if(g_weaponarena)
 313                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 314                                 return false;
 315         }
 316         return true;
 317 }
 318
 319 /*
 320 float Item_Customize()
 321 {
 322         if(self.spawnshieldtime)
 323                 return true;
 324         if(self.weapons & ~other.weapons)
 325         {
 326                 self.colormod = '0 0 0';
 327                 self.glowmod = self.colormod;
 328                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 329                 return true;
 330         }
 331         else
 332         {
 333                 if(g_ghost_items)
 334                 {
 335                         self.colormod = stov(autocvar_g_ghost_items_color);
 336                         self.glowmod = self.colormod;
 337                         self.alpha = g_ghost_items;
 338                         return true;
 339                 }
 340                 else
 341                         return false;
 342         }
 343 }
 344 */
 345
 346 void Item_Show (entity e, float mode)
 347 {
 348         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 349         e.ItemStatus &= ~ITS_STAYWEP;
 350         if (mode > 0)
 351         {
 352                 // make the item look normal, and be touchable
 353                 e.model = e.mdl;
 354                 e.solid = SOLID_TRIGGER;
 355                 e.spawnshieldtime = 1;
 356                 e.ItemStatus |= ITS_AVAILABLE;
 357         }
 358         else if (mode < 0)
 359         {
 360                 // hide the item completely
 361                 e.model = string_null;
 362                 e.solid = SOLID_NOT;
 363                 e.spawnshieldtime = 1;
 364                 e.ItemStatus &= ~ITS_AVAILABLE;
 365         }
 366         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 367         {
 368                 // make the item translucent and not touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 371                 e.effects |= EF_STARDUST;
 372                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 373                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 374         }
 375         else
 376         {
 377                 //setmodel(e, "null");
 378                 e.solid = SOLID_NOT;
 379                 e.colormod = '0 0 0';
 380                 e.glowmod = e.colormod;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus &= ~ITS_AVAILABLE;
 383         }
 384
 385         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 386             e.ItemStatus |= ITS_POWERUP;
 387
 388         if (autocvar_g_nodepthtestitems)
 389                 e.effects |= EF_NODEPTHTEST;
 390
 391
 392     if (autocvar_g_fullbrightitems)
 393                 e.ItemStatus |= ITS_ALLOWFB;
 394
 395         if (autocvar_sv_simple_items)
 396         e.ItemStatus |= ITS_ALLOWSI;
 397
 398         // relink entity (because solid may have changed)
 399         setorigin(e, e.origin);
 400     e.SendFlags |= ISF_STATUS;
 401 }
 402
 403 void Item_Think()
 404 {SELFPARAM();
 405         self.nextthink = time;
 406         if(self.origin != self.oldorigin)
 407         {
 408                 self.oldorigin = self.origin;
 409                 ItemUpdate(self);
 410         }
 411 }
 412
 413 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 414 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons);
 415 float Item_ItemsTime_UpdateTime(entity e, float t);
 416 void Item_ItemsTime_SetTime(entity e, float t);
 417 void Item_ItemsTime_SetTimesForAllPlayers();
 418
 419 void Item_Respawn (void)
 420 {SELFPARAM();
 421         Item_Show(self, 1);
 422         // this is ugly...
 423         if(self.items == ITEM_Strength.m_itemid)
 424                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 425         else if(self.items == ITEM_Shield.m_itemid)
 426                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 427         else
 428                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 429         setorigin (self, self.origin);
 430
 431     if (Item_ItemsTime_Allow(self.itemdef, self.weapons))
 432         {
 433                 float t = Item_ItemsTime_UpdateTime(self, 0);
 434                 Item_ItemsTime_SetTime(self, t);
 435                 Item_ItemsTime_SetTimesForAllPlayers();
 436         }
 437
 438         self.think = Item_Think;
 439         self.nextthink = time;
 440
 441         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 442         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 443 }
 444
 445 void Item_RespawnCountdown (void)
 446 {SELFPARAM();
 447         if(self.count >= ITEM_RESPAWN_TICKS)
 448         {
 449                 if(self.waypointsprite_attached)
 450                         WaypointSprite_Kill(self.waypointsprite_attached);
 451                 Item_Respawn();
 452         }
 453         else
 454         {
 455                 self.nextthink = time + 1;
 456                 self.count += 1;
 457                 if(self.count == 1)
 458                 {
 459                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 460                         int wpextra = 0;
 461             entity e = self.itemdef;
 462             if (e) wpextra = e.m_id;
 463                         if (self.flags & FL_WEAPON) {
 464                                 entity wi = get_weaponinfo(self.weapon);
 465                                 if (wi) wpextra = wi.m_id;
 466                         }
 467             entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP);
 468             wp.wp_extra = wpextra;
 469             if(self.waypointsprite_attached)
 470             {
 471                 GameItem def = self.itemdef;
 472                 if (Item_ItemsTime_SpectatorOnly(def))
 473                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 474                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 475             }
 476                 }
 477
 478                 if(self.waypointsprite_attached)
 479                 {
 480                         setself(self.waypointsprite_attached);
 481                         entity e;
 482                         FOR_EACH_REALCLIENT(e)
 483                                 if(self.waypointsprite_visible_for_player(e))
 484                                 {
 485                                         msg_entity = e;
 486                                         soundto(MSG_ONE, this, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 487                                 }
 488                         setself(this);
 489
 490                         WaypointSprite_Ping(self.waypointsprite_attached);
 491                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 492                 }
 493                 else
 494                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 495         }
 496 }
 497
 498 void Item_RespawnThink()
 499 {SELFPARAM();
 500         self.nextthink = time;
 501         if(self.origin != self.oldorigin)
 502         {
 503                 self.oldorigin = self.origin;
 504                 ItemUpdate(self);
 505         }
 506
 507         if(time >= self.wait)
 508                 Item_Respawn();
 509 }
 510
 511 void Item_ScheduleRespawnIn(entity e, float t)
 512 {
 513         if (Item_ItemsTime_Allow(e.itemdef, e.weapons))
 514         {
 515                 e.think = Item_RespawnCountdown;
 516                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 517                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 518                 e.count = 0;
 519                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 520                 Item_ItemsTime_SetTime(e, t);
 521                 Item_ItemsTime_SetTimesForAllPlayers();
 522         }
 523         else
 524         {
 525                 e.think = Item_RespawnThink;
 526                 e.nextthink = time;
 527                 e.scheduledrespawntime = time + t;
 528                 e.wait = time + t;
 529         }
 530 }
 531
 532 void Item_ScheduleRespawn(entity e)
 533 {
 534         if(e.respawntime > 0)
 535         {
 536                 Item_Show(e, 0);
 537                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 538         }
 539         else // if respawntime is -1, this item does not respawn
 540                 Item_Show(e, -1);
 541 }
 542
 543 void Item_ScheduleInitialRespawn(entity e)
 544 {
 545         Item_Show(e, 0);
 546         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 547 }
 548
 549 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 550 {
 551         if (!item.(ammotype))
 552                 return false;
 553
 554         if (item.spawnshieldtime)
 555         {
 556                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 557                 {
 558                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 559                         goto YEAH;
 560                 }
 561         }
 562         else if(g_weapon_stay == 2)
 563         {
 564                 float mi = min(item.(ammotype), ammomax);
 565                 if (player.(ammotype) < mi)
 566                 {
 567                         player.(ammotype) = mi;
 568                         goto YEAH;
 569                 }
 570         }
 571
 572         return false;
 573
 574 :YEAH
 575         switch(mode)
 576         {
 577                 case ITEM_MODE_FUEL:
 578                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 579                         break;
 580                 case ITEM_MODE_HEALTH:
 581                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 582                         break;
 583                 case ITEM_MODE_ARMOR:
 584                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 585                         break;
 586                 default:
 587                         break;
 588         }
 589         return true;
 590 }
 591
 592 float Item_GiveTo(entity item, entity player)
 593 {
 594         float _switchweapon;
 595         float pickedup;
 596         float it;
 597         float i;
 598
 599         // if nothing happens to player, just return without taking the item
 600         pickedup = false;
 601         _switchweapon = false;
 602         // in case the player has autoswitch enabled do the following:
 603         // if the player is using their best weapon before items are given, they
 604         // probably want to switch to an even better weapon after items are given
 605         if (player.autoswitch)
 606         if (player.switchweapon == w_getbestweapon(player))
 607                 _switchweapon = true;
 608
 609         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 610                 _switchweapon = true;
 611
 612         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 614         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 615         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 616         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 617         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 618         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 619         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 620
 621         if (item.flags & FL_WEAPON)
 622         {
 623                 WepSet it;
 624                 it = item.weapons;
 625                 it &= ~player.weapons;
 626
 627                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 628                 {
 629                         pickedup = true;
 630                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 631                         if(it & WepSet_FromWeapon(i))
 632                         {
 633                                 W_DropEvent(WR_PICKUP, player, i, item);
 634                                 W_GiveWeapon(player, i);
 635                         }
 636                 }
 637         }
 638
 639         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 640         {
 641                 pickedup = true;
 642                 player.items |= it;
 643                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 644         }
 645
 646         if (item.strength_finished)
 647         {
 648                 pickedup = true;
 649                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 650         }
 651         if (item.invincible_finished)
 652         {
 653                 pickedup = true;
 654                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 655         }
 656         if (item.superweapons_finished)
 657         {
 658                 pickedup = true;
 659                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 660         }
 661
 662 :skip
 663
 664         // always eat teamed entities
 665         if(item.team)
 666                 pickedup = true;
 667
 668         if (!pickedup)
 669                 return 0;
 670
 671         if (_switchweapon)
 672                 if (player.switchweapon != w_getbestweapon(player))
 673                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 674
 675         return 1;
 676 }
 677
 678 void Item_Touch (void)
 679 {SELFPARAM();
 680         entity e, head;
 681
 682         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 683         if(self.classname == "droppedweapon")
 684         {
 685                 if (ITEM_TOUCH_NEEDKILL())
 686                 {
 687                         remove(self);
 688                         return;
 689                 }
 690         }
 691
 692         if(!(other.flags & FL_PICKUPITEMS)
 693         || other.frozen
 694         || other.deadflag
 695         || (self.solid != SOLID_TRIGGER)
 696         || (self.owner == other)
 697         || (time < self.item_spawnshieldtime)
 698         ) { return;}
 699
 700         switch(MUTATOR_CALLHOOK(ItemTouch, self, other))
 701         {
 702                 case MUT_ITEMTOUCH_RETURN: { return; }
 703                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 704         }
 705
 706         if (self.classname == "droppedweapon")
 707         {
 708                 self.strength_finished = max(0, self.strength_finished - time);
 709                 self.invincible_finished = max(0, self.invincible_finished - time);
 710                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 711         }
 712         entity it = self.itemdef;
 713         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 714         if (!gave)
 715         {
 716                 if (self.classname == "droppedweapon")
 717                 {
 718                         // undo what we did above
 719                         self.strength_finished += time;
 720                         self.invincible_finished += time;
 721                         self.superweapons_finished += time;
 722                 }
 723                 return;
 724         }
 725
 726         :pickup
 727
 728         other.last_pickup = time;
 729
 730         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 731         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 732
 733         if (self.classname == "droppedweapon")
 734                 remove (self);
 735         else if (self.spawnshieldtime)
 736         {
 737                 if(self.team)
 738                 {
 739                         RandomSelection_Init();
 740                         for(head = world; (head = findfloat(head, team, self.team)); )
 741                         {
 742                                 if(head.flags & FL_ITEM)
 743                                 {
 744                                         Item_Show(head, -1);
 745                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 746                                 }
 747                         }
 748                         e = RandomSelection_chosen_ent;
 749
 750                 }
 751                 else
 752                         e = self;
 753                 Item_ScheduleRespawn(e);
 754         }
 755 }
 756
 757 void Item_Reset()
 758 {SELFPARAM();
 759         Item_Show(self, !self.state);
 760         setorigin (self, self.origin);
 761
 762         if(self.classname != "droppedweapon")
 763         {
 764                 self.think = Item_Think;
 765                 self.nextthink = time;
 766
 767                 if(self.waypointsprite_attached)
 768                         WaypointSprite_Kill(self.waypointsprite_attached);
 769
 770                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 771                         Item_ScheduleInitialRespawn(self);
 772         }
 773 }
 774
 775 void Item_FindTeam()
 776 {SELFPARAM();
 777         entity head, e;
 778
 779         if(self.effects & EF_NODRAW)
 780         {
 781                 // marker for item team search
 782                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 783                 RandomSelection_Init();
 784                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 785                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 786                 e = RandomSelection_chosen_ent;
 787                 e.state = 0;
 788                 Item_Show(e, 1);
 789
 790                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 791                 {
 792                         if(head != e)
 793                         {
 794                                 // make it a non-spawned item
 795                                 Item_Show(head, -1);
 796                                 head.state = 1; // state 1 = initially hidden item
 797                         }
 798                         head.effects &= ~EF_NODRAW;
 799                 }
 800
 801                 Item_Reset();
 802         }
 803 }
 804
 805 // Savage: used for item garbage-collection
 806 // TODO: perhaps nice special effect?
 807 void RemoveItem(void)
 808 {SELFPARAM();
 809         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 810         remove(self);
 811 }
 812
 813 // pickup evaluation functions
 814 // these functions decide how desirable an item is to the bots
 815
 816 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 817
 818 float weapon_pickupevalfunc(entity player, entity item)
 819 {
 820         float c;
 821
 822         // See if I have it already
 823         if(item.weapons & ~player.weapons)
 824         {
 825                 // If I can pick it up
 826                 if(!item.spawnshieldtime)
 827                         c = 0;
 828                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 829                 {
 830                         // Skilled bots will grab more
 831                         c = bound(0, skill / 10, 1) * 0.5;
 832                 }
 833                 else
 834                         c = 0;
 835         }
 836         else
 837                 c = 1;
 838
 839         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 840         if( bot_custom_weapon && c )
 841         {
 842                 // Find the highest position on any range
 843                 int position = -1;
 844                 for (int j = 0; j < WEP_LAST ; ++j){
 845                         if(
 846                                         bot_weapons_far[j] == item.weapon ||
 847                                         bot_weapons_mid[j] == item.weapon ||
 848                                         bot_weapons_close[j] == item.weapon
 849                           )
 850                         {
 851                                 position = j;
 852                                 break;
 853                         }
 854                 }
 855
 856                 // Rate it
 857                 if (position >= 0 )
 858                 {
 859                         position = WEP_LAST - position;
 860                         // item.bot_pickupbasevalue is overwritten here
 861                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 862                 }
 863         }
 864
 865         return item.bot_pickupbasevalue * c;
 866 }
 867
 868 float commodity_pickupevalfunc(entity player, entity item)
 869 {
 870         float c, i;
 871         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 872         entity wi;
 873         c = 0;
 874
 875         // Detect needed ammo
 876         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 877         {
 878                 wi = get_weaponinfo(i);
 879
 880                 if (!(player.weapons & WepSet_FromWeapon(i)))
 881                         continue;
 882
 883                 if(wi.items & ITEM_Shells.m_itemid)
 884                         need_shells = true;
 885                 else if(wi.items & ITEM_Bullets.m_itemid)
 886                         need_nails = true;
 887                 else if(wi.items & ITEM_Rockets.m_itemid)
 888                         need_rockets = true;
 889                 else if(wi.items & ITEM_Cells.m_itemid)
 890                         need_cells = true;
 891                 else if(wi.items & ITEM_Plasma.m_itemid)
 892                         need_plasma = true;
 893                 else if(wi.items & ITEM_JetpackFuel.m_itemid)
 894                         need_fuel = true;
 895         }
 896
 897         // TODO: figure out if the player even has the weapon this ammo is for?
 898         // may not affect strategy much though...
 899         // find out how much more ammo/armor/health the player can hold
 900         if (need_shells)
 901         if (item.ammo_shells)
 902         if (player.ammo_shells < g_pickup_shells_max)
 903                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 904         if (need_nails)
 905         if (item.ammo_nails)
 906         if (player.ammo_nails < g_pickup_nails_max)
 907                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 908         if (need_rockets)
 909         if (item.ammo_rockets)
 910         if (player.ammo_rockets < g_pickup_rockets_max)
 911                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 912         if (need_cells)
 913         if (item.ammo_cells)
 914         if (player.ammo_cells < g_pickup_cells_max)
 915                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 916         if (need_plasma)
 917         if (item.ammo_plasma)
 918         if (player.ammo_plasma < g_pickup_plasma_max)
 919                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
 920         if (need_fuel)
 921         if (item.ammo_fuel)
 922         if (player.ammo_fuel < g_pickup_fuel_max)
 923                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 924         if (item.armorvalue)
 925         if (player.armorvalue < item.max_armorvalue)
 926                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 927         if (item.health)
 928         if (player.health < item.max_health)
 929                 c = c + max(0, 1 - player.health / item.max_health);
 930
 931         return item.bot_pickupbasevalue * c;
 932 }
 933
 934 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 935 {
 936         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 937                 RemoveItem();
 938 }
 939
 940 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 941 {SELFPARAM();
 942         startitem_failed = false;
 943
 944         if(self.model == "")
 945                 self.model = itemmodel;
 946
 947         if(self.model == "")
 948     {
 949         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 950         return;
 951     }
 952
 953         if(self.item_pickupsound == "")
 954                 self.item_pickupsound = pickupsound;
 955
 956         if(!self.respawntime) // both need to be set
 957         {
 958                 self.respawntime = defaultrespawntime;
 959                 self.respawntimejitter = defaultrespawntimejitter;
 960         }
 961
 962         self.items = itemid;
 963         self.weapon = weaponid;
 964
 965         if(weaponid)
 966                 self.weapons = WepSet_FromWeapon(weaponid);
 967
 968         self.flags = FL_ITEM | itemflags;
 969
 970         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 971         {
 972                 startitem_failed = true;
 973                 remove(self);
 974                 return;
 975         }
 976
 977         // is it a dropped weapon?
 978         if (self.classname == "droppedweapon")
 979         {
 980                 self.reset = SUB_Remove;
 981                 // it's a dropped weapon
 982                 self.movetype = MOVETYPE_TOSS;
 983
 984                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 985                 self.think = RemoveItem;
 986                 self.nextthink = time + 20;
 987
 988                 self.takedamage = DAMAGE_YES;
 989                 self.event_damage = Item_Damage;
 990
 991                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 992                 /*
 993                 if(self.items == 0)
 994                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
 995                 if(self.ammo_nails == 0)
 996                 if(self.ammo_cells == 0)
 997                 if(self.ammo_rockets == 0)
 998                 if(self.ammo_shells == 0)
 999                 if(self.ammo_fuel == 0)
1000                 if(self.health == 0)
1001                 if(self.armorvalue == 0)
1002                 */
1003                 {
1004                         // if item is worthless after a timer, have it expire then
1005                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1006                 }
1007
1008                 // don't drop if in a NODROP zone (such as lava)
1009                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1010                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1011                 {
1012                         startitem_failed = true;
1013                         remove(self);
1014                         return;
1015                 }
1016         }
1017         else
1018         {
1019                 if(!have_pickup_item())
1020                 {
1021                         startitem_failed = true;
1022                         remove (self);
1023                         return;
1024                 }
1025
1026                 self.reset = Item_Reset;
1027                 // it's a level item
1028                 if(self.spawnflags & 1)
1029                         self.noalign = 1;
1030                 if (self.noalign)
1031                         self.movetype = MOVETYPE_NONE;
1032                 else
1033                         self.movetype = MOVETYPE_TOSS;
1034                 // do item filtering according to game mode and other things
1035                 if (!self.noalign)
1036                 {
1037                         // first nudge it off the floor a little bit to avoid math errors
1038                         setorigin(self, self.origin + '0 0 1');
1039                         // set item size before we spawn a spawnfunc_waypoint
1040                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1041                                 setsize (self, '-16 -16 0', '16 16 48');
1042                         else
1043                                 setsize (self, '-16 -16 0', '16 16 32');
1044
1045                         // note droptofloor returns false if stuck/or would fall too far
1046                         droptofloor();
1047                         waypoint_spawnforitem(self);
1048                 }
1049
1050                 /*
1051                  * can't do it that way, as it would break maps
1052                  * TODO make a target_give like entity another way, that perhaps has
1053                  * the weapon name in a key
1054                 if(self.targetname)
1055                 {
1056                         // target_give not yet supported; maybe later
1057                         print("removed targeted ", self.classname, "\n");
1058                         startitem_failed = true;
1059                         remove (self);
1060                         return;
1061                 }
1062                 */
1063
1064                 if(autocvar_spawn_debug >= 2)
1065                 {
1066                         entity otheritem;
1067                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1068                         {
1069                             // why not flags & fl_item?
1070                                 if(otheritem.is_item)
1071                                 {
1072                                         LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(self.origin));
1073                                         LOG_TRACE(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1074                                         error("Mapper sucks.");
1075                                 }
1076                         }
1077                         self.is_item = true;
1078                 }
1079
1080                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1081
1082                 precache_model (self.model);
1083                 precache_sound (self.item_pickupsound);
1084
1085                 precache_sound ("misc/itemrespawncountdown.wav");
1086                 if(itemid == ITEM_Strength.m_itemid)
1087                         precache_sound ("misc/strength_respawn.wav");
1088                 else if(itemid == ITEM_Shield.m_itemid)
1089                         precache_sound ("misc/shield_respawn.wav");
1090                 else
1091                         precache_sound ("misc/itemrespawn.wav");
1092
1093                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1094                         self.target = "###item###"; // for finding the nearest item using find()
1095
1096                 Item_ItemsTime_SetTime(self, 0);
1097         }
1098
1099         self.bot_pickup = true;
1100         self.bot_pickupevalfunc = pickupevalfunc;
1101         self.bot_pickupbasevalue = pickupbasevalue;
1102         self.mdl = self.model;
1103         self.netname = itemname;
1104         self.touch = Item_Touch;
1105         setmodel(self, "null"); // precision set below
1106         //self.effects |= EF_LOWPRECISION;
1107
1108         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1109     {
1110         self.pos1 = '-16 -16 0';
1111         self.pos2 = '16 16 48';
1112     }
1113         else
1114     {
1115         self.pos1 = '-16 -16 0';
1116         self.pos2 = '16 16 32';
1117     }
1118     setsize (self, self.pos1, self.pos2);
1119
1120     if(itemflags & FL_POWERUP)
1121         self.ItemStatus |= ITS_ANIMATE1;
1122
1123         if(self.armorvalue || self.health)
1124         self.ItemStatus |= ITS_ANIMATE2;
1125
1126         if(itemflags & FL_WEAPON)
1127         {
1128                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1129             self.colormap = 1024; // color shirt=0 pants=0 grey
1130         else
1131             self.gravity = 1;
1132
1133                 self.ItemStatus |= ITS_ANIMATE1;
1134                 self.ItemStatus |= ISF_COLORMAP;
1135         }
1136
1137         self.state = 0;
1138         if(self.team) // broken, no idea why.
1139         {
1140                 if(!self.cnt)
1141                         self.cnt = 1; // item probability weight
1142
1143                 self.effects |= EF_NODRAW; // marker for item team search
1144                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1145         }
1146         else
1147                 Item_Reset();
1148
1149     Net_LinkEntity(self, false, 0, ItemSend);
1150
1151         self.SendFlags |= ISF_SIZE;
1152         if(self.angles)
1153                 self.SendFlags |= ISF_ANGLES;
1154
1155         // call this hook after everything else has been done
1156         if(MUTATOR_CALLHOOK(Item_Spawn, self))
1157         {
1158                 startitem_failed = true;
1159                 remove(self);
1160                 return;
1161         }
1162 }
1163
1164 string Item_Model(string item_mdl)
1165 {
1166         string output = strcat("models/items/", item_mdl);
1167         MUTATOR_CALLHOOK(ItemModel, item_mdl, output);
1168         return strzone(item_model_output);
1169 }
1170
1171 void StartItemA (entity a)
1172 {SELFPARAM();
1173     self.itemdef = a;
1174     StartItem(Item_Model(a.m_model), a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1175 }
1176
1177 void spawnfunc_item_rockets()
1178 {SELFPARAM();
1179         if(!self.ammo_rockets)
1180                 self.ammo_rockets = g_pickup_rockets;
1181         if(!self.pickup_anyway)
1182                 self.pickup_anyway = g_pickup_ammo_anyway;
1183     StartItemA (ITEM_Rockets);
1184 }
1185
1186 void spawnfunc_item_bullets()
1187 {SELFPARAM();
1188         if(!weaponswapping)
1189         if(autocvar_sv_q3acompat_machineshotgunswap)
1190         if(self.classname != "droppedweapon")
1191         {
1192                 weaponswapping = true;
1193                 spawnfunc_item_shells();
1194                 weaponswapping = false;
1195                 return;
1196         }
1197
1198         if(!self.ammo_nails)
1199                 self.ammo_nails = g_pickup_nails;
1200         if(!self.pickup_anyway)
1201                 self.pickup_anyway = g_pickup_ammo_anyway;
1202     StartItemA (ITEM_Bullets);
1203 }
1204
1205 void spawnfunc_item_cells()
1206 {SELFPARAM();
1207         if(!self.ammo_cells)
1208                 self.ammo_cells = g_pickup_cells;
1209         if(!self.pickup_anyway)
1210                 self.pickup_anyway = g_pickup_ammo_anyway;
1211         StartItemA (ITEM_Cells);
1212 }
1213
1214 void spawnfunc_item_plasma()
1215 {SELFPARAM();
1216         if(!self.ammo_plasma)
1217                 self.ammo_plasma = g_pickup_plasma;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_ammo_anyway;
1220         StartItemA (ITEM_Plasma);
1221 }
1222
1223 void spawnfunc_item_shells()
1224 {SELFPARAM();
1225         if(!weaponswapping)
1226         if(autocvar_sv_q3acompat_machineshotgunswap)
1227         if(self.classname != "droppedweapon")
1228         {
1229                 weaponswapping = true;
1230                 spawnfunc_item_bullets();
1231                 weaponswapping = false;
1232                 return;
1233         }
1234
1235         if(!self.ammo_shells)
1236                 self.ammo_shells = g_pickup_shells;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_ammo_anyway;
1239         StartItemA (ITEM_Shells);
1240 }
1241
1242 void spawnfunc_item_armor_small()
1243 {SELFPARAM();
1244         if(!self.armorvalue)
1245                 self.armorvalue = g_pickup_armorsmall;
1246         if(!self.max_armorvalue)
1247                 self.max_armorvalue = g_pickup_armorsmall_max;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1250         StartItemA (ITEM_ArmorSmall);
1251 }
1252
1253 void spawnfunc_item_armor_medium()
1254 {SELFPARAM();
1255         if(!self.armorvalue)
1256                 self.armorvalue = g_pickup_armormedium;
1257         if(!self.max_armorvalue)
1258                 self.max_armorvalue = g_pickup_armormedium_max;
1259         if(!self.pickup_anyway)
1260                 self.pickup_anyway = g_pickup_armormedium_anyway;
1261         StartItemA (ITEM_ArmorMedium);
1262 }
1263
1264 void spawnfunc_item_armor_big()
1265 {SELFPARAM();
1266         if(!self.armorvalue)
1267                 self.armorvalue = g_pickup_armorbig;
1268         if(!self.max_armorvalue)
1269                 self.max_armorvalue = g_pickup_armorbig_max;
1270         if(!self.pickup_anyway)
1271                 self.pickup_anyway = g_pickup_armorbig_anyway;
1272         StartItemA (ITEM_ArmorLarge);
1273 }
1274
1275 void spawnfunc_item_armor_large()
1276 {SELFPARAM();
1277         if(!self.armorvalue)
1278                 self.armorvalue = g_pickup_armorlarge;
1279         if(!self.max_armorvalue)
1280                 self.max_armorvalue = g_pickup_armorlarge_max;
1281         if(!self.pickup_anyway)
1282                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1283         StartItemA (ITEM_ArmorMega);
1284 }
1285
1286 void spawnfunc_item_health_small()
1287 {SELFPARAM();
1288         if(!self.max_health)
1289                 self.max_health = g_pickup_healthsmall_max;
1290         if(!self.health)
1291                 self.health = g_pickup_healthsmall;
1292         if(!self.pickup_anyway)
1293                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1294         StartItemA (ITEM_HealthSmall);
1295 }
1296
1297 void spawnfunc_item_health_medium()
1298 {SELFPARAM();
1299         if(!self.max_health)
1300                 self.max_health = g_pickup_healthmedium_max;
1301         if(!self.health)
1302                 self.health = g_pickup_healthmedium;
1303         if(!self.pickup_anyway)
1304                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1305     StartItemA (ITEM_HealthMedium);
1306 }
1307
1308 void spawnfunc_item_health_large()
1309 {SELFPARAM();
1310         if(!self.max_health)
1311                 self.max_health = g_pickup_healthlarge_max;
1312         if(!self.health)
1313                 self.health = g_pickup_healthlarge;
1314         if(!self.pickup_anyway)
1315                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1316         StartItemA (ITEM_HealthLarge);
1317 }
1318
1319 void spawnfunc_item_health_mega()
1320 {SELFPARAM();
1321     if(!self.max_health)
1322         self.max_health = g_pickup_healthmega_max;
1323     if(!self.health)
1324         self.health = g_pickup_healthmega;
1325     if(!self.pickup_anyway)
1326         self.pickup_anyway = g_pickup_healthmega_anyway;
1327     StartItemA (ITEM_HealthMega);
1328 }
1329
1330 // support old misnamed entities
1331 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1332 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1333 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1334 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1335 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1336
1337 void spawnfunc_item_strength()
1338 {SELFPARAM();
1339                 precache_sound("weapons/strength_fire.wav");
1340                 if(!self.strength_finished)
1341                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1342                 StartItemA (ITEM_Strength);
1343 }
1344
1345 void spawnfunc_item_invincible()
1346 {SELFPARAM();
1347                 if(!self.invincible_finished)
1348                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1349                 StartItemA (ITEM_Shield);
1350 }
1351
1352 // compatibility:
1353 void spawnfunc_item_quad() {SELFPARAM(); self.classname = "item_strength";spawnfunc_item_strength();}
1354
1355 void target_items_use()
1356 {SELFPARAM();
1357         if(activator.classname == "droppedweapon")
1358         {
1359                 EXACTTRIGGER_TOUCH;
1360                 remove(activator);
1361                 return;
1362         }
1363
1364         if (!IS_PLAYER(activator))
1365                 return;
1366         if(activator.deadflag != DEAD_NO)
1367                 return;
1368         EXACTTRIGGER_TOUCH;
1369
1370         entity e;
1371         for(e = world; (e = find(e, classname, "droppedweapon")); )
1372                 if(e.enemy == activator)
1373                         remove(e);
1374
1375         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1376                 centerprint(activator, self.message);
1377 }
1378
1379 void spawnfunc_target_items (void)
1380 {SELFPARAM();
1381         float n, i, j;
1382         entity e;
1383         string s;
1384
1385         self.use = target_items_use;
1386         if(!self.strength_finished)
1387                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1388         if(!self.invincible_finished)
1389                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1390         if(!self.superweapons_finished)
1391                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1392
1393         precache_sound("misc/itempickup.wav");
1394         precache_sound("misc/megahealth.wav");
1395         precache_sound("misc/armor25.wav");
1396         precache_sound("misc/powerup.wav");
1397         precache_sound("misc/poweroff.wav");
1398         precache_sound(W_Sound("weaponpickup"));
1399
1400         n = tokenize_console(self.netname);
1401         if(argv(0) == "give")
1402         {
1403                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1404         }
1405         else
1406         {
1407                 for(i = 0; i < n; ++i)
1408                 {
1409                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1410                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1411                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1412                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1413                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1414                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1415                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1416                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1417                         else
1418                         {
1419                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1420                                 {
1421                                         e = get_weaponinfo(j);
1422                                         s = W_UndeprecateName(argv(i));
1423                                         if(s == e.netname)
1424                                         {
1425                                                 self.weapons |= WepSet_FromWeapon(j);
1426                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1427                                                         WEP_ACTION(e.weapon, WR_INIT);
1428                                                 break;
1429                                         }
1430                                 }
1431                                 if(j > WEP_LAST)
1432                                         LOG_INFO("target_items: invalid item ", argv(i), "\n");
1433                         }
1434                 }
1435
1436                 string itemprefix, valueprefix;
1437                 if(self.spawnflags == 0)
1438                 {
1439                         itemprefix = "";
1440                         valueprefix = "";
1441                 }
1442                 else if(self.spawnflags == 1)
1443                 {
1444                         itemprefix = "max ";
1445                         valueprefix = "max ";
1446                 }
1447                 else if(self.spawnflags == 2)
1448                 {
1449                         itemprefix = "min ";
1450                         valueprefix = "min ";
1451                 }
1452                 else if(self.spawnflags == 4)
1453                 {
1454                         itemprefix = "minus ";
1455                         valueprefix = "max ";
1456                 }
1457                 else
1458                 {
1459                         error("invalid spawnflags");
1460                         itemprefix = valueprefix = string_null;
1461                 }
1462
1463                 self.netname = "";
1464                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1465                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1466                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & ITEM_Strength.m_itemid), "strength");
1467                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & ITEM_Shield.m_itemid), "invincible");
1468                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1469                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1470                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1471                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1472                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1473                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1474                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1475                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1476                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1477                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1478                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1479                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1480                 {
1481                         e = get_weaponinfo(j);
1482                         if(e.weapon)
1483                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1484                 }
1485         }
1486         self.netname = strzone(self.netname);
1487         //print(self.netname, "\n");
1488
1489         n = tokenize_console(self.netname);
1490         for(i = 0; i < n; ++i)
1491         {
1492                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1493                 {
1494                         e = get_weaponinfo(j);
1495                         if(argv(i) == e.netname)
1496                         {
1497                                 WEP_ACTION(e.weapon, WR_INIT);
1498                                 break;
1499                         }
1500                 }
1501         }
1502 }
1503
1504 void spawnfunc_item_fuel(void)
1505 {SELFPARAM();
1506         if(!self.ammo_fuel)
1507                 self.ammo_fuel = g_pickup_fuel;
1508         if(!self.pickup_anyway)
1509                 self.pickup_anyway = g_pickup_ammo_anyway;
1510         StartItemA (ITEM_JetpackFuel);
1511 }
1512
1513 void spawnfunc_item_fuel_regen(void)
1514 {
1515         if(start_items & ITEM_JetpackRegen.m_itemid)
1516         {
1517                 spawnfunc_item_fuel();
1518                 return;
1519         }
1520         StartItemA (ITEM_JetpackRegen);
1521 }
1522
1523 void spawnfunc_item_jetpack(void)
1524 {SELFPARAM();
1525         if(!self.ammo_fuel)
1526                 self.ammo_fuel = g_pickup_fuel_jetpack;
1527         if(start_items & ITEM_Jetpack.m_itemid)
1528         {
1529                 spawnfunc_item_fuel();
1530                 return;
1531         }
1532         StartItemA (ITEM_Jetpack);
1533 }
1534
1535 float GiveWeapon(entity e, float wpn, float op, float val)
1536 {
1537         WepSet v0, v1;
1538         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1539         switch(op)
1540         {
1541                 case OP_SET:
1542                         if(val > 0)
1543                                 e.weapons |= WepSet_FromWeapon(wpn);
1544                         else
1545                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1546                         break;
1547                 case OP_MIN:
1548                 case OP_PLUS:
1549                         if(val > 0)
1550                                 e.weapons |= WepSet_FromWeapon(wpn);
1551                         break;
1552                 case OP_MAX:
1553                         if(val <= 0)
1554                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1555                         break;
1556                 case OP_MINUS:
1557                         if(val > 0)
1558                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1559                         break;
1560         }
1561         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1562         return (v0 != v1);
1563 }
1564
1565 float GiveBit(entity e, .float fld, float bit, float op, float val)
1566 {
1567         float v0, v1;
1568         v0 = (e.(fld) & bit);
1569         switch(op)
1570         {
1571                 case OP_SET:
1572                         if(val > 0)
1573                                 e.(fld) |= bit;
1574                         else
1575                                 e.(fld) &= ~bit;
1576                         break;
1577                 case OP_MIN:
1578                 case OP_PLUS:
1579                         if(val > 0)
1580                                 e.(fld) |= bit;
1581                         break;
1582                 case OP_MAX:
1583                         if(val <= 0)
1584                                 e.(fld) &= ~bit;
1585                         break;
1586                 case OP_MINUS:
1587                         if(val > 0)
1588                                 e.(fld) &= ~bit;
1589                         break;
1590         }
1591         v1 = (e.(fld) & bit);
1592         return (v0 != v1);
1593 }
1594
1595 float GiveValue(entity e, .float fld, float op, float val)
1596 {
1597         float v0, v1;
1598         v0 = e.(fld);
1599         switch(op)
1600         {
1601                 case OP_SET:
1602                         e.(fld) = val;
1603                         break;
1604                 case OP_MIN:
1605                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1606                         break;
1607                 case OP_MAX:
1608                         e.(fld) = min(e.(fld), val);
1609                         break;
1610                 case OP_PLUS:
1611                         e.(fld) += val;
1612                         break;
1613                 case OP_MINUS:
1614                         e.(fld) -= val;
1615                         break;
1616         }
1617         v1 = e.(fld);
1618         return (v0 != v1);
1619 }
1620
1621 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1622 {
1623         if(v1 == v0)
1624                 return;
1625         if(v1 <= v0 - t)
1626         {
1627                 if(snd_decr != "")
1628                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1629         }
1630         else if(v0 >= v0 + t)
1631         {
1632                 if(snd_incr != "")
1633                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1634         }
1635 }
1636
1637 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1638 {
1639         if(v0 < v1)
1640                 e.(rotfield) = max(e.(rotfield), time + rottime);
1641         else if(v0 > v1)
1642                 e.(regenfield) = max(e.(regenfield), time + regentime);
1643 }
1644 float GiveItems(entity e, float beginarg, float endarg)
1645 {SELFPARAM();
1646         float got, i, j, val, op;
1647         float _switchweapon;
1648         entity wi;
1649         string cmd;
1650
1651         val = 999;
1652         op = OP_SET;
1653
1654         got = 0;
1655
1656         _switchweapon = false;
1657         if (e.autoswitch)
1658                 if (e.switchweapon == w_getbestweapon(e))
1659                         _switchweapon = true;
1660
1661         e.strength_finished = max(0, e.strength_finished - time);
1662         e.invincible_finished = max(0, e.invincible_finished - time);
1663         e.superweapons_finished = max(0, e.superweapons_finished - time);
1664
1665         PREGIVE(e, items);
1666         PREGIVE_WEAPONS(e);
1667         PREGIVE(e, strength_finished);
1668         PREGIVE(e, invincible_finished);
1669         PREGIVE(e, superweapons_finished);
1670         PREGIVE(e, ammo_nails);
1671         PREGIVE(e, ammo_cells);
1672         PREGIVE(e, ammo_plasma);
1673         PREGIVE(e, ammo_shells);
1674         PREGIVE(e, ammo_rockets);
1675         PREGIVE(e, ammo_fuel);
1676         PREGIVE(e, armorvalue);
1677         PREGIVE(e, health);
1678
1679         for(i = beginarg; i < endarg; ++i)
1680         {
1681                 cmd = argv(i);
1682
1683                 if(cmd == "0" || stof(cmd))
1684                 {
1685                         val = stof(cmd);
1686                         continue;
1687                 }
1688                 switch(cmd)
1689                 {
1690                         case "no":
1691                                 op = OP_MAX;
1692                                 val = 0;
1693                                 continue;
1694                         case "max":
1695                                 op = OP_MAX;
1696                                 continue;
1697                         case "min":
1698                                 op = OP_MIN;
1699                                 continue;
1700                         case "plus":
1701                                 op = OP_PLUS;
1702                                 continue;
1703                         case "minus":
1704                                 op = OP_MINUS;
1705                                 continue;
1706                         case "ALL":
1707                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1708                                 got += GiveValue(e, strength_finished, op, val);
1709                                 got += GiveValue(e, invincible_finished, op, val);
1710                                 got += GiveValue(e, superweapons_finished, op, val);
1711                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1712                         case "all":
1713                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1714                                 got += GiveValue(e, health, op, val);
1715                                 got += GiveValue(e, armorvalue, op, val);
1716                         case "allweapons":
1717                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1718                                 {
1719                                         wi = get_weaponinfo(j);
1720                                         if(wi.weapon)
1721                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1722                                                         got += GiveWeapon(e, j, op, val);
1723                                 }
1724                         case "allammo":
1725                                 got += GiveValue(e, ammo_cells, op, val);
1726                                 got += GiveValue(e, ammo_plasma, op, val);
1727                                 got += GiveValue(e, ammo_shells, op, val);
1728                                 got += GiveValue(e, ammo_nails, op, val);
1729                                 got += GiveValue(e, ammo_rockets, op, val);
1730                                 got += GiveValue(e, ammo_fuel, op, val);
1731                                 break;
1732                         case "unlimited_ammo":
1733                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1734                                 break;
1735                         case "unlimited_weapon_ammo":
1736                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1737                                 break;
1738                         case "unlimited_superweapons":
1739                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1740                                 break;
1741                         case "jetpack":
1742                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1743                                 break;
1744                         case "fuel_regen":
1745                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1746                                 break;
1747                         case "strength":
1748                                 got += GiveValue(e, strength_finished, op, val);
1749                                 break;
1750                         case "invincible":
1751                                 got += GiveValue(e, invincible_finished, op, val);
1752                                 break;
1753                         case "superweapons":
1754                                 got += GiveValue(e, superweapons_finished, op, val);
1755                                 break;
1756                         case "cells":
1757                                 got += GiveValue(e, ammo_cells, op, val);
1758                                 break;
1759                         case "plasma":
1760                                 got += GiveValue(e, ammo_plasma, op, val);
1761                                 break;
1762                         case "shells":
1763                                 got += GiveValue(e, ammo_shells, op, val);
1764                                 break;
1765                         case "nails":
1766                         case "bullets":
1767                                 got += GiveValue(e, ammo_nails, op, val);
1768                                 break;
1769                         case "rockets":
1770                                 got += GiveValue(e, ammo_rockets, op, val);
1771                                 break;
1772                         case "health":
1773                                 got += GiveValue(e, health, op, val);
1774                                 break;
1775                         case "armor":
1776                                 got += GiveValue(e, armorvalue, op, val);
1777                                 break;
1778                         case "fuel":
1779                                 got += GiveValue(e, ammo_fuel, op, val);
1780                                 break;
1781                         default:
1782                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1783                                 {
1784                                         wi = get_weaponinfo(j);
1785                                         if(cmd == wi.netname)
1786                                         {
1787                                                 got += GiveWeapon(e, j, op, val);
1788                                                 break;
1789                                         }
1790                                 }
1791                                 if(j > WEP_LAST)
1792                                         LOG_INFO("give: invalid item ", cmd, "\n");
1793                                 break;
1794                 }
1795                 val = 999;
1796                 op = OP_SET;
1797         }
1798
1799         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, "misc/itempickup.wav", string_null);
1800         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1801         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1802         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, "misc/itempickup.wav", string_null);
1803         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1804         {
1805                 wi = get_weaponinfo(j);
1806                 if(wi.weapon)
1807                 {
1808                         POSTGIVE_WEAPON(e, j, W_Sound("weaponpickup"), string_null);
1809                         if (!(save_weapons & WepSet_FromWeapon(j)))
1810                                 if(e.weapons & WepSet_FromWeapon(j))
1811                                         WEP_ACTION(wi.weapon, WR_INIT);
1812                 }
1813         }
1814         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1815         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1816         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1817         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1818         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1819         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1820         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1821         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1822         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1823         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1824
1825         if(e.superweapons_finished <= 0)
1826                 if(self.weapons & WEPSET_SUPERWEAPONS)
1827                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1828
1829         if(e.strength_finished <= 0)
1830                 e.strength_finished = 0;
1831         else
1832                 e.strength_finished += time;
1833         if(e.invincible_finished <= 0)
1834                 e.invincible_finished = 0;
1835         else
1836                 e.invincible_finished += time;
1837         if(e.superweapons_finished <= 0)
1838                 e.superweapons_finished = 0;
1839         else
1840                 e.superweapons_finished += time;
1841
1842         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
1843                 _switchweapon = true;
1844         if(_switchweapon)
1845                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1846
1847         return got;
1848 }
1849 #endif