qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float it_armor_large_time;
 416 float it_health_mega_time;
 417 float it_invisible_time;
 418 float it_speed_time;
 419 float it_extralife_time;
 420 float it_strength_time;
 421 float it_shield_time;
 422 float it_fuelregen_time;
 423 float it_jetpack_time;
 424 float it_superweapons_time;
 425
 426 void Item_ItemsTime_Init()
 427 {
 428         it_armor_large_time = -1;
 429         it_health_mega_time = -1;
 430         it_invisible_time = -1;
 431         it_speed_time = -1;
 432         it_extralife_time = -1;
 433         it_strength_time = -1;
 434         it_shield_time = -1;
 435         it_fuelregen_time = -1;
 436         it_jetpack_time = -1;
 437         it_superweapons_time = -1;
 438 }
 439 void Item_ItemsTime_ResetTimes()
 440 {
 441         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 442         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 443         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 444         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 445         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 446         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 447         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 448         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 449         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 450         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 451 }
 452 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 453 {
 454         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 455         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 456         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 457         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 458         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 459         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 460         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 461         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 462         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 463         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 464 }
 465 void Item_ItemsTime_SetTimesForPlayer(entity e)
 466 {
 467         e.item_armor_large_time = it_armor_large_time;
 468         e.item_health_mega_time = it_health_mega_time;
 469         e.item_invisible_time = it_invisible_time;
 470         e.item_speed_time = it_speed_time;
 471         e.item_extralife_time = it_extralife_time;
 472         e.item_strength_time = it_strength_time;
 473         e.item_shield_time = it_shield_time;
 474         e.item_fuelregen_time = it_fuelregen_time;
 475         e.item_jetpack_time = it_jetpack_time;
 476         e.item_superweapons_time = it_superweapons_time;
 477 }
 478 bool Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 479 {
 480         if(t == 0 && item_time == -1)
 481                 return true;
 482         if(t < 0) // negative means there's another available item of the same kind
 483                 t = -t;
 484         if(time < t && (item_time <= time || t < item_time))
 485                 return true;
 486         return false;
 487 }
 488 void Item_ItemsTime_UpdateTime(entity e, float t)
 489 {
 490         if(!autocvar_sv_itemstime)
 491                 return;
 492
 493         if(g_instagib)
 494         {
 495                 switch(e.items)
 496                 {
 497                         case IT_STRENGTH://"item-invis"
 498                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 499                                         it_invisible_time = t;
 500                                 break;
 501                         case IT_NAILS://"item-extralife"
 502                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 503                                         it_extralife_time = t;
 504                                 break;
 505                         case IT_INVINCIBLE://"item-speed"
 506                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 507                                         it_speed_time = t;
 508                                 break;
 509                 }
 510         }
 511         else
 512         {
 513                 switch(e.items)
 514                 {
 515                         case IT_HEALTH:
 516                                 //if (e.classname == "item_health_mega")
 517                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 518                                                 it_health_mega_time = t;
 519                                 break;
 520                         case IT_ARMOR:
 521                                 if (e.classname == "item_armor_large")
 522                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 523                                                 it_armor_large_time = t;
 524                                 break;
 525                         case IT_STRENGTH://"item-strength"
 526                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 527                                         it_strength_time = t;
 528                                 break;
 529                         case IT_INVINCIBLE://"item-shield"
 530                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 531                                         it_shield_time = t;
 532                                 break;
 533                         default:
 534                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 535                                         if(Item_ItemsTime_UpdateTime_Check(it_superweapons_time, t))
 536                                                 it_superweapons_time = t;
 537                 }
 538         }
 539         switch(e.items)
 540         {
 541                 case IT_FUEL_REGEN://"item-fuelregen"
 542                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 543                                 it_fuelregen_time = t;
 544                         break;
 545                 case IT_JETPACK://"item-jetpack"
 546                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 547                                 it_jetpack_time = t;
 548                         break;
 549         }
 550 }
 551 void Item_ItemsTime_SetTimesForAllPlayers()
 552 {
 553         entity e;
 554         if(warmup_stage)
 555         {
 556                 FOR_EACH_REALCLIENT(e)
 557                         Item_ItemsTime_SetTimesForPlayer(e);
 558         }
 559         else
 560         {
 561                 FOR_EACH_REALCLIENT(e)
 562                 {
 563                         if(!IS_PLAYER(e))
 564                                 Item_ItemsTime_SetTimesForPlayer(e);
 565                 }
 566         }
 567 }
 568
 569 void Item_Respawn (void)
 570 {
 571         Item_Show(self, 1);
 572         // this is ugly...
 573         if(self.items == IT_STRENGTH)
 574                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 575         else if(self.items == IT_INVINCIBLE)
 576                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 577         else
 578                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 579         setorigin (self, self.origin);
 580
 581         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 582         {
 583                 entity head;
 584                 float t = 0;
 585                 float isavailable = true;
 586                 for(head = world; (head = find(head, classname, self.classname)); )
 587                 {
 588                         // in instagib .classname is "instagib" for every item
 589                         if(self == head || (g_instagib && self.items != head.items))
 590                                 continue;
 591                         if(head.scheduledrespawntime > time && (t == 0 || head.scheduledrespawntime < t))
 592                                 t = head.scheduledrespawntime;
 593                 }
 594
 595                 if(isavailable)
 596                         t = -t; // let know the client there's another available item
 597                 Item_ItemsTime_UpdateTime(self, t);
 598                 Item_ItemsTime_SetTimesForAllPlayers();
 599         }
 600
 601         self.think = Item_Think;
 602         self.nextthink = time;
 603
 604         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 605         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 606 }
 607
 608 void Item_RespawnCountdown (void)
 609 {
 610         if(self.count >= ITEM_RESPAWN_TICKS)
 611         {
 612                 if(self.waypointsprite_attached)
 613                         WaypointSprite_Kill(self.waypointsprite_attached);
 614                 Item_Respawn();
 615         }
 616         else
 617         {
 618                 self.nextthink = time + 1;
 619                 self.count += 1;
 620                 if(self.count == 1)
 621                 {
 622                         string name;
 623                         vector rgb = '1 0 1';
 624                         name = string_null;
 625                         switch(self.items)
 626                         {
 627                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 628                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 629                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 630                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 631                                 case IT_HEALTH:
 632                                         //if (self.classname == "item_health_mega")
 633                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 634                                         break;
 635                                 case IT_ARMOR:
 636                                         if (self.classname == "item_armor_large")
 637                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 638                                         break;
 639                         }
 640                         item_name = name;
 641                         item_color = rgb;
 642                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 643                         name = item_name;
 644                         rgb = item_color;
 645                         if(self.flags & FL_WEAPON)
 646                         {
 647                                 entity wi = get_weaponinfo(self.weapon);
 648                                 if(wi)
 649                                 {
 650                                         name = wi.wpmodel;
 651                                         rgb = '1 0 0';
 652                                 }
 653                         }
 654                         if(name)
 655                         {
 656                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 657                                 if(self.waypointsprite_attached)
 658                                 {
 659                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 660                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 661                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 662                                 }
 663                         }
 664                         else
 665                         {
 666                                 print("Unknown powerup-marked item is wanting to respawn\n");
 667                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 668                         }
 669                 }
 670
 671                 if(self.waypointsprite_attached)
 672                 {
 673                         entity e;
 674                         entity it = self;
 675                         self = self.waypointsprite_attached;
 676                         FOR_EACH_REALCLIENT(e)
 677                                 if(self.waypointsprite_visible_for_player(e))
 678                                 {
 679                                         msg_entity = e;
 680                                         soundto(MSG_ONE, it, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 681                                 }
 682                         self = it;
 683
 684                         WaypointSprite_Ping(self.waypointsprite_attached);
 685                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 686                 }
 687                 else
 688                         sound(self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 689         }
 690 }
 691
 692 void Item_RespawnThink()
 693 {
 694         self.nextthink = time;
 695         if(self.origin != self.oldorigin)
 696         {
 697                 self.oldorigin = self.origin;
 698                 ItemUpdate(self);
 699         }
 700
 701         if(time >= self.wait)
 702                 Item_Respawn();
 703 }
 704
 705 void Item_ScheduleRespawnIn(entity e, float t)
 706 {
 707         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 708         {
 709                 entity head;
 710                 e.think = Item_RespawnCountdown;
 711                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 712                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 713                 e.count = 0;
 714                 if(e.weapons & WEPSET_SUPERWEAPONS)
 715                 {
 716                         for(t = e.scheduledrespawntime, head = world; (head = nextent(head)); )
 717                         {
 718                                 if(e == head)
 719                                         continue;
 720                                 if(clienttype(head) == CLIENTTYPE_NOTACLIENT)
 721                                 if(head.weapons & WEPSET_SUPERWEAPONS)
 722                                 if(head.classname != "weapon_info")
 723                                 {
 724                                         if(head.scheduledrespawntime <= time)
 725                                         {
 726                                                 t = 0;
 727                                                 break;
 728                                         }
 729                                         if(head.scheduledrespawntime < t)
 730                                                 t = head.scheduledrespawntime;
 731                                 }
 732                         }
 733                 }
 734                 else
 735                 {
 736                         bool isavailable = false;
 737                         for(t = e.scheduledrespawntime, head = world; (head = find(head, classname, e.classname)); )
 738                         {
 739                                 // in instagib .classname is "instagib" for every item
 740                                 if(e == head || (g_instagib && e.items != head.items))
 741                                         continue;
 742                                 if(head.scheduledrespawntime <= time)
 743                                         isavailable = true;
 744                                 else if(head.scheduledrespawntime < t)
 745                                         t = head.scheduledrespawntime;
 746                         }
 747                         if(isavailable)
 748                                 t = -t; // let know the client there's another available item
 749                 }
 750                 Item_ItemsTime_UpdateTime(e, t);
 751                 Item_ItemsTime_SetTimesForAllPlayers();
 752         }
 753         else
 754         {
 755                 e.think = Item_RespawnThink;
 756                 e.nextthink = time;
 757                 e.scheduledrespawntime = time + t;
 758                 e.wait = time + t;
 759         }
 760 }
 761
 762 void Item_ScheduleRespawn(entity e)
 763 {
 764         if(e.respawntime > 0)
 765         {
 766                 Item_Show(e, 0);
 767                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 768         }
 769         else // if respawntime is -1, this item does not respawn
 770                 Item_Show(e, -1);
 771 }
 772
 773 void Item_ScheduleInitialRespawn(entity e)
 774 {
 775         Item_Show(e, 0);
 776         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 777 }
 778
 779 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 780 {
 781         if (!item.(ammotype))
 782                 return false;
 783
 784         if (item.spawnshieldtime)
 785         {
 786                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 787                 {
 788                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 789                         goto YEAH;
 790                 }
 791         }
 792         else if(g_weapon_stay == 2)
 793         {
 794                 float mi = min(item.(ammotype), ammomax);
 795                 if (player.(ammotype) < mi)
 796                 {
 797                         player.(ammotype) = mi;
 798                         goto YEAH;
 799                 }
 800         }
 801
 802         return false;
 803
 804 :YEAH
 805         switch(mode)
 806         {
 807                 case ITEM_MODE_FUEL:
 808                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 809                         break;
 810                 case ITEM_MODE_HEALTH:
 811                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 812                         break;
 813                 case ITEM_MODE_ARMOR:
 814                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 815                         break;
 816                 default:
 817                         break;
 818         }
 819         return true;
 820 }
 821
 822 float Item_GiveTo(entity item, entity player)
 823 {
 824         float _switchweapon;
 825         float pickedup;
 826         float it;
 827         float i;
 828
 829         // if nothing happens to player, just return without taking the item
 830         pickedup = false;
 831         _switchweapon = false;
 832         // in case the player has autoswitch enabled do the following:
 833         // if the player is using their best weapon before items are given, they
 834         // probably want to switch to an even better weapon after items are given
 835         if (player.autoswitch)
 836         if (player.switchweapon == w_getbestweapon(player))
 837                 _switchweapon = true;
 838
 839         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 840                 _switchweapon = true;
 841
 842         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 843         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 844         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 845         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 846         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 847         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 848         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 849         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 850
 851         if (item.flags & FL_WEAPON)
 852         {
 853                 WepSet it;
 854                 it = item.weapons;
 855                 it &= ~player.weapons;
 856
 857                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 858                 {
 859                         pickedup = true;
 860                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 861                         if(it & WepSet_FromWeapon(i))
 862                         {
 863                                 W_DropEvent(WR_PICKUP, player, i, item);
 864                                 W_GiveWeapon(player, i);
 865                         }
 866                 }
 867         }
 868
 869         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 870         {
 871                 pickedup = true;
 872                 player.items |= it;
 873                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 874         }
 875
 876         if (item.strength_finished)
 877         {
 878                 pickedup = true;
 879                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 880         }
 881         if (item.invincible_finished)
 882         {
 883                 pickedup = true;
 884                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 885         }
 886         if (item.superweapons_finished)
 887         {
 888                 pickedup = true;
 889                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 890         }
 891
 892 :skip
 893
 894         // always eat teamed entities
 895         if(item.team)
 896                 pickedup = true;
 897
 898         if (!pickedup)
 899                 return 0;
 900
 901         if (_switchweapon)
 902                 if (player.switchweapon != w_getbestweapon(player))
 903                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 904
 905         return 1;
 906 }
 907
 908 .entity itemdef;
 909
 910 void Item_Touch (void)
 911 {
 912         entity e, head;
 913
 914         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 915         if(self.classname == "droppedweapon")
 916         {
 917                 if (ITEM_TOUCH_NEEDKILL())
 918                 {
 919                         remove(self);
 920                         return;
 921                 }
 922         }
 923
 924         if (!IS_PLAYER(other))
 925                 return;
 926         if (other.frozen)
 927                 return;
 928         if (other.deadflag)
 929                 return;
 930         if (self.solid != SOLID_TRIGGER)
 931                 return;
 932         if (self.owner == other)
 933                 return;
 934         if (time < self.item_spawnshieldtime)
 935                 return;
 936
 937         switch(MUTATOR_CALLHOOK(ItemTouch))
 938         {
 939                 case MUT_ITEMTOUCH_RETURN: { return; }
 940                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 941         }
 942
 943         if (self.classname == "droppedweapon")
 944         {
 945                 self.strength_finished = max(0, self.strength_finished - time);
 946                 self.invincible_finished = max(0, self.invincible_finished - time);
 947                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 948         }
 949         entity it = self.itemdef;
 950         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 951         if (!gave)
 952         {
 953                 if (self.classname == "droppedweapon")
 954                 {
 955                         // undo what we did above
 956                         self.strength_finished += time;
 957                         self.invincible_finished += time;
 958                         self.superweapons_finished += time;
 959                 }
 960                 return;
 961         }
 962
 963         :pickup
 964
 965         other.last_pickup = time;
 966
 967         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 968         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 969
 970         if (self.classname == "droppedweapon")
 971                 remove (self);
 972         else if (self.spawnshieldtime)
 973         {
 974                 if(self.team)
 975                 {
 976                         RandomSelection_Init();
 977                         for(head = world; (head = findfloat(head, team, self.team)); )
 978                         {
 979                                 if(head.flags & FL_ITEM)
 980                                 {
 981                                         Item_Show(head, -1);
 982                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 983                                 }
 984                         }
 985                         e = RandomSelection_chosen_ent;
 986
 987                 }
 988                 else
 989                         e = self;
 990                 Item_ScheduleRespawn(e);
 991         }
 992 }
 993
 994 void Item_Reset()
 995 {
 996         Item_Show(self, !self.state);
 997         setorigin (self, self.origin);
 998
 999         if(self.classname != "droppedweapon")
1000         {
1001                 self.think = Item_Think;
1002                 self.nextthink = time;
1003
1004                 if(self.waypointsprite_attached)
1005                         WaypointSprite_Kill(self.waypointsprite_attached);
1006
1007                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1008                         Item_ScheduleInitialRespawn(self);
1009         }
1010 }
1011
1012 void Item_FindTeam()
1013 {
1014         entity head, e;
1015
1016         if(self.effects & EF_NODRAW)
1017         {
1018                 // marker for item team search
1019                 dprint("Initializing item team ", ftos(self.team), "\n");
1020                 RandomSelection_Init();
1021                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
1022                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
1023                 e = RandomSelection_chosen_ent;
1024                 e.state = 0;
1025                 Item_Show(e, 1);
1026
1027                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
1028                 {
1029                         if(head != e)
1030                         {
1031                                 // make it a non-spawned item
1032                                 Item_Show(head, -1);
1033                                 head.state = 1; // state 1 = initially hidden item
1034                         }
1035                         head.effects &= ~EF_NODRAW;
1036                 }
1037
1038                 Item_Reset();
1039         }
1040 }
1041
1042 // Savage: used for item garbage-collection
1043 // TODO: perhaps nice special effect?
1044 void RemoveItem(void)
1045 {
1046         remove(self);
1047 }
1048
1049 // pickup evaluation functions
1050 // these functions decide how desirable an item is to the bots
1051
1052 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1053
1054 float weapon_pickupevalfunc(entity player, entity item)
1055 {
1056         float c;
1057
1058         // See if I have it already
1059         if(item.weapons & ~player.weapons)
1060         {
1061                 // If I can pick it up
1062                 if(!item.spawnshieldtime)
1063                         c = 0;
1064                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1065                 {
1066                         // Skilled bots will grab more
1067                         c = bound(0, skill / 10, 1) * 0.5;
1068                 }
1069                 else
1070                         c = 0;
1071         }
1072         else
1073                 c = 1;
1074
1075         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1076         if( bot_custom_weapon && c )
1077         {
1078                 // Find the highest position on any range
1079                 int position = -1;
1080                 for (int j = 0; j < WEP_LAST ; ++j){
1081                         if(
1082                                         bot_weapons_far[j] == item.weapon ||
1083                                         bot_weapons_mid[j] == item.weapon ||
1084                                         bot_weapons_close[j] == item.weapon
1085                           )
1086                         {
1087                                 position = j;
1088                                 break;
1089                         }
1090                 }
1091
1092                 // Rate it
1093                 if (position >= 0 )
1094                 {
1095                         position = WEP_LAST - position;
1096                         // item.bot_pickupbasevalue is overwritten here
1097                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1098                 }
1099         }
1100
1101         return item.bot_pickupbasevalue * c;
1102 }
1103
1104 float commodity_pickupevalfunc(entity player, entity item)
1105 {
1106         float c, i;
1107         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1108         entity wi;
1109         c = 0;
1110
1111         // Detect needed ammo
1112         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1113         {
1114                 wi = get_weaponinfo(i);
1115
1116                 if (!(player.weapons & WepSet_FromWeapon(i)))
1117                         continue;
1118
1119                 if(wi.items & IT_SHELLS)
1120                         need_shells = true;
1121                 else if(wi.items & IT_NAILS)
1122                         need_nails = true;
1123                 else if(wi.items & IT_ROCKETS)
1124                         need_rockets = true;
1125                 else if(wi.items & IT_CELLS)
1126                         need_cells = true;
1127                 else if(wi.items & IT_PLASMA)
1128                         need_plasma = true;
1129                 else if(wi.items & IT_FUEL)
1130                         need_fuel = true;
1131         }
1132
1133         // TODO: figure out if the player even has the weapon this ammo is for?
1134         // may not affect strategy much though...
1135         // find out how much more ammo/armor/health the player can hold
1136         if (need_shells)
1137         if (item.ammo_shells)
1138         if (player.ammo_shells < g_pickup_shells_max)
1139                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1140         if (need_nails)
1141         if (item.ammo_nails)
1142         if (player.ammo_nails < g_pickup_nails_max)
1143                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1144         if (need_rockets)
1145         if (item.ammo_rockets)
1146         if (player.ammo_rockets < g_pickup_rockets_max)
1147                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1148         if (need_cells)
1149         if (item.ammo_cells)
1150         if (player.ammo_cells < g_pickup_cells_max)
1151                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1152         if (need_plasma)
1153         if (item.ammo_plasma)
1154         if (player.ammo_plasma < g_pickup_plasma_max)
1155                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1156         if (need_fuel)
1157         if (item.ammo_fuel)
1158         if (player.ammo_fuel < g_pickup_fuel_max)
1159                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1160         if (item.armorvalue)
1161         if (player.armorvalue < item.max_armorvalue)
1162                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1163         if (item.health)
1164         if (player.health < item.max_health)
1165                 c = c + max(0, 1 - player.health / item.max_health);
1166
1167         return item.bot_pickupbasevalue * c;
1168 }
1169
1170 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1171 {
1172         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1173                 RemoveItem();
1174 }
1175
1176 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1177 {
1178         startitem_failed = false;
1179
1180         if(self.model == "")
1181                 self.model = itemmodel;
1182
1183         if(self.model == "")
1184     {
1185         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1186         return;
1187     }
1188
1189         if(self.item_pickupsound == "")
1190                 self.item_pickupsound = pickupsound;
1191
1192         if(!self.respawntime) // both need to be set
1193         {
1194                 self.respawntime = defaultrespawntime;
1195                 self.respawntimejitter = defaultrespawntimejitter;
1196         }
1197
1198         self.items = itemid;
1199         self.weapon = weaponid;
1200
1201         if(weaponid)
1202                 self.weapons = WepSet_FromWeapon(weaponid);
1203
1204         self.flags = FL_ITEM | itemflags;
1205
1206         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1207         {
1208                 startitem_failed = true;
1209                 remove(self);
1210                 return;
1211         }
1212
1213         // is it a dropped weapon?
1214         if (self.classname == "droppedweapon")
1215         {
1216                 self.reset = SUB_Remove;
1217                 // it's a dropped weapon
1218                 self.movetype = MOVETYPE_TOSS;
1219
1220                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1221                 self.think = RemoveItem;
1222                 self.nextthink = time + 20;
1223
1224                 self.takedamage = DAMAGE_YES;
1225                 self.event_damage = Item_Damage;
1226
1227                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1228                 /*
1229                 if(self.items == 0)
1230                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1231                 if(self.ammo_nails == 0)
1232                 if(self.ammo_cells == 0)
1233                 if(self.ammo_rockets == 0)
1234                 if(self.ammo_shells == 0)
1235                 if(self.ammo_fuel == 0)
1236                 if(self.health == 0)
1237                 if(self.armorvalue == 0)
1238                 */
1239                 {
1240                         // if item is worthless after a timer, have it expire then
1241                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1242                 }
1243
1244                 // don't drop if in a NODROP zone (such as lava)
1245                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1246                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1247                 {
1248                         startitem_failed = true;
1249                         remove(self);
1250                         return;
1251                 }
1252         }
1253         else
1254         {
1255                 if(!have_pickup_item())
1256                 {
1257                         startitem_failed = true;
1258                         remove (self);
1259                         return;
1260                 }
1261
1262                 self.reset = Item_Reset;
1263                 // it's a level item
1264                 if(self.spawnflags & 1)
1265                         self.noalign = 1;
1266                 if (self.noalign)
1267                         self.movetype = MOVETYPE_NONE;
1268                 else
1269                         self.movetype = MOVETYPE_TOSS;
1270                 // do item filtering according to game mode and other things
1271                 if (!self.noalign)
1272                 {
1273                         // first nudge it off the floor a little bit to avoid math errors
1274                         setorigin(self, self.origin + '0 0 1');
1275                         // set item size before we spawn a spawnfunc_waypoint
1276                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1277                                 setsize (self, '-16 -16 0', '16 16 48');
1278                         else
1279                                 setsize (self, '-16 -16 0', '16 16 32');
1280
1281                         // note droptofloor returns false if stuck/or would fall too far
1282                         droptofloor();
1283                         waypoint_spawnforitem(self);
1284                 }
1285
1286                 /*
1287                  * can't do it that way, as it would break maps
1288                  * TODO make a target_give like entity another way, that perhaps has
1289                  * the weapon name in a key
1290                 if(self.targetname)
1291                 {
1292                         // target_give not yet supported; maybe later
1293                         print("removed targeted ", self.classname, "\n");
1294                         startitem_failed = true;
1295                         remove (self);
1296                         return;
1297                 }
1298                 */
1299
1300                 if(autocvar_spawn_debug >= 2)
1301                 {
1302                         entity otheritem;
1303                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1304                         {
1305                             // why not flags & fl_item?
1306                                 if(otheritem.is_item)
1307                                 {
1308                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1309                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1310                                         error("Mapper sucks.");
1311                                 }
1312                         }
1313                         self.is_item = true;
1314                 }
1315
1316                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1317
1318                 precache_model (self.model);
1319                 precache_sound (self.item_pickupsound);
1320
1321                 precache_sound ("misc/itemrespawncountdown.wav");
1322                 if(itemid == IT_STRENGTH)
1323                         precache_sound ("misc/strength_respawn.wav");
1324                 else if(itemid == IT_INVINCIBLE)
1325                         precache_sound ("misc/shield_respawn.wav");
1326                 else
1327                         precache_sound ("misc/itemrespawn.wav");
1328
1329                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1330                         self.target = "###item###"; // for finding the nearest item using find()
1331
1332                 Item_ItemsTime_UpdateTime(self, 0);
1333         }
1334
1335         self.bot_pickup = true;
1336         self.bot_pickupevalfunc = pickupevalfunc;
1337         self.bot_pickupbasevalue = pickupbasevalue;
1338         self.mdl = self.model;
1339         self.netname = itemname;
1340         self.touch = Item_Touch;
1341         setmodel(self, "null"); // precision set below
1342         //self.effects |= EF_LOWPRECISION;
1343
1344         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1345     {
1346         self.pos1 = '-16 -16 0';
1347         self.pos2 = '16 16 48';
1348     }
1349         else
1350     {
1351         self.pos1 = '-16 -16 0';
1352         self.pos2 = '16 16 32';
1353     }
1354     setsize (self, self.pos1, self.pos2);
1355
1356     if(itemflags & FL_POWERUP)
1357         self.ItemStatus |= ITS_ANIMATE1;
1358
1359         if(self.armorvalue || self.health)
1360         self.ItemStatus |= ITS_ANIMATE2;
1361
1362         if(itemflags & FL_WEAPON)
1363         {
1364                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1365             self.colormap = 1024; // color shirt=0 pants=0 grey
1366         else
1367             self.gravity = 1;
1368
1369                 self.ItemStatus |= ITS_ANIMATE1;
1370                 self.ItemStatus |= ISF_COLORMAP;
1371         }
1372
1373         self.state = 0;
1374         if(self.team) // broken, no idea why.
1375         {
1376                 if(!self.cnt)
1377                         self.cnt = 1; // item probability weight
1378
1379                 self.effects |= EF_NODRAW; // marker for item team search
1380                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1381         }
1382         else
1383                 Item_Reset();
1384
1385     Net_LinkEntity(self, false, 0, ItemSend);
1386
1387         self.SendFlags |= ISF_SIZE;
1388         if(self.angles)
1389                 self.SendFlags |= ISF_ANGLES;
1390
1391         // call this hook after everything else has been done
1392         if(MUTATOR_CALLHOOK(Item_Spawn))
1393         {
1394                 startitem_failed = true;
1395                 remove(self);
1396                 return;
1397         }
1398 }
1399
1400 void StartItemA (entity a)
1401 {
1402     self.itemdef = a;
1403     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1404 }
1405
1406 void spawnfunc_item_rockets (void) {
1407         if(!self.ammo_rockets)
1408                 self.ammo_rockets = g_pickup_rockets;
1409         if(!self.pickup_anyway)
1410                 self.pickup_anyway = g_pickup_ammo_anyway;
1411     StartItemA (ITEM_Rockets);
1412 }
1413
1414 void spawnfunc_item_bullets (void) {
1415         if(!weaponswapping)
1416         if(autocvar_sv_q3acompat_machineshotgunswap)
1417         if(self.classname != "droppedweapon")
1418         {
1419                 weaponswapping = true;
1420                 spawnfunc_item_shells();
1421                 weaponswapping = false;
1422                 return;
1423         }
1424
1425         if(!self.ammo_nails)
1426                 self.ammo_nails = g_pickup_nails;
1427         if(!self.pickup_anyway)
1428                 self.pickup_anyway = g_pickup_ammo_anyway;
1429     StartItemA (ITEM_Bullets);
1430 }
1431
1432 void spawnfunc_item_cells (void) {
1433         if(!self.ammo_cells)
1434                 self.ammo_cells = g_pickup_cells;
1435         if(!self.pickup_anyway)
1436                 self.pickup_anyway = g_pickup_ammo_anyway;
1437         StartItemA (ITEM_Cells);
1438 }
1439
1440 void spawnfunc_item_plasma()
1441 {
1442         if(!self.ammo_plasma)
1443                 self.ammo_plasma = g_pickup_plasma;
1444         if(!self.pickup_anyway)
1445                 self.pickup_anyway = g_pickup_ammo_anyway;
1446         StartItemA (ITEM_Plasma);
1447 }
1448
1449 void spawnfunc_item_shells (void) {
1450         if(!weaponswapping)
1451         if(autocvar_sv_q3acompat_machineshotgunswap)
1452         if(self.classname != "droppedweapon")
1453         {
1454                 weaponswapping = true;
1455                 spawnfunc_item_bullets();
1456                 weaponswapping = false;
1457                 return;
1458         }
1459
1460         if(!self.ammo_shells)
1461                 self.ammo_shells = g_pickup_shells;
1462         if(!self.pickup_anyway)
1463                 self.pickup_anyway = g_pickup_ammo_anyway;
1464         StartItemA (ITEM_Shells);
1465 }
1466
1467 void spawnfunc_item_armor_small (void) {
1468         if(!self.armorvalue)
1469                 self.armorvalue = g_pickup_armorsmall;
1470         if(!self.max_armorvalue)
1471                 self.max_armorvalue = g_pickup_armorsmall_max;
1472         if(!self.pickup_anyway)
1473                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1474         StartItemA (ITEM_ArmorSmall);
1475 }
1476
1477 void spawnfunc_item_armor_medium (void) {
1478         if(!self.armorvalue)
1479                 self.armorvalue = g_pickup_armormedium;
1480         if(!self.max_armorvalue)
1481                 self.max_armorvalue = g_pickup_armormedium_max;
1482         if(!self.pickup_anyway)
1483                 self.pickup_anyway = g_pickup_armormedium_anyway;
1484         StartItemA (ITEM_ArmorMedium);
1485 }
1486
1487 void spawnfunc_item_armor_big (void) {
1488         if(!self.armorvalue)
1489                 self.armorvalue = g_pickup_armorbig;
1490         if(!self.max_armorvalue)
1491                 self.max_armorvalue = g_pickup_armorbig_max;
1492         if(!self.pickup_anyway)
1493                 self.pickup_anyway = g_pickup_armorbig_anyway;
1494         StartItemA (ITEM_ArmorBig);
1495 }
1496
1497 void spawnfunc_item_armor_large (void) {
1498         if(!self.armorvalue)
1499                 self.armorvalue = g_pickup_armorlarge;
1500         if(!self.max_armorvalue)
1501                 self.max_armorvalue = g_pickup_armorlarge_max;
1502         if(!self.pickup_anyway)
1503                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1504         StartItemA (ITEM_ArmorLarge);
1505 }
1506
1507 void spawnfunc_item_health_small (void) {
1508         if(!self.max_health)
1509                 self.max_health = g_pickup_healthsmall_max;
1510         if(!self.health)
1511                 self.health = g_pickup_healthsmall;
1512         if(!self.pickup_anyway)
1513                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1514         StartItemA (ITEM_HealthSmall);
1515 }
1516
1517 void spawnfunc_item_health_medium (void) {
1518         if(!self.max_health)
1519                 self.max_health = g_pickup_healthmedium_max;
1520         if(!self.health)
1521                 self.health = g_pickup_healthmedium;
1522         if(!self.pickup_anyway)
1523                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1524     StartItemA (ITEM_HealthMedium);
1525 }
1526
1527 void spawnfunc_item_health_large (void) {
1528         if(!self.max_health)
1529                 self.max_health = g_pickup_healthlarge_max;
1530         if(!self.health)
1531                 self.health = g_pickup_healthlarge;
1532         if(!self.pickup_anyway)
1533                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1534         StartItemA (ITEM_HealthLarge);
1535 }
1536
1537 void spawnfunc_item_health_mega (void) {
1538     if(!self.max_health)
1539         self.max_health = g_pickup_healthmega_max;
1540     if(!self.health)
1541         self.health = g_pickup_healthmega;
1542     if(!self.pickup_anyway)
1543         self.pickup_anyway = g_pickup_healthmega_anyway;
1544     StartItemA (ITEM_HealthMega);
1545 }
1546
1547 // support old misnamed entities
1548 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1549 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1550 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1551 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1552 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1553
1554 void spawnfunc_item_strength (void) {
1555                 precache_sound("weapons/strength_fire.wav");
1556                 if(!self.strength_finished)
1557                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1558                 StartItemA (ITEM_Strength);
1559 }
1560
1561 void spawnfunc_item_invincible (void) {
1562                 if(!self.invincible_finished)
1563                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1564                 StartItemA (ITEM_Shield);
1565 }
1566
1567 // compatibility:
1568 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1569
1570 void target_items_use (void)
1571 {
1572         if(activator.classname == "droppedweapon")
1573         {
1574                 EXACTTRIGGER_TOUCH;
1575                 remove(activator);
1576                 return;
1577         }
1578
1579         if (!IS_PLAYER(activator))
1580                 return;
1581         if(activator.deadflag != DEAD_NO)
1582                 return;
1583         EXACTTRIGGER_TOUCH;
1584
1585         entity e;
1586         for(e = world; (e = find(e, classname, "droppedweapon")); )
1587                 if(e.enemy == activator)
1588                         remove(e);
1589
1590         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1591                 centerprint(activator, self.message);
1592 }
1593
1594 void spawnfunc_target_items (void)
1595 {
1596         float n, i, j;
1597         entity e;
1598         string s;
1599
1600         self.use = target_items_use;
1601         if(!self.strength_finished)
1602                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1603         if(!self.invincible_finished)
1604                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1605         if(!self.superweapons_finished)
1606                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1607
1608         precache_sound("misc/itempickup.wav");
1609         precache_sound("misc/megahealth.wav");
1610         precache_sound("misc/armor25.wav");
1611         precache_sound("misc/powerup.wav");
1612         precache_sound("misc/poweroff.wav");
1613         precache_sound("weapons/weaponpickup.wav");
1614
1615         n = tokenize_console(self.netname);
1616         if(argv(0) == "give")
1617         {
1618                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1619         }
1620         else
1621         {
1622                 for(i = 0; i < n; ++i)
1623                 {
1624                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1625                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1626                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1627                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1628                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1629                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1630                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1631                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1632                         else
1633                         {
1634                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1635                                 {
1636                                         e = get_weaponinfo(j);
1637                                         s = W_UndeprecateName(argv(i));
1638                                         if(s == e.netname)
1639                                         {
1640                                                 self.weapons |= WepSet_FromWeapon(j);
1641                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1642                                                         WEP_ACTION(e.weapon, WR_INIT);
1643                                                 break;
1644                                         }
1645                                 }
1646                                 if(j > WEP_LAST)
1647                                         print("target_items: invalid item ", argv(i), "\n");
1648                         }
1649                 }
1650
1651                 string itemprefix, valueprefix;
1652                 if(self.spawnflags == 0)
1653                 {
1654                         itemprefix = "";
1655                         valueprefix = "";
1656                 }
1657                 else if(self.spawnflags == 1)
1658                 {
1659                         itemprefix = "max ";
1660                         valueprefix = "max ";
1661                 }
1662                 else if(self.spawnflags == 2)
1663                 {
1664                         itemprefix = "min ";
1665                         valueprefix = "min ";
1666                 }
1667                 else if(self.spawnflags == 4)
1668                 {
1669                         itemprefix = "minus ";
1670                         valueprefix = "max ";
1671                 }
1672                 else
1673                 {
1674                         error("invalid spawnflags");
1675                         itemprefix = valueprefix = string_null;
1676                 }
1677
1678                 self.netname = "";
1679                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1680                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1681                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1682                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1683                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1684                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1685                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1686                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1687                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1688                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1689                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1690                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1691                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1692                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1693                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1694                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1695                 {
1696                         e = get_weaponinfo(j);
1697                         if(e.weapon)
1698                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1699                 }
1700         }
1701         self.netname = strzone(self.netname);
1702         //print(self.netname, "\n");
1703
1704         n = tokenize_console(self.netname);
1705         for(i = 0; i < n; ++i)
1706         {
1707                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1708                 {
1709                         e = get_weaponinfo(j);
1710                         if(argv(i) == e.netname)
1711                         {
1712                                 WEP_ACTION(e.weapon, WR_INIT);
1713                                 break;
1714                         }
1715                 }
1716         }
1717 }
1718
1719 void spawnfunc_item_fuel(void)
1720 {
1721         if(!self.ammo_fuel)
1722                 self.ammo_fuel = g_pickup_fuel;
1723         if(!self.pickup_anyway)
1724                 self.pickup_anyway = g_pickup_ammo_anyway;
1725         StartItemA (ITEM_JetpackFuel);
1726 }
1727
1728 void spawnfunc_item_fuel_regen(void)
1729 {
1730         if(start_items & IT_FUEL_REGEN)
1731         {
1732                 spawnfunc_item_fuel();
1733                 return;
1734         }
1735         StartItemA (ITEM_JetpackRegen);
1736 }
1737
1738 void spawnfunc_item_jetpack(void)
1739 {
1740         if(!self.ammo_fuel)
1741                 self.ammo_fuel = g_pickup_fuel_jetpack;
1742         if(start_items & IT_JETPACK)
1743         {
1744                 spawnfunc_item_fuel();
1745                 return;
1746         }
1747         StartItemA (ITEM_Jetpack);
1748 }
1749
1750 float GiveWeapon(entity e, float wpn, float op, float val)
1751 {
1752         WepSet v0, v1;
1753         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1754         switch(op)
1755         {
1756                 case OP_SET:
1757                         if(val > 0)
1758                                 e.weapons |= WepSet_FromWeapon(wpn);
1759                         else
1760                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1761                         break;
1762                 case OP_MIN:
1763                 case OP_PLUS:
1764                         if(val > 0)
1765                                 e.weapons |= WepSet_FromWeapon(wpn);
1766                         break;
1767                 case OP_MAX:
1768                         if(val <= 0)
1769                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1770                         break;
1771                 case OP_MINUS:
1772                         if(val > 0)
1773                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1774                         break;
1775         }
1776         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1777         return (v0 != v1);
1778 }
1779
1780 float GiveBit(entity e, .float fld, float bit, float op, float val)
1781 {
1782         float v0, v1;
1783         v0 = (e.(fld) & bit);
1784         switch(op)
1785         {
1786                 case OP_SET:
1787                         if(val > 0)
1788                                 e.(fld) |= bit;
1789                         else
1790                                 e.(fld) &= ~bit;
1791                         break;
1792                 case OP_MIN:
1793                 case OP_PLUS:
1794                         if(val > 0)
1795                                 e.(fld) |= bit;
1796                         break;
1797                 case OP_MAX:
1798                         if(val <= 0)
1799                                 e.(fld) &= ~bit;
1800                         break;
1801                 case OP_MINUS:
1802                         if(val > 0)
1803                                 e.(fld) &= ~bit;
1804                         break;
1805         }
1806         v1 = (e.(fld) & bit);
1807         return (v0 != v1);
1808 }
1809
1810 float GiveValue(entity e, .float fld, float op, float val)
1811 {
1812         float v0, v1;
1813         v0 = e.(fld);
1814         switch(op)
1815         {
1816                 case OP_SET:
1817                         e.(fld) = val;
1818                         break;
1819                 case OP_MIN:
1820                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1821                         break;
1822                 case OP_MAX:
1823                         e.(fld) = min(e.(fld), val);
1824                         break;
1825                 case OP_PLUS:
1826                         e.(fld) += val;
1827                         break;
1828                 case OP_MINUS:
1829                         e.(fld) -= val;
1830                         break;
1831         }
1832         v1 = e.(fld);
1833         return (v0 != v1);
1834 }
1835
1836 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1837 {
1838         if(v1 == v0)
1839                 return;
1840         if(v1 <= v0 - t)
1841         {
1842                 if(snd_decr != "")
1843                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1844         }
1845         else if(v0 >= v0 + t)
1846         {
1847                 if(snd_incr != "")
1848                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1849         }
1850 }
1851
1852 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1853 {
1854         if(v0 < v1)
1855                 e.(rotfield) = max(e.(rotfield), time + rottime);
1856         else if(v0 > v1)
1857                 e.(regenfield) = max(e.(regenfield), time + regentime);
1858 }
1859 float GiveItems(entity e, float beginarg, float endarg)
1860 {
1861         float got, i, j, val, op;
1862         float _switchweapon;
1863         entity wi;
1864         string cmd;
1865
1866         val = 999;
1867         op = OP_SET;
1868
1869         got = 0;
1870
1871         _switchweapon = false;
1872         if (e.autoswitch)
1873                 if (e.switchweapon == w_getbestweapon(e))
1874                         _switchweapon = true;
1875
1876         e.strength_finished = max(0, e.strength_finished - time);
1877         e.invincible_finished = max(0, e.invincible_finished - time);
1878         e.superweapons_finished = max(0, e.superweapons_finished - time);
1879
1880         PREGIVE(e, items);
1881         PREGIVE_WEAPONS(e);
1882         PREGIVE(e, strength_finished);
1883         PREGIVE(e, invincible_finished);
1884         PREGIVE(e, superweapons_finished);
1885         PREGIVE(e, ammo_nails);
1886         PREGIVE(e, ammo_cells);
1887         PREGIVE(e, ammo_plasma);
1888         PREGIVE(e, ammo_shells);
1889         PREGIVE(e, ammo_rockets);
1890         PREGIVE(e, ammo_fuel);
1891         PREGIVE(e, armorvalue);
1892         PREGIVE(e, health);
1893
1894         for(i = beginarg; i < endarg; ++i)
1895         {
1896                 cmd = argv(i);
1897
1898                 if(cmd == "0" || stof(cmd))
1899                 {
1900                         val = stof(cmd);
1901                         continue;
1902                 }
1903                 switch(cmd)
1904                 {
1905                         case "no":
1906                                 op = OP_MAX;
1907                                 val = 0;
1908                                 continue;
1909                         case "max":
1910                                 op = OP_MAX;
1911                                 continue;
1912                         case "min":
1913                                 op = OP_MIN;
1914                                 continue;
1915                         case "plus":
1916                                 op = OP_PLUS;
1917                                 continue;
1918                         case "minus":
1919                                 op = OP_MINUS;
1920                                 continue;
1921                         case "ALL":
1922                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1923                                 got += GiveValue(e, strength_finished, op, val);
1924                                 got += GiveValue(e, invincible_finished, op, val);
1925                                 got += GiveValue(e, superweapons_finished, op, val);
1926                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1927                         case "all":
1928                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1929                                 got += GiveValue(e, health, op, val);
1930                                 got += GiveValue(e, armorvalue, op, val);
1931                         case "allweapons":
1932                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1933                                 {
1934                                         wi = get_weaponinfo(j);
1935                                         if(wi.weapon)
1936                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1937                                                         got += GiveWeapon(e, j, op, val);
1938                                 }
1939                         case "allammo":
1940                                 got += GiveValue(e, ammo_cells, op, val);
1941                                 got += GiveValue(e, ammo_plasma, op, val);
1942                                 got += GiveValue(e, ammo_shells, op, val);
1943                                 got += GiveValue(e, ammo_nails, op, val);
1944                                 got += GiveValue(e, ammo_rockets, op, val);
1945                                 got += GiveValue(e, ammo_fuel, op, val);
1946                                 break;
1947                         case "unlimited_ammo":
1948                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1949                                 break;
1950                         case "unlimited_weapon_ammo":
1951                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1952                                 break;
1953                         case "unlimited_superweapons":
1954                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1955                                 break;
1956                         case "jetpack":
1957                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1958                                 break;
1959                         case "fuel_regen":
1960                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1961                                 break;
1962                         case "strength":
1963                                 got += GiveValue(e, strength_finished, op, val);
1964                                 break;
1965                         case "invincible":
1966                                 got += GiveValue(e, invincible_finished, op, val);
1967                                 break;
1968                         case "superweapons":
1969                                 got += GiveValue(e, superweapons_finished, op, val);
1970                                 break;
1971                         case "cells":
1972                                 got += GiveValue(e, ammo_cells, op, val);
1973                                 break;
1974                         case "plasma":
1975                                 got += GiveValue(e, ammo_plasma, op, val);
1976                                 break;
1977                         case "shells":
1978                                 got += GiveValue(e, ammo_shells, op, val);
1979                                 break;
1980                         case "nails":
1981                         case "bullets":
1982                                 got += GiveValue(e, ammo_nails, op, val);
1983                                 break;
1984                         case "rockets":
1985                                 got += GiveValue(e, ammo_rockets, op, val);
1986                                 break;
1987                         case "health":
1988                                 got += GiveValue(e, health, op, val);
1989                                 break;
1990                         case "armor":
1991                                 got += GiveValue(e, armorvalue, op, val);
1992                                 break;
1993                         case "fuel":
1994                                 got += GiveValue(e, ammo_fuel, op, val);
1995                                 break;
1996                         default:
1997                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1998                                 {
1999                                         wi = get_weaponinfo(j);
2000                                         if(cmd == wi.netname)
2001                                         {
2002                                                 got += GiveWeapon(e, j, op, val);
2003                                                 break;
2004                                         }
2005                                 }
2006                                 if(j > WEP_LAST)
2007                                         print("give: invalid item ", cmd, "\n");
2008                                 break;
2009                 }
2010                 val = 999;
2011                 op = OP_SET;
2012         }
2013
2014         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
2015         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
2016         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
2017         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
2018         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
2019         {
2020                 wi = get_weaponinfo(j);
2021                 if(wi.weapon)
2022                 {
2023                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
2024                         if (!(save_weapons & WepSet_FromWeapon(j)))
2025                                 if(e.weapons & WepSet_FromWeapon(j))
2026                                         WEP_ACTION(wi.weapon, WR_INIT);
2027                 }
2028         }
2029         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2030         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2031         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2032         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2033         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
2034         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2035         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2036         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2037         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2038         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2039
2040         if(e.superweapons_finished <= 0)
2041                 if(self.weapons & WEPSET_SUPERWEAPONS)
2042                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2043
2044         if(e.strength_finished <= 0)
2045                 e.strength_finished = 0;
2046         else
2047                 e.strength_finished += time;
2048         if(e.invincible_finished <= 0)
2049                 e.invincible_finished = 0;
2050         else
2051                 e.invincible_finished += time;
2052         if(e.superweapons_finished <= 0)
2053                 e.superweapons_finished = 0;
2054         else
2055                 e.superweapons_finished += time;
2056
2057         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2058                 _switchweapon = true;
2059         if(_switchweapon)
2060                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2061
2062         return got;
2063 }
2064 #endif