qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle() {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10
  11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  14         WriteCoord(MSG_BROADCAST, v_x);
  15         WriteCoord(MSG_BROADCAST, v_y);
  16         WriteCoord(MSG_BROADCAST, v_z);
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, myvel;
  22         if(issecondary)
  23         {
  24                 mydmg = cvar("g_balance_nex_secondary_damage");
  25                 myforce = cvar("g_balance_nex_secondary_force");
  26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
  27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
  28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
  29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
  30                 myammo = cvar("g_balance_nex_secondary_ammo");
  31         }
  32         else
  33         {
  34                 mydmg = cvar("g_balance_nex_primary_damage");
  35                 myforce = cvar("g_balance_nex_primary_force");
  36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
  37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
  38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
  39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
  40                 myammo = cvar("g_balance_nex_primary_ammo");
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         if(cvar("g_balance_nex_velocitydependent")) // player velocity dependent damage and force
  47         {
  48                 myvel = vlen(self.velocity);
  49                 myvel = bound(cvar("g_balance_nex_velocitydependent_minspeed"), myvel, cvar("g_balance_nex_velocitydependent_maxspeed"));
  50
  51                 // TODO: make it more obvious (through effects, indicator on weapon) that damage increases when speed increases
  52                 mydmg *= myvel / cvar("g_balance_nex_velocitydependent_maxspeed");
  53                 myforce *= myvel / cvar("g_balance_nex_velocitydependent_maxspeed");
  54         }
  55
  56         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
  57
  58         yoda = 0;
  59         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  60
  61         if(yoda && flying)
  62                 AnnounceTo(self, "yoda");
  63
  64         //beam and muzzle flash done on client
  65         SendCSQCNexBeamParticle();
  66
  67         // flash and burn the wall
  68         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  69                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  70
  71         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  72                 self.ammo_cells = self.ammo_cells - myammo;
  73 }
  74
  75 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  76
  77 float w_nex(float req)
  78 {
  79         if (req == WR_AIM)
  80         {
  81                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  82                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  83         }
  84         else if (req == WR_THINK)
  85         {
  86                 if (self.BUTTON_ATCK)
  87                 {
  88                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
  89                         {
  90                                 W_Nex_Attack(0);
  91                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
  92                         }
  93                 }
  94                 if (self.BUTTON_ATCK2)
  95                 {
  96                         if(cvar("g_balance_nex_secondary"))
  97                         {
  98                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
  99                                 {
 100                                         W_Nex_Attack(1);
 101                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
 102                                 }
 103                         }
 104                 }
 105         }
 106         else if (req == WR_PRECACHE)
 107         {
 108                 precache_model ("models/nexflash.md3");
 109                 precache_model ("models/weapons/g_nex.md3");
 110                 precache_model ("models/weapons/v_nex.md3");
 111                 precache_model ("models/weapons/h_nex.iqm");
 112                 precache_sound ("weapons/nexfire.wav");
 113                 precache_sound ("weapons/nexwhoosh1.wav");
 114                 precache_sound ("weapons/nexwhoosh2.wav");
 115                 precache_sound ("weapons/nexwhoosh3.wav");
 116         }
 117         else if (req == WR_SETUP)
 118                 weapon_setup(WEP_NEX);
 119         else if (req == WR_CHECKAMMO1)
 120                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 121         else if (req == WR_CHECKAMMO2)
 122                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
 123         return TRUE;
 124 };
 125 #endif
 126 #ifdef CSQC
 127 float w_nex(float req)
 128 {
 129         if(req == WR_IMPACTEFFECT)
 130         {
 131                 vector org2;
 132                 org2 = w_org + w_backoff * 6;
 133                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 134                 if(!w_issilent)
 135                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 136         }
 137         else if(req == WR_PRECACHE)
 138         {
 139                 precache_sound("weapons/neximpact.wav");
 140         }
 141         else if (req == WR_SUICIDEMESSAGE)
 142                 w_deathtypestring = "%s did the impossible";
 143         else if (req == WR_KILLMESSAGE)
 144                 w_deathtypestring = "%s has been vaporized by %s";
 145         return TRUE;
 146 }
 147 #endif
 148 #endif