qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         Cmd_HUD_SetFields(0);
 100
 101         postinit = false;
 102
 103         calledhooks = 0;
 104
 105         teams = Sort_Spawn();
 106         players = Sort_Spawn();
 107
 108         GetTeam(NUM_SPECTATOR, true); // add specs first
 109
 110         // needs to be done so early because of the constants they create
 111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 118
 119         WaypointSprite_Load();
 120
 121         // precaches
 122         precache_model("null");
 123         precache_sound("misc/hit.wav");
 124         precache_sound("misc/typehit.wav");
 125
 126         Projectile_Precache();
 127         Hook_Precache();
 128         GibSplash_Precache();
 129         Casings_Precache();
 130         Vehicles_Precache();
 131         turrets_precache();
 132         Tuba_Precache();
 133         CSQCPlayer_Precache();
 134
 135         if(autocvar_cl_reticle)
 136         {
 137                 precache_pic("gfx/reticle_normal");
 138                 // weapon reticles are precached in weapon files
 139         }
 140
 141         get_mi_min_max_texcoords(1); // try the CLEVER way first
 142         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 143         shortmapname = mi_shortname;
 144
 145         if(precache_pic(minimapname) == "")
 146         {
 147                 // but maybe we have a non-clever minimap
 148                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 149                 if(precache_pic(minimapname) == "")
 150                         minimapname = ""; // FAIL
 151                 else
 152                         get_mi_min_max_texcoords(0); // load new texcoords
 153         }
 154
 155         mi_center = (mi_min + mi_max) * 0.5;
 156         mi_scale = mi_max - mi_min;
 157         minimapname = strzone(minimapname);
 158
 159         WarpZone_Init();
 160
 161         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 162         hud_configure_prev = -1;
 163
 164         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 165 }
 166
 167 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 168 void Shutdown(void)
 169 {
 170 #ifdef USE_FTE
 171 #pragma TARGET id
 172         if(!__engine_check)
 173                 return 0;
 174 #pragma TARGET fte
 175 #endif
 176
 177         WarpZone_Shutdown();
 178
 179         remove(teams);
 180         remove(players);
 181         db_close(binddb);
 182         db_close(tempdb);
 183         if(autocvar_cl_db_saveasdump)
 184                 db_dump(ClientProgsDB, "client.db");
 185         else
 186                 db_save(ClientProgsDB, "client.db");
 187         db_close(ClientProgsDB);
 188
 189         if(camera_active)
 190                 cvar_set("chase_active",ftos(chase_active_backup));
 191
 192         // unset the event chasecam's chase_active
 193         if(autocvar_chase_active < 0)
 194                 cvar_set("chase_active", "0");
 195
 196         if (!isdemo())
 197         {
 198                 if (!(calledhooks & HOOK_START))
 199                         localcmd("\n_cl_hook_gamestart nop\n");
 200                 if (!(calledhooks & HOOK_END))
 201                         localcmd("\ncl_hook_gameend\n");
 202         }
 203 }
 204
 205 .float has_team;
 206 float SetTeam(entity o, float Team)
 207 {
 208         entity tm;
 209         if(teamplay)
 210         {
 211                 switch(Team)
 212                 {
 213                         case -1:
 214                         case NUM_TEAM_1:
 215                         case NUM_TEAM_2:
 216                         case NUM_TEAM_3:
 217                         case NUM_TEAM_4:
 218                                 break;
 219                         default:
 220                                 if(GetTeam(Team, false) == world)
 221                                 {
 222                                         dprintf("trying to switch to unsupported team %d\n", Team);
 223                                         Team = NUM_SPECTATOR;
 224                                 }
 225                                 break;
 226                 }
 227         }
 228         else
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case 0:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         dprintf("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         if(Team == -1) // leave
 245         {
 246                 if(o.has_team)
 247                 {
 248                         tm = GetTeam(o.team, false);
 249                         tm.team_size -= 1;
 250                         o.has_team = 0;
 251                         return TRUE;
 252                 }
 253         }
 254         else
 255         {
 256                 if (!o.has_team)
 257                 {
 258                         o.team = Team;
 259                         tm = GetTeam(Team, true);
 260                         tm.team_size += 1;
 261                         o.has_team = 1;
 262                         return TRUE;
 263                 }
 264                 else if(Team != o.team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         return TRUE;
 272                 }
 273         }
 274         return FALSE;
 275 }
 276
 277 void Playerchecker_Think()
 278 {
 279         float i;
 280         entity e;
 281         for(i = 0; i < maxclients; ++i)
 282         {
 283                 e = playerslots[i];
 284                 if(GetPlayerName(i) == "")
 285                 {
 286                         if(e.sort_prev)
 287                         {
 288                                 // player disconnected
 289                                 SetTeam(e, -1);
 290                                 RemovePlayer(e);
 291                                 e.sort_prev = world;
 292                                 //e.gotscores = 0;
 293                         }
 294                 }
 295                 else
 296                 {
 297                         if (!e.sort_prev)
 298                         {
 299                                 // player connected
 300                                 if (!e)
 301                                         playerslots[i] = e = spawn();
 302                                 e.sv_entnum = i;
 303                                 e.ping = 0;
 304                                 e.ping_packetloss = 0;
 305                                 e.ping_movementloss = 0;
 306                                 //e.gotscores = 0; // we might already have the scores...
 307                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 308                                 RegisterPlayer(e);
 309                                 HUD_UpdatePlayerPos(e);
 310                         }
 311                 }
 312         }
 313         self.nextthink = time + 0.2;
 314 }
 315
 316 void Porto_Init();
 317 void TrueAim_Init();
 318 void PostInit(void)
 319 {
 320         entity playerchecker;
 321         playerchecker = spawn();
 322         playerchecker.think = Playerchecker_Think;
 323         playerchecker.nextthink = time + 0.2;
 324
 325         Porto_Init();
 326         TrueAim_Init();
 327
 328         postinit = true;
 329 }
 330
 331 float button_zoom;
 332
 333 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 334 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 335 // All keys are in ascii.
 336 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 337 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 338 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 339 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 340 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 341 {
 342         float bSkipKey;
 343         bSkipKey = false;
 344
 345         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 346                 return true;
 347
 348         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 349                 return true;
 350
 351         if(menu_visible && menu_action)
 352                 if(menu_action(bInputType, nPrimary, nSecondary))
 353                         return TRUE;
 354
 355         return bSkipKey;
 356 }
 357
 358 // END REQUIRED CSQC FUNCTIONS
 359 // --------------------------------------------------------------------------
 360
 361 // --------------------------------------------------------------------------
 362 // BEGIN OPTIONAL CSQC FUNCTIONS
 363 void Ent_RemoveEntCS()
 364 {
 365         entcs_receiver[self.sv_entnum] = world;
 366 }
 367 void Ent_ReadEntCS()
 368 {
 369         float sf;
 370         InterpolateOrigin_Undo();
 371
 372         self.classname = "entcs_receiver";
 373         sf = ReadByte();
 374
 375         if(sf & 1)
 376                 self.sv_entnum = ReadByte();
 377         if(sf & 2)
 378         {
 379                 self.origin_x = ReadShort();
 380                 self.origin_y = ReadShort();
 381                 self.origin_z = ReadShort();
 382                 setorigin(self, self.origin);
 383         }
 384         if(sf & 4)
 385         {
 386                 self.angles_y = ReadByte() * 360.0 / 256;
 387                 self.angles_x = self.angles_z = 0;
 388         }
 389         if(sf & 8)
 390                 self.healthvalue = ReadByte() * 10;
 391         if(sf & 16)
 392                 self.armorvalue = ReadByte() * 10;
 393
 394         entcs_receiver[self.sv_entnum] = self;
 395         self.entremove = Ent_RemoveEntCS;
 396         self.iflags |= IFLAG_ORIGIN;
 397
 398         InterpolateOrigin_Note();
 399 }
 400
 401 void Ent_Remove();
 402
 403 void Ent_RemovePlayerScore()
 404 {
 405         float i;
 406
 407         if(self.owner)
 408         {
 409                 SetTeam(self.owner, -1);
 410                 self.owner.gotscores = 0;
 411                 for(i = 0; i < MAX_SCORE; ++i)
 412                         self.owner.(scores[i]) = 0; // clear all scores
 413         }
 414 }
 415
 416 void Ent_ReadPlayerScore()
 417 {
 418         float i, n;
 419         float isNew;
 420         entity o;
 421
 422         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 423         // (no I've never heard of M-x replace-string, sed, or anything like that)
 424         isNew = !self.owner; // workaround for DP bug
 425         n = ReadByte()-1;
 426
 427 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 428         if(!isNew && n != self.sv_entnum)
 429         {
 430                 //print("A CSQC entity changed its owner!\n");
 431                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 432                 isNew = true;
 433                 Ent_Remove();
 434                 self.enttype = ENT_CLIENT_SCORES;
 435         }
 436 #endif
 437
 438         self.sv_entnum = n;
 439
 440         if (!(playerslots[self.sv_entnum]))
 441                 playerslots[self.sv_entnum] = spawn();
 442         o = self.owner = playerslots[self.sv_entnum];
 443         o.sv_entnum = self.sv_entnum;
 444         o.gotscores = 1;
 445
 446         //if (!o.sort_prev)
 447         //      RegisterPlayer(o);
 448         //playerchecker will do this for us later, if it has not already done so
 449
 450         float sf, lf;
 451 #if MAX_SCORE <= 8
 452         sf = ReadByte();
 453         lf = ReadByte();
 454 #else
 455         sf = ReadShort();
 456         lf = ReadShort();
 457 #endif
 458         float p;
 459         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 460                 if(sf & p)
 461                 {
 462                         if(lf & p)
 463                                 o.(scores[i]) = ReadInt24_t();
 464                         else
 465                                 o.(scores[i]) = ReadChar();
 466                 }
 467
 468         if(o.sort_prev)
 469                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 470
 471         self.entremove = Ent_RemovePlayerScore;
 472 }
 473
 474 void Ent_ReadTeamScore()
 475 {
 476         float i;
 477         entity o;
 478
 479         self.team = ReadByte();
 480         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 481
 482         float sf, lf;
 483 #if MAX_TEAMSCORE <= 8
 484         sf = ReadByte();
 485         lf = ReadByte();
 486 #else
 487         sf = ReadShort();
 488         lf = ReadShort();
 489 #endif
 490         float p;
 491         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 492                 if(sf & p)
 493                 {
 494                         if(lf & p)
 495                                 o.(teamscores[i]) = ReadInt24_t();
 496                         else
 497                                 o.(teamscores[i]) = ReadChar();
 498                 }
 499
 500         HUD_UpdateTeamPos(o);
 501 }
 502
 503 void Ent_ClientData()
 504 {
 505         float f;
 506         float newspectatee_status;
 507
 508         f = ReadByte();
 509
 510         scoreboard_showscores_force = (f & 1);
 511
 512         if(f & 2)
 513         {
 514                 newspectatee_status = ReadByte();
 515                 if(newspectatee_status == player_localnum + 1)
 516                         newspectatee_status = -1; // observing
 517         }
 518         else
 519                 newspectatee_status = 0;
 520
 521         spectatorbutton_zoom = (f & 4);
 522
 523         if(f & 8)
 524         {
 525                 angles_held_status = 1;
 526                 angles_held_x = ReadAngle();
 527                 angles_held_y = ReadAngle();
 528                 angles_held_z = 0;
 529         }
 530         else
 531                 angles_held_status = 0;
 532
 533         if(newspectatee_status != spectatee_status)
 534         {
 535                 // clear race stuff
 536                 race_laptime = 0;
 537                 race_checkpointtime = 0;
 538         }
 539         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 540         {
 541                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 542                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 543                 )
 544                         prev_p_health = -1;
 545                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 546                         prev_health = -1;
 547         }
 548         spectatee_status = newspectatee_status;
 549
 550         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 551 }
 552
 553 void Ent_Nagger()
 554 {
 555         float nags, i, j, b, f;
 556
 557         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 558
 559         if(!(nags & 4))
 560         {
 561                 if(vote_called_vote)
 562                         strunzone(vote_called_vote);
 563                 vote_called_vote = string_null;
 564                 vote_active = 0;
 565         }
 566         else
 567         {
 568                 vote_active = 1;
 569         }
 570
 571         if(nags & 64)
 572         {
 573                 vote_yescount = ReadByte();
 574                 vote_nocount = ReadByte();
 575                 vote_needed = ReadByte();
 576                 vote_highlighted = ReadChar();
 577         }
 578
 579         if(nags & 128)
 580         {
 581                 if(vote_called_vote)
 582                         strunzone(vote_called_vote);
 583                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 584         }
 585
 586         if(nags & 1)
 587         {
 588                 for(j = 0; j < maxclients; ++j)
 589                         if(playerslots[j])
 590                                 playerslots[j].ready = 1;
 591                 for(i = 1; i <= maxclients; i += 8)
 592                 {
 593                         f = ReadByte();
 594                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 595                                 if (!(f & b))
 596                                         if(playerslots[j])
 597                                                 playerslots[j].ready = 0;
 598                 }
 599         }
 600
 601         ready_waiting = (nags & 1);
 602         ready_waiting_for_me = (nags & 2);
 603         vote_waiting = (nags & 4);
 604         vote_waiting_for_me = (nags & 8);
 605         warmup_stage = (nags & 16);
 606 }
 607
 608 void Ent_EliminatedPlayers()
 609 {
 610         float sf, i, j, b, f;
 611
 612         sf = ReadByte();
 613         if(sf & 1)
 614         {
 615                 for(j = 0; j < maxclients; ++j)
 616                         if(playerslots[j])
 617                                 playerslots[j].eliminated = 1;
 618                 for(i = 1; i <= maxclients; i += 8)
 619                 {
 620                         f = ReadByte();
 621                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 622                                 if (!(f & b))
 623                                         if(playerslots[j])
 624                                                 playerslots[j].eliminated = 0;
 625                 }
 626         }
 627 }
 628
 629 void Ent_RandomSeed()
 630 {
 631         float s;
 632         prandom_debug();
 633         s = ReadShort();
 634         psrandom(s);
 635 }
 636
 637 void Ent_ReadAccuracy(void)
 638 {
 639         float sf, f, w, b;
 640         sf = ReadInt24_t();
 641         if(sf == 0)
 642         {
 643                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 644                         weapon_accuracy[w] = -1;
 645                 return;
 646         }
 647
 648         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 649         {
 650                 if(sf & f)
 651                 {
 652                         b = ReadByte();
 653                         if(b == 0)
 654                                 weapon_accuracy[w] = -1;
 655                         else if(b == 255)
 656                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 657                         else
 658                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 659                 }
 660                 if(f == 0x800000)
 661                         f = 1;
 662                 else
 663                         f *= 2;
 664         }
 665 }
 666
 667 void Spawn_Draw(void)
 668 {
 669         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 670 }
 671
 672 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 673 {
 674         float teamnum = (ReadByte() - 1);
 675         vector spn_origin;
 676         spn_origin_x = ReadShort();
 677         spn_origin_y = ReadShort();
 678         spn_origin_z = ReadShort();
 679
 680         if(is_new)
 681         {
 682                 self.origin = spn_origin;
 683                 setsize(self, PL_MIN, PL_MAX);
 684                 droptofloor();
 685
 686                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 687                 {
 688                         self.mdl = "models/spawnpoint.md3";
 689                         self.colormod = Team_ColorRGB(teamnum);
 690                         precache_model(self.mdl);
 691                         setmodel(self, self.mdl);
 692                         self.drawmask = MASK_NORMAL;
 693                         //self.movetype = MOVETYPE_NOCLIP;
 694                         //self.draw = Spawn_Draw;
 695                 }*/
 696                 if(autocvar_cl_spawn_point_particles)
 697                 {
 698                         if((serverflags & SERVERFLAG_TEAMPLAY))
 699                         {
 700                                 switch(teamnum)
 701                                 {
 702                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 703                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 704                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 705                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 706                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 707                                 }
 708                         }
 709                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 710
 711                         self.draw = Spawn_Draw;
 712                 }
 713         }
 714
 715         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 716 }
 717
 718 void Ent_ReadSpawnEvent(float is_new)
 719 {
 720         // If entnum is 0, ONLY do the local spawn actions
 721         // this way the server can disable the sending of
 722         // spawn origin or such to clients if wanted.
 723         float entnum = ReadByte();
 724
 725         if(entnum)
 726         {
 727                 self.origin_x = ReadShort();
 728                 self.origin_y = ReadShort();
 729                 self.origin_z = ReadShort();
 730
 731                 if(is_new)
 732                 {
 733                         float teamnum = GetPlayerColor(entnum - 1);
 734
 735                         if(autocvar_cl_spawn_event_particles)
 736                         {
 737                                 switch(teamnum)
 738                                 {
 739                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 740                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 741                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 742                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 743                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 744                                 }
 745                         }
 746                         if(autocvar_cl_spawn_event_sound)
 747                         {
 748                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 749                         }
 750                 }
 751         }
 752
 753         // local spawn actions
 754         if(is_new && (!entnum || (entnum == player_localentnum)))
 755         {
 756                 zoomin_effect = 1;
 757                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 758
 759                 if(autocvar_cl_unpress_zoom_on_spawn)
 760                 {
 761                         localcmd("-zoom\n");
 762                         button_zoom = FALSE;
 763                 }
 764         }
 765
 766         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 767 }
 768
 769 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 770 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 771 void Ent_RadarLink();
 772 void Ent_Init();
 773 void Ent_ScoresInfo();
 774 void ent_func_ladder();
 775 void ent_trigger_push();
 776 void ent_target_push();
 777 void CSQC_Ent_Update(float bIsNewEntity)
 778 {
 779         float t;
 780         float savetime;
 781         t = ReadByte();
 782
 783         if(autocvar_developer_csqcentities)
 784                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 785
 786         // set up the "time" global for received entities to be correct for interpolation purposes
 787         savetime = time;
 788         if(servertime)
 789         {
 790                 time = servertime;
 791         }
 792         else
 793         {
 794                 serverprevtime = time;
 795                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 796                 time = serverprevtime + serverdeltatime;
 797         }
 798
 799 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 800         if(self.enttype)
 801         {
 802                 if(t != self.enttype || bIsNewEntity)
 803                 {
 804                         //print("A CSQC entity changed its type!\n");
 805                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 806                         Ent_Remove();
 807                         clearentity(self);
 808                         bIsNewEntity = 1;
 809                 }
 810         }
 811         else
 812         {
 813                 if(!bIsNewEntity)
 814                 {
 815                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 816                         bIsNewEntity = 1;
 817                 }
 818         }
 819 #endif
 820         self.enttype = t;
 821         switch(t)
 822         {
 823                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 824                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 825                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 826                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 827                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 828                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 829                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 830                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 831                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 832                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 833                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 834                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 835                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 836                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 837                 case ENT_CLIENT_INIT: Ent_Init(); break;
 838                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 839                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 840                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 841                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 842                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 843                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 844                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 845                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 846                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 847                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 848                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 849                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 850                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 851                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 852                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 853                 case ENT_CLIENT_TURRET: ent_turret(); break;
 854                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 855                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 856                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 857                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 858                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 859                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 860                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 861                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 862                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 863                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 864
 865                 default:
 866                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 867                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 868                         break;
 869         }
 870
 871         time = savetime;
 872 }
 873 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 874 // used when an entity changes its type. For an entity that someone interacts
 875 // with others, make sure it can no longer do so.
 876 void Ent_Remove()
 877 {
 878         if(self.entremove)
 879                 self.entremove();
 880
 881         if(self.skeletonindex)
 882         {
 883                 skel_delete(self.skeletonindex);
 884                 self.skeletonindex = 0;
 885         }
 886
 887         if(self.snd_looping > 0)
 888         {
 889                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 890                 self.snd_looping = 0;
 891         }
 892
 893         self.enttype = 0;
 894         self.classname = "";
 895         self.draw = menu_sub_null;
 896         self.entremove = menu_sub_null;
 897         // TODO possibly set more stuff to defaults
 898 }
 899 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 900 void CSQC_Ent_Remove()
 901 {
 902         if(autocvar_developer_csqcentities)
 903                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 904
 905         if(wasfreed(self))
 906         {
 907                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 908                 return;
 909         }
 910         if(self.enttype)
 911                 Ent_Remove();
 912         remove(self);
 913 }
 914
 915 void Gamemode_Init()
 916 {
 917         if (!isdemo())
 918         {
 919                 if(!(calledhooks & HOOK_START))
 920                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 921                 calledhooks |= HOOK_START;
 922         }
 923 }
 924 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 925 void CSQC_Parse_StuffCmd(string strMessage)
 926 {
 927         if(autocvar_developer_csqcentities)
 928                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 929
 930         localcmd(strMessage);
 931 }
 932 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 933 void CSQC_Parse_Print(string strMessage)
 934 {
 935         if(autocvar_developer_csqcentities)
 936                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 937
 938         print(ColorTranslateRGB(strMessage));
 939 }
 940
 941 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 942 void CSQC_Parse_CenterPrint(string strMessage)
 943 {
 944         if(autocvar_developer_csqcentities)
 945                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 946
 947         centerprint_hud(strMessage);
 948 }
 949
 950 string notranslate_fogcmd1 = "\nfog ";
 951 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 952 void Fog_Force()
 953 {
 954         // TODO somehow thwart prvm_globalset client ...
 955
 956         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 957                 { localcmd("\nr_drawfog 0\n"); }
 958         else if(forcefog != "")
 959                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 960 }
 961
 962 void Gamemode_Init();
 963 void Ent_ScoresInfo()
 964 {
 965         float i;
 966         self.classname = "ent_client_scores_info";
 967         gametype = ReadInt24_t();
 968         HUD_ModIcons_SetFunc();
 969         for(i = 0; i < MAX_SCORE; ++i)
 970         {
 971                 if(scores_label[i])
 972                         strunzone(scores_label[i]);
 973                 scores_label[i] = strzone(ReadString());
 974                 scores_flags[i] = ReadByte();
 975         }
 976         for(i = 0; i < MAX_TEAMSCORE; ++i)
 977         {
 978                 if(teamscores_label[i])
 979                         strunzone(teamscores_label[i]);
 980                 teamscores_label[i] = strzone(ReadString());
 981                 teamscores_flags[i] = ReadByte();
 982         }
 983         HUD_InitScores();
 984         Gamemode_Init();
 985 }
 986
 987 void Ent_Init()
 988 {
 989         self.classname = "ent_client_init";
 990
 991         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 992
 993         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 994         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 995         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 996         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 997         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 998         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 999         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1000         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1001
1002         if(forcefog)
1003                 strunzone(forcefog);
1004         forcefog = strzone(ReadString());
1005
1006         armorblockpercent = ReadByte() / 255.0;
1007
1008         g_balance_mortar_bouncefactor = ReadCoord();
1009         g_balance_mortar_bouncestop = ReadCoord();
1010         g_balance_electro_secondary_bouncefactor = ReadCoord();
1011         g_balance_electro_secondary_bouncestop = ReadCoord();
1012
1013         vortex_scope = !ReadByte();
1014         rifle_scope = !ReadByte();
1015
1016         serverflags = ReadByte();
1017
1018         minelayer_maxmines = ReadByte();
1019
1020         hagar_maxrockets = ReadByte();
1021
1022         g_trueaim_minrange = ReadCoord();
1023         g_balance_porto_secondary = ReadByte();
1024
1025         if(!postinit)
1026                 PostInit();
1027 }
1028
1029 void Net_ReadRace()
1030 {
1031         float b;
1032
1033         b = ReadByte();
1034
1035         switch(b)
1036         {
1037                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1038                         race_checkpoint = ReadByte();
1039                         race_time = ReadInt24_t();
1040                         race_previousbesttime = ReadInt24_t();
1041                         if(race_previousbestname)
1042                                 strunzone(race_previousbestname);
1043                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1044
1045                         race_checkpointtime = time;
1046
1047                         if(race_checkpoint == 0 || race_checkpoint == 254)
1048                         {
1049                                 race_penaltyaccumulator = 0;
1050                                 race_laptime = time; // valid
1051                         }
1052
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_CLEAR:
1056                         race_laptime = 0;
1057                         race_checkpointtime = 0;
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1061                         race_laptime = ReadCoord();
1062                         race_checkpointtime = -99999;
1063                         // fall through
1064                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1065                         race_nextcheckpoint = ReadByte();
1066
1067                         race_nextbesttime = ReadInt24_t();
1068                         if(race_nextbestname)
1069                                 strunzone(race_nextbestname);
1070                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_HIT_RACE:
1074                         race_mycheckpoint = ReadByte();
1075                         race_mycheckpointtime = time;
1076                         race_mycheckpointdelta = ReadInt24_t();
1077                         race_mycheckpointlapsdelta = ReadByte();
1078                         if(race_mycheckpointlapsdelta >= 128)
1079                                 race_mycheckpointlapsdelta -= 256;
1080                         if(race_mycheckpointenemy)
1081                                 strunzone(race_mycheckpointenemy);
1082                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1083                         break;
1084
1085                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1086                         race_othercheckpoint = ReadByte();
1087                         race_othercheckpointtime = time;
1088                         race_othercheckpointdelta = ReadInt24_t();
1089                         race_othercheckpointlapsdelta = ReadByte();
1090                         if(race_othercheckpointlapsdelta >= 128)
1091                                 race_othercheckpointlapsdelta -= 256;
1092                         if(race_othercheckpointenemy)
1093                                 strunzone(race_othercheckpointenemy);
1094                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1095                         break;
1096
1097                 case RACE_NET_PENALTY_RACE:
1098                         race_penaltyeventtime = time;
1099                         race_penaltytime = ReadShort();
1100                         //race_penaltyaccumulator += race_penaltytime;
1101                         if(race_penaltyreason)
1102                                 strunzone(race_penaltyreason);
1103                         race_penaltyreason = strzone(ReadString());
1104                         break;
1105
1106                 case RACE_NET_PENALTY_QUALIFYING:
1107                         race_penaltyeventtime = time;
1108                         race_penaltytime = ReadShort();
1109                         race_penaltyaccumulator += race_penaltytime;
1110                         if(race_penaltyreason)
1111                                 strunzone(race_penaltyreason);
1112                         race_penaltyreason = strzone(ReadString());
1113                         break;
1114
1115                 case RACE_NET_SERVER_RECORD:
1116                         race_server_record = ReadInt24_t();
1117                         break;
1118                 case RACE_NET_SPEED_AWARD:
1119                         race_speedaward = ReadInt24_t();
1120                         if(race_speedaward_holder)
1121                                 strunzone(race_speedaward_holder);
1122                         race_speedaward_holder = strzone(ReadString());
1123                         break;
1124                 case RACE_NET_SPEED_AWARD_BEST:
1125                         race_speedaward_alltimebest = ReadInt24_t();
1126                         if(race_speedaward_alltimebest_holder)
1127                                 strunzone(race_speedaward_alltimebest_holder);
1128                         race_speedaward_alltimebest_holder = strzone(ReadString());
1129                         break;
1130                 case RACE_NET_SERVER_RANKINGS:
1131                         float pos, prevpos, del;
1132                         pos = ReadShort();
1133                         prevpos = ReadShort();
1134                         del = ReadShort();
1135
1136                         // move other rankings out of the way
1137                         float i;
1138                         if (prevpos) {
1139                                 for (i=prevpos-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         } else if (del) { // a record has been deleted by the admin
1146                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1147                                         if (i == RANKINGS_CNT-1) { // clear out last record
1148                                                 grecordtime[i] = 0;
1149                                                 if (grecordholder[i])
1150                                                         strunzone(grecordholder[i]);
1151                                                 grecordholder[i] = string_null;
1152                                         }
1153                                         else {
1154                                                 grecordtime[i] = grecordtime[i+1];
1155                                                 if (grecordholder[i])
1156                                                         strunzone(grecordholder[i]);
1157                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1158                                         }
1159                                 }
1160                         } else { // player has no ranked record yet
1161                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1162                                         grecordtime[i] = grecordtime[i-1];
1163                                         if(grecordholder[i])
1164                                                 strunzone(grecordholder[i]);
1165                                         grecordholder[i] = strzone(grecordholder[i-1]);
1166                                 }
1167                         }
1168
1169                         // store new ranking
1170                         if(grecordholder[pos-1] != "")
1171                                 strunzone(grecordholder[pos-1]);
1172                         grecordholder[pos-1] = strzone(ReadString());
1173                         grecordtime[pos-1] = ReadInt24_t();
1174                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1175                                 race_myrank = pos;
1176                         break;
1177                 case RACE_NET_SERVER_STATUS:
1178                         race_status = ReadShort();
1179                         if(race_status_name)
1180                                 strunzone(race_status_name);
1181                         race_status_name = strzone(ReadString());
1182         }
1183 }
1184
1185 void Net_TeamNagger()
1186 {
1187         teamnagger = 1;
1188 }
1189
1190 void Net_ReadPingPLReport()
1191 {
1192         float e, pi, pl, ml;
1193         e = ReadByte();
1194         pi = ReadShort();
1195         pl = ReadByte();
1196         ml = ReadByte();
1197         if (!(playerslots[e]))
1198                 return;
1199         playerslots[e].ping = pi;
1200         playerslots[e].ping_packetloss = pl / 255.0;
1201         playerslots[e].ping_movementloss = ml / 255.0;
1202 }
1203
1204 void Net_WeaponComplain()
1205 {
1206         complain_weapon = ReadByte();
1207
1208         if(complain_weapon_name)
1209                 strunzone(complain_weapon_name);
1210         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1211
1212         complain_weapon_type = ReadByte();
1213
1214         complain_weapon_time = time;
1215         weapontime = time; // ping the weapon panel
1216
1217         switch(complain_weapon_type)
1218         {
1219                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1220                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1221                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1222         }
1223 }
1224
1225 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1226 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1227 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1228 float CSQC_Parse_TempEntity()
1229 {
1230         float bHandled;
1231                 bHandled  = true;
1232         // Acquire TE ID
1233         float nTEID;
1234                 nTEID = ReadByte();
1235
1236         if(autocvar_developer_csqcentities)
1237                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1238
1239                 // NOTE: Could just do return instead of break...
1240         switch(nTEID)
1241         {
1242                 case TE_CSQC_TARGET_MUSIC:
1243                         Net_TargetMusic();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_PICTURE:
1247                         Net_MapVote_Picture();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_RACE:
1251                         Net_ReadRace();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_VORTEXBEAMPARTICLE:
1255                         Net_ReadVortexBeamParticle();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_TEAMNAGGER:
1259                         Net_TeamNagger();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_ARC:
1263                         Net_ReadArc();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_PINGPLREPORT:
1267                         Net_ReadPingPLReport();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_WEAPONCOMPLAIN:
1271                         Net_WeaponComplain();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_VEHICLESETUP:
1275                         Net_VehicleSetup();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_SVNOTICE:
1279                         cl_notice_read();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_SHOCKWAVEPARTICLE:
1283                         Net_ReadShockwaveParticle();
1284                         bHandled = true;
1285                         break;
1286                 default:
1287                         // No special logic for this temporary entity; return 0 so the engine can handle it
1288                         bHandled = false;
1289                         break;
1290         }
1291
1292         return bHandled;
1293 }
1294
1295 string getcommandkey(string text, string command)
1296 {
1297         string keys;
1298         float n, j, k, l = 0;
1299
1300         if (!autocvar_hud_showbinds)
1301                 return text;
1302
1303         keys = db_get(binddb, command);
1304         if (keys == "")
1305         {
1306                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1307                 for(j = 0; j < n; ++j)
1308                 {
1309                         k = stof(argv(j));
1310                         if(k != -1)
1311                         {
1312                                 if ("" == keys)
1313                                         keys = keynumtostring(k);
1314                                 else
1315                                         keys = strcat(keys, ", ", keynumtostring(k));
1316
1317                                 ++l;
1318                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1319                                         break;
1320                         }
1321
1322                 }
1323                 if (keys == "")
1324                         keys = "NO_KEY";
1325                 db_put(binddb, command, keys);
1326         }
1327
1328         if (keys == "NO_KEY") {
1329                 if (autocvar_hud_showbinds > 1)
1330                         return sprintf(_("%s (not bound)"), text);
1331                 else
1332                         return text;
1333         }
1334         else if (autocvar_hud_showbinds > 1)
1335                 return sprintf(_("%s (%s)"), text, keys);
1336         else
1337                 return keys;
1338 }