qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(NUM_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Monsters_Precache();
 176         Projectile_Precache();
 177         Hook_Precache();
 178         GibSplash_Precache();
 179         Casings_Precache();
 180         DamageInfo_Precache();
 181         Vehicles_Precache();
 182         turrets_precache();
 183     Announcer_Precache();
 184         Tuba_Precache();
 185         CSQCPlayer_Precache();
 186
 187         if(autocvar_cl_reticle)
 188         {
 189                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 190                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 191         }
 192
 193         get_mi_min_max_texcoords(1); // try the CLEVER way first
 194         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 195         shortmapname = mi_shortname;
 196
 197         if(precache_pic(minimapname) == "")
 198         {
 199                 // but maybe we have a non-clever minimap
 200                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 201                 if(precache_pic(minimapname) == "")
 202                         minimapname = ""; // FAIL
 203                 else
 204                         get_mi_min_max_texcoords(0); // load new texcoords
 205         }
 206
 207         mi_center = (mi_min + mi_max) * 0.5;
 208         mi_scale = mi_max - mi_min;
 209         minimapname = strzone(minimapname);
 210
 211         WarpZone_Init();
 212
 213         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 214         hud_configure_prev = -1;
 215         tab_panel = -1;
 216
 217         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 218 }
 219
 220 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 221 void Shutdown(void)
 222 {
 223 #ifdef USE_FTE
 224 #pragma TARGET id
 225         if(!__engine_check)
 226                 return 0;
 227 #pragma TARGET fte
 228 #endif
 229
 230         WarpZone_Shutdown();
 231
 232         remove(teams);
 233         remove(players);
 234         db_close(binddb);
 235         db_close(tempdb);
 236         if(autocvar_cl_db_saveasdump)
 237                 db_dump(ClientProgsDB, "client.db");
 238         else
 239                 db_save(ClientProgsDB, "client.db");
 240         db_close(ClientProgsDB);
 241
 242         if(camera_active)
 243                 cvar_set("chase_active",ftos(chase_active_backup));
 244
 245         // unset the event chasecam's chase_active
 246         if(autocvar_chase_active < 0)
 247                 cvar_set("chase_active", "0");
 248
 249         if not(isdemo())
 250         {
 251                 if not(calledhooks & HOOK_START)
 252                         localcmd("\n_cl_hook_gamestart nop\n");
 253                 if not(calledhooks & HOOK_END)
 254                         localcmd("\ncl_hook_gameend\n");
 255         }
 256 }
 257
 258 .float has_team;
 259 float SetTeam(entity o, float Team)
 260 {
 261         entity tm;
 262         if(teamplay)
 263         {
 264                 switch(Team)
 265                 {
 266                         case -1:
 267                         case NUM_TEAM_1:
 268                         case NUM_TEAM_2:
 269                         case NUM_TEAM_3:
 270                         case NUM_TEAM_4:
 271                                 break;
 272                         default:
 273                                 if(GetTeam(Team, false) == world)
 274                                 {
 275                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 276                                         Team = NUM_SPECTATOR;
 277                                 }
 278                                 break;
 279                 }
 280         }
 281         else
 282         {
 283                 switch(Team)
 284                 {
 285                         case -1:
 286                         case 0:
 287                                 break;
 288                         default:
 289                                 if(GetTeam(Team, false) == world)
 290                                 {
 291                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 292                                         Team = NUM_SPECTATOR;
 293                                 }
 294                                 break;
 295                 }
 296         }
 297         if(Team == -1) // leave
 298         {
 299                 if(o.has_team)
 300                 {
 301                         tm = GetTeam(o.team, false);
 302                         tm.team_size -= 1;
 303                         o.has_team = 0;
 304                         return TRUE;
 305                 }
 306         }
 307         else
 308         {
 309                 if not(o.has_team)
 310                 {
 311                         o.team = Team;
 312                         tm = GetTeam(Team, true);
 313                         tm.team_size += 1;
 314                         o.has_team = 1;
 315                         return TRUE;
 316                 }
 317                 else if(Team != o.team)
 318                 {
 319                         tm = GetTeam(o.team, false);
 320                         tm.team_size -= 1;
 321                         o.team = Team;
 322                         tm = GetTeam(Team, true);
 323                         tm.team_size += 1;
 324                         return TRUE;
 325                 }
 326         }
 327         return FALSE;
 328 }
 329
 330 void Playerchecker_Think()
 331 {
 332         float i;
 333         entity e;
 334         for(i = 0; i < maxclients; ++i)
 335         {
 336                 e = playerslots[i];
 337                 if(GetPlayerName(i) == "")
 338                 {
 339                         if(e.sort_prev)
 340                         {
 341                                 // player disconnected
 342                                 SetTeam(e, -1);
 343                                 RemovePlayer(e);
 344                                 e.sort_prev = world;
 345                                 //e.gotscores = 0;
 346                         }
 347                 }
 348                 else
 349                 {
 350                         if not(e.sort_prev)
 351                         {
 352                                 // player connected
 353                                 if not(e)
 354                                         playerslots[i] = e = spawn();
 355                                 e.sv_entnum = i;
 356                                 e.ping = 0;
 357                                 e.ping_packetloss = 0;
 358                                 e.ping_movementloss = 0;
 359                                 //e.gotscores = 0; // we might already have the scores...
 360                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 361                                 RegisterPlayer(e);
 362                                 HUD_UpdatePlayerPos(e);
 363                         }
 364                 }
 365         }
 366         self.nextthink = time + 0.2;
 367 }
 368
 369 void Porto_Init();
 370 void TrueAim_Init();
 371 void PostInit(void)
 372 {
 373         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 374
 375         entity playerchecker;
 376         playerchecker = spawn();
 377         playerchecker.think = Playerchecker_Think;
 378         playerchecker.nextthink = time + 0.2;
 379
 380         Porto_Init();
 381         TrueAim_Init();
 382
 383         postinit = true;
 384 }
 385
 386 float button_zoom;
 387
 388 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 389 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 390 // All keys are in ascii.
 391 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 392 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 393 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 394 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 395 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 396 {
 397         float bSkipKey;
 398         bSkipKey = false;
 399
 400         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 401                 return true;
 402
 403         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 404                 return true;
 405
 406         if(menu_visible && menu_action)
 407                 if(menu_action(bInputType, nPrimary, nSecondary))
 408                         return TRUE;
 409
 410         return bSkipKey;
 411 }
 412
 413 // END REQUIRED CSQC FUNCTIONS
 414 // --------------------------------------------------------------------------
 415
 416 // --------------------------------------------------------------------------
 417 // BEGIN OPTIONAL CSQC FUNCTIONS
 418 void Ent_RemoveEntCS()
 419 {
 420         entcs_receiver[self.sv_entnum] = world;
 421 }
 422 void Ent_ReadEntCS()
 423 {
 424         float sf;
 425         InterpolateOrigin_Undo();
 426
 427         self.classname = "entcs_receiver";
 428         sf = ReadByte();
 429
 430         if(sf & 1)
 431                 self.sv_entnum = ReadByte();
 432         if(sf & 2)
 433         {
 434                 self.origin_x = ReadShort();
 435                 self.origin_y = ReadShort();
 436                 self.origin_z = ReadShort();
 437                 setorigin(self, self.origin);
 438         }
 439         if(sf & 4)
 440         {
 441                 self.angles_y = ReadByte() * 360.0 / 256;
 442                 self.angles_x = self.angles_z = 0;
 443         }
 444         if(sf & 8)
 445                 self.healthvalue = ReadByte() * 10;
 446         if(sf & 16)
 447                 self.armorvalue = ReadByte() * 10;
 448
 449         entcs_receiver[self.sv_entnum] = self;
 450         self.entremove = Ent_RemoveEntCS;
 451         self.iflags |= IFLAG_ORIGIN;
 452
 453         InterpolateOrigin_Note();
 454 }
 455
 456 void Ent_Remove();
 457
 458 void Ent_RemovePlayerScore()
 459 {
 460         float i;
 461
 462         if(self.owner)
 463         {
 464                 SetTeam(self.owner, -1);
 465                 self.owner.gotscores = 0;
 466                 for(i = 0; i < MAX_SCORE; ++i)
 467                         self.owner.(scores[i]) = 0; // clear all scores
 468         }
 469 }
 470
 471 void Ent_ReadPlayerScore()
 472 {
 473         float i, n;
 474         float isNew;
 475         entity o;
 476
 477         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 478         // (no I've never heard of M-x replace-string, sed, or anything like that)
 479         isNew = !self.owner; // workaround for DP bug
 480         n = ReadByte()-1;
 481
 482 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 483         if(!isNew && n != self.sv_entnum)
 484         {
 485                 //print(_("A CSQC entity changed its owner!\n"));
 486                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 487                 isNew = true;
 488                 Ent_Remove();
 489                 self.enttype = ENT_CLIENT_SCORES;
 490         }
 491 #endif
 492
 493         self.sv_entnum = n;
 494
 495         if not(playerslots[self.sv_entnum])
 496                 playerslots[self.sv_entnum] = spawn();
 497         o = self.owner = playerslots[self.sv_entnum];
 498         o.sv_entnum = self.sv_entnum;
 499         o.gotscores = 1;
 500
 501         //if not(o.sort_prev)
 502         //      RegisterPlayer(o);
 503         //playerchecker will do this for us later, if it has not already done so
 504
 505         float sf, lf;
 506 #if MAX_SCORE <= 8
 507         sf = ReadByte();
 508         lf = ReadByte();
 509 #else
 510         sf = ReadShort();
 511         lf = ReadShort();
 512 #endif
 513         float p;
 514         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 515                 if(sf & p)
 516                 {
 517                         if(lf & p)
 518                                 o.(scores[i]) = ReadInt24_t();
 519                         else
 520                                 o.(scores[i]) = ReadChar();
 521                 }
 522
 523         if(o.sort_prev)
 524                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 525
 526         self.entremove = Ent_RemovePlayerScore;
 527 }
 528
 529 void Ent_ReadTeamScore()
 530 {
 531         float i;
 532         entity o;
 533
 534         self.team = ReadByte();
 535         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 536
 537         float sf, lf;
 538 #if MAX_TEAMSCORE <= 8
 539         sf = ReadByte();
 540         lf = ReadByte();
 541 #else
 542         sf = ReadShort();
 543         lf = ReadShort();
 544 #endif
 545         float p;
 546         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 547                 if(sf & p)
 548                 {
 549                         if(lf & p)
 550                                 o.(teamscores[i]) = ReadInt24_t();
 551                         else
 552                                 o.(teamscores[i]) = ReadChar();
 553                 }
 554
 555         HUD_UpdateTeamPos(o);
 556 }
 557
 558 void Ent_ClientData()
 559 {
 560         float f;
 561         float newspectatee_status;
 562
 563         f = ReadByte();
 564
 565         scoreboard_showscores_force = (f & 1);
 566
 567         if(f & 2)
 568         {
 569                 newspectatee_status = ReadByte();
 570                 if(newspectatee_status == player_localnum + 1)
 571                         newspectatee_status = -1; // observing
 572         }
 573         else
 574                 newspectatee_status = 0;
 575
 576         spectatorbutton_zoom = (f & 4);
 577
 578         if(f & 8)
 579         {
 580                 angles_held_status = 1;
 581                 angles_held_x = ReadAngle();
 582                 angles_held_y = ReadAngle();
 583                 angles_held_z = 0;
 584         }
 585         else
 586                 angles_held_status = 0;
 587
 588         if(newspectatee_status != spectatee_status)
 589         {
 590                 // clear race stuff
 591                 race_laptime = 0;
 592                 race_checkpointtime = 0;
 593         }
 594         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 595         {
 596                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 597                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 598                 )
 599                         prev_p_health = -1;
 600                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 601                         prev_health = -1;
 602         }
 603         spectatee_status = newspectatee_status;
 604
 605         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 606 }
 607
 608 void Ent_Nagger()
 609 {
 610         float nags, i, j, b, f;
 611
 612         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 613
 614         if(!(nags & 4))
 615         {
 616                 if(vote_called_vote)
 617                         strunzone(vote_called_vote);
 618                 vote_called_vote = string_null;
 619                 vote_active = 0;
 620         }
 621         else
 622         {
 623                 vote_active = 1;
 624         }
 625
 626         if(nags & 64)
 627         {
 628                 vote_yescount = ReadByte();
 629                 vote_nocount = ReadByte();
 630                 vote_needed = ReadByte();
 631                 vote_highlighted = ReadChar();
 632         }
 633
 634         if(nags & 128)
 635         {
 636                 if(vote_called_vote)
 637                         strunzone(vote_called_vote);
 638                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 639         }
 640
 641         if(nags & 1)
 642         {
 643                 for(j = 0; j < maxclients; ++j)
 644                         if(playerslots[j])
 645                                 playerslots[j].ready = 1;
 646                 for(i = 1; i <= maxclients; i += 8)
 647                 {
 648                         f = ReadByte();
 649                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 650                                 if not(f & b)
 651                                         if(playerslots[j])
 652                                                 playerslots[j].ready = 0;
 653                 }
 654         }
 655
 656         ready_waiting = (nags & 1);
 657         ready_waiting_for_me = (nags & 2);
 658         vote_waiting = (nags & 4);
 659         vote_waiting_for_me = (nags & 8);
 660         warmup_stage = (nags & 16);
 661 }
 662
 663 void Ent_RandomSeed()
 664 {
 665         float s;
 666         prandom_debug();
 667         s = ReadShort();
 668         psrandom(s);
 669 }
 670
 671 void Ent_ReadAccuracy(void)
 672 {
 673         float sf, f, w, b;
 674         sf = ReadInt24_t();
 675         if(sf == 0)
 676         {
 677                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 678                         weapon_accuracy[w] = -1;
 679                 return;
 680         }
 681
 682         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 683         {
 684                 if(sf & f)
 685                 {
 686                         b = ReadByte();
 687                         if(b == 0)
 688                                 weapon_accuracy[w] = -1;
 689                         else if(b == 255)
 690                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 691                         else
 692                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 693                 }
 694                 if(f == 0x800000)
 695                         f = 1;
 696                 else
 697                         f *= 2;
 698         }
 699 }
 700
 701 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 702 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 703 void Ent_RadarLink();
 704 void Ent_Init();
 705 void Ent_ScoresInfo();
 706 void CSQC_Ent_Update(float bIsNewEntity)
 707 {
 708         float t;
 709         float savetime;
 710         t = ReadByte();
 711
 712         if(autocvar_developer_csqcentities)
 713                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 714
 715         // set up the "time" global for received entities to be correct for interpolation purposes
 716         savetime = time;
 717         if(servertime)
 718         {
 719                 time = servertime;
 720         }
 721         else
 722         {
 723                 serverprevtime = time;
 724                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 725                 time = serverprevtime + serverdeltatime;
 726         }
 727
 728 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 729         if(self.enttype)
 730         {
 731                 if(t != self.enttype || bIsNewEntity)
 732                 {
 733                         //print(_("A CSQC entity changed its type!\n"));
 734                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 735                         Ent_Remove();
 736                         clearentity(self);
 737                         bIsNewEntity = 1;
 738                 }
 739         }
 740         else
 741         {
 742                 if(!bIsNewEntity)
 743                 {
 744                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 745                         bIsNewEntity = 1;
 746                 }
 747         }
 748 #endif
 749         self.enttype = t;
 750         switch(t)
 751         {
 752                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 753                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 754                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 755                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 756                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 757                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 758                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 759                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 760                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 761                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 762                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 763                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 764                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 765                 case ENT_CLIENT_INIT: Ent_Init(); break;
 766                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 767                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 768                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 769                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 770                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 771                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 772                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 773                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 774                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 775                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 776                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 777                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 778                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 779                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 780                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 781                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 782                 case ENT_CLIENT_TURRET: ent_turret(); break;
 783                 case ENT_CLIENT_MONSTER: ent_monster(); break;
 784                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 785                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 786                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 787                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 788                 default:
 789                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 790                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 791                         break;
 792         }
 793
 794         time = savetime;
 795 }
 796 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 797 // used when an entity changes its type. For an entity that someone interacts
 798 // with others, make sure it can no longer do so.
 799 void Ent_Remove()
 800 {
 801         if(self.entremove)
 802                 self.entremove();
 803
 804         if(self.skeletonindex)
 805         {
 806                 skel_delete(self.skeletonindex);
 807                 self.skeletonindex = 0;
 808         }
 809
 810         if(self.snd_looping > 0)
 811         {
 812                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 813                 self.snd_looping = 0;
 814         }
 815
 816         self.enttype = 0;
 817         self.classname = "";
 818         self.draw = menu_sub_null;
 819         self.entremove = menu_sub_null;
 820         // TODO possibly set more stuff to defaults
 821 }
 822 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 823 void CSQC_Ent_Remove()
 824 {
 825         if(autocvar_developer_csqcentities)
 826                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 827
 828         if(wasfreed(self))
 829         {
 830                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 831                 return;
 832         }
 833         if(self.enttype)
 834                 Ent_Remove();
 835         remove(self);
 836 }
 837
 838 void Gamemode_Init()
 839 {
 840         if not(isdemo())
 841         {
 842                 if(!(calledhooks & HOOK_START))
 843                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 844                 calledhooks |= HOOK_START;
 845         }
 846 }
 847 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 848 void CSQC_Parse_StuffCmd(string strMessage)
 849 {
 850         if(autocvar_developer_csqcentities)
 851                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 852
 853         localcmd(strMessage);
 854 }
 855 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 856 void CSQC_Parse_Print(string strMessage)
 857 {
 858         if(autocvar_developer_csqcentities)
 859                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 860
 861         print(ColorTranslateRGB(strMessage));
 862 }
 863
 864 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 865 void CSQC_Parse_CenterPrint(string strMessage)
 866 {
 867         if(autocvar_developer_csqcentities)
 868                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 869
 870         centerprint_hud(strMessage);
 871 }
 872
 873 string notranslate_fogcmd1 = "\nfog ";
 874 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 875 void Fog_Force()
 876 {
 877         // TODO somehow thwart prvm_globalset client ...
 878
 879         if(forcefog != "")
 880                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 881 }
 882
 883 void Gamemode_Init();
 884 void Ent_ScoresInfo()
 885 {
 886         float i;
 887         self.classname = "ent_client_scores_info";
 888         gametype = ReadInt24_t();
 889         for(i = 0; i < MAX_SCORE; ++i)
 890         {
 891                 scores_label[i] = strzone(ReadString());
 892                 scores_flags[i] = ReadByte();
 893         }
 894         for(i = 0; i < MAX_TEAMSCORE; ++i)
 895         {
 896                 teamscores_label[i] = strzone(ReadString());
 897                 teamscores_flags[i] = ReadByte();
 898         }
 899         HUD_InitScores();
 900         Gamemode_Init();
 901 }
 902
 903 void Ent_Init()
 904 {
 905         self.classname = "ent_client_init";
 906
 907         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 908
 909         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 910         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 911         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 912         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 913         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 914         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 915         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 916         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 917         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 918         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 919         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 920         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 921
 922         if(forcefog)
 923                 strunzone(forcefog);
 924         forcefog = strzone(ReadString());
 925
 926         armorblockpercent = ReadByte() / 255.0;
 927
 928         g_weaponswitchdelay = ReadByte() / 255.0;
 929
 930         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 931         g_balance_grenadelauncher_bouncestop = ReadCoord();
 932         g_balance_electro_secondary_bouncefactor = ReadCoord();
 933         g_balance_electro_secondary_bouncestop = ReadCoord();
 934
 935         nex_scope = !ReadByte();
 936         rifle_scope = !ReadByte();
 937
 938         serverflags = ReadByte();
 939
 940         minelayer_maxmines = ReadByte();
 941
 942         hagar_maxrockets = ReadByte();
 943
 944         g_trueaim_minrange = ReadCoord();
 945         g_balance_porto_secondary = ReadByte();
 946
 947         if(!postinit)
 948                 PostInit();
 949 }
 950
 951 void Net_ReadRace()
 952 {
 953         float b;
 954
 955         b = ReadByte();
 956
 957         switch(b)
 958         {
 959                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 960                         race_checkpoint = ReadByte();
 961                         race_time = ReadInt24_t();
 962                         race_previousbesttime = ReadInt24_t();
 963                         if(race_previousbestname)
 964                                 strunzone(race_previousbestname);
 965                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 966
 967                         race_checkpointtime = time;
 968
 969                         if(race_checkpoint == 0 || race_checkpoint == 254)
 970                         {
 971                                 race_penaltyaccumulator = 0;
 972                                 race_laptime = time; // valid
 973                         }
 974
 975                         break;
 976
 977                 case RACE_NET_CHECKPOINT_CLEAR:
 978                         race_laptime = 0;
 979                         race_checkpointtime = 0;
 980                         break;
 981
 982                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 983                         race_laptime = ReadCoord();
 984                         race_checkpointtime = -99999;
 985                         // fall through
 986                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 987                         race_nextcheckpoint = ReadByte();
 988
 989                         race_nextbesttime = ReadInt24_t();
 990                         if(race_nextbestname)
 991                                 strunzone(race_nextbestname);
 992                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 993                         break;
 994
 995                 case RACE_NET_CHECKPOINT_HIT_RACE:
 996                         race_mycheckpoint = ReadByte();
 997                         race_mycheckpointtime = time;
 998                         race_mycheckpointdelta = ReadInt24_t();
 999                         race_mycheckpointlapsdelta = ReadByte();
1000                         if(race_mycheckpointlapsdelta >= 128)
1001                                 race_mycheckpointlapsdelta -= 256;
1002                         if(race_mycheckpointenemy)
1003                                 strunzone(race_mycheckpointenemy);
1004                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1005                         break;
1006
1007                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1008                         race_othercheckpoint = ReadByte();
1009                         race_othercheckpointtime = time;
1010                         race_othercheckpointdelta = ReadInt24_t();
1011                         race_othercheckpointlapsdelta = ReadByte();
1012                         if(race_othercheckpointlapsdelta >= 128)
1013                                 race_othercheckpointlapsdelta -= 256;
1014                         if(race_othercheckpointenemy)
1015                                 strunzone(race_othercheckpointenemy);
1016                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1017                         break;
1018
1019                 case RACE_NET_PENALTY_RACE:
1020                         race_penaltyeventtime = time;
1021                         race_penaltytime = ReadShort();
1022                         //race_penaltyaccumulator += race_penaltytime;
1023                         if(race_penaltyreason)
1024                                 strunzone(race_penaltyreason);
1025                         race_penaltyreason = strzone(ReadString());
1026                         break;
1027
1028                 case RACE_NET_PENALTY_QUALIFYING:
1029                         race_penaltyeventtime = time;
1030                         race_penaltytime = ReadShort();
1031                         race_penaltyaccumulator += race_penaltytime;
1032                         if(race_penaltyreason)
1033                                 strunzone(race_penaltyreason);
1034                         race_penaltyreason = strzone(ReadString());
1035                         break;
1036
1037                 case RACE_NET_SERVER_RECORD:
1038                         race_server_record = ReadInt24_t();
1039                         break;
1040                 case RACE_NET_SPEED_AWARD:
1041                         race_speedaward = ReadInt24_t();
1042                         if(race_speedaward_holder)
1043                                 strunzone(race_speedaward_holder);
1044                         race_speedaward_holder = strzone(ReadString());
1045                         break;
1046                 case RACE_NET_SPEED_AWARD_BEST:
1047                         race_speedaward_alltimebest = ReadInt24_t();
1048                         if(race_speedaward_alltimebest_holder)
1049                                 strunzone(race_speedaward_alltimebest_holder);
1050                         race_speedaward_alltimebest_holder = strzone(ReadString());
1051                         break;
1052                 case RACE_NET_SERVER_RANKINGS:
1053                         float pos, prevpos, del;
1054                         pos = ReadShort();
1055                         prevpos = ReadShort();
1056                         del = ReadShort();
1057
1058                         // move other rankings out of the way
1059                         float i;
1060                         if (prevpos) {
1061                                 for (i=prevpos-1;i>pos-1;--i) {
1062                                         grecordtime[i] = grecordtime[i-1];
1063                                         if(grecordholder[i])
1064                                                 strunzone(grecordholder[i]);
1065                                         grecordholder[i] = strzone(grecordholder[i-1]);
1066                                 }
1067                         } else if (del) { // a record has been deleted by the admin
1068                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1069                                         if (i == RANKINGS_CNT-1) { // clear out last record
1070                                                 grecordtime[i] = 0;
1071                                                 if (grecordholder[i])
1072                                                         strunzone(grecordholder[i]);
1073                                                 grecordholder[i] = string_null;
1074                                         }
1075                                         else {
1076                                                 grecordtime[i] = grecordtime[i+1];
1077                                                 if (grecordholder[i])
1078                                                         strunzone(grecordholder[i]);
1079                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1080                                         }
1081                                 }
1082                         } else { // player has no ranked record yet
1083                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1084                                         grecordtime[i] = grecordtime[i-1];
1085                                         if(grecordholder[i])
1086                                                 strunzone(grecordholder[i]);
1087                                         grecordholder[i] = strzone(grecordholder[i-1]);
1088                                 }
1089                         }
1090
1091                         // store new ranking
1092                         if(grecordholder[pos-1] != "")
1093                                 strunzone(grecordholder[pos-1]);
1094                         grecordholder[pos-1] = strzone(ReadString());
1095                         grecordtime[pos-1] = ReadInt24_t();
1096                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1097                                 race_myrank = pos;
1098                         break;
1099                 case RACE_NET_SERVER_STATUS:
1100                         race_status = ReadShort();
1101                         if(race_status_name)
1102                                 strunzone(race_status_name);
1103                         race_status_name = strzone(ReadString());
1104         }
1105 }
1106
1107 void Net_ReadSpawn()
1108 {
1109         zoomin_effect = 1;
1110         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1111
1112         if(autocvar_cl_unpress_zoom_on_spawn)
1113         {
1114                 localcmd("-zoom\n");
1115                 button_zoom = FALSE;
1116         }
1117 }
1118
1119 void Net_TeamNagger()
1120 {
1121         teamnagger = 1;
1122 }
1123
1124 void Net_ReadPingPLReport()
1125 {
1126         float e, pi, pl, ml;
1127         e = ReadByte();
1128         pi = ReadShort();
1129         pl = ReadByte();
1130         ml = ReadByte();
1131         if not(playerslots[e])
1132                 return;
1133         playerslots[e].ping = pi;
1134         playerslots[e].ping_packetloss = pl / 255.0;
1135         playerslots[e].ping_movementloss = ml / 255.0;
1136 }
1137
1138 void Net_WeaponComplain()
1139 {
1140         complain_weapon = ReadByte();
1141
1142         if(complain_weapon_name)
1143                 strunzone(complain_weapon_name);
1144         complain_weapon_name = strzone(ReadString());
1145
1146         complain_weapon_type = ReadByte();
1147
1148         complain_weapon_time = time;
1149         weapontime = time; // ping the weapon panel
1150
1151         switch(complain_weapon_type)
1152         {
1153                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1154                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1155                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1156         }
1157 }
1158
1159 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1160 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1161 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1162 float CSQC_Parse_TempEntity()
1163 {
1164         float bHandled;
1165                 bHandled  = true;
1166         // Acquire TE ID
1167         float nTEID;
1168                 nTEID = ReadByte();
1169
1170         if(autocvar_developer_csqcentities)
1171                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1172
1173                 // NOTE: Could just do return instead of break...
1174         switch(nTEID)
1175         {
1176                 case TE_CSQC_TARGET_MUSIC:
1177                         Net_TargetMusic();
1178                         bHandled = true;
1179                         break;
1180                 case TE_CSQC_PICTURE:
1181                         Net_MapVote_Picture();
1182                         bHandled = true;
1183                         break;
1184                 case TE_CSQC_RACE:
1185                         Net_ReadRace();
1186                         bHandled = true;
1187                         break;
1188                 case TE_CSQC_SPAWN:
1189                         Net_ReadSpawn();
1190                         bHandled = true;
1191                         break;
1192                 case TE_CSQC_ZCURVEPARTICLES:
1193                         Net_ReadZCurveParticles();
1194                         bHandled = true;
1195                         break;
1196                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1197                         Net_ReadNexgunBeamParticle();
1198                         bHandled = true;
1199                         break;
1200                 case TE_CSQC_TEAMNAGGER:
1201                         Net_TeamNagger();
1202                         bHandled = true;
1203                         break;
1204                 case TE_CSQC_LIGHTNINGARC:
1205                         Net_ReadLightningarc();
1206                         bHandled = true;
1207                         break;
1208                 case TE_CSQC_PINGPLREPORT:
1209                         Net_ReadPingPLReport();
1210                         bHandled = true;
1211                         break;
1212                 case TE_CSQC_ANNOUNCE:
1213                         Announcer_Play(ReadString());
1214                         bHandled = true;
1215                         break;
1216                 case TE_CSQC_WEAPONCOMPLAIN:
1217                         Net_WeaponComplain();
1218                         bHandled = true;
1219                         break;
1220                 case TE_CSQC_VEHICLESETUP:
1221                         Net_VehicleSetup();
1222                         bHandled = true;
1223                         break;
1224                 case TE_CSQC_SVNOTICE:
1225                         cl_notice_read();
1226                         bHandled = true;
1227                         break;
1228                 default:
1229                         // No special logic for this temporary entity; return 0 so the engine can handle it
1230                         bHandled = false;
1231                         break;
1232         }
1233
1234         return bHandled;
1235 }
1236
1237 string getcommandkey(string text, string command)
1238 {
1239         string keys;
1240         float n, j, k, l = 0;
1241
1242         if (!autocvar_hud_showbinds)
1243                 return text;
1244
1245         keys = db_get(binddb, command);
1246         if (keys == "")
1247         {
1248                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1249                 for(j = 0; j < n; ++j)
1250                 {
1251                         k = stof(argv(j));
1252                         if(k != -1)
1253                         {
1254                                 if ("" == keys)
1255                                         keys = keynumtostring(k);
1256                                 else
1257                                         keys = strcat(keys, ", ", keynumtostring(k));
1258
1259                                 ++l;
1260                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1261                                         break;
1262                         }
1263
1264                 }
1265                 if (keys == "")
1266                         keys = "NO_KEY";
1267                 db_put(binddb, command, keys);
1268         }
1269
1270         if (keys == "NO_KEY") {
1271                 if (autocvar_hud_showbinds > 1)
1272                         return sprintf(_("%s (not bound)"), text);
1273                 else
1274                         return text;
1275         }
1276         else if (autocvar_hud_showbinds > 1)
1277                 return sprintf(_("%s (%s)"), text, keys);
1278         else
1279                 return keys;
1280 }