qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         Cmd_HUD_SetFields(0);
 100
 101         postinit = false;
 102
 103         calledhooks = 0;
 104
 105         teams = Sort_Spawn();
 106         players = Sort_Spawn();
 107
 108         GetTeam(NUM_SPECTATOR, true); // add specs first
 109
 110         // needs to be done so early because of the constants they create
 111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 118
 119         WaypointSprite_Load();
 120
 121         // precaches
 122         precache_model("null");
 123         precache_sound("misc/hit.wav");
 124         precache_sound("misc/typehit.wav");
 125
 126         Projectile_Precache();
 127         Hook_Precache();
 128         GibSplash_Precache();
 129         Casings_Precache();
 130         Vehicles_Precache();
 131         turrets_precache();
 132         Tuba_Precache();
 133         CSQCPlayer_Precache();
 134
 135         if(autocvar_cl_reticle)
 136         {
 137                 precache_pic("gfx/reticle_normal");
 138                 // weapon reticles are precached in weapon files
 139         }
 140
 141         get_mi_min_max_texcoords(1); // try the CLEVER way first
 142         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 143         shortmapname = mi_shortname;
 144
 145         if(precache_pic(minimapname) == "")
 146         {
 147                 // but maybe we have a non-clever minimap
 148                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 149                 if(precache_pic(minimapname) == "")
 150                         minimapname = ""; // FAIL
 151                 else
 152                         get_mi_min_max_texcoords(0); // load new texcoords
 153         }
 154
 155         mi_center = (mi_min + mi_max) * 0.5;
 156         mi_scale = mi_max - mi_min;
 157         minimapname = strzone(minimapname);
 158
 159         WarpZone_Init();
 160
 161         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 162         hud_configure_prev = -1;
 163
 164         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 165 }
 166
 167 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 168 void Shutdown(void)
 169 {
 170 #ifdef USE_FTE
 171 #pragma TARGET id
 172         if(!__engine_check)
 173                 return 0;
 174 #pragma TARGET fte
 175 #endif
 176
 177         WarpZone_Shutdown();
 178
 179         remove(teams);
 180         remove(players);
 181         db_close(binddb);
 182         db_close(tempdb);
 183         if(autocvar_cl_db_saveasdump)
 184                 db_dump(ClientProgsDB, "client.db");
 185         else
 186                 db_save(ClientProgsDB, "client.db");
 187         db_close(ClientProgsDB);
 188
 189         if(camera_active)
 190                 cvar_set("chase_active",ftos(chase_active_backup));
 191
 192         // unset the event chasecam's chase_active
 193         if(autocvar_chase_active < 0)
 194                 cvar_set("chase_active", "0");
 195
 196         if (!isdemo())
 197         {
 198                 if (!(calledhooks & HOOK_START))
 199                         localcmd("\n_cl_hook_gamestart nop\n");
 200                 if (!(calledhooks & HOOK_END))
 201                         localcmd("\ncl_hook_gameend\n");
 202         }
 203 }
 204
 205 .float has_team;
 206 float SetTeam(entity o, float Team)
 207 {
 208         entity tm;
 209         if(teamplay)
 210         {
 211                 switch(Team)
 212                 {
 213                         case -1:
 214                         case NUM_TEAM_1:
 215                         case NUM_TEAM_2:
 216                         case NUM_TEAM_3:
 217                         case NUM_TEAM_4:
 218                                 break;
 219                         default:
 220                                 if(GetTeam(Team, false) == world)
 221                                 {
 222                                         dprintf("trying to switch to unsupported team %d\n", Team);
 223                                         Team = NUM_SPECTATOR;
 224                                 }
 225                                 break;
 226                 }
 227         }
 228         else
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case 0:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         dprintf("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         if(Team == -1) // leave
 245         {
 246                 if(o.has_team)
 247                 {
 248                         tm = GetTeam(o.team, false);
 249                         tm.team_size -= 1;
 250                         o.has_team = 0;
 251                         return TRUE;
 252                 }
 253         }
 254         else
 255         {
 256                 if (!o.has_team)
 257                 {
 258                         o.team = Team;
 259                         tm = GetTeam(Team, true);
 260                         tm.team_size += 1;
 261                         o.has_team = 1;
 262                         return TRUE;
 263                 }
 264                 else if(Team != o.team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         return TRUE;
 272                 }
 273         }
 274         return FALSE;
 275 }
 276
 277 void Playerchecker_Think()
 278 {
 279         float i;
 280         entity e;
 281         for(i = 0; i < maxclients; ++i)
 282         {
 283                 e = playerslots[i];
 284                 if(GetPlayerName(i) == "")
 285                 {
 286                         if(e.sort_prev)
 287                         {
 288                                 // player disconnected
 289                                 SetTeam(e, -1);
 290                                 RemovePlayer(e);
 291                                 e.sort_prev = world;
 292                                 //e.gotscores = 0;
 293                         }
 294                 }
 295                 else
 296                 {
 297                         if (!e.sort_prev)
 298                         {
 299                                 // player connected
 300                                 if (!e)
 301                                         playerslots[i] = e = spawn();
 302                                 e.sv_entnum = i;
 303                                 e.ping = 0;
 304                                 e.ping_packetloss = 0;
 305                                 e.ping_movementloss = 0;
 306                                 //e.gotscores = 0; // we might already have the scores...
 307                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 308                                 RegisterPlayer(e);
 309                                 HUD_UpdatePlayerPos(e);
 310                         }
 311                 }
 312         }
 313         self.nextthink = time + 0.2;
 314 }
 315
 316 void Porto_Init();
 317 void TrueAim_Init();
 318 void PostInit(void)
 319 {
 320         entity playerchecker;
 321         playerchecker = spawn();
 322         playerchecker.think = Playerchecker_Think;
 323         playerchecker.nextthink = time + 0.2;
 324
 325         Porto_Init();
 326         TrueAim_Init();
 327
 328         postinit = true;
 329 }
 330
 331 float button_zoom;
 332
 333 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 334 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 335 // All keys are in ascii.
 336 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 337 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 338 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 339 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 340 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 341 {
 342         float bSkipKey;
 343         bSkipKey = false;
 344
 345         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 346                 return true;
 347
 348         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 349                 return true;
 350
 351         if(menu_visible && menu_action)
 352                 if(menu_action(bInputType, nPrimary, nSecondary))
 353                         return TRUE;
 354
 355         return bSkipKey;
 356 }
 357
 358 // END REQUIRED CSQC FUNCTIONS
 359 // --------------------------------------------------------------------------
 360
 361 // --------------------------------------------------------------------------
 362 // BEGIN OPTIONAL CSQC FUNCTIONS
 363 void Ent_RemoveEntCS()
 364 {
 365         entcs_receiver[self.sv_entnum] = world;
 366 }
 367 void Ent_ReadEntCS()
 368 {
 369         float sf;
 370         InterpolateOrigin_Undo();
 371
 372         self.classname = "entcs_receiver";
 373         sf = ReadByte();
 374
 375         if(sf & 1)
 376                 self.sv_entnum = ReadByte();
 377         if(sf & 2)
 378         {
 379                 self.origin_x = ReadShort();
 380                 self.origin_y = ReadShort();
 381                 self.origin_z = ReadShort();
 382                 setorigin(self, self.origin);
 383         }
 384         if(sf & 4)
 385         {
 386                 self.angles_y = ReadByte() * 360.0 / 256;
 387                 self.angles_x = self.angles_z = 0;
 388         }
 389         if(sf & 8)
 390                 self.healthvalue = ReadByte() * 10;
 391         if(sf & 16)
 392                 self.armorvalue = ReadByte() * 10;
 393
 394         entcs_receiver[self.sv_entnum] = self;
 395         self.entremove = Ent_RemoveEntCS;
 396         self.iflags |= IFLAG_ORIGIN;
 397
 398         InterpolateOrigin_Note();
 399 }
 400
 401 void Ent_Remove();
 402
 403 void Ent_RemovePlayerScore()
 404 {
 405         float i;
 406
 407         if(self.owner)
 408         {
 409                 SetTeam(self.owner, -1);
 410                 self.owner.gotscores = 0;
 411                 for(i = 0; i < MAX_SCORE; ++i)
 412                         self.owner.(scores[i]) = 0; // clear all scores
 413         }
 414 }
 415
 416 void Ent_ReadPlayerScore()
 417 {
 418         float i, n;
 419         float isNew;
 420         entity o;
 421
 422         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 423         // (no I've never heard of M-x replace-string, sed, or anything like that)
 424         isNew = !self.owner; // workaround for DP bug
 425         n = ReadByte()-1;
 426
 427 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 428         if(!isNew && n != self.sv_entnum)
 429         {
 430                 //print("A CSQC entity changed its owner!\n");
 431                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 432                 isNew = true;
 433                 Ent_Remove();
 434                 self.enttype = ENT_CLIENT_SCORES;
 435         }
 436 #endif
 437
 438         self.sv_entnum = n;
 439
 440         if (!(playerslots[self.sv_entnum]))
 441                 playerslots[self.sv_entnum] = spawn();
 442         o = self.owner = playerslots[self.sv_entnum];
 443         o.sv_entnum = self.sv_entnum;
 444         o.gotscores = 1;
 445
 446         //if (!o.sort_prev)
 447         //      RegisterPlayer(o);
 448         //playerchecker will do this for us later, if it has not already done so
 449
 450         float sf, lf;
 451 #if MAX_SCORE <= 8
 452         sf = ReadByte();
 453         lf = ReadByte();
 454 #else
 455         sf = ReadShort();
 456         lf = ReadShort();
 457 #endif
 458         float p;
 459         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 460                 if(sf & p)
 461                 {
 462                         if(lf & p)
 463                                 o.(scores[i]) = ReadInt24_t();
 464                         else
 465                                 o.(scores[i]) = ReadChar();
 466                 }
 467
 468         if(o.sort_prev)
 469                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 470
 471         self.entremove = Ent_RemovePlayerScore;
 472 }
 473
 474 void Ent_ReadTeamScore()
 475 {
 476         float i;
 477         entity o;
 478
 479         self.team = ReadByte();
 480         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 481
 482         float sf, lf;
 483 #if MAX_TEAMSCORE <= 8
 484         sf = ReadByte();
 485         lf = ReadByte();
 486 #else
 487         sf = ReadShort();
 488         lf = ReadShort();
 489 #endif
 490         float p;
 491         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 492                 if(sf & p)
 493                 {
 494                         if(lf & p)
 495                                 o.(teamscores[i]) = ReadInt24_t();
 496                         else
 497                                 o.(teamscores[i]) = ReadChar();
 498                 }
 499
 500         HUD_UpdateTeamPos(o);
 501 }
 502
 503 void Ent_ClientData()
 504 {
 505         float f;
 506         float newspectatee_status;
 507
 508         f = ReadByte();
 509
 510         scoreboard_showscores_force = (f & 1);
 511
 512         if(f & 2)
 513         {
 514                 newspectatee_status = ReadByte();
 515                 if(newspectatee_status == player_localnum + 1)
 516                         newspectatee_status = -1; // observing
 517         }
 518         else
 519                 newspectatee_status = 0;
 520
 521         spectatorbutton_zoom = (f & 4);
 522
 523         if(f & 8)
 524         {
 525                 angles_held_status = 1;
 526                 angles_held_x = ReadAngle();
 527                 angles_held_y = ReadAngle();
 528                 angles_held_z = 0;
 529         }
 530         else
 531                 angles_held_status = 0;
 532
 533         if(newspectatee_status != spectatee_status)
 534         {
 535                 // clear race stuff
 536                 race_laptime = 0;
 537                 race_checkpointtime = 0;
 538         }
 539         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 540         {
 541                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 542                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 543                 )
 544                         prev_p_health = -1;
 545                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 546                         prev_health = -1;
 547         }
 548         spectatee_status = newspectatee_status;
 549
 550         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 551 }
 552
 553 void Ent_Nagger()
 554 {
 555         float nags, i, j, b, f;
 556
 557         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 558
 559         if(!(nags & 4))
 560         {
 561                 if(vote_called_vote)
 562                         strunzone(vote_called_vote);
 563                 vote_called_vote = string_null;
 564                 vote_active = 0;
 565         }
 566         else
 567         {
 568                 vote_active = 1;
 569         }
 570
 571         if(nags & 64)
 572         {
 573                 vote_yescount = ReadByte();
 574                 vote_nocount = ReadByte();
 575                 vote_needed = ReadByte();
 576                 vote_highlighted = ReadChar();
 577         }
 578
 579         if(nags & 128)
 580         {
 581                 if(vote_called_vote)
 582                         strunzone(vote_called_vote);
 583                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 584         }
 585
 586         if(nags & 1)
 587         {
 588                 for(j = 0; j < maxclients; ++j)
 589                         if(playerslots[j])
 590                                 playerslots[j].ready = 1;
 591                 for(i = 1; i <= maxclients; i += 8)
 592                 {
 593                         f = ReadByte();
 594                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 595                                 if (!(f & b))
 596                                         if(playerslots[j])
 597                                                 playerslots[j].ready = 0;
 598                 }
 599         }
 600
 601         ready_waiting = (nags & 1);
 602         ready_waiting_for_me = (nags & 2);
 603         vote_waiting = (nags & 4);
 604         vote_waiting_for_me = (nags & 8);
 605         warmup_stage = (nags & 16);
 606 }
 607
 608 void Ent_EliminatedPlayers()
 609 {
 610         float sf, i, j, b, f;
 611
 612         sf = ReadByte();
 613         if(sf & 1)
 614         {
 615                 for(j = 0; j < maxclients; ++j)
 616                         if(playerslots[j])
 617                                 playerslots[j].eliminated = 1;
 618                 for(i = 1; i <= maxclients; i += 8)
 619                 {
 620                         f = ReadByte();
 621                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 622                                 if (!(f & b))
 623                                         if(playerslots[j])
 624                                                 playerslots[j].eliminated = 0;
 625                 }
 626         }
 627 }
 628
 629 void Ent_RandomSeed()
 630 {
 631         float s;
 632         prandom_debug();
 633         s = ReadShort();
 634         psrandom(s);
 635 }
 636
 637 void Ent_ReadAccuracy(void)
 638 {
 639         float sf, f, w, b;
 640         sf = ReadInt24_t();
 641         if(sf == 0)
 642         {
 643                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 644                         weapon_accuracy[w] = -1;
 645                 return;
 646         }
 647
 648         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 649         {
 650                 if(sf & f)
 651                 {
 652                         b = ReadByte();
 653                         if(b == 0)
 654                                 weapon_accuracy[w] = -1;
 655                         else if(b == 255)
 656                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 657                         else
 658                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 659                 }
 660                 if(f == 0x800000)
 661                         f = 1;
 662                 else
 663                         f *= 2;
 664         }
 665 }
 666
 667 void Spawn_Draw(void)
 668 {
 669         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 670 }
 671
 672 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 673 {
 674         float teamnum = (ReadByte() - 1);
 675         vector spn_origin;
 676         spn_origin_x = ReadShort();
 677         spn_origin_y = ReadShort();
 678         spn_origin_z = ReadShort();
 679
 680         if(is_new)
 681         {
 682                 self.origin = spn_origin;
 683                 setsize(self, PL_MIN, PL_MAX);
 684                 droptofloor();
 685
 686                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 687                 {
 688                         self.mdl = "models/spawnpoint.md3";
 689                         self.colormod = Team_ColorRGB(teamnum);
 690                         precache_model(self.mdl);
 691                         setmodel(self, self.mdl);
 692                         self.drawmask = MASK_NORMAL;
 693                         //self.movetype = MOVETYPE_NOCLIP;
 694                         //self.draw = Spawn_Draw;
 695                 }*/
 696                 if(autocvar_cl_spawn_point_particles)
 697                 {
 698                         if((serverflags & SERVERFLAG_TEAMPLAY))
 699                         {
 700                                 switch(teamnum)
 701                                 {
 702                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 703                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 704                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 705                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 706                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 707                                 }
 708                         }
 709                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 710
 711                         self.draw = Spawn_Draw;
 712                 }
 713         }
 714
 715         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 716 }
 717
 718 void Ent_ReadSpawnEvent(float is_new)
 719 {
 720         // If entnum is 0, ONLY do the local spawn actions
 721         // this way the server can disable the sending of
 722         // spawn origin or such to clients if wanted.
 723         float entnum = ReadByte();
 724
 725         if(entnum)
 726         {
 727                 self.origin_x = ReadShort();
 728                 self.origin_y = ReadShort();
 729                 self.origin_z = ReadShort();
 730
 731                 if(is_new)
 732                 {
 733                         float teamnum = GetPlayerColor(entnum - 1);
 734
 735                         if(autocvar_cl_spawn_event_particles)
 736                         {
 737                                 switch(teamnum)
 738                                 {
 739                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 740                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 741                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 742                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 743                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 744                                 }
 745                         }
 746                         if(autocvar_cl_spawn_event_sound)
 747                         {
 748                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 749                         }
 750                 }
 751         }
 752
 753         // local spawn actions
 754         if(is_new && (!entnum || (entnum == player_localentnum)))
 755         {
 756                 zoomin_effect = 1;
 757                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 758
 759                 if(autocvar_cl_unpress_zoom_on_spawn)
 760                 {
 761                         localcmd("-zoom\n");
 762                         button_zoom = FALSE;
 763                 }
 764         }
 765
 766         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 767 }
 768
 769 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 770 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 771 void Ent_RadarLink();
 772 void Ent_Init();
 773 void Ent_ScoresInfo();
 774 void ent_func_ladder();
 775 void CSQC_Ent_Update(float bIsNewEntity)
 776 {
 777         float t;
 778         float savetime;
 779         t = ReadByte();
 780
 781         if(autocvar_developer_csqcentities)
 782                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 783
 784         // set up the "time" global for received entities to be correct for interpolation purposes
 785         savetime = time;
 786         if(servertime)
 787         {
 788                 time = servertime;
 789         }
 790         else
 791         {
 792                 serverprevtime = time;
 793                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 794                 time = serverprevtime + serverdeltatime;
 795         }
 796
 797 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 798         if(self.enttype)
 799         {
 800                 if(t != self.enttype || bIsNewEntity)
 801                 {
 802                         //print("A CSQC entity changed its type!\n");
 803                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 804                         Ent_Remove();
 805                         clearentity(self);
 806                         bIsNewEntity = 1;
 807                 }
 808         }
 809         else
 810         {
 811                 if(!bIsNewEntity)
 812                 {
 813                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 814                         bIsNewEntity = 1;
 815                 }
 816         }
 817 #endif
 818         self.enttype = t;
 819         switch(t)
 820         {
 821                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 822                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 823                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 824                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 825                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 826                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 827                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 828                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 829                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 830                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 831                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 832                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 833                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 834                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 835                 case ENT_CLIENT_INIT: Ent_Init(); break;
 836                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 837                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 838                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 839                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 840                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 841                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 842                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 843                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 844                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 845                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 846                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 847                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 848                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 849                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 850                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 851                 case ENT_CLIENT_TURRET: ent_turret(); break;
 852                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 853                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 854                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 855                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 856                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 857                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 858                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 859                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 860
 861                 default:
 862                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 863                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 864                         break;
 865         }
 866
 867         time = savetime;
 868 }
 869 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 870 // used when an entity changes its type. For an entity that someone interacts
 871 // with others, make sure it can no longer do so.
 872 void Ent_Remove()
 873 {
 874         if(self.entremove)
 875                 self.entremove();
 876
 877         if(self.skeletonindex)
 878         {
 879                 skel_delete(self.skeletonindex);
 880                 self.skeletonindex = 0;
 881         }
 882
 883         if(self.snd_looping > 0)
 884         {
 885                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 886                 self.snd_looping = 0;
 887         }
 888
 889         self.enttype = 0;
 890         self.classname = "";
 891         self.draw = menu_sub_null;
 892         self.entremove = menu_sub_null;
 893         // TODO possibly set more stuff to defaults
 894 }
 895 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 896 void CSQC_Ent_Remove()
 897 {
 898         if(autocvar_developer_csqcentities)
 899                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 900
 901         if(wasfreed(self))
 902         {
 903                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 904                 return;
 905         }
 906         if(self.enttype)
 907                 Ent_Remove();
 908         remove(self);
 909 }
 910
 911 void Gamemode_Init()
 912 {
 913         if (!isdemo())
 914         {
 915                 if(!(calledhooks & HOOK_START))
 916                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 917                 calledhooks |= HOOK_START;
 918         }
 919 }
 920 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 921 void CSQC_Parse_StuffCmd(string strMessage)
 922 {
 923         if(autocvar_developer_csqcentities)
 924                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 925
 926         localcmd(strMessage);
 927 }
 928 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 929 void CSQC_Parse_Print(string strMessage)
 930 {
 931         if(autocvar_developer_csqcentities)
 932                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 933
 934         print(ColorTranslateRGB(strMessage));
 935 }
 936
 937 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 938 void CSQC_Parse_CenterPrint(string strMessage)
 939 {
 940         if(autocvar_developer_csqcentities)
 941                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 942
 943         centerprint_hud(strMessage);
 944 }
 945
 946 string notranslate_fogcmd1 = "\nfog ";
 947 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 948 void Fog_Force()
 949 {
 950         // TODO somehow thwart prvm_globalset client ...
 951
 952         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 953                 { localcmd("\nr_drawfog 0\n"); }
 954         else if(forcefog != "")
 955                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 956 }
 957
 958 void Gamemode_Init();
 959 void Ent_ScoresInfo()
 960 {
 961         float i;
 962         self.classname = "ent_client_scores_info";
 963         gametype = ReadInt24_t();
 964         HUD_ModIcons_SetFunc();
 965         for(i = 0; i < MAX_SCORE; ++i)
 966         {
 967                 if(scores_label[i])
 968                         strunzone(scores_label[i]);
 969                 scores_label[i] = strzone(ReadString());
 970                 scores_flags[i] = ReadByte();
 971         }
 972         for(i = 0; i < MAX_TEAMSCORE; ++i)
 973         {
 974                 if(teamscores_label[i])
 975                         strunzone(teamscores_label[i]);
 976                 teamscores_label[i] = strzone(ReadString());
 977                 teamscores_flags[i] = ReadByte();
 978         }
 979         HUD_InitScores();
 980         Gamemode_Init();
 981 }
 982
 983 void Ent_Init()
 984 {
 985         self.classname = "ent_client_init";
 986
 987         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 988
 989         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 990         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 991         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 992         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 993         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 994         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 995         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 996         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 997
 998         if(forcefog)
 999                 strunzone(forcefog);
1000         forcefog = strzone(ReadString());
1001
1002         armorblockpercent = ReadByte() / 255.0;
1003
1004         g_balance_mortar_bouncefactor = ReadCoord();
1005         g_balance_mortar_bouncestop = ReadCoord();
1006         g_balance_electro_secondary_bouncefactor = ReadCoord();
1007         g_balance_electro_secondary_bouncestop = ReadCoord();
1008
1009         vortex_scope = !ReadByte();
1010         rifle_scope = !ReadByte();
1011
1012         serverflags = ReadByte();
1013
1014         minelayer_maxmines = ReadByte();
1015
1016         hagar_maxrockets = ReadByte();
1017
1018         g_trueaim_minrange = ReadCoord();
1019         g_balance_porto_secondary = ReadByte();
1020
1021         if(!postinit)
1022                 PostInit();
1023 }
1024
1025 void Net_ReadRace()
1026 {
1027         float b;
1028
1029         b = ReadByte();
1030
1031         switch(b)
1032         {
1033                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1034                         race_checkpoint = ReadByte();
1035                         race_time = ReadInt24_t();
1036                         race_previousbesttime = ReadInt24_t();
1037                         if(race_previousbestname)
1038                                 strunzone(race_previousbestname);
1039                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1040
1041                         race_checkpointtime = time;
1042
1043                         if(race_checkpoint == 0 || race_checkpoint == 254)
1044                         {
1045                                 race_penaltyaccumulator = 0;
1046                                 race_laptime = time; // valid
1047                         }
1048
1049                         break;
1050
1051                 case RACE_NET_CHECKPOINT_CLEAR:
1052                         race_laptime = 0;
1053                         race_checkpointtime = 0;
1054                         break;
1055
1056                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1057                         race_laptime = ReadCoord();
1058                         race_checkpointtime = -99999;
1059                         // fall through
1060                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1061                         race_nextcheckpoint = ReadByte();
1062
1063                         race_nextbesttime = ReadInt24_t();
1064                         if(race_nextbestname)
1065                                 strunzone(race_nextbestname);
1066                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1067                         break;
1068
1069                 case RACE_NET_CHECKPOINT_HIT_RACE:
1070                         race_mycheckpoint = ReadByte();
1071                         race_mycheckpointtime = time;
1072                         race_mycheckpointdelta = ReadInt24_t();
1073                         race_mycheckpointlapsdelta = ReadByte();
1074                         if(race_mycheckpointlapsdelta >= 128)
1075                                 race_mycheckpointlapsdelta -= 256;
1076                         if(race_mycheckpointenemy)
1077                                 strunzone(race_mycheckpointenemy);
1078                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1079                         break;
1080
1081                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1082                         race_othercheckpoint = ReadByte();
1083                         race_othercheckpointtime = time;
1084                         race_othercheckpointdelta = ReadInt24_t();
1085                         race_othercheckpointlapsdelta = ReadByte();
1086                         if(race_othercheckpointlapsdelta >= 128)
1087                                 race_othercheckpointlapsdelta -= 256;
1088                         if(race_othercheckpointenemy)
1089                                 strunzone(race_othercheckpointenemy);
1090                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1091                         break;
1092
1093                 case RACE_NET_PENALTY_RACE:
1094                         race_penaltyeventtime = time;
1095                         race_penaltytime = ReadShort();
1096                         //race_penaltyaccumulator += race_penaltytime;
1097                         if(race_penaltyreason)
1098                                 strunzone(race_penaltyreason);
1099                         race_penaltyreason = strzone(ReadString());
1100                         break;
1101
1102                 case RACE_NET_PENALTY_QUALIFYING:
1103                         race_penaltyeventtime = time;
1104                         race_penaltytime = ReadShort();
1105                         race_penaltyaccumulator += race_penaltytime;
1106                         if(race_penaltyreason)
1107                                 strunzone(race_penaltyreason);
1108                         race_penaltyreason = strzone(ReadString());
1109                         break;
1110
1111                 case RACE_NET_SERVER_RECORD:
1112                         race_server_record = ReadInt24_t();
1113                         break;
1114                 case RACE_NET_SPEED_AWARD:
1115                         race_speedaward = ReadInt24_t();
1116                         if(race_speedaward_holder)
1117                                 strunzone(race_speedaward_holder);
1118                         race_speedaward_holder = strzone(ReadString());
1119                         break;
1120                 case RACE_NET_SPEED_AWARD_BEST:
1121                         race_speedaward_alltimebest = ReadInt24_t();
1122                         if(race_speedaward_alltimebest_holder)
1123                                 strunzone(race_speedaward_alltimebest_holder);
1124                         race_speedaward_alltimebest_holder = strzone(ReadString());
1125                         break;
1126                 case RACE_NET_SERVER_RANKINGS:
1127                         float pos, prevpos, del;
1128                         pos = ReadShort();
1129                         prevpos = ReadShort();
1130                         del = ReadShort();
1131
1132                         // move other rankings out of the way
1133                         float i;
1134                         if (prevpos) {
1135                                 for (i=prevpos-1;i>pos-1;--i) {
1136                                         grecordtime[i] = grecordtime[i-1];
1137                                         if(grecordholder[i])
1138                                                 strunzone(grecordholder[i]);
1139                                         grecordholder[i] = strzone(grecordholder[i-1]);
1140                                 }
1141                         } else if (del) { // a record has been deleted by the admin
1142                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1143                                         if (i == RANKINGS_CNT-1) { // clear out last record
1144                                                 grecordtime[i] = 0;
1145                                                 if (grecordholder[i])
1146                                                         strunzone(grecordholder[i]);
1147                                                 grecordholder[i] = string_null;
1148                                         }
1149                                         else {
1150                                                 grecordtime[i] = grecordtime[i+1];
1151                                                 if (grecordholder[i])
1152                                                         strunzone(grecordholder[i]);
1153                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1154                                         }
1155                                 }
1156                         } else { // player has no ranked record yet
1157                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1158                                         grecordtime[i] = grecordtime[i-1];
1159                                         if(grecordholder[i])
1160                                                 strunzone(grecordholder[i]);
1161                                         grecordholder[i] = strzone(grecordholder[i-1]);
1162                                 }
1163                         }
1164
1165                         // store new ranking
1166                         if(grecordholder[pos-1] != "")
1167                                 strunzone(grecordholder[pos-1]);
1168                         grecordholder[pos-1] = strzone(ReadString());
1169                         grecordtime[pos-1] = ReadInt24_t();
1170                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1171                                 race_myrank = pos;
1172                         break;
1173                 case RACE_NET_SERVER_STATUS:
1174                         race_status = ReadShort();
1175                         if(race_status_name)
1176                                 strunzone(race_status_name);
1177                         race_status_name = strzone(ReadString());
1178         }
1179 }
1180
1181 void Net_TeamNagger()
1182 {
1183         teamnagger = 1;
1184 }
1185
1186 void Net_ReadPingPLReport()
1187 {
1188         float e, pi, pl, ml;
1189         e = ReadByte();
1190         pi = ReadShort();
1191         pl = ReadByte();
1192         ml = ReadByte();
1193         if (!(playerslots[e]))
1194                 return;
1195         playerslots[e].ping = pi;
1196         playerslots[e].ping_packetloss = pl / 255.0;
1197         playerslots[e].ping_movementloss = ml / 255.0;
1198 }
1199
1200 void Net_WeaponComplain()
1201 {
1202         complain_weapon = ReadByte();
1203
1204         if(complain_weapon_name)
1205                 strunzone(complain_weapon_name);
1206         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1207
1208         complain_weapon_type = ReadByte();
1209
1210         complain_weapon_time = time;
1211         weapontime = time; // ping the weapon panel
1212
1213         switch(complain_weapon_type)
1214         {
1215                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1216                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1217                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1218         }
1219 }
1220
1221 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1222 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1223 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1224 float CSQC_Parse_TempEntity()
1225 {
1226         float bHandled;
1227                 bHandled  = true;
1228         // Acquire TE ID
1229         float nTEID;
1230                 nTEID = ReadByte();
1231
1232         if(autocvar_developer_csqcentities)
1233                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1234
1235                 // NOTE: Could just do return instead of break...
1236         switch(nTEID)
1237         {
1238                 case TE_CSQC_TARGET_MUSIC:
1239                         Net_TargetMusic();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_PICTURE:
1243                         Net_MapVote_Picture();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_RACE:
1247                         Net_ReadRace();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_VORTEXBEAMPARTICLE:
1251                         Net_ReadVortexBeamParticle();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_TEAMNAGGER:
1255                         Net_TeamNagger();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_ARC:
1259                         Net_ReadArc();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_PINGPLREPORT:
1263                         Net_ReadPingPLReport();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_WEAPONCOMPLAIN:
1267                         Net_WeaponComplain();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_VEHICLESETUP:
1271                         Net_VehicleSetup();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_SVNOTICE:
1275                         cl_notice_read();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_SHOCKWAVEPARTICLE:
1279                         Net_ReadShockwaveParticle();
1280                         bHandled = true;
1281                         break;
1282                 default:
1283                         // No special logic for this temporary entity; return 0 so the engine can handle it
1284                         bHandled = false;
1285                         break;
1286         }
1287
1288         return bHandled;
1289 }
1290
1291 string getcommandkey(string text, string command)
1292 {
1293         string keys;
1294         float n, j, k, l = 0;
1295
1296         if (!autocvar_hud_showbinds)
1297                 return text;
1298
1299         keys = db_get(binddb, command);
1300         if (keys == "")
1301         {
1302                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1303                 for(j = 0; j < n; ++j)
1304                 {
1305                         k = stof(argv(j));
1306                         if(k != -1)
1307                         {
1308                                 if ("" == keys)
1309                                         keys = keynumtostring(k);
1310                                 else
1311                                         keys = strcat(keys, ", ", keynumtostring(k));
1312
1313                                 ++l;
1314                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1315                                         break;
1316                         }
1317
1318                 }
1319                 if (keys == "")
1320                         keys = "NO_KEY";
1321                 db_put(binddb, command, keys);
1322         }
1323
1324         if (keys == "NO_KEY") {
1325                 if (autocvar_hud_showbinds > 1)
1326                         return sprintf(_("%s (not bound)"), text);
1327                 else
1328                         return text;
1329         }
1330         else if (autocvar_hud_showbinds > 1)
1331                 return sprintf(_("%s (%s)"), text, keys);
1332         else
1333                 return keys;
1334 }