qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182         CSQCPlayer_Precache();
 183
 184         if(autocvar_cl_reticle)
 185         {
 186                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 187                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 188         }
 189
 190         get_mi_min_max_texcoords(1); // try the CLEVER way first
 191         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 192         shortmapname = mi_shortname;
 193
 194         if(precache_pic(minimapname) == "")
 195         {
 196                 // but maybe we have a non-clever minimap
 197                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 198                 if(precache_pic(minimapname) == "")
 199                         minimapname = ""; // FAIL
 200                 else
 201                         get_mi_min_max_texcoords(0); // load new texcoords
 202         }
 203
 204         mi_center = (mi_min + mi_max) * 0.5;
 205         mi_scale = mi_max - mi_min;
 206         minimapname = strzone(minimapname);
 207
 208         WarpZone_Init();
 209
 210         hud_configure_prev = -1;
 211         tab_panel = -1;
 212
 213         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 214 }
 215
 216 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 217 void Shutdown(void)
 218 {
 219 #ifdef USE_FTE
 220 #pragma TARGET id
 221         if(!__engine_check)
 222                 return 0;
 223 #pragma TARGET fte
 224 #endif
 225
 226         WarpZone_Shutdown();
 227
 228         remove(teams);
 229         remove(players);
 230         db_close(binddb);
 231         db_close(tempdb);
 232         if(autocvar_cl_db_saveasdump)
 233                 db_dump(ClientProgsDB, "client.db");
 234         else
 235                 db_save(ClientProgsDB, "client.db");
 236         db_close(ClientProgsDB);
 237
 238         if(camera_active)
 239                 cvar_set("chase_active",ftos(chase_active_backup));
 240
 241         // unset the event chasecam's chase_active
 242         if(autocvar_chase_active < 0)
 243                 cvar_set("chase_active", "0");
 244
 245         if not(isdemo())
 246         {
 247                 if not(calledhooks & HOOK_START)
 248                         localcmd("\n_cl_hook_gamestart nop\n");
 249                 if not(calledhooks & HOOK_END)
 250                         localcmd("\ncl_hook_gameend\n");
 251         }
 252 }
 253
 254 .float has_team;
 255 float SetTeam(entity o, float Team)
 256 {
 257         entity tm;
 258         if(teamplay)
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case COLOR_TEAM1:
 264                         case COLOR_TEAM2:
 265                         case COLOR_TEAM3:
 266                         case COLOR_TEAM4:
 267                                 break;
 268                         default:
 269                                 if(GetTeam(Team, false) == world)
 270                                 {
 271                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 272                                         Team = COLOR_SPECTATOR;
 273                                 }
 274                                 break;
 275                 }
 276         }
 277         else
 278         {
 279                 switch(Team)
 280                 {
 281                         case -1:
 282                         case 0:
 283                                 break;
 284                         default:
 285                                 if(GetTeam(Team, false) == world)
 286                                 {
 287                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 288                                         Team = COLOR_SPECTATOR;
 289                                 }
 290                                 break;
 291                 }
 292         }
 293         if(Team == -1) // leave
 294         {
 295                 if(o.has_team)
 296                 {
 297                         tm = GetTeam(o.team, false);
 298                         tm.team_size -= 1;
 299                         o.has_team = 0;
 300                         return TRUE;
 301                 }
 302         }
 303         else
 304         {
 305                 if not(o.has_team)
 306                 {
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         o.has_team = 1;
 311                         return TRUE;
 312                 }
 313                 else if(Team != o.team)
 314                 {
 315                         tm = GetTeam(o.team, false);
 316                         tm.team_size -= 1;
 317                         o.team = Team;
 318                         tm = GetTeam(Team, true);
 319                         tm.team_size += 1;
 320                         return TRUE;
 321                 }
 322         }
 323         return FALSE;
 324 }
 325
 326 void Playerchecker_Think()
 327 {
 328         float i;
 329         entity e;
 330         for(i = 0; i < maxclients; ++i)
 331         {
 332                 e = playerslots[i];
 333                 if(GetPlayerName(i) == "")
 334                 {
 335                         if(e.sort_prev)
 336                         {
 337                                 // player disconnected
 338                                 SetTeam(e, -1);
 339                                 RemovePlayer(e);
 340                                 e.sort_prev = world;
 341                                 //e.gotscores = 0;
 342                         }
 343                 }
 344                 else
 345                 {
 346                         if not(e.sort_prev)
 347                         {
 348                                 // player connected
 349                                 if not(e)
 350                                         playerslots[i] = e = spawn();
 351                                 e.sv_entnum = i;
 352                                 e.ping = 0;
 353                                 e.ping_packetloss = 0;
 354                                 e.ping_movementloss = 0;
 355                                 //e.gotscores = 0; // we might already have the scores...
 356                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 357                                 RegisterPlayer(e);
 358                                 HUD_UpdatePlayerPos(e);
 359                         }
 360                 }
 361         }
 362         self.nextthink = time + 0.2;
 363 }
 364
 365 void Porto_Init();
 366 void TrueAim_Init();
 367 void PostInit(void)
 368 {
 369         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 370
 371         entity playerchecker;
 372         playerchecker = spawn();
 373         playerchecker.think = Playerchecker_Think;
 374         playerchecker.nextthink = time + 0.2;
 375
 376         Porto_Init();
 377         TrueAim_Init();
 378
 379         postinit = true;
 380 }
 381
 382 float button_zoom;
 383
 384 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 385 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 386 // All keys are in ascii.
 387 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 388 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 389 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 390 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 391 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 392 {
 393         float bSkipKey;
 394         bSkipKey = false;
 395
 396         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 397                 return true;
 398
 399         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 400                 return true;
 401
 402         if(menu_visible && menu_action)
 403                 if(menu_action(bInputType, nPrimary, nSecondary))
 404                         return TRUE;
 405
 406         return bSkipKey;
 407 }
 408
 409 // END REQUIRED CSQC FUNCTIONS
 410 // --------------------------------------------------------------------------
 411
 412 // --------------------------------------------------------------------------
 413 // BEGIN OPTIONAL CSQC FUNCTIONS
 414 void Ent_RemoveEntCS()
 415 {
 416         entcs_receiver[self.sv_entnum] = world;
 417 }
 418 void Ent_ReadEntCS()
 419 {
 420         float sf;
 421         InterpolateOrigin_Undo();
 422
 423         self.classname = "entcs_receiver";
 424         sf = ReadByte();
 425
 426         if(sf & 1)
 427                 self.sv_entnum = ReadByte();
 428         if(sf & 2)
 429         {
 430                 self.origin_x = ReadShort();
 431                 self.origin_y = ReadShort();
 432                 self.origin_z = ReadShort();
 433                 setorigin(self, self.origin);
 434         }
 435         if(sf & 4)
 436         {
 437                 self.angles_y = ReadByte() * 360.0 / 256;
 438                 self.angles_x = self.angles_z = 0;
 439         }
 440         if(sf & 8)
 441                 self.healthvalue = ReadByte() * 10;
 442         if(sf & 16)
 443                 self.armorvalue = ReadByte() * 10;
 444
 445         entcs_receiver[self.sv_entnum] = self;
 446         self.entremove = Ent_RemoveEntCS;
 447
 448         InterpolateOrigin_Note();
 449 }
 450
 451 void Ent_Remove();
 452
 453 void Ent_RemovePlayerScore()
 454 {
 455         float i;
 456
 457         if(self.owner)
 458         {
 459                 SetTeam(self.owner, -1);
 460                 self.owner.gotscores = 0;
 461                 for(i = 0; i < MAX_SCORE; ++i)
 462                         self.owner.(scores[i]) = 0; // clear all scores
 463         }
 464 }
 465
 466 void Ent_ReadPlayerScore()
 467 {
 468         float i, n;
 469         float isNew;
 470         entity o;
 471
 472         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 473         // (no I've never heard of M-x replace-string, sed, or anything like that)
 474         isNew = !self.owner; // workaround for DP bug
 475         n = ReadByte()-1;
 476
 477 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 478         if(!isNew && n != self.sv_entnum)
 479         {
 480                 //print(_("A CSQC entity changed its owner!\n"));
 481                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 482                 isNew = true;
 483                 Ent_Remove();
 484                 self.enttype = ENT_CLIENT_SCORES;
 485         }
 486 #endif
 487
 488         self.sv_entnum = n;
 489
 490         if not(playerslots[self.sv_entnum])
 491                 playerslots[self.sv_entnum] = spawn();
 492         o = self.owner = playerslots[self.sv_entnum];
 493         o.sv_entnum = self.sv_entnum;
 494         o.gotscores = 1;
 495
 496         //if not(o.sort_prev)
 497         //      RegisterPlayer(o);
 498         //playerchecker will do this for us later, if it has not already done so
 499
 500         float sf, lf;
 501 #if MAX_SCORE <= 8
 502         sf = ReadByte();
 503         lf = ReadByte();
 504 #else
 505         sf = ReadShort();
 506         lf = ReadShort();
 507 #endif
 508         float p;
 509         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 510                 if(sf & p)
 511                 {
 512                         if(lf & p)
 513                                 o.(scores[i]) = ReadInt24_t();
 514                         else
 515                                 o.(scores[i]) = ReadChar();
 516                 }
 517
 518         if(o.sort_prev)
 519                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 520
 521         self.entremove = Ent_RemovePlayerScore;
 522 }
 523
 524 void Ent_ReadTeamScore()
 525 {
 526         float i;
 527         entity o;
 528
 529         self.team = ReadByte();
 530         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 531
 532         float sf, lf;
 533 #if MAX_TEAMSCORE <= 8
 534         sf = ReadByte();
 535         lf = ReadByte();
 536 #else
 537         sf = ReadShort();
 538         lf = ReadShort();
 539 #endif
 540         float p;
 541         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 542                 if(sf & p)
 543                 {
 544                         if(lf & p)
 545                                 o.(teamscores[i]) = ReadInt24_t();
 546                         else
 547                                 o.(teamscores[i]) = ReadChar();
 548                 }
 549
 550         HUD_UpdateTeamPos(o);
 551 }
 552
 553 void Ent_ClientData()
 554 {
 555         float f;
 556         float newspectatee_status;
 557
 558         f = ReadByte();
 559
 560         scoreboard_showscores_force = (f & 1);
 561
 562         if(f & 2)
 563         {
 564                 newspectatee_status = ReadByte();
 565                 if(newspectatee_status == player_localnum + 1)
 566                         newspectatee_status = -1; // observing
 567         }
 568         else
 569                 newspectatee_status = 0;
 570
 571         spectatorbutton_zoom = (f & 4);
 572
 573         if(f & 8)
 574         {
 575                 angles_held_status = 1;
 576                 angles_held_x = ReadAngle();
 577                 angles_held_y = ReadAngle();
 578                 angles_held_z = 0;
 579         }
 580         else
 581                 angles_held_status = 0;
 582
 583         if(newspectatee_status != spectatee_status)
 584         {
 585                 // clear race stuff
 586                 race_laptime = 0;
 587                 race_checkpointtime = 0;
 588         }
 589         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 590         {
 591                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 592                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 593                 )
 594                         prev_p_health = -1;
 595                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 596                         prev_health = -1;
 597         }
 598         spectatee_status = newspectatee_status;
 599
 600         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 601 }
 602
 603 void Ent_Nagger()
 604 {
 605         float nags, i, j, b, f;
 606
 607         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 608
 609         if(!(nags & 4))
 610         {
 611                 if(vote_called_vote)
 612                         strunzone(vote_called_vote);
 613                 vote_called_vote = string_null;
 614                 vote_active = 0;
 615         }
 616         else
 617         {
 618                 vote_active = 1;
 619         }
 620
 621         if(nags & 64)
 622         {
 623                 vote_yescount = ReadByte();
 624                 vote_nocount = ReadByte();
 625                 vote_needed = ReadByte();
 626                 vote_highlighted = ReadChar();
 627         }
 628
 629         if(nags & 128)
 630         {
 631                 if(vote_called_vote)
 632                         strunzone(vote_called_vote);
 633                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 634         }
 635
 636         if(nags & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].ready = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if not(f & b)
 646                                         if(playerslots[j])
 647                                                 playerslots[j].ready = 0;
 648                 }
 649         }
 650
 651         ready_waiting = (nags & 1);
 652         ready_waiting_for_me = (nags & 2);
 653         vote_waiting = (nags & 4);
 654         vote_waiting_for_me = (nags & 8);
 655         warmup_stage = (nags & 16);
 656 }
 657
 658 void Ent_RandomSeed()
 659 {
 660         float s;
 661         prandom_debug();
 662         s = ReadShort();
 663         psrandom(s);
 664 }
 665
 666 void Ent_ReadAccuracy(void)
 667 {
 668         float sf, f, w, b;
 669         sf = ReadInt24_t();
 670         if(sf == 0)
 671         {
 672                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 673                         weapon_accuracy[w] = -1;
 674                 return;
 675         }
 676
 677         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 678         {
 679                 if(sf & f)
 680                 {
 681                         b = ReadByte();
 682                         if(b == 0)
 683                                 weapon_accuracy[w] = -1;
 684                         else if(b == 255)
 685                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 686                         else
 687                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 688                 }
 689                 if(f == 0x800000)
 690                         f = 1;
 691                 else
 692                         f *= 2;
 693         }
 694 }
 695
 696 void Spawn_Draw(void)
 697 {
 698         pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 2', bound(0, frametime, 0.1));
 699 }
 700
 701 void Ent_ReadSpawnPoint(float is_new)
 702 {
 703         self.team = ReadByte();
 704         self.origin_x = ReadShort();
 705         self.origin_y = ReadShort();
 706         self.origin_z = ReadShort();
 707
 708         //setsize(self, PL_MIN, PL_MAX);
 709
 710         //droptofloor();
 711
 712         //self.mdl = "models/domination/dom_unclaimed.md3";
 713         //precache_model(self.mdl);
 714         //setmodel(self, self.mdl);
 715         self.drawmask = MASK_NORMAL;
 716         self.movetype = MOVETYPE_NOCLIP;
 717         self.draw = Spawn_Draw;
 718
 719         print(ftos(is_new), " - read a spawnpoint at ", vtos(self.origin), ", bitches.\n");
 720 }
 721
 722 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 723 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 724 void Ent_RadarLink();
 725 void Ent_Init();
 726 void Ent_ScoresInfo();
 727 void CSQC_Ent_Update(float bIsNewEntity)
 728 {
 729         float t;
 730         float savetime;
 731         t = ReadByte();
 732
 733         if(autocvar_developer_csqcentities)
 734                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 735
 736         // set up the "time" global for received entities to be correct for interpolation purposes
 737         savetime = time;
 738         if(servertime)
 739         {
 740                 time = servertime;
 741         }
 742         else
 743         {
 744                 serverprevtime = time;
 745                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 746                 time = serverprevtime + serverdeltatime;
 747         }
 748
 749 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 750         if(self.enttype)
 751         {
 752                 if(t != self.enttype || bIsNewEntity)
 753                 {
 754                         //print(_("A CSQC entity changed its type!\n"));
 755                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 756                         Ent_Remove();
 757                         clearentity(self);
 758                         bIsNewEntity = 1;
 759                 }
 760         }
 761         else
 762         {
 763                 if(!bIsNewEntity)
 764                 {
 765                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 766                         bIsNewEntity = 1;
 767                 }
 768         }
 769 #endif
 770         self.enttype = t;
 771         switch(t)
 772         {
 773                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 774                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 775                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 776                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 777                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 778                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 779                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 780                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 781                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 782                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 783                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 784                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 785                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 786                 case ENT_CLIENT_INIT: Ent_Init(); break;
 787                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 788                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 789                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 790                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 791                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 792                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 793                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 794                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 795                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 796                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 797                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 798                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 799                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 800                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 801                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 802                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 803                 case ENT_CLIENT_TURRET: ent_turret(); break;
 804                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 805                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 806                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 807                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 808                 default:
 809                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 810                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 811                         break;
 812         }
 813
 814         time = savetime;
 815 }
 816 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 817 // used when an entity changes its type. For an entity that someone interacts
 818 // with others, make sure it can no longer do so.
 819 void Ent_Remove()
 820 {
 821         if(self.entremove)
 822                 self.entremove();
 823
 824         if(self.skeletonindex)
 825         {
 826                 skel_delete(self.skeletonindex);
 827                 self.skeletonindex = 0;
 828         }
 829
 830         if(self.snd_looping > 0)
 831         {
 832                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 833                 self.snd_looping = 0;
 834         }
 835
 836         self.enttype = 0;
 837         self.classname = "";
 838         self.draw = menu_sub_null;
 839         self.entremove = menu_sub_null;
 840         // TODO possibly set more stuff to defaults
 841 }
 842 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 843 void CSQC_Ent_Remove()
 844 {
 845         if(autocvar_developer_csqcentities)
 846                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 847
 848         if(wasfreed(self))
 849         {
 850                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 851                 return;
 852         }
 853         if(self.enttype)
 854                 Ent_Remove();
 855         remove(self);
 856 }
 857
 858 void Gamemode_Init()
 859 {
 860         if not(isdemo())
 861         {
 862                 if(!(calledhooks & HOOK_START))
 863                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 864                 calledhooks |= HOOK_START;
 865         }
 866 }
 867 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 868 void CSQC_Parse_StuffCmd(string strMessage)
 869 {
 870         if(autocvar_developer_csqcentities)
 871                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 872
 873         localcmd(strMessage);
 874 }
 875 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 876 void CSQC_Parse_Print(string strMessage)
 877 {
 878         if(autocvar_developer_csqcentities)
 879                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 880
 881         print(ColorTranslateRGB(strMessage));
 882 }
 883
 884 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 885 void CSQC_Parse_CenterPrint(string strMessage)
 886 {
 887         if(autocvar_developer_csqcentities)
 888                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 889
 890         centerprint_hud(strMessage);
 891 }
 892
 893 string notranslate_fogcmd1 = "\nfog ";
 894 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 895 void Fog_Force()
 896 {
 897         // TODO somehow thwart prvm_globalset client ...
 898
 899         if(forcefog != "")
 900                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 901 }
 902
 903 void Gamemode_Init();
 904 void Ent_ScoresInfo()
 905 {
 906         float i;
 907         self.classname = "ent_client_scores_info";
 908         gametype = ReadInt24_t();
 909         for(i = 0; i < MAX_SCORE; ++i)
 910         {
 911                 scores_label[i] = strzone(ReadString());
 912                 scores_flags[i] = ReadByte();
 913         }
 914         for(i = 0; i < MAX_TEAMSCORE; ++i)
 915         {
 916                 teamscores_label[i] = strzone(ReadString());
 917                 teamscores_flags[i] = ReadByte();
 918         }
 919         HUD_InitScores();
 920         Gamemode_Init();
 921 }
 922
 923 void Ent_Init()
 924 {
 925         self.classname = "ent_client_init";
 926
 927         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 928
 929         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 930         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 931         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 932         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 933         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 934         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 935         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 936         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 937         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 938         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 939         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 940         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 941
 942         if(forcefog)
 943                 strunzone(forcefog);
 944         forcefog = strzone(ReadString());
 945
 946         armorblockpercent = ReadByte() / 255.0;
 947
 948         g_weaponswitchdelay = ReadByte() / 255.0;
 949
 950         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 951         g_balance_grenadelauncher_bouncestop = ReadCoord();
 952         g_balance_electro_secondary_bouncefactor = ReadCoord();
 953         g_balance_electro_secondary_bouncestop = ReadCoord();
 954
 955         nex_scope = !ReadByte();
 956         rifle_scope = !ReadByte();
 957
 958         serverflags = ReadByte();
 959
 960         minelayer_maxmines = ReadByte();
 961
 962         hagar_maxrockets = ReadByte();
 963
 964         g_trueaim_minrange = ReadCoord();
 965         g_balance_porto_secondary = ReadByte();
 966
 967         if(!postinit)
 968                 PostInit();
 969 }
 970
 971 void Net_ReadRace()
 972 {
 973         float b;
 974
 975         b = ReadByte();
 976
 977         switch(b)
 978         {
 979                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 980                         race_checkpoint = ReadByte();
 981                         race_time = ReadInt24_t();
 982                         race_previousbesttime = ReadInt24_t();
 983                         if(race_previousbestname)
 984                                 strunzone(race_previousbestname);
 985                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 986
 987                         race_checkpointtime = time;
 988
 989                         if(race_checkpoint == 0 || race_checkpoint == 254)
 990                         {
 991                                 race_penaltyaccumulator = 0;
 992                                 race_laptime = time; // valid
 993                         }
 994
 995                         break;
 996
 997                 case RACE_NET_CHECKPOINT_CLEAR:
 998                         race_laptime = 0;
 999                         race_checkpointtime = 0;
1000                         break;
1001
1002                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1003                         race_laptime = ReadCoord();
1004                         race_checkpointtime = -99999;
1005                         // fall through
1006                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1007                         race_nextcheckpoint = ReadByte();
1008
1009                         race_nextbesttime = ReadInt24_t();
1010                         if(race_nextbestname)
1011                                 strunzone(race_nextbestname);
1012                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1013                         break;
1014
1015                 case RACE_NET_CHECKPOINT_HIT_RACE:
1016                         race_mycheckpoint = ReadByte();
1017                         race_mycheckpointtime = time;
1018                         race_mycheckpointdelta = ReadInt24_t();
1019                         race_mycheckpointlapsdelta = ReadByte();
1020                         if(race_mycheckpointlapsdelta >= 128)
1021                                 race_mycheckpointlapsdelta -= 256;
1022                         if(race_mycheckpointenemy)
1023                                 strunzone(race_mycheckpointenemy);
1024                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1025                         break;
1026
1027                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1028                         race_othercheckpoint = ReadByte();
1029                         race_othercheckpointtime = time;
1030                         race_othercheckpointdelta = ReadInt24_t();
1031                         race_othercheckpointlapsdelta = ReadByte();
1032                         if(race_othercheckpointlapsdelta >= 128)
1033                                 race_othercheckpointlapsdelta -= 256;
1034                         if(race_othercheckpointenemy)
1035                                 strunzone(race_othercheckpointenemy);
1036                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1037                         break;
1038
1039                 case RACE_NET_PENALTY_RACE:
1040                         race_penaltyeventtime = time;
1041                         race_penaltytime = ReadShort();
1042                         //race_penaltyaccumulator += race_penaltytime;
1043                         if(race_penaltyreason)
1044                                 strunzone(race_penaltyreason);
1045                         race_penaltyreason = strzone(ReadString());
1046                         break;
1047
1048                 case RACE_NET_PENALTY_QUALIFYING:
1049                         race_penaltyeventtime = time;
1050                         race_penaltytime = ReadShort();
1051                         race_penaltyaccumulator += race_penaltytime;
1052                         if(race_penaltyreason)
1053                                 strunzone(race_penaltyreason);
1054                         race_penaltyreason = strzone(ReadString());
1055                         break;
1056
1057                 case RACE_NET_SERVER_RECORD:
1058                         race_server_record = ReadInt24_t();
1059                         break;
1060                 case RACE_NET_SPEED_AWARD:
1061                         race_speedaward = ReadInt24_t();
1062                         if(race_speedaward_holder)
1063                                 strunzone(race_speedaward_holder);
1064                         race_speedaward_holder = strzone(ReadString());
1065                         break;
1066                 case RACE_NET_SPEED_AWARD_BEST:
1067                         race_speedaward_alltimebest = ReadInt24_t();
1068                         if(race_speedaward_alltimebest_holder)
1069                                 strunzone(race_speedaward_alltimebest_holder);
1070                         race_speedaward_alltimebest_holder = strzone(ReadString());
1071                         break;
1072                 case RACE_NET_SERVER_RANKINGS:
1073                         float pos, prevpos, del;
1074                         pos = ReadShort();
1075                         prevpos = ReadShort();
1076                         del = ReadShort();
1077
1078                         // move other rankings out of the way
1079                         float i;
1080                         if (prevpos) {
1081                                 for (i=prevpos-1;i>pos-1;--i) {
1082                                         grecordtime[i] = grecordtime[i-1];
1083                                         if(grecordholder[i])
1084                                                 strunzone(grecordholder[i]);
1085                                         grecordholder[i] = strzone(grecordholder[i-1]);
1086                                 }
1087                         } else if (del) { // a record has been deleted by the admin
1088                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1089                                         if (i == RANKINGS_CNT-1) { // clear out last record
1090                                                 grecordtime[i] = 0;
1091                                                 if (grecordholder[i])
1092                                                         strunzone(grecordholder[i]);
1093                                                 grecordholder[i] = string_null;
1094                                         }
1095                                         else {
1096                                                 grecordtime[i] = grecordtime[i+1];
1097                                                 if (grecordholder[i])
1098                                                         strunzone(grecordholder[i]);
1099                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1100                                         }
1101                                 }
1102                         } else { // player has no ranked record yet
1103                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1104                                         grecordtime[i] = grecordtime[i-1];
1105                                         if(grecordholder[i])
1106                                                 strunzone(grecordholder[i]);
1107                                         grecordholder[i] = strzone(grecordholder[i-1]);
1108                                 }
1109                         }
1110
1111                         // store new ranking
1112                         if(grecordholder[pos-1] != "")
1113                                 strunzone(grecordholder[pos-1]);
1114                         grecordholder[pos-1] = strzone(ReadString());
1115                         grecordtime[pos-1] = ReadInt24_t();
1116                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1117                                 race_myrank = pos;
1118                         break;
1119                 case RACE_NET_SERVER_STATUS:
1120                         race_status = ReadShort();
1121                         if(race_status_name)
1122                                 strunzone(race_status_name);
1123                         race_status_name = strzone(ReadString());
1124         }
1125 }
1126
1127 void Net_ReadSpawn()
1128 {
1129         zoomin_effect = 1;
1130         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1131 }
1132
1133 void Net_TeamNagger()
1134 {
1135         teamnagger = 1;
1136 }
1137
1138 void Net_ReadPingPLReport()
1139 {
1140         float e, pi, pl, ml;
1141         e = ReadByte();
1142         pi = ReadShort();
1143         pl = ReadByte();
1144         ml = ReadByte();
1145         if not(playerslots[e])
1146                 return;
1147         playerslots[e].ping = pi;
1148         playerslots[e].ping_packetloss = pl / 255.0;
1149         playerslots[e].ping_movementloss = ml / 255.0;
1150 }
1151
1152 void Net_WeaponComplain() {
1153         complain_weapon = ReadByte();
1154
1155         if(complain_weapon_name)
1156                 strunzone(complain_weapon_name);
1157         complain_weapon_name = strzone(ReadString());
1158
1159         complain_weapon_type = ReadByte();
1160
1161         complain_weapon_time = time;
1162         weapontime = time; // ping the weapon panel
1163 }
1164
1165 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1166 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1167 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1168 float CSQC_Parse_TempEntity()
1169 {
1170         float bHandled;
1171                 bHandled  = true;
1172         // Acquire TE ID
1173         float nTEID;
1174                 nTEID = ReadByte();
1175
1176         if(autocvar_developer_csqcentities)
1177                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1178
1179                 // NOTE: Could just do return instead of break...
1180         switch(nTEID)
1181         {
1182                 case TE_CSQC_TARGET_MUSIC:
1183                         Net_TargetMusic();
1184                         bHandled = true;
1185                         break;
1186                 case TE_CSQC_PICTURE:
1187                         Net_MapVote_Picture();
1188                         bHandled = true;
1189                         break;
1190                 case TE_CSQC_RACE:
1191                         Net_ReadRace();
1192                         bHandled = true;
1193                         break;
1194                 case TE_CSQC_SPAWN:
1195                         Net_ReadSpawn();
1196                         bHandled = true;
1197                         break;
1198                 case TE_CSQC_ZCURVEPARTICLES:
1199                         Net_ReadZCurveParticles();
1200                         bHandled = true;
1201                         break;
1202                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1203                         Net_ReadNexgunBeamParticle();
1204                         bHandled = true;
1205                         break;
1206                 case TE_CSQC_TEAMNAGGER:
1207                         Net_TeamNagger();
1208                         bHandled = true;
1209                         break;
1210                 case TE_CSQC_LIGHTNINGARC:
1211                         Net_ReadLightningarc();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_PINGPLREPORT:
1215                         Net_ReadPingPLReport();
1216                         bHandled = true;
1217                         break;
1218                 case TE_CSQC_ANNOUNCE:
1219                         Announcer_Play(ReadString());
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_KILLNOTIFY:
1223                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1224                         bHandled = true;
1225                         break;
1226                 case TE_CSQC_KILLCENTERPRINT:
1227                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_CENTERPRINT_GENERIC:
1231                         float id;
1232                         string s;
1233                         id = ReadByte();
1234                         s = ReadString();
1235                         if (id != 0 && s != "")
1236                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1237                         else
1238                                 centerprint_generic(id, s, 0, 0);
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_WEAPONCOMPLAIN:
1242                         Net_WeaponComplain();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_VEHICLESETUP:
1246                         Net_VehicleSetup();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_SVNOTICE:
1250                         cl_notice_read();
1251                         bHandled = true;
1252                         break;
1253                 default:
1254                         // No special logic for this temporary entity; return 0 so the engine can handle it
1255                         bHandled = false;
1256                         break;
1257         }
1258
1259         return bHandled;
1260 }
1261
1262 string getcommandkey(string text, string command)
1263 {
1264         string keys;
1265         float n, j, k, l = 0;
1266
1267         if (!autocvar_hud_showbinds)
1268                 return text;
1269
1270         keys = db_get(binddb, command);
1271         if (keys == "")
1272         {
1273                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1274                 for(j = 0; j < n; ++j)
1275                 {
1276                         k = stof(argv(j));
1277                         if(k != -1)
1278                         {
1279                                 if ("" == keys)
1280                                         keys = keynumtostring(k);
1281                                 else
1282                                         keys = strcat(keys, ", ", keynumtostring(k));
1283
1284                                 ++l;
1285                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1286                                         break;
1287                         }
1288
1289                 }
1290                 if (keys == "")
1291                         keys = "NO_KEY";
1292                 db_put(binddb, command, keys);
1293         }
1294
1295         if (keys == "NO_KEY") {
1296                 if (autocvar_hud_showbinds > 1)
1297                         return sprintf(_("%s (not bound)"), text);
1298                 else
1299                         return text;
1300         }
1301         else if (autocvar_hud_showbinds > 1)
1302                 return sprintf(_("%s (%s)"), text, keys);
1303         else
1304                 return keys;
1305 }