qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369 void CSQC_SPIDER_HUD();
 370 void CSQC_RAPTOR_HUD();
 371
 372 vector freeze_org, freeze_ang;
 373 entity nightvision_noise, nightvision_noise2;
 374
 375 #define MAX_TIME_DIFF 5
 376 float pickup_crosshair_time, pickup_crosshair_size;
 377 float hit_time, typehit_time;
 378 float nextsound_hit_time, nextsound_typehit_time;
 379 float hitindication_crosshair_time, hitindication_crosshair_size;
 380 float use_nex_chargepool;
 381
 382 float myhealth, myhealth_prev;
 383 float myhealth_flash;
 384
 385 float old_blurradius, old_bluralpha;
 386 float old_sharpen_intensity;
 387
 388 vector myhealth_gentlergb;
 389
 390 float contentavgalpha, liquidalpha_prev;
 391 vector liquidcolor_prev;
 392
 393 float eventchase_current_distance;
 394
 395 vector damage_blurpostprocess, content_blurpostprocess;
 396
 397 float checkfail[16];
 398
 399 float rainbow_last_flicker;
 400 vector rainbow_prev_color;
 401
 402 #define BUTTON_3 4
 403 #define BUTTON_4 8
 404 float cl_notice_run();
 405 float prev_myteam;
 406 .float health;
 407 void CSQC_UpdateView(float w, float h)
 408 {
 409         entity e;
 410         float fov;
 411         float f, i, j;
 412         vector v;
 413         vector vf_size, vf_min;
 414         float a;
 415
 416         execute_next_frame();
 417
 418         ++framecount;
 419
 420         hud = getstati(STAT_HUD);
 421
 422         if(autocvar__hud_showbinds_reload) // menu can set this one
 423         {
 424                 db_close(binddb);
 425                 binddb = db_create();
 426                 cvar_set("_hud_showbinds_reload", "0");
 427         }
 428
 429         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 430                 view_quality = getproperty(VF_MINFPS_QUALITY);
 431         else
 432                 view_quality = 1;
 433
 434         button_attack2 = (input_buttons & BUTTON_3);
 435         button_zoom = (input_buttons & BUTTON_4);
 436
 437 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 438         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 439         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 440         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 441         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 443         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 444         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 445
 446         vf_size = getpropertyvec(VF_SIZE);
 447         vf_min = getpropertyvec(VF_MIN);
 448         vid_width = vf_size_x;
 449         vid_height = vf_size_y;
 450
 451         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 452         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 453
 454         WaypointSprite_Load();
 455
 456         CSQCPlayer_SetCamera();
 457
 458 #ifdef COMPAT_XON050_ENGINE
 459         if(spectatee_status)
 460                 myteam = GetPlayerColor(spectatee_status - 1);
 461         else
 462 #endif
 463                 myteam = GetPlayerColor(player_localentnum - 1);
 464
 465         if(myteam != prev_myteam)
 466         {
 467                 myteamcolors = colormapPaletteColor(myteam, 1);
 468                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 469                         hud_panel[i].update_time = time;
 470                 prev_myteam = myteam;
 471         }
 472
 473         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 474
 475         float is_dead = (getstati(STAT_HEALTH) <= 0);
 476
 477         // FIXME do we need this hack?
 478         if(isdemo())
 479         {
 480                 // in demos, input_buttons do not work
 481                 button_zoom = (autocvar__togglezoom == "-");
 482         }
 483         else if(button_zoom
 484                 && autocvar_cl_unpress_zoom_on_death
 485                 && (spectatee_status >= 0)
 486                 && (is_dead || intermission))
 487         {
 488                 // no zoom while dead or in intermission please
 489                 localcmd("-zoom\n");
 490                 button_zoom = FALSE;
 491         }
 492
 493         // event chase camera
 494         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 495         {
 496                 WepSet weapons_stat = WepSet_GetFromStat();
 497                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
 498                 entity gen = world;
 499
 500                 if(ons_roundlost)
 501                 {
 502                         entity e;
 503                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
 504                         {
 505                                 if(e.health <= 0)
 506                                 {
 507                                         gen = e;
 508                                         break;
 509                                 }
 510                         }
 511                         if(!gen)
 512                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
 513                 }
 514                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission || ons_roundlost) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 515                 {
 516                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 517                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 518                         if(ons_roundlost) { current_view_origin = gen.origin; }
 519
 520                         // detect maximum viewoffset and use it
 521                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 522                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
 523
 524                         if(view_offset)
 525                         {
 526                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 527                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 528                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 529                         }
 530
 531                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 532                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 533                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 534                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 535
 536                         // make the camera smooth back
 537                         float chase_distance = autocvar_cl_eventchase_distance;
 538                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
 539
 540                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 541                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 542                         else if(eventchase_current_distance != chase_distance)
 543                                 eventchase_current_distance = chase_distance;
 544
 545                         makevectors(view_angles);
 546
 547                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 548                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 549
 550                         // If the boxtrace fails, revert back to line tracing.
 551                         if(trace_startsolid)
 552                         {
 553                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 554                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 555                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 556                         }
 557                         else { setproperty(VF_ORIGIN, trace_endpos); }
 558
 559                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 560                 }
 561                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 562                 {
 563                         cvar_set("chase_active", "0");
 564                         eventchase_current_distance = 0; // start from 0 next time
 565                 }
 566         }
 567         // workaround for camera stuck between player's legs when using chase_active 1
 568         // because the engine stops updating the chase_active camera when the game ends
 569         else if(intermission)
 570         {
 571                 cvar_settemp("chase_active", "-1");
 572                 eventchase_current_distance = 0;
 573         }
 574
 575         // do lockview after event chase camera so that it still applies whenever necessary.
 576         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 577         {
 578                 setproperty(VF_ORIGIN, freeze_org);
 579                 setproperty(VF_ANGLES, freeze_ang);
 580         }
 581         else
 582         {
 583                 freeze_org = getpropertyvec(VF_ORIGIN);
 584                 freeze_ang = getpropertyvec(VF_ANGLES);
 585         }
 586
 587         WarpZone_FixView();
 588         //WarpZone_FixPMove();
 589
 590         vector ov_org = '0 0 0';
 591         vector ov_mid = '0 0 0';
 592         vector ov_worldmin = '0 0 0';
 593         vector ov_worldmax = '0 0 0';
 594         if(autocvar_cl_orthoview)
 595         {
 596                 ov_worldmin = mi_picmin;
 597                 ov_worldmax = mi_picmax;
 598
 599                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 600                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 601                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 602
 603                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 604                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 605
 606                 float ov_nearest = vlen(ov_org - vec3(
 607                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 608                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 609                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 610                 ));
 611
 612                 float ov_furthest = 0;
 613                 float dist = 0;
 614
 615                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 616                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 617                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 618                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 619                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 620                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 621                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 622                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 623
 624                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 625                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 626                 cvar_settemp("r_farclip_world", "0");
 627                 cvar_settemp("r_novis", "1");
 628                 cvar_settemp("r_useportalculling", "0");
 629                 cvar_settemp("r_useinfinitefarclip", "0");
 630
 631                 setproperty(VF_ORIGIN, ov_org);
 632                 setproperty(VF_ANGLES, '90 0 0');
 633
 634                 #if 0
 635                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 636                         vtos(ov_org),
 637                         vtos(getpropertyvec(VF_ANGLES)),
 638                         ov_distance,
 639                         ov_nearest,
 640                         ov_furthest);
 641                 #endif
 642         }
 643
 644         // Render the Scene
 645         view_origin = getpropertyvec(VF_ORIGIN);
 646         view_angles = getpropertyvec(VF_ANGLES);
 647         makevectors(view_angles);
 648         view_forward = v_forward;
 649         view_right = v_right;
 650         view_up = v_up;
 651
 652 #ifdef BLURTEST
 653         if(time > blurtest_time0 && time < blurtest_time1)
 654         {
 655                 float r, t;
 656
 657                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 658                 r = t * blurtest_radius;
 659                 f = 1 / pow(t, blurtest_power) - 1;
 660
 661                 cvar_set("r_glsl_postprocess", "1");
 662                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 663         }
 664         else
 665         {
 666                 cvar_set("r_glsl_postprocess", "0");
 667                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 668         }
 669 #endif
 670
 671         TargetMusic_Advance();
 672         Fog_Force();
 673
 674         if(drawtime == 0)
 675                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 676         else
 677                 drawframetime = bound(0.000001, time - drawtime, 1);
 678         drawtime = time;
 679
 680         // watch for gametype changes here...
 681         // in ParseStuffCMD the cmd isn't executed yet :/
 682         // might even be better to add the gametype to TE_CSQC_INIT...?
 683         if(!postinit)
 684                 PostInit();
 685
 686         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 687         {
 688                 if(calledhooks & HOOK_START)
 689                 {
 690                         localcmd("\ncl_hook_gameend\n");
 691                         calledhooks |= HOOK_END;
 692                 }
 693         }
 694
 695         Announcer();
 696
 697         fov = autocvar_fov;
 698         if(fov <= 59.5)
 699         {
 700                 if(!zoomscript_caught)
 701                 {
 702                         localcmd("+button9\n");
 703                         zoomscript_caught = 1;
 704                 }
 705         }
 706         else
 707         {
 708                 if(zoomscript_caught)
 709                 {
 710                         localcmd("-button9\n");
 711                         zoomscript_caught = 0;
 712                 }
 713         }
 714
 715         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 716
 717         // next WANTED weapon (for HUD)
 718         switchweapon = getstati(STAT_SWITCHWEAPON);
 719
 720         // currently switching-to weapon (for crosshair)
 721         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 722
 723         // actually active weapon (for zoom)
 724         activeweapon = getstati(STAT_ACTIVEWEAPON);
 725
 726         f = (serverflags & SERVERFLAG_TEAMPLAY);
 727         if(f != teamplay)
 728         {
 729                 teamplay = f;
 730                 HUD_InitScores();
 731         }
 732
 733         if(last_switchweapon != switchweapon)
 734         {
 735                 weapontime = time;
 736                 last_switchweapon = switchweapon;
 737                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 738                 {
 739                         localcmd("-zoom\n");
 740                         button_zoom = FALSE;
 741                 }
 742                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 743                 {
 744                         localcmd("-fire\n");
 745                         localcmd("-fire2\n");
 746                         button_attack2 = FALSE;
 747                 }
 748         }
 749         if(last_activeweapon != activeweapon)
 750         {
 751                 last_activeweapon = activeweapon;
 752
 753                 e = get_weaponinfo(activeweapon);
 754                 if(e.netname != "")
 755                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 756                 else
 757                         localcmd("\ncl_hook_activeweapon none\n");
 758         }
 759
 760         // ALWAYS Clear Current Scene First
 761         clearscene();
 762 #ifdef WORKAROUND_XON010
 763         if(checkextension("DP_CSQC_ROTATEMOVES"))
 764         {
 765 #endif
 766         setproperty(VF_ORIGIN, view_origin);
 767         setproperty(VF_ANGLES, view_angles);
 768 #ifdef WORKAROUND_XON010
 769         }
 770 #endif
 771
 772         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 773         setproperty(VF_SIZE, vf_size);
 774         setproperty(VF_MIN, vf_min);
 775
 776         // Assign Standard Viewflags
 777         // Draw the World (and sky)
 778         setproperty(VF_DRAWWORLD, 1);
 779
 780         // Set the console size vars
 781         vid_conwidth = autocvar_vid_conwidth;
 782         vid_conheight = autocvar_vid_conheight;
 783         vid_pixelheight = autocvar_vid_pixelheight;
 784
 785         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 786         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 787
 788         // Camera for demo playback
 789         if(camera_active)
 790         {
 791                 if(autocvar_camera_enable)
 792                         CSQC_Demo_Camera();
 793                 else
 794                 {
 795                         cvar_set("chase_active", ftos(chase_active_backup));
 796                         cvar_set("cl_demo_mousegrab", "0");
 797                         camera_active = FALSE;
 798                 }
 799         }
 800 #ifdef CAMERATEST
 801         else if(autocvar_camera_enable)
 802 #else
 803         else if(autocvar_camera_enable && isdemo())
 804 #endif
 805         {
 806                 // Enable required Darkplaces cvars
 807                 chase_active_backup = autocvar_chase_active;
 808                 cvar_set("chase_active", "2");
 809                 cvar_set("cl_demo_mousegrab", "1");
 810                 camera_active = TRUE;
 811                 camera_mode = FALSE;
 812         }
 813
 814         // Draw the Crosshair
 815         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 816
 817         // Draw the Engine Status Bar (the default Quake HUD)
 818         setproperty(VF_DRAWENGINESBAR, 0);
 819
 820         // Update the mouse position
 821         /*
 822            mousepos_x = vid_conwidth;
 823            mousepos_y = vid_conheight;
 824            mousepos = mousepos*0.5 + getmousepos();
 825          */
 826
 827         e = self;
 828         for(self = world; (self = nextent(self)); )
 829                 if(self.draw)
 830                         self.draw();
 831         self = e;
 832
 833         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 834         renderscene();
 835
 836         // now switch to 2D drawing mode by calling a 2D drawing function
 837         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 838         // next R_RenderScene call
 839         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 840
 841         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 842         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 843         {
 844                 // apply night vision effect
 845                 vector tc_00, tc_01, tc_10, tc_11;
 846                 vector rgb;
 847                 rgb_x = 0; // fteqcc sucks
 848                 rgb_y = 0; // fteqcc sucks
 849                 rgb_z = 0; // fteqcc sucks
 850
 851                 if(!nightvision_noise)
 852                 {
 853                         nightvision_noise = spawn();
 854                         nightvision_noise.classname = "nightvision_noise";
 855                 }
 856                 if(!nightvision_noise2)
 857                 {
 858                         nightvision_noise2 = spawn();
 859                         nightvision_noise2.classname = "nightvision_noise2";
 860                 }
 861
 862                 // color tint in yellow
 863                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 864
 865                 // draw BG
 866                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 867                 rgb = '1 1 1';
 868                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 869                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 870                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 871                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 872                 tc_11 = tc_01 + tc_10 - tc_00;
 873                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 874                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 875                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 876                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 877                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 878                 R_EndPolygon();
 879
 880                 // draw FG
 881                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 882                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 883                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 884                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 885                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 886                 tc_11 = tc_01 + tc_10 - tc_00;
 887                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 888                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 889                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 890                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 891                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 892                 R_EndPolygon();
 893         }
 894
 895         // Draw the aiming reticle for weapons that use it
 896         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 897         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 898         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 899         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 900                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 901         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 902                 reticle_type = 2; // nex zoom
 903         else if(button_zoom || zoomscript_caught)
 904                 reticle_type = 1; // normal zoom
 905         else if((activeweapon == WEP_NEX) && button_attack2)
 906                 reticle_type = 2; // nex zoom
 907
 908         if(reticle_type && autocvar_cl_reticle)
 909         {
 910                 if(autocvar_cl_reticle_stretch)
 911                 {
 912                         reticle_size_x = vid_conwidth;
 913                         reticle_size_y = vid_conheight;
 914                         reticle_pos_x = 0;
 915                         reticle_pos_y = 0;
 916                 }
 917                 else
 918                 {
 919                         reticle_size_x = max(vid_conwidth, vid_conheight);
 920                         reticle_size_y = max(vid_conwidth, vid_conheight);
 921                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 922                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 923                 }
 924
 925                 f = current_zoomfraction;
 926                 if(zoomscript_caught)
 927                         f = 1;
 928                 if(autocvar_cl_reticle_item_normal)
 929                 {
 930                         if(reticle_type == 1 && f)
 931                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 932                 }
 933                 if(autocvar_cl_reticle_item_nex)
 934                 {
 935                         if(reticle_type == 2 && f)
 936                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 937                 }
 938         }
 939
 940
 941         // improved polyblend
 942         if(autocvar_hud_contents)
 943         {
 944                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 945                 vector liquidcolor;
 946
 947                 switch(pointcontents(view_origin))
 948                 {
 949                         case CONTENT_WATER:
 950                                 liquidalpha = autocvar_hud_contents_water_alpha;
 951                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 952                                 incontent = 1;
 953                                 break;
 954
 955                         case CONTENT_LAVA:
 956                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 957                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 958                                 incontent = 1;
 959                                 break;
 960
 961                         case CONTENT_SLIME:
 962                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 963                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 964                                 incontent = 1;
 965                                 break;
 966
 967                         default:
 968                                 liquidalpha = 0;
 969                                 liquidcolor = '0 0 0';
 970                                 incontent = 0;
 971                                 break;
 972                 }
 973
 974                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 975                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 976                         contentfadetime = autocvar_hud_contents_fadeintime;
 977                         liquidalpha_prev = liquidalpha;
 978                         liquidcolor_prev = liquidcolor;
 979                 }
 980                 else
 981                         contentfadetime = autocvar_hud_contents_fadeouttime;
 982
 983                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 984                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 985
 986                 if(contentavgalpha)
 987                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 988
 989                 if(autocvar_hud_postprocessing)
 990                 {
 991                         if(autocvar_hud_contents_blur && contentavgalpha)
 992                         {
 993                                 content_blurpostprocess_x = 1;
 994                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 995                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 996                         }
 997                         else
 998                         {
 999                                 content_blurpostprocess_x = 0;
1000                                 content_blurpostprocess_y = 0;
1001                                 content_blurpostprocess_z = 0;
1002                         }
1003                 }
1004         }
1005
1006         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1007         {
1008                 splash_size_x = max(vid_conwidth, vid_conheight);
1009                 splash_size_y = max(vid_conwidth, vid_conheight);
1010                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1011                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1012
1013                 float myhealth_flash_temp;
1014                 myhealth = getstati(STAT_HEALTH);
1015
1016                 // fade out
1017                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1018                 // add new damage
1019                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1020
1021                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1022                 pain_threshold = autocvar_hud_damage_pain_threshold;
1023                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1024                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1025
1026                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1027                 {
1028                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1029                 }
1030
1031                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1032
1033                 if(myhealth_prev < 1)
1034                 {
1035                         if(myhealth >= 1)
1036                         {
1037                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1038                                 myhealth_flash_temp = 0;
1039                         }
1040                         else
1041                         {
1042                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1043                         }
1044                 }
1045
1046                 if(spectatee_status == -1 || intermission)
1047                 {
1048                         myhealth_flash = 0; // observing, or match ended
1049                         myhealth_flash_temp = 0;
1050                 }
1051
1052                 myhealth_prev = myhealth;
1053
1054                 // IDEA: change damage color/picture based on player model for robot/alien species?
1055                 // pro: matches model better
1056                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1057                 // maybe different reddish pics?
1058                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1059                 {
1060                         if(autocvar_cl_gentle_damage == 2)
1061                         {
1062                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1063                                 {
1064                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1065                                 }
1066                         }
1067                         else
1068                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1069
1070                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1071                 }
1072                 else
1073                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1074
1075                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1076                 {
1077                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1078                         {
1079                                 damage_blurpostprocess_x = 1;
1080                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1081                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1082                         }
1083                         else
1084                         {
1085                                 damage_blurpostprocess_x = 0;
1086                                 damage_blurpostprocess_y = 0;
1087                                 damage_blurpostprocess_z = 0;
1088                         }
1089                 }
1090         }
1091
1092         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1093         float e2 = (autocvar_hud_powerup != 0);
1094         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1095         {
1096                 // enable or disable rendering types if they are used or not
1097                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1098                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1099
1100                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1101                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1102                 {
1103                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1104                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1105                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1106                         {
1107                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1108                                 old_blurradius = blurradius;
1109                                 old_bluralpha = bluralpha;
1110                         }
1111                 }
1112                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1113                 {
1114                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1115                         old_blurradius = 0;
1116                         old_bluralpha = 0;
1117                 }
1118
1119                 // edge detection postprocess handling done second (used by hud_powerup)
1120                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1121                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1122                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1123
1124                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1125
1126                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1127                 {
1128                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1129                         {
1130                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1131                                 old_sharpen_intensity = sharpen_intensity;
1132                         }
1133                 }
1134                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1135                 {
1136                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1137                         old_sharpen_intensity = 0;
1138                 }
1139
1140                 if(cvar("r_glsl_postprocess") == 0)
1141                         cvar_set("r_glsl_postprocess", "2");
1142         }
1143         else if(cvar("r_glsl_postprocess") == 2)
1144                 cvar_set("r_glsl_postprocess", "0");
1145
1146         if(menu_visible)
1147                 menu_show();
1148
1149         /*if(gametype == MAPINFO_TYPE_CTF)
1150           {
1151           ctf_view();
1152           } else */
1153
1154         // draw 2D entities
1155         e = self;
1156         for(self = world; (self = nextent(self)); )
1157                 if(self.draw2d)
1158                         self.draw2d();
1159         self = e;
1160         Draw_ShowNames_All();
1161
1162         scoreboard_active = HUD_WouldDrawScoreboard();
1163
1164         hit_time = getstatf(STAT_HIT_TIME);
1165         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1166         {
1167                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1168                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1169
1170                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1171         }
1172         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1173         if(typehit_time > nextsound_typehit_time)
1174         {
1175                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1176                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1177
1178                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1179         }
1180
1181         //else
1182         {
1183                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1184                 {
1185                         if(getstati(STAT_FROZEN))
1186                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1187                         if(getstatf(STAT_REVIVE_PROGRESS))
1188                         {
1189                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1190                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1191                         }
1192                 }
1193
1194                 if(autocvar_r_letterbox == 0)
1195                         if(autocvar_viewsize < 120)
1196                                 CSQC_common_hud();
1197
1198                 // crosshair goes VERY LAST
1199                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1200                 {
1201                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1202                                 return;
1203
1204                         string wcross_style;
1205                         float wcross_alpha, wcross_resolution;
1206                         wcross_style = autocvar_crosshair;
1207                         if (wcross_style == "0")
1208                                 return;
1209                         wcross_resolution = autocvar_crosshair_size;
1210                         if (wcross_resolution == 0)
1211                                 return;
1212                         wcross_alpha = autocvar_crosshair_alpha;
1213                         if (wcross_alpha == 0)
1214                                 return;
1215
1216                         // TrueAim check
1217                         float shottype;
1218
1219                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1220                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1221                         wcross_origin_z = 0;
1222                         if(autocvar_crosshair_hittest)
1223                         {
1224                                 vector wcross_oldorigin;
1225                                 wcross_oldorigin = wcross_origin;
1226                                 shottype = TrueAimCheck();
1227                                 if(shottype == SHOTTYPE_HITWORLD)
1228                                 {
1229                                         v = wcross_origin - wcross_oldorigin;
1230                                         v_x /= vid_conwidth;
1231                                         v_y /= vid_conheight;
1232                                         if(vlen(v) > 0.01)
1233                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1234                                 }
1235                                 if(!autocvar_crosshair_hittest_showimpact)
1236                                         wcross_origin = wcross_oldorigin;
1237                         }
1238                         else
1239                                 shottype = SHOTTYPE_HITWORLD;
1240
1241                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1242                         string wcross_wep = "", wcross_name;
1243                         float wcross_scale, wcross_blur;
1244
1245                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1246                         {
1247                                 e = get_weaponinfo(switchingweapon);
1248                                 if (e && e.netname != "")
1249                                 {
1250                                         wcross_wep = e.netname;
1251                                         if(autocvar_crosshair_per_weapon)
1252                                         {
1253                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1254                                                 if (wcross_resolution == 0)
1255                                                         return;
1256                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1257                                                 if (wcross_alpha == 0)
1258                                                         return;
1259
1260                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1261                                                 if(wcross_style == "" || wcross_style == "0")
1262                                                         wcross_style = wcross_wep;
1263                                         }
1264                                 }
1265                         }
1266
1267                         //printf("crosshair style: %s\n", wcross_style);
1268                         wcross_name = strcat("gfx/crosshair", wcross_style);
1269
1270                         // MAIN CROSSHAIR COLOR DECISION
1271                         switch(autocvar_crosshair_color_special)
1272                         {
1273                                 case 1: // crosshair_color_per_weapon
1274                                 {
1275                                         if(wcross_wep != "")
1276                                         {
1277                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1278                                                 break;
1279                                         }
1280                                         else { goto normalcolor; }
1281                                 }
1282
1283                                 case 2: // crosshair_color_by_health
1284                                 {
1285                                         float x = getstati(STAT_HEALTH);
1286
1287                                         //x = red
1288                                         //y = green
1289                                         //z = blue
1290
1291                                         wcross_color_z = 0;
1292
1293                                         if(x > 200)
1294                                         {
1295                                                 wcross_color_x = 0;
1296                                                 wcross_color_y = 1;
1297                                         }
1298                                         else if(x > 150)
1299                                         {
1300                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1301                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1302                                         }
1303                                         else if(x > 100)
1304                                         {
1305                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1306                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1307                                                 wcross_color_z = 1 - (x-100)*0.02;
1308                                         }
1309                                         else if(x > 50)
1310                                         {
1311                                                 wcross_color_x = 1;
1312                                                 wcross_color_y = 1;
1313                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1314                                         }
1315                                         else if(x > 20)
1316                                         {
1317                                                 wcross_color_x = 1;
1318                                                 wcross_color_y = (x-20)*90/27/100;
1319                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1320                                         }
1321                                         else
1322                                         {
1323                                                 wcross_color_x = 1;
1324                                                 wcross_color_y = 0;
1325                                         }
1326                                         break;
1327                                 }
1328
1329                                 case 3: // crosshair_color_rainbow
1330                                 {
1331                                         if(time >= rainbow_last_flicker)
1332                                         {
1333                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1334                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1335                                         }
1336                                         wcross_color = rainbow_prev_color;
1337                                         break;
1338                                 }
1339                                 :normalcolor
1340                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1341                         }
1342
1343                         if(autocvar_crosshair_effect_scalefade)
1344                         {
1345                                 wcross_scale = wcross_resolution;
1346                                 wcross_resolution = 1;
1347                         }
1348                         else
1349                         {
1350                                 wcross_scale = 1;
1351                         }
1352
1353                         if(autocvar_crosshair_pickup)
1354                         {
1355                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1356
1357                                 if(pickup_crosshair_time < stat_pickup_time)
1358                                 {
1359                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1360                                                 pickup_crosshair_size = 1;
1361
1362                                         pickup_crosshair_time = stat_pickup_time;
1363                                 }
1364
1365                                 if(pickup_crosshair_size > 0)
1366                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1367                                 else
1368                                         pickup_crosshair_size = 0;
1369
1370                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1371                         }
1372
1373                         if(autocvar_crosshair_hitindication)
1374                         {
1375                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1376
1377                                 if(hitindication_crosshair_time < hit_time)
1378                                 {
1379                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1380                                                 hitindication_crosshair_size = 1;
1381
1382                                         hitindication_crosshair_time = hit_time;
1383                                 }
1384
1385                                 if(hitindication_crosshair_size > 0)
1386                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1387                                 else
1388                                         hitindication_crosshair_size = 0;
1389
1390                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1391                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1392                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1393                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1394                         }
1395
1396                         if(shottype == SHOTTYPE_HITENEMY)
1397                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1398                         if(shottype == SHOTTYPE_HITTEAM)
1399                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1400
1401                         f = fabs(autocvar_crosshair_effect_time);
1402                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1403                         {
1404                                 wcross_changedonetime = time + f;
1405                         }
1406                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1407                         {
1408                                 wcross_name_changestarttime = time;
1409                                 wcross_name_changedonetime = time + f;
1410                                 if(wcross_name_goal_prev_prev)
1411                                         strunzone(wcross_name_goal_prev_prev);
1412                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1413                                 wcross_name_goal_prev = strzone(wcross_name);
1414                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1415                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1416                                 wcross_resolution_goal_prev = wcross_resolution;
1417                         }
1418
1419                         wcross_scale_goal_prev = wcross_scale;
1420                         wcross_alpha_goal_prev = wcross_alpha;
1421                         wcross_color_goal_prev = wcross_color;
1422
1423                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1424                         {
1425                                 wcross_blur = 1;
1426                                 wcross_alpha *= 0.75;
1427                         }
1428                         else
1429                                 wcross_blur = 0;
1430                         // *_prev is at time-frametime
1431                         // * is at wcross_changedonetime+f
1432                         // what do we have at time?
1433                         if(time < wcross_changedonetime)
1434                         {
1435                                 f = frametime / (wcross_changedonetime - time + frametime);
1436                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1437                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1438                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1439                         }
1440
1441                         wcross_scale_prev = wcross_scale;
1442                         wcross_alpha_prev = wcross_alpha;
1443                         wcross_color_prev = wcross_color;
1444
1445                         wcross_scale *= 1 - autocvar__menu_alpha;
1446                         wcross_alpha *= 1 - autocvar__menu_alpha;
1447                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1448
1449                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1450                         {
1451                                 // crosshair rings for weapon stats
1452                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1453                                 {
1454                                         // declarations and stats
1455                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1456                                         string ring_image = string_null, ring_inner_image = string_null;
1457                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1458
1459                                         ring_scale = autocvar_crosshair_ring_size;
1460
1461                                         float weapon_clipload, weapon_clipsize;
1462                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1463                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1464
1465                                         float nex_charge, nex_chargepool;
1466                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1467                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1468
1469                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1470                                                 nex_charge_movingavg = nex_charge;
1471
1472
1473                                         // handle the values
1474                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1475                                         {
1476                                                 if (nex_chargepool || use_nex_chargepool) {
1477                                                         use_nex_chargepool = 1;
1478                                                         ring_inner_value = nex_chargepool;
1479                                                 } else {
1480                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1481                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1482                                                 }
1483
1484                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1485                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1486                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1487
1488                                                 // draw the outer ring to show the current charge of the weapon
1489                                                 ring_value = nex_charge;
1490                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1491                                                 ring_rgb = wcross_color;
1492                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1493                                         }
1494                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1495                                         {
1496                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1497                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1498                                                 ring_rgb = wcross_color;
1499                                                 ring_image = "gfx/crosshair_ring.tga";
1500                                         }
1501                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1502                                         {
1503                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1504                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1505                                                 ring_rgb = wcross_color;
1506                                                 ring_image = "gfx/crosshair_ring.tga";
1507                                         }
1508
1509                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1510                                         {
1511                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1512                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1513                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1514                                                 ring_rgb = wcross_color;
1515
1516                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1517                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1518                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1519                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1520                                                 else
1521                                                         ring_image = "gfx/crosshair_ring.tga";
1522                                         }
1523
1524                                         // if in weapon switch animation, fade ring out/in
1525                                         if(autocvar_crosshair_effect_time > 0)
1526                                         {
1527                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1528                                                 if (!(f < 1))
1529                                                 {
1530                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1531                                                 }
1532
1533                                                 if(wcross_ring_prev)
1534                                                 {
1535                                                         if(f < 1)
1536                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1537                                                 }
1538                                                 else
1539                                                 {
1540                                                         if(f < 1)
1541                                                                 ring_alpha *= bound(0, f, 1);
1542                                                 }
1543                                         }
1544
1545                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1546                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1547
1548                                         if (ring_value)
1549                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1550                                 }
1551
1552 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1553                                 do \
1554                                 { \
1555                                         if(wcross_blur > 0) \
1556                                         { \
1557                                                 for(i = -2; i <= 2; ++i) \
1558                                                 for(j = -2; j <= 2; ++j) \
1559                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1560                                         } \
1561                                         else \
1562                                         { \
1563                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1564                                         } \
1565                                 } \
1566                                 while(0)
1567
1568 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1569                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1570
1571 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1572                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1573
1574                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1575                                 {
1576                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1577                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1578                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1579                                         f = 1 - f;
1580                                 }
1581                                 else
1582                                 {
1583                                         f = 1;
1584                                 }
1585                                 wcross_name_alpha_goal_prev = f;
1586
1587                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1588                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1589
1590                                 if(autocvar_crosshair_dot)
1591                                 {
1592                                         vector wcross_color_old;
1593                                         wcross_color_old = wcross_color;
1594
1595                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1596                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1597
1598                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1599                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1600                                         wcross_color = wcross_color_old;
1601                                 }
1602                         }
1603                 }
1604                 else
1605                 {
1606                         wcross_scale_prev = 0;
1607                         wcross_alpha_prev = 0;
1608                         wcross_scale_goal_prev = 0;
1609                         wcross_alpha_goal_prev = 0;
1610                         wcross_changedonetime = 0;
1611                         if(wcross_name_goal_prev)
1612                                 strunzone(wcross_name_goal_prev);
1613                         wcross_name_goal_prev = string_null;
1614                         if(wcross_name_goal_prev_prev)
1615                                 strunzone(wcross_name_goal_prev_prev);
1616                         wcross_name_goal_prev_prev = string_null;
1617                         wcross_name_changestarttime = 0;
1618                         wcross_name_changedonetime = 0;
1619                         wcross_name_alpha_goal_prev = 0;
1620                         wcross_name_alpha_goal_prev_prev = 0;
1621                         wcross_resolution_goal_prev = 0;
1622                         wcross_resolution_goal_prev_prev = 0;
1623                 }
1624         }
1625
1626         if(NextFrameCommand)
1627         {
1628                 localcmd("\n", NextFrameCommand, "\n");
1629                 NextFrameCommand = string_null;
1630         }
1631
1632         // we must do this check AFTER a frame was rendered, or it won't work
1633         if(cs_project_is_b0rked == 0)
1634         {
1635                 string w0, h0;
1636                 w0 = ftos(autocvar_vid_conwidth);
1637                 h0 = ftos(autocvar_vid_conheight);
1638                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1639                 //setproperty(VF_FOV, '90 90 0');
1640                 setproperty(VF_ORIGIN, '0 0 0');
1641                 setproperty(VF_ANGLES, '0 0 0');
1642                 setproperty(VF_PERSPECTIVE, 1);
1643                 makevectors('0 0 0');
1644                 vector v1, v2;
1645                 cvar_set("vid_conwidth", "800");
1646                 cvar_set("vid_conheight", "600");
1647                 v1 = cs_project(v_forward);
1648                 cvar_set("vid_conwidth", "640");
1649                 cvar_set("vid_conheight", "480");
1650                 v2 = cs_project(v_forward);
1651                 if(v1 == v2)
1652                         cs_project_is_b0rked = 1;
1653                 else
1654                         cs_project_is_b0rked = -1;
1655                 cvar_set("vid_conwidth", w0);
1656                 cvar_set("vid_conheight", h0);
1657         }
1658
1659         if(autocvar__hud_configure)
1660                 HUD_Panel_Mouse();
1661         else
1662                 HUD_Radar_Mouse();
1663
1664     if(hud && !intermission)
1665     {
1666         if(hud == HUD_SPIDERBOT)
1667             CSQC_SPIDER_HUD();
1668         else if(hud == HUD_WAKIZASHI)
1669             CSQC_WAKIZASHI_HUD();
1670         else if(hud == HUD_RAPTOR)
1671             CSQC_RAPTOR_HUD();
1672         else if(hud == HUD_BUMBLEBEE)
1673             CSQC_BUMBLE_HUD();
1674         else if(hud == HUD_BUMBLEBEE_GUN)
1675             CSQC_BUMBLE_GUN_HUD();
1676     }
1677
1678         cl_notice_run();
1679
1680         // let's reset the view back to normal for the end
1681         setproperty(VF_MIN, '0 0 0');
1682         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1683 }
1684
1685
1686 void CSQC_common_hud(void)
1687 {
1688         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1689                 Accuracy_LoadLevels();
1690
1691         HUD_Main(); // always run these functions for alpha checks
1692         HUD_DrawScoreboard();
1693
1694         if (scoreboard_active) // scoreboard/accuracy
1695                 HUD_Reset();
1696         else if (intermission == 2) // map voting screen
1697         {
1698                 MapVote_Draw();
1699                 HUD_Reset();
1700         }
1701 }
1702
1703
1704 // following vectors must be global to allow seamless switching between camera modes
1705 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1706 void CSQC_Demo_Camera()
1707 {
1708         float speed, attenuation, dimensions;
1709         vector tmp, delta;
1710
1711         if( autocvar_camera_reset || !camera_mode )
1712         {
1713                 camera_offset = '0 0 0';
1714                 current_angles = '0 0 0';
1715                 camera_direction = '0 0 0';
1716                 camera_offset_z += 30;
1717                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1718                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1719                 current_origin = view_origin;
1720                 current_camera_offset  = camera_offset;
1721                 cvar_set("camera_reset", "0");
1722                 camera_mode = CAMERA_CHASE;
1723         }
1724
1725         // Camera angles
1726         if( camera_roll )
1727                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1728
1729         if(autocvar_camera_look_player)
1730         {
1731                 vector dir;
1732                 float n;
1733
1734                 dir = normalize(view_origin - current_position);
1735                 n = mouse_angles_z;
1736                 mouse_angles = vectoangles(dir);
1737                 mouse_angles_x = mouse_angles_x * -1;
1738                 mouse_angles_z = n;
1739         }
1740         else
1741         {
1742                 tmp = getmousepos() * 0.1;
1743                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1744                 {
1745                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1746                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1747                 }
1748         }
1749
1750         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1751         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1752         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1753         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1754
1755         // Fix difference when angles don't have the same sign
1756         delta = '0 0 0';
1757         if(mouse_angles_y < -60 && current_angles_y > 60)
1758                 delta = '0 360 0';
1759         if(mouse_angles_y > 60 && current_angles_y < -60)
1760                 delta = '0 -360 0';
1761
1762         if(autocvar_camera_look_player)
1763                 attenuation = autocvar_camera_look_attenuation;
1764         else
1765                 attenuation = autocvar_camera_speed_attenuation;
1766
1767         attenuation = 1 / max(1, attenuation);
1768         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1769
1770         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1771         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1772         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1773         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1774
1775         // Camera position
1776         tmp = '0 0 0';
1777         dimensions = 0;
1778
1779         if( camera_direction_x )
1780         {
1781                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1782                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1783                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1784                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1785                 ++dimensions;
1786         }
1787
1788         if( camera_direction_y )
1789         {
1790                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1791                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1792                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1793                 ++dimensions;
1794         }
1795
1796         if( camera_direction_z )
1797         {
1798                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1799                 ++dimensions;
1800         }
1801
1802         if(autocvar_camera_free)
1803                 speed = autocvar_camera_speed_free;
1804         else
1805                 speed = autocvar_camera_speed_chase;
1806
1807         if(dimensions)
1808         {
1809                 speed = speed * sqrt(1 / dimensions);
1810                 camera_offset += tmp * speed;
1811         }
1812
1813         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1814
1815         // Camera modes
1816         if( autocvar_camera_free )
1817         {
1818                 if ( camera_mode == CAMERA_CHASE )
1819                 {
1820                         current_camera_offset = current_origin + current_camera_offset;
1821                         camera_offset = current_origin + camera_offset;
1822                 }
1823
1824                 camera_mode = CAMERA_FREE;
1825                 current_position = current_camera_offset;
1826         }
1827         else
1828         {
1829                 if ( camera_mode == CAMERA_FREE )
1830                 {
1831                         current_origin = view_origin;
1832                         camera_offset = camera_offset - current_origin;
1833                         current_camera_offset = current_camera_offset - current_origin;
1834                 }
1835
1836                 camera_mode = CAMERA_CHASE;
1837
1838                 if(autocvar_camera_chase_smoothly)
1839                         current_origin += (view_origin - current_origin) * attenuation;
1840                 else
1841                         current_origin = view_origin;
1842
1843                 current_position = current_origin + current_camera_offset;
1844         }
1845
1846         setproperty(VF_ANGLES, current_angles);
1847         setproperty(VF_ORIGIN, current_position);
1848 }