qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float chase_used;
 370 float chase_default;
 371 float chase_current_distance;
 372
 373 void CSQC_UpdateView(float w, float h)
 374 {
 375         entity e;
 376         float fov;
 377         float f, i, j;
 378         vector v, vo;
 379         vector vf_size, vf_min;
 380         float a;
 381
 382         vf_size = R_SetView3fv(VF_SIZE);
 383         vf_min = R_SetView3fv(VF_MIN);
 384         vid_width = vf_size_x;
 385         vid_height = vf_size_y;
 386
 387         vector reticle_pos, reticle_size;
 388         vector splash_pos, splash_size;
 389
 390         WaypointSprite_Load();
 391
 392         if(spectatee_status)
 393                 myteam = GetPlayerColor(spectatee_status - 1);
 394         else
 395                 myteam = GetPlayerColor(player_localentnum - 1);
 396
 397         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 398         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 399
 400         warpzone_fixview_origin = pmove_org + vo;
 401         warpzone_fixview_cl_viewangles = input_angles;
 402         warpzone_fixview_angles = view_angles;
 403         WarpZone_FixView();
 404         pmove_org = warpzone_fixview_origin - vo;
 405         input_angles = warpzone_fixview_cl_viewangles;
 406         view_angles = warpzone_fixview_angles;
 407
 408         // event chase cam
 409         if(spectatee_status >= 0 && (autocvar_cl_chase_death || autocvar_cl_chase_intermission))
 410         {
 411                 if((autocvar_cl_chase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_chase_intermission && intermission))
 412                 {
 413                         if(!chase_used)
 414                         {
 415                                 cvar_set("chase_active", "1");
 416                                 chase_used = TRUE;
 417                         }
 418
 419                         // make the camera smooth back
 420                         if(autocvar_cl_chase_speed && chase_current_distance < autocvar_cl_chase_distance)
 421                                 chase_current_distance += autocvar_cl_chase_speed * (autocvar_cl_chase_distance - chase_current_distance) * frametime;
 422                         else if(chase_current_distance != autocvar_cl_chase_distance)
 423                                 chase_current_distance = autocvar_cl_chase_distance;
 424
 425                         makevectors(view_angles);
 426                         R_SetView(VF_ORIGIN_X, pmove_org_x - view_forward_x * chase_current_distance);
 427                         R_SetView(VF_ORIGIN_Y, pmove_org_y - view_forward_y * chase_current_distance);
 428                 }
 429                 else
 430                 {
 431                         if(chase_used)
 432                         {
 433                                 cvar_set("chase_active", ftos(chase_default));
 434                                 chase_current_distance = 0; // start from 0
 435                                 chase_used = FALSE;
 436                         }
 437
 438                         // keep the defaults updated
 439                         if(chase_default != cvar("chase_active"))
 440                                 chase_default = cvar("chase_active");
 441                 }
 442         }
 443
 444         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 445         {
 446                 pmove_org = freeze_pmove_org;
 447                 input_angles = view_angles = freeze_input_angles;
 448                 R_SetView(VF_ORIGIN, pmove_org + vo);
 449                 R_SetView(VF_ANGLES, view_angles);
 450                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 451         }
 452         freeze_pmove_org = pmove_org;
 453         freeze_input_angles = input_angles;
 454
 455         // Render the Scene
 456         if(!intermission || !view_set)
 457         {
 458                 view_origin = pmove_org + vo;
 459                 view_angles = input_angles;
 460                 makevectors(view_angles);
 461                 view_forward = v_forward;
 462                 view_right = v_right;
 463                 view_up = v_up;
 464                 view_set = 1;
 465         }
 466
 467 #ifdef BLURTEST
 468         if(time > blurtest_time0 && time < blurtest_time1)
 469         {
 470                 float r, t;
 471
 472                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 473                 r = t * blurtest_radius;
 474                 f = 1 / pow(t, blurtest_power) - 1;
 475
 476                 cvar_set("r_glsl_postprocess", "1");
 477                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 478         }
 479         else
 480         {
 481                 cvar_set("r_glsl_postprocess", "0");
 482                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 483         }
 484 #endif
 485
 486         TargetMusic_Advance();
 487         Fog_Force();
 488
 489         drawframetime = max(0.000001, time - drawtime);
 490         drawtime = time;
 491
 492         // watch for gametype changes here...
 493         // in ParseStuffCMD the cmd isn't executed yet :/
 494         // might even be better to add the gametype to TE_CSQC_INIT...?
 495         if(!postinit)
 496                 PostInit();
 497
 498         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 499                 if(calledhooks & HOOK_START)
 500                 {
 501                         localcmd("\ncl_hook_gameend\n");
 502                         calledhooks |= HOOK_END;
 503                 }
 504
 505         CheckForGamestartChange();
 506         serverAnnouncer();
 507         maptimeAnnouncer();
 508         carrierAnnouncer();
 509
 510         fov = autocvar_fov;
 511         if(button_zoom || fov <= 59.5)
 512         {
 513                 if(!zoomscript_caught)
 514                 {
 515                         localcmd("+button4\n");
 516                         zoomscript_caught = 1;
 517                         ignore_plus_zoom += 1;
 518                 }
 519         }
 520         else
 521         {
 522                 if(zoomscript_caught)
 523                 {
 524                         localcmd("-button4\n");
 525                         zoomscript_caught = 0;
 526                         ignore_minus_zoom += 1;
 527                 }
 528         }
 529
 530         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 531         activeweapon = getstati(STAT_SWITCHWEAPON);
 532         f = (serverflags & SERVERFLAG_TEAMPLAY);
 533         if(f != teamplay)
 534         {
 535                 teamplay = f;
 536                 HUD_InitScores();
 537         }
 538
 539         if(last_weapon != activeweapon) {
 540                 weapontime = time;
 541                 last_weapon = activeweapon;
 542
 543                 e = get_weaponinfo(activeweapon);
 544                 if(e.netname != "")
 545                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 546                 else
 547                         localcmd("\ncl_hook_activeweapon none\n");
 548         }
 549
 550         // ALWAYS Clear Current Scene First
 551         R_ClearScene();
 552
 553         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 554         R_SetView(VF_SIZE, vf_size);
 555         R_SetView(VF_MIN, vf_min);
 556
 557         // Assign Standard Viewflags
 558         // Draw the World (and sky)
 559         R_SetView(VF_DRAWWORLD, 1);
 560
 561         // Set the console size vars
 562         vid_conwidth = autocvar_vid_conwidth;
 563         vid_conheight = autocvar_vid_conheight;
 564         vid_pixelheight = autocvar_vid_pixelheight;
 565
 566         R_SetView(VF_FOV, GetCurrentFov(fov));
 567
 568         // Camera for demo playback
 569         if(camera_active)
 570         {
 571                 if(autocvar_camera_enable)
 572                         CSQC_Demo_Camera();
 573                 else
 574                 {
 575                         cvar_set("chase_active", ftos(chase_active_backup));
 576                         cvar_set("cl_demo_mousegrab", "0");
 577                         camera_active = FALSE;
 578                 }
 579         }
 580 #ifdef CAMERATEST
 581         else if(autocvar_camera_enable)
 582 #else
 583         else if(autocvar_camera_enable && isdemo())
 584 #endif
 585         {
 586                 // Enable required Darkplaces cvars
 587                 chase_active_backup = autocvar_chase_active;
 588                 cvar_set("chase_active", "2");
 589                 cvar_set("cl_demo_mousegrab", "1");
 590                 camera_active = TRUE;
 591                 camera_mode = FALSE;
 592         }
 593
 594         // Draw the Crosshair
 595         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 596
 597         // Draw the Engine Status Bar (the default Quake HUD)
 598         R_SetView(VF_DRAWENGINEHUD, 0);
 599
 600         // fetch this one only once per frame
 601         hud_showbinds = autocvar_hud_showbinds;
 602         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 603
 604         // Update the mouse position
 605         /*
 606            mousepos_x = vid_conwidth;
 607            mousepos_y = vid_conheight;
 608            mousepos = mousepos*0.5 + getmousepos();
 609          */
 610
 611         e = self;
 612         for(self = world; (self = nextent(self)); )
 613                 if(self.draw)
 614                         self.draw();
 615         self = e;
 616
 617         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 618         R_RenderScene();
 619
 620         // now switch to 2D drawing mode by calling a 2D drawing function
 621         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 622         // next R_RenderScene call
 623         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 624
 625         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 626         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 627         {
 628                 // apply night vision effect
 629                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 630
 631                 if(!nightvision_noise)
 632                 {
 633                         nightvision_noise = spawn();
 634                         nightvision_noise.classname = "nightvision_noise";
 635                 }
 636                 if(!nightvision_noise2)
 637                 {
 638                         nightvision_noise2 = spawn();
 639                         nightvision_noise2.classname = "nightvision_noise2";
 640                 }
 641
 642                 // color tint in yellow
 643                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 644
 645                 // draw BG
 646                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 647                 rgb = '1 1 1';
 648                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 649                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 650                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 651                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 652                 tc_11 = tc_01 + tc_10 - tc_00;
 653                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 654                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 655                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 656                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 657                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 658                 R_EndPolygon();
 659
 660                 // draw FG
 661                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 662                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 663                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 664                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 665                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 666                 tc_11 = tc_01 + tc_10 - tc_00;
 667                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 668                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 669                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 670                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 671                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 672                 R_EndPolygon();
 673         }
 674
 675         // Draw the aiming reticle for weapons that use it
 676         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 677         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 678         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 679         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 680                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 681         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 682                 reticle_type = 2; // nex zoom
 683         else if(button_zoom || zoomscript_caught)
 684                 reticle_type = 1; // normal zoom
 685         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 686                 reticle_type = 2; // nex zoom
 687
 688         if (reticle_type)
 689         {
 690                 if(autocvar_cl_reticle_stretch)
 691                 {
 692                         reticle_size_x = vid_conwidth;
 693                         reticle_size_y = vid_conheight;
 694                         reticle_pos_x = 0;
 695                         reticle_pos_y = 0;
 696                 }
 697                 else
 698                 {
 699                         reticle_size_x = max(vid_conwidth, vid_conheight);
 700                         reticle_size_y = max(vid_conwidth, vid_conheight);
 701                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 702                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 703                 }
 704
 705                 f = current_zoomfraction;
 706                 if(zoomscript_caught)
 707                         f = 1;
 708                 if(autocvar_cl_reticle_item_normal)
 709                 {
 710                         if(reticle_type == 1 && f)
 711                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 712                 }
 713                 if(autocvar_cl_reticle_item_nex)
 714                 {
 715                         if(reticle_type == 2 && f)
 716                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 717                 }
 718         }
 719
 720
 721         // improved polyblend
 722         vector rgb;
 723         if(autocvar_hud_contents)
 724         {
 725                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 726                 vector liquidcolor;
 727
 728                 switch(pointcontents(view_origin))
 729                 {
 730                         case CONTENT_WATER:
 731                                 liquidalpha = autocvar_hud_contents_water_alpha;
 732                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 733                                 incontent = 1;
 734                                 break;
 735
 736                         case CONTENT_LAVA:
 737                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 738                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 739                                 incontent = 1;
 740                                 break;
 741
 742                         case CONTENT_SLIME:
 743                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 744                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 745                                 incontent = 1;
 746                                 break;
 747
 748                         default:
 749                                 liquidalpha = 0;
 750                                 liquidcolor = '0 0 0';
 751                                 incontent = 0;
 752                                 break;
 753                 }
 754
 755                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 756                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 757                         contentfadetime = autocvar_hud_contents_fadeintime;
 758                         liquidalpha_prev = liquidalpha;
 759                         liquidcolor_prev = liquidcolor;
 760                 }
 761                 else
 762                         contentfadetime = autocvar_hud_contents_fadeouttime;
 763
 764                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 765                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 766
 767                 if(contentavgalpha)
 768                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 769         }
 770
 771         if(autocvar_hud_damage)
 772         {
 773                 splash_size_x = max(vid_conwidth, vid_conheight);
 774                 splash_size_y = max(vid_conwidth, vid_conheight);
 775                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 776                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 777
 778                 float myhealth_flash_temp;
 779                 myhealth = getstati(STAT_HEALTH);
 780
 781                 // fade out
 782                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 783                 // add new damage
 784                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 785
 786                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 787                 pain_threshold = autocvar_hud_damage_pain_threshold;
 788                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 789                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 790
 791                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 792                 {
 793                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 794                 }
 795
 796                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 797
 798                 if(myhealth_prev < 1)
 799                 {
 800                         if(myhealth >= 1)
 801                         {
 802                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 803                                 myhealth_flash_temp = 0;
 804                         }
 805                         else
 806                         {
 807                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 808                         }
 809                 }
 810
 811                 if(spectatee_status == -1 || intermission)
 812                 {
 813                         myhealth_flash = 0; // observing, or match ended
 814                         myhealth_flash_temp = 0;
 815                 }
 816
 817                 myhealth_prev = myhealth;
 818
 819                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 820                 {
 821                         if(autocvar_cl_gentle_damage == 2)
 822                         {
 823                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 824                                 {
 825                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 826                                 }
 827                         }
 828                         else
 829                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 830
 831                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 832                 }
 833                 else
 834                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 835         }
 836
 837         // Draw the mouse cursor
 838         // NOTE: drawpic must happen after R_RenderScene for some reason
 839         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 840         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 841         //self = edict_num(player_localnum);
 842         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 843         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 844         // as long as the ctf part isn't in, this is useless
 845         if(menu_visible)
 846                 menu_show();
 847
 848         /*if(gametype == GAME_CTF)
 849           {
 850           ctf_view();
 851           } else */
 852
 853         // draw 2D entities
 854         e = self;
 855         for(self = world; (self = nextent(self)); )
 856                 if(self.draw2d)
 857                         self.draw2d();
 858         self = e;
 859
 860         scoreboard_active = HUD_WouldDrawScoreboard();
 861
 862         hit_time = getstatf(STAT_HIT_TIME);
 863         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 864         {
 865                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 866                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 867         }
 868         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 869         if(typehit_time > nextsound_typehit_time)
 870         {
 871                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 872                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 873         }
 874
 875         float hud;
 876         hud = getstati(STAT_HUD);
 877         if(hud == HUD_SPIDERBOT)
 878                 CSQC_SPIDER_HUD();
 879         else if(hud == HUD_WAKIZASHI)
 880         CSQC_WAKIZASHI_HUD();
 881     else if(hud == HUD_RAPTOR)
 882         CSQC_RAPTOR_HUD();
 883         else
 884         {
 885                 if(gametype == GAME_FREEZETAG)
 886                 {
 887                         if(getstati(STAT_FROZEN))
 888                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 889                         if(getstatf(STAT_REVIVE_PROGRESS))
 890                         {
 891                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 892                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 893                         }
 894                 }
 895
 896                 if(autocvar_r_letterbox == 0)
 897                         if(autocvar_viewsize < 120)
 898                                 CSQC_common_hud();
 899
 900                 // crosshair goes VERY LAST
 901                 if(!scoreboard_active && !camera_active && intermission != 2) {
 902                         string wcross_style;
 903                         float wcross_alpha, wcross_resolution;
 904                         wcross_style = autocvar_crosshair;
 905                         if (wcross_style == "0")
 906                                 return;
 907                         wcross_resolution = autocvar_crosshair_size;
 908                         if (wcross_resolution == 0)
 909                                 return;
 910                         wcross_alpha = autocvar_crosshair_alpha;
 911                         if (wcross_alpha == 0)
 912                                 return;
 913
 914                         // TrueAim check
 915                         float shottype;
 916
 917                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 918                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 919                         wcross_origin_z = 0;
 920                         if(autocvar_crosshair_hittest)
 921                         {
 922                                 vector wcross_oldorigin;
 923                                 wcross_oldorigin = wcross_origin;
 924                                 shottype = TrueAimCheck();
 925                                 if(shottype == SHOTTYPE_HITWORLD)
 926                                 {
 927                                         v = wcross_origin - wcross_oldorigin;
 928                                         v_x /= vid_conwidth;
 929                                         v_y /= vid_conheight;
 930                                         if(vlen(v) > 0.01)
 931                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 932                                 }
 933                                 if(!autocvar_crosshair_hittest_showimpact)
 934                                         wcross_origin = wcross_oldorigin;
 935                         }
 936                         else
 937                                 shottype = SHOTTYPE_HITWORLD;
 938
 939                         vector wcross_color, wcross_size;
 940                         string wcross_wep, wcross_name;
 941                         float wcross_scale, wcross_blur;
 942
 943                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 944                                 e = get_weaponinfo(activeweapon);
 945                                 if (e && e.netname != "")
 946                                 {
 947                                         wcross_wep = e.netname;
 948                                         if(autocvar_crosshair_per_weapon)
 949                                         {
 950                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 951                                                 if (wcross_resolution == 0)
 952                                                         return;
 953                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 954                                                 if (wcross_alpha == 0)
 955                                                         return;
 956
 957                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 958                                                 if(wcross_style == "" || wcross_style == "0")
 959                                                         wcross_style = wcross_wep;
 960                                         }
 961                                 }
 962                         }
 963                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 964                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 965                         else if(autocvar_crosshair_color_by_health)
 966                         {
 967                                 local float x = getstati(STAT_HEALTH);
 968
 969                                 //x = red
 970                                 //y = green
 971                                 //z = blue
 972
 973                                 wcross_color_z = 0;
 974
 975                                 if(x > 200)
 976                                 {
 977                                         wcross_color_x = 0;
 978                                         wcross_color_y = 1;
 979                                 }
 980                                 else if(x > 150)
 981                                 {
 982                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 983                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 984                                 }
 985                                 else if(x > 100)
 986                                 {
 987                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 988                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 989                                         wcross_color_z = 1 - (x-100)*0.02;
 990                                 }
 991                                 else if(x > 50)
 992                                 {
 993                                         wcross_color_x = 1;
 994                                         wcross_color_y = 1;
 995                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 996                                 }
 997                                 else if(x > 20)
 998                                 {
 999                                         wcross_color_x = 1;
1000                                         wcross_color_y = (x-20)*90/27/100;
1001                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1002                                 }
1003                                 else
1004                                 {
1005                                         wcross_color_x = 1;
1006                                         wcross_color_y = 0;
1007                                 }
1008                         }
1009                         else
1010                                 wcross_color = stov(autocvar_crosshair_color);
1011
1012                         wcross_name = strcat("gfx/crosshair", wcross_style);
1013
1014                         if(autocvar_crosshair_effect_scalefade)
1015                         {
1016                                 wcross_scale = wcross_resolution;
1017                                 wcross_resolution = 1;
1018                         }
1019                         else
1020                         {
1021                                 wcross_scale = 1;
1022                         }
1023
1024                         if(autocvar_crosshair_pickup)
1025                         {
1026                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1027                                 {
1028                                         pickup_crosshair_size = 1;
1029                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1030                                 }
1031
1032                                 if(pickup_crosshair_size > 0)
1033                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1034                                 else
1035                                         pickup_crosshair_size = 0;
1036
1037                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1038                         }
1039
1040                         vector hitindication_color;
1041                         if(autocvar_crosshair_hitindication)
1042                         {
1043                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1044                                 if(hitindication_crosshair_time < hit_time)
1045                                 {
1046                                         hitindication_crosshair_size = 1;
1047                                         hitindication_crosshair_time = hit_time;
1048                                 }
1049
1050                                 if(hitindication_crosshair_size > 0)
1051                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1052                                 else
1053                                         hitindication_crosshair_size = 0;
1054
1055                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1056                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1057                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1058                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1059                         }
1060
1061                         if(shottype == SHOTTYPE_HITENEMY)
1062                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1063                         if(shottype == SHOTTYPE_HITTEAM)
1064                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1065
1066                         f = autocvar_crosshair_effect_speed;
1067                         if(f < 0)
1068                                 f *= -2 * g_weaponswitchdelay;
1069                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1070                         {
1071                                 wcross_changedonetime = time + f;
1072                         }
1073                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1074                         {
1075                                 wcross_name_changestarttime = time;
1076                                 wcross_name_changedonetime = time + f;
1077                                 if(wcross_name_goal_prev_prev)
1078                                         strunzone(wcross_name_goal_prev_prev);
1079                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1080                                 wcross_name_goal_prev = strzone(wcross_name);
1081                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1082                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1083                                 wcross_resolution_goal_prev = wcross_resolution;
1084                         }
1085
1086                         wcross_scale_goal_prev = wcross_scale;
1087                         wcross_alpha_goal_prev = wcross_alpha;
1088                         wcross_color_goal_prev = wcross_color;
1089
1090                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1091                         {
1092                                 wcross_blur = 1;
1093                                 wcross_alpha *= 0.75;
1094                         }
1095                         else
1096                                 wcross_blur = 0;
1097                         // *_prev is at time-frametime
1098                         // * is at wcross_changedonetime+f
1099                         // what do we have at time?
1100                         if(time < wcross_changedonetime)
1101                         {
1102                                 f = frametime / (wcross_changedonetime - time + frametime);
1103                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1104                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1105                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1106                         }
1107
1108                         wcross_scale_prev = wcross_scale;
1109                         wcross_alpha_prev = wcross_alpha;
1110                         wcross_color_prev = wcross_color;
1111
1112                         wcross_scale *= 1 - autocvar__menu_alpha;
1113                         wcross_alpha *= 1 - autocvar__menu_alpha;
1114                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1115
1116                         // crosshair rings for weapon stats
1117                         if ((autocvar_crosshair_ring) || (autocvar_crosshair_ring_reload))
1118                         {
1119                                 // declarations and stats
1120                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1121                                 string ring_image, ring_inner_image;
1122                                 vector ring_rgb, ring_inner_rgb;
1123
1124                                 ring_scale = autocvar_crosshair_ring_size;
1125
1126                                 float weapon_clipload, weapon_clipsize;
1127                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1128                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1129
1130                                 float nex_charge, nex_chargepool;
1131                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1132                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1133
1134                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1135                                         nex_charge_movingavg = nex_charge;
1136
1137
1138                                 // handle the values
1139                                 if (activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1140                                 {
1141                                         if (nex_chargepool || use_nex_chargepool) {
1142                                                 use_nex_chargepool = 1;
1143                                                 ring_inner_value = nex_chargepool;
1144                                         } else {
1145                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1146                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1147                                         }
1148
1149                                         ring_inner_alpha = wcross_alpha * autocvar_crosshair_ring_nex_inner_alpha;
1150                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1151                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1152
1153                                         // draw the outer ring to show the current charge of the weapon
1154                                         ring_value = nex_charge;
1155                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_nex_alpha;
1156                                         ring_rgb = wcross_color;
1157                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1158                                 }
1159                                 else if (activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1160                                 {
1161                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1162                                         ring_alpha = wcross_alpha * autocvar_crosshair_ring_minelayer_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring.tga";
1165                                 }
1166
1167                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1168                                 {
1169                                         // if the main ring is already used by another weapon, instead use the inner one for ammo.
1170                                         // inner ring is secondary anyway and doesn't matter as much as main ring, so overriding it is no issue.
1171                                         if(ring_value && autocvar_crosshair_ring_reload_inner)
1172                                         {
1173                                                 ring_inner_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1174                                                 ring_inner_alpha = autocvar_crosshair_ring_reload_alpha;
1175                                                 ring_inner_rgb = wcross_color;
1176                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1177                                         }
1178                                         else
1179                                         {
1180                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1181                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1182                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1183                                                 ring_rgb = wcross_color;
1184
1185                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1186                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1187                                                 if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1188                                                         ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1189                                                 else
1190                                                         ring_image = "gfx/crosshair_ring.tga";
1191                                         }
1192                                 }
1193
1194                                 if ((autocvar_crosshair_ring_inner || autocvar_crosshair_ring_reload_inner) && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1195                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, ring_inner_alpha, DRAWFLAG_ADDITIVE);
1196
1197                                 if (ring_value)
1198                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, ring_alpha, DRAWFLAG_ADDITIVE);
1199                         }
1200
1201 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1202                         do \
1203                         { \
1204                                 if(wcross_blur > 0) \
1205                                 { \
1206                                         for(i = -2; i <= 2; ++i) \
1207                                                 for(j = -2; j <= 2; ++j) \
1208                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1209                                 } \
1210                                 else \
1211                                 { \
1212                                         M(0,0,sz,wcross_name,wcross_alpha); \
1213                                 } \
1214                         } \
1215                         while(0)
1216
1217 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1218                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1219
1220 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1221                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1222
1223                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1224                         {
1225                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1226                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1227                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1228                                 f = 1 - f;
1229                         }
1230                         else
1231                         {
1232                                 f = 1;
1233                         }
1234
1235                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1236                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1237
1238                         if(autocvar_crosshair_dot)
1239             {
1240                 vector wcross_color_old;
1241                 wcross_color_old = wcross_color;
1242                 if(autocvar_crosshair_dot_color != "0")
1243                     wcross_color = stov(autocvar_crosshair_dot_color);
1244                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1245                 wcross_color = wcross_color_old;
1246             }
1247
1248                         wcross_name_alpha_goal_prev = f;
1249                 }
1250                 else
1251                 {
1252                         wcross_scale_prev = 0;
1253                         wcross_alpha_prev = 0;
1254                         wcross_scale_goal_prev = 0;
1255                         wcross_alpha_goal_prev = 0;
1256                         wcross_changedonetime = 0;
1257                         if(wcross_name_goal_prev)
1258                                 strunzone(wcross_name_goal_prev);
1259                         wcross_name_goal_prev = string_null;
1260                         if(wcross_name_goal_prev_prev)
1261                                 strunzone(wcross_name_goal_prev_prev);
1262                         wcross_name_goal_prev_prev = string_null;
1263                         wcross_name_changestarttime = 0;
1264                         wcross_name_changedonetime = 0;
1265                         wcross_name_alpha_goal_prev = 0;
1266                         wcross_name_alpha_goal_prev_prev = 0;
1267                         wcross_resolution_goal_prev = 0;
1268                         wcross_resolution_goal_prev_prev = 0;
1269                 }
1270         }
1271
1272         if(NextFrameCommand)
1273         {
1274                 localcmd("\n", NextFrameCommand, "\n");
1275                 NextFrameCommand = string_null;
1276         }
1277
1278         // we must do this check AFTER a frame was rendered, or it won't work
1279         if(cs_project_is_b0rked == 0)
1280         {
1281                 string w0, h0;
1282                 w0 = ftos(autocvar_vid_conwidth);
1283                 h0 = ftos(autocvar_vid_conheight);
1284                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1285                 //R_SetView(VF_FOV, '90 90 0');
1286                 R_SetView(VF_ORIGIN, '0 0 0');
1287                 R_SetView(VF_ANGLES, '0 0 0');
1288                 R_SetView(VF_PERSPECTIVE, 1);
1289                 makevectors('0 0 0');
1290                 vector v1, v2;
1291                 cvar_set("vid_conwidth", "800");
1292                 cvar_set("vid_conheight", "600");
1293                 v1 = cs_project(v_forward);
1294                 cvar_set("vid_conwidth", "640");
1295                 cvar_set("vid_conheight", "480");
1296                 v2 = cs_project(v_forward);
1297                 if(v1 == v2)
1298                         cs_project_is_b0rked = 1;
1299                 else
1300                         cs_project_is_b0rked = -1;
1301                 cvar_set("vid_conwidth", w0);
1302                 cvar_set("vid_conheight", h0);
1303         }
1304
1305         if(autocvar__hud_configure)
1306                 HUD_Panel_Mouse();
1307
1308         // let's reset the view back to normal for the end
1309         R_SetView(VF_MIN, '0 0 0');
1310         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1311 }
1312
1313 #define spider_h "gfx/vehicles/hud_bg.tga"
1314 #define spider_b "gfx/vehicles/sbot.tga"
1315 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1316 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1317 #define spider_s "gfx/vehicles/shiled.tga"
1318 #define spider_a1 "gfx/hud/sb_rocket.tga"
1319 #define spider_a2 "gfx/sb_bullets.tga"
1320
1321 void CSQC_SPIDER_HUD()
1322 {
1323         float rockets, reload, heat, hp, shield;
1324         vector picsize, hudloc;
1325
1326     // Fetch health & ammo stats
1327     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1328         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1329         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1330         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1331         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1332
1333     // Draw the crosshairs
1334     picsize = drawgetimagesize(SPIDER_CROSS);
1335     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1336     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1337     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1338
1339     hudloc_y =  4;
1340     hudloc_x = 4;
1341
1342     picsize = drawgetimagesize(spider_h) * 0.5;
1343     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1344
1345     picsize = drawgetimagesize(spider_a2) * 0.5;
1346     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1347
1348     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1349     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1350     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1351
1352     picsize = drawgetimagesize(spider_a1) * 0.85;
1353     if(rockets == 9)
1354     {
1355         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1356         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1357     }
1358     else
1359     {
1360         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1361         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1362     }
1363
1364     picsize = drawgetimagesize(spider_b) * 0.5;
1365     hudloc_y = 10.5;
1366     hudloc_x = 10.5;
1367
1368     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1369     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1370     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1371     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1372
1373
1374         /*
1375         // Draw health bar
1376         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1377         p = p + '0 1 0' * vid_conheight - '0 32 0';
1378         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1379         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1380         p_y += 8;
1381         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1382         p_x += 256 * hp;
1383         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1384
1385         // Draw minigun heat indicator
1386         p = '0.5 0 0' * (vid_conwidth - 256);
1387         p = p + '0 1 0' * vid_conheight - '0 34  0';
1388         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1389         p_x += 256 * (1-heat);
1390         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1391
1392
1393         // Draw rocket icons for loaded/empty tubes.
1394         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1395         pp += '0 1 0' * vid_conheight - '0 64 0';
1396         for(i = 0; i < 8; ++i)
1397         {
1398                 p = pp + '1 0 0' * (rkt_size * i);
1399                 if(rockets == 8)
1400                 {
1401                         if(floor(reload * 8) == i)
1402                         {
1403                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1404                         }
1405                         else if(i < reload * 8)
1406                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1407                         else
1408                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1409                 }
1410                 else
1411                 {
1412                         if(i < rockets)
1413                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1414                         else
1415                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1416                 }
1417         }
1418         */
1419
1420         if (scoreboard_showscores)
1421         {
1422                 HUD_DrawScoreboard();
1423                 HUD_DrawCenterPrint();
1424         }
1425
1426 }
1427
1428 #define raptor_h "gfx/vehicles/hud_bg.tga"
1429 #define raptor_b "gfx/vehicles/raptor.tga"
1430 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1431 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1432 #define raptor_s "gfx/vehicles/shiled.tga"
1433
1434 void CSQC_RAPTOR_HUD()
1435 {
1436         float reload, hp, shield, energy;
1437         vector picsize, hudloc;
1438
1439     // Fetch health & ammo stats
1440     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1441         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1442         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1443         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1444
1445     // Draw the crosshairs
1446     picsize = drawgetimagesize(SPIDER_CROSS);
1447     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1448     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1449     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1450
1451     hudloc_y =  4;
1452     hudloc_x = 4;
1453
1454     picsize = drawgetimagesize(raptor_h) * 0.5;
1455     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1456
1457     picsize = drawgetimagesize(spider_a2) * 0.5;
1458     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1459
1460     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1461     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1462     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1463
1464
1465     picsize = drawgetimagesize(spider_a1) * 0.85;
1466     if(reload == 1)
1467     {
1468         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1469         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1470     }
1471     else
1472     {
1473         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1474         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1475     }
1476
1477     picsize = drawgetimagesize(raptor_b) * 0.5;
1478     hudloc_y = 10.5;
1479     hudloc_x = 10.5;
1480
1481     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1482     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1483     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1484     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1485
1486
1487         if (scoreboard_showscores)
1488         {
1489                 HUD_DrawScoreboard();
1490                 HUD_DrawCenterPrint();
1491         }
1492
1493 }
1494
1495 #define waki_h "gfx/vehicles/hud_bg.tga"
1496 #define waki_b "gfx/vehicles/waki.tga"
1497 #define waki_e "gfx/vehicles/waki_e.tga"
1498 #define waki_g "gfx/vehicles/waki_guns.tga"
1499 #define waki_r "gfx/vehicles/waki_rockets.tga"
1500 #define waki_s "gfx/vehicles/shiled.tga"
1501
1502 #define waki_a1 "gfx/hud/sb_rocket.tga"
1503 #define waki_a2 "gfx/sb_cells.tga"
1504
1505 void CSQC_WAKIZASHI_HUD()
1506 {
1507         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1508         float health, shield, energy, rockets;
1509         vector picsize, hudloc;
1510
1511     picsize = drawgetimagesize(SPIDER_CROSS);
1512     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1513     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1514     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1515
1516 /*
1517 const float STAT_VEHICLESTAT_HEALTH  = 60;
1518 const float STAT_VEHICLESTAT_SHIELD  = 61;
1519 const float STAT_VEHICLESTAT_ENERGY  = 62;
1520 const float STAT_VEHICLESTAT_AMMO1   = 63;
1521 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1522 const float STAT_VEHICLESTAT_AMMO2   = 65;
1523 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1524 */
1525     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1526         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1527         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1528         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1529
1530     hudloc_y =  4;
1531     hudloc_x = 4;
1532
1533     picsize = drawgetimagesize(waki_h) * 0.5;
1534     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1535
1536     picsize = drawgetimagesize(waki_a2) * 0.7;
1537     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1538
1539
1540     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1541     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1542
1543     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1544
1545     picsize = drawgetimagesize(waki_a1) * 0.75;
1546     if(rockets == 1)
1547     {
1548         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1549         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1550     }
1551     else
1552     {
1553         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1554         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1555         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1556     }
1557
1558     picsize = drawgetimagesize(waki_b) * 0.5;
1559     hudloc_y = 10.5;
1560     hudloc_x = 10.5;
1561
1562     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1563     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1564     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1565     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1566
1567
1568
1569         /*
1570         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1571         p = p + '0 1 0' * vid_conheight - '0 32 0';
1572
1573         // Draw health bar
1574         p_y += 8;
1575         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1576         p_x += 256 * health;
1577         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1578
1579         // Draw shiled bar
1580         p_x -= 256 * health;
1581         p_y += 4;
1582         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1583
1584         // Draw energy
1585         //p_x -= 256 * health;
1586         p_y -= 8;
1587         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1588
1589         // Draw rockets bar
1590         p_y += 12;
1591         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1592         */
1593
1594
1595
1596
1597         if (scoreboard_showscores)
1598         {
1599                 HUD_DrawScoreboard();
1600                 HUD_DrawCenterPrint();
1601         }
1602
1603 }
1604
1605
1606 void CSQC_common_hud(void)
1607 {
1608         // HUD_SortFrags(); done in HUD_Draw
1609         float hud;
1610         hud = getstati(STAT_HUD);
1611
1612         //hud = 10;
1613         switch(hud)
1614         {
1615                 case HUD_NORMAL:
1616                         // do some accuracy var caching
1617                         float i;
1618                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1619                         {
1620                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1621                                 {
1622                                         if(acc_color_levels)
1623                                                 strunzone(acc_color_levels);
1624                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1625                                         acc_levels = tokenize(acc_color_levels);
1626                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1627                                                 acc_levels = MAX_ACCURACY_LEVELS;
1628
1629                                         for (i = 0; i < acc_levels; ++i)
1630                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1631                                 }
1632                                 // let know that acc_col[] needs to be loaded
1633                                 acc_col_x[0] = -1;
1634                         }
1635
1636                         HUD_Main(); // always run these functions for alpha checks
1637                         HUD_DrawScoreboard();
1638
1639                         if (scoreboard_active) // scoreboard/accuracy
1640                         {
1641                                 HUD_Reset();
1642                                 // HUD_DrawScoreboard takes care of centerprint_start
1643                         }
1644                         else if (intermission == 2) // map voting screen
1645                         {
1646                                 HUD_FinaleOverlay();
1647                                 HUD_Reset();
1648
1649                                 centerprint_start_x = 0;
1650                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1651                         }
1652                         else // hud
1653                         {
1654                                 centerprint_start_x = 0;
1655                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1656                         }
1657
1658                         HUD_DrawCenterPrint();
1659                         break;
1660
1661                 case HUD_SPIDERBOT:
1662                         CSQC_SPIDER_HUD();
1663                         break;
1664
1665                 case HUD_WAKIZASHI:
1666                         CSQC_WAKIZASHI_HUD();
1667                         break;
1668         }
1669 }
1670
1671
1672 // following vectors must be global to allow seamless switching between camera modes
1673 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1674 void CSQC_Demo_Camera()
1675 {
1676         float speed, attenuation, dimensions;
1677         vector tmp, delta;
1678
1679         if( autocvar_camera_reset || !camera_mode )
1680         {
1681                 camera_offset = '0 0 0';
1682                 current_angles = '0 0 0';
1683                 camera_direction = '0 0 0';
1684                 camera_offset_z += 30;
1685                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1686                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1687                 current_origin = view_origin;
1688                 current_camera_offset  = camera_offset;
1689                 cvar_set("camera_reset", "0");
1690                 camera_mode = CAMERA_CHASE;
1691         }
1692
1693         // Camera angles
1694         if( camera_roll )
1695                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1696
1697         if(autocvar_camera_look_player)
1698         {
1699                 local vector dir;
1700                 local float n;
1701
1702                 dir = normalize(view_origin - current_position);
1703                 n = mouse_angles_z;
1704                 mouse_angles = vectoangles(dir);
1705                 mouse_angles_x = mouse_angles_x * -1;
1706                 mouse_angles_z = n;
1707         }
1708         else
1709         {
1710                 tmp = getmousepos() * 0.1;
1711                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1712                 {
1713                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1714                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1715                 }
1716         }
1717
1718         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1719         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1720         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1721         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1722
1723         // Fix difference when angles don't have the same sign
1724         delta = '0 0 0';
1725         if(mouse_angles_y < -60 && current_angles_y > 60)
1726                 delta = '0 360 0';
1727         if(mouse_angles_y > 60 && current_angles_y < -60)
1728                 delta = '0 -360 0';
1729
1730         if(autocvar_camera_look_player)
1731                 attenuation = autocvar_camera_look_attenuation;
1732         else
1733                 attenuation = autocvar_camera_speed_attenuation;
1734
1735         attenuation = 1 / max(1, attenuation);
1736         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1737
1738         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1739         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1740         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1741         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1742
1743         // Camera position
1744         tmp = '0 0 0';
1745         dimensions = 0;
1746
1747         if( camera_direction_x )
1748         {
1749                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1750                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1751                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1752                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1753                 ++dimensions;
1754         }
1755
1756         if( camera_direction_y )
1757         {
1758                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1759                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1760                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1761                 ++dimensions;
1762         }
1763
1764         if( camera_direction_z )
1765         {
1766                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1767                 ++dimensions;
1768         }
1769
1770         if(autocvar_camera_free)
1771                 speed = autocvar_camera_speed_free;
1772         else
1773                 speed = autocvar_camera_speed_chase;
1774
1775         if(dimensions)
1776         {
1777                 speed = speed * sqrt(1 / dimensions);
1778                 camera_offset += tmp * speed;
1779         }
1780
1781         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1782
1783         // Camera modes
1784         if( autocvar_camera_free )
1785         {
1786                 if ( camera_mode == CAMERA_CHASE )
1787                 {
1788                         current_camera_offset = current_origin + current_camera_offset;
1789                         camera_offset = current_origin + camera_offset;
1790                 }
1791
1792                 camera_mode = CAMERA_FREE;
1793                 current_position = current_camera_offset;
1794         }
1795         else
1796         {
1797                 if ( camera_mode == CAMERA_FREE )
1798                 {
1799                         current_origin = view_origin;
1800                         camera_offset = camera_offset - current_origin;
1801                         current_camera_offset = current_camera_offset - current_origin;
1802                 }
1803
1804                 camera_mode = CAMERA_CHASE;
1805
1806                 if(autocvar_camera_chase_smoothly)
1807                         current_origin += (view_origin - current_origin) * attenuation;
1808                 else
1809                         current_origin = view_origin;
1810
1811                 current_position = current_origin + current_camera_offset;
1812         }
1813
1814         R_SetView(VF_ANGLES, current_angles);
1815         R_SetView(VF_ORIGIN, current_position);
1816 }