qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (mi_picmax_x - mi_picmin_x);
 206         float height = (mi_picmax_y - mi_picmin_y);
 207         float distance_to_middle_of_world = vlen(ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 322
 323         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 324         trueaimpoint = trace_endpos;
 325
 326         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 327                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 328
 329         if(vecs_x > 0)
 330                 vecs_y = -vecs_y;
 331         else
 332                 vecs = '0 0 0';
 333
 334         dv = view_right * vecs_y + view_up * vecs_z;
 335         w_shotorg = view_origin + dv;
 336
 337         // now move the vecs forward as much as requested if possible
 338         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 339         w_shotorg = trace_endpos - view_forward * nudge;
 340
 341         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 342         shottype = EnemyHitCheck();
 343         if(shottype != SHOTTYPE_HITWORLD)
 344                 return shottype;
 345
 346 #if 0
 347         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 348         // or rather, I know why, but see no fix
 349         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 350                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 351                 return SHOTTYPE_HITOBSTRUCTION;
 352 #endif
 353
 354         return SHOTTYPE_HITWORLD;
 355 }
 356
 357 void CSQC_common_hud(void);
 358
 359 void PostInit(void);
 360 void CSQC_Demo_Camera();
 361 float HUD_WouldDrawScoreboard();
 362 float camera_mode;
 363 const float CAMERA_FREE = 1;
 364 const float CAMERA_CHASE = 2;
 365 float reticle_type;
 366 string NextFrameCommand;
 367 void CSQC_SPIDER_HUD();
 368 void CSQC_RAPTOR_HUD();
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hit_time, typehit_time;
 376 float nextsound_hit_time, nextsound_typehit_time;
 377 float hitindication_crosshair_time, hitindication_crosshair_size;
 378 float use_nex_chargepool;
 379
 380 float myhealth, myhealth_prev;
 381 float myhealth_flash;
 382
 383 float old_blurradius, old_bluralpha;
 384 float old_sharpen_intensity;
 385
 386 vector myhealth_gentlergb;
 387
 388 float contentavgalpha, liquidalpha_prev;
 389 vector liquidcolor_prev;
 390
 391 float eventchase_current_distance;
 392
 393 vector damage_blurpostprocess, content_blurpostprocess;
 394
 395 float checkfail[16];
 396
 397 float rainbow_last_flicker;
 398 vector rainbow_prev_color;
 399 //float autocvar_cl_orthoview_distanceoverride;
 400 #define BUTTON_3 4
 401 #define BUTTON_4 8
 402 float cl_notice_run();
 403 float prev_myteam;
 404 void CSQC_UpdateView(float w, float h)
 405 {
 406         entity e;
 407         float fov;
 408         float f, i, j;
 409         vector v;
 410         vector vf_size, vf_min;
 411         float a;
 412
 413         execute_next_frame();
 414
 415         ++framecount;
 416
 417         hud = getstati(STAT_HUD);
 418
 419         if(autocvar__hud_showbinds_reload) // menu can set this one
 420         {
 421                 db_close(binddb);
 422                 binddb = db_create();
 423                 cvar_set("_hud_showbinds_reload", "0");
 424         }
 425
 426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 427                 view_quality = getproperty(VF_MINFPS_QUALITY);
 428         else
 429                 view_quality = 1;
 430
 431         button_attack2 = (input_buttons & BUTTON_3);
 432         button_zoom = (input_buttons & BUTTON_4);
 433
 434 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 435         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 436         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 437         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 438         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 439         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 440         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 441         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442
 443         vf_size = getpropertyvec(VF_SIZE);
 444         vf_min = getpropertyvec(VF_MIN);
 445         vid_width = vf_size_x;
 446         vid_height = vf_size_y;
 447
 448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 450
 451         WaypointSprite_Load();
 452
 453         CSQCPlayer_SetCamera();
 454
 455 #ifdef COMPAT_XON050_ENGINE
 456         if(spectatee_status)
 457                 myteam = GetPlayerColor(spectatee_status - 1);
 458         else
 459 #endif
 460                 myteam = GetPlayerColor(player_localentnum - 1);
 461
 462         if(myteam != prev_myteam)
 463         {
 464                 myteamcolors = colormapPaletteColor(myteam, 1);
 465                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 466                         hud_panel[i].update_time = time;
 467                 prev_myteam = myteam;
 468         }
 469
 470         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 471
 472         float is_dead = (getstati(STAT_HEALTH) <= 0);
 473
 474         // FIXME do we need this hack?
 475         if(isdemo())
 476         {
 477                 // in demos, input_buttons do not work
 478                 button_zoom = (autocvar__togglezoom == "-");
 479         }
 480         else if(button_zoom
 481                 && autocvar_cl_unpress_zoom_on_death
 482                 && (spectatee_status >= 0)
 483                 && (is_dead || intermission))
 484         {
 485                 // no zoom while dead or in intermission please
 486                 localcmd("-zoom\n");
 487                 button_zoom = FALSE;
 488         }
 489
 490         // event chase camera
 491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 492         {
 493                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 494                 {
 495                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 496                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 497
 498                         // detect maximum viewoffset and use it
 499                         if(autocvar_cl_eventchase_viewoffset)
 500                         {
 501                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 502                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 503                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 504                         }
 505
 506                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 507                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 508                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 509                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 510
 511                         // make the camera smooth back
 512                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 513                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 514                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 515                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 516
 517                         makevectors(view_angles);
 518
 519                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 520                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 521
 522                         // If the boxtrace fails, revert back to line tracing.
 523                         if(trace_startsolid)
 524                         {
 525                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 526                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 527                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 528                         }
 529                         else { setproperty(VF_ORIGIN, trace_endpos); }
 530
 531                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 532                 }
 533                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 534                 {
 535                         cvar_set("chase_active", "0");
 536                         eventchase_current_distance = 0; // start from 0 next time
 537                 }
 538         }
 539         // workaround for camera stuck between player's legs when using chase_active 1
 540         // because the engine stops updating the chase_active camera when the game ends
 541         else if(intermission)
 542         {
 543                 cvar_settemp("chase_active", "-1");
 544                 eventchase_current_distance = 0;
 545         }
 546
 547         // do lockview after event chase camera so that it still applies whenever necessary.
 548         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 549         {
 550                 setproperty(VF_ORIGIN, freeze_org);
 551                 setproperty(VF_ANGLES, freeze_ang);
 552         }
 553         else
 554         {
 555                 freeze_org = getpropertyvec(VF_ORIGIN);
 556                 freeze_ang = getpropertyvec(VF_ANGLES);
 557         }
 558
 559         WarpZone_FixView();
 560         //WarpZone_FixPMove();
 561
 562         vector ov_org = '0 0 0';
 563         if(autocvar_cl_orthoview)
 564         {
 565                 #define FL2VEC(x,y,z) (('1 0 0' * x) + ('0 1 0' * y) + ('0 0 1' * z))
 566
 567                 float ov_width = (mi_picmax_x - mi_picmin_x);
 568                 float ov_height = (mi_picmax_y - mi_picmin_y);
 569                 float ov_distance = (512 * max(ov_width, ov_height));
 570                 //if(autocvar_cl_orthoview_distanceoverride) { ov_distance = autocvar_cl_orthoview_distanceoverride; }
 571                 ov_org = ((mi_picmax + mi_picmin) * 0.5);
 572                 ov_org = FL2VEC(ov_org_x, ov_org_y, (ov_org_z * ov_distance));
 573
 574                 float ov_nearest = vlen(ov_org - FL2VEC(
 575                         bound(mi_picmin_x, ov_org_x, mi_picmax_x),
 576                         bound(mi_picmin_y, ov_org_y, mi_picmax_y),
 577                         bound(mi_picmin_z, ov_org_z, mi_picmax_z)
 578                 ));
 579
 580                 float ov_furthest = 0;
 581                 float dist = 0;
 582
 583                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmin_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 584                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmin_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 585                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmax_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 586                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmin_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 587                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmax_y, mi_picmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 588                 if((dist = vlen(FL2VEC(mi_picmin_x, mi_picmax_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 589                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmin_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 590                 if((dist = vlen(FL2VEC(mi_picmax_x, mi_picmax_y, mi_picmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 591
 592                 cvar_set("r_nearclip", ftos(ov_nearest));
 593                 cvar_set("r_farclip_base", ftos(ov_furthest));
 594                 cvar_set("r_farclip_world", "0");
 595                 cvar_set("r_useinfinitefarclip", "0");
 596
 597                 setproperty(VF_ORIGIN, ov_org);
 598                 setproperty(VF_ANGLES, '90 0 0');
 599         }
 600
 601         // Render the Scene
 602         view_origin = getpropertyvec(VF_ORIGIN);
 603         view_angles = getpropertyvec(VF_ANGLES);
 604         makevectors(view_angles);
 605         view_forward = v_forward;
 606         view_right = v_right;
 607         view_up = v_up;
 608
 609 #ifdef BLURTEST
 610         if(time > blurtest_time0 && time < blurtest_time1)
 611         {
 612                 float r, t;
 613
 614                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 615                 r = t * blurtest_radius;
 616                 f = 1 / pow(t, blurtest_power) - 1;
 617
 618                 cvar_set("r_glsl_postprocess", "1");
 619                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 620         }
 621         else
 622         {
 623                 cvar_set("r_glsl_postprocess", "0");
 624                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 625         }
 626 #endif
 627
 628         TargetMusic_Advance();
 629         Fog_Force();
 630
 631         if(drawtime == 0)
 632                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 633         else
 634                 drawframetime = bound(0.000001, time - drawtime, 1);
 635         drawtime = time;
 636
 637         // watch for gametype changes here...
 638         // in ParseStuffCMD the cmd isn't executed yet :/
 639         // might even be better to add the gametype to TE_CSQC_INIT...?
 640         if(!postinit)
 641                 PostInit();
 642
 643         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 644         {
 645                 if(calledhooks & HOOK_START)
 646                 {
 647                         localcmd("\ncl_hook_gameend\n");
 648                         calledhooks |= HOOK_END;
 649                 }
 650         }
 651
 652         Announcer();
 653
 654         fov = autocvar_fov;
 655         if(fov <= 59.5)
 656         {
 657                 if(!zoomscript_caught)
 658                 {
 659                         localcmd("+button9\n");
 660                         zoomscript_caught = 1;
 661                 }
 662         }
 663         else
 664         {
 665                 if(zoomscript_caught)
 666                 {
 667                         localcmd("-button9\n");
 668                         zoomscript_caught = 0;
 669                 }
 670         }
 671
 672         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 673
 674         // next WANTED weapon (for HUD)
 675         switchweapon = getstati(STAT_SWITCHWEAPON);
 676
 677         // currently switching-to weapon (for crosshair)
 678         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 679
 680         // actually active weapon (for zoom)
 681         activeweapon = getstati(STAT_ACTIVEWEAPON);
 682
 683         f = (serverflags & SERVERFLAG_TEAMPLAY);
 684         if(f != teamplay)
 685         {
 686                 teamplay = f;
 687                 HUD_InitScores();
 688         }
 689
 690         if(last_switchweapon != switchweapon)
 691         {
 692                 weapontime = time;
 693                 last_switchweapon = switchweapon;
 694                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 695                 {
 696                         localcmd("-zoom\n");
 697                         button_zoom = FALSE;
 698                 }
 699                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 700                 {
 701                         localcmd("-fire\n");
 702                         localcmd("-fire2\n");
 703                         button_attack2 = FALSE;
 704                 }
 705         }
 706         if(last_activeweapon != activeweapon)
 707         {
 708                 last_activeweapon = activeweapon;
 709
 710                 e = get_weaponinfo(activeweapon);
 711                 if(e.netname != "")
 712                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 713                 else
 714                         localcmd("\ncl_hook_activeweapon none\n");
 715         }
 716
 717         // ALWAYS Clear Current Scene First
 718         clearscene();
 719 #ifdef WORKAROUND_XON010
 720         if(checkextension("DP_CSQC_ROTATEMOVES"))
 721         {
 722 #endif
 723         setproperty(VF_ORIGIN, view_origin);
 724         setproperty(VF_ANGLES, view_angles);
 725 #ifdef WORKAROUND_XON010
 726         }
 727 #endif
 728
 729         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 730         setproperty(VF_SIZE, vf_size);
 731         setproperty(VF_MIN, vf_min);
 732
 733         // Assign Standard Viewflags
 734         // Draw the World (and sky)
 735         setproperty(VF_DRAWWORLD, 1);
 736
 737         // Set the console size vars
 738         vid_conwidth = autocvar_vid_conwidth;
 739         vid_conheight = autocvar_vid_conheight;
 740         vid_pixelheight = autocvar_vid_pixelheight;
 741
 742         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_org)); }
 743         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 744
 745         // Camera for demo playback
 746         if(camera_active)
 747         {
 748                 if(autocvar_camera_enable)
 749                         CSQC_Demo_Camera();
 750                 else
 751                 {
 752                         cvar_set("chase_active", ftos(chase_active_backup));
 753                         cvar_set("cl_demo_mousegrab", "0");
 754                         camera_active = FALSE;
 755                 }
 756         }
 757 #ifdef CAMERATEST
 758         else if(autocvar_camera_enable)
 759 #else
 760         else if(autocvar_camera_enable && isdemo())
 761 #endif
 762         {
 763                 // Enable required Darkplaces cvars
 764                 chase_active_backup = autocvar_chase_active;
 765                 cvar_set("chase_active", "2");
 766                 cvar_set("cl_demo_mousegrab", "1");
 767                 camera_active = TRUE;
 768                 camera_mode = FALSE;
 769         }
 770
 771         // Draw the Crosshair
 772         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 773
 774         // Draw the Engine Status Bar (the default Quake HUD)
 775         setproperty(VF_DRAWENGINESBAR, 0);
 776
 777         // Update the mouse position
 778         /*
 779            mousepos_x = vid_conwidth;
 780            mousepos_y = vid_conheight;
 781            mousepos = mousepos*0.5 + getmousepos();
 782          */
 783
 784         e = self;
 785         for(self = world; (self = nextent(self)); )
 786                 if(self.draw)
 787                         self.draw();
 788         self = e;
 789
 790         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 791         renderscene();
 792
 793         // now switch to 2D drawing mode by calling a 2D drawing function
 794         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 795         // next R_RenderScene call
 796         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 797
 798         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 799         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 800         {
 801                 // apply night vision effect
 802                 vector tc_00, tc_01, tc_10, tc_11;
 803                 vector rgb;
 804                 rgb_x = 0; // fteqcc sucks
 805                 rgb_y = 0; // fteqcc sucks
 806                 rgb_z = 0; // fteqcc sucks
 807
 808                 if(!nightvision_noise)
 809                 {
 810                         nightvision_noise = spawn();
 811                         nightvision_noise.classname = "nightvision_noise";
 812                 }
 813                 if(!nightvision_noise2)
 814                 {
 815                         nightvision_noise2 = spawn();
 816                         nightvision_noise2.classname = "nightvision_noise2";
 817                 }
 818
 819                 // color tint in yellow
 820                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 821
 822                 // draw BG
 823                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 824                 rgb = '1 1 1';
 825                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 826                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 827                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 828                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 829                 tc_11 = tc_01 + tc_10 - tc_00;
 830                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 831                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 832                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 833                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 834                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 835                 R_EndPolygon();
 836
 837                 // draw FG
 838                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 839                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 840                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 841                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 842                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 843                 tc_11 = tc_01 + tc_10 - tc_00;
 844                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 845                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 846                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 847                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 848                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 849                 R_EndPolygon();
 850         }
 851
 852         // Draw the aiming reticle for weapons that use it
 853         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 854         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 855         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 856         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 857                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 858         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 859                 reticle_type = 2; // nex zoom
 860         else if(button_zoom || zoomscript_caught)
 861                 reticle_type = 1; // normal zoom
 862         else if((activeweapon == WEP_NEX) && button_attack2)
 863                 reticle_type = 2; // nex zoom
 864
 865         if(reticle_type && autocvar_cl_reticle)
 866         {
 867                 if(autocvar_cl_reticle_stretch)
 868                 {
 869                         reticle_size_x = vid_conwidth;
 870                         reticle_size_y = vid_conheight;
 871                         reticle_pos_x = 0;
 872                         reticle_pos_y = 0;
 873                 }
 874                 else
 875                 {
 876                         reticle_size_x = max(vid_conwidth, vid_conheight);
 877                         reticle_size_y = max(vid_conwidth, vid_conheight);
 878                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 879                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 880                 }
 881
 882                 f = current_zoomfraction;
 883                 if(zoomscript_caught)
 884                         f = 1;
 885                 if(autocvar_cl_reticle_item_normal)
 886                 {
 887                         if(reticle_type == 1 && f)
 888                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 889                 }
 890                 if(autocvar_cl_reticle_item_nex)
 891                 {
 892                         if(reticle_type == 2 && f)
 893                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 894                 }
 895         }
 896
 897
 898         // improved polyblend
 899         if(autocvar_hud_contents)
 900         {
 901                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 902                 vector liquidcolor;
 903
 904                 switch(pointcontents(view_origin))
 905                 {
 906                         case CONTENT_WATER:
 907                                 liquidalpha = autocvar_hud_contents_water_alpha;
 908                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 909                                 incontent = 1;
 910                                 break;
 911
 912                         case CONTENT_LAVA:
 913                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 914                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 915                                 incontent = 1;
 916                                 break;
 917
 918                         case CONTENT_SLIME:
 919                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 920                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 921                                 incontent = 1;
 922                                 break;
 923
 924                         default:
 925                                 liquidalpha = 0;
 926                                 liquidcolor = '0 0 0';
 927                                 incontent = 0;
 928                                 break;
 929                 }
 930
 931                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 932                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 933                         contentfadetime = autocvar_hud_contents_fadeintime;
 934                         liquidalpha_prev = liquidalpha;
 935                         liquidcolor_prev = liquidcolor;
 936                 }
 937                 else
 938                         contentfadetime = autocvar_hud_contents_fadeouttime;
 939
 940                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 941                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 942
 943                 if(contentavgalpha)
 944                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 945
 946                 if(autocvar_hud_postprocessing)
 947                 {
 948                         if(autocvar_hud_contents_blur && contentavgalpha)
 949                         {
 950                                 content_blurpostprocess_x = 1;
 951                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 952                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 953                         }
 954                         else
 955                         {
 956                                 content_blurpostprocess_x = 0;
 957                                 content_blurpostprocess_y = 0;
 958                                 content_blurpostprocess_z = 0;
 959                         }
 960                 }
 961         }
 962
 963         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 964         {
 965                 splash_size_x = max(vid_conwidth, vid_conheight);
 966                 splash_size_y = max(vid_conwidth, vid_conheight);
 967                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 968                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 969
 970                 float myhealth_flash_temp;
 971                 myhealth = getstati(STAT_HEALTH);
 972
 973                 // fade out
 974                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 975                 // add new damage
 976                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 977
 978                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 979                 pain_threshold = autocvar_hud_damage_pain_threshold;
 980                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 981                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 982
 983                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 984                 {
 985                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 986                 }
 987
 988                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 989
 990                 if(myhealth_prev < 1)
 991                 {
 992                         if(myhealth >= 1)
 993                         {
 994                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 995                                 myhealth_flash_temp = 0;
 996                         }
 997                         else
 998                         {
 999                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1000                         }
1001                 }
1002
1003                 if(spectatee_status == -1 || intermission)
1004                 {
1005                         myhealth_flash = 0; // observing, or match ended
1006                         myhealth_flash_temp = 0;
1007                 }
1008
1009                 myhealth_prev = myhealth;
1010
1011                 // IDEA: change damage color/picture based on player model for robot/alien species?
1012                 // pro: matches model better
1013                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1014                 // maybe different reddish pics?
1015                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1016                 {
1017                         if(autocvar_cl_gentle_damage == 2)
1018                         {
1019                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1020                                 {
1021                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1022                                 }
1023                         }
1024                         else
1025                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1026
1027                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1028                 }
1029                 else
1030                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1031
1032                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1033                 {
1034                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1035                         {
1036                                 damage_blurpostprocess_x = 1;
1037                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1038                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1039                         }
1040                         else
1041                         {
1042                                 damage_blurpostprocess_x = 0;
1043                                 damage_blurpostprocess_y = 0;
1044                                 damage_blurpostprocess_z = 0;
1045                         }
1046                 }
1047         }
1048
1049         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1050         float e2 = (autocvar_hud_powerup != 0);
1051         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1052         {
1053                 // enable or disable rendering types if they are used or not
1054                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1055                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1056
1057                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1058                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1059                 {
1060                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1061                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1062                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1063                         {
1064                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1065                                 old_blurradius = blurradius;
1066                                 old_bluralpha = bluralpha;
1067                         }
1068                 }
1069                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1070                 {
1071                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1072                         old_blurradius = 0;
1073                         old_bluralpha = 0;
1074                 }
1075
1076                 // edge detection postprocess handling done second (used by hud_powerup)
1077                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1078                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1079                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1080
1081                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1082
1083                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1084                 {
1085                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1086                         {
1087                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1088                                 old_sharpen_intensity = sharpen_intensity;
1089                         }
1090                 }
1091                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1092                 {
1093                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1094                         old_sharpen_intensity = 0;
1095                 }
1096
1097                 if(cvar("r_glsl_postprocess") == 0)
1098                         cvar_set("r_glsl_postprocess", "2");
1099         }
1100         else if(cvar("r_glsl_postprocess") == 2)
1101                 cvar_set("r_glsl_postprocess", "0");
1102
1103         if(menu_visible)
1104                 menu_show();
1105
1106         /*if(gametype == MAPINFO_TYPE_CTF)
1107           {
1108           ctf_view();
1109           } else */
1110
1111         // draw 2D entities
1112         e = self;
1113         for(self = world; (self = nextent(self)); )
1114                 if(self.draw2d)
1115                         self.draw2d();
1116         self = e;
1117         Draw_ShowNames_All();
1118
1119         scoreboard_active = HUD_WouldDrawScoreboard();
1120
1121         hit_time = getstatf(STAT_HIT_TIME);
1122         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1123         {
1124                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1125                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1126
1127                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1128         }
1129         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1130         if(typehit_time > nextsound_typehit_time)
1131         {
1132                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1133                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1134
1135                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1136         }
1137
1138         //else
1139         {
1140                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1141                 {
1142                         if(getstati(STAT_FROZEN))
1143                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1144                         if(getstatf(STAT_REVIVE_PROGRESS))
1145                         {
1146                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1147                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1148                         }
1149                 }
1150
1151                 if(autocvar_r_letterbox == 0)
1152                         if(autocvar_viewsize < 120)
1153                                 CSQC_common_hud();
1154
1155                 // crosshair goes VERY LAST
1156                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1157                 {
1158                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1159                                 return;
1160
1161                         string wcross_style;
1162                         float wcross_alpha, wcross_resolution;
1163                         wcross_style = autocvar_crosshair;
1164                         if (wcross_style == "0")
1165                                 return;
1166                         wcross_resolution = autocvar_crosshair_size;
1167                         if (wcross_resolution == 0)
1168                                 return;
1169                         wcross_alpha = autocvar_crosshair_alpha;
1170                         if (wcross_alpha == 0)
1171                                 return;
1172
1173                         // TrueAim check
1174                         float shottype;
1175
1176                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1177                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1178                         wcross_origin_z = 0;
1179                         if(autocvar_crosshair_hittest)
1180                         {
1181                                 vector wcross_oldorigin;
1182                                 wcross_oldorigin = wcross_origin;
1183                                 shottype = TrueAimCheck();
1184                                 if(shottype == SHOTTYPE_HITWORLD)
1185                                 {
1186                                         v = wcross_origin - wcross_oldorigin;
1187                                         v_x /= vid_conwidth;
1188                                         v_y /= vid_conheight;
1189                                         if(vlen(v) > 0.01)
1190                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1191                                 }
1192                                 if(!autocvar_crosshair_hittest_showimpact)
1193                                         wcross_origin = wcross_oldorigin;
1194                         }
1195                         else
1196                                 shottype = SHOTTYPE_HITWORLD;
1197
1198                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1199                         string wcross_wep = "", wcross_name;
1200                         float wcross_scale, wcross_blur;
1201
1202                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1203                         {
1204                                 e = get_weaponinfo(switchingweapon);
1205                                 if (e && e.netname != "")
1206                                 {
1207                                         wcross_wep = e.netname;
1208                                         if(autocvar_crosshair_per_weapon)
1209                                         {
1210                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1211                                                 if (wcross_resolution == 0)
1212                                                         return;
1213                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1214                                                 if (wcross_alpha == 0)
1215                                                         return;
1216
1217                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1218                                                 if(wcross_style == "" || wcross_style == "0")
1219                                                         wcross_style = wcross_wep;
1220                                         }
1221                                 }
1222                         }
1223
1224                         //print(sprintf("crosshair style: %s\n", wcross_style));
1225                         wcross_name = strcat("gfx/crosshair", wcross_style);
1226
1227                         // MAIN CROSSHAIR COLOR DECISION
1228                         switch(autocvar_crosshair_color_special)
1229                         {
1230                                 case 1: // crosshair_color_per_weapon
1231                                 {
1232                                         if(wcross_wep != "")
1233                                         {
1234                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1235                                                 break;
1236                                         }
1237                                         else { goto normalcolor; }
1238                                 }
1239
1240                                 case 2: // crosshair_color_by_health
1241                                 {
1242                                         float x = getstati(STAT_HEALTH);
1243
1244                                         //x = red
1245                                         //y = green
1246                                         //z = blue
1247
1248                                         wcross_color_z = 0;
1249
1250                                         if(x > 200)
1251                                         {
1252                                                 wcross_color_x = 0;
1253                                                 wcross_color_y = 1;
1254                                         }
1255                                         else if(x > 150)
1256                                         {
1257                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1258                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1259                                         }
1260                                         else if(x > 100)
1261                                         {
1262                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1263                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1264                                                 wcross_color_z = 1 - (x-100)*0.02;
1265                                         }
1266                                         else if(x > 50)
1267                                         {
1268                                                 wcross_color_x = 1;
1269                                                 wcross_color_y = 1;
1270                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1271                                         }
1272                                         else if(x > 20)
1273                                         {
1274                                                 wcross_color_x = 1;
1275                                                 wcross_color_y = (x-20)*90/27/100;
1276                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1277                                         }
1278                                         else
1279                                         {
1280                                                 wcross_color_x = 1;
1281                                                 wcross_color_y = 0;
1282                                         }
1283                                         break;
1284                                 }
1285
1286                                 case 3: // crosshair_color_rainbow
1287                                 {
1288                                         if(time >= rainbow_last_flicker)
1289                                         {
1290                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1291                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1292                                         }
1293                                         wcross_color = rainbow_prev_color;
1294                                         break;
1295                                 }
1296                                 :normalcolor
1297                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1298                         }
1299
1300                         if(autocvar_crosshair_effect_scalefade)
1301                         {
1302                                 wcross_scale = wcross_resolution;
1303                                 wcross_resolution = 1;
1304                         }
1305                         else
1306                         {
1307                                 wcross_scale = 1;
1308                         }
1309
1310                         if(autocvar_crosshair_pickup)
1311                         {
1312                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1313
1314                                 if(pickup_crosshair_time < stat_pickup_time)
1315                                 {
1316                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1317                                                 pickup_crosshair_size = 1;
1318
1319                                         pickup_crosshair_time = stat_pickup_time;
1320                                 }
1321
1322                                 if(pickup_crosshair_size > 0)
1323                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1324                                 else
1325                                         pickup_crosshair_size = 0;
1326
1327                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1328                         }
1329
1330                         if(autocvar_crosshair_hitindication)
1331                         {
1332                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1333
1334                                 if(hitindication_crosshair_time < hit_time)
1335                                 {
1336                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1337                                                 hitindication_crosshair_size = 1;
1338
1339                                         hitindication_crosshair_time = hit_time;
1340                                 }
1341
1342                                 if(hitindication_crosshair_size > 0)
1343                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1344                                 else
1345                                         hitindication_crosshair_size = 0;
1346
1347                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1348                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1349                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1350                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1351                         }
1352
1353                         if(shottype == SHOTTYPE_HITENEMY)
1354                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1355                         if(shottype == SHOTTYPE_HITTEAM)
1356                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1357
1358                         f = fabs(autocvar_crosshair_effect_time);
1359                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1360                         {
1361                                 wcross_changedonetime = time + f;
1362                         }
1363                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1364                         {
1365                                 wcross_name_changestarttime = time;
1366                                 wcross_name_changedonetime = time + f;
1367                                 if(wcross_name_goal_prev_prev)
1368                                         strunzone(wcross_name_goal_prev_prev);
1369                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1370                                 wcross_name_goal_prev = strzone(wcross_name);
1371                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1372                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1373                                 wcross_resolution_goal_prev = wcross_resolution;
1374                         }
1375
1376                         wcross_scale_goal_prev = wcross_scale;
1377                         wcross_alpha_goal_prev = wcross_alpha;
1378                         wcross_color_goal_prev = wcross_color;
1379
1380                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1381                         {
1382                                 wcross_blur = 1;
1383                                 wcross_alpha *= 0.75;
1384                         }
1385                         else
1386                                 wcross_blur = 0;
1387                         // *_prev is at time-frametime
1388                         // * is at wcross_changedonetime+f
1389                         // what do we have at time?
1390                         if(time < wcross_changedonetime)
1391                         {
1392                                 f = frametime / (wcross_changedonetime - time + frametime);
1393                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1394                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1395                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1396                         }
1397
1398                         wcross_scale_prev = wcross_scale;
1399                         wcross_alpha_prev = wcross_alpha;
1400                         wcross_color_prev = wcross_color;
1401
1402                         wcross_scale *= 1 - autocvar__menu_alpha;
1403                         wcross_alpha *= 1 - autocvar__menu_alpha;
1404                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1405
1406                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1407                         {
1408                                 // crosshair rings for weapon stats
1409                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1410                                 {
1411                                         // declarations and stats
1412                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1413                                         string ring_image = string_null, ring_inner_image = string_null;
1414                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1415
1416                                         ring_scale = autocvar_crosshair_ring_size;
1417
1418                                         float weapon_clipload, weapon_clipsize;
1419                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1420                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1421
1422                                         float nex_charge, nex_chargepool;
1423                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1424                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1425
1426                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1427                                                 nex_charge_movingavg = nex_charge;
1428
1429
1430                                         // handle the values
1431                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1432                                         {
1433                                                 if (nex_chargepool || use_nex_chargepool) {
1434                                                         use_nex_chargepool = 1;
1435                                                         ring_inner_value = nex_chargepool;
1436                                                 } else {
1437                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1438                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1439                                                 }
1440
1441                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1442                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1443                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1444
1445                                                 // draw the outer ring to show the current charge of the weapon
1446                                                 ring_value = nex_charge;
1447                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1448                                                 ring_rgb = wcross_color;
1449                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1450                                         }
1451                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1452                                         {
1453                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1454                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1455                                                 ring_rgb = wcross_color;
1456                                                 ring_image = "gfx/crosshair_ring.tga";
1457                                         }
1458                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1459                                         {
1460                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1461                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1462                                                 ring_rgb = wcross_color;
1463                                                 ring_image = "gfx/crosshair_ring.tga";
1464                                         }
1465
1466                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1467                                         {
1468                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1469                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1470                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1471                                                 ring_rgb = wcross_color;
1472
1473                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1474                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1475                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1476                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1477                                                 else
1478                                                         ring_image = "gfx/crosshair_ring.tga";
1479                                         }
1480
1481                                         // if in weapon switch animation, fade ring out/in
1482                                         if(autocvar_crosshair_effect_time > 0)
1483                                         {
1484                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1485                                                 if not(f < 1)
1486                                                 {
1487                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1488                                                 }
1489
1490                                                 if(wcross_ring_prev)
1491                                                 {
1492                                                         if(f < 1)
1493                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1494                                                 }
1495                                                 else
1496                                                 {
1497                                                         if(f < 1)
1498                                                                 ring_alpha *= bound(0, f, 1);
1499                                                 }
1500                                         }
1501
1502                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1503                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1504
1505                                         if (ring_value)
1506                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1507                                 }
1508
1509 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1510                                 do \
1511                                 { \
1512                                         if(wcross_blur > 0) \
1513                                         { \
1514                                                 for(i = -2; i <= 2; ++i) \
1515                                                 for(j = -2; j <= 2; ++j) \
1516                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1517                                         } \
1518                                         else \
1519                                         { \
1520                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1521                                         } \
1522                                 } \
1523                                 while(0)
1524
1525 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1526                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1527
1528 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1529                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1530
1531                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1532                                 {
1533                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1534                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1535                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1536                                         f = 1 - f;
1537                                 }
1538                                 else
1539                                 {
1540                                         f = 1;
1541                                 }
1542                                 wcross_name_alpha_goal_prev = f;
1543
1544                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1545                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1546
1547                                 if(autocvar_crosshair_dot)
1548                                 {
1549                                         vector wcross_color_old;
1550                                         wcross_color_old = wcross_color;
1551
1552                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1553                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1554
1555                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1556                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1557                                         wcross_color = wcross_color_old;
1558                                 }
1559                         }
1560                 }
1561                 else
1562                 {
1563                         wcross_scale_prev = 0;
1564                         wcross_alpha_prev = 0;
1565                         wcross_scale_goal_prev = 0;
1566                         wcross_alpha_goal_prev = 0;
1567                         wcross_changedonetime = 0;
1568                         if(wcross_name_goal_prev)
1569                                 strunzone(wcross_name_goal_prev);
1570                         wcross_name_goal_prev = string_null;
1571                         if(wcross_name_goal_prev_prev)
1572                                 strunzone(wcross_name_goal_prev_prev);
1573                         wcross_name_goal_prev_prev = string_null;
1574                         wcross_name_changestarttime = 0;
1575                         wcross_name_changedonetime = 0;
1576                         wcross_name_alpha_goal_prev = 0;
1577                         wcross_name_alpha_goal_prev_prev = 0;
1578                         wcross_resolution_goal_prev = 0;
1579                         wcross_resolution_goal_prev_prev = 0;
1580                 }
1581         }
1582
1583         if(NextFrameCommand)
1584         {
1585                 localcmd("\n", NextFrameCommand, "\n");
1586                 NextFrameCommand = string_null;
1587         }
1588
1589         // we must do this check AFTER a frame was rendered, or it won't work
1590         if(cs_project_is_b0rked == 0)
1591         {
1592                 string w0, h0;
1593                 w0 = ftos(autocvar_vid_conwidth);
1594                 h0 = ftos(autocvar_vid_conheight);
1595                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1596                 //setproperty(VF_FOV, '90 90 0');
1597                 setproperty(VF_ORIGIN, '0 0 0');
1598                 setproperty(VF_ANGLES, '0 0 0');
1599                 setproperty(VF_PERSPECTIVE, 1);
1600                 makevectors('0 0 0');
1601                 vector v1, v2;
1602                 cvar_set("vid_conwidth", "800");
1603                 cvar_set("vid_conheight", "600");
1604                 v1 = cs_project(v_forward);
1605                 cvar_set("vid_conwidth", "640");
1606                 cvar_set("vid_conheight", "480");
1607                 v2 = cs_project(v_forward);
1608                 if(v1 == v2)
1609                         cs_project_is_b0rked = 1;
1610                 else
1611                         cs_project_is_b0rked = -1;
1612                 cvar_set("vid_conwidth", w0);
1613                 cvar_set("vid_conheight", h0);
1614         }
1615
1616         if(autocvar__hud_configure)
1617                 HUD_Panel_Mouse();
1618
1619     if(hud && !intermission)
1620     {
1621         if(hud == HUD_SPIDERBOT)
1622             CSQC_SPIDER_HUD();
1623         else if(hud == HUD_WAKIZASHI)
1624             CSQC_WAKIZASHI_HUD();
1625         else if(hud == HUD_RAPTOR)
1626             CSQC_RAPTOR_HUD();
1627         else if(hud == HUD_BUMBLEBEE)
1628             CSQC_BUMBLE_HUD();
1629         else if(hud == HUD_BUMBLEBEE_GUN)
1630             CSQC_BUMBLE_GUN_HUD();
1631     }
1632
1633         cl_notice_run();
1634
1635         // let's reset the view back to normal for the end
1636         setproperty(VF_MIN, '0 0 0');
1637         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1638 }
1639
1640
1641 void CSQC_common_hud(void)
1642 {
1643         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1644                 Accuracy_LoadLevels();
1645
1646     HUD_Main(); // always run these functions for alpha checks
1647     HUD_DrawScoreboard();
1648
1649     if (scoreboard_active) // scoreboard/accuracy
1650         HUD_Reset();
1651     else if (intermission == 2) // map voting screen
1652     {
1653         HUD_FinaleOverlay();
1654         HUD_Reset();
1655     }
1656         /*
1657         switch(hud)
1658         {
1659                 case HUD_SPIDERBOT:
1660                         CSQC_SPIDER_HUD();
1661                         break;
1662
1663                 case HUD_WAKIZASHI:
1664                         CSQC_WAKIZASHI_HUD();
1665                         break;
1666
1667         case HUD_BUMBLEBEE:
1668             CSQC_BUMBLE_HUD();
1669             break;
1670         }
1671         */
1672 }
1673
1674
1675 // following vectors must be global to allow seamless switching between camera modes
1676 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1677 void CSQC_Demo_Camera()
1678 {
1679         float speed, attenuation, dimensions;
1680         vector tmp, delta;
1681
1682         if( autocvar_camera_reset || !camera_mode )
1683         {
1684                 camera_offset = '0 0 0';
1685                 current_angles = '0 0 0';
1686                 camera_direction = '0 0 0';
1687                 camera_offset_z += 30;
1688                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1689                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1690                 current_origin = view_origin;
1691                 current_camera_offset  = camera_offset;
1692                 cvar_set("camera_reset", "0");
1693                 camera_mode = CAMERA_CHASE;
1694         }
1695
1696         // Camera angles
1697         if( camera_roll )
1698                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1699
1700         if(autocvar_camera_look_player)
1701         {
1702                 vector dir;
1703                 float n;
1704
1705                 dir = normalize(view_origin - current_position);
1706                 n = mouse_angles_z;
1707                 mouse_angles = vectoangles(dir);
1708                 mouse_angles_x = mouse_angles_x * -1;
1709                 mouse_angles_z = n;
1710         }
1711         else
1712         {
1713                 tmp = getmousepos() * 0.1;
1714                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1715                 {
1716                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1717                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1718                 }
1719         }
1720
1721         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1722         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1723         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1724         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1725
1726         // Fix difference when angles don't have the same sign
1727         delta = '0 0 0';
1728         if(mouse_angles_y < -60 && current_angles_y > 60)
1729                 delta = '0 360 0';
1730         if(mouse_angles_y > 60 && current_angles_y < -60)
1731                 delta = '0 -360 0';
1732
1733         if(autocvar_camera_look_player)
1734                 attenuation = autocvar_camera_look_attenuation;
1735         else
1736                 attenuation = autocvar_camera_speed_attenuation;
1737
1738         attenuation = 1 / max(1, attenuation);
1739         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1740
1741         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1742         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1743         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1744         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1745
1746         // Camera position
1747         tmp = '0 0 0';
1748         dimensions = 0;
1749
1750         if( camera_direction_x )
1751         {
1752                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1753                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1754                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1755                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1756                 ++dimensions;
1757         }
1758
1759         if( camera_direction_y )
1760         {
1761                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1762                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1763                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1764                 ++dimensions;
1765         }
1766
1767         if( camera_direction_z )
1768         {
1769                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1770                 ++dimensions;
1771         }
1772
1773         if(autocvar_camera_free)
1774                 speed = autocvar_camera_speed_free;
1775         else
1776                 speed = autocvar_camera_speed_chase;
1777
1778         if(dimensions)
1779         {
1780                 speed = speed * sqrt(1 / dimensions);
1781                 camera_offset += tmp * speed;
1782         }
1783
1784         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1785
1786         // Camera modes
1787         if( autocvar_camera_free )
1788         {
1789                 if ( camera_mode == CAMERA_CHASE )
1790                 {
1791                         current_camera_offset = current_origin + current_camera_offset;
1792                         camera_offset = current_origin + camera_offset;
1793                 }
1794
1795                 camera_mode = CAMERA_FREE;
1796                 current_position = current_camera_offset;
1797         }
1798         else
1799         {
1800                 if ( camera_mode == CAMERA_FREE )
1801                 {
1802                         current_origin = view_origin;
1803                         camera_offset = camera_offset - current_origin;
1804                         current_camera_offset = current_camera_offset - current_origin;
1805                 }
1806
1807                 camera_mode = CAMERA_CHASE;
1808
1809                 if(autocvar_camera_chase_smoothly)
1810                         current_origin += (view_origin - current_origin) * attenuation;
1811                 else
1812                         current_origin = view_origin;
1813
1814                 current_position = current_origin + current_camera_offset;
1815         }
1816
1817         setproperty(VF_ANGLES, current_angles);
1818         setproperty(VF_ORIGIN, current_position);
1819 }