qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 float checkfail[16];
 372
 373 void CSQC_UpdateView(float w, float h)
 374 {
 375         entity e;
 376         float fov;
 377         float f, i, j;
 378         vector v, vo;
 379         vector vf_size, vf_min;
 380         float a;
 381
 382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 389
 390         vf_size = R_SetView3fv(VF_SIZE);
 391         vf_min = R_SetView3fv(VF_MIN);
 392         vid_width = vf_size_x;
 393         vid_height = vf_size_y;
 394
 395         vector reticle_pos, reticle_size;
 396         vector splash_pos, splash_size;
 397
 398         WaypointSprite_Load();
 399
 400         if(spectatee_status)
 401                 myteam = GetPlayerColor(spectatee_status - 1);
 402         else
 403                 myteam = GetPlayerColor(player_localentnum - 1);
 404
 405         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 406         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 407
 408         warpzone_fixview_origin = pmove_org + vo;
 409         warpzone_fixview_cl_viewangles = input_angles;
 410         warpzone_fixview_angles = view_angles;
 411         WarpZone_FixView();
 412         pmove_org = warpzone_fixview_origin - vo;
 413         input_angles = warpzone_fixview_cl_viewangles;
 414         view_angles = warpzone_fixview_angles;
 415
 416         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 417         {
 418                 pmove_org = freeze_pmove_org;
 419                 input_angles = view_angles = freeze_input_angles;
 420                 R_SetView(VF_ORIGIN, pmove_org + vo);
 421                 R_SetView(VF_ANGLES, view_angles);
 422                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 423         }
 424         freeze_pmove_org = pmove_org;
 425         freeze_input_angles = input_angles;
 426
 427         // event chase camera
 428         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 429         {
 430                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_eventchase_intermission && intermission))
 431                 {
 432                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 433                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 434                         if(!autocvar_chase_active)
 435                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 436
 437                         // make the camera smooth back
 438                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 439                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 440                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 441                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 442
 443                         vector eventchase_target_origin;
 444                         makevectors(view_angles);
 445                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 446                         eventchase_target_origin = pmove_org - view_forward * eventchase_current_distance;
 447
 448                         traceline(pmove_org, eventchase_target_origin, MOVE_NORMAL, self);
 449                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 450                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 451                         eventchase_target_origin = pmove_org - view_forward * eventchase_current_distance * (trace_fraction - 0.1);
 452
 453                         R_SetView(VF_ORIGIN, eventchase_target_origin);
 454                 }
 455                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 456                 {
 457                         cvar_set("chase_active", "0");
 458                         eventchase_current_distance = 0; // start from 0 next time
 459                 }
 460         }
 461
 462         // Render the Scene
 463         if(!intermission || !view_set || (intermission && autocvar_cl_eventchase_intermission))
 464         {
 465                 view_origin = pmove_org + vo;
 466                 view_angles = input_angles;
 467                 makevectors(view_angles);
 468                 view_forward = v_forward;
 469                 view_right = v_right;
 470                 view_up = v_up;
 471                 view_set = 1;
 472         }
 473
 474 #ifdef BLURTEST
 475         if(time > blurtest_time0 && time < blurtest_time1)
 476         {
 477                 float r, t;
 478
 479                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 480                 r = t * blurtest_radius;
 481                 f = 1 / pow(t, blurtest_power) - 1;
 482
 483                 cvar_set("r_glsl_postprocess", "1");
 484                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 485         }
 486         else
 487         {
 488                 cvar_set("r_glsl_postprocess", "0");
 489                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 490         }
 491 #endif
 492
 493         TargetMusic_Advance();
 494         Fog_Force();
 495
 496         drawframetime = max(0.000001, time - drawtime);
 497         drawtime = time;
 498
 499         // watch for gametype changes here...
 500         // in ParseStuffCMD the cmd isn't executed yet :/
 501         // might even be better to add the gametype to TE_CSQC_INIT...?
 502         if(!postinit)
 503                 PostInit();
 504
 505         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 506                 if(calledhooks & HOOK_START)
 507                 {
 508                         localcmd("\ncl_hook_gameend\n");
 509                         calledhooks |= HOOK_END;
 510                 }
 511
 512         CheckForGamestartChange();
 513         serverAnnouncer();
 514         maptimeAnnouncer();
 515         carrierAnnouncer();
 516
 517         fov = autocvar_fov;
 518         if(button_zoom || fov <= 59.5)
 519         {
 520                 if(!zoomscript_caught)
 521                 {
 522                         localcmd("+button4\n");
 523                         zoomscript_caught = 1;
 524                         ignore_plus_zoom += 1;
 525                 }
 526         }
 527         else
 528         {
 529                 if(zoomscript_caught)
 530                 {
 531                         localcmd("-button4\n");
 532                         zoomscript_caught = 0;
 533                         ignore_minus_zoom += 1;
 534                 }
 535         }
 536
 537         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 538         activeweapon = getstati(STAT_SWITCHWEAPON);
 539         f = (serverflags & SERVERFLAG_TEAMPLAY);
 540         if(f != teamplay)
 541         {
 542                 teamplay = f;
 543                 HUD_InitScores();
 544         }
 545
 546         if(last_weapon != activeweapon) {
 547                 weapontime = time;
 548                 last_weapon = activeweapon;
 549
 550                 e = get_weaponinfo(activeweapon);
 551                 if(e.netname != "")
 552                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 553                 else
 554                         localcmd("\ncl_hook_activeweapon none\n");
 555         }
 556
 557         // ALWAYS Clear Current Scene First
 558         R_ClearScene();
 559
 560         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 561         R_SetView(VF_SIZE, vf_size);
 562         R_SetView(VF_MIN, vf_min);
 563
 564         // Assign Standard Viewflags
 565         // Draw the World (and sky)
 566         R_SetView(VF_DRAWWORLD, 1);
 567
 568         // Set the console size vars
 569         vid_conwidth = autocvar_vid_conwidth;
 570         vid_conheight = autocvar_vid_conheight;
 571         vid_pixelheight = autocvar_vid_pixelheight;
 572
 573         R_SetView(VF_FOV, GetCurrentFov(fov));
 574
 575         // Camera for demo playback
 576         if(camera_active)
 577         {
 578                 if(autocvar_camera_enable)
 579                         CSQC_Demo_Camera();
 580                 else
 581                 {
 582                         cvar_set("chase_active", ftos(chase_active_backup));
 583                         cvar_set("cl_demo_mousegrab", "0");
 584                         camera_active = FALSE;
 585                 }
 586         }
 587 #ifdef CAMERATEST
 588         else if(autocvar_camera_enable)
 589 #else
 590         else if(autocvar_camera_enable && isdemo())
 591 #endif
 592         {
 593                 // Enable required Darkplaces cvars
 594                 chase_active_backup = autocvar_chase_active;
 595                 cvar_set("chase_active", "2");
 596                 cvar_set("cl_demo_mousegrab", "1");
 597                 camera_active = TRUE;
 598                 camera_mode = FALSE;
 599         }
 600
 601         // Draw the Crosshair
 602         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 603
 604         // Draw the Engine Status Bar (the default Quake HUD)
 605         R_SetView(VF_DRAWENGINEHUD, 0);
 606
 607         // fetch this one only once per frame
 608         hud_showbinds = autocvar_hud_showbinds;
 609         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 610
 611         // Update the mouse position
 612         /*
 613            mousepos_x = vid_conwidth;
 614            mousepos_y = vid_conheight;
 615            mousepos = mousepos*0.5 + getmousepos();
 616          */
 617
 618         e = self;
 619         for(self = world; (self = nextent(self)); )
 620                 if(self.draw)
 621                         self.draw();
 622         self = e;
 623
 624         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 625         R_RenderScene();
 626
 627         // now switch to 2D drawing mode by calling a 2D drawing function
 628         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 629         // next R_RenderScene call
 630         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 631
 632         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 633         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 634         {
 635                 // apply night vision effect
 636                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 637
 638                 if(!nightvision_noise)
 639                 {
 640                         nightvision_noise = spawn();
 641                         nightvision_noise.classname = "nightvision_noise";
 642                 }
 643                 if(!nightvision_noise2)
 644                 {
 645                         nightvision_noise2 = spawn();
 646                         nightvision_noise2.classname = "nightvision_noise2";
 647                 }
 648
 649                 // color tint in yellow
 650                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 651
 652                 // draw BG
 653                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 654                 rgb = '1 1 1';
 655                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 656                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 657                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 658                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 659                 tc_11 = tc_01 + tc_10 - tc_00;
 660                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 661                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 662                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 663                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 664                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 665                 R_EndPolygon();
 666
 667                 // draw FG
 668                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 669                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 670                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 671                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 672                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 673                 tc_11 = tc_01 + tc_10 - tc_00;
 674                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 675                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 676                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 677                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 678                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 679                 R_EndPolygon();
 680         }
 681
 682         // Draw the aiming reticle for weapons that use it
 683         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 684         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 685         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 686         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 687                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 688         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 689                 reticle_type = 2; // nex zoom
 690         else if(button_zoom || zoomscript_caught)
 691                 reticle_type = 1; // normal zoom
 692         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 693                 reticle_type = 2; // nex zoom
 694
 695         if (reticle_type)
 696         {
 697                 if(autocvar_cl_reticle_stretch)
 698                 {
 699                         reticle_size_x = vid_conwidth;
 700                         reticle_size_y = vid_conheight;
 701                         reticle_pos_x = 0;
 702                         reticle_pos_y = 0;
 703                 }
 704                 else
 705                 {
 706                         reticle_size_x = max(vid_conwidth, vid_conheight);
 707                         reticle_size_y = max(vid_conwidth, vid_conheight);
 708                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 709                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 710                 }
 711
 712                 f = current_zoomfraction;
 713                 if(zoomscript_caught)
 714                         f = 1;
 715                 if(autocvar_cl_reticle_item_normal)
 716                 {
 717                         if(reticle_type == 1 && f)
 718                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 719                 }
 720                 if(autocvar_cl_reticle_item_nex)
 721                 {
 722                         if(reticle_type == 2 && f)
 723                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 724                 }
 725         }
 726
 727
 728         // improved polyblend
 729         vector rgb;
 730         if(autocvar_hud_contents)
 731         {
 732                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 733                 vector liquidcolor;
 734
 735                 switch(pointcontents(view_origin))
 736                 {
 737                         case CONTENT_WATER:
 738                                 liquidalpha = autocvar_hud_contents_water_alpha;
 739                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 740                                 incontent = 1;
 741                                 break;
 742
 743                         case CONTENT_LAVA:
 744                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 745                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 746                                 incontent = 1;
 747                                 break;
 748
 749                         case CONTENT_SLIME:
 750                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 751                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 752                                 incontent = 1;
 753                                 break;
 754
 755                         default:
 756                                 liquidalpha = 0;
 757                                 liquidcolor = '0 0 0';
 758                                 incontent = 0;
 759                                 break;
 760                 }
 761
 762                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 763                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 764                         contentfadetime = autocvar_hud_contents_fadeintime;
 765                         liquidalpha_prev = liquidalpha;
 766                         liquidcolor_prev = liquidcolor;
 767                 }
 768                 else
 769                         contentfadetime = autocvar_hud_contents_fadeouttime;
 770
 771                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 772                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 773
 774                 if(contentavgalpha)
 775                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 776         }
 777
 778         if(autocvar_hud_damage)
 779         {
 780                 splash_size_x = max(vid_conwidth, vid_conheight);
 781                 splash_size_y = max(vid_conwidth, vid_conheight);
 782                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 783                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 784
 785                 float myhealth_flash_temp;
 786                 myhealth = getstati(STAT_HEALTH);
 787
 788                 // fade out
 789                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 790                 // add new damage
 791                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 792
 793                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 794                 pain_threshold = autocvar_hud_damage_pain_threshold;
 795                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 796                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 797
 798                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 799                 {
 800                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 801                 }
 802
 803                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 804
 805                 if(myhealth_prev < 1)
 806                 {
 807                         if(myhealth >= 1)
 808                         {
 809                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 810                                 myhealth_flash_temp = 0;
 811                         }
 812                         else
 813                         {
 814                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 815                         }
 816                 }
 817
 818                 if(spectatee_status == -1 || intermission)
 819                 {
 820                         myhealth_flash = 0; // observing, or match ended
 821                         myhealth_flash_temp = 0;
 822                 }
 823
 824                 myhealth_prev = myhealth;
 825
 826                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 827                 {
 828                         if(autocvar_cl_gentle_damage == 2)
 829                         {
 830                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 831                                 {
 832                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 833                                 }
 834                         }
 835                         else
 836                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 837
 838                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 839                 }
 840                 else
 841                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 842         }
 843
 844         // Draw the mouse cursor
 845         // NOTE: drawpic must happen after R_RenderScene for some reason
 846         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 847         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 848         //self = edict_num(player_localnum);
 849         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 850         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 851         // as long as the ctf part isn't in, this is useless
 852         if(menu_visible)
 853                 menu_show();
 854
 855         /*if(gametype == GAME_CTF)
 856           {
 857           ctf_view();
 858           } else */
 859
 860         // draw 2D entities
 861         e = self;
 862         for(self = world; (self = nextent(self)); )
 863                 if(self.draw2d)
 864                         self.draw2d();
 865         self = e;
 866
 867         scoreboard_active = HUD_WouldDrawScoreboard();
 868
 869         hit_time = getstatf(STAT_HIT_TIME);
 870         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 871         {
 872                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 873                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 874         }
 875         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 876         if(typehit_time > nextsound_typehit_time)
 877         {
 878                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 879                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 880         }
 881
 882         float hud;
 883         hud = getstati(STAT_HUD);
 884         if(hud == HUD_SPIDERBOT)
 885                 CSQC_SPIDER_HUD();
 886         else if(hud == HUD_WAKIZASHI)
 887         CSQC_WAKIZASHI_HUD();
 888     else if(hud == HUD_RAPTOR)
 889         CSQC_RAPTOR_HUD();
 890         else
 891         {
 892                 if(gametype == GAME_FREEZETAG)
 893                 {
 894                         if(getstati(STAT_FROZEN))
 895                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 896                         if(getstatf(STAT_REVIVE_PROGRESS))
 897                         {
 898                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 899                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 900                         }
 901                 }
 902
 903                 if(autocvar_r_letterbox == 0)
 904                         if(autocvar_viewsize < 120)
 905                                 CSQC_common_hud();
 906
 907                 // crosshair goes VERY LAST
 908                 if(!scoreboard_active && !camera_active && intermission != 2) {
 909                         string wcross_style;
 910                         float wcross_alpha, wcross_resolution;
 911                         wcross_style = autocvar_crosshair;
 912                         if (wcross_style == "0")
 913                                 return;
 914                         wcross_resolution = autocvar_crosshair_size;
 915                         if (wcross_resolution == 0)
 916                                 return;
 917                         wcross_alpha = autocvar_crosshair_alpha;
 918                         if (wcross_alpha == 0)
 919                                 return;
 920
 921                         // TrueAim check
 922                         float shottype;
 923
 924                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 925                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 926                         wcross_origin_z = 0;
 927                         if(autocvar_crosshair_hittest)
 928                         {
 929                                 vector wcross_oldorigin;
 930                                 wcross_oldorigin = wcross_origin;
 931                                 shottype = TrueAimCheck();
 932                                 if(shottype == SHOTTYPE_HITWORLD)
 933                                 {
 934                                         v = wcross_origin - wcross_oldorigin;
 935                                         v_x /= vid_conwidth;
 936                                         v_y /= vid_conheight;
 937                                         if(vlen(v) > 0.01)
 938                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 939                                 }
 940                                 if(!autocvar_crosshair_hittest_showimpact)
 941                                         wcross_origin = wcross_oldorigin;
 942                         }
 943                         else
 944                                 shottype = SHOTTYPE_HITWORLD;
 945
 946                         vector wcross_color, wcross_size;
 947                         string wcross_wep, wcross_name;
 948                         float wcross_scale, wcross_blur;
 949
 950                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 951                                 e = get_weaponinfo(activeweapon);
 952                                 if (e && e.netname != "")
 953                                 {
 954                                         wcross_wep = e.netname;
 955                                         if(autocvar_crosshair_per_weapon)
 956                                         {
 957                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 958                                                 if (wcross_resolution == 0)
 959                                                         return;
 960                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 961                                                 if (wcross_alpha == 0)
 962                                                         return;
 963
 964                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 965                                                 if(wcross_style == "" || wcross_style == "0")
 966                                                         wcross_style = wcross_wep;
 967                                         }
 968                                 }
 969                         }
 970                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 971                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 972                         else if(autocvar_crosshair_color_by_health)
 973                         {
 974                                 local float x = getstati(STAT_HEALTH);
 975
 976                                 //x = red
 977                                 //y = green
 978                                 //z = blue
 979
 980                                 wcross_color_z = 0;
 981
 982                                 if(x > 200)
 983                                 {
 984                                         wcross_color_x = 0;
 985                                         wcross_color_y = 1;
 986                                 }
 987                                 else if(x > 150)
 988                                 {
 989                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 990                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 991                                 }
 992                                 else if(x > 100)
 993                                 {
 994                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 995                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 996                                         wcross_color_z = 1 - (x-100)*0.02;
 997                                 }
 998                                 else if(x > 50)
 999                                 {
1000                                         wcross_color_x = 1;
1001                                         wcross_color_y = 1;
1002                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1003                                 }
1004                                 else if(x > 20)
1005                                 {
1006                                         wcross_color_x = 1;
1007                                         wcross_color_y = (x-20)*90/27/100;
1008                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1009                                 }
1010                                 else
1011                                 {
1012                                         wcross_color_x = 1;
1013                                         wcross_color_y = 0;
1014                                 }
1015                         }
1016                         else
1017                                 wcross_color = stov(autocvar_crosshair_color);
1018
1019                         wcross_name = strcat("gfx/crosshair", wcross_style);
1020
1021                         if(autocvar_crosshair_effect_scalefade)
1022                         {
1023                                 wcross_scale = wcross_resolution;
1024                                 wcross_resolution = 1;
1025                         }
1026                         else
1027                         {
1028                                 wcross_scale = 1;
1029                         }
1030
1031                         if(autocvar_crosshair_pickup)
1032                         {
1033                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1034                                 {
1035                                         pickup_crosshair_size = 1;
1036                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1037                                 }
1038
1039                                 if(pickup_crosshair_size > 0)
1040                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1041                                 else
1042                                         pickup_crosshair_size = 0;
1043
1044                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1045                         }
1046
1047                         vector hitindication_color;
1048                         if(autocvar_crosshair_hitindication)
1049                         {
1050                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1051                                 if(hitindication_crosshair_time < hit_time)
1052                                 {
1053                                         hitindication_crosshair_size = 1;
1054                                         hitindication_crosshair_time = hit_time;
1055                                 }
1056
1057                                 if(hitindication_crosshair_size > 0)
1058                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1059                                 else
1060                                         hitindication_crosshair_size = 0;
1061
1062                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1063                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1064                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1065                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1066                         }
1067
1068                         if(shottype == SHOTTYPE_HITENEMY)
1069                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1070                         if(shottype == SHOTTYPE_HITTEAM)
1071                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1072
1073                         f = autocvar_crosshair_effect_speed;
1074                         if(f < 0)
1075                                 f *= -2 * g_weaponswitchdelay;
1076                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1077                         {
1078                                 wcross_changedonetime = time + f;
1079                         }
1080                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1081                         {
1082                                 wcross_name_changestarttime = time;
1083                                 wcross_name_changedonetime = time + f;
1084                                 if(wcross_name_goal_prev_prev)
1085                                         strunzone(wcross_name_goal_prev_prev);
1086                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1087                                 wcross_name_goal_prev = strzone(wcross_name);
1088                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1089                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1090                                 wcross_resolution_goal_prev = wcross_resolution;
1091                         }
1092
1093                         wcross_scale_goal_prev = wcross_scale;
1094                         wcross_alpha_goal_prev = wcross_alpha;
1095                         wcross_color_goal_prev = wcross_color;
1096
1097                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1098                         {
1099                                 wcross_blur = 1;
1100                                 wcross_alpha *= 0.75;
1101                         }
1102                         else
1103                                 wcross_blur = 0;
1104                         // *_prev is at time-frametime
1105                         // * is at wcross_changedonetime+f
1106                         // what do we have at time?
1107                         if(time < wcross_changedonetime)
1108                         {
1109                                 f = frametime / (wcross_changedonetime - time + frametime);
1110                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1111                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1112                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1113                         }
1114
1115                         wcross_scale_prev = wcross_scale;
1116                         wcross_alpha_prev = wcross_alpha;
1117                         wcross_color_prev = wcross_color;
1118
1119                         wcross_scale *= 1 - autocvar__menu_alpha;
1120                         wcross_alpha *= 1 - autocvar__menu_alpha;
1121                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1122
1123                         // crosshair rings for weapon stats
1124                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1125                         {
1126                                 // declarations and stats
1127                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1128                                 string ring_image, ring_inner_image;
1129                                 vector ring_rgb, ring_inner_rgb;
1130
1131                                 ring_scale = autocvar_crosshair_ring_size;
1132
1133                                 float weapon_clipload, weapon_clipsize;
1134                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1135                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1136
1137                                 float nex_charge, nex_chargepool;
1138                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1139                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1140
1141                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1142                                         nex_charge_movingavg = nex_charge;
1143
1144
1145                                 // handle the values
1146                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1147                                 {
1148                                         if (nex_chargepool || use_nex_chargepool) {
1149                                                 use_nex_chargepool = 1;
1150                                                 ring_inner_value = nex_chargepool;
1151                                         } else {
1152                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1153                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1154                                         }
1155
1156                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1157                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1158                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1159
1160                                         // draw the outer ring to show the current charge of the weapon
1161                                         ring_value = nex_charge;
1162                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1165                                 }
1166                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1167                                 {
1168                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1169                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173
1174                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1175                                 {
1176                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1177                                         ring_scale = autocvar_crosshair_ring_reload_size;
1178                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1179                                         ring_rgb = wcross_color;
1180
1181                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1182                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1183                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1184                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1185                                         else
1186                                                 ring_image = "gfx/crosshair_ring.tga";
1187                                 }
1188
1189                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1190                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1191
1192                                 if (ring_value)
1193                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1194                         }
1195
1196 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1197                         do \
1198                         { \
1199                                 if(wcross_blur > 0) \
1200                                 { \
1201                                         for(i = -2; i <= 2; ++i) \
1202                                                 for(j = -2; j <= 2; ++j) \
1203                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1204                                 } \
1205                                 else \
1206                                 { \
1207                                         M(0,0,sz,wcross_name,wcross_alpha); \
1208                                 } \
1209                         } \
1210                         while(0)
1211
1212 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1213                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1214
1215 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1216                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1217
1218                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1219                         {
1220                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1221                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1222                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1223                                 f = 1 - f;
1224                         }
1225                         else
1226                         {
1227                                 f = 1;
1228                         }
1229
1230                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1231                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1232
1233                         if(autocvar_crosshair_dot)
1234             {
1235                 vector wcross_color_old;
1236                 wcross_color_old = wcross_color;
1237                 if(autocvar_crosshair_dot_color != "0")
1238                     wcross_color = stov(autocvar_crosshair_dot_color);
1239                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1240                 wcross_color = wcross_color_old;
1241             }
1242
1243                         wcross_name_alpha_goal_prev = f;
1244                 }
1245                 else
1246                 {
1247                         wcross_scale_prev = 0;
1248                         wcross_alpha_prev = 0;
1249                         wcross_scale_goal_prev = 0;
1250                         wcross_alpha_goal_prev = 0;
1251                         wcross_changedonetime = 0;
1252                         if(wcross_name_goal_prev)
1253                                 strunzone(wcross_name_goal_prev);
1254                         wcross_name_goal_prev = string_null;
1255                         if(wcross_name_goal_prev_prev)
1256                                 strunzone(wcross_name_goal_prev_prev);
1257                         wcross_name_goal_prev_prev = string_null;
1258                         wcross_name_changestarttime = 0;
1259                         wcross_name_changedonetime = 0;
1260                         wcross_name_alpha_goal_prev = 0;
1261                         wcross_name_alpha_goal_prev_prev = 0;
1262                         wcross_resolution_goal_prev = 0;
1263                         wcross_resolution_goal_prev_prev = 0;
1264                 }
1265         }
1266
1267         if(NextFrameCommand)
1268         {
1269                 localcmd("\n", NextFrameCommand, "\n");
1270                 NextFrameCommand = string_null;
1271         }
1272
1273         // we must do this check AFTER a frame was rendered, or it won't work
1274         if(cs_project_is_b0rked == 0)
1275         {
1276                 string w0, h0;
1277                 w0 = ftos(autocvar_vid_conwidth);
1278                 h0 = ftos(autocvar_vid_conheight);
1279                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1280                 //R_SetView(VF_FOV, '90 90 0');
1281                 R_SetView(VF_ORIGIN, '0 0 0');
1282                 R_SetView(VF_ANGLES, '0 0 0');
1283                 R_SetView(VF_PERSPECTIVE, 1);
1284                 makevectors('0 0 0');
1285                 vector v1, v2;
1286                 cvar_set("vid_conwidth", "800");
1287                 cvar_set("vid_conheight", "600");
1288                 v1 = cs_project(v_forward);
1289                 cvar_set("vid_conwidth", "640");
1290                 cvar_set("vid_conheight", "480");
1291                 v2 = cs_project(v_forward);
1292                 if(v1 == v2)
1293                         cs_project_is_b0rked = 1;
1294                 else
1295                         cs_project_is_b0rked = -1;
1296                 cvar_set("vid_conwidth", w0);
1297                 cvar_set("vid_conheight", h0);
1298         }
1299
1300         if(autocvar__hud_configure)
1301                 HUD_Panel_Mouse();
1302
1303         // let's reset the view back to normal for the end
1304         R_SetView(VF_MIN, '0 0 0');
1305         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1306 }
1307
1308 #define spider_h "gfx/vehicles/hud_bg.tga"
1309 #define spider_b "gfx/vehicles/sbot.tga"
1310 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1311 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1312 #define spider_s "gfx/vehicles/shiled.tga"
1313 #define spider_a1 "gfx/hud/sb_rocket.tga"
1314 #define spider_a2 "gfx/sb_bullets.tga"
1315
1316 void CSQC_SPIDER_HUD()
1317 {
1318         float rockets, reload, heat, hp, shield;
1319         vector picsize, hudloc;
1320
1321     // Fetch health & ammo stats
1322     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1323         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1324         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1325         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1326         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1327
1328     // Draw the crosshairs
1329     picsize = drawgetimagesize(SPIDER_CROSS);
1330     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1331     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1332     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1333
1334     hudloc_y =  4;
1335     hudloc_x = 4;
1336
1337     picsize = drawgetimagesize(spider_h) * 0.5;
1338     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1339
1340     picsize = drawgetimagesize(spider_a2) * 0.5;
1341     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1342
1343     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1344     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1345     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1346
1347     picsize = drawgetimagesize(spider_a1) * 0.85;
1348     if(rockets == 9)
1349     {
1350         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1351         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1352     }
1353     else
1354     {
1355         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1356         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1357     }
1358
1359     picsize = drawgetimagesize(spider_b) * 0.5;
1360     hudloc_y = 10.5;
1361     hudloc_x = 10.5;
1362
1363     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1364     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1365     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1366     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1367
1368
1369         /*
1370         // Draw health bar
1371         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1372         p = p + '0 1 0' * vid_conheight - '0 32 0';
1373         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1374         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1375         p_y += 8;
1376         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1377         p_x += 256 * hp;
1378         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1379
1380         // Draw minigun heat indicator
1381         p = '0.5 0 0' * (vid_conwidth - 256);
1382         p = p + '0 1 0' * vid_conheight - '0 34  0';
1383         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1384         p_x += 256 * (1-heat);
1385         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1386
1387
1388         // Draw rocket icons for loaded/empty tubes.
1389         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1390         pp += '0 1 0' * vid_conheight - '0 64 0';
1391         for(i = 0; i < 8; ++i)
1392         {
1393                 p = pp + '1 0 0' * (rkt_size * i);
1394                 if(rockets == 8)
1395                 {
1396                         if(floor(reload * 8) == i)
1397                         {
1398                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1399                         }
1400                         else if(i < reload * 8)
1401                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1402                         else
1403                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1404                 }
1405                 else
1406                 {
1407                         if(i < rockets)
1408                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1409                         else
1410                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1411                 }
1412         }
1413         */
1414
1415         if (scoreboard_showscores)
1416         {
1417                 HUD_DrawScoreboard();
1418                 HUD_DrawCenterPrint();
1419         }
1420
1421 }
1422
1423 #define raptor_h "gfx/vehicles/hud_bg.tga"
1424 #define raptor_b "gfx/vehicles/raptor.tga"
1425 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1426 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1427 #define raptor_s "gfx/vehicles/shiled.tga"
1428
1429 void CSQC_RAPTOR_HUD()
1430 {
1431         float reload, hp, shield, energy;
1432         vector picsize, hudloc;
1433
1434     // Fetch health & ammo stats
1435     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1436         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1437         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1438         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1439
1440     // Draw the crosshairs
1441     picsize = drawgetimagesize(SPIDER_CROSS);
1442     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1443     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1444     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1445
1446     hudloc_y =  4;
1447     hudloc_x = 4;
1448
1449     picsize = drawgetimagesize(raptor_h) * 0.5;
1450     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1451
1452     picsize = drawgetimagesize(spider_a2) * 0.5;
1453     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1454
1455     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1456     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1457     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1458
1459
1460     picsize = drawgetimagesize(spider_a1) * 0.85;
1461     if(reload == 1)
1462     {
1463         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1464         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1465     }
1466     else
1467     {
1468         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1469         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1470     }
1471
1472     picsize = drawgetimagesize(raptor_b) * 0.5;
1473     hudloc_y = 10.5;
1474     hudloc_x = 10.5;
1475
1476     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1477     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1478     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1479     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1480
1481
1482         if (scoreboard_showscores)
1483         {
1484                 HUD_DrawScoreboard();
1485                 HUD_DrawCenterPrint();
1486         }
1487
1488 }
1489
1490 #define waki_h "gfx/vehicles/hud_bg.tga"
1491 #define waki_b "gfx/vehicles/waki.tga"
1492 #define waki_e "gfx/vehicles/waki_e.tga"
1493 #define waki_g "gfx/vehicles/waki_guns.tga"
1494 #define waki_r "gfx/vehicles/waki_rockets.tga"
1495 #define waki_s "gfx/vehicles/shiled.tga"
1496
1497 #define waki_a1 "gfx/hud/sb_rocket.tga"
1498 #define waki_a2 "gfx/sb_cells.tga"
1499
1500 void CSQC_WAKIZASHI_HUD()
1501 {
1502         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1503         float health, shield, energy, rockets;
1504         vector picsize, hudloc;
1505
1506     picsize = drawgetimagesize(SPIDER_CROSS);
1507     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1508     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1509     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1510
1511 /*
1512 const float STAT_VEHICLESTAT_HEALTH  = 60;
1513 const float STAT_VEHICLESTAT_SHIELD  = 61;
1514 const float STAT_VEHICLESTAT_ENERGY  = 62;
1515 const float STAT_VEHICLESTAT_AMMO1   = 63;
1516 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1517 const float STAT_VEHICLESTAT_AMMO2   = 65;
1518 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1519 */
1520     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1521         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1522         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1523         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1524
1525     hudloc_y =  4;
1526     hudloc_x = 4;
1527
1528     picsize = drawgetimagesize(waki_h) * 0.5;
1529     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1530
1531     picsize = drawgetimagesize(waki_a2) * 0.7;
1532     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1533
1534
1535     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1536     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1537
1538     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1539
1540     picsize = drawgetimagesize(waki_a1) * 0.75;
1541     if(rockets == 1)
1542     {
1543         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1544         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1545     }
1546     else
1547     {
1548         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1549         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1550         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1551     }
1552
1553     picsize = drawgetimagesize(waki_b) * 0.5;
1554     hudloc_y = 10.5;
1555     hudloc_x = 10.5;
1556
1557     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1558     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1559     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1560     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1561
1562
1563
1564         /*
1565         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1566         p = p + '0 1 0' * vid_conheight - '0 32 0';
1567
1568         // Draw health bar
1569         p_y += 8;
1570         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1571         p_x += 256 * health;
1572         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1573
1574         // Draw shiled bar
1575         p_x -= 256 * health;
1576         p_y += 4;
1577         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1578
1579         // Draw energy
1580         //p_x -= 256 * health;
1581         p_y -= 8;
1582         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1583
1584         // Draw rockets bar
1585         p_y += 12;
1586         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1587         */
1588
1589
1590
1591
1592         if (scoreboard_showscores)
1593         {
1594                 HUD_DrawScoreboard();
1595                 HUD_DrawCenterPrint();
1596         }
1597
1598 }
1599
1600
1601 void CSQC_common_hud(void)
1602 {
1603         // HUD_SortFrags(); done in HUD_Draw
1604         float hud;
1605         hud = getstati(STAT_HUD);
1606
1607         //hud = 10;
1608         switch(hud)
1609         {
1610                 case HUD_NORMAL:
1611                         // do some accuracy var caching
1612                         float i;
1613                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1614                         {
1615                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1616                                 {
1617                                         if(acc_color_levels)
1618                                                 strunzone(acc_color_levels);
1619                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1620                                         acc_levels = tokenize(acc_color_levels);
1621                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1622                                                 acc_levels = MAX_ACCURACY_LEVELS;
1623
1624                                         for (i = 0; i < acc_levels; ++i)
1625                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1626                                 }
1627                                 // let know that acc_col[] needs to be loaded
1628                                 acc_col_x[0] = -1;
1629                         }
1630
1631                         HUD_Main(); // always run these functions for alpha checks
1632                         HUD_DrawScoreboard();
1633
1634                         if (scoreboard_active) // scoreboard/accuracy
1635                         {
1636                                 HUD_Reset();
1637                                 // HUD_DrawScoreboard takes care of centerprint_start
1638                         }
1639                         else if (intermission == 2) // map voting screen
1640                         {
1641                                 HUD_FinaleOverlay();
1642                                 HUD_Reset();
1643
1644                                 centerprint_start_x = 0;
1645                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1646                         }
1647                         else // hud
1648                         {
1649                                 centerprint_start_x = 0;
1650                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1651                         }
1652
1653                         HUD_DrawCenterPrint();
1654                         break;
1655
1656                 case HUD_SPIDERBOT:
1657                         CSQC_SPIDER_HUD();
1658                         break;
1659
1660                 case HUD_WAKIZASHI:
1661                         CSQC_WAKIZASHI_HUD();
1662                         break;
1663         }
1664 }
1665
1666
1667 // following vectors must be global to allow seamless switching between camera modes
1668 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1669 void CSQC_Demo_Camera()
1670 {
1671         float speed, attenuation, dimensions;
1672         vector tmp, delta;
1673
1674         if( autocvar_camera_reset || !camera_mode )
1675         {
1676                 camera_offset = '0 0 0';
1677                 current_angles = '0 0 0';
1678                 camera_direction = '0 0 0';
1679                 camera_offset_z += 30;
1680                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1681                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1682                 current_origin = view_origin;
1683                 current_camera_offset  = camera_offset;
1684                 cvar_set("camera_reset", "0");
1685                 camera_mode = CAMERA_CHASE;
1686         }
1687
1688         // Camera angles
1689         if( camera_roll )
1690                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1691
1692         if(autocvar_camera_look_player)
1693         {
1694                 local vector dir;
1695                 local float n;
1696
1697                 dir = normalize(view_origin - current_position);
1698                 n = mouse_angles_z;
1699                 mouse_angles = vectoangles(dir);
1700                 mouse_angles_x = mouse_angles_x * -1;
1701                 mouse_angles_z = n;
1702         }
1703         else
1704         {
1705                 tmp = getmousepos() * 0.1;
1706                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1707                 {
1708                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1709                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1710                 }
1711         }
1712
1713         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1714         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1715         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1716         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1717
1718         // Fix difference when angles don't have the same sign
1719         delta = '0 0 0';
1720         if(mouse_angles_y < -60 && current_angles_y > 60)
1721                 delta = '0 360 0';
1722         if(mouse_angles_y > 60 && current_angles_y < -60)
1723                 delta = '0 -360 0';
1724
1725         if(autocvar_camera_look_player)
1726                 attenuation = autocvar_camera_look_attenuation;
1727         else
1728                 attenuation = autocvar_camera_speed_attenuation;
1729
1730         attenuation = 1 / max(1, attenuation);
1731         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1732
1733         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1734         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1735         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1736         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1737
1738         // Camera position
1739         tmp = '0 0 0';
1740         dimensions = 0;
1741
1742         if( camera_direction_x )
1743         {
1744                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1745                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1746                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1747                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1748                 ++dimensions;
1749         }
1750
1751         if( camera_direction_y )
1752         {
1753                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1754                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1755                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1756                 ++dimensions;
1757         }
1758
1759         if( camera_direction_z )
1760         {
1761                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1762                 ++dimensions;
1763         }
1764
1765         if(autocvar_camera_free)
1766                 speed = autocvar_camera_speed_free;
1767         else
1768                 speed = autocvar_camera_speed_chase;
1769
1770         if(dimensions)
1771         {
1772                 speed = speed * sqrt(1 / dimensions);
1773                 camera_offset += tmp * speed;
1774         }
1775
1776         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1777
1778         // Camera modes
1779         if( autocvar_camera_free )
1780         {
1781                 if ( camera_mode == CAMERA_CHASE )
1782                 {
1783                         current_camera_offset = current_origin + current_camera_offset;
1784                         camera_offset = current_origin + camera_offset;
1785                 }
1786
1787                 camera_mode = CAMERA_FREE;
1788                 current_position = current_camera_offset;
1789         }
1790         else
1791         {
1792                 if ( camera_mode == CAMERA_FREE )
1793                 {
1794                         current_origin = view_origin;
1795                         camera_offset = camera_offset - current_origin;
1796                         current_camera_offset = current_camera_offset - current_origin;
1797                 }
1798
1799                 camera_mode = CAMERA_CHASE;
1800
1801                 if(autocvar_camera_chase_smoothly)
1802                         current_origin += (view_origin - current_origin) * attenuation;
1803                 else
1804                         current_origin = view_origin;
1805
1806                 current_position = current_origin + current_camera_offset;
1807         }
1808
1809         R_SetView(VF_ANGLES, current_angles);
1810         R_SetView(VF_ORIGIN, current_position);
1811 }