qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2
   3 #include <client/mutators/_mod.qh>
   4 #include <client/player_skeleton.qh>
   5 #include <client/weapons/projectile.qh>
   6 #include <common/animdecide.qh>
   7 #include <common/effects/all.inc>
   8 #include <common/effects/all.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/viewloc.qh>
  15 #include <lib/csqcmodel/cl_model.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17 #include <lib/csqcmodel/interpolate.qh>
  18
  19 .float death_time;
  20 .int modelflags;
  21
  22 // FEATURE: LOD
  23 .int lodmodelindex0;
  24 .int lodmodelindex1;
  25 .int lodmodelindex2;
  26 void CSQCPlayer_LOD_Apply(entity this, bool isplayer)
  27 {
  28         int detailreduction = ((isplayer) ? autocvar_cl_playerdetailreduction : autocvar_cl_modeldetailreduction);
  29
  30         // LOD model loading
  31         if(this.lodmodelindex0 != this.modelindex)
  32         {
  33                 string modelname = this.model;
  34                 string s;
  35
  36                 vector mi = this.mins;
  37                 vector ma = this.maxs;
  38
  39                 // set modelindex
  40                 this.lodmodelindex0 = this.modelindex;
  41                 this.lodmodelindex1 = this.modelindex;
  42                 this.lodmodelindex2 = this.modelindex;
  43
  44                 // FIXME: this only supports 3-letter extensions
  45                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  46                 if(fexists(s))
  47                 {
  48                         precache_model(s);
  49                         _setmodel(this, s);
  50                         if(this.modelindex)
  51                                 this.lodmodelindex1 = this.modelindex;
  52                 }
  53
  54                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  55                 if(fexists(s))
  56                 {
  57                         precache_model(s);
  58                         _setmodel(this, s);
  59                         if(this.modelindex)
  60                                 this.lodmodelindex2 = this.modelindex;
  61                 }
  62
  63                 _setmodel(this, modelname); // make everything normal again
  64                 setsize(this, mi, ma);
  65         }
  66
  67         // apply LOD
  68         if(detailreduction <= 0)
  69         {
  70                 if(detailreduction <= -2)
  71                         this.modelindex = this.lodmodelindex2;
  72                 else if(detailreduction <= -1)
  73                         this.modelindex = this.lodmodelindex1;
  74                 else
  75                         this.modelindex = this.lodmodelindex0;
  76         }
  77         else
  78         {
  79                 float distance = vlen(((isplayer) ? this.origin : NearestPointOnBox(this, view_origin)) - view_origin); // TODO: perhaps it should just use NearestPointOnBox all the time, player hitbox can potentially be huge
  80                 float f = (distance * current_viewzoom + 100.0) * detailreduction;
  81                 f *= 1.0 / bound(0.01, view_quality, 1);
  82                 if(f > autocvar_cl_loddistance2)
  83                         this.modelindex = this.lodmodelindex2;
  84                 else if(f > autocvar_cl_loddistance1)
  85                         this.modelindex = this.lodmodelindex1;
  86                 else
  87                         this.modelindex = this.lodmodelindex0;
  88         }
  89 }
  90
  91 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  92 string forceplayermodels_model;
  93 bool forceplayermodels_modelisgoodmodel;
  94 int forceplayermodels_modelindex;
  95 int forceplayermodels_skin;
  96
  97 string forceplayermodels_mymodel;
  98 bool forceplayermodels_myisgoodmodel;
  99 int forceplayermodels_mymodelindex;
 100
 101 bool forceplayermodels_attempted;
 102
 103 .string forceplayermodels_savemodel;
 104 .int forceplayermodels_savemodelindex;
 105 .int forceplayermodels_saveskin;
 106 .int forceplayermodels_savecolormap;
 107
 108 .string forceplayermodels_isgoodmodel_mdl;
 109 .bool forceplayermodels_isgoodmodel;
 110
 111 string forceplayermodels_goodmodel;
 112 int forceplayermodels_goodmodelindex;
 113
 114 .vector glowmod;
 115
 116 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 117 {
 118         this.model = this.forceplayermodels_savemodel;
 119         this.modelindex = this.forceplayermodels_savemodelindex;
 120         this.skin = this.forceplayermodels_saveskin;
 121         this.colormap = this.forceplayermodels_savecolormap;
 122 }
 123 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 124 {
 125         this.forceplayermodels_savemodel = this.model;
 126         this.forceplayermodels_savemodelindex = this.modelindex;
 127         this.forceplayermodels_saveskin = this.skin;
 128         this.forceplayermodels_savecolormap = this.colormap;
 129
 130         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 131         {
 132                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 133                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 134                 if(!this.forceplayermodels_isgoodmodel)
 135                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 136         }
 137 }
 138 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 139 {
 140         int cm = this.forceplayermodels_savecolormap;
 141         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 142
 143         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 144                 goto skipforcemodels;
 145
 146         // FORCEMODEL
 147         // which one is ALWAYS good?
 148         if (!forceplayermodels_goodmodel)
 149         {
 150                 entity e = spawn();
 151                 precache_model(cvar_defstring("_cl_playermodel"));
 152                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 153                 forceplayermodels_goodmodel = e.model;
 154                 forceplayermodels_goodmodelindex = e.modelindex;
 155                 delete(e);
 156         }
 157
 158         // first, try finding it from the server
 159         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 160         {
 161                 if(islocalplayer)
 162                 {
 163                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 164                         {
 165                                 // trust server's idea of "own player model"
 166                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 167                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 168                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 169                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 170                                 forceplayermodels_attempted = 1;
 171                         }
 172                 }
 173         }
 174
 175         // forcemodel finding
 176         if(!forceplayermodels_attempted)
 177         {
 178                 forceplayermodels_attempted = 1;
 179
 180                 // only if this failed, find it out on our own
 181                 entity e = spawn();
 182                 precache_model(autocvar__cl_playermodel);
 183                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 184                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 185                 forceplayermodels_model = e.model;
 186                 forceplayermodels_modelindex = e.modelindex;
 187                 forceplayermodels_skin = autocvar__cl_playerskin;
 188                 delete(e);
 189         }
 190
 191         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 192         {
 193                 entity e = spawn();
 194                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 195                 forceplayermodels_myisgoodmodel = fexists(e.model);
 196                 forceplayermodels_mymodel = e.model;
 197                 forceplayermodels_mymodelindex = e.modelindex;
 198                 delete(e);
 199         }
 200
 201         // apply it
 202         bool isfriend;
 203
 204         if(teamplay)
 205                 isfriend = (cm == 1024 + 17 * myteam);
 206         else
 207                 isfriend = islocalplayer;
 208
 209         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 210         {
 211                 this.model = forceplayermodels_mymodel;
 212                 this.modelindex = forceplayermodels_mymodelindex;
 213                 this.skin = autocvar_cl_forcemyplayerskin;
 214         }
 215         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 216         {
 217                 this.model = forceplayermodels_model;
 218                 this.modelindex = forceplayermodels_modelindex;
 219                 this.skin = forceplayermodels_skin;
 220         }
 221         else if(this.forceplayermodels_isgoodmodel)
 222         {
 223                 this.model = this.forceplayermodels_savemodel;
 224                 this.modelindex = this.forceplayermodels_savemodelindex;
 225                 this.skin = this.forceplayermodels_saveskin;
 226         }
 227         else
 228         {
 229                 this.model = forceplayermodels_goodmodel;
 230                 this.modelindex = forceplayermodels_goodmodelindex;
 231                 this.skin = this.forceplayermodels_saveskin;
 232         }
 233
 234         LABEL(skipforcemodels)
 235
 236         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
 237                 goto skipforcecolors;
 238
 239         bool forceplayercolors_enabled = false;
 240         #define fpc autocvar_cl_forceplayercolors
 241         if (gametype.m_1v1)
 242         {
 243                 if ((myteam != NUM_SPECTATOR) && (fpc == 1 || fpc == 2 || fpc == 3 || fpc == 5))
 244                         forceplayercolors_enabled = true;
 245         }
 246         else if (teamplay)
 247         {
 248                 if ((team_count == 2) && (myteam != NUM_SPECTATOR) && (fpc == 2 || fpc == 4 || fpc == 5))
 249                         forceplayercolors_enabled = true;
 250         }
 251         else
 252         {
 253                 if (fpc == 1 || fpc == 2)
 254                         forceplayercolors_enabled = true;
 255         }
 256
 257         // forceplayercolors too
 258         if(teamplay)
 259         {
 260                 // own team's color is never forced
 261                 int forcecolor_friend = 0, forcecolor_enemy = 0;
 262                 entity tm;
 263
 264                 if(autocvar_cl_forcemyplayercolors)
 265                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 266
 267                 if(forceplayercolors_enabled)
 268                         forcecolor_enemy = 1024 + autocvar__cl_color;
 269
 270                 if(forcecolor_enemy && !forcecolor_friend)
 271                 {
 272                         // only enemy color is forced?
 273                         // verify it is not equal to the friend color
 274                         if(forcecolor_enemy == 1024 + 17 * myteam)
 275                                 forcecolor_enemy = 0;
 276                 }
 277
 278                 if(forcecolor_friend && !forcecolor_enemy)
 279                 {
 280                         // only friend color is forced?
 281                         // verify it is not equal to the enemy color
 282                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 283                                 // note: we even compare against our own team.
 284                                 // if we rejected because we matched our OWN team color,
 285                                 // this is not bad; we then simply keep our color as is
 286                                 // anyway.
 287                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 288                                         forcecolor_friend = 0;
 289                 }
 290
 291                 if(cm == 1024 + 17 * myteam)
 292                 {
 293                         if(forcecolor_friend)
 294                                 this.colormap = forcecolor_friend;
 295                 }
 296                 else
 297                 {
 298                         if(forcecolor_enemy)
 299                                 this.colormap = forcecolor_enemy;
 300                 }
 301         }
 302         else // if(!teamplay)
 303         {
 304                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 305                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 306                 else if (autocvar_cl_forceuniqueplayercolors && !islocalplayer && !gametype.m_1v1)
 307                 {
 308                         // Assign each enemy unique colors
 309                         // pick colors from 0 to 14 since 15 is the rainbow color
 310                         // pl01 0 1, pl02 1 2, ..., pl14 13 14, pl15 14 0
 311                         // pl16 0 2, pl17 1 3, ..., pl29 13  0, pl30 14 1
 312                         int num = this.entnum - 1;
 313                         int c1 = num % 15;
 314                         int q = floor(num / 15);
 315                         int c2 = (c1 + 1 + q) % 15;
 316                         this.colormap = 1024 + (c1 << 4) + c2;
 317                 }
 318                 else if(forceplayercolors_enabled)
 319                         this.colormap = player_localnum + 1;
 320         }
 321
 322         LABEL(skipforcecolors)
 323
 324         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
 325         {
 326                 this.glowmod = '0 0 0';
 327                 this.colormap = 0;
 328                 return;
 329         }
 330
 331         // GLOWMOD AND DEATH FADING
 332         if(this.colormap > 0)
 333                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
 334         else
 335                 this.glowmod = '1 1 1';
 336
 337         if(autocvar_cl_deathglow > 0)
 338         {
 339                 if(this.csqcmodel_isdead)
 340                 {
 341                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 342                         if(this.colormap > 0)
 343                                 min_factor /= 2;
 344                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 345                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 346                         if (this.glowmod == '0 0 0')
 347                                 this.glowmod.x = 0.000001;
 348                 }
 349         }
 350
 351         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 352 }
 353
 354 // FEATURE: fallback frames
 355 .int csqcmodel_saveframe;
 356 .int csqcmodel_saveframe2;
 357 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 358 .int csqcmodel_saveframe3;
 359 .int csqcmodel_saveframe4;
 360 #endif
 361 .int csqcmodel_framecount;
 362
 363 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 364 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 365 {
 366         this.frame = this.csqcmodel_saveframe;
 367         this.frame2 = this.csqcmodel_saveframe2;
 368 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 369         this.frame3 = this.csqcmodel_saveframe3;
 370         this.frame4 = this.csqcmodel_saveframe4;
 371 #endif
 372 }
 373 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 374 {
 375         this.csqcmodel_saveframe = this.frame;
 376         this.csqcmodel_saveframe2 = this.frame2;
 377 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 378         this.csqcmodel_saveframe3 = this.frame3;
 379         this.csqcmodel_saveframe4 = this.frame4;
 380 #endif
 381
 382         // hack for death animations: set their frametime to zero in case a
 383         // player "pops in"
 384         if(isnew)
 385         {
 386 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 387                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 388                         this.ft = this.death_time; \
 389 MACRO_END
 390                 FIX_FRAMETIME(frame, frame1time);
 391                 FIX_FRAMETIME(frame2, frame2time);
 392 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 393                 FIX_FRAMETIME(frame3, frame3time);
 394                 FIX_FRAMETIME(frame4, frame4time);
 395 #endif
 396         }
 397         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 398 }
 399 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 400 {
 401         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 402 }
 403 int CSQCPlayer_FallbackFrame(entity this, int f)
 404 {
 405         TC(int, f);
 406         if(frameduration(this.modelindex, f) > 0)
 407                 return f; // goooooood
 408         if(frameduration(this.modelindex, 1) <= 0)
 409                 return f; // this is a static model. We can't fix it if we wanted to
 410         switch(f)
 411         {
 412                 case 23: return 11; // anim_melee -> anim_shoot
 413                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 414                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 415                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 416                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 417                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 418                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 419                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 420         }
 421         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 422         return f;
 423 }
 424 void CSQCPlayer_FallbackFrame_Apply(entity this)
 425 {
 426         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 427         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 428 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 429         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 430         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 431 #endif
 432 }
 433
 434 // FEATURE: auto tag_index
 435 .entity tag_entity;
 436 .int tag_entity_lastmodelindex;
 437 .int tag_index;
 438 void CSQCModel_AutoTagIndex_Apply(entity this)
 439 {
 440         if(this.tag_entity && wasfreed(this.tag_entity))
 441                 this.tag_entity = NULL;
 442
 443         MUTATOR_CALLHOOK(TagIndex_Update, this);
 444
 445         if(this.tag_networkentity)
 446         {
 447                 // we are ATTACHED!
 448                 bool changed = 0;
 449                 if(this.tag_entity.entnum != this.tag_networkentity)
 450                 {
 451                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 452                         changed = 1;
 453                 }
 454
 455                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 456                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
 457                 {
 458                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 459                 }
 460
 461                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 462                 {
 463                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 464                         changed = 1;
 465                 }
 466                 if(changed)
 467                 {
 468                         if(this.tag_entity)
 469                         {
 470                                 // the best part is: IT EXISTS
 471                                 if(substring(this.model, 0, 14) == "models/weapons")
 472                                 {
 473                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 474                                         {
 475                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 476                                                 if(!this.tag_index)
 477                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 478                                                 if(!this.tag_index)
 479                                                 {
 480                                                         // we need to prevent this from 'appening
 481                                                         this.tag_entity = NULL;
 482                                                         this.drawmask = 0;
 483                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 484                                                 }
 485                                         }
 486                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 487                                         {
 488                                                 skeleton_loadinfo(this.tag_entity);
 489                                                 this.tag_index = this.tag_entity.bone_weapon;
 490                                         }
 491                                 }
 492
 493                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 494                                 {
 495                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 496                                         if(!this.tag_index)
 497                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 498                                 }
 499
 500                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 501                         }
 502                         else
 503                         {
 504                                 // damn, see you next frame
 505                                 this.drawmask = 0;
 506                         }
 507                 }
 508         }
 509 }
 510
 511 void CSQCModel_Effects_PreUpdate(entity this)
 512 {
 513         this.effects = this.csqcmodel_effects;
 514         this.modelflags = this.csqcmodel_modelflags;
 515         this.traileffect = this.csqcmodel_traileffect;
 516 }
 517 void Reset_ArcBeam();
 518 void CSQCModel_Effects_PostUpdate(entity this)
 519 {
 520         if (this == csqcplayer) {
 521                 if (this.csqcmodel_teleported) {
 522                         Reset_ArcBeam();
 523                 }
 524         }
 525         this.csqcmodel_effects = this.effects;
 526         this.csqcmodel_modelflags = this.modelflags;
 527         this.csqcmodel_traileffect = this.traileffect;
 528         this.effects = 0;
 529         this.modelflags = 0;
 530         if(this.csqcmodel_teleported)
 531                 Projectile_ResetTrail(this, this.origin);
 532 }
 533 .int snd_looping;
 534 void CSQCModel_Effects_Apply(entity this)
 535 {
 536         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 537         int tref = this.csqcmodel_traileffect;
 538
 539         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 540         this.effects = 0;
 541         this.traileffect = 0;
 542
 543         if(eff & EF_BRIGHTFIELD)
 544                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 545         // ignoring EF_MUZZLEFLASH
 546         if(eff & EF_BRIGHTLIGHT)
 547                 adddynamiclight(this.origin, 400, '3 3 3');
 548         if(eff & EF_DIMLIGHT)
 549                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 550         if((eff & EF_NODRAW) || (this.alpha < 0))
 551                 this.drawmask = 0;
 552         if(eff & EF_ADDITIVE)
 553                 this.renderflags |= RF_ADDITIVE;
 554         if(eff & EF_BLUE)
 555                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 556         if(eff & EF_RED)
 557                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 558         // ignoring EF_NOGUNBOB
 559         if(eff & EF_FULLBRIGHT)
 560                 this.renderflags |= RF_FULLBRIGHT;
 561         if(eff & EF_FLAME)
 562         {
 563                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 564                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 565         }
 566         if(eff & EF_STARDUST)
 567         {
 568                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 569                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 570         }
 571         if(eff & EF_NOSHADOW)
 572                 this.renderflags |= RF_NOSHADOW;
 573         if(eff & EF_NODEPTHTEST)
 574                 this.renderflags |= RF_DEPTHHACK;
 575         // ignoring EF_SELECTABLE
 576         if(eff & EF_DOUBLESIDED)
 577                 this.effects |= EF_DOUBLESIDED;
 578         if(eff & EF_NOSELFSHADOW)
 579                 this.effects |= EF_NOSELFSHADOW;
 580         if(eff & EF_DYNAMICMODELLIGHT)
 581                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 582         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 583         if(this.csqcmodel_modelflags & MF_ROCKET)
 584                 tref = EFFECT_TR_ROCKET.m_id;
 585         if(this.csqcmodel_modelflags & MF_GRENADE)
 586                 tref = EFFECT_TR_GRENADE.m_id;
 587         if(this.csqcmodel_modelflags & MF_GIB)
 588                 tref = EFFECT_TR_BLOOD.m_id;
 589         if(this.csqcmodel_modelflags & MF_ROTATE)
 590         {
 591                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 592                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 593                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 594                 this.renderflags |= RF_USEAXIS;
 595                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 596         }
 597         if(this.csqcmodel_modelflags & MF_TRACER)
 598                 tref = EFFECT_TR_WIZSPIKE.m_id;
 599         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 600                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 601         if(this.csqcmodel_modelflags & MF_TRACER2)
 602                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 603         if(this.csqcmodel_modelflags & MF_TRACER3)
 604                 tref = EFFECT_TR_VORESPIKE.m_id;
 605
 606         this.traileffect = tref;
 607
 608         if(this.drawmask)
 609                 Projectile_DrawTrail(this, this.origin);
 610         else
 611                 Projectile_ResetTrail(this, this.origin);
 612
 613         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 614                 this.renderflags |= RF_ADDITIVE;
 615                 // also special in CSQCPlayer_GlowMod_Apply
 616
 617         if(this.csqcmodel_modelflags & MF_ROCKET)
 618         {
 619                 if(!this.snd_looping)
 620                 {
 621                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 622                         this.snd_looping = CH_TRIGGER_SINGLE;
 623                 }
 624         }
 625         else
 626         {
 627                 if(this.snd_looping)
 628                 {
 629                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 630                         this.snd_looping = 0;
 631                 }
 632         }
 633 }
 634
 635 // general functions
 636 .int csqcmodel_predraw_run;
 637 .int anim_frame;
 638 .int anim_frame1time;
 639 .int anim_frame2;
 640 .int anim_frame2time;
 641 .int anim_saveframe;
 642 .int anim_saveframe1time;
 643 .int anim_saveframe2;
 644 .int anim_saveframe2time;
 645 .int anim_prev_pmove_flags;
 646 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 647 {
 648         if(this.csqcmodel_predraw_run == framecount)
 649                 return;
 650         this.csqcmodel_predraw_run = framecount;
 651
 652         if(!this.modelindex || this.model == "null")
 653         {
 654                 this.drawmask = 0;
 655                 if(this.snd_looping > 0)
 656                 {
 657                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 658                         this.snd_looping = 0;
 659                 }
 660                 return;
 661         }
 662         else
 663                 this.drawmask = MASK_NORMAL;
 664
 665         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 666         {
 667                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 668                 CSQCPlayer_LOD_Apply(this, true);
 669
 670                 if(!isplayer)
 671                 {
 672                         skeleton_loadinfo(this);
 673                         bool doblend = (this.bone_upperbody >= 0);
 674                         CSQCPlayer_FallbackFrame_Apply(this);
 675                         if(doblend)
 676                         {
 677                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 678                         }
 679                         else
 680                         {
 681                                 free_skeleton_from_frames(this);
 682                                 // just in case, clear these (we're animating in frame and frame3)
 683                                 this.lerpfrac = 0;
 684                                 this.lerpfrac4 = 0;
 685                         }
 686                 }
 687                 else
 688                 {
 689                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 690                         skeleton_loadinfo(this);
 691                         bool doblend = (this.bone_upperbody >= 0);
 692                         bool onground = 0;
 693                         if(this == csqcplayer)
 694                         {
 695                                 if(IS_ONGROUND(this))
 696                                         onground = 1;
 697                                 this.anim_prev_pmove_flags = this.flags;
 698                                 if(this.flags & FL_DUCKED)
 699                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 700                                 else if(this.anim_state & ANIMSTATE_DUCK)
 701                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 702                         }
 703                         else
 704                         {
 705                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 706                                 if(trace_startsolid || trace_fraction < 1)
 707                                         onground = 1;
 708                                 // predicted clients handle smoothing in the prediction code
 709                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
 710                         }
 711                         animdecide_load_if_needed(this);
 712                         animdecide_setimplicitstate(this, onground);
 713                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 714                         int sf = 0;
 715                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 716                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 717                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 718                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 719                         this.anim_saveframe = this.anim_frame;
 720                         this.anim_saveframe1time = this.anim_frame1time;
 721                         this.anim_saveframe2 = this.anim_frame2;
 722                         this.anim_saveframe2time = this.anim_frame2time;
 723                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 724                         // This ensures that .frame etc. are always written.
 725                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 726                         this.lerpfrac = (doblend ? 0.5 : 0);
 727                         this.frame = this.anim_frame;
 728                         this.frame1time = this.anim_frame1time;
 729                         this.frame2 = this.anim_frame2;
 730                         this.frame2time = this.anim_frame2time;
 731                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 732                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 733                         if(doblend)
 734                         {
 735                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 736                         }
 737                         else
 738                         {
 739                                 free_skeleton_from_frames(this);
 740                                 // just in case, clear these (we're animating in frame and frame3)
 741                                 this.lerpfrac = 0;
 742                                 this.lerpfrac4 = 0;
 743                         }
 744                 }
 745         }
 746         else
 747                 CSQCPlayer_LOD_Apply(this, false);
 748
 749         CSQCModel_AutoTagIndex_Apply(this);
 750
 751         CSQCModel_Effects_Apply(this);
 752 }
 753
 754 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 755 {
 756         // interpolate v_angle
 757         this.iflags |= IFLAG_V_ANGLE_X;
 758         // revert to values from server
 759         CSQCModel_Effects_PreUpdate(this);
 760         if((this.isplayermodel & ISPLAYER_MODEL))
 761         {
 762                 if(!isplayer)
 763                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 764                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 765         }
 766 }
 767
 768 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 769 {
 770         // is it a player model? (shared state)
 771         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 772                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 773         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 774         this.csqcmodel_isdead = false; // workaround for dead players who become a spectator
 775
 776         // save values set by server
 777         if((this.isplayermodel & ISPLAYER_MODEL))
 778         {
 779                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 780                 if(isplayer)
 781                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 782                 else
 783                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 784         }
 785         CSQCModel_Effects_PostUpdate(this);
 786 }