qcsrc/client/hud/crosshair.qc

   1 #include "crosshair.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <client/view.qh>
   6 #include <common/deathtypes/all.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/mapobjects/trigger/viewloc.qh>
   9 #include <common/minigames/cl_minigames.qh>
  10 #include <common/minigames/cl_minigames_hud.qh>
  11 #include <common/mutators/mutator/overkill/oknex.qh>
  12 #include <common/vehicles/all.qh>
  13 #include <common/viewloc.qh>
  14 #include <common/wepent.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16
  17 float pickup_crosshair_time, pickup_crosshair_size;
  18 float hitindication_crosshair_size;
  19 float use_vortex_chargepool;
  20
  21 float reticle_type;
  22
  23 vector wcross_origin;
  24 float wcross_scale_prev, wcross_alpha_prev;
  25 vector wcross_color_prev;
  26 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
  27 vector wcross_color_goal_prev;
  28 float wcross_changedonetime;
  29
  30 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
  31 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
  32 float wcross_name_changestarttime, wcross_name_changedonetime;
  33 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
  34
  35 float wcross_ring_prev;
  36
  37 entity trueaim;
  38 entity trueaim_rifle;
  39
  40 const float SHOTTYPE_HITTEAM = 1;
  41 const float SHOTTYPE_HITOBSTRUCTION = 2;
  42 const float SHOTTYPE_HITWORLD = 3;
  43 const float SHOTTYPE_HITENEMY = 4;
  44
  45 void TrueAim_Init()
  46 {
  47         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  48         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  49 }
  50
  51 float EnemyHitCheck()
  52 {
  53         float t, n;
  54         wcross_origin = project_3d_to_2d(trace_endpos);
  55         wcross_origin.z = 0;
  56         if(trace_ent)
  57                 n = trace_ent.entnum;
  58         else
  59                 n = trace_networkentity;
  60         if(n < 1)
  61                 return SHOTTYPE_HITWORLD;
  62         if(n > maxclients)
  63                 return SHOTTYPE_HITWORLD;
  64         t = entcs_GetTeam(n - 1);
  65         if(teamplay)
  66                 if(t == myteam)
  67                         return SHOTTYPE_HITTEAM;
  68         if(t == NUM_SPECTATOR)
  69                 return SHOTTYPE_HITWORLD;
  70         return SHOTTYPE_HITENEMY;
  71 }
  72
  73 float TrueAimCheck(entity wepent)
  74 {
  75         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
  76                 return SHOTTYPE_HITWORLD;
  77
  78         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  79         vector vecs, trueaimpoint, w_shotorg;
  80         vector mi, ma, dv;
  81         float shottype;
  82         entity ta;
  83         float mv;
  84
  85         mi = ma = '0 0 0';
  86         ta = trueaim;
  87         mv = MOVE_NOMONSTERS;
  88
  89         switch(wepent.activeweapon) // WEAPONTODO
  90         {
  91                 case WEP_VORTEX:
  92                 case WEP_OVERKILL_NEX:
  93                 case WEP_VAPORIZER:
  94                         mv = MOVE_NORMAL;
  95                         break;
  96                 case WEP_RIFLE:
  97                         ta = trueaim_rifle;
  98                         mv = MOVE_NORMAL;
  99                         if(zoomscript_caught)
 100                         {
 101                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 102                                 return EnemyHitCheck();
 103                         }
 104                         break;
 105                 case WEP_DEVASTATOR: // projectile has a size!
 106                         mi = '-3 -3 -3';
 107                         ma = '3 3 3';
 108                         break;
 109                 case WEP_FIREBALL: // projectile has a size!
 110                         mi = '-16 -16 -16';
 111                         ma = '16 16 16';
 112                         break;
 113                 case WEP_SEEKER: // projectile has a size!
 114                         mi = '-2 -2 -2';
 115                         ma = '2 2 2';
 116                         break;
 117                 case WEP_ELECTRO: // projectile has a size!
 118                         mi = '0 0 -3';
 119                         ma = '0 0 -3';
 120                         break;
 121         }
 122
 123         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 124
 125         vecs = decompressShotOrigin(STAT(SHOTORG));
 126
 127         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 128         trueaimpoint = trace_endpos;
 129         // move trueaimpoint a little bit forward to make the final tracebox reliable
 130         // since it sometimes doesn't reach a teammate by a hair
 131         trueaimpoint += view_forward;
 132
 133         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 134                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 135
 136         if(vecs.x > 0)
 137                 vecs.y = -vecs.y;
 138         else
 139                 vecs = '0 0 0';
 140
 141         dv = view_right * vecs.y + view_up * vecs.z;
 142         w_shotorg = traceorigin + dv;
 143
 144         // now move the vecs forward as much as requested if possible
 145         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 146         w_shotorg = trace_endpos - view_forward * nudge;
 147
 148         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 149         shottype = EnemyHitCheck();
 150         if(shottype != SHOTTYPE_HITWORLD)
 151                 return shottype;
 152
 153 #if 0
 154         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 155         // or rather, I know why, but see no fix
 156         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 157                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 158                 return SHOTTYPE_HITOBSTRUCTION;
 159 #endif
 160
 161         return SHOTTYPE_HITWORLD;
 162 }
 163
 164 void HUD_Crosshair_Vehicle(entity this)
 165 {
 166         if(hud != HUD_BUMBLEBEE_GUN)
 167         {
 168                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 169                 info.vr_crosshair(info, this);
 170         }
 171 }
 172
 173 vector crosshair_getcolor(entity this, float health_stat)
 174 {
 175         static float rainbow_last_flicker;
 176         static vector rainbow_prev_color;
 177         vector wcross_color = '0 0 0';
 178         switch(autocvar_crosshair_color_special)
 179         {
 180                 case 1: // weapon color
 181                 {
 182                         if(this != WEP_Null && hud == HUD_NORMAL)
 183                         {
 184                                 wcross_color = this.wpcolor;
 185                                 break;
 186                         }
 187                         else { goto normalcolor; }
 188                 }
 189
 190                 case 2: // color based on health and armor
 191                 {
 192                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 193                         float health_and_armor = floor(v.x + 1);
 194                         wcross_color = HUD_Get_Num_Color(health_and_armor, 200, false);
 195                         break;
 196                 }
 197
 198                 case 3: // rainbow/random color
 199                 {
 200                         if(time >= rainbow_last_flicker)
 201                         {
 202                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 203                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 204                         }
 205                         wcross_color = rainbow_prev_color;
 206                         break;
 207                 }
 208 LABEL(normalcolor)
 209                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 210         }
 211
 212         return wcross_color;
 213 }
 214
 215 void HUD_Crosshair(entity this)
 216 {
 217         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
 218         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
 219                 csqcplayer.alpha = csqcplayer.m_alpha;
 220
 221         if (autocvar_chase_active > 0 && autocvar_chase_front)
 222         {
 223                 csqcplayer.alpha = csqcplayer.m_alpha;
 224                 return;
 225         }
 226
 227         float f, i, j;
 228         vector v;
 229         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
 230                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
 231                 && !HUD_MinigameMenu_IsOpened())
 232         {
 233                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 234                         return;
 235
 236                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 237                         return;
 238
 239                 if (hud != HUD_NORMAL)
 240                 {
 241                         HUD_Crosshair_Vehicle(this);
 242                         return;
 243                 }
 244
 245                 string wcross_style;
 246                 float wcross_alpha, wcross_resolution;
 247                 wcross_style = autocvar_crosshair;
 248                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 249                         wcross_style = autocvar_crosshair_2d;
 250                 if (wcross_style == "0")
 251                         return;
 252                 wcross_resolution = autocvar_crosshair_size;
 253                 if (wcross_resolution == 0)
 254                         return;
 255                 wcross_alpha = autocvar_crosshair_alpha;
 256                 if (wcross_alpha == 0)
 257                         return;
 258
 259                 // TrueAim check
 260                 float shottype;
 261
 262                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 263                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 264                         wcross_origin = viewloc_mousepos;
 265                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 266                 {
 267                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 268                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1)
 269                         {
 270                                 bool hit = false;
 271                                 if (pointinsidebox(view_origin, csqcplayer.absmin, csqcplayer.absmax))
 272                                         hit = true;
 273                                 else
 274                                 {
 275                                         WarpZone_TraceLine(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 276                                         if(trace_ent == csqcplayer)
 277                                                 hit = true;
 278                                 }
 279                                 if(hit)
 280                                 {
 281                                         float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 282                                         csqcplayer.alpha = min(autocvar_crosshair_chase_playeralpha, myalpha);
 283                                 }
 284                                 else
 285                                         csqcplayer.alpha = csqcplayer.m_alpha;
 286                         }
 287                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 288                         wcross_origin = project_3d_to_2d(trace_endpos);
 289                 }
 290                 else
 291                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 292                 wcross_origin.z = 0;
 293                 if(autocvar_crosshair_hittest)
 294                 {
 295                         vector wcross_oldorigin;
 296                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 297                         wcross_oldorigin = wcross_origin;
 298                         shottype = TrueAimCheck(thiswep);
 299                         if(shottype == SHOTTYPE_HITWORLD)
 300                         {
 301                                 v = wcross_origin - wcross_oldorigin;
 302                                 v.x /= vid_conwidth;
 303                                 v.y /= vid_conheight;
 304                                 if(vdist(v, >, 0.01))
 305                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 306                         }
 307                         if(!autocvar_crosshair_hittest_showimpact)
 308                                 wcross_origin = wcross_oldorigin;
 309                 }
 310                 else
 311                         shottype = SHOTTYPE_HITWORLD;
 312
 313                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 314                 string wcross_name = "";
 315                 float wcross_scale, wcross_blur;
 316
 317                 entity e = WEP_Null;
 318                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 319                 {
 320                         entity wepent = viewmodels[0]; // TODO: unhardcode
 321                         e = wepent.switchingweapon;
 322                         if(e)
 323                         {
 324                                 if(autocvar_crosshair_per_weapon)
 325                                 {
 326                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 327                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 328                                         //if (wcross_resolution == 0)
 329                                                 //return;
 330
 331                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 332                                         wcross_resolution *= e.w_crosshair_size;
 333                                         wcross_name = e.w_crosshair;
 334                                 }
 335                         }
 336                 }
 337
 338                 if(wcross_name == "")
 339                         wcross_name = strcat("gfx/crosshair", wcross_style);
 340
 341                 // MAIN CROSSHAIR COLOR DECISION
 342                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
 343
 344                 if(autocvar_crosshair_effect_scalefade)
 345                 {
 346                         wcross_scale = wcross_resolution;
 347                         wcross_resolution = 1;
 348                 }
 349                 else
 350                 {
 351                         wcross_scale = 1;
 352                 }
 353
 354                 if(autocvar_crosshair_pickup)
 355                 {
 356                         float stat_pickup_time = STAT(LAST_PICKUP);
 357
 358                         if(pickup_crosshair_time < stat_pickup_time)
 359                         {
 360                                 if(time - stat_pickup_time < 5) // don't trigger the animation if it's too old
 361                                         pickup_crosshair_size = 1;
 362
 363                                 pickup_crosshair_time = stat_pickup_time;
 364                         }
 365
 366                         if(pickup_crosshair_size > 0)
 367                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 368                         else
 369                                 pickup_crosshair_size = 0;
 370
 371                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 372                 }
 373
 374                 // todo: make crosshair hit indication dependent on damage dealt
 375                 if(autocvar_crosshair_hitindication)
 376                 {
 377                         vector col = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 378
 379                         if(unaccounted_damage)
 380                         {
 381                                 hitindication_crosshair_size = 1;
 382                         }
 383
 384                         if(hitindication_crosshair_size > 0)
 385                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 386                         else
 387                                 hitindication_crosshair_size = 0;
 388
 389                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 390                         wcross_color.x += sin(hitindication_crosshair_size) * col.x;
 391                         wcross_color.y += sin(hitindication_crosshair_size) * col.y;
 392                         wcross_color.z += sin(hitindication_crosshair_size) * col.z;
 393                 }
 394
 395                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
 396                 // just show for teammates to give a sign that they're an invalid target
 397                 //if(shottype == SHOTTYPE_HITENEMY)
 398                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 399                 if(shottype == SHOTTYPE_HITTEAM)
 400                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 401
 402                 f = fabs(autocvar_crosshair_effect_time);
 403                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 404                 {
 405                         wcross_changedonetime = time + f;
 406                 }
 407                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 408                 {
 409                         wcross_name_changestarttime = time;
 410                         wcross_name_changedonetime = time + f;
 411                         if(wcross_name_goal_prev_prev)
 412                                 strunzone(wcross_name_goal_prev_prev);
 413                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 414                         wcross_name_goal_prev = strzone(wcross_name);
 415                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 416                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 417                         wcross_resolution_goal_prev = wcross_resolution;
 418                 }
 419
 420                 wcross_scale_goal_prev = wcross_scale;
 421                 wcross_alpha_goal_prev = wcross_alpha;
 422                 wcross_color_goal_prev = wcross_color;
 423
 424                 if((shottype == SHOTTYPE_HITTEAM && autocvar_crosshair_hittest_blur_teammate)
 425                         || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur_wall && !autocvar_chase_active))
 426                 {
 427                         wcross_blur = 1;
 428                         wcross_alpha *= 0.75;
 429                 }
 430                 else
 431                         wcross_blur = 0;
 432                 // *_prev is at time-frametime
 433                 // * is at wcross_changedonetime+f
 434                 // what do we have at time?
 435                 if(time < wcross_changedonetime)
 436                 {
 437                         f = frametime / (wcross_changedonetime - time + frametime);
 438                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 439                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 440                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 441                 }
 442
 443                 wcross_scale_prev = wcross_scale;
 444                 wcross_alpha_prev = wcross_alpha;
 445                 wcross_color_prev = wcross_color;
 446
 447                 MUTATOR_CALLHOOK(UpdateCrosshair);
 448
 449                 wcross_scale *= 1 - autocvar__menu_alpha;
 450                 wcross_alpha *= 1 - autocvar__menu_alpha;
 451                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 452
 453                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 454                 {
 455                         // crosshair rings for weapon stats
 456                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 457                         {
 458                                 // declarations and stats
 459                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 460                                 string ring_image = string_null, ring_inner_image = string_null;
 461                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 462
 463                                 ring_scale = autocvar_crosshair_ring_size;
 464
 465                                 entity wepent = viewmodels[0]; // TODO: unhardcode
 466
 467                                 int weapon_clipload = wepent.clip_load;
 468                                 int weapon_clipsize = wepent.clip_size;
 469
 470                                 float arc_heat = wepent.arc_heat_percent;
 471
 472                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 473                                         vortex_charge_movingavg = wepent.vortex_charge;
 474
 475                                 float charge = 0;
 476                                 float chargepool = 0;
 477                                 bool ring_vortex_enabled = false;
 478                                 if (autocvar_crosshair_ring && autocvar_crosshair_ring_vortex)
 479                                 {
 480                                         if (wepent.activeweapon == WEP_VORTEX)
 481                                         {
 482                                                 charge = wepent.vortex_charge;
 483                                                 chargepool = wepent.vortex_chargepool_ammo;
 484                                         }
 485                                         else if (wepent.activeweapon == WEP_OVERKILL_NEX)
 486                                         {
 487                                                 charge = wepent.oknex_charge;
 488                                                 chargepool = wepent.oknex_chargepool_ammo;
 489                                         }
 490                                         if (charge)
 491                                                 ring_vortex_enabled = true;
 492                                 }
 493
 494                                 if (ring_vortex_enabled)
 495                                 {
 496                                         if (chargepool || use_vortex_chargepool) {
 497                                                 use_vortex_chargepool = 1;
 498                                                 ring_inner_value = chargepool;
 499                                         } else {
 500                                                 float rate = autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate;
 501                                                 vortex_charge_movingavg = (1 - rate) * vortex_charge_movingavg + rate * charge;
 502                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (charge - vortex_charge_movingavg), 1);
 503                                         }
 504
 505                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 506                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
 507                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 508
 509                                         // draw the outer ring to show the current charge of the weapon
 510                                         ring_value = charge;
 511                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 512                                         ring_rgb = wcross_color;
 513                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 514                                 }
 515                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
 516                                 {
 517                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1);
 518                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 519                                         ring_rgb = wcross_color;
 520                                         ring_image = "gfx/crosshair_ring.tga";
 521                                 }
 522                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
 523                                 {
 524                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
 525                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 526                                         ring_rgb = wcross_color;
 527                                         ring_image = "gfx/crosshair_ring.tga";
 528                                 }
 529                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 530                                 {
 531                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 532                                         ring_scale = autocvar_crosshair_ring_reload_size;
 533                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 534                                         ring_rgb = wcross_color;
 535
 536                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 537                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 538                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 539                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 540                                         else
 541                                                 ring_image = "gfx/crosshair_ring.tga";
 542                                 }
 543                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
 544                                 {
 545                                         ring_value = arc_heat;
 546                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 547                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 548                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 549                                         ring_image = "gfx/crosshair_ring.tga";
 550                                 }
 551
 552                                 // if in weapon switch animation, fade ring out/in
 553                                 if(autocvar_crosshair_effect_time > 0)
 554                                 {
 555                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 556                                         if (f >= 1)
 557                                         {
 558                                                 wcross_ring_prev = ((ring_image) ? true : false);
 559                                         }
 560
 561                                         if(wcross_ring_prev)
 562                                         {
 563                                                 if(f < 1)
 564                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 565                                         }
 566                                         else
 567                                         {
 568                                                 if(f < 1)
 569                                                         ring_alpha *= bound(0, f, 1);
 570                                         }
 571                                 }
 572
 573                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 574                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 575
 576                                 if (ring_value)
 577                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 578                         }
 579
 580 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 581                         MACRO_BEGIN \
 582                                 vector scaled_sz = sz * wcross_size; \
 583                                 if(wcross_blur > 0) \
 584                                 { \
 585                                         for(i = -2; i <= 2; ++i) \
 586                                         for(j = -2; j <= 2; ++j) \
 587                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
 588                                 } \
 589                                 else \
 590                                 { \
 591                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
 592                                 } \
 593                         MACRO_END
 594
 595 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
 596                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 597
 598 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 599                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 600
 601                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 602                         {
 603                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 604                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 605                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 606                                 f = 1 - f;
 607                         }
 608                         else
 609                         {
 610                                 f = 1;
 611                         }
 612                         wcross_name_alpha_goal_prev = f;
 613
 614                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 615                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 616
 617                         if(autocvar_crosshair_dot)
 618                         {
 619                                 vector wcross_color_old;
 620                                 wcross_color_old = wcross_color;
 621
 622                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 623                                         wcross_color = stov(autocvar_crosshair_dot_color);
 624
 625                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 626                                 // FIXME why don't we use wcross_alpha here?
 627                                 wcross_color = wcross_color_old;
 628                         }
 629                 }
 630         }
 631         else
 632         {
 633                 wcross_scale_prev = 0;
 634                 wcross_alpha_prev = 0;
 635                 wcross_scale_goal_prev = 0;
 636                 wcross_alpha_goal_prev = 0;
 637                 wcross_changedonetime = 0;
 638                 strfree(wcross_name_goal_prev);
 639                 strfree(wcross_name_goal_prev_prev);
 640                 wcross_name_changestarttime = 0;
 641                 wcross_name_changedonetime = 0;
 642                 wcross_name_alpha_goal_prev = 0;
 643                 wcross_name_alpha_goal_prev_prev = 0;
 644                 wcross_resolution_goal_prev = 0;
 645                 wcross_resolution_goal_prev_prev = 0;
 646         }
 647 }
 648
 649 void DrawReticle(entity this)
 650 {
 651         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
 652         {
 653                 reticle_type = 0;
 654                 return;
 655         }
 656
 657         float is_dead = (STAT(HEALTH) <= 0);
 658         string reticle_image = string_null;
 659         bool wep_zoomed = false;
 660         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 661         {
 662                 entity wepe = viewmodels[slot];
 663                 Weapon wep = wepe.activeweapon;
 664                 if(wep != WEP_Null && wep.wr_zoom)
 665                 {
 666                         bool do_zoom = wep.wr_zoom(wep, NULL);
 667                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
 668                                 reticle_image = wep.w_reticle;
 669                         wep_zoomed += do_zoom;
 670                 }
 671         }
 672         // Draw the aiming reticle for weapons that use it
 673         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 674         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 675         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 676         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
 677         {
 678                 // no zoom reticle while dead
 679                 reticle_type = 0;
 680         }
 681         else if(wep_zoomed && autocvar_cl_reticle_weapon)
 682         {
 683                 if(reticle_image) { reticle_type = 2; }
 684                 else { reticle_type = 0; }
 685         }
 686         else if(button_zoom || zoomscript_caught)
 687         {
 688                 // normal zoom
 689                 reticle_type = 1;
 690         }
 691
 692         if(reticle_type)
 693         {
 694                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 695                 if(autocvar_cl_reticle_stretch)
 696                 {
 697                         reticle_size.x = vid_conwidth;
 698                         reticle_size.y = vid_conheight;
 699                         reticle_pos.x = 0;
 700                         reticle_pos.y = 0;
 701                 }
 702                 else
 703                 {
 704                         reticle_size.x = max(vid_conwidth, vid_conheight);
 705                         reticle_size.y = max(vid_conwidth, vid_conheight);
 706                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
 707                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
 708                 }
 709
 710                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
 711
 712                 if(f)
 713                 {
 714                         switch(reticle_type)
 715                         {
 716                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 717                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 718                         }
 719                 }
 720         }
 721 }