qcsrc/client/hud/hud.qh

   1 #ifndef CLIENT_HUD_H
   2 #define CLIENT_HUD_H
   3
   4 #include "../common/weapons/all.qh"
   5
   6 bool HUD_Radar_Clickable();
   7 void HUD_Radar_Mouse();
   8
   9 REGISTRY(hud_panels, BITS(6))
  10 #define hud_panels_from(i) _hud_panels_from(i, NULL)
  11 REGISTER_REGISTRY(hud_panels)
  12
  13 #define REGISTER_HUD_PANEL(id, draw_func, name, configflags, showflags) \
  14         void draw_func(); \
  15         REGISTER(hud_panels, HUD_PANEL, id, m_id, new(hud_panel)) { \
  16                 make_pure(this); \
  17                 this.panel_id = this.m_id; \
  18                 this.panel_draw = draw_func; \
  19                 this.panel_name = #name; \
  20                 this.panel_configflags = configflags; \
  21                 this.panel_showflags = showflags; \
  22         }
  23
  24 #define HUD_PANEL(NAME) HUD_PANEL_##NAME
  25
  26 // draw the background/borders
  27 #define HUD_Panel_DrawBg(theAlpha) MACRO_BEGIN {                                                                                                                                                                \
  28         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
  29                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
  30 } MACRO_END
  31
  32 int panel_order[hud_panels_MAX];
  33 string hud_panelorder_prev;
  34
  35 bool hud_draw_maximized;
  36 bool hud_panel_radar_maximized;
  37 bool hud_panel_radar_mouse;
  38 float hud_panel_radar_bottom;
  39 bool hud_panel_radar_temp_hidden;
  40 bool chat_panel_modified;
  41 bool radar_panel_modified;
  42
  43 float HUD_Radar_InputEvent(float bInputType, float nPrimary, float nSecondary);
  44 void HUD_Radar_Hide_Maximized();
  45
  46 void HUD_Reset ();
  47 void HUD_Main ();
  48
  49 int vote_yescount;
  50 int vote_nocount;
  51 int vote_needed;
  52 int vote_highlighted; // currently selected vote
  53
  54 int vote_active; // is there an active vote?
  55 int vote_prev; // previous state of vote_active to check for a change
  56 float vote_alpha;
  57 float vote_change; // "time" when vote_active changed
  58
  59 float hud_panel_quickmenu;
  60
  61 vector mousepos;
  62 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  63 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  64 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  65 entity highlightedPanel;
  66 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  67
  68 const float BORDER_MULTIPLIER = 0.25;
  69 float scoreboard_bottom;
  70 int weapon_accuracy[Weapons_MAX];
  71
  72 int complain_weapon;
  73 float complain_weapon_type;
  74 float complain_weapon_time;
  75
  76 int ps_primary, ps_secondary;
  77 int ts_primary, ts_secondary;
  78
  79 Weapon last_switchweapon;
  80 Weapon last_activeweapon;
  81 float weapontime;
  82 float weaponprevtime;
  83
  84 float teamnagger;
  85
  86 float hud_configure_checkcollisions;
  87 float hud_configure_prev;
  88 vector hud_configure_gridSize;
  89 vector hud_configure_realGridSize;
  90
  91 int hudShiftState;
  92 const int S_SHIFT = 1;
  93 const int S_CTRL = 2;
  94 const int S_ALT = 4;
  95
  96 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  97
  98 float hud_fade_alpha;
  99
 100 string hud_skin_path;
 101 string hud_skin_prev;
 102
 103 vector myteamcolors;
 104
 105 entity highlightedPanel_backup;
 106 vector panel_pos_backup;
 107 vector panel_size_backup;
 108
 109 vector panel_size_copied;
 110
 111 entity panel;
 112 entityclass(HUDPanel);
 113 class(HUDPanel) .string panel_name;
 114 class(HUDPanel) .int panel_id;
 115 class(HUDPanel) .vector current_panel_pos;
 116 class(HUDPanel) .vector current_panel_size;
 117 class(HUDPanel) .string current_panel_bg;
 118 class(HUDPanel) .float current_panel_bg_alpha;
 119 class(HUDPanel) .float current_panel_bg_border;
 120 class(HUDPanel) .vector current_panel_bg_color;
 121 class(HUDPanel) .float current_panel_bg_color_team;
 122 class(HUDPanel) .float current_panel_bg_padding;
 123 class(HUDPanel) .float current_panel_fg_alpha;
 124 class(HUDPanel) .float update_time;
 125 float panel_enabled;
 126 vector panel_pos;
 127 vector panel_size;
 128 string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
 129 vector panel_bg_color;
 130 string panel_bg_color_str;
 131 float panel_bg_color_team;
 132 string panel_bg_color_team_str;
 133 float panel_fg_alpha;
 134 float panel_bg_alpha;
 135 string panel_bg_alpha_str;
 136 float panel_bg_border;
 137 string panel_bg_border_str;
 138 float panel_bg_padding;
 139 string panel_bg_padding_str;
 140
 141 class(HUDPanel) .void() panel_draw;
 142
 143 // chat panel can be reduced / moved while the mapvote is active
 144 // let know the mapvote panel about chat pos and size
 145 float chat_posy;
 146 float chat_sizey;
 147
 148 float current_player;
 149
 150 float stringwidth_colors(string s, vector theSize);
 151 float stringwidth_nocolors(string s, vector theSize);
 152 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag);
 153
 154 .int panel_showflags;
 155 const int PANEL_SHOW_NEVER    = 0x00;
 156 const int PANEL_SHOW_MAINGAME = 0x01;
 157 const int PANEL_SHOW_MINIGAME = 0x02;
 158 const int PANEL_SHOW_MAPVOTE  = 0x04;
 159 const int PANEL_SHOW_ALWAYS   = 0xff;
 160 bool HUD_Panel_CheckFlags(int showflags);
 161
 162 .int panel_configflags;
 163 const int PANEL_CONFIG_NO    = 0x00;
 164 const int PANEL_CONFIG_MAIN  = 0x01;
 165
 166
 167 // prev_* vars contain the health/armor at the previous FRAME
 168 // set to -1 when player is dead or was not playing
 169 int prev_health, prev_armor;
 170 float health_damagetime, armor_damagetime;
 171 int health_beforedamage, armor_beforedamage;
 172 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
 173 int old_p_health, old_p_armor;
 174 float old_p_healthtime, old_p_armortime;
 175 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
 176 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
 177 int prev_p_health, prev_p_armor;
 178
 179 void HUD_ItemsTime();
 180
 181 REGISTER_HUD_PANEL(WEAPONS,         HUD_Weapons,        weapons,        PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 182 REGISTER_HUD_PANEL(AMMO,            HUD_Ammo,           ammo,           PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 183 REGISTER_HUD_PANEL(POWERUPS,        HUD_Powerups,       powerups,       PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 184 REGISTER_HUD_PANEL(HEALTHARMOR,     HUD_HealthArmor,    healtharmor,    PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 185 REGISTER_HUD_PANEL(NOTIFY,          HUD_Notify,         notify,         PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS & ~PANEL_SHOW_MAPVOTE)
 186 REGISTER_HUD_PANEL(TIMER,           HUD_Timer,          timer,          PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS & ~PANEL_SHOW_MAPVOTE)
 187 REGISTER_HUD_PANEL(RADAR,           HUD_Radar,          radar,          PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 188 REGISTER_HUD_PANEL(SCORE,           HUD_Score,          score,          PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS & ~PANEL_SHOW_MAPVOTE)
 189 REGISTER_HUD_PANEL(RACETIMER,       HUD_RaceTimer,      racetimer,      PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 190 REGISTER_HUD_PANEL(VOTE,            HUD_Vote,           vote,           PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS  )
 191 REGISTER_HUD_PANEL(MODICONS,        HUD_ModIcons,       modicons,       PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 192 REGISTER_HUD_PANEL(PRESSEDKEYS,     HUD_PressedKeys,    pressedkeys,    PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 193 REGISTER_HUD_PANEL(CHAT,            HUD_Chat,           chat,           PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS  )
 194 REGISTER_HUD_PANEL(ENGINEINFO,      HUD_EngineInfo,     engineinfo,     PANEL_CONFIG_MAIN, PANEL_SHOW_ALWAYS  )
 195 REGISTER_HUD_PANEL(INFOMESSAGES,    HUD_InfoMessages,   infomessages,   PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 196 REGISTER_HUD_PANEL(PHYSICS,         HUD_Physics,        physics,        PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 197 REGISTER_HUD_PANEL(CENTERPRINT,     HUD_CenterPrint,    centerprint,    PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 198 REGISTER_HUD_PANEL(MINIGAME_BOARD,  HUD_MinigameBoard,  minigameboard,  PANEL_CONFIG_NO  , PANEL_SHOW_MINIGAME)
 199 REGISTER_HUD_PANEL(MINIGAME_STATUS, HUD_MinigameStatus, minigamestatus, PANEL_CONFIG_NO  , PANEL_SHOW_MINIGAME)
 200 REGISTER_HUD_PANEL(MINIGAME_HELP,   HUD_MinigameHelp,   minigamehelp,   PANEL_CONFIG_NO  , PANEL_SHOW_MINIGAME)
 201 REGISTER_HUD_PANEL(MINIGAME_MENU,   HUD_MinigameMenu,   minigamemenu,   PANEL_CONFIG_NO  , PANEL_SHOW_ALWAYS  )
 202 REGISTER_HUD_PANEL(MAPVOTE,         MapVote_Draw,       mapvote,        PANEL_CONFIG_NO  , PANEL_SHOW_MAPVOTE )
 203 REGISTER_HUD_PANEL(ITEMSTIME,       HUD_ItemsTime,      itemstime,      PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 204 REGISTER_HUD_PANEL(QUICKMENU,       HUD_QuickMenu,      quickmenu,      PANEL_CONFIG_MAIN, PANEL_SHOW_MAINGAME)
 205 // always add new panels to the end of list
 206
 207 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 208 // ----------------------
 209 // MACRO HELL STARTS HERE
 210 // ----------------------
 211 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 212
 213 // Get value for panel.current_panel_bg: if "" fetch default, else use panel_bg_str
 214 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 215 #define HUD_Panel_GetBg() MACRO_BEGIN {                                                                             \
 216         string panel_bg;                                                                                                \
 217         if (!autocvar__hud_configure && panel_bg_str == "0") {                                                          \
 218                 panel_bg = "0";                                                                                             \
 219         } else {                                                                                                        \
 220                 if (panel_bg_str == "") {                                                                                   \
 221                         panel_bg_str = autocvar_hud_panel_bg;                                                                   \
 222                 }                                                                                                           \
 223                 if (panel_bg_str == "0" && !autocvar__hud_configure) {                                                      \
 224                         panel_bg = "0";                                                                                         \
 225                 } else {                                                                                                    \
 226                         if (panel_bg_str == "0" && autocvar__hud_configure)                                                     \
 227                                 panel_bg_alpha_str = "0";                                                                           \
 228                         panel_bg = strcat(hud_skin_path, "/", panel_bg_str);                                                    \
 229                         if (precache_pic(panel_bg) == "") {                                                                     \
 230                                 panel_bg = strcat(hud_skin_path, "/", "border_default");                                            \
 231                                 if (precache_pic(panel_bg) == "") {                                                                 \
 232                                         panel_bg = strcat("gfx/hud/default/", "border_default");                                        \
 233                                 }                                                                                                   \
 234                         }                                                                                                       \
 235                 }                                                                                                           \
 236         }                                                                                                               \
 237         if (panel.current_panel_bg)                                                                                     \
 238                 strunzone(panel.current_panel_bg);                                                                          \
 239         panel.current_panel_bg = strzone(panel_bg);                                                                     \
 240 } MACRO_END
 241
 242 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 243 #define HUD_Panel_GetColor() MACRO_BEGIN {                                                                          \
 244         if ((teamplay) && panel_bg_color_team) {                                                                        \
 245                 if (autocvar__hud_configure && myteam == NUM_SPECTATOR)                                                     \
 246                         panel_bg_color = '1 0 0' * panel_bg_color_team;                                                         \
 247                 else                                                                                                        \
 248                         panel_bg_color = myteamcolors * panel_bg_color_team;                                                    \
 249         } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {          \
 250                 panel_bg_color = '1 0 0' * panel_bg_color_team;                                                             \
 251         } else {                                                                                                        \
 252                 if (panel_bg_color_str == "") {                                                                             \
 253                         panel_bg_color = autocvar_hud_panel_bg_color;                                                           \
 254                 } else {                                                                                                    \
 255                         if (panel_bg_color_str == "shirt") {                                                                    \
 256                                 panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player, "colors")) / 16), 0); \
 257                         } else if (panel_bg_color_str == "pants") {                                                             \
 258                                 panel_bg_color = colormapPaletteColor(stof(getplayerkeyvalue(current_player, "colors")) % 16, 1); \
 259                         } else {                                                                                                \
 260                                 panel_bg_color = stov(panel_bg_color_str);                                                          \
 261                         }                                                                                                       \
 262                 }                                                                                                           \
 263         }                                                                                                               \
 264 } MACRO_END
 265
 266 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 267 #define HUD_Panel_GetColorTeam() MACRO_BEGIN {                                                                      \
 268         if (panel_bg_color_team_str == "") {                                                                            \
 269                 panel_bg_color_team = autocvar_hud_panel_bg_color_team;                                                     \
 270         } else {                                                                                                        \
 271                 panel_bg_color_team = stof(panel_bg_color_team_str);                                                        \
 272         }                                                                                                               \
 273 } MACRO_END
 274
 275 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 276 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 277 #define HUD_Panel_GetBgAlpha() MACRO_BEGIN {                                                                        \
 278         if (panel_bg_alpha_str == "") {                                                                                 \
 279                 panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);                                                     \
 280         }                                                                                                               \
 281         panel_bg_alpha = stof(panel_bg_alpha_str);                                                                      \
 282         if (autocvar__hud_configure) {                                                                                  \
 283                 if (!panel_enabled)                                                                                         \
 284                         panel_bg_alpha = 0.25;                                                                                  \
 285                 else if (menu_enabled == 2 && panel == highlightedPanel)                                                    \
 286                         panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 287                 else                                                                                                        \
 288                         panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);                                \
 289         }                                                                                                               \
 290 } MACRO_END
 291
 292 // Get value for panel_fg_alpha. Also do various minalpha checks
 293 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 294 #define HUD_Panel_GetFgAlpha() MACRO_BEGIN {                                                                        \
 295         panel_fg_alpha = autocvar_hud_panel_fg_alpha;                                                                   \
 296         if (autocvar__hud_configure && !panel_enabled)                                                                  \
 297                 panel_fg_alpha = 0.25;                                                                                      \
 298 } MACRO_END
 299
 300 // Get border. See comments above, it's similar.
 301 #define HUD_Panel_GetBorder() MACRO_BEGIN {                                                                         \
 302         if (panel_bg_border_str == "") {                                                                                \
 303                 panel_bg_border = autocvar_hud_panel_bg_border;                                                             \
 304         } else {                                                                                                        \
 305                 panel_bg_border = stof(panel_bg_border_str);                                                                \
 306         }                                                                                                               \
 307 } MACRO_END
 308
 309 // Get padding. See comments above, it's similar.
 310 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 311 #define HUD_Panel_GetPadding() MACRO_BEGIN {                                                                        \
 312         if (panel_bg_padding_str == "") {                                                                               \
 313                 panel_bg_padding = autocvar_hud_panel_bg_padding;                                                           \
 314         } else {                                                                                                        \
 315                 panel_bg_padding = stof(panel_bg_padding_str);                                                              \
 316         }                                                                                                               \
 317         panel_bg_padding = min(min(panel_size.x, panel_size.y)/2 - 5, panel_bg_padding);                                \
 318 } MACRO_END
 319
 320 // return smoothly faded pos and size of given panel when a dialog is active
 321 // don't center too wide panels, it doesn't work with different resolutions
 322 #define HUD_Panel_UpdatePosSize_ForMenu() MACRO_BEGIN { \
 323         vector menu_enable_size = panel_size; \
 324         float max_panel_width = 0.52 * vid_conwidth; \
 325         if(panel_size.x > max_panel_width) \
 326         { \
 327                 menu_enable_size.x = max_panel_width; \
 328                 menu_enable_size.y = panel_size.y * (menu_enable_size.x / panel_size.x); \
 329         } \
 330         vector menu_enable_pos = eX * (panel_bg_border + 0.5 * max_panel_width) + eY * 0.5 * vid_conheight - 0.5 * menu_enable_size; \
 331         panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_pos; \
 332         panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size; \
 333 } MACRO_END
 334
 335 // Scale the pos and size vectors to absolute coordinates
 336 #define HUD_Panel_ScalePosSize() MACRO_BEGIN {                                                                      \
 337         panel_pos.x *= vid_conwidth;  panel_pos.y *= vid_conheight;                                                     \
 338         panel_size.x *= vid_conwidth; panel_size.y *= vid_conheight;                                                    \
 339 } MACRO_END
 340
 341 // NOTE: in hud_configure mode cvars must be reloaded every frame
 342 #define HUD_Panel_UpdateCvars() MACRO_BEGIN {                                                                       \
 343         if (panel.update_time <= time) {                                                                                \
 344                 if (autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name));                  \
 345                 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));                              \
 346                 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));                            \
 347                 HUD_Panel_ScalePosSize();                                                                                   \
 348                 panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg"));                                  \
 349                 panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color"));                      \
 350                 panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team"));            \
 351                 panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha"));                      \
 352                 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));                    \
 353                 panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding"));                  \
 354                 HUD_Panel_GetBg();                                                                                          \
 355                 if (panel.current_panel_bg != "0") {                                                                        \
 356                         HUD_Panel_GetColorTeam();                                                                               \
 357                         HUD_Panel_GetColor();                                                                                   \
 358                         HUD_Panel_GetBgAlpha();                                                                                 \
 359                         HUD_Panel_GetBorder();                                                                                  \
 360                 }                                                                                                           \
 361                 HUD_Panel_GetFgAlpha();                                                                                     \
 362                 HUD_Panel_GetPadding();                                                                                     \
 363                 panel.current_panel_bg_alpha = panel_bg_alpha;                                                              \
 364                 panel.current_panel_fg_alpha = panel_fg_alpha;                                                              \
 365                 if (menu_enabled == 2 && panel == highlightedPanel) {                                                       \
 366                         HUD_Panel_UpdatePosSize_ForMenu();                                                                      \
 367                 } else {                                                                                                    \
 368                         panel_bg_alpha *= hud_fade_alpha;                                                                       \
 369                         panel_fg_alpha *= hud_fade_alpha;                                                                       \
 370                 }                                                                                                           \
 371                 panel.current_panel_pos = panel_pos;                                                                        \
 372                 panel.current_panel_size = panel_size;                                                                      \
 373                 panel.current_panel_bg_border = panel_bg_border;                                                            \
 374                 panel.current_panel_bg_color = panel_bg_color;                                                              \
 375                 panel.current_panel_bg_color_team = panel_bg_color_team;                                                    \
 376                 panel.current_panel_bg_padding = panel_bg_padding;                                                          \
 377                 panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval;           \
 378         } else {                                                                                                        \
 379                 panel_pos = panel.current_panel_pos;                                                                        \
 380                 panel_size = panel.current_panel_size;                                                                      \
 381                 panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha;                                             \
 382                 panel_bg_border = panel.current_panel_bg_border;                                                            \
 383                 panel_bg_color = panel.current_panel_bg_color;                                                              \
 384                 panel_bg_color_team = panel.current_panel_bg_color_team;                                                    \
 385                 panel_bg_padding = panel.current_panel_bg_padding;                                                          \
 386                 panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha;                                             \
 387         }                                                                                                               \
 388 } MACRO_END
 389
 390 #define HUD_Panel_UpdatePosSize() MACRO_BEGIN {                                                                     \
 391         panel_enabled = cvar(strcat("hud_panel_", panel.panel_name));                                                   \
 392         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));                                  \
 393         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));                                \
 394         HUD_Panel_ScalePosSize();                                                                                       \
 395         if (menu_enabled == 2 && panel == highlightedPanel) {                                                           \
 396                 HUD_Panel_UpdatePosSize_ForMenu();                                                                          \
 397         }                                                                                                               \
 398         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));                        \
 399         HUD_Panel_GetBorder();                                                                                          \
 400 } MACRO_END
 401
 402 const int NOTIFY_MAX_ENTRIES = 10;
 403 const float NOTIFY_ICON_MARGIN = 0.02;
 404
 405 int notify_index;
 406 int notify_count;
 407 float notify_times[NOTIFY_MAX_ENTRIES];
 408 string notify_attackers[NOTIFY_MAX_ENTRIES];
 409 string notify_victims[NOTIFY_MAX_ENTRIES];
 410 string notify_icons[NOTIFY_MAX_ENTRIES];
 411
 412 void HUD_Notify_Push(string icon, string attacker, string victim);
 413
 414 var void HUD_ModIcons_GameType(vector pos, vector size);
 415 void HUD_ModIcons_SetFunc();
 416 #endif