qcsrc/client/hud/panel/modicons.qc

   1 #include "modicons.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/ent_cs.qh>
   5 #include <server/mutators/mutator/gamemode_ctf.qh> // TODO: remove
   6
   7 // Mod icons panel (#10)
   8
   9 bool mod_active; // is there any active mod icon?
  10
  11 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
  12 {
  13     TC(int, layout); TC(int, i);
  14         int stat = -1;
  15         string pic = "";
  16         vector color = '0 0 0';
  17         switch(i)
  18         {
  19                 case 0:
  20                         stat = STAT(REDALIVE);
  21                         pic = "player_red.tga";
  22                         color = '1 0 0';
  23                         break;
  24                 case 1:
  25                         stat = STAT(BLUEALIVE);
  26                         pic = "player_blue.tga";
  27                         color = '0 0 1';
  28                         break;
  29                 case 2:
  30                         stat = STAT(YELLOWALIVE);
  31                         pic = "player_yellow.tga";
  32                         color = '1 1 0';
  33                         break;
  34                 default:
  35                 case 3:
  36                         stat = STAT(PINKALIVE);
  37                         pic = "player_pink.tga";
  38                         color = '1 0 1';
  39                         break;
  40         }
  41
  42         if(mySize.x/mySize.y > aspect_ratio)
  43         {
  44                 i = aspect_ratio * mySize.y;
  45                 myPos.x = myPos.x + (mySize.x - i) / 2;
  46                 mySize.x = i;
  47         }
  48         else
  49         {
  50                 i = 1/aspect_ratio * mySize.x;
  51                 myPos.y = myPos.y + (mySize.y - i) / 2;
  52                 mySize.y = i;
  53         }
  54
  55         if(layout)
  56         {
  57                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  58                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  59         }
  60         else
  61                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
  62 }
  63
  64 // Clan Arena and Freeze Tag HUD modicons
  65 void HUD_Mod_CA(vector myPos, vector mySize)
  66 {
  67         mod_active = 1; // required in each mod function that always shows something
  68
  69         int layout;
  70         if(gametype == MAPINFO_TYPE_CA)
  71                 layout = autocvar_hud_panel_modicons_ca_layout;
  72         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
  73                 layout = autocvar_hud_panel_modicons_freezetag_layout;
  74         int rows, columns;
  75         float aspect_ratio;
  76         aspect_ratio = (layout) ? 2 : 1;
  77         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
  78         columns = ceil(team_count/rows);
  79
  80         int i;
  81         float row = 0, column = 0;
  82         vector pos, itemSize;
  83         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
  84         for(i=0; i<team_count; ++i)
  85         {
  86                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
  87
  88                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
  89
  90                 ++row;
  91                 if(row >= rows)
  92                 {
  93                         row = 0;
  94                         ++column;
  95                 }
  96         }
  97 }
  98
  99 // CTF HUD modicon section
 100 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
 101 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
 102 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
 103
 104 void HUD_Mod_CTF_Reset()
 105 {
 106         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
 107         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
 108         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
 109 }
 110
 111 int autocvar__teams_available;
 112 void HUD_Mod_CTF(vector pos, vector mySize)
 113 {
 114         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
 115         vector flag_size;
 116         float f; // every function should have that
 117
 118         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
 119         float redflag_statuschange_elapsedtime = 0, blueflag_statuschange_elapsedtime = 0, yellowflag_statuschange_elapsedtime = 0, pinkflag_statuschange_elapsedtime = 0, neutralflag_statuschange_elapsedtime = 0; // time since the status changed
 120         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
 121         int stat_items = STAT(CTF_FLAGSTATUS);
 122         float fs, fs2, fs3, size1, size2;
 123         vector e1, e2;
 124
 125         int nteams = autocvar__teams_available;
 126
 127         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
 128         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
 129         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
 130         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
 131         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
 132
 133         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
 134
 135         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag || (stat_items & CTF_SHIELDED));
 136
 137         if (autocvar__hud_configure) {
 138                 redflag = 1;
 139                 blueflag = 2;
 140                 if (nteams & BIT(2))
 141                         yellowflag = 2;
 142                 if (nteams & BIT(3))
 143                         pinkflag = 3;
 144                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
 145         }
 146
 147         // when status CHANGES, set old status into prevstatus and current status into status
 148         #define X(team) MACRO_BEGIN {                                                                                                   \
 149                 if (team##flag != team##flag_prevframe) {                                                                       \
 150                 team##flag_statuschange_time = time;                                                                    \
 151                 team##flag_prevstatus = team##flag_prevframe;                                                   \
 152                 team##flag_prevframe = team##flag;                                                                              \
 153         }                                                                                                                                                       \
 154         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
 155     } MACRO_END
 156         X(red);
 157         X(blue);
 158         X(yellow);
 159         X(pink);
 160         X(neutral);
 161         #undef X
 162
 163         const float BLINK_FACTOR = 0.15;
 164         const float BLINK_BASE = 0.85;
 165         // note:
 166         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
 167         // thus
 168         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
 169         // ensure RMS == 1
 170         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
 171
 172         #define X(team, cond) \
 173         string team##_icon = string_null, team##_icon_prevstatus = string_null; \
 174         int team##_alpha, team##_alpha_prevstatus; \
 175         team##_alpha = team##_alpha_prevstatus = 1; \
 176         MACRO_BEGIN { \
 177                 switch (team##flag) { \
 178                         case 1: team##_icon = "flag_" #team "_taken"; break; \
 179                         case 2: team##_icon = "flag_" #team "_lost"; break; \
 180                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
 181                         default: \
 182                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
 183                                         team##_icon = "flag_" #team "_shielded"; \
 184                                 } else { \
 185                                         team##_icon = string_null; \
 186                                 } \
 187                                 break; \
 188                 } \
 189                 switch (team##flag_prevstatus) { \
 190                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
 191                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
 192                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
 193                         default: \
 194                                 if (team##flag == 3) { \
 195                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
 196                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
 197                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
 198                                 } else { \
 199                                         team##_icon_prevstatus = string_null; \
 200                                 } \
 201                                 break; \
 202                 } \
 203         } MACRO_END
 204         X(red, myteam != NUM_TEAM_1);
 205         X(blue, myteam != NUM_TEAM_2);
 206         X(yellow, myteam != NUM_TEAM_3 && (nteams & BIT(2)));
 207         X(pink, myteam != NUM_TEAM_4 && (nteams & BIT(3)));
 208         X(neutral, ctf_oneflag);
 209         #undef X
 210
 211         int tcount = 2;
 212         if(nteams & BIT(2))
 213                 tcount = 3;
 214         if(nteams & BIT(3))
 215                 tcount = 4;
 216
 217         LOG_INFO(ftos(tcount), "\n");
 218
 219         if (ctf_oneflag) {
 220                 // hacky, but these aren't needed
 221                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
 222                 fs = fs2 = fs3 = 1;
 223         } else switch (tcount) {
 224                 default:
 225                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
 226                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
 227                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
 228         }
 229
 230         if (mySize_x > mySize_y) {
 231                 size1 = mySize_x;
 232                 size2 = mySize_y;
 233                 e1 = eX;
 234                 e2 = eY;
 235         } else {
 236                 size1 = mySize_y;
 237                 size2 = mySize_x;
 238                 e1 = eY;
 239                 e2 = eX;
 240         }
 241
 242         switch (myteam) {
 243                 default:
 244                 case NUM_TEAM_1: {
 245                         redflag_pos = pos;
 246                         blueflag_pos = pos + eX * fs2 * size1;
 247                         yellowflag_pos = pos - eX * fs2 * size1;
 248                         pinkflag_pos = pos + eX * fs3 * size1;
 249                         break;
 250                 }
 251                 case NUM_TEAM_2: {
 252                         redflag_pos = pos + eX * fs2 * size1;
 253                         blueflag_pos = pos;
 254                         yellowflag_pos = pos - eX * fs2 * size1;
 255                         pinkflag_pos = pos + eX * fs3 * size1;
 256                         break;
 257                 }
 258                 case NUM_TEAM_3: {
 259                         redflag_pos = pos + eX * fs3 * size1;
 260                         blueflag_pos = pos - eX * fs2 * size1;
 261                         yellowflag_pos = pos;
 262                         pinkflag_pos = pos + eX * fs2 * size1;
 263                         break;
 264                 }
 265                 case NUM_TEAM_4: {
 266                         redflag_pos = pos - eX * fs2 * size1;
 267                         blueflag_pos = pos + eX * fs3 * size1;
 268                         yellowflag_pos = pos + eX * fs2 * size1;
 269                         pinkflag_pos = pos;
 270                         break;
 271                 }
 272         }
 273         neutralflag_pos = pos;
 274         flag_size = e1 * fs * size1 + e2 * size2;
 275
 276         #define X(team) MACRO_BEGIN { \
 277                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
 278                 if (team##_icon_prevstatus && f < 1) \
 279                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
 280                 if (team##_icon) \
 281                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
 282         } MACRO_END
 283         X(red);
 284         X(blue);
 285         X(yellow);
 286         X(pink);
 287         X(neutral);
 288         #undef X
 289 }
 290
 291 // Keyhunt HUD modicon section
 292 vector KH_SLOTS[4];
 293
 294 void HUD_Mod_KH(vector pos, vector mySize)
 295 {
 296         mod_active = 1; // keyhunt should never hide the mod icons panel
 297
 298         // Read current state
 299
 300         int state = STAT(KH_KEYS);
 301         int i, key_state;
 302         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
 303         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
 304
 305         for(i = 0; i < 4; ++i)
 306         {
 307                 key_state = (bitshift(state, i * -5) & 31) - 1;
 308
 309                 if(key_state == -1)
 310                         continue;
 311
 312                 if(key_state == 30)
 313                 {
 314                         ++carrying_keys;
 315                         key_state = myteam;
 316                 }
 317
 318                 switch(key_state)
 319                 {
 320                         case NUM_TEAM_1: ++team1_keys; break;
 321                         case NUM_TEAM_2: ++team2_keys; break;
 322                         case NUM_TEAM_3: ++team3_keys; break;
 323                         case NUM_TEAM_4: ++team4_keys; break;
 324                         case 29: ++dropped_keys; break;
 325                 }
 326
 327                 ++all_keys;
 328         }
 329
 330         // Calculate slot measurements
 331
 332         vector slot_size;
 333
 334         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
 335         {
 336                 // Quadratic arrangement
 337                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
 338                 KH_SLOTS[0] = pos;
 339                 KH_SLOTS[1] = pos + eX * slot_size.x;
 340                 KH_SLOTS[2] = pos + eY * slot_size.y;
 341                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
 342         }
 343         else
 344         {
 345                 if(mySize.x > mySize.y)
 346                 {
 347                         // Horizontal arrangement
 348                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
 349                         for(i = 0; i < all_keys; ++i)
 350                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
 351                 }
 352                 else
 353                 {
 354                         // Vertical arrangement
 355                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
 356                         for(i = 0; i < all_keys; ++i)
 357                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
 358                 }
 359         }
 360
 361         // Make icons blink in case of RUN HERE
 362
 363         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
 364         float alpha;
 365         alpha = 1;
 366
 367         if(carrying_keys)
 368                 switch(myteam)
 369                 {
 370                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
 371                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
 372                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
 373                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
 374                 }
 375
 376         // Draw icons
 377
 378         i = 0;
 379
 380         while(team1_keys--)
 381                 if(myteam == NUM_TEAM_1 && carrying_keys)
 382                 {
 383                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 384                         --carrying_keys;
 385                 }
 386                 else
 387                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 388
 389         while(team2_keys--)
 390                 if(myteam == NUM_TEAM_2 && carrying_keys)
 391                 {
 392                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 393                         --carrying_keys;
 394                 }
 395                 else
 396                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 397
 398         while(team3_keys--)
 399                 if(myteam == NUM_TEAM_3 && carrying_keys)
 400                 {
 401                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 402                         --carrying_keys;
 403                 }
 404                 else
 405                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 406
 407         while(team4_keys--)
 408                 if(myteam == NUM_TEAM_4 && carrying_keys)
 409                 {
 410                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 411                         --carrying_keys;
 412                 }
 413                 else
 414                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 415
 416         while(dropped_keys--)
 417                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 418 }
 419
 420 // Keepaway HUD mod icon
 421 int kaball_prevstatus; // last remembered status
 422 float kaball_statuschange_time; // time when the status changed
 423
 424 // we don't need to reset for keepaway since it immediately
 425 // autocorrects prevstatus as to if the player has the ball or not
 426
 427 void HUD_Mod_Keepaway(vector pos, vector mySize)
 428 {
 429         mod_active = 1; // keepaway should always show the mod HUD
 430
 431         float BLINK_FACTOR = 0.15;
 432         float BLINK_BASE = 0.85;
 433         float BLINK_FREQ = 5;
 434         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 435
 436         int stat_items = STAT(ITEMS);
 437         int kaball = (stat_items/IT_KEY1) & 1;
 438
 439         if(kaball != kaball_prevstatus)
 440         {
 441                 kaball_statuschange_time = time;
 442                 kaball_prevstatus = kaball;
 443         }
 444
 445         vector kaball_pos, kaball_size;
 446
 447         if(mySize.x > mySize.y) {
 448                 kaball_pos = pos + eX * 0.25 * mySize.x;
 449                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
 450         } else {
 451                 kaball_pos = pos + eY * 0.25 * mySize.y;
 452                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
 453         }
 454
 455         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
 456         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
 457
 458         if(kaball_prevstatus && f < 1)
 459                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
 460
 461         if(kaball)
 462                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
 463 }
 464
 465
 466 // Nexball HUD mod icon
 467 void HUD_Mod_NexBall(vector pos, vector mySize)
 468 {
 469         float nb_pb_starttime, dt, p;
 470         int stat_items;
 471
 472         stat_items = STAT(ITEMS);
 473         nb_pb_starttime = STAT(NB_METERSTART);
 474
 475         if (stat_items & IT_KEY1)
 476                 mod_active = 1;
 477         else
 478                 mod_active = 0;
 479
 480         //Manage the progress bar if any
 481         if (nb_pb_starttime > 0)
 482         {
 483                 dt = (time - nb_pb_starttime) % nb_pb_period;
 484                 // one period of positive triangle
 485                 p = 2 * dt / nb_pb_period;
 486                 if (p > 1)
 487                         p = 2 - p;
 488
 489                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 490         }
 491
 492         if (stat_items & IT_KEY1)
 493                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 494 }
 495
 496 // Race/CTS HUD mod icons
 497 float crecordtime_prev; // last remembered crecordtime
 498 float crecordtime_change_time; // time when crecordtime last changed
 499 float srecordtime_prev; // last remembered srecordtime
 500 float srecordtime_change_time; // time when srecordtime last changed
 501
 502 float race_status_time;
 503 int race_status_prev;
 504 string race_status_name_prev;
 505
 506 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 507 int race_CheckName(string net_name)
 508 {
 509         int i;
 510         for (i=RANKINGS_CNT-1;i>=0;--i)
 511                 if(grecordholder[i] == net_name)
 512                         return i+1;
 513         return 0;
 514 }
 515
 516 void race_showTime(string text, vector pos, vector timeText_ofs, float theTime, vector textSize, float f)
 517 {
 518         drawstring_aspect(pos, text, textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 519         drawstring_aspect(pos + timeText_ofs, TIME_ENCODED_TOSTRING(theTime), textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 520         if (f < 1) {
 521                 drawstring_aspect_expanding(pos, text, textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
 522                 drawstring_aspect_expanding(pos + timeText_ofs, TIME_ENCODED_TOSTRING(theTime), textSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
 523         }
 524 }
 525
 526 void HUD_Mod_Race(vector pos, vector mySize)
 527 {
 528         mod_active = 1; // race should never hide the mod icons panel
 529         entity me;
 530         me = playerslots[player_localnum];
 531         float score;
 532         score = me.(scores[ps_primary]);
 533
 534         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
 535                 return; // no records in the actual race
 536
 537         // clientside personal record
 538         string rr;
 539         if(gametype == MAPINFO_TYPE_CTS)
 540                 rr = CTS_RECORD;
 541         else
 542                 rr = RACE_RECORD;
 543         float t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
 544
 545         if(score && (score < t || !t)) {
 546                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
 547                 if(autocvar_cl_autodemo_delete_keeprecords)
 548                 {
 549                         float f = autocvar_cl_autodemo_delete;
 550                         f &= ~1;
 551                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
 552                 }
 553         }
 554
 555         if(t != crecordtime_prev) {
 556                 crecordtime_prev = t;
 557                 crecordtime_change_time = time;
 558         }
 559
 560         vector textPos, medalPos;
 561         float squareSize;
 562         if(mySize.x > mySize.y) {
 563                 // text on left side
 564                 squareSize = min(mySize.y, mySize.x/2);
 565                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
 566                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
 567         } else {
 568                 // text on top
 569                 squareSize = min(mySize.x, mySize.y/2);
 570                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
 571                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
 572         }
 573         vector textSize = eX * squareSize + eY * 0.25 * squareSize;
 574
 575         race_showTime(_("Personal best"), textPos, eY * 0.25 * squareSize, t, textSize, time - crecordtime_change_time);
 576
 577         // server record
 578         t = race_server_record;
 579         if(t != srecordtime_prev) {
 580                 srecordtime_prev = t;
 581                 srecordtime_change_time = time;
 582         }
 583
 584         textPos += eY * 0.5 * squareSize;
 585         race_showTime(_("Server best"), textPos, eY * 0.25 * squareSize, t, textSize, time - srecordtime_change_time);
 586
 587         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
 588                 race_status_time = time + 5;
 589                 race_status_prev = race_status;
 590                 if (race_status_name_prev)
 591                         strunzone(race_status_name_prev);
 592                 race_status_name_prev = strzone(race_status_name);
 593         }
 594
 595         // race "awards"
 596         float a;
 597         a = bound(0, race_status_time - time, 1);
 598
 599         string s;
 600         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
 601
 602         float rank;
 603         if(race_status > 0)
 604                 rank = race_CheckName(race_status_name);
 605         else
 606                 rank = 0;
 607         string rankname;
 608         rankname = count_ordinal(rank);
 609
 610         vector namepos;
 611         namepos = medalPos + '0 0.8 0' * squareSize;
 612         vector rankpos;
 613         rankpos = medalPos + '0 0.15 0' * squareSize;
 614
 615         if(race_status == 0)
 616                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 617         else if(race_status == 1) {
 618                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 619                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 620                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 621         } else if(race_status == 2) {
 622                 if(race_status_name == entcs_GetName(player_localnum) || !race_myrank || race_myrank < rank)
 623                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 624                 else
 625                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 626                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 627                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 628         } else if(race_status == 3) {
 629                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 630                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
 631                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 632         }
 633
 634         if (race_status_time - time <= 0) {
 635                 race_status_prev = -1;
 636                 race_status = -1;
 637                 if(race_status_name)
 638                         strunzone(race_status_name);
 639                 race_status_name = string_null;
 640                 if(race_status_name_prev)
 641                         strunzone(race_status_name_prev);
 642                 race_status_name_prev = string_null;
 643         }
 644 }
 645
 646 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
 647 {
 648     TC(int, layout); TC(int, i);
 649         float stat = -1;
 650         string pic = "";
 651         vector color = '0 0 0';
 652         switch(i)
 653         {
 654                 case 0:
 655                         stat = STAT(DOM_PPS_RED);
 656                         pic = "dom_icon_red";
 657                         color = '1 0 0';
 658                         break;
 659                 case 1:
 660                         stat = STAT(DOM_PPS_BLUE);
 661                         pic = "dom_icon_blue";
 662                         color = '0 0 1';
 663                         break;
 664                 case 2:
 665                         stat = STAT(DOM_PPS_YELLOW);
 666                         pic = "dom_icon_yellow";
 667                         color = '1 1 0';
 668                         break;
 669                 default:
 670                 case 3:
 671                         stat = STAT(DOM_PPS_PINK);
 672                         pic = "dom_icon_pink";
 673                         color = '1 0 1';
 674                         break;
 675         }
 676         float pps_ratio = stat / STAT(DOM_TOTAL_PPS);
 677
 678         if(mySize.x/mySize.y > aspect_ratio)
 679         {
 680                 i = aspect_ratio * mySize.y;
 681                 myPos.x = myPos.x + (mySize.x - i) / 2;
 682                 mySize.x = i;
 683         }
 684         else
 685         {
 686                 i = 1/aspect_ratio * mySize.x;
 687                 myPos.y = myPos.y + (mySize.y - i) / 2;
 688                 mySize.y = i;
 689         }
 690
 691         if (layout) // show text too
 692         {
 693                 //draw the text
 694                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
 695                 if (layout == 2) // average pps
 696                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 697                 else // percentage of average pps
 698                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 699         }
 700
 701         //draw the icon
 702         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 703         if (stat > 0)
 704         {
 705                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
 706                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 707                 drawresetcliparea();
 708         }
 709 }
 710
 711 void HUD_Mod_Dom(vector myPos, vector mySize)
 712 {
 713         mod_active = 1; // required in each mod function that always shows something
 714
 715         int layout = autocvar_hud_panel_modicons_dom_layout;
 716         int rows, columns;
 717         float aspect_ratio;
 718         aspect_ratio = (layout) ? 3 : 1;
 719         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
 720         columns = ceil(team_count/rows);
 721
 722         int i;
 723         float row = 0, column = 0;
 724         vector pos, itemSize;
 725         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 726         for(i=0; i<team_count; ++i)
 727         {
 728                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
 729
 730                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
 731
 732                 ++row;
 733                 if(row >= rows)
 734                 {
 735                         row = 0;
 736                         ++column;
 737                 }
 738         }
 739 }
 740
 741 void HUD_ModIcons_SetFunc()
 742 {
 743         switch(gametype)
 744         {
 745                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
 746                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
 747                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
 748                 case MAPINFO_TYPE_CTS:
 749                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
 750                 case MAPINFO_TYPE_CA:
 751                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
 752                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
 753                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
 754         }
 755 }
 756
 757 int mod_prev; // previous state of mod_active to check for a change
 758 float mod_alpha;
 759 float mod_change; // "time" when mod_active changed
 760
 761 void HUD_ModIcons()
 762 {
 763         if(!autocvar__hud_configure)
 764         {
 765                 if(!autocvar_hud_panel_modicons) return;
 766                 if(!HUD_ModIcons_GameType) return;
 767         }
 768
 769         HUD_Panel_UpdateCvars();
 770
 771         draw_beginBoldFont();
 772
 773         if(mod_active != mod_prev) {
 774                 mod_change = time;
 775                 mod_prev = mod_active;
 776         }
 777
 778         if(mod_active || autocvar__hud_configure)
 779                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
 780         else
 781                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
 782
 783         if (autocvar_hud_panel_modicons_dynamichud)
 784                 HUD_Scale_Enable();
 785         else
 786                 HUD_Scale_Disable();
 787         if(mod_alpha)
 788                 HUD_Panel_DrawBg(mod_alpha);
 789
 790         if(panel_bg_padding)
 791         {
 792                 panel_pos += '1 1 0' * panel_bg_padding;
 793                 panel_size -= '2 2 0' * panel_bg_padding;
 794         }
 795
 796         if(autocvar__hud_configure)
 797                 HUD_Mod_CTF(panel_pos, panel_size);
 798         else
 799                 HUD_ModIcons_GameType(panel_pos, panel_size);
 800
 801         draw_endBoldFont();
 802 }