qcsrc/client/hud/panel/notify.qc

   1 #include "notify.qh"
   2 // Notification area (#4)
   3
   4 void HUD_Notify_Push(string icon, string attacker, string victim)
   5 {
   6         if (icon == "")
   7                 return;
   8
   9         ++notify_count;
  10         --notify_index;
  11
  12         if (notify_index == -1)
  13                 notify_index = NOTIFY_MAX_ENTRIES-1;
  14
  15         // Free old strings
  16         if (notify_attackers[notify_index])
  17                 strunzone(notify_attackers[notify_index]);
  18
  19         if (notify_victims[notify_index])
  20                 strunzone(notify_victims[notify_index]);
  21
  22         if (notify_icons[notify_index])
  23                 strunzone(notify_icons[notify_index]);
  24
  25         // Allocate new strings
  26         if (victim != "")
  27         {
  28                 notify_attackers[notify_index] = strzone(attacker);
  29                 notify_victims[notify_index] = strzone(victim);
  30         }
  31         else
  32         {
  33                 // In case of a notification without a victim, the attacker
  34                 // is displayed on the victim's side. Instead of special
  35                 // treatment later on, we can simply switch them here.
  36                 notify_attackers[notify_index] = string_null;
  37                 notify_victims[notify_index] = strzone(attacker);
  38         }
  39
  40         notify_icons[notify_index] = strzone(icon);
  41         notify_times[notify_index] = time;
  42 }
  43
  44 void HUD_Notify()
  45 {
  46         if (!autocvar__hud_configure)
  47                 if (!autocvar_hud_panel_notify)
  48                         return;
  49
  50         HUD_Panel_UpdateCvars();
  51         HUD_Scale_Enable();
  52         HUD_Panel_DrawBg(1);
  53
  54         if (!autocvar__hud_configure)
  55                 if (notify_count == 0)
  56                         return;
  57
  58         vector pos, size;
  59         pos  = panel_pos;
  60         size = panel_size;
  61
  62         if (panel_bg_padding)
  63         {
  64                 pos  += '1 1 0' * panel_bg_padding;
  65                 size -= '2 2 0' * panel_bg_padding;
  66         }
  67
  68         float fade_start = max(0, autocvar_hud_panel_notify_time);
  69         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
  70         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
  71
  72         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
  73         float entry_height = size.y / entry_count;
  74
  75         float panel_width_half = size.x * 0.5;
  76         float icon_width_half = entry_height * icon_aspect / 2;
  77         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
  78
  79         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
  80         vector icon_size = (eX * icon_aspect + eY) * entry_height;
  81         vector icon_left = eX * (panel_width_half - icon_width_half);
  82         vector attacker_right = eX * name_maxwidth;
  83         vector victim_left = eX * (size.x - name_maxwidth);
  84
  85         vector attacker_pos, victim_pos, icon_pos;
  86         string attacker, victim, icon;
  87         int i, j, count, step, limit;
  88         float alpha;
  89
  90         if (autocvar_hud_panel_notify_flip)
  91         {
  92                 // Order items from the top down
  93                 i = 0;
  94                 step = +1;
  95                 limit = entry_count;
  96         }
  97         else
  98         {
  99                 // Order items from the bottom up
 100                 i = entry_count - 1;
 101                 step = -1;
 102                 limit = -1;
 103         }
 104
 105         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
 106         {
 107                 if(autocvar__hud_configure)
 108                 {
 109                         attacker = sprintf(_("Player %d"), count + 1);
 110                         victim = sprintf(_("Player %d"), count + 2);
 111                         icon = Weapons_from(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
 112                         alpha = bound(0, 1.2 - count / entry_count, 1);
 113                 }
 114                 else
 115                 {
 116                         if (j == NOTIFY_MAX_ENTRIES)
 117                                 j = 0;
 118
 119                         if (notify_times[j] + fade_start > time)
 120                                 alpha = 1;
 121                         else if (fade_time != 0)
 122                         {
 123                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
 124                                 if (alpha == 0)
 125                                         break;
 126                         }
 127                         else
 128                                 break;
 129
 130                         attacker = notify_attackers[j];
 131                         victim = notify_victims[j];
 132                         icon = notify_icons[j];
 133                 }
 134
 135                 if (icon != "" && victim != "")
 136                 {
 137                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
 138
 139                         icon_pos = pos + icon_left + eY * i * entry_height;
 140                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
 141
 142                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
 143                         victim_pos = pos + victim_left + name_top;
 144                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
 145
 146                         if (attacker != "")
 147                         {
 148                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
 149                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
 150                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
 151                         }
 152                 }
 153         }
 154
 155         notify_count = count;
 156 }