qcsrc/client/hud/panel/score.qc

   1 #include "score.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <common/ent_cs.qh>
   6 #include <common/scores.qh>
   7
   8 // Score (#7)
   9
  10 void HUD_Score_Export(int fh)
  11 {
  12         // allow saving cvars that aesthetically change the panel into hud skin files
  13         HUD_Write_Cvar("hud_panel_score_rankings");
  14 }
  15
  16 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
  17 {
  18         float score;
  19         entity tm = NULL, pl;
  20         int SCOREPANEL_MAX_ENTRIES = 6;
  21         float SCOREPANEL_ASPECTRATIO = 2;
  22         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
  23         vector fontsize = '1 1 0' * (mySize.y/entries);
  24
  25         vector rgb, score_color;
  26         rgb = '1 1 1';
  27         score_color = '1 1 1';
  28
  29         float name_size = mySize.x*0.75;
  30         float spacing_size = mySize.x*0.04;
  31         const float highlight_alpha = 0.2;
  32         int i = 0, first_pl = 0;
  33         bool me_printed = false;
  34         string s;
  35         if (autocvar__hud_configure)
  36         {
  37                 float players_per_team = 0;
  38                 if (team_count)
  39                 {
  40                         // show team scores in the first line
  41                         float score_size = mySize.x / team_count;
  42                         players_per_team = max(2, ceil((entries - 1) / team_count));
  43                         for(i=0; i<team_count; ++i) {
  44                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
  45                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, vec2(score_size, fontsize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  46                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), vec2(score_size, fontsize.y), Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
  47                         }
  48                         first_pl = 1;
  49                         pos.y += fontsize.y;
  50                 }
  51                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
  52                 for (i=first_pl; i<entries; ++i)
  53                 {
  54                         //simulate my score is lower than all displayed players,
  55                         //so that I don't appear at all showing pure rankings.
  56                         //This is to better show the difference between the 2 ranking views
  57                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
  58                         {
  59                                 rgb = '1 1 0';
  60                                 drawfill(pos, vec2(mySize.x, fontsize.y), rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
  61                                 s = entcs_GetName(player_localnum);
  62                                 score = 7;
  63                         }
  64                         else
  65                         {
  66                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
  67                                 score -= 3;
  68                         }
  69
  70                         if (team_count)
  71                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
  72                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
  73                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
  74                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
  75                         pos.y += fontsize.y;
  76                 }
  77                 return;
  78         }
  79
  80         Scoreboard_UpdatePlayerTeams();
  81         if (team_count)
  82         {
  83                 // show team scores in the first line
  84                 float score_size = mySize.x / team_count;
  85                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
  86                         if(tm.team == NUM_SPECTATOR)
  87                                 continue;
  88                         if(!tm.team)
  89                                 continue;
  90
  91                         if (tm.team == myteam)
  92                                 drawfill(pos + eX * score_size * i, vec2(score_size, fontsize.y), '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
  93                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores(ts_primary))), vec2(score_size, fontsize.y), Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
  94                         ++i;
  95                 }
  96                 first_pl = 1;
  97                 pos.y += fontsize.y;
  98                 tm = teams.sort_next;
  99         }
 100         i = first_pl;
 101
 102         do
 103         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
 104         {
 105                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
 106                         continue;
 107
 108                 if (i == entries-1 && !me_printed && pl != me)
 109                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
 110                 {
 111                         for (pl = me.sort_next; pl; pl = pl.sort_next)
 112                                 if (pl.team != NUM_SPECTATOR)
 113                                         break;
 114
 115                         if (pl)
 116                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
 117                         else
 118                                 rgb = '1 0 0'; //last: red
 119                         pl = me;
 120                 }
 121
 122                 if (pl == me)
 123                 {
 124                         if (i == first_pl)
 125                                 rgb = '0 1 0'; //first: green
 126                         me_printed = true;
 127                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 128                 }
 129                 if (team_count)
 130                         score_color = Team_ColorRGB(pl.team) * 0.8;
 131                 s = textShortenToWidth(entcs_GetName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
 132                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 133                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores(ps_primary))), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 134                 pos.y += fontsize.y;
 135                 ++i;
 136         }
 137         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
 138 }
 139
 140 void HUD_Score()
 141 {
 142         if(!autocvar__hud_configure)
 143         {
 144                 if(!autocvar_hud_panel_score) return;
 145                 if(MUTATOR_CALLHOOK(HUD_Score_show)) return;
 146         }
 147
 148         HUD_Panel_LoadCvars();
 149         vector pos, mySize;
 150         pos = panel_pos;
 151         mySize = panel_size;
 152
 153         if (autocvar_hud_panel_score_dynamichud)
 154                 HUD_Scale_Enable();
 155         else
 156                 HUD_Scale_Disable();
 157         HUD_Panel_DrawBg();
 158         if(panel_bg_padding)
 159         {
 160                 pos += '1 1 0' * panel_bg_padding;
 161                 mySize -= '2 2 0' * panel_bg_padding;
 162         }
 163
 164         float score, distribution = 0;
 165         string sign;
 166         vector distribution_color;
 167         entity tm, pl, me;
 168
 169         me = playerslots[current_player];
 170
 171         if((scores_flags(ps_primary) & SFL_TIME) && !teamplay) { // race/cts record display on HUD
 172                 string timer, distrtimer;
 173
 174                 pl = players.sort_next;
 175                 if(pl == me)
 176                         pl = pl.sort_next;
 177                 if(scores_flags(ps_primary) & SFL_ZERO_IS_WORST)
 178                         if(pl.scores(ps_primary) == 0)
 179                                 pl = NULL;
 180
 181                 score = me.(scores(ps_primary));
 182                 timer = TIME_ENCODED_TOSTRING(score);
 183
 184                 draw_beginBoldFont();
 185                 if (pl && ((!(scores_flags(ps_primary) & SFL_ZERO_IS_WORST)) || score)) {
 186                         // distribution display
 187                         distribution = me.(scores(ps_primary)) - pl.(scores(ps_primary));
 188
 189                         distrtimer = ftos_decimals(fabs(distribution/(10 ** TIME_DECIMALS)), TIME_DECIMALS);
 190
 191                         if (distribution <= 0) {
 192                                 distribution_color = '0 1 0';
 193                                 sign = "-";
 194                         }
 195                         else {
 196                                 distribution_color = '1 0 0';
 197                                 sign = "+";
 198                         }
 199                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), vec2(0.25 * mySize.x, (1/3) * mySize.y), distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 200                 }
 201                 // race record display
 202                 if (distribution <= 0)
 203                         HUD_Panel_DrawHighlight(pos, vec2(0.75 * mySize.x, mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 204                 drawstring_aspect(pos, timer, vec2(0.75 * mySize.x, mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 205                 draw_endBoldFont();
 206         } else if (!teamplay) { // non-teamgames
 207                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
 208                 {
 209                         HUD_Score_Rankings(pos, mySize, me);
 210                         return;
 211                 }
 212                 // me vector := [team/connected frags id]
 213                 pl = players.sort_next;
 214                 if(pl == me)
 215                         pl = pl.sort_next;
 216
 217                 if(autocvar__hud_configure)
 218                         distribution = 42;
 219                 else if(pl)
 220                         distribution = me.(scores(ps_primary)) - pl.(scores(ps_primary));
 221                 else
 222                         distribution = 0;
 223
 224                 score = me.(scores(ps_primary));
 225                 if(autocvar__hud_configure)
 226                         score = 123;
 227
 228                 if(distribution >= 5)
 229                         distribution_color = eY;
 230                 else if(distribution >= 0)
 231                         distribution_color = '1 1 1';
 232                 else if(distribution >= -5)
 233                         distribution_color = '1 1 0';
 234                 else
 235                         distribution_color = eX;
 236
 237                 string distribution_str;
 238                 distribution_str = ftos(distribution);
 239                 draw_beginBoldFont();
 240                 if (distribution >= 0)
 241                 {
 242                         if (distribution > 0)
 243                                 distribution_str = strcat("+", distribution_str);
 244                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 245                 }
 246                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 247                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, vec2(0.25 * mySize.x, (1/3) * mySize.y), distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
 248                 draw_endBoldFont();
 249         } else { // teamgames
 250                 float row, column, rows = 0, columns = 0;
 251                 vector offset = '0 0 0';
 252                 vector score_pos, score_size; //for scores other than myteam
 253                 if(autocvar_hud_panel_score_rankings)
 254                 {
 255                         HUD_Score_Rankings(pos, mySize, me);
 256                         return;
 257                 }
 258                 if(spectatee_status == -1)
 259                 {
 260                         rows = HUD_GetRowCount(team_count, mySize, 3);
 261                         columns = ceil(team_count/rows);
 262                         score_size = vec2(mySize.x / columns, mySize.y / rows);
 263
 264                         float newSize;
 265                         if(score_size.x/score_size.y > 3)
 266                         {
 267                                 newSize = 3 * score_size.y;
 268                                 offset.x = score_size.x - newSize;
 269                                 pos.x += offset.x/2;
 270                                 score_size.x = newSize;
 271                         }
 272                         else
 273                         {
 274                                 newSize = 1/3 * score_size.x;
 275                                 offset.y = score_size.y - newSize;
 276                                 pos.y += offset.y/2;
 277                                 score_size.y = newSize;
 278                         }
 279                 }
 280                 else
 281                         score_size = vec2(mySize.x / 4, mySize.y / 3);
 282
 283                 float max_fragcount;
 284                 max_fragcount = -99;
 285                 draw_beginBoldFont();
 286                 row = column = 0;
 287                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
 288                         if(tm.team == NUM_SPECTATOR)
 289                                 continue;
 290                         if(!tm.team)
 291                                 continue;
 292
 293                         score = tm.(teamscores(ts_primary));
 294                         if(autocvar__hud_configure)
 295                                 score = 123;
 296
 297                         if (score > max_fragcount)
 298                                 max_fragcount = score;
 299
 300                         if (spectatee_status == -1)
 301                         {
 302                                 score_pos = pos + vec2(column * (score_size.x + offset.x), row * (score_size.y + offset.y));
 303                                 if (max_fragcount == score)
 304                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 305                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
 306                                 ++row;
 307                                 if(row >= rows)
 308                                 {
 309                                         row = 0;
 310                                         ++column;
 311                                 }
 312                         }
 313                         else if(tm.team == myteam) {
 314                                 if (max_fragcount == score)
 315                                         HUD_Panel_DrawHighlight(pos, vec2(0.75 * mySize.x, mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 316                                 drawstring_aspect(pos, ftos(score), vec2(0.75 * mySize.x, mySize.y), Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
 317                         } else {
 318                                 if (max_fragcount == score)
 319                                         HUD_Panel_DrawHighlight(pos + vec2(0.75 * mySize.x, (1/3) * rows * mySize.y), score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 320                                 drawstring_aspect(pos + vec2(0.75 * mySize.x, (1/3) * rows * mySize.y), ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
 321                                 ++rows;
 322                         }
 323                 }
 324                 draw_endBoldFont();
 325         }
 326 }