qcsrc/client/hud.qh

   1 #define HUD_PANEL_MAX 24
   2 entity hud_panel[HUD_PANEL_MAX];
   3 #define HUD_PANEL_FIRST 0
   4 float HUD_PANEL_NUM;
   5 float HUD_PANEL_LAST;
   6
   7 float panel_order[HUD_PANEL_MAX];
   8 string hud_panelorder_prev;
   9
  10 float hud_draw_maximized;
  11 float hud_panel_radar_maximized;
  12 float hud_panel_radar_mouse;
  13 float hud_panel_radar_bottom;
  14 float hud_panel_radar_temp_hidden;
  15 float chat_panel_modified;
  16 float radar_panel_modified;
  17
  18 void HUD_Radar_Hide_Maximized();
  19
  20 vector mousepos;
  21 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  22 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  23 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  24 entity highlightedPanel;
  25 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  26
  27 const float BORDER_MULTIPLIER = 0.25;
  28 float scoreboard_bottom;
  29 float weapon_accuracy[WEP_MAXCOUNT];
  30
  31 float complain_weapon;
  32 string complain_weapon_name;
  33 float complain_weapon_type;
  34 float complain_weapon_time;
  35
  36 float ps_primary, ps_secondary;
  37 float ts_primary, ts_secondary;
  38
  39 float last_switchweapon;
  40 float last_activeweapon;
  41 float weapontime;
  42 float weaponprevtime;
  43
  44 float teamnagger;
  45
  46 float hud_configure_checkcollisions;
  47 float hud_configure_prev;
  48 noref vector hud_configure_gridSize; // fteqcc sucks
  49 noref vector hud_configure_realGridSize; // fteqcc sucks
  50
  51 float hudShiftState;
  52 const float S_SHIFT = 1;
  53 const float S_CTRL = 2;
  54 const float S_ALT = 4;
  55
  56 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  57
  58 float hud_fade_alpha;
  59
  60 string hud_skin_path;
  61 string hud_skin_prev;
  62
  63 vector myteamcolors;
  64
  65 entity highlightedPanel_backup;
  66 var vector panel_pos_backup;
  67 var vector panel_size_backup;
  68
  69 var vector panel_size_copied;
  70
  71 entity panel;
  72 .string panel_name;
  73 .float panel_id;
  74 .vector current_panel_pos;
  75 .vector current_panel_size;
  76 .string current_panel_bg;
  77 .float current_panel_bg_alpha;
  78 .float current_panel_bg_border;
  79 .vector current_panel_bg_color;
  80 .float current_panel_bg_color_team;
  81 .float current_panel_bg_padding;
  82 .float current_panel_fg_alpha;
  83 .float update_time;
  84 var float panel_enabled;
  85 var vector panel_pos;
  86 var vector panel_size;
  87 var string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
  88 var vector panel_bg_color;
  89 var string panel_bg_color_str;
  90 var float panel_bg_color_team;
  91 var string panel_bg_color_team_str;
  92 var float panel_fg_alpha;
  93 var float panel_bg_alpha;
  94 var string panel_bg_alpha_str;
  95 var float panel_bg_border;
  96 var string panel_bg_border_str;
  97 var float panel_bg_padding;
  98 var string panel_bg_padding_str;
  99
 100 .void() panel_draw;
 101
 102 float current_player;
 103
 104 float mv_active;
 105
 106
 107 #define HUD_PANELS \
 108         HUD_PANEL(WEAPONS      , HUD_Weapons      , weapons) \
 109         HUD_PANEL(AMMO         , HUD_Ammo         , ammo) \
 110         HUD_PANEL(POWERUPS     , HUD_Powerups     , powerups) \
 111         HUD_PANEL(HEALTHARMOR  , HUD_HealthArmor  , healtharmor) \
 112         HUD_PANEL(NOTIFY       , HUD_Notify       , notify) \
 113         HUD_PANEL(TIMER        , HUD_Timer        , timer) \
 114         HUD_PANEL(RADAR        , HUD_Radar        , radar) \
 115         HUD_PANEL(SCORE        , HUD_Score        , score) \
 116         HUD_PANEL(RACETIMER    , HUD_RaceTimer    , racetimer) \
 117         HUD_PANEL(VOTE         , HUD_Vote         , vote) \
 118         HUD_PANEL(MODICONS     , HUD_ModIcons     , modicons) \
 119         HUD_PANEL(PRESSEDKEYS  , HUD_PressedKeys  , pressedkeys) \
 120         HUD_PANEL(CHAT         , HUD_Chat         , chat) \
 121         HUD_PANEL(ENGINEINFO   , HUD_EngineInfo   , engineinfo) \
 122         HUD_PANEL(INFOMESSAGES , HUD_InfoMessages , infomessages) \
 123         HUD_PANEL(PHYSICS      , HUD_Physics      , physics) \
 124         HUD_PANEL(CENTERPRINT  , HUD_CenterPrint  , centerprint) \
 125         HUD_PANEL(BUFFS        , HUD_Buffs        , buffs)
 126
 127 #define HUD_PANEL(NAME,draw_func,name) \
 128         float HUD_PANEL_##NAME; \
 129         void draw_func(void); \
 130         void RegisterHUD_Panel_##NAME() \
 131         { \
 132                 HUD_PANEL_LAST = HUD_PANEL_##NAME = HUD_PANEL_NUM; \
 133                 entity hud_panelent = spawn(); \
 134                 hud_panel[HUD_PANEL_##NAME] = hud_panelent; \
 135                 hud_panelent.classname = "hud_panel"; \
 136                 hud_panelent.panel_name = #name; \
 137                 hud_panelent.panel_id = HUD_PANEL_##NAME; \
 138                 hud_panelent.panel_draw = draw_func; \
 139                 ++HUD_PANEL_NUM; \
 140         } \
 141         ACCUMULATE_FUNCTION(RegisterHUD_Panels, RegisterHUD_Panel_##NAME);
 142
 143 HUD_PANELS
 144 #undef HUD_PANEL
 145
 146 #define HUD_PANEL(NAME) hud_panel[HUD_PANEL_##NAME]
 147
 148
 149 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 150 // ----------------------
 151 // MACRO HELL STARTS HERE
 152 // ----------------------
 153 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 154
 155 // Get value for panel.current_panel_bg: if "" fetch default, else use panel_bg_str
 156 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 157 #define HUD_Panel_GetBg()\
 158 string panel_bg;\
 159 if(!autocvar__hud_configure && panel_bg_str == "0") {\
 160         panel_bg = "0";\
 161 } else {\
 162         if(panel_bg_str == "") {\
 163                 panel_bg_str = autocvar_hud_panel_bg;\
 164         }\
 165         if(panel_bg_str == "0" && !autocvar__hud_configure) {\
 166                         panel_bg = "0";\
 167         } else {\
 168                 if (panel_bg_str == "0" && autocvar__hud_configure)\
 169                         panel_bg_alpha_str = "0";\
 170                 panel_bg = strcat(hud_skin_path, "/", panel_bg_str);\
 171                 if(precache_pic(panel_bg) == "") {\
 172                         panel_bg = strcat(hud_skin_path, "/", "border_default");\
 173                         if(precache_pic(panel_bg) == "") {\
 174                                 panel_bg = strcat("gfx/hud/default/", "border_default");\
 175                         }\
 176                 }\
 177         }\
 178 }\
 179 if(panel.current_panel_bg)\
 180         strunzone(panel.current_panel_bg);\
 181 panel.current_panel_bg = strzone(panel_bg);
 182
 183 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 184 #define HUD_Panel_GetColor()\
 185 if((teamplay) && panel_bg_color_team) {\
 186         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)\
 187                 panel_bg_color = '1 0 0' * panel_bg_color_team;\
 188         else\
 189                 panel_bg_color = myteamcolors * panel_bg_color_team;\
 190 } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {\
 191         panel_bg_color = '1 0 0' * panel_bg_color_team;\
 192 } else {\
 193         if(panel_bg_color_str == "") {\
 194                 panel_bg_color = autocvar_hud_panel_bg_color;\
 195         } else {\
 196                 if(panel_bg_color_str == "shirt") {\
 197                         panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player - 1, "colors")) / 16), 0);\
 198                 } else if(panel_bg_color_str == "pants") {\
 199                         panel_bg_color = colormapPaletteColor(stof(getplayerkeyvalue(current_player - 1, "colors")) % 16, 1);\
 200                 } else {\
 201                         panel_bg_color = stov(panel_bg_color_str);\
 202                 }\
 203         }\
 204 }
 205
 206 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 207 #define HUD_Panel_GetColorTeam()\
 208 if(panel_bg_color_team_str == "") {\
 209         panel_bg_color_team = autocvar_hud_panel_bg_color_team;\
 210 } else {\
 211         panel_bg_color_team = stof(panel_bg_color_team_str);\
 212 }
 213
 214 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 215 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 216 #define HUD_Panel_GetBgAlpha()\
 217 if(panel_bg_alpha_str == "") {\
 218         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);\
 219 }\
 220 panel_bg_alpha = stof(panel_bg_alpha_str);\
 221 if(autocvar__hud_configure) {\
 222         if(!panel_enabled)\
 223                 panel_bg_alpha = 0.25;\
 224         else if(menu_enabled == 2 && panel == highlightedPanel)\
 225                 panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 226         else\
 227                 panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);\
 228 }
 229
 230 // Get value for panel_fg_alpha. Also do various minalpha checks
 231 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 232 #define HUD_Panel_GetFgAlpha()\
 233 panel_fg_alpha = autocvar_hud_panel_fg_alpha;\
 234 if(autocvar__hud_configure && !panel_enabled)\
 235         panel_fg_alpha = 0.25;\
 236
 237 // Get border. See comments above, it's similar.
 238 #define HUD_Panel_GetBorder()\
 239 if(panel_bg_border_str == "") {\
 240         panel_bg_border = autocvar_hud_panel_bg_border;\
 241 } else {\
 242         panel_bg_border = stof(panel_bg_border_str);\
 243 } ENDS_WITH_CURLY_BRACE
 244
 245 // Get padding. See comments above, it's similar.
 246 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 247 #define HUD_Panel_GetPadding()\
 248 if(panel_bg_padding_str == "") {\
 249         panel_bg_padding = autocvar_hud_panel_bg_padding;\
 250 } else {\
 251         panel_bg_padding = stof(panel_bg_padding_str);\
 252 }\
 253 panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);
 254
 255 // return smoothly faded pos and size of given panel when a dialog is active
 256 #define HUD_Panel_UpdatePosSize_ForMenu()\
 257 vector menu_enable_pos;\
 258 vector menu_enable_size = '0 0 0';\
 259 float menu_enable_maxsize_x = 0.3 * vid_conwidth;\
 260 float menu_enable_maxsize_y = 0.18 * vid_conheight;\
 261 if(panel_size_x > panel_size_y)\
 262 {\
 263         if(panel_size_y > menu_enable_maxsize_y)\
 264         {\
 265                 menu_enable_size_y = menu_enable_maxsize_y;\
 266                 menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);\
 267                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 268         }\
 269         menu_enable_pos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * (vid_conheight - menu_enable_maxsize_y);\
 270 }\
 271 else\
 272 {\
 273         if(panel_size_x > menu_enable_maxsize_x)\
 274         {\
 275                 menu_enable_size_x = menu_enable_maxsize_x;\
 276                 menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);\
 277                 panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;\
 278         }\
 279         menu_enable_pos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * (vid_conwidth - menu_enable_maxsize_x);\
 280 }\
 281 panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_pos;
 282
 283 // Scale the pos and size vectors to absolute coordinates
 284 #define HUD_Panel_ScalePosSize()\
 285 panel_pos_x *= vid_conwidth; panel_pos_y *= vid_conheight;\
 286 panel_size_x *= vid_conwidth; panel_size_y *= vid_conheight;
 287
 288 // NOTE: in hud_configure mode cvars must be reloaded every frame
 289 #define HUD_Panel_UpdateCvars() \
 290 if(panel.update_time <= time) { \
 291         if(autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 292         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 293         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 294         HUD_Panel_ScalePosSize() \
 295         panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg")); \
 296         panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color")); \
 297         panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team")); \
 298         panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha")); \
 299         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 300         panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding")); \
 301         HUD_Panel_GetBg()\
 302         if (panel.current_panel_bg != "0") {\
 303                 HUD_Panel_GetColorTeam()\
 304                 HUD_Panel_GetColor()\
 305                 HUD_Panel_GetBgAlpha()\
 306                 HUD_Panel_GetBorder()\
 307         }\
 308         HUD_Panel_GetFgAlpha()\
 309         HUD_Panel_GetPadding()\
 310         panel.current_panel_bg_alpha = panel_bg_alpha; \
 311         panel.current_panel_fg_alpha = panel_fg_alpha; \
 312         if(menu_enabled == 2 && panel == highlightedPanel) {\
 313                 HUD_Panel_UpdatePosSize_ForMenu()\
 314         } else {\
 315                 panel_bg_alpha *= hud_fade_alpha;\
 316                 panel_fg_alpha *= hud_fade_alpha;\
 317         }\
 318         panel.current_panel_pos = panel_pos; \
 319         panel.current_panel_size = panel_size; \
 320         panel.current_panel_bg_border = panel_bg_border; \
 321         panel.current_panel_bg_color = panel_bg_color; \
 322         panel.current_panel_bg_color_team = panel_bg_color_team; \
 323         panel.current_panel_bg_padding = panel_bg_padding; \
 324         panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval; \
 325 } else { \
 326         panel_pos = panel.current_panel_pos; \
 327         panel_size = panel.current_panel_size; \
 328         panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha; \
 329         panel_bg_border = panel.current_panel_bg_border; \
 330         panel_bg_color = panel.current_panel_bg_color; \
 331         panel_bg_color_team = panel.current_panel_bg_color_team; \
 332         panel_bg_padding = panel.current_panel_bg_padding; \
 333         panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha; \
 334 } ENDS_WITH_CURLY_BRACE
 335
 336 #define HUD_Panel_UpdatePosSize() {\
 337 panel_enabled = cvar(strcat("hud_panel_", panel.panel_name)); \
 338 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos"))); \
 339 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size"))); \
 340 HUD_Panel_ScalePosSize()\
 341 if(menu_enabled == 2 && panel == highlightedPanel) {\
 342         HUD_Panel_UpdatePosSize_ForMenu()\
 343 }\
 344 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border")); \
 345 HUD_Panel_GetBorder() \
 346 } ENDS_WITH_CURLY_BRACE
 347
 348 #define NOTIFY_MAX_ENTRIES 10
 349 #define NOTIFY_ICON_MARGIN 0.02
 350
 351 float notify_index;
 352 float notify_count;
 353 float notify_times[NOTIFY_MAX_ENTRIES];
 354 string notify_attackers[NOTIFY_MAX_ENTRIES];
 355 string notify_victims[NOTIFY_MAX_ENTRIES];
 356 string notify_icons[NOTIFY_MAX_ENTRIES];
 357
 358 void HUD_Notify_Push(string icon, string attacker, string victim);
 359
 360 var void HUD_ModIcons_GameType(vector pos, vector size);
 361 void HUD_ModIcons_SetFunc();