qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_attack");
 142                                         HUD_Write_PanelCvar_q("_aspect");
 143                                         break;
 144                                 case HUD_PANEL_ENGINEINFO:
 145                                         HUD_Write_PanelCvar_q("_framecounter_time");
 146                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 147                                         break;
 148                                 case HUD_PANEL_INFOMESSAGES:
 149                                         HUD_Write_PanelCvar_q("_flip");
 150                                         break;
 151                                 case HUD_PANEL_PHYSICS:
 152                                         HUD_Write_PanelCvar_q("_speed_unit");
 153                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 154                                         HUD_Write_PanelCvar_q("_speed_max");
 155                                         HUD_Write_PanelCvar_q("_speed_vertical");
 156                                         HUD_Write_PanelCvar_q("_topspeed");
 157                                         HUD_Write_PanelCvar_q("_topspeed_time");
 158                                         HUD_Write_PanelCvar_q("_acceleration_max");
 159                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 160                                         HUD_Write_PanelCvar_q("_flip");
 161                                         HUD_Write_PanelCvar_q("_baralign");
 162                                         HUD_Write_PanelCvar_q("_progressbar");
 163                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 164                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 165                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 166                                         HUD_Write_PanelCvar_q("_text");
 167                                         HUD_Write_PanelCvar_q("_text_scale");
 168                                         break;
 169                                 case HUD_PANEL_CENTERPRINT:
 170                                         HUD_Write_PanelCvar_q("_align");
 171                                         HUD_Write_PanelCvar_q("_flip");
 172                                         HUD_Write_PanelCvar_q("_fontscale");
 173                                         HUD_Write_PanelCvar_q("_time");
 174                                         HUD_Write_PanelCvar_q("_fade_in");
 175                                         HUD_Write_PanelCvar_q("_fade_out");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 178                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 179                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 180                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 182                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 183                                         break;
 184                                 case HUD_PANEL_ITEMSTIME:
 185                                         HUD_Write_PanelCvar_q("_iconalign");
 186                                         HUD_Write_PanelCvar_q("_progressbar");
 187                                         HUD_Write_PanelCvar_q("_progressbar_name");
 188                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 189                                         HUD_Write_PanelCvar_q("_showspawned");
 190                                         HUD_Write_PanelCvar_q("_text");
 191                                         HUD_Write_PanelCvar_q("_ratio");
 192                                         break;
 193                         }
 194                         HUD_Write("\n");
 195                 }
 196                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 197
 198                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 199                 fclose(fh);
 200         }
 201         else
 202                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 203 }
 204
 205 void HUD_Configure_Exit_Force()
 206 {
 207         if (menu_enabled)
 208         {
 209                 menu_enabled = 0;
 210                 localcmd("togglemenu\n");
 211         }
 212         cvar_set("_hud_configure", "0");
 213 }
 214
 215 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 216 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 217 {
 218         float i;
 219         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 220         vector myTarget;
 221         myTarget = myPos;
 222
 223         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 224                 if(i == highlightedPanel || !panel_enabled)
 225                         continue;
 226
 227                 HUD_Panel_UpdatePosSizeForId(i);
 228
 229                 panel_pos -= '1 1 0' * panel_bg_border;
 230                 panel_size += '2 2 0' * panel_bg_border;
 231
 232                 if(myPos_y + mySize_y < panel_pos_y)
 233                         continue;
 234                 if(myPos_y > panel_pos_y + panel_size_y)
 235                         continue;
 236
 237                 if(myPos_x + mySize_x < panel_pos_x)
 238                         continue;
 239                 if(myPos_x > panel_pos_x + panel_size_x)
 240                         continue;
 241
 242                 // OK, there IS a collision.
 243
 244                 myCenter_x = myPos_x + 0.5 * mySize_x;
 245                 myCenter_y = myPos_y + 0.5 * mySize_y;
 246
 247                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 248                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 249
 250                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 251                 {
 252                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 253                                 myTarget_x = panel_pos_x - mySize_x;
 254                         else // push it upwards
 255                                 myTarget_y = panel_pos_y - mySize_y;
 256                 }
 257                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 258                 {
 259                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 260                                 myTarget_x = panel_pos_x + panel_size_x;
 261                         else // push it upwards
 262                                 myTarget_y = panel_pos_y - mySize_y;
 263                 }
 264                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 265                 {
 266                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 267                                 myTarget_x = panel_pos_x - mySize_x;
 268                         else // push it downwards
 269                                 myTarget_y = panel_pos_y + panel_size_y;
 270                 }
 271                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 272                 {
 273                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 274                                 myTarget_x = panel_pos_x + panel_size_x;
 275                         else // push it downwards
 276                                 myTarget_y = panel_pos_y + panel_size_y;
 277                 }
 278                 //if(cvar("hud_configure_checkcollisions_debug"))
 279                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 280         }
 281
 282         return myTarget;
 283 }
 284
 285 void HUD_Panel_SetPos(vector pos)
 286 {
 287         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 288         vector mySize;
 289         mySize = panel_size;
 290
 291         //if(cvar("hud_configure_checkcollisions_debug"))
 292                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 293
 294         if(autocvar_hud_configure_grid)
 295         {
 296                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 297                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 298         }
 299
 300         if(hud_configure_checkcollisions)
 301                 pos = HUD_Panel_CheckMove(pos, mySize);
 302
 303         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 304         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 305
 306         string s;
 307         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 308
 309         HUD_Panel_GetName(highlightedPanel);
 310         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 311 }
 312
 313 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 314 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 315         float i;
 316
 317         vector targEndPos;
 318
 319         float dist_x, dist_y;
 320         float ratio;
 321         ratio = mySize_x/mySize_y;
 322
 323         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 324                 if(i == highlightedPanel || !panel_enabled)
 325                         continue;
 326
 327                 HUD_Panel_UpdatePosSizeForId(i);
 328
 329                 panel_pos -= '1 1 0' * panel_bg_border;
 330                 panel_size += '2 2 0' * panel_bg_border;
 331
 332                 targEndPos = panel_pos + panel_size;
 333
 334                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 335                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 336                         continue;
 337
 338                 if (resizeCorner == 1)
 339                 {
 340                         // check if this panel is on our way
 341                         if (resizeorigin_x <= panel_pos_x)
 342                                 continue;
 343                         if (resizeorigin_y <= panel_pos_y)
 344                                 continue;
 345                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 346                                 continue;
 347                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 348                                 continue;
 349
 350                         // there is a collision:
 351                         // detect which side of the panel we are facing is actually limiting the resizing
 352                         // (which side the resize direction finds for first) and reduce the size up to there
 353                         //
 354                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 355                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 356                         dist_x = resizeorigin_x - targEndPos_x;
 357                         dist_y = resizeorigin_y - targEndPos_y;
 358                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 359                                 mySize_x = min(mySize_x, dist_x);
 360                         else
 361                                 mySize_y = min(mySize_y, dist_y);
 362                 }
 363                 else if (resizeCorner == 2)
 364                 {
 365                         if (resizeorigin_x >= targEndPos_x)
 366                                 continue;
 367                         if (resizeorigin_y <= panel_pos_y)
 368                                 continue;
 369                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 370                                 continue;
 371                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 372                                 continue;
 373
 374                         dist_x = panel_pos_x - resizeorigin_x;
 375                         dist_y = resizeorigin_y - targEndPos_y;
 376                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 377                                 mySize_x = min(mySize_x, dist_x);
 378                         else
 379                                 mySize_y = min(mySize_y, dist_y);
 380                 }
 381                 else if (resizeCorner == 3)
 382                 {
 383                         if (resizeorigin_x <= panel_pos_x)
 384                                 continue;
 385                         if (resizeorigin_y >= targEndPos_y)
 386                                 continue;
 387                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 388                                 continue;
 389                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 390                                 continue;
 391
 392                         dist_x = resizeorigin_x - targEndPos_x;
 393                         dist_y = panel_pos_y - resizeorigin_y;
 394                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 395                                 mySize_x = min(mySize_x, dist_x);
 396                         else
 397                                 mySize_y = min(mySize_y, dist_y);
 398                 }
 399                 else if (resizeCorner == 4)
 400                 {
 401                         if (resizeorigin_x >= targEndPos_x)
 402                                 continue;
 403                         if (resizeorigin_y >= targEndPos_y)
 404                                 continue;
 405                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 406                                 continue;
 407                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 408                                 continue;
 409
 410                         dist_x = panel_pos_x - resizeorigin_x;
 411                         dist_y = panel_pos_y - resizeorigin_y;
 412                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 413                                 mySize_x = min(mySize_x, dist_x);
 414                         else
 415                                 mySize_y = min(mySize_y, dist_y);
 416                 }
 417                 //if(cvar("hud_configure_checkcollisions_debug"))
 418                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 419         }
 420
 421         return mySize;
 422 }
 423
 424 void HUD_Panel_SetPosSize(vector mySize)
 425 {
 426         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 427         vector resizeorigin;
 428         resizeorigin = panel_click_resizeorigin;
 429         local noref vector myPos; // fteqcc sucks
 430
 431         // minimum panel size cap
 432         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 433         mySize_y = max(0.025 * vid_conheight, mySize_y);
 434
 435         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 436         {
 437                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 438                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 439         }
 440
 441         // collision testing|
 442         // -----------------+
 443
 444         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 445         if(resizeCorner == 1) {
 446                 myPos_x = resizeorigin_x - mySize_x;
 447                 myPos_y = resizeorigin_y - mySize_y;
 448         } else if(resizeCorner == 2) {
 449                 myPos_x = resizeorigin_x;
 450                 myPos_y = resizeorigin_y - mySize_y;
 451         } else if(resizeCorner == 3) {
 452                 myPos_x = resizeorigin_x - mySize_x;
 453                 myPos_y = resizeorigin_y;
 454         } else { // resizeCorner == 4
 455                 myPos_x = resizeorigin_x;
 456                 myPos_y = resizeorigin_y;
 457         }
 458
 459         // left/top screen edges
 460         if(myPos_x < 0)
 461                 mySize_x = mySize_x + myPos_x;
 462         if(myPos_y < 0)
 463                 mySize_y = mySize_y + myPos_y;
 464
 465         // bottom/right screen edges
 466         if(myPos_x + mySize_x > vid_conwidth)
 467                 mySize_x = vid_conwidth - myPos_x;
 468         if(myPos_y + mySize_y > vid_conheight)
 469                 mySize_y = vid_conheight - myPos_y;
 470
 471         //if(cvar("hud_configure_checkcollisions_debug"))
 472                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 473
 474         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 475         if(autocvar_hud_configure_grid)
 476         {
 477                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 478                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 479         }
 480
 481         if(hud_configure_checkcollisions)
 482                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 483
 484         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 485         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 486         mySize_y = max(0.025 * vid_conheight, mySize_y);
 487
 488         // do another pos check, as size might have changed by now
 489         if(resizeCorner == 1) {
 490                 myPos_x = resizeorigin_x - mySize_x;
 491                 myPos_y = resizeorigin_y - mySize_y;
 492         } else if(resizeCorner == 2) {
 493                 myPos_x = resizeorigin_x;
 494                 myPos_y = resizeorigin_y - mySize_y;
 495         } else if(resizeCorner == 3) {
 496                 myPos_x = resizeorigin_x - mySize_x;
 497                 myPos_y = resizeorigin_y;
 498         } else { // resizeCorner == 4
 499                 myPos_x = resizeorigin_x;
 500                 myPos_y = resizeorigin_y;
 501         }
 502
 503         //if(cvar("hud_configure_checkcollisions_debug"))
 504                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 505
 506         HUD_Panel_GetName(highlightedPanel);
 507         string s;
 508         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 509         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 510
 511         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 512         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 513 }
 514
 515 float pressed_key_time;
 516 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 517 void HUD_Panel_Arrow_Action(float nPrimary)
 518 {
 519         if (highlightedPanel == -1)
 520                 return;
 521
 522         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 523
 524         float step;
 525         if(autocvar_hud_configure_grid)
 526         {
 527                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 528                 {
 529                         if (hudShiftState & S_SHIFT)
 530                                 step = hud_configure_realGridSize_y;
 531                         else
 532                                 step = 2 * hud_configure_realGridSize_y;
 533                 }
 534                 else
 535                 {
 536                         if (hudShiftState & S_SHIFT)
 537                                 step = hud_configure_realGridSize_x;
 538                         else
 539                                 step = 2 * hud_configure_realGridSize_x;
 540                 }
 541         }
 542         else
 543         {
 544                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 545                         step = vid_conheight;
 546                 else
 547                         step = vid_conwidth;
 548                 if (hudShiftState & S_SHIFT)
 549                         step = (step / 256); // more precision
 550                 else
 551                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 552         }
 553
 554         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 555
 556         highlightedPanel_initial_pos = panel_pos;
 557         highlightedPanel_initial_size = panel_size;
 558
 559         if (hudShiftState & S_ALT) // resize
 560         {
 561                 highlightedAction = 1;
 562                 if(nPrimary == K_UPARROW)
 563                         resizeCorner = 1;
 564                 else if(nPrimary == K_RIGHTARROW)
 565                         resizeCorner = 2;
 566                 else if(nPrimary == K_LEFTARROW)
 567                         resizeCorner = 3;
 568                 else // if(nPrimary == K_DOWNARROW)
 569                         resizeCorner = 4;
 570
 571                 // ctrl+arrow reduces the size, instead of increasing it
 572                 // Note that ctrl disables collisions check too, but it's fine
 573                 // since we don't collide with anything reducing the size
 574                 if (hudShiftState & S_CTRL) {
 575                         step = -step;
 576                         resizeCorner = 5 - resizeCorner;
 577                 }
 578
 579                 vector mySize;
 580                 mySize = panel_size;
 581                 panel_click_resizeorigin = panel_pos;
 582                 if(resizeCorner == 1) {
 583                         panel_click_resizeorigin += mySize;
 584                         mySize_y += step;
 585                 } else if(resizeCorner == 2) {
 586                         panel_click_resizeorigin_y += mySize_y;
 587                         mySize_x += step;
 588                 } else if(resizeCorner == 3) {
 589                         panel_click_resizeorigin_x += mySize_x;
 590                         mySize_x += step;
 591                 } else { // resizeCorner == 4
 592                         mySize_y += step;
 593                 }
 594                 HUD_Panel_SetPosSize(mySize);
 595         }
 596         else // move
 597         {
 598                 highlightedAction = 2;
 599                 vector pos;
 600                 pos = panel_pos;
 601                 if(nPrimary == K_UPARROW)
 602                         pos_y -= step;
 603                 else if(nPrimary == K_DOWNARROW)
 604                         pos_y += step;
 605                 else if(nPrimary == K_LEFTARROW)
 606                         pos_x -= step;
 607                 else // if(nPrimary == K_RIGHTARROW)
 608                         pos_x += step;
 609
 610                 HUD_Panel_SetPos(pos);
 611         }
 612
 613         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 614
 615         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 616         {
 617                 // backup!
 618                 panel_pos_backup = highlightedPanel_initial_pos;
 619                 panel_size_backup = highlightedPanel_initial_size;
 620                 highlightedPanel_backup = highlightedPanel;
 621         }
 622 }
 623
 624 const float S_MOUSE1 = 1;
 625 const float S_MOUSE2 = 2;
 626 const float S_MOUSE3 = 4;
 627 float mouseClicked;
 628 float prevMouseClicked; // previous state
 629 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 630 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 631
 632 void HUD_Panel_EnableMenu();
 633 float tab_panels[HUD_PANEL_NUM];
 634 float tab_panel, tab_backward;
 635 vector tab_panel_pos;
 636 void HUD_Panel_FirstInDrawQ(float id);
 637 void reset_tab_panels()
 638 {
 639         int i;
 640         for(i = 0; i < HUD_PANEL_NUM; ++i)
 641                 tab_panels[i] = -1;
 642 }
 643 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 644 {
 645         string s;
 646
 647         // we only care for keyboard events
 648         if(bInputType != 0 && bInputType != 1)
 649                 return false;
 650
 651         if(!autocvar__hud_configure)
 652                 return false;
 653
 654         // block any input while a menu dialog is fading
 655         if(autocvar__menu_alpha)
 656                 return true;
 657
 658         // allow console bind to work
 659         string con_keys;
 660         float keys;
 661         con_keys = findkeysforcommand("toggleconsole", 0);
 662         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 663
 664         float hit_con_bind, i;
 665         for (i = 0; i < keys; ++i)
 666         {
 667                 if(nPrimary == stof(argv(i)))
 668                         hit_con_bind = 1;
 669         }
 670
 671         if(bInputType == 0) {
 672                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 673                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 674                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 675         }
 676         else if(bInputType == 1) {
 677                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 678                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 679                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 680         }
 681
 682         if(nPrimary == K_CTRL)
 683         {
 684                 if (bInputType == 1) //ctrl has been released
 685                 {
 686                         if (tab_panel != -1)
 687                         {
 688                                 //switch to selected panel
 689                                 highlightedPanel = tab_panel;
 690                                 highlightedAction = 0;
 691                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 692                         }
 693                         tab_panel = -1;
 694                         reset_tab_panels();
 695                 }
 696         }
 697
 698         if(nPrimary == K_MOUSE1)
 699         {
 700                 if(bInputType == 0) // key pressed
 701                         mouseClicked |= S_MOUSE1;
 702                 else if(bInputType == 1) // key released
 703                         mouseClicked -= (mouseClicked & S_MOUSE1);
 704         }
 705         else if(nPrimary == K_MOUSE2)
 706         {
 707                 if(bInputType == 0) // key pressed
 708                         mouseClicked |= S_MOUSE2;
 709                 else if(bInputType == 1) // key released
 710                         mouseClicked -= (mouseClicked & S_MOUSE2);
 711         }
 712         else if(nPrimary == K_ESCAPE)
 713         {
 714                 if (bInputType == 1)
 715                         return true;
 716                 menu_enabled = 1;
 717                 menu_enabled_time = time;
 718                 localcmd("menu_showhudexit\n");
 719         }
 720         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 721         {
 722                 if (bInputType == 1)
 723                         return true;
 724                 if (!menu_enabled)
 725                         cvar_set("_hud_configure", "0");
 726         }
 727         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 728         {
 729                 if (bInputType == 1 || mouseClicked)
 730                         return true;
 731
 732                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 733                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 734                 //(it should only after every other panel of the hud)
 735                 //It's a minor bug anyway, we can live with it
 736
 737                 float starting_panel;
 738                 float old_tab_panel = tab_panel;
 739                 if (tab_panel == -1) //first press of TAB
 740                 {
 741                         if (highlightedPanel != -1)
 742                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 743                         else
 744                                 panel_pos = '0 0 0';
 745                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 746                         tab_panel_pos = panel_pos; //to compute level
 747                 }
 748                 else
 749                 {
 750                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 751                                 reset_tab_panels();
 752                         starting_panel = tab_panel;
 753                 }
 754                 tab_backward = (hudShiftState & S_SHIFT);
 755
 756                 float k, level, start_pos_x;
 757                 vector candidate_pos;
 758                 const float LEVELS_NUM = 4;
 759                 float level_height = vid_conheight / LEVELS_NUM;
 760 :find_tab_panel
 761                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 762                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 763                 start_pos_x = tab_panel_pos_x;
 764                 tab_panel = -1;
 765                 k=0;
 766                 while(++k)
 767                 {
 768                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 769                         {
 770                                 if (i == tab_panels[i] || i == starting_panel)
 771                                         continue;
 772                                 HUD_Panel_UpdatePosSizeForId(i)
 773                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 774                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 775                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 776                                 {
 777                                         tab_panel = i;
 778                                         tab_panel_pos = candidate_pos = panel_pos;
 779                                 }
 780                         }
 781                         if (tab_panel != -1)
 782                                 break;
 783                         if (k == LEVELS_NUM) //tab_panel not found
 784                         {
 785                                 reset_tab_panels();
 786                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 787                                 {
 788                                         tab_panel = -1;
 789                                         return true;
 790                                 }
 791                                 starting_panel = old_tab_panel;
 792                                 old_tab_panel = -2;
 793                                 goto find_tab_panel; //u must find tab_panel!
 794                         }
 795                         if (!tab_backward)
 796                         {
 797                                 level = mod(level + level_height, vid_conheight);
 798                                 start_pos_x = 0;
 799                                 candidate_pos_x = vid_conwidth;
 800                         }
 801                         else
 802                         {
 803                                 level = mod(level - level_height, vid_conheight);
 804                                 start_pos_x = vid_conwidth;
 805                                 candidate_pos_x = 0;
 806                         }
 807                 }
 808
 809                 tab_panels[tab_panel] = tab_panel;
 810         }
 811         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 812         {
 813                 if (bInputType == 1 || mouseClicked)
 814                         return true;
 815
 816                 if (highlightedPanel != -1)
 817                 {
 818                         HUD_Panel_GetName(highlightedPanel);
 819                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 820                 }
 821                 else
 822                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 823         }
 824         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 825         {
 826                 if (bInputType == 1 || mouseClicked)
 827                         return true;
 828
 829                 if (highlightedPanel != -1)
 830                 {
 831                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 832                         panel_size_copied = panel_size;
 833                         highlightedPanel_copied = highlightedPanel;
 834                 }
 835         }
 836         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 837         {
 838                 if (bInputType == 1 || mouseClicked)
 839                         return true;
 840
 841                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 842                         return true;
 843
 844                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 845
 846                 // reduce size if it'd go beyond screen boundaries
 847                 vector tmp_size = panel_size_copied;
 848                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 849                         tmp_size_x = vid_conwidth - panel_pos_x;
 850                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 851                         tmp_size_y = vid_conheight - panel_pos_y;
 852
 853                 if (panel_size == tmp_size)
 854                         return true;
 855
 856                 // backup first!
 857                 panel_pos_backup = panel_pos;
 858                 panel_size_backup = panel_size;
 859                 highlightedPanel_backup = highlightedPanel;
 860
 861                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 862                 HUD_Panel_GetName(highlightedPanel);
 863                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 864         }
 865         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 866         {
 867                 if (bInputType == 1 || mouseClicked)
 868                         return true;
 869                 //restore previous values
 870                 if (highlightedPanel_backup != -1)
 871                 {
 872                         HUD_Panel_GetName(highlightedPanel_backup);
 873                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 874                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 875                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 876                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 877                         highlightedPanel_backup = -1;
 878                 }
 879         }
 880         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 881         {
 882                 if (bInputType == 1)
 883                 {
 884                         pressed_key_time = 0;
 885                         return true;
 886                 }
 887                 else if (pressed_key_time == 0)
 888                         pressed_key_time = time;
 889
 890                 if (!mouseClicked)
 891                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 892         }
 893         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 894         {
 895                 if (bInputType == 1)
 896                         return true;
 897                 if (highlightedPanel != -1)
 898                         HUD_Panel_EnableMenu();
 899         }
 900         else if(hit_con_bind)
 901                 return false;
 902
 903         return true;
 904 }
 905
 906 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 907 {
 908         float i, j, border;
 909
 910         while(j < HUD_PANEL_NUM)
 911         {
 912                 i = panel_order[j];
 913                 j += 1;
 914
 915                 HUD_Panel_UpdatePosSizeForId(i);
 916
 917                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 918
 919                 // move
 920                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 921                 {
 922                         return 1;
 923                 }
 924                 // resize from topleft border
 925                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 926                 {
 927                         return 2;
 928                 }
 929                 // resize from topright border
 930                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 931                 {
 932                         return 3;
 933                 }
 934                 // resize from bottomleft border
 935                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 936                 {
 937                         return 3;
 938                 }
 939                 // resize from bottomright border
 940                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 941                 {
 942                         return 2;
 943                 }
 944         }
 945         return 0;
 946 }
 947
 948 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 949 void HUD_Panel_FirstInDrawQ(float id)
 950 {
 951         float i;
 952         var float place = -1;
 953         // find out where in the array our current id is, save into place
 954         for(i = 0; i < HUD_PANEL_NUM; ++i)
 955         {
 956                 if(panel_order[i] == id)
 957                 {
 958                         place = i;
 959                         break;
 960                 }
 961         }
 962         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 963         if(place == -1)
 964                 place = HUD_PANEL_NUM - 1;
 965
 966         // move all ids up by one step in the array until "place"
 967         for(i = place; i > 0; --i)
 968         {
 969                 panel_order[i] = panel_order[i-1];
 970         }
 971         // now save the new top id
 972         panel_order[0] = id;
 973
 974         // let's save them into the cvar by some strcat trickery
 975         string s;
 976         for(i = 0; i < HUD_PANEL_NUM; ++i)
 977         {
 978                 s = strcat(s, ftos(panel_order[i]), " ");
 979         }
 980         cvar_set("_hud_panelorder", s);
 981         if(hud_panelorder_prev)
 982                 strunzone(hud_panelorder_prev);
 983         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 984 }
 985
 986 void HUD_Panel_Highlight(float allow_move)
 987 {
 988         float i, j, border;
 989
 990         while(j < HUD_PANEL_NUM)
 991         {
 992                 i = panel_order[j];
 993                 j += 1;
 994
 995                 HUD_Panel_UpdatePosSizeForId(i);
 996
 997                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 998
 999                 // move
1000                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
1001                 {
1002                         highlightedPanel = i;
1003                         HUD_Panel_FirstInDrawQ(i);
1004                         highlightedAction = 1;
1005                         panel_click_distance = mousepos - panel_pos;
1006                         return;
1007                 }
1008                 // resize from topleft border
1009                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1010                 {
1011                         highlightedPanel = i;
1012                         HUD_Panel_FirstInDrawQ(i);
1013                         highlightedAction = 2;
1014                         resizeCorner = 1;
1015                         panel_click_distance = mousepos - panel_pos;
1016                         panel_click_resizeorigin = panel_pos + panel_size;
1017                         return;
1018                 }
1019                 // resize from topright border
1020                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1021                 {
1022                         highlightedPanel = i;
1023                         HUD_Panel_FirstInDrawQ(i);
1024                         highlightedAction = 2;
1025                         resizeCorner = 2;
1026                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1027                         panel_click_distance_y = mousepos_y - panel_pos_y;
1028                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1029                         return;
1030                 }
1031                 // resize from bottomleft border
1032                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1033                 {
1034                         highlightedPanel = i;
1035                         HUD_Panel_FirstInDrawQ(i);
1036                         highlightedAction = 2;
1037                         resizeCorner = 3;
1038                         panel_click_distance_x = mousepos_x - panel_pos_x;
1039                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1040                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1041                         return;
1042                 }
1043                 // resize from bottomright border
1044                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1045                 {
1046                         highlightedPanel = i;
1047                         HUD_Panel_FirstInDrawQ(i);
1048                         highlightedAction = 2;
1049                         resizeCorner = 4;
1050                         panel_click_distance = panel_size - mousepos + panel_pos;
1051                         panel_click_resizeorigin = panel_pos;
1052                         return;
1053                 }
1054         }
1055         highlightedPanel = -1;
1056         highlightedAction = 0;
1057 }
1058
1059 void HUD_Panel_EnableMenu()
1060 {
1061         menu_enabled = 2;
1062         menu_enabled_time = time;
1063         HUD_Panel_GetName(highlightedPanel);
1064         localcmd("menu_showhudoptions ", panel_name, "\n");
1065 }
1066 float mouse_over_panel;
1067 void HUD_Panel_Mouse()
1068 {
1069         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1070         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1071                 menu_enabled = 0;
1072
1073         /*
1074         print("menu_enabled: ", ftos(menu_enabled), "\n");
1075         print("Highlighted: ", ftos(highlightedPanel), "\n");
1076         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1077         */
1078
1079         if(autocvar__menu_alpha == 1)
1080                 return;
1081
1082         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1083
1084         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1085         mousepos_y = bound(0, mousepos_y, vid_conheight);
1086
1087         if(mouseClicked)
1088         {
1089                 if(prevMouseClicked == 0)
1090                 {
1091                         if (tab_panel != -1)
1092                         {
1093                                 //stop ctrl-tab selection
1094                                 tab_panel = -1;
1095                                 reset_tab_panels();
1096                         }
1097                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1098                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1099                         if (highlightedPanel != -1)
1100                         {
1101                                 highlightedPanel_initial_pos = panel_pos;
1102                                 highlightedPanel_initial_size = panel_size;
1103                         }
1104                         // doubleclick check
1105                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1106                         {
1107                                 mouseClicked = 0; // to prevent spam, I guess.
1108                                 HUD_Panel_EnableMenu();
1109                         }
1110                         else
1111                         {
1112                                 if (mouseClicked & S_MOUSE1)
1113                                 {
1114                                         prevMouseClickedTime = time;
1115                                         prevMouseClickedPos = mousepos;
1116                                 }
1117                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1118                         }
1119                 }
1120                 else
1121                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1122
1123                 if (highlightedPanel != -1)
1124                 {
1125                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1126                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1127                         {
1128                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1129                                 // backup!
1130                                 panel_pos_backup = highlightedPanel_initial_pos;
1131                                 panel_size_backup = highlightedPanel_initial_size;
1132                                 highlightedPanel_backup = highlightedPanel;
1133                         }
1134                         else
1135                                 // in case the clicked panel is inside another panel and we aren't
1136                                 // moving it, avoid the immediate "fix" of its position/size
1137                                 // (often unwanted and hateful) by disabling collisions check
1138                                 hud_configure_checkcollisions = false;
1139                 }
1140
1141                 if(highlightedAction == 1)
1142                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1143                 else if(highlightedAction == 2)
1144                 {
1145                         vector mySize;
1146                         if(resizeCorner == 1) {
1147                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1148                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1149                         } else if(resizeCorner == 2) {
1150                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1151                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1152                         } else if(resizeCorner == 3) {
1153                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1154                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1155                         } else { // resizeCorner == 4
1156                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1157                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1158                         }
1159                         HUD_Panel_SetPosSize(mySize);
1160                 }
1161         }
1162         else
1163         {
1164                 if(menu_enabled == 2)
1165                         mouse_over_panel = 0;
1166                 else
1167                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1168                 if (mouse_over_panel && tab_panel == -1)
1169                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1170         }
1171         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1172         const vector cursorsize = '32 32 0';
1173         float cursor_alpha = 1 - autocvar__menu_alpha;
1174
1175         if(!mouse_over_panel)
1176                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1177         else if(mouse_over_panel == 1)
1178                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1179         else if(mouse_over_panel == 2)
1180                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1181         else
1182                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1183
1184         prevMouseClicked = mouseClicked;
1185 }
1186
1187 const float hlBorderSize = 4;
1188 const string hlBorder = "gfx/hud/default/border_highlighted";
1189 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1190 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1191 {
1192         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1193         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1194         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1195         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1196         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1197 }