qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_aspect");
 142                                         break;
 143                                 case HUD_PANEL_ENGINEINFO:
 144                                         HUD_Write_PanelCvar_q("_framecounter_time");
 145                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 146                                         break;
 147                                 case HUD_PANEL_INFOMESSAGES:
 148                                         HUD_Write_PanelCvar_q("_flip");
 149                                         break;
 150                                 case HUD_PANEL_PHYSICS:
 151                                         HUD_Write_PanelCvar_q("_speed_unit");
 152                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 153                                         HUD_Write_PanelCvar_q("_speed_max");
 154                                         HUD_Write_PanelCvar_q("_speed_vertical");
 155                                         HUD_Write_PanelCvar_q("_topspeed");
 156                                         HUD_Write_PanelCvar_q("_topspeed_time");
 157                                         HUD_Write_PanelCvar_q("_acceleration_max");
 158                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         HUD_Write_PanelCvar_q("_baralign");
 161                                         HUD_Write_PanelCvar_q("_progressbar");
 162                                         HUD_Write_PanelCvar_q("_acceleration_mode");
 163                                         HUD_Write_PanelCvar_q("_text");
 164                                         break;
 165                                 case HUD_PANEL_CENTERPRINT:
 166                                         HUD_Write_PanelCvar_q("_align");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_fontscale");
 169                                         HUD_Write_PanelCvar_q("_time");
 170                                         HUD_Write_PanelCvar_q("_fade_in");
 171                                         HUD_Write_PanelCvar_q("_fade_out");
 172                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 173                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 174                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 175                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 178                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 179                                         break;
 180                                 case HUD_PANEL_ITEMSTIME:
 181                                         HUD_Write_PanelCvar_q("_iconalign");
 182                                         HUD_Write_PanelCvar_q("_progressbar");
 183                                         HUD_Write_PanelCvar_q("_progressbar_name");
 184                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 185                                         HUD_Write_PanelCvar_q("_showspawned");
 186                                         HUD_Write_PanelCvar_q("_text");
 187                                         break;
 188                         }
 189                         HUD_Write("\n");
 190                 }
 191                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 192
 193                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 194                 fclose(fh);
 195         }
 196         else
 197                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 198 }
 199
 200 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 201 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 202 {
 203         float i;
 204         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 205         vector myTarget;
 206         myTarget = myPos;
 207
 208         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 209                 if(i == highlightedPanel || !panel_enabled)
 210                         continue;
 211
 212                 HUD_Panel_UpdatePosSizeForId(i);
 213
 214                 panel_pos -= '1 1 0' * panel_bg_border;
 215                 panel_size += '2 2 0' * panel_bg_border;
 216
 217                 if(myPos_y + mySize_y < panel_pos_y)
 218                         continue;
 219                 if(myPos_y > panel_pos_y + panel_size_y)
 220                         continue;
 221
 222                 if(myPos_x + mySize_x < panel_pos_x)
 223                         continue;
 224                 if(myPos_x > panel_pos_x + panel_size_x)
 225                         continue;
 226
 227                 // OK, there IS a collision.
 228
 229                 myCenter_x = myPos_x + 0.5 * mySize_x;
 230                 myCenter_y = myPos_y + 0.5 * mySize_y;
 231
 232                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 233                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 234
 235                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 236                 {
 237                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 238                                 myTarget_x = panel_pos_x - mySize_x;
 239                         else // push it upwards
 240                                 myTarget_y = panel_pos_y - mySize_y;
 241                 }
 242                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 243                 {
 244                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 245                                 myTarget_x = panel_pos_x + panel_size_x;
 246                         else // push it upwards
 247                                 myTarget_y = panel_pos_y - mySize_y;
 248                 }
 249                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 250                 {
 251                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 252                                 myTarget_x = panel_pos_x - mySize_x;
 253                         else // push it downwards
 254                                 myTarget_y = panel_pos_y + panel_size_y;
 255                 }
 256                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 257                 {
 258                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 259                                 myTarget_x = panel_pos_x + panel_size_x;
 260                         else // push it downwards
 261                                 myTarget_y = panel_pos_y + panel_size_y;
 262                 }
 263                 //if(cvar("hud_configure_checkcollisions_debug"))
 264                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 265         }
 266
 267         return myTarget;
 268 }
 269
 270 void HUD_Panel_SetPos(vector pos)
 271 {
 272         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 273         vector mySize;
 274         mySize = panel_size;
 275
 276         //if(cvar("hud_configure_checkcollisions_debug"))
 277                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 278
 279         if(autocvar_hud_configure_grid)
 280         {
 281                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 282                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 283         }
 284
 285         if(hud_configure_checkcollisions)
 286                 pos = HUD_Panel_CheckMove(pos, mySize);
 287
 288         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 289         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 290
 291         string s;
 292         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 293
 294         HUD_Panel_GetName(highlightedPanel);
 295         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 296 }
 297
 298 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 299 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 300         float i;
 301
 302         vector targEndPos;
 303
 304         float dist_x, dist_y;
 305         float ratio;
 306         ratio = mySize_x/mySize_y;
 307
 308         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 309                 if(i == highlightedPanel || !panel_enabled)
 310                         continue;
 311
 312                 HUD_Panel_UpdatePosSizeForId(i);
 313
 314                 panel_pos -= '1 1 0' * panel_bg_border;
 315                 panel_size += '2 2 0' * panel_bg_border;
 316
 317                 targEndPos = panel_pos + panel_size;
 318
 319                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 320                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 321                         continue;
 322
 323                 if (resizeCorner == 1)
 324                 {
 325                         // check if this panel is on our way
 326                         if (resizeorigin_x <= panel_pos_x)
 327                                 continue;
 328                         if (resizeorigin_y <= panel_pos_y)
 329                                 continue;
 330                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 331                                 continue;
 332                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 333                                 continue;
 334
 335                         // there is a collision:
 336                         // detect which side of the panel we are facing is actually limiting the resizing
 337                         // (which side the resize direction finds for first) and reduce the size up to there
 338                         //
 339                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 340                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 341                         dist_x = resizeorigin_x - targEndPos_x;
 342                         dist_y = resizeorigin_y - targEndPos_y;
 343                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 344                                 mySize_x = min(mySize_x, dist_x);
 345                         else
 346                                 mySize_y = min(mySize_y, dist_y);
 347                 }
 348                 else if (resizeCorner == 2)
 349                 {
 350                         if (resizeorigin_x >= targEndPos_x)
 351                                 continue;
 352                         if (resizeorigin_y <= panel_pos_y)
 353                                 continue;
 354                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 355                                 continue;
 356                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 357                                 continue;
 358
 359                         dist_x = panel_pos_x - resizeorigin_x;
 360                         dist_y = resizeorigin_y - targEndPos_y;
 361                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 362                                 mySize_x = min(mySize_x, dist_x);
 363                         else
 364                                 mySize_y = min(mySize_y, dist_y);
 365                 }
 366                 else if (resizeCorner == 3)
 367                 {
 368                         if (resizeorigin_x <= panel_pos_x)
 369                                 continue;
 370                         if (resizeorigin_y >= targEndPos_y)
 371                                 continue;
 372                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 373                                 continue;
 374                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 375                                 continue;
 376
 377                         dist_x = resizeorigin_x - targEndPos_x;
 378                         dist_y = panel_pos_y - resizeorigin_y;
 379                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 380                                 mySize_x = min(mySize_x, dist_x);
 381                         else
 382                                 mySize_y = min(mySize_y, dist_y);
 383                 }
 384                 else if (resizeCorner == 4)
 385                 {
 386                         if (resizeorigin_x >= targEndPos_x)
 387                                 continue;
 388                         if (resizeorigin_y >= targEndPos_y)
 389                                 continue;
 390                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 391                                 continue;
 392                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 393                                 continue;
 394
 395                         dist_x = panel_pos_x - resizeorigin_x;
 396                         dist_y = panel_pos_y - resizeorigin_y;
 397                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 398                                 mySize_x = min(mySize_x, dist_x);
 399                         else
 400                                 mySize_y = min(mySize_y, dist_y);
 401                 }
 402                 //if(cvar("hud_configure_checkcollisions_debug"))
 403                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 404         }
 405
 406         return mySize;
 407 }
 408
 409 void HUD_Panel_SetPosSize(vector mySize)
 410 {
 411         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 412         vector resizeorigin;
 413         resizeorigin = panel_click_resizeorigin;
 414         local noref vector myPos; // fteqcc sucks
 415
 416         // minimum panel size cap
 417         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 418         mySize_y = max(0.025 * vid_conheight, mySize_y);
 419
 420         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 421         {
 422                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 423                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 424         }
 425
 426         // collision testing|
 427         // -----------------+
 428
 429         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 430         if(resizeCorner == 1) {
 431                 myPos_x = resizeorigin_x - mySize_x;
 432                 myPos_y = resizeorigin_y - mySize_y;
 433         } else if(resizeCorner == 2) {
 434                 myPos_x = resizeorigin_x;
 435                 myPos_y = resizeorigin_y - mySize_y;
 436         } else if(resizeCorner == 3) {
 437                 myPos_x = resizeorigin_x - mySize_x;
 438                 myPos_y = resizeorigin_y;
 439         } else { // resizeCorner == 4
 440                 myPos_x = resizeorigin_x;
 441                 myPos_y = resizeorigin_y;
 442         }
 443
 444         // left/top screen edges
 445         if(myPos_x < 0)
 446                 mySize_x = mySize_x + myPos_x;
 447         if(myPos_y < 0)
 448                 mySize_y = mySize_y + myPos_y;
 449
 450         // bottom/right screen edges
 451         if(myPos_x + mySize_x > vid_conwidth)
 452                 mySize_x = vid_conwidth - myPos_x;
 453         if(myPos_y + mySize_y > vid_conheight)
 454                 mySize_y = vid_conheight - myPos_y;
 455
 456         //if(cvar("hud_configure_checkcollisions_debug"))
 457                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 458
 459         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 460         if(autocvar_hud_configure_grid)
 461         {
 462                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 463                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 464         }
 465
 466         if(hud_configure_checkcollisions)
 467                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 468
 469         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 470         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 471         mySize_y = max(0.025 * vid_conheight, mySize_y);
 472
 473         // do another pos check, as size might have changed by now
 474         if(resizeCorner == 1) {
 475                 myPos_x = resizeorigin_x - mySize_x;
 476                 myPos_y = resizeorigin_y - mySize_y;
 477         } else if(resizeCorner == 2) {
 478                 myPos_x = resizeorigin_x;
 479                 myPos_y = resizeorigin_y - mySize_y;
 480         } else if(resizeCorner == 3) {
 481                 myPos_x = resizeorigin_x - mySize_x;
 482                 myPos_y = resizeorigin_y;
 483         } else { // resizeCorner == 4
 484                 myPos_x = resizeorigin_x;
 485                 myPos_y = resizeorigin_y;
 486         }
 487
 488         //if(cvar("hud_configure_checkcollisions_debug"))
 489                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 490
 491         HUD_Panel_GetName(highlightedPanel);
 492         string s;
 493         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 494         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 495
 496         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 497         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 498 }
 499
 500 float pressed_key_time;
 501 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 502 void HUD_Panel_Arrow_Action(float nPrimary)
 503 {
 504         if (highlightedPanel == -1)
 505                 return;
 506
 507         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 508
 509         float step;
 510         if(autocvar_hud_configure_grid)
 511         {
 512                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 513                 {
 514                         if (hudShiftState & S_SHIFT)
 515                                 step = hud_configure_realGridSize_y;
 516                         else
 517                                 step = 2 * hud_configure_realGridSize_y;
 518                 }
 519                 else
 520                 {
 521                         if (hudShiftState & S_SHIFT)
 522                                 step = hud_configure_realGridSize_x;
 523                         else
 524                                 step = 2 * hud_configure_realGridSize_x;
 525                 }
 526         }
 527         else
 528         {
 529                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 530                         step = vid_conheight;
 531                 else
 532                         step = vid_conwidth;
 533                 if (hudShiftState & S_SHIFT)
 534                         step = (step / 256); // more precision
 535                 else
 536                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 537         }
 538
 539         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 540
 541         highlightedPanel_initial_pos = panel_pos;
 542         highlightedPanel_initial_size = panel_size;
 543
 544         if (hudShiftState & S_ALT) // resize
 545         {
 546                 highlightedAction = 1;
 547                 if(nPrimary == K_UPARROW)
 548                         resizeCorner = 1;
 549                 else if(nPrimary == K_RIGHTARROW)
 550                         resizeCorner = 2;
 551                 else if(nPrimary == K_LEFTARROW)
 552                         resizeCorner = 3;
 553                 else // if(nPrimary == K_DOWNARROW)
 554                         resizeCorner = 4;
 555
 556                 // ctrl+arrow reduces the size, instead of increasing it
 557                 // Note that ctrl disables collisions check too, but it's fine
 558                 // since we don't collide with anything reducing the size
 559                 if (hudShiftState & S_CTRL) {
 560                         step = -step;
 561                         resizeCorner = 5 - resizeCorner;
 562                 }
 563
 564                 vector mySize;
 565                 mySize = panel_size;
 566                 panel_click_resizeorigin = panel_pos;
 567                 if(resizeCorner == 1) {
 568                         panel_click_resizeorigin += mySize;
 569                         mySize_y += step;
 570                 } else if(resizeCorner == 2) {
 571                         panel_click_resizeorigin_y += mySize_y;
 572                         mySize_x += step;
 573                 } else if(resizeCorner == 3) {
 574                         panel_click_resizeorigin_x += mySize_x;
 575                         mySize_x += step;
 576                 } else { // resizeCorner == 4
 577                         mySize_y += step;
 578                 }
 579                 HUD_Panel_SetPosSize(mySize);
 580         }
 581         else // move
 582         {
 583                 highlightedAction = 2;
 584                 vector pos;
 585                 pos = panel_pos;
 586                 if(nPrimary == K_UPARROW)
 587                         pos_y -= step;
 588                 else if(nPrimary == K_DOWNARROW)
 589                         pos_y += step;
 590                 else if(nPrimary == K_LEFTARROW)
 591                         pos_x -= step;
 592                 else // if(nPrimary == K_RIGHTARROW)
 593                         pos_x += step;
 594
 595                 HUD_Panel_SetPos(pos);
 596         }
 597
 598         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 599
 600         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 601         {
 602                 // backup!
 603                 panel_pos_backup = highlightedPanel_initial_pos;
 604                 panel_size_backup = highlightedPanel_initial_size;
 605                 highlightedPanel_backup = highlightedPanel;
 606         }
 607 }
 608
 609 const float S_MOUSE1 = 1;
 610 const float S_MOUSE2 = 2;
 611 const float S_MOUSE3 = 4;
 612 float mouseClicked;
 613 float prevMouseClicked; // previous state
 614 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 615 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 616
 617 void HUD_Panel_EnableMenu();
 618 float tab_panels[HUD_PANEL_NUM];
 619 float tab_panel, tab_backward;
 620 vector tab_panel_pos;
 621 void HUD_Panel_FirstInDrawQ(float id);
 622 void reset_tab_panels()
 623 {
 624         int i;
 625         for(i = 0; i < HUD_PANEL_NUM; ++i)
 626                 tab_panels[i] = -1;
 627 }
 628 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 629 {
 630         string s;
 631
 632         // we only care for keyboard events
 633         if(bInputType != 0 && bInputType != 1)
 634                 return false;
 635
 636         if(!autocvar__hud_configure)
 637                 return false;
 638
 639         // allow console bind to work
 640         string con_keys;
 641         float keys;
 642         con_keys = findkeysforcommand("toggleconsole", 0);
 643         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 644
 645         float hit_con_bind, i;
 646         for (i = 0; i < keys; ++i)
 647         {
 648                 if(nPrimary == stof(argv(i)))
 649                         hit_con_bind = 1;
 650         }
 651
 652         if(bInputType == 0) {
 653                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 654                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 655                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 656         }
 657         else if(bInputType == 1) {
 658                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 659                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 660                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 661         }
 662
 663         if(nPrimary == K_CTRL)
 664         {
 665                 if (bInputType == 1) //ctrl has been released
 666                 {
 667                         if (tab_panel != -1)
 668                         {
 669                                 //switch to selected panel
 670                                 highlightedPanel = tab_panel;
 671                                 highlightedAction = 0;
 672                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 673                         }
 674                         tab_panel = -1;
 675                         reset_tab_panels();
 676                 }
 677         }
 678
 679         if(nPrimary == K_MOUSE1)
 680         {
 681                 if(bInputType == 0) // key pressed
 682                         mouseClicked |= S_MOUSE1;
 683                 else if(bInputType == 1) // key released
 684                         mouseClicked -= (mouseClicked & S_MOUSE1);
 685         }
 686         else if(nPrimary == K_MOUSE2)
 687         {
 688                 if(bInputType == 0) // key pressed
 689                         mouseClicked |= S_MOUSE2;
 690                 else if(bInputType == 1) // key released
 691                         mouseClicked -= (mouseClicked & S_MOUSE2);
 692         }
 693         else if(nPrimary == K_ESCAPE)
 694         {
 695                 if (bInputType == 1)
 696                         return true;
 697                 menu_enabled = 1;
 698                 menu_enabled_time = time;
 699                 localcmd("menu_showhudexit\n");
 700         }
 701         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 702         {
 703                 if (bInputType == 1)
 704                         return true;
 705                 if (!menu_enabled)
 706                         cvar_set("_hud_configure", "0");
 707         }
 708         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 709         {
 710                 if (bInputType == 1 || mouseClicked)
 711                         return true;
 712
 713                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 714                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 715                 //(it should only after every other panel of the hud)
 716                 //It's a minor bug anyway, we can live with it
 717
 718                 float starting_panel;
 719                 float old_tab_panel = tab_panel;
 720                 if (tab_panel == -1) //first press of TAB
 721                 {
 722                         if (highlightedPanel != -1)
 723                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 724                         else
 725                                 panel_pos = '0 0 0';
 726                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 727                         tab_panel_pos = panel_pos; //to compute level
 728                 }
 729                 else
 730                 {
 731                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 732                                 reset_tab_panels();
 733                         starting_panel = tab_panel;
 734                 }
 735                 tab_backward = (hudShiftState & S_SHIFT);
 736
 737                 float k, level, start_pos_x;
 738                 vector candidate_pos;
 739                 const float LEVELS_NUM = 4;
 740                 float level_height = vid_conheight / LEVELS_NUM;
 741 :find_tab_panel
 742                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 743                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 744                 start_pos_x = tab_panel_pos_x;
 745                 tab_panel = -1;
 746                 k=0;
 747                 while(++k)
 748                 {
 749                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 750                         {
 751                                 if (i == tab_panels[i] || i == starting_panel)
 752                                         continue;
 753                                 HUD_Panel_UpdatePosSizeForId(i)
 754                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 755                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 756                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 757                                 {
 758                                         tab_panel = i;
 759                                         tab_panel_pos = candidate_pos = panel_pos;
 760                                 }
 761                         }
 762                         if (tab_panel != -1)
 763                                 break;
 764                         if (k == LEVELS_NUM) //tab_panel not found
 765                         {
 766                                 reset_tab_panels();
 767                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 768                                 {
 769                                         tab_panel = -1;
 770                                         return true;
 771                                 }
 772                                 starting_panel = old_tab_panel;
 773                                 old_tab_panel = -2;
 774                                 goto find_tab_panel; //u must find tab_panel!
 775                         }
 776                         if (!tab_backward)
 777                         {
 778                                 level = mod(level + level_height, vid_conheight);
 779                                 start_pos_x = 0;
 780                                 candidate_pos_x = vid_conwidth;
 781                         }
 782                         else
 783                         {
 784                                 level = mod(level - level_height, vid_conheight);
 785                                 start_pos_x = vid_conwidth;
 786                                 candidate_pos_x = 0;
 787                         }
 788                 }
 789
 790                 tab_panels[tab_panel] = tab_panel;
 791         }
 792         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 793         {
 794                 if (bInputType == 1 || mouseClicked)
 795                         return true;
 796
 797                 if (highlightedPanel != -1)
 798                 {
 799                         HUD_Panel_GetName(highlightedPanel);
 800                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 801                 }
 802                 else
 803                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 804         }
 805         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 806         {
 807                 if (bInputType == 1 || mouseClicked)
 808                         return true;
 809
 810                 if (highlightedPanel != -1)
 811                 {
 812                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 813                         panel_size_copied = panel_size;
 814                         highlightedPanel_copied = highlightedPanel;
 815                 }
 816         }
 817         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 818         {
 819                 if (bInputType == 1 || mouseClicked)
 820                         return true;
 821
 822                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 823                         return true;
 824
 825                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 826
 827                 // reduce size if it'd go beyond screen boundaries
 828                 vector tmp_size = panel_size_copied;
 829                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 830                         tmp_size_x = vid_conwidth - panel_pos_x;
 831                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 832                         tmp_size_y = vid_conheight - panel_pos_y;
 833
 834                 if (panel_size == tmp_size)
 835                         return true;
 836
 837                 // backup first!
 838                 panel_pos_backup = panel_pos;
 839                 panel_size_backup = panel_size;
 840                 highlightedPanel_backup = highlightedPanel;
 841
 842                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 843                 HUD_Panel_GetName(highlightedPanel);
 844                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 845         }
 846         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 847         {
 848                 if (bInputType == 1 || mouseClicked)
 849                         return true;
 850                 //restore previous values
 851                 if (highlightedPanel_backup != -1)
 852                 {
 853                         HUD_Panel_GetName(highlightedPanel_backup);
 854                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 855                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 856                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 857                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 858                         highlightedPanel_backup = -1;
 859                 }
 860         }
 861         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 862         {
 863                 if (bInputType == 1)
 864                 {
 865                         pressed_key_time = 0;
 866                         return true;
 867                 }
 868                 else if (pressed_key_time == 0)
 869                         pressed_key_time = time;
 870
 871                 if (!mouseClicked)
 872                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 873         }
 874         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 875         {
 876                 if (bInputType == 1)
 877                         return true;
 878                 if (highlightedPanel != -1)
 879                         HUD_Panel_EnableMenu();
 880         }
 881         else if(hit_con_bind)
 882                 return false;
 883
 884         return true;
 885 }
 886
 887 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 888 {
 889         float i, j, border;
 890
 891         while(j < HUD_PANEL_NUM)
 892         {
 893                 i = panel_order[j];
 894                 j += 1;
 895
 896                 HUD_Panel_UpdatePosSizeForId(i);
 897
 898                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 899
 900                 // move
 901                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 902                 {
 903                         return 1;
 904                 }
 905                 // resize from topleft border
 906                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 907                 {
 908                         return 2;
 909                 }
 910                 // resize from topright border
 911                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 912                 {
 913                         return 3;
 914                 }
 915                 // resize from bottomleft border
 916                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 917                 {
 918                         return 3;
 919                 }
 920                 // resize from bottomright border
 921                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 922                 {
 923                         return 2;
 924                 }
 925         }
 926         return 0;
 927 }
 928
 929 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 930 void HUD_Panel_FirstInDrawQ(float id)
 931 {
 932         float i;
 933         var float place = -1;
 934         // find out where in the array our current id is, save into place
 935         for(i = 0; i < HUD_PANEL_NUM; ++i)
 936         {
 937                 if(panel_order[i] == id)
 938                 {
 939                         place = i;
 940                         break;
 941                 }
 942         }
 943         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 944         if(place == -1)
 945                 place = HUD_PANEL_NUM - 1;
 946
 947         // move all ids up by one step in the array until "place"
 948         for(i = place; i > 0; --i)
 949         {
 950                 panel_order[i] = panel_order[i-1];
 951         }
 952         // now save the new top id
 953         panel_order[0] = id;
 954
 955         // let's save them into the cvar by some strcat trickery
 956         string s;
 957         for(i = 0; i < HUD_PANEL_NUM; ++i)
 958         {
 959                 s = strcat(s, ftos(panel_order[i]), " ");
 960         }
 961         cvar_set("_hud_panelorder", s);
 962         if(hud_panelorder_prev)
 963                 strunzone(hud_panelorder_prev);
 964         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 965 }
 966
 967 void HUD_Panel_Highlight(float allow_move)
 968 {
 969         float i, j, border;
 970
 971         while(j < HUD_PANEL_NUM)
 972         {
 973                 i = panel_order[j];
 974                 j += 1;
 975
 976                 HUD_Panel_UpdatePosSizeForId(i);
 977
 978                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 979
 980                 // move
 981                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 982                 {
 983                         highlightedPanel = i;
 984                         HUD_Panel_FirstInDrawQ(i);
 985                         highlightedAction = 1;
 986                         panel_click_distance = mousepos - panel_pos;
 987                         return;
 988                 }
 989                 // resize from topleft border
 990                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 991                 {
 992                         highlightedPanel = i;
 993                         HUD_Panel_FirstInDrawQ(i);
 994                         highlightedAction = 2;
 995                         resizeCorner = 1;
 996                         panel_click_distance = mousepos - panel_pos;
 997                         panel_click_resizeorigin = panel_pos + panel_size;
 998                         return;
 999                 }
1000                 // resize from topright border
1001                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1002                 {
1003                         highlightedPanel = i;
1004                         HUD_Panel_FirstInDrawQ(i);
1005                         highlightedAction = 2;
1006                         resizeCorner = 2;
1007                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1008                         panel_click_distance_y = mousepos_y - panel_pos_y;
1009                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1010                         return;
1011                 }
1012                 // resize from bottomleft border
1013                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1014                 {
1015                         highlightedPanel = i;
1016                         HUD_Panel_FirstInDrawQ(i);
1017                         highlightedAction = 2;
1018                         resizeCorner = 3;
1019                         panel_click_distance_x = mousepos_x - panel_pos_x;
1020                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1021                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1022                         return;
1023                 }
1024                 // resize from bottomright border
1025                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1026                 {
1027                         highlightedPanel = i;
1028                         HUD_Panel_FirstInDrawQ(i);
1029                         highlightedAction = 2;
1030                         resizeCorner = 4;
1031                         panel_click_distance = panel_size - mousepos + panel_pos;
1032                         panel_click_resizeorigin = panel_pos;
1033                         return;
1034                 }
1035         }
1036         highlightedPanel = -1;
1037         highlightedAction = 0;
1038 }
1039
1040 void HUD_Panel_EnableMenu()
1041 {
1042         menu_enabled = 2;
1043         menu_enabled_time = time;
1044         HUD_Panel_GetName(highlightedPanel);
1045         localcmd("menu_showhudoptions ", panel_name, "\n");
1046 }
1047 float mouse_over_panel;
1048 void HUD_Panel_Mouse()
1049 {
1050         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1051         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1052                 menu_enabled = 0;
1053
1054         /*
1055         print("menu_enabled: ", ftos(menu_enabled), "\n");
1056         print("Highlighted: ", ftos(highlightedPanel), "\n");
1057         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1058         */
1059
1060         // instantly hide the editor cursor if we open the HUDExit dialog
1061         // as hud_fade_alpha doesn't decrease to 0 in this case
1062         // TODO: find a way to fade the cursor out even in this case
1063         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
1064                 return;
1065
1066         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1067
1068         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1069         mousepos_y = bound(0, mousepos_y, vid_conheight);
1070
1071         if(mouseClicked)
1072         {
1073                 if(prevMouseClicked == 0)
1074                 {
1075                         if (tab_panel != -1)
1076                         {
1077                                 //stop ctrl-tab selection
1078                                 tab_panel = -1;
1079                                 reset_tab_panels();
1080                         }
1081                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1082                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1083                         if (highlightedPanel != -1)
1084                         {
1085                                 highlightedPanel_initial_pos = panel_pos;
1086                                 highlightedPanel_initial_size = panel_size;
1087                         }
1088                         // doubleclick check
1089                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1090                         {
1091                                 mouseClicked = 0; // to prevent spam, I guess.
1092                                 HUD_Panel_EnableMenu();
1093                         }
1094                         else
1095                         {
1096                                 if (mouseClicked & S_MOUSE1)
1097                                 {
1098                                         prevMouseClickedTime = time;
1099                                         prevMouseClickedPos = mousepos;
1100                                 }
1101                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1102                         }
1103                 }
1104                 else
1105                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1106
1107                 if (highlightedPanel != -1)
1108                 {
1109                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1110                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1111                         {
1112                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1113                                 // backup!
1114                                 panel_pos_backup = highlightedPanel_initial_pos;
1115                                 panel_size_backup = highlightedPanel_initial_size;
1116                                 highlightedPanel_backup = highlightedPanel;
1117                         }
1118                         else
1119                                 // in case the clicked panel is inside another panel and we aren't
1120                                 // moving it, avoid the immediate "fix" of its position/size
1121                                 // (often unwanted and hateful) by disabling collisions check
1122                                 hud_configure_checkcollisions = false;
1123                 }
1124
1125                 if(highlightedAction == 1)
1126                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1127                 else if(highlightedAction == 2)
1128                 {
1129                         vector mySize;
1130                         if(resizeCorner == 1) {
1131                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1132                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1133                         } else if(resizeCorner == 2) {
1134                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1135                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1136                         } else if(resizeCorner == 3) {
1137                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1138                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1139                         } else { // resizeCorner == 4
1140                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1141                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1142                         }
1143                         HUD_Panel_SetPosSize(mySize);
1144                 }
1145         }
1146         else
1147         {
1148                 if(menu_enabled == 2)
1149                         mouse_over_panel = 0;
1150                 else
1151                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1152                 if (mouse_over_panel && tab_panel == -1)
1153                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1154         }
1155         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1156         const vector cursorsize = '32 32 0';
1157
1158         if(!mouse_over_panel)
1159                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1160         else if(mouse_over_panel == 1)
1161                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1162         else if(mouse_over_panel == 2)
1163                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1164         else
1165                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1166
1167         prevMouseClicked = mouseClicked;
1168 }
1169
1170 const float hlBorderSize = 4;
1171 const string hlBorder = "gfx/hud/default/border_highlighted";
1172 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1173 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1174 {
1175         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1176         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1177         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1178         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1179         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1180 }