qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/checkextension.qh>
  17 #include <common/deathtypes/all.qh>
  18 #include <common/effects/all.inc>
  19 #include <common/effects/all.qh>
  20 #include <common/effects/effect.qh>
  21 #include <common/effects/qc/_mod.qh>
  22 #include <common/ent_cs.qh>
  23 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  24 #include <common/items/_mod.qh>
  25 #include <common/mapinfo.qh>
  26 #include <common/mapobjects/_mod.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/scores.qh>
  32 #include <common/vehicles/all.qh>
  33 #include <lib/csqcmodel/cl_model.qh>
  34 #include <lib/csqcmodel/interpolate.qh>
  35 #include <lib/warpzone/client.qh>
  36
  37 // --------------------------------------------------------------------------
  38 // BEGIN REQUIRED CSQC FUNCTIONS
  39 //include "main.qh"
  40
  41 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  42
  43 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  44 // Useful for precaching things
  45
  46 void CSQC_Init(float apilevel, string enginename, float engineversion)
  47 {
  48         prvm_language = strzone(cvar_string("prvm_language"));
  49
  50 #ifdef WATERMARK
  51         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  52 #endif
  53
  54         CheckEngineExtensions();
  55
  56         {
  57                 int i = 0;
  58                 for ( ; i < 255; ++i)
  59                         if (getplayerkeyvalue(i, "viewentity") == "")
  60                                 break;
  61                 maxclients = i;
  62         }
  63
  64         // needs to be done so early because of the constants they create
  65         static_init();
  66         static_init_late();
  67         static_init_precache();
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72
  73         draw_endBoldFont();
  74
  75         //registercommand("hud_configure");
  76         //registercommand("hud_save");
  77         //registercommand("menu_action");
  78
  79         ConsoleCommand_macro_init();
  80
  81         registercvar("hud_usecsqc", "1");
  82         registercvar("scoreboard_columns", "default");
  83
  84         registercvar("cl_nade_type", "3");
  85         registercvar("cl_pokenade_type", "zombie");
  86
  87         registercvar("cl_jumpspeedcap_min", "");
  88         registercvar("cl_jumpspeedcap_max", "");
  89
  90         registercvar("cl_shootfromfixedorigin", "");
  91
  92         registercvar("cl_multijump", "-1");
  93
  94         registercvar("cl_dodging", "0");
  95
  96         registercvar("cl_spawn_near_teammate", "1");
  97
  98         registercvar("cl_weapon_switch_reload", "1");
  99         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 100
 101         registercvar("cl_allow_uidranking", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         strfree(gametype_custom_name);
 202
 203         deactivate_minigame();
 204         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 205
 206         ReplicateVars(REPLICATEVARS_DESTROY);
 207 }
 208
 209 void AuditLists()
 210 {
 211         entity e;
 212         entity prev;
 213
 214         prev = players;
 215         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 216         {
 217                 if(prev != e.sort_prev)
 218                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 219         }
 220
 221         prev = teams;
 222         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 223         {
 224                 if(prev != e.sort_prev)
 225                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 226         }
 227 }
 228
 229 float RegisterPlayer(entity player)
 230 {
 231         entity pl;
 232         AuditLists();
 233         for(pl = players.sort_next; pl; pl = pl.sort_next)
 234                 if(pl == player)
 235                         error("Player already registered!");
 236         player.sort_next = players.sort_next;
 237         player.sort_prev = players;
 238         if(players.sort_next)
 239                 players.sort_next.sort_prev = player;
 240         players.sort_next = player;
 241         AuditLists();
 242         return true;
 243 }
 244
 245 void RemovePlayer(entity player)
 246 {
 247         entity pl, parent;
 248         AuditLists();
 249         parent = players;
 250         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 251                 parent = pl;
 252
 253         if(!pl)
 254         {
 255                 error("Trying to remove a player which is not in the playerlist!");
 256                 return;
 257         }
 258         parent.sort_next = player.sort_next;
 259         if(player.sort_next)
 260                 player.sort_next.sort_prev = parent;
 261         AuditLists();
 262 }
 263
 264 void MoveToLast(entity e)
 265 {
 266         AuditLists();
 267         entity ent = e.sort_next;
 268         while(ent)
 269         {
 270                 SORT_SWAP(ent, e);
 271                 ent = e.sort_next;
 272         }
 273         AuditLists();
 274 }
 275
 276 float RegisterTeam(entity Team)
 277 {
 278         assert_once(Team.team, eprint(Team));
 279         entity tm;
 280         AuditLists();
 281         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 282                 if(tm == Team)
 283                         error("Team already registered!");
 284         Team.sort_next = teams.sort_next;
 285         Team.sort_prev = teams;
 286         if(teams.sort_next)
 287                 teams.sort_next.sort_prev = Team;
 288         teams.sort_next = Team;
 289         if(Team.team && Team.team != NUM_SPECTATOR)
 290                 ++team_count;
 291         AuditLists();
 292         return true;
 293 }
 294
 295 void RemoveTeam(entity Team)
 296 {
 297         entity tm, parent;
 298         AuditLists();
 299         parent = teams;
 300         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 301                 parent = tm;
 302
 303         if(!tm)
 304         {
 305                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 306                 return;
 307         }
 308         parent.sort_next = Team.sort_next;
 309         if(Team.sort_next)
 310                 Team.sort_next.sort_prev = parent;
 311         if(Team.team && Team.team != NUM_SPECTATOR)
 312                 --team_count;
 313         AuditLists();
 314 }
 315
 316 entity GetTeam(int Team, bool add)
 317 {
 318         TC(int, Team); TC(bool, add);
 319         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 320         if(teamslots[num])
 321                 return teamslots[num];
 322         if (!add)
 323                 return NULL;
 324         entity tm = new_pure(team);
 325         tm.team = Team;
 326         teamslots[num] = tm;
 327         RegisterTeam(tm);
 328         return tm;
 329 }
 330
 331 .float has_team;
 332 bool SetTeam(entity o, int Team)
 333 {
 334         TC(int, Team);
 335         //devassert_once(Team);
 336         entity tm;
 337         if(teamplay)
 338         {
 339                 switch(Team)
 340                 {
 341                         case -1:
 342                         case NUM_TEAM_1:
 343                         case NUM_TEAM_2:
 344                         case NUM_TEAM_3:
 345                         case NUM_TEAM_4:
 346                                 break;
 347                         default:
 348                                 if(GetTeam(Team, false) == NULL)
 349                                 {
 350                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 351                                         Team = NUM_SPECTATOR;
 352                                 }
 353                                 break;
 354                 }
 355         }
 356         else
 357         {
 358                 switch(Team)
 359                 {
 360                         case -1:
 361                         case 0:
 362                                 break;
 363                         default:
 364                                 if(GetTeam(Team, false) == NULL)
 365                                 {
 366                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 367                                         Team = NUM_SPECTATOR;
 368                                 }
 369                                 break;
 370                 }
 371         }
 372         if(Team == -1) // leave
 373         {
 374                 if(o.has_team)
 375                 {
 376                         tm = GetTeam(o.team, false);
 377                         tm.team_size -= 1;
 378                         o.has_team = 0;
 379                         return true;
 380                 }
 381         }
 382         else
 383         {
 384                 if (!o.has_team)
 385                 {
 386                         o.team = Team;
 387                         tm = GetTeam(Team, true);
 388                         tm.team_size += 1;
 389                         o.has_team = 1;
 390                         return true;
 391                 }
 392                 else if(Team != o.team)
 393                 {
 394                         tm = GetTeam(o.team, false);
 395                         tm.team_size -= 1;
 396                         o.team = Team;
 397                         tm = GetTeam(Team, true);
 398                         tm.team_size += 1;
 399                         return true;
 400                 }
 401         }
 402         return false;
 403 }
 404
 405 void Playerchecker_Think(entity this)
 406 {
 407         int i;
 408         entity e;
 409         for(i = 0; i < maxclients; ++i)
 410         {
 411                 e = playerslots[i];
 412                 if(entcs_GetName(i) == "")
 413                 {
 414                         if(e.sort_prev)
 415                         {
 416                                 // player disconnected
 417                                 SetTeam(e, -1);
 418                                 RemovePlayer(e);
 419                                 e.sort_prev = NULL;
 420                                 //e.gotscores = 0;
 421                         }
 422                 }
 423                 else
 424                 {
 425                         if (!e.sort_prev)
 426                         {
 427                                 // player connected
 428                                 if (!e)
 429                                 {
 430                                         playerslots[i] = e = new_pure(playerslot);
 431                                 }
 432                                 e.sv_entnum = i;
 433                                 e.ping = 0;
 434                                 e.ping_packetloss = 0;
 435                                 e.ping_movementloss = 0;
 436                                 //e.gotscores = 0; // we might already have the scores...
 437                                 int t = entcs_GetScoreTeam(i);
 438                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 439                                 RegisterPlayer(e);
 440                                 Scoreboard_UpdatePlayerPos(e);
 441                         }
 442                 }
 443         }
 444         this.nextthink = time + 0.2;
 445 }
 446
 447 void PostInit()
 448 {
 449         entity playerchecker = new_pure(playerchecker);
 450         setthink(playerchecker, Playerchecker_Think);
 451         playerchecker.nextthink = time + 0.2;
 452
 453         TrueAim_Init();
 454
 455         // this can't be called in CSQC_Init as it'd send cvars too early
 456         ReplicateVars_Start();
 457
 458         postinit = true;
 459 }
 460
 461 void Release_Common_Keys()
 462 {
 463         localcmd("-fire\n");
 464         localcmd("-fire2\n");
 465         localcmd("-use\n");
 466         localcmd("-hook\n");
 467         localcmd("-jump\n");
 468         localcmd("-forward\n");
 469         localcmd("-back\n");
 470         localcmd("-moveleft\n");
 471         localcmd("-moveright\n");
 472 }
 473
 474 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 475 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 476 // All keys are in ascii.
 477 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 478 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 479 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 480 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 481 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 482 {
 483         TC(int, bInputType);
 484         bool override = false;
 485
 486         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 487         if (override)
 488                 return true;
 489
 490         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 491         if (override)
 492                 return true;
 493
 494         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 499
 500         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 501
 502         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 503
 504         if(override)
 505                 return true;
 506
 507         if(bInputType == 3 || bInputType == 2)
 508                 return false;
 509
 510         // at this point bInputType can only be 0 or 1 (key pressed or released)
 511         bool key_pressed = (bInputType == 0);
 512
 513         if(key_pressed) {
 514                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 515                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 516                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 517                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 518         }
 519         else {
 520                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 521                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 522                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 523                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 524         }
 525
 526         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 527         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 528         {
 529                 if (hudShiftState & S_TAB)
 530                 {
 531                         Scoreboard_UI_Enable(0);
 532                         return true;
 533                 }
 534                 if (autocvar_menu_gamemenu && !isdemo() && cvar("_menu_gamemenu_dialog_available"))
 535                 {
 536                         localcmd("\nmenu_showgamemenudialog\n");
 537                         return true;
 538                 }
 539         }
 540
 541         return false;
 542 }
 543
 544 // END REQUIRED CSQC FUNCTIONS
 545 // --------------------------------------------------------------------------
 546
 547 // --------------------------------------------------------------------------
 548 // BEGIN OPTIONAL CSQC FUNCTIONS
 549 .int survival_status;
 550 void Ent_RemovePlayerScore(entity this)
 551 {
 552         if(this.owner) {
 553                 SetTeam(this.owner, -1);
 554                 this.owner.gotscores = 0;
 555                 FOREACH(Scores, true, {
 556                         this.owner.(scores(it)) = 0; // clear all scores
 557                 });
 558                 this.owner.ready = 0;
 559                 this.owner.eliminated = 0;
 560                 this.owner.colormap = 0;
 561                 // TODO add a hook to reset this Survival field
 562                 this.owner.survival_status = 0;
 563         }
 564 }
 565
 566 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 567 {
 568         make_pure(this);
 569         entity o;
 570
 571         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 572         // (no I've never heard of M-x replace-string, sed, or anything like that)
 573         bool isNew = !this.owner; // workaround for DP bug
 574         int n = ReadByte()-1;
 575
 576 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 577         if(!isNew && n != this.sv_entnum)
 578         {
 579                 //print("A CSQC entity changed its owner!\n");
 580                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 581                 isNew = true;
 582                 Ent_Remove(this);
 583         }
 584 #endif
 585
 586         this.sv_entnum = n;
 587
 588         o = playerslots[this.sv_entnum];
 589         if (!o)
 590         {
 591                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 592         }
 593         this.owner = o;
 594         o.sv_entnum = this.sv_entnum;
 595         o.gotscores = 1;
 596
 597         //if (!o.sort_prev)
 598         //      RegisterPlayer(o);
 599         //playerchecker will do this for us later, if it has not already done so
 600
 601         int sf = ReadShort();
 602         int lf = ReadShort();
 603         FOREACH(Scores, true, {
 604                 int p = 1 << (i % 16);
 605                 if (sf & p)
 606                 {
 607                         if (lf & p)
 608                                 o.(scores(it)) = ReadInt24_t();
 609                         else
 610                                 o.(scores(it)) = ReadChar();
 611                 }
 612         });
 613
 614         return = true;
 615
 616         if(o.sort_prev)
 617                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 618
 619         this.entremove = Ent_RemovePlayerScore;
 620 }
 621
 622 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 623 {
 624         make_pure(this);
 625         int i;
 626
 627         this.team = ReadByte();
 628         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 629
 630 #if MAX_TEAMSCORE <= 8
 631         int sf = ReadByte();
 632         int lf = ReadByte();
 633 #else
 634         int sf = ReadShort();
 635         int lf = ReadShort();
 636 #endif
 637         for(i = 0; i < MAX_TEAMSCORE; ++i)
 638                 if(sf & BIT(i))
 639                 {
 640                         if(lf & BIT(i))
 641                                 o.(teamscores(i)) = ReadInt24_t();
 642                         else
 643                                 o.(teamscores(i)) = ReadChar();
 644                 }
 645
 646         return = true;
 647
 648         Scoreboard_UpdateTeamPos(o);
 649 }
 650
 651 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 652 {
 653         make_pure(this);
 654         float newspectatee_status;
 655
 656         int f = ReadByte();
 657
 658         scoreboard_showscores_force = (f & BIT(0));
 659
 660         if(f & BIT(1))
 661         {
 662                 newspectatee_status = ReadByte();
 663                 if(newspectatee_status == player_localnum + 1)
 664                         newspectatee_status = -1; // observing
 665         }
 666         else
 667                 newspectatee_status = 0;
 668
 669         spectatorbutton_zoom = (f & BIT(2));
 670         observe_blocked = (f & BIT(3));
 671
 672         if(f & BIT(4))
 673         {
 674                 num_spectators = ReadByte();
 675
 676                 float i, slot;
 677
 678                 for(i = 0; i < MAX_SPECTATORS; ++i)
 679                         spectatorlist[i] = 0; // reset list first
 680
 681                 int limit = min(num_spectators, MAX_SPECTATORS);
 682                 for(i = 0; i < limit; ++i)
 683                 {
 684                         slot = ReadByte();
 685                         spectatorlist[i] = slot - 1;
 686                 }
 687         }
 688         else
 689         {
 690                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 691                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 692                 num_spectators = 0;
 693         }
 694
 695         return = true;
 696
 697         if(newspectatee_status != spectatee_status)
 698         {
 699                 // clear race stuff
 700                 race_laptime = 0;
 701                 race_checkpointtime = 0;
 702                 hud_dynamic_shake_factor = -1;
 703                 spectatee_status_changed_time = time;
 704         }
 705         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 706         {
 707                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 708                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 709                 )
 710                         prev_p_health = -1;
 711                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 712                         prev_health = -1;
 713         }
 714         spectatee_status = newspectatee_status;
 715
 716         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 717 }
 718
 719 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 720 {
 721         make_pure(this);
 722
 723         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 724
 725         if(!(nags & BIT(2)))
 726         {
 727                 strfree(vote_called_vote);
 728                 vote_active = 0;
 729         }
 730         else
 731         {
 732                 vote_active = 1;
 733         }
 734
 735         if(nags & BIT(6))
 736         {
 737                 vote_yescount = ReadByte();
 738                 vote_nocount = ReadByte();
 739                 vote_needed = ReadByte();
 740                 vote_highlighted = ReadChar();
 741         }
 742
 743         if(nags & BIT(7))
 744         {
 745                 strcpy(vote_called_vote, ReadString());
 746         }
 747
 748         if(nags & BIT(0))
 749                 for(int i = 0; i < maxclients;)
 750                         for(int f = ReadByte(), b = 0; b < 8 && i < maxclients; ++b, ++i)
 751                                 if(playerslots[i])
 752                                         playerslots[i].ready = f & BIT(b);
 753
 754         return = true;
 755
 756         ready_waiting = (nags & BIT(0));
 757         ready_waiting_for_me = (nags & BIT(1));
 758         vote_waiting = (nags & BIT(2));
 759         vote_waiting_for_me = (nags & BIT(3));
 760         warmup_stage = (nags & BIT(4));
 761 }
 762
 763 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 764 {
 765         make_pure(this);
 766         int sf = 0;
 767         serialize(byte, 0, sf);
 768         if (sf & 1) {
 769                 for (int j = 0; j < maxclients; ++j) {
 770                         if (playerslots[j]) {
 771                                 playerslots[j].eliminated = true;
 772                         }
 773                 }
 774                 for (int i = 1; i <= maxclients; i += 8) {
 775                         int f = 0;
 776                         serialize(byte, 0, f);
 777                         for (int b = 0; b < 8; ++b) {
 778                                 if (f & BIT(b)) continue;
 779                                 int j = i - 1 + b;
 780                                 if (playerslots[j]) {
 781                                         playerslots[j].eliminated = false;
 782                                 }
 783                         }
 784                 }
 785         }
 786         return true;
 787 }
 788
 789 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 790 {
 791         make_pure(this);
 792         prandom_debug();
 793         float s = ReadShort();
 794         psrandom(s);
 795         return true;
 796 }
 797
 798 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 799 {
 800         make_pure(this);
 801         int sf = ReadInt24_t();
 802         if (sf == 0) {
 803                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 804                         weapon_accuracy[w] = -1;
 805                 return true;
 806         }
 807
 808         int f = 1;
 809         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 810                 if (sf & f) {
 811                         int b = ReadByte();
 812                         if (b == 0)
 813                                 weapon_accuracy[w] = -1;
 814                         else if (b == 255)
 815                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 816                         else
 817                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 818                 }
 819                 f = (f == 0x800000) ? 1 : f * 2;
 820         }
 821         return true;
 822 }
 823
 824 void Spawn_Draw(entity this)
 825 {
 826         bool dodraw = autocvar_cl_spawn_point_particles;
 827         if(dodraw && autocvar_cl_spawn_point_dist_max)
 828         {
 829                 vector org = getpropertyvec(VF_ORIGIN);
 830                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 831         }
 832
 833         if(dodraw)
 834                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 835 }
 836
 837 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 838 {
 839         float teamnum = (ReadByte() - 1);
 840         vector spn_origin = ReadVector();
 841
 842         this.team = (teamnum + 1);
 843
 844         //if(is_new)
 845         //{
 846                 this.origin = spn_origin;
 847                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 848                 //droptofloor();
 849
 850                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 851                 {
 852                         this.mdl = "models/spawnpoint.md3";
 853                         this.colormod = Team_ColorRGB(teamnum);
 854                         precache_model(this.mdl);
 855                         setmodel(this, this.mdl);
 856                         this.drawmask = MASK_NORMAL;
 857                         //this.move_movetype = MOVETYPE_NOCLIP;
 858                         //this.draw = Spawn_Draw;
 859                         IL_PUSH(g_drawables, this);
 860                 }*/
 861                 this.draw = Spawn_Draw;
 862                 if (is_new) IL_PUSH(g_drawables, this);
 863         //}
 864
 865         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 866         return true;
 867 }
 868
 869 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 870 {
 871         // If entnum is 0, ONLY do the local spawn actions
 872         // this way the server can disable the sending of
 873         // spawn origin or such to clients if wanted.
 874         float entnum = ReadByte();
 875
 876         if(entnum)
 877         {
 878                 this.origin = ReadVector();
 879
 880                 if(is_new)
 881                 {
 882                         float teamnum = entcs_GetTeam(entnum - 1);
 883
 884                         if(autocvar_cl_spawn_event_particles)
 885                         {
 886                                 switch(teamnum)
 887                                 {
 888                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 889                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 890                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 891                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 892                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 893                                 }
 894                         }
 895                         if(autocvar_cl_spawn_event_sound)
 896                         {
 897                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 898                         }
 899                 }
 900         }
 901         return = true;
 902
 903         // local spawn actions
 904         if(is_new && (!entnum || (entnum == player_localentnum)))
 905         {
 906                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 907                 {
 908                         zoomin_effect = 1;
 909                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 910                 }
 911
 912                 if(autocvar_cl_unpress_zoom_on_spawn)
 913                 {
 914                         localcmd("-zoom\n");
 915                         button_zoom = false;
 916                 }
 917                 HUD_Radar_Hide_Maximized();
 918         }
 919         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 920 }
 921
 922 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 923 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 924 void CSQC_Ent_Update(entity this, bool isnew)
 925 {
 926         this.sourceLoc = __FILE__":"STR(__LINE__);
 927         int t = ReadByte();
 928
 929         // set up the "time" global for received entities to be correct for interpolation purposes
 930         float savetime = time;
 931         if(servertime)
 932         {
 933                 time = servertime;
 934         }
 935         else
 936         {
 937                 serverprevtime = time;
 938                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 939                 time = serverprevtime + serverdeltatime;
 940         }
 941
 942 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 943         if (this.enttype)
 944         {
 945                 if (t != this.enttype || isnew)
 946                 {
 947                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 948                         Ent_Remove(this);
 949                         ONREMOVE(this);
 950                         clearentity(this);
 951                         isnew = true;
 952                 }
 953         }
 954         else
 955         {
 956                 if (!isnew)
 957                 {
 958                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 959                         isnew = true;
 960                 }
 961         }
 962 #endif
 963         this.enttype = t;
 964         bool done = false;
 965         FOREACH(LinkedEntities, it.m_id == t, {
 966                 if (isnew) this.classname = it.netname;
 967                 if (autocvar_developer_csqcentities)
 968                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 969                 done = it.m_read(this, NULL, isnew);
 970                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 971                 break;
 972         });
 973         time = savetime;
 974         if (!done)
 975         {
 976                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 977         }
 978 }
 979
 980 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 981 // used when an entity changes its type. For an entity that someone interacts
 982 // with others, make sure it can no longer do so.
 983 void Ent_Remove(entity this)
 984 {
 985         if(this.entremove) this.entremove(this);
 986
 987         if(this.skeletonindex)
 988         {
 989                 skel_delete(this.skeletonindex);
 990                 this.skeletonindex = 0;
 991         }
 992
 993         if(this.snd_looping > 0)
 994         {
 995                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 996                 this.snd_looping = 0;
 997         }
 998
 999         this.enttype = 0;
1000         this.classname = "";
1001         this.draw = func_null;
1002         this.entremove = func_null;
1003         // TODO possibly set more stuff to defaults
1004 }
1005 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1006 void CSQC_Ent_Remove(entity this)
1007 {
1008         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1009         if (wasfreed(this))
1010         {
1011                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1012                 return;
1013         }
1014         if (this.enttype) Ent_Remove(this);
1015         delete(this);
1016 }
1017
1018 void Gamemode_Init()
1019 {
1020         if (!isdemo())
1021         {
1022                 if(!(calledhooks & HOOK_START))
1023                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1024                 calledhooks |= HOOK_START;
1025         }
1026 }
1027 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1028 void CSQC_Parse_StuffCmd(string strMessage)
1029 {
1030         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1031         localcmd(strMessage);
1032 }
1033 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1034 void CSQC_Parse_Print(string strMessage)
1035 {
1036         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1037         print(ColorTranslateRGB(strMessage));
1038 }
1039
1040 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1041 void CSQC_Parse_CenterPrint(string strMessage)
1042 {
1043         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1044         centerprint_AddStandard(strMessage);
1045 }
1046
1047 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1048 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1049 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1050 bool CSQC_Parse_TempEntity()
1051 {
1052         // Acquire TE ID
1053         int nTEID = ReadByte();
1054
1055         FOREACH(TempEntities, it.m_id == nTEID, {
1056                 if (autocvar_developer_csqcentities)
1057                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1058                 return it.m_read(NULL, NULL, true);
1059         });
1060
1061         if (autocvar_developer_csqcentities)
1062                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1063
1064         // No special logic for this temporary entity; return 0 so the engine can handle it
1065         return false;
1066 }
1067
1068 bool autocvar_r_drawfog;
1069 bool autocvar_r_fog_exp2;
1070 string forcefog;
1071 void Fog_Force()
1072 {
1073         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1074         {
1075                 if (autocvar_r_drawfog)
1076                         cvar_set("r_drawfog", "0");
1077         }
1078         else if (forcefog != "")
1079         {
1080                 // using cvar_set as it's faster and safer than a command
1081                 if (!autocvar_r_drawfog)
1082                         cvar_set("r_drawfog", "1");
1083                 if (autocvar_r_fog_exp2)
1084                         cvar_set("r_fog_exp2", "0");
1085                 localcmd(sprintf("\nfog %s\n", forcefog));
1086         }
1087 }
1088
1089 bool net_handle_ServerWelcome();
1090 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1091 {
1092         make_pure(this);
1093         gametype = ReadRegistered(Gametypes);
1094         strcpy(gametype_custom_name, ReadString());
1095         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1096         HUD_ModIcons_SetFunc();
1097         FOREACH(Scores, true, {
1098                 strcpy(scores_label(it), ReadString());
1099                 scores_flags(it) = ReadByte();
1100         });
1101         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1102         {
1103                 strcpy(teamscores_label(i), ReadString());
1104                 teamscores_flags(i) = ReadByte();
1105         }
1106         bool welcome_msg_too = ReadByte();
1107         if (welcome_msg_too)
1108                 net_handle_ServerWelcome();
1109         return = true;
1110         Scoreboard_InitScores();
1111         Gamemode_Init();
1112 }
1113
1114 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1115 {
1116         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1117
1118         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1123         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1124         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1125         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1126
1127         strcpy(forcefog, ReadString());
1128
1129         armorblockpercent = ReadByte() / 255.0;
1130         damagepush_speedfactor = ReadByte() / 255.0;
1131
1132         serverflags = ReadByte();
1133
1134         g_trueaim_minrange = ReadCoord();
1135
1136         return = true;
1137
1138         MUTATOR_CALLHOOK(Ent_Init);
1139
1140         if (!postinit) PostInit();
1141 }
1142
1143 float GetSpeedUnitFactor(int speed_unit)
1144 {
1145         switch(speed_unit)
1146         {
1147                 default:
1148                 case 1: return 1.0;
1149                 case 2: return 0.0254;
1150                 case 3: return 0.0254 * 3.6;
1151                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1152                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1153         }
1154 }
1155
1156 string GetSpeedUnit(int speed_unit)
1157 {
1158         switch(speed_unit)
1159         {
1160                 // translator-friendly strings without the initial space
1161                 default:
1162                 case 1: return strcat(" ", _("qu/s"));
1163                 case 2: return strcat(" ", _("m/s"));
1164                 case 3: return strcat(" ", _("km/h"));
1165                 case 4: return strcat(" ", _("mph"));
1166                 case 5: return strcat(" ", _("knots"));
1167         }
1168 }
1169
1170 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1171 {
1172         int b = ReadByte();
1173
1174         switch (b)
1175         {
1176                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1177                         race_checkpoint = ReadByte();
1178                         race_time = ReadInt24_t();
1179                         race_previousbesttime = ReadInt24_t();
1180                         race_mypreviousbesttime = ReadInt24_t();
1181                         string pbestname = ReadString();
1182                         if(autocvar_cl_race_cptimes_onlyself)
1183                         {
1184                                 race_previousbesttime = race_mypreviousbesttime;
1185                                 race_mypreviousbesttime = 0;
1186                                 strcpy(race_previousbestname, "");
1187                         }
1188                         else
1189                                 strcpy(race_previousbestname, pbestname);
1190
1191                         race_checkpointtime = time;
1192
1193                         if(race_checkpoint == 0 || race_checkpoint == 254)
1194                         {
1195                                 race_penaltyaccumulator = 0;
1196                                 race_laptime = time; // valid
1197                         }
1198                         break;
1199
1200                 case RACE_NET_CHECKPOINT_CLEAR:
1201                         race_laptime = 0;
1202                         race_checkpointtime = 0;
1203                         break;
1204
1205                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1206                         race_laptime = ReadCoord();
1207                         race_checkpointtime = -99999;
1208                         // fall through
1209                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1210                         race_nextcheckpoint = ReadByte();
1211
1212                         race_nextbesttime = ReadInt24_t();
1213                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1214                                 race_mybesttime = ReadInt24_t();
1215                         string newname = ReadString();
1216                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1217                         {
1218                                 race_nextbesttime = race_mybesttime;
1219                                 race_mybesttime = 0;
1220                                 strcpy(race_nextbestname, "");
1221                         }
1222                         else
1223                                 strcpy(race_nextbestname, newname);
1224                         break;
1225
1226                 case RACE_NET_CHECKPOINT_HIT_RACE:
1227                         race_mycheckpoint = ReadByte();
1228                         race_mycheckpointtime = time;
1229                         race_mycheckpointdelta = ReadInt24_t();
1230                         race_mycheckpointlapsdelta = ReadByte();
1231                         if(race_mycheckpointlapsdelta >= 128)
1232                                 race_mycheckpointlapsdelta -= 256;
1233                         int who = ReadByte();
1234                         if(who)
1235                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1236                         else
1237                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1238                         break;
1239
1240                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1241                         race_othercheckpoint = ReadByte();
1242                         race_othercheckpointtime = time;
1243                         race_othercheckpointdelta = ReadInt24_t();
1244                         race_othercheckpointlapsdelta = ReadByte();
1245                         if(race_othercheckpointlapsdelta >= 128)
1246                                 race_othercheckpointlapsdelta -= 256;
1247                         int what = ReadByte();
1248                         if(what)
1249                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1250                         else
1251                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1252                         break;
1253
1254                 case RACE_NET_PENALTY_RACE:
1255                 case RACE_NET_PENALTY_QUALIFYING:
1256                         race_penaltyeventtime = time;
1257                         race_penaltytime = ReadShort();
1258                         string reason = ReadString();
1259                         if (reason == "missing a checkpoint")
1260                                 reason = _("missing a checkpoint");
1261                         strcpy(race_penaltyreason, reason);
1262                         if (b == RACE_NET_PENALTY_QUALIFYING)
1263                                 race_penaltyaccumulator += race_penaltytime;
1264                         break;
1265
1266                 case RACE_NET_SERVER_RECORD:
1267                         race_server_record = ReadInt24_t();
1268                         break;
1269                 case RACE_NET_SPEED_AWARD:
1270                         race_speedaward = ReadInt24_t();
1271                         strcpy(race_speedaward_holder, ReadString());
1272                         break;
1273                 case RACE_NET_SPEED_AWARD_BEST:
1274                         race_speedaward_alltimebest = ReadInt24_t();
1275                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1276                         break;
1277                 case RACE_NET_RANKINGS_CNT:
1278                         RANKINGS_DISPLAY_CNT = ReadByte();
1279                         break;
1280                 case RACE_NET_SERVER_RANKINGS:
1281                         float prevpos, del;
1282                         int pos = ReadShort();
1283                         prevpos = ReadShort();
1284                         del = ReadShort();
1285
1286                         // move other rankings out of the way
1287                         int i;
1288                         if (prevpos) {
1289                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1290                                 for (i=m-1; i>pos-1; --i) {
1291                                         grecordtime[i] = grecordtime[i-1];
1292                                         strcpy(grecordholder[i], grecordholder[i-1]);
1293                                 }
1294                         } else if (del) { // a record has been deleted by the admin
1295                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1296                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1297                                                 grecordtime[i] = 0;
1298                                                 strfree(grecordholder[i]);
1299                                         }
1300                                         else {
1301                                                 grecordtime[i] = grecordtime[i+1];
1302                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1303                                         }
1304                                 }
1305                         } else { // player has no ranked record yet
1306                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1307                                         grecordtime[i] = grecordtime[i-1];
1308                                         strcpy(grecordholder[i], grecordholder[i-1]);
1309                                 }
1310                         }
1311
1312                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1313                                 // kick off the player who fell from the last displayed position
1314                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1315                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1316                         }
1317
1318                         // store new ranking
1319                         strcpy(grecordholder[pos-1], ReadString());
1320                         grecordtime[pos-1] = ReadInt24_t();
1321                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1322                                 race_myrank = pos;
1323                         break;
1324                 case RACE_NET_SERVER_STATUS:
1325                         race_status = ReadShort();
1326                         strcpy(race_status_name, ReadString());
1327         }
1328         return true;
1329 }
1330
1331 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1332 {
1333         teamnagger = 1;
1334         return true;
1335 }
1336
1337 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1338 {
1339         int i = ReadByte();
1340         int pi = ReadShort();
1341         int pl = ReadByte();
1342         int ml = ReadByte();
1343         return = true;
1344         entity e = playerslots[i];
1345         if (!e) return;
1346         e.ping = pi;
1347         e.ping_packetloss = pl / 255.0;
1348         e.ping_movementloss = ml / 255.0;
1349 }
1350
1351 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1352 {
1353         int weapon_id = ReadByte();
1354         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1355         complain_weapon_type = ReadByte();
1356         return = true;
1357
1358         complain_weapon_time = time;
1359         weapontime = time; // ping the weapon panel
1360
1361         switch(complain_weapon_type)
1362         {
1363                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1364                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1365                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1366         }
1367 }
1368
1369 string translate_modifications(string s)
1370 {
1371         return build_mutator_list(s);
1372 }
1373
1374 string translate_weaponarena(string s)
1375 {
1376         if (s == "") return s;
1377         if (s == "All Weapons Arena") return _("All Weapons Arena");
1378         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1379         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1380         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1381         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1382         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1383         if (s == "No Weapons Arena") return _("No Weapons Arena");
1384
1385         int n = tokenizebyseparator(s, " & ");
1386         string wpn_list = "";
1387         for (int i = 0; i < n; ++i)
1388         {
1389                 Weapon wep = Weapon_from_name(argv(i));
1390                 if (wep == WEP_Null)
1391                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1392                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1393         }
1394         if (wpn_list != "")
1395                 return sprintf(_("%s Arena"), wpn_list);
1396         else
1397                 return _("No Weapons Arena");
1398 }
1399
1400 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1401 {
1402         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1403         if (version_mismatch)
1404         {
1405                 if(!version_check)
1406                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1407                                 _("Your client version is outdated."), "\n\n\n",
1408                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1409                                 _("Please update!"));
1410                 else
1411                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1412                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1413                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1414         }
1415         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1416 }
1417
1418 bool net_handle_ServerWelcome()
1419 {
1420         campaign = ReadByte();
1421         if (campaign)
1422         {
1423                 int campaign_level = ReadByte();
1424                 // Menu can't build the whole campaign message because it lacks getcommandkey and CCR
1425                 // so we build part of the message here and let the menu insert the level description
1426                 // (that client doesn't know) by replacing the keyword _LEVEL_DESC
1427                 string key = getcommandkey(_("jump"), "+jump");
1428                 string msg = strcat(
1429                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1430                         sprintf(CCR(" ^BG%s\n\n"), "_LEVEL_DESC"),
1431                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1432                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1433                 string welcomedialog_args = strcat("CAMPAIGN ", itos(campaign_level), " \"", msg, "\"");
1434
1435                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1436                 return true;
1437         }
1438
1439         strcpy(hostname, ReadString());
1440         string hostversion = ReadString();
1441         bool version_mismatch = ReadByte();
1442         bool version_check = ReadByte();
1443         srv_minplayers = ReadByte();
1444         srv_maxplayers = ReadByte();
1445         string modifications = translate_modifications(ReadString());
1446         string weaponarena_list = translate_weaponarena(ReadString());
1447         string cache_mutatormsg = ReadString();
1448         string motd = ReadString();
1449
1450         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1451
1452         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1453
1454         msg = strcat(msg, "\n", _("Map:"), " ^2");
1455         if (world.message == "")
1456                 msg = strcat(msg, mi_shortname, "\n");
1457         else
1458         {
1459                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1460                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1461                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1462         }
1463
1464         if (srv_minplayers || srv_maxplayers)
1465         {
1466                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1467                 if (srv_minplayers == srv_maxplayers)
1468                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1469                 else if (srv_minplayers && srv_maxplayers)
1470                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1471                 else if (srv_maxplayers)
1472                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1473                 else
1474                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1475         }
1476
1477         modifications = cons_mid(modifications, ", ", weaponarena_list);
1478         if(modifications != "")
1479                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1480
1481         if (cache_mutatormsg != "")
1482                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1483         string mutator_msg = "";
1484         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1485         mutator_msg = M_ARGV(0, string);
1486         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1487
1488         if (motd != "")
1489                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1490
1491         strcpy(welcome_msg, msg);
1492         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1493         return true;
1494 }
1495
1496 void Welcome_Message_Show_Try()
1497 {
1498         if (!welcome_msg_menu_check_maxtime)
1499                 return;
1500
1501         // if want dialog check if menu is initialized but for a short time
1502         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1503         {
1504                 if (cvar("_menu_welcome_dialog_available"))
1505                 {
1506                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1507                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1508                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1509
1510                         if (intermission || isdemo() || !autocvar_cl_welcome)
1511                         {
1512                                 if (cvar("_menu_cmd_closemenu_available"))
1513                                 {
1514                                         // initialize the dialog without opening it
1515                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1516                                 }
1517                                 else
1518                                 {
1519                                         // legacy code for clients with old menus
1520                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1521                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1522                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1523                                         // close it after it's been initialized so it can still be opened manually
1524                                         localcmd("\ntogglemenu 0\n");
1525                                 }
1526                         }
1527                         else
1528                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1529                 }
1530
1531                 strfree(welcome_msg);
1532                 welcome_msg_menu_check_maxtime = 0;
1533         }
1534 }
1535
1536 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1537 {
1538         return net_handle_ServerWelcome();
1539 }
1540
1541 string _getcommandkey(string cmd_name, string command, bool forcename)
1542 {
1543         string keys;
1544         float n, j, k, l = 0;
1545
1546         if (!autocvar_hud_showbinds)
1547                 return cmd_name;
1548
1549         keys = db_get(binddb, command);
1550         if (keys == "")
1551         {
1552                 bool joy_active = cvar("joy_active");
1553                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1554                 for(j = 0; j < n; ++j)
1555                 {
1556                         k = stof(argv(j));
1557                         if(k != -1)
1558                         {
1559                                 string key = keynumtostring(k);
1560                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1561                                         continue;
1562
1563                                 key = translate_key(key);
1564
1565                                 if (keys == "")
1566                                         keys = key;
1567                                 else
1568                                         keys = strcat(keys, ", ", key);
1569
1570                                 ++l;
1571                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1572                                         break;
1573                         }
1574
1575                 }
1576                 if (keys == "")
1577                         keys = "NO_KEY";
1578                 db_put(binddb, command, keys);
1579         }
1580
1581         if (keys == "NO_KEY") {
1582                 if (autocvar_hud_showbinds > 1)
1583                         return sprintf(_("%s (not bound)"), cmd_name);
1584                 else
1585                         return cmd_name;
1586         }
1587         else if (autocvar_hud_showbinds > 1 || forcename)
1588                 return sprintf("%s (%s)", cmd_name, keys);
1589         else
1590                 return keys;
1591 }
1592
1593 /** engine callback */
1594 void URI_Get_Callback(int id, int status, string data)
1595 {
1596         TC(int, id); TC(int, status);
1597         if(url_URI_Get_Callback(id, status, data))
1598         {
1599                 // handled
1600         }
1601         else if (id == URI_GET_DISCARD)
1602         {
1603                 // discard
1604         }
1605         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1606         {
1607                 // sv_cmd curl
1608                 Curl_URI_Get_Callback(id, status, data);
1609         }
1610         else
1611         {
1612                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1613         }
1614 }